git.notmuchmail.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3
   4 # Use clang on MacOSX. gcc doesn't support __thread key, and Apple has
   5 # abandoned it for clang.  This must be done before the project is defined.
   6 if (APPLE)
   7     set (CMAKE_C_COMPILER "clang")
   8     set (CMAKE_CXX_COMPILER "clang++")
   9 endif ()
  10
  11
  12 project (apitrace)
  13
  14
  15 ##############################################################################
  16 # Options
  17
  18 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  19 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  20     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  21 endif ()
  22
  23 # We use a cached string variable instead of the standard (boolean) OPTION
  24 # command so that we can default to auto-detecting optional depencies, while
  25 # still providing a mechanism to force/disable these optional dependencies, as
  26 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  27 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  28
  29 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  30
  31 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  32
  33
  34 ##############################################################################
  35 # Find dependencies
  36
  37 # Ensure __thread is support
  38 if (NOT MSVC)
  39     include (CheckCXXSourceCompiles)
  40     check_cxx_source_compiles("__thread int i; int main() { return 0; }" HAVE_COMPILER_TLS)
  41     if (NOT HAVE_COMPILER_TLS)
  42         if (APPLE)
  43             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please install XCode 4.5 or higher.")
  44         else (MINGW32)
  45             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please use MinGW g++ version 4.4 or higher")
  46         else ()
  47             message (FATAL_ERROR "C++ compiler does not support __thread keyword.")
  48         endif ()
  49     endif ()
  50 endif ()
  51
  52 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  53
  54 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  55
  56 if (ANDROID)
  57     set (ENABLE_GUI false)
  58 else ()
  59     macro (find_host_package)
  60         find_package (${ARGN})
  61     endmacro()
  62 endif ()
  63
  64 find_host_package (PythonInterp REQUIRED)
  65 find_package (Threads)
  66
  67 if (ENABLE_GUI)
  68     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  69         set (REQUIRE_GUI REQUIRED)
  70     endif ()
  71     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  72 endif ()
  73
  74 if (WIN32)
  75     find_package (DirectX)
  76     set (ENABLE_EGL false)
  77 elseif (APPLE)
  78     set (ENABLE_EGL false)
  79 else ()
  80     find_package (X11)
  81
  82     if (X11_FOUND)
  83         include_directories (${X11_INCLUDE_DIR})
  84         add_definitions (-DHAVE_X11)
  85     else ()
  86         # Print a clear message when X11 is not found
  87         include (FindPackageMessage)
  88         find_package_message (X11 "Could not find X11" "")
  89     endif ()
  90 endif ()
  91
  92
  93 ##############################################################################
  94 # Set global build options
  95
  96 include (CheckCXXCompilerFlag)
  97
  98 if (WIN32)
  99     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
 100     add_definitions (-D_WIN32_WINNT=0x0601 -DWINVER=0x0601)
 101 else (WIN32)
 102     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
 103     if (CXX_COMPILER_FLAG_VISIBILITY)
 104         add_definitions ("-fvisibility=hidden")
 105     endif ()
 106 endif ()
 107
 108 if (MSVC)
 109     # C99 includes for msvc
 110     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
 111
 112     # Enable math constants defines
 113     add_definitions (-D_USE_MATH_DEFINES)
 114
 115     # No min/max macros
 116     add_definitions (-DNOMINMAX)
 117
 118     # Adjust warnings
 119     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 120     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 121     add_definitions (-W4)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-wd4018) # signed/unsigned mismatch
 124     add_definitions (-wd4063) # not a valid value for switch of enum
 125     add_definitions (-wd4100) # unreferenced formal parameter
 126     add_definitions (-wd4127) # conditional expression is constant
 127     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 128     add_definitions (-wd4505) # unreferenced local function has been removed
 129     add_definitions (-wd4512) # assignment operator could not be generated
 130     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 131
 132     # Use static runtime
 133     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 134     foreach (flag_var
 135         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 136         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 137     )
 138         if (${flag_var} MATCHES "/MD")
 139             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 140         endif ()
 141     endforeach (flag_var)
 142 else ()
 143     # Adjust warnings
 144     add_definitions (-Wall)
 145     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 146     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 147
 148     # Use GDB extensions if available
 149     if (CMAKE_COMPILER_IS_GNUC)
 150         set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -ggdb -O0")
 151         set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -ggdb")
 152     endif ()
 153     if (CMAKE_COMPILER_IS_GNUCXX)
 154         set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -ggdb -O0")
 155         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -ggdb")
 156     endif ()
 157
 158     # Be nice to Eclipse
 159     add_definitions (-fmessage-length=0)
 160 endif ()
 161
 162 if (MINGW)
 163     # Avoid depending on MinGW runtime DLLs
 164     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 165     if (HAVE_STATIC_LIBGCC_FLAG)
 166         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 167         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 168         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 169     endif ()
 170     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 171     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 172         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 173         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 174         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 175     endif ()
 176 endif ()
 177
 178
 179 # Put all executables into the same top level build directory, regardless of
 180 # which subdirectory they are declared
 181 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 182
 183
 184 ##############################################################################
 185 # Bundled dependencies
 186 #
 187 # We always use the bundled zlib, libpng, and snappy sources:
 188 # - on Windows to make it easy to deploy the wrappers DLLs
 189 # - on unices to prevent symbol collisions when tracing applications that link
 190 # against other versions of these libraries
 191
 192 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 193 set (ZLIB_LIBRARIES z_bundled)
 194 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 195
 196 include_directories (${ZLIB_INCLUDE_DIRS})
 197
 198 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 199 set (SNAPPY_LIBRARIES snappy_bundled)
 200 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 201
 202 include_directories (${SNAPPY_INCLUDE_DIRS})
 203
 204 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 205 set (PNG_DEFINITIONS "")
 206 set (PNG_LIBRARIES png_bundled)
 207
 208 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 209 include_directories (${PNG_INCLUDE_DIR})
 210 add_definitions (${PNG_DEFINITIONS})
 211
 212 if (MSVC)
 213     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 214     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 215     set (GETOPT_LIBRARIES getopt_bundled)
 216 endif ()
 217
 218 if (WIN32)
 219     add_subdirectory (thirdparty/less)
 220 endif ()
 221
 222 # Always use bundled QJSon.
 223 # - The packaged versions QJson are very old, and do not support NaN/Infinity.
 224 # - To make it easier to build the GUI on Windows and MacOSX, as there are no
 225 # binaries at all.
 226 if (QT4_FOUND)
 227     add_definitions (-DQJSON_EXPORT=)
 228     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 229     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 230     set (QJSON_LIBRARY_DIRS)
 231     set (QJSON_LIBRARIES qjson_bundled)
 232     set (QJSON_FOUND TRUE)
 233 endif ()
 234
 235 # We use bundled headers for all Khronos APIs, to guarantee support for both
 236 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 237 # are so intertwined that conditional compilation extremely difficult. This
 238 # also avoids missing/inconsistent declarations in system headers.
 239 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 240
 241
 242 ##############################################################################
 243 # Installation directories
 244
 245 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 246     # Debian multiarch support
 247     execute_process(COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH
 248         OUTPUT_VARIABLE ARCH_SUBDIR
 249         ERROR_QUIET
 250         OUTPUT_STRIP_TRAILING_WHITESPACE
 251     )
 252 endif()
 253
 254 if (WIN32 OR APPLE)
 255     # On Windows/MacOSX, applications are usually installed on a directory of
 256     # their own
 257     set (DOC_INSTALL_DIR doc)
 258     set (LIB_INSTALL_DIR lib)
 259     set (LIB_ARCH_INSTALL_DIR lib)
 260 else ()
 261     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 262     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 263     if (ARCH_SUBDIR)
 264         set (LIB_ARCH_INSTALL_DIR lib/${ARCH_SUBDIR}/${CMAKE_PROJECT_NAME})
 265     else ()
 266         set (LIB_ARCH_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 267     endif ()
 268 endif ()
 269
 270 set (SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 271 set (WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 272
 273 # Expose the binary/install directories to source
 274 #
 275 # TODO: Use the same directory layout, for both build and install directories,
 276 # so that binaries can find each other using just relative paths.
 277 #
 278 add_definitions(
 279     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 280     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 281     -DAPITRACE_PROGRAMS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/bin"
 282     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 283     -DAPITRACE_WRAPPERS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 284 )
 285
 286
 287 ##############################################################################
 288 # Common libraries / utilities
 289
 290 include_directories (
 291     ${CMAKE_CURRENT_BINARY_DIR}
 292     ${CMAKE_CURRENT_SOURCE_DIR}
 293     ${CMAKE_CURRENT_SOURCE_DIR}/common
 294 )
 295
 296 if (WIN32)
 297     set (os os_win32.cpp)
 298     set (glws_os glws_wgl.cpp)
 299 else ()
 300     set (os os_posix.cpp)
 301     if (APPLE)
 302         set (glws_os glws_cocoa.mm)
 303     else ()
 304         set (glws_os glws_glx.cpp)
 305     endif ()
 306 endif ()
 307
 308 add_library (common STATIC
 309     common/trace_callset.cpp
 310     common/trace_dump.cpp
 311     common/trace_file.cpp
 312     common/trace_file_read.cpp
 313     common/trace_file_write.cpp
 314     common/trace_file_zlib.cpp
 315     common/trace_file_snappy.cpp
 316     common/trace_model.cpp
 317     common/trace_parser.cpp
 318     common/trace_parser_flags.cpp
 319     common/trace_writer.cpp
 320     common/trace_writer_local.cpp
 321     common/trace_writer_model.cpp
 322     common/trace_loader.cpp
 323     common/trace_resource.cpp
 324     common/trace_tools_trace.cpp
 325     common/trace_profiler.cpp
 326     common/image.cpp
 327     common/image_bmp.cpp
 328     common/image_pnm.cpp
 329     common/image_png.cpp
 330     common/trace_option.cpp
 331     common/${os}
 332 )
 333
 334 set_target_properties (common PROPERTIES
 335     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 336     # Ensure it can be statically linked in shared libraries
 337     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 338 )
 339
 340 if (ANDROID)
 341     target_link_libraries (common
 342         log
 343     )
 344 endif ()
 345
 346
 347 ##############################################################################
 348 # Sub-directories
 349
 350 add_subdirectory (dispatch)
 351 add_subdirectory (helpers)
 352 add_subdirectory (wrappers)
 353 add_subdirectory (retrace)
 354
 355
 356 ##############################################################################
 357 # CLI
 358
 359 if (ENABLE_CLI)
 360     add_subdirectory (cli)
 361 endif ()
 362
 363 ##############################################################################
 364 # Scripts (to support the CLI)
 365
 366 install (
 367     PROGRAMS
 368         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 369         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 370         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 371     DESTINATION ${SCRIPTS_INSTALL_DIR}
 372 )
 373
 374 ##############################################################################
 375 # GUI
 376
 377 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 378     add_subdirectory(gui)
 379 endif ()
 380
 381
 382 ##############################################################################
 383 # Packaging
 384
 385 install (
 386     FILES
 387         BUGS.markdown
 388         LICENSE
 389         NEWS.markdown
 390         README.markdown
 391     DESTINATION ${DOC_INSTALL_DIR}
 392 )
 393
 394 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 395 set (CPACK_PACKAGE_VERSION_MINOR "0")
 396
 397 # Use current date in YYYYMMDD format as patch number
 398 execute_process (
 399     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 400     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 401 )
 402
 403 # cpack mistakenly detects Mingw-w64 as win32
 404 if (MINGW)
 405     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 406         set (CPACK_SYSTEM_NAME win64)
 407     endif ()
 408 endif ()
 409
 410 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 411 if (WIN32)
 412     set (CPACK_GENERATOR "ZIP")
 413 elseif (APPLE)
 414     set (CPACK_GENERATOR "DragNDrop")
 415 else ()
 416     set (CPACK_GENERATOR "TBZ2")
 417 endif ()
 418
 419 include(CPack)