git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-maildir-fcc.el

   1 ;;; notmuch-maildir-fcc.el --- inserting using a fcc handler  -*- lexical-binding: t -*-
   2
   3 ;; Copyright © Jesse Rosenthal
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Jesse Rosenthal <jrosenthal@jhu.edu>
  21
  22 ;;; Code:
  23
  24 (require 'seq)
  25
  26 (require 'message)
  27
  28 (require 'notmuch-lib)
  29
  30 (defvar notmuch-maildir-fcc-count 0)
  31
  32 ;;; Options
  33
  34 (defcustom notmuch-fcc-dirs "sent"
  35   "Determines the Fcc Header which says where to save outgoing mail.
  36
  37 Three types of values are permitted:
  38
  39 - nil: no Fcc header is added,
  40
  41 - a string: the value of `notmuch-fcc-dirs' is the Fcc header to
  42   be used.
  43
  44 - an alist: the folder is chosen based on the From address of
  45   the current message according to an alist mapping regular
  46   expressions to folders or nil:
  47
  48      ((\"Sebastian@SSpaeth.de\" . \"privat\")
  49       (\"spaetz@sspaeth.de\" . \"OUTBOX.OSS\")
  50       (\".*\" . \"defaultinbox\"))
  51
  52   If none of the regular expressions match the From address, or
  53   if the cdr of the matching entry is nil, then no Fcc header
  54   will be added.
  55
  56 If `notmuch-maildir-use-notmuch-insert' is set (the default) then
  57 the header should be of the form \"folder +tag1 -tag2\" where
  58 folder is the folder (relative to the notmuch mailstore) to store
  59 the message in, and tag1 and tag2 are tag changes to apply to the
  60 stored message. This string is split using `split-string-and-unquote',
  61 so a folder name containing spaces can be specified by
  62 quoting each space with an immediately preceding backslash
  63 or surrounding the entire folder name in double quotes.
  64
  65 If `notmuch-maildir-use-notmuch-insert' is nil then the Fcc
  66 header should be the directory where the message should be
  67 saved. A relative directory will be understood to specify a
  68 directory within the notmuch mail store, (as set by the
  69 database.path option in the notmuch configuration file).
  70
  71 In all cases you will be prompted to create the folder or
  72 directory if it does not exist yet when sending a mail."
  73
  74   :type '(choice
  75           (const :tag "No FCC header" nil)
  76           (string :tag "A single folder")
  77           (repeat :tag "A folder based on the From header"
  78                   (cons regexp (choice (const :tag "No FCC header" nil)
  79                                        (string :tag "Folder")))))
  80   :require 'notmuch-fcc-initialization
  81   :group 'notmuch-send)
  82
  83 (defcustom notmuch-maildir-use-notmuch-insert t
  84   "Should fcc use notmuch insert instead of simple fcc."
  85   :type '(choice :tag "Fcc Method"
  86                  (const :tag "Use notmuch insert" t)
  87                  (const :tag "Use simple fcc" nil))
  88   :group 'notmuch-send)
  89
  90 ;;; Functions which set up the fcc header in the message buffer.
  91
  92 (defun notmuch-fcc-header-setup ()
  93   "Add an Fcc header to the current message buffer.
  94
  95 If the Fcc header is already set, then keep it as-is.
  96 Otherwise set it according to `notmuch-fcc-dirs'."
  97   (let ((subdir
  98          (cond
  99           ((or (not notmuch-fcc-dirs)
 100                (message-field-value "Fcc"))
 101            ;; Nothing set or an existing header.
 102            nil)
 103           ((stringp notmuch-fcc-dirs)
 104            notmuch-fcc-dirs)
 105           ((and (listp notmuch-fcc-dirs)
 106                 (stringp (car notmuch-fcc-dirs)))
 107            ;; Old style - no longer works.
 108            (error "Invalid `notmuch-fcc-dirs' setting (old style)"))
 109           ((listp notmuch-fcc-dirs)
 110            (if-let ((match (seq-some (let ((from (message-field-value "From")))
 111                                        (pcase-lambda (`(,regexp . ,folder))
 112                                          (and (string-match-p regexp from)
 113                                               (cons t folder))))
 114                                      notmuch-fcc-dirs)))
 115                (cdr match)
 116              (message "No Fcc header added.")
 117              nil))
 118           (t
 119            (error "Invalid `notmuch-fcc-dirs' setting (neither string nor list)")))))
 120     (when subdir
 121       (if notmuch-maildir-use-notmuch-insert
 122           (notmuch-maildir-add-notmuch-insert-style-fcc-header subdir)
 123         (notmuch-maildir-add-file-style-fcc-header subdir)))))
 124
 125 (defun notmuch-maildir-add-notmuch-insert-style-fcc-header (subdir)
 126   ;; Notmuch insert does not accept absolute paths, so check the user
 127   ;; really want this header inserted.
 128   (when (or (not (= (elt subdir 0) ?/))
 129             (y-or-n-p (format "Fcc header %s is an absolute path %s %s" subdir
 130                               "and notmuch insert is requested."
 131                               "Insert header anyway? ")))
 132     (message-add-header (concat "Fcc: " subdir))))
 133
 134 (defun notmuch-maildir-add-file-style-fcc-header (subdir)
 135   (message-add-header
 136    (concat "Fcc: "
 137            (file-truename
 138             ;; If the resulting directory is not an absolute path,
 139             ;; prepend the standard notmuch database path.
 140             (if (= (elt subdir 0) ?/)
 141                 subdir
 142               (concat (notmuch-database-path) "/" subdir))))))
 143
 144 ;;; Functions for saving a message using either method.
 145
 146 (defmacro with-temporary-notmuch-message-buffer (&rest body)
 147   "Set-up a temporary copy of the current message-mode buffer."
 148   `(without-restriction
 149      (let ((case-fold-search t)
 150            (buf (current-buffer))
 151            (mml-externalize-attachments message-fcc-externalize-attachments))
 152        (with-current-buffer (get-buffer-create " *message temp*")
 153          (message-clone-locals buf) ;; for message-encoded-mail-cache
 154          (erase-buffer)
 155          (insert-buffer-substring buf)
 156          ,@body))))
 157
 158 (defun notmuch-maildir-setup-message-for-saving ()
 159   "Setup message for saving.
 160
 161 This should be called on a temporary copy.
 162 This is taken from the function message-do-fcc."
 163   (if (not message-encoded-mail-cache)
 164       (message-encode-message-body)
 165     (erase-buffer)
 166     (insert message-encoded-mail-cache))
 167   (save-restriction
 168     (message-narrow-to-headers)
 169     (mail-encode-encoded-word-buffer))
 170   (goto-char (point-min))
 171   (when (re-search-forward
 172          (concat "^" (regexp-quote mail-header-separator) "$")
 173          nil t)
 174     (replace-match "" t t )))
 175
 176 (defun notmuch-maildir-message-do-fcc ()
 177   "Process Fcc headers in the current buffer.
 178
 179 This is a rearranged version of message mode's message-do-fcc."
 180   (let (files file)
 181     (save-excursion
 182       (save-restriction
 183         (message-narrow-to-headers)
 184         (setq file (message-fetch-field "fcc" t)))
 185       (when file
 186         (with-temporary-notmuch-message-buffer
 187          (notmuch-maildir-setup-message-for-saving)
 188          (save-restriction
 189            (message-narrow-to-headers)
 190            (while (setq file (message-fetch-field "fcc" t))
 191              (push file files)
 192              (message-remove-header "fcc" nil t)))
 193          ;; Process FCC operations.
 194          (mapc #'notmuch-fcc-handler files)
 195          (kill-buffer (current-buffer)))))))
 196
 197 (defun notmuch-fcc-handler (fcc-header)
 198   "Store message with notmuch insert or normal (file) fcc.
 199
 200 If `notmuch-maildir-use-notmuch-insert' is set then store the
 201 message using notmuch insert. Otherwise store the message using
 202 normal fcc."
 203   (message "Doing Fcc...")
 204   (if notmuch-maildir-use-notmuch-insert
 205       (notmuch-maildir-fcc-with-notmuch-insert fcc-header)
 206     (notmuch-maildir-fcc-file-fcc fcc-header))
 207   (message "Doing Fcc...done"))
 208
 209 ;;; Functions for saving a message using notmuch insert.
 210
 211 (defun notmuch-maildir-notmuch-insert-current-buffer (folder &optional create tags)
 212   "Use notmuch insert to put the current buffer in the database.
 213
 214 This inserts the current buffer as a message into the notmuch
 215 database in folder FOLDER. If CREATE is non-nil it will supply
 216 the --create-folder flag to create the folder if necessary. TAGS
 217 should be a list of tag changes to apply to the inserted message."
 218   (apply 'notmuch-call-notmuch-process
 219          :stdin-string (buffer-string) "insert"
 220          (append (and create (list "--create-folder"))
 221                  (list (concat "--folder=" folder))
 222                  tags)))
 223
 224 (defun notmuch-maildir-fcc-with-notmuch-insert (fcc-header &optional create)
 225   "Store message with notmuch insert.
 226
 227 The fcc-header should be of the form \"folder +tag1 -tag2\" where
 228 folder is the folder (relative to the notmuch mailstore) to store
 229 the message in, and tag1 and tag2 are tag changes to apply to the
 230 stored message. This string is split using `split-string-and-unquote',
 231 so a folder name containing spaces can be specified by
 232 quoting each space with an immediately preceding backslash
 233 or surrounding the entire folder name in double quotes.
 234
 235 If CREATE is non-nil then create the folder if necessary."
 236   (pcase-let ((`(,folder . ,tags)
 237                (split-string-and-unquote fcc-header)))
 238     (condition-case nil
 239         (notmuch-maildir-notmuch-insert-current-buffer folder create tags)
 240       ;; Since there are many reasons notmuch insert could fail, e.g.,
 241       ;; locked database, non-existent folder (which could be due to a
 242       ;; typo, or just the user want a new folder, let the user decide
 243       ;; how to deal with it.
 244       (error
 245        (let ((response (read-char-choice "Insert failed: \
 246 \(r)etry, (c)reate folder, (i)gnore, or (e)dit the header? " '(?r ?c ?i ?e))))
 247          (cl-case response
 248            (?r (notmuch-maildir-fcc-with-notmuch-insert fcc-header))
 249            (?c (notmuch-maildir-fcc-with-notmuch-insert fcc-header t))
 250            (?i t)
 251            (?e (notmuch-maildir-fcc-with-notmuch-insert
 252                 (read-from-minibuffer "Fcc header: " fcc-header)))))))))
 253
 254 ;;; Functions for saving a message using file fcc.
 255
 256 (defun notmuch-maildir-fcc-host-fixer (hostname)
 257   (replace-regexp-in-string "/\\|:"
 258                             (lambda (s)
 259                               (cond ((string-equal s "/") "\\057")
 260                                     ((string-equal s ":") "\\072")
 261                                     (t s)))
 262                             hostname
 263                             t
 264                             t))
 265
 266 (defun notmuch-maildir-fcc-make-uniq-maildir-id ()
 267   (let* ((ftime (float-time))
 268          (microseconds (mod (* 1000000 ftime) 1000000))
 269          (hostname (notmuch-maildir-fcc-host-fixer (system-name))))
 270     (cl-incf notmuch-maildir-fcc-count)
 271     (format "%d.%d_%d_%d.%s"
 272             ftime
 273             (emacs-pid)
 274             microseconds
 275             notmuch-maildir-fcc-count
 276             hostname)))
 277
 278 (defun notmuch-maildir-fcc-dir-is-maildir-p (dir)
 279   (and (file-exists-p (concat dir "/cur/"))
 280        (file-exists-p (concat dir "/new/"))
 281        (file-exists-p (concat dir "/tmp/"))))
 282
 283 (defun notmuch-maildir-fcc-create-maildir (path)
 284   (cond ((or (not (file-exists-p path)) (file-directory-p path))
 285          (make-directory (concat path "/cur/") t)
 286          (make-directory (concat path "/new/") t)
 287          (make-directory (concat path "/tmp/") t))
 288         ((file-regular-p path)
 289          (error "%s is a file. Can't create maildir." path))
 290         (t
 291          (error "I don't know how to create a maildir here"))))
 292
 293 (defun notmuch-maildir-fcc-save-buffer-to-tmp (destdir)
 294   "Returns the msg id of the message written to the temp directory
 295 if successful, nil if not."
 296   (let ((msg-id (notmuch-maildir-fcc-make-uniq-maildir-id)))
 297     (while (file-exists-p (concat destdir "/tmp/" msg-id))
 298       (setq msg-id (notmuch-maildir-fcc-make-uniq-maildir-id)))
 299     (cond ((notmuch-maildir-fcc-dir-is-maildir-p destdir)
 300            (write-file (concat destdir "/tmp/" msg-id))
 301            msg-id)
 302           (t
 303            (error "Can't write to %s. Not a maildir." destdir)))))
 304
 305 (defun notmuch-maildir-fcc-move-tmp-to-new (destdir msg-id)
 306   (add-name-to-file
 307    (concat destdir "/tmp/" msg-id)
 308    (concat destdir "/new/" msg-id ":2,")))
 309
 310 (defun notmuch-maildir-fcc-move-tmp-to-cur (destdir msg-id &optional mark-seen)
 311   (add-name-to-file
 312    (concat destdir "/tmp/" msg-id)
 313    (concat destdir "/cur/" msg-id ":2," (and mark-seen "S"))))
 314
 315 (defun notmuch-maildir-fcc-file-fcc (fcc-header)
 316   "Write the message to the file specified by FCC-HEADER.
 317
 318 If that fails, then offer the user a chance to correct the header
 319 or filesystem."
 320   (if (notmuch-maildir-fcc-dir-is-maildir-p fcc-header)
 321       (notmuch-maildir-fcc-write-buffer-to-maildir fcc-header t)
 322     ;; The fcc-header is not a valid maildir see if the user wants to
 323     ;; fix it in some way.
 324     (let* ((prompt (format "Fcc %s is not a maildir: \
 325 \(r)etry, (c)reate folder, (i)gnore, or (e)dit the header? " fcc-header))
 326            (response (read-char-choice prompt '(?r ?c ?i ?e))))
 327       (cl-case response
 328         (?r (notmuch-maildir-fcc-file-fcc fcc-header))
 329         (?c (if (file-writable-p fcc-header)
 330                 (notmuch-maildir-fcc-create-maildir fcc-header)
 331               (message "No permission to create %s." fcc-header)
 332               (sit-for 2))
 333             (notmuch-maildir-fcc-file-fcc fcc-header))
 334         (?i t)
 335         (?e (notmuch-maildir-fcc-file-fcc
 336              (read-from-minibuffer "Fcc header: " fcc-header)))))))
 337
 338 (defun notmuch-maildir-fcc-write-buffer-to-maildir (destdir &optional mark-seen)
 339   "Write the current buffer to maildir destdir.
 340
 341 If mark-seen is non-nil, then write it to \"cur/\", and mark it
 342 as read, otherwise write it to \"new/\". Return t if successful,
 343 and nil otherwise."
 344   (let ((orig-buffer (buffer-name)))
 345     (with-temp-buffer
 346       (insert-buffer-substring orig-buffer)
 347       (catch 'link-error
 348         (let ((msg-id (notmuch-maildir-fcc-save-buffer-to-tmp destdir)))
 349           (when msg-id
 350             (condition-case nil
 351                 (if mark-seen
 352                     (notmuch-maildir-fcc-move-tmp-to-cur destdir msg-id t)
 353                   (notmuch-maildir-fcc-move-tmp-to-new destdir msg-id))
 354               (file-already-exists
 355                (throw 'link-error nil))))
 356           (delete-file (concat destdir "/tmp/" msg-id))))
 357       t)))
 358
 359 ;;; _
 360
 361 (provide 'notmuch-maildir-fcc)
 362
 363 ;;; notmuch-maildir-fcc.el ends here