git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 ;;; Code:
  23
  24 (eval-when-compile (require 'cl-lib))
  25
  26 (require 'message)
  27 (require 'mm-view)
  28 (require 'format-spec)
  29
  30 (require 'notmuch-lib)
  31 (require 'notmuch-address)
  32 (require 'notmuch-draft)
  33 (require 'notmuch-message)
  34
  35 (declare-function notmuch-show-insert-body "notmuch-show" (msg body depth))
  36 (declare-function notmuch-fcc-header-setup "notmuch-maildir-fcc" ())
  37 (declare-function notmuch-maildir-message-do-fcc "notmuch-maildir-fcc" ())
  38 (declare-function notmuch-draft-postpone "notmuch-draft" ())
  39 (declare-function notmuch-draft-save "notmuch-draft" ())
  40
  41 ;;
  42
  43 (defcustom notmuch-mua-send-hook nil
  44   "Hook run before sending messages."
  45   :type 'hook
  46   :group 'notmuch-send
  47   :group 'notmuch-hooks)
  48
  49 (defcustom notmuch-mua-compose-in 'current-window
  50   (concat
  51    "Where to create the mail buffer used to compose a new message.
  52 Possible values are `current-window' (default), `new-window' and
  53 `new-frame'. If set to `current-window', the mail buffer will be
  54 displayed in the current window, so the old buffer will be
  55 restored when the mail buffer is killed. If set to `new-window'
  56 or `new-frame', the mail buffer will be displayed in a new
  57 window/frame that will be destroyed when the buffer is killed.
  58 You may want to customize `message-kill-buffer-on-exit'
  59 accordingly."
  60    (when (< emacs-major-version 24)
  61      " Due to a known bug in Emacs 23, you should not set
  62 this to `new-window' if `message-kill-buffer-on-exit' is
  63 disabled: this would result in an incorrect behavior."))
  64   :group 'notmuch-send
  65   :type '(choice (const :tag "Compose in the current window" current-window)
  66                  (const :tag "Compose mail in a new window"  new-window)
  67                  (const :tag "Compose mail in a new frame"   new-frame)))
  68
  69 (defcustom notmuch-mua-user-agent-function nil
  70   "Function used to generate a `User-Agent:' string. If this is
  71 `nil' then no `User-Agent:' will be generated."
  72   :type '(choice (const :tag "No user agent string" nil)
  73                  (const :tag "Full" notmuch-mua-user-agent-full)
  74                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  75                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  76                  (function :tag "Custom user agent function"
  77                            :value notmuch-mua-user-agent-full))
  78   :group 'notmuch-send)
  79
  80 (defcustom notmuch-mua-hidden-headers nil
  81   "Headers that are added to the `message-mode' hidden headers
  82 list."
  83   :type '(repeat string)
  84   :group 'notmuch-send)
  85
  86 (defgroup notmuch-reply nil
  87   "Replying to messages in notmuch"
  88   :group 'notmuch)
  89
  90 (defcustom notmuch-mua-cite-function 'message-cite-original
  91   "*Function for citing an original message.
  92 Predefined functions include `message-cite-original' and
  93 `message-cite-original-without-signature'.
  94 Note that these functions use `mail-citation-hook' if that is non-nil."
  95   :type '(radio (function-item message-cite-original)
  96                 (function-item message-cite-original-without-signature)
  97                 (function-item sc-cite-original)
  98                 (function :tag "Other"))
  99   :link '(custom-manual "(message)Insertion Variables")
 100   :group 'notmuch-reply)
 101
 102 (defcustom notmuch-mua-reply-insert-header-p-function
 103   'notmuch-show-reply-insert-header-p-never
 104   "Function to decide which parts get a header when replying.
 105
 106 This function specifies which parts of a mime message with
 107 multiple parts get a header."
 108   :type '(radio (const :tag "No part headers"
 109                        notmuch-show-reply-insert-header-p-never)
 110                 (const :tag "All except multipart/* and hidden parts"
 111                        notmuch-show-reply-insert-header-p-trimmed)
 112                 (const :tag "Only for included text parts"
 113                        notmuch-show-reply-insert-header-p-minimal)
 114                 (const :tag "Exactly as in show view"
 115                        notmuch-show-insert-header-p)
 116                 (function :tag "Other"))
 117   :group 'notmuch-reply)
 118
 119 (defcustom notmuch-mua-attachment-regexp
 120   "\\b\\(attache\?ment\\|attached\\|attach\\|pi[èe]ce\s+jointe?\\)\\b"
 121   "Message body text indicating that an attachment is expected.
 122
 123 This is not used unless `notmuch-mua-attachment-check' is added
 124 to `notmuch-mua-send-hook'."
 125   :type 'regexp
 126   :group 'notmuch-send)
 127
 128 ;;
 129
 130 (defun notmuch-mua-attachment-check ()
 131   "Signal an error if the message text indicates that an
 132 attachment is expected but no MML referencing an attachment is
 133 found.
 134
 135 Typically this is added to `notmuch-mua-send-hook'."
 136   (when (and
 137          ;; When the message mentions attachment...
 138          (save-excursion
 139            (message-goto-body)
 140            ;; Limit search from reaching other possible parts of the message
 141            (let ((search-limit (search-forward "\n<#" nil t)))
 142              (message-goto-body)
 143              (cl-loop while (re-search-forward notmuch-mua-attachment-regexp
 144                                                search-limit t)
 145                       ;; For every instance of the "attachment" string
 146                       ;; found, examine the text properties. If the text
 147                       ;; has either a `face' or `syntax-table' property
 148                       ;; then it is quoted text and should *not* cause the
 149                       ;; user to be asked about a missing attachment.
 150                       if (let ((props (text-properties-at (match-beginning 0))))
 151                            (not (or (memq 'syntax-table props)
 152                                     (memq 'face props))))
 153                       return t
 154                       finally return nil)))
 155          ;; ...but doesn't have a part with a filename...
 156          (save-excursion
 157            (message-goto-body)
 158            (not (re-search-forward "^<#part [^>]*filename=" nil t)))
 159          ;; ...and that's not okay...
 160          (not (y-or-n-p "Attachment mentioned, but no attachment - is that okay?")))
 161     ;; ...signal an error.
 162     (error "Missing attachment")))
 163
 164 (defun notmuch-mua-get-switch-function ()
 165   "Get a switch function according to `notmuch-mua-compose-in'."
 166   (cond ((eq notmuch-mua-compose-in 'current-window)
 167          'switch-to-buffer)
 168         ((eq notmuch-mua-compose-in 'new-window)
 169          'switch-to-buffer-other-window)
 170         ((eq notmuch-mua-compose-in 'new-frame)
 171          'switch-to-buffer-other-frame)
 172         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
 173
 174 (defun notmuch-mua-maybe-set-window-dedicated ()
 175   "Set the selected window as dedicated according to
 176 `notmuch-mua-compose-in'."
 177   (when (or (eq notmuch-mua-compose-in 'new-frame)
 178             (eq notmuch-mua-compose-in 'new-window))
 179     (set-window-dedicated-p (selected-window) t)))
 180
 181 (defun notmuch-mua-user-agent-full ()
 182   "Generate a `User-Agent:' string suitable for notmuch."
 183   (concat (notmuch-mua-user-agent-notmuch)
 184           " "
 185           (notmuch-mua-user-agent-emacs)))
 186
 187 (defun notmuch-mua-user-agent-notmuch ()
 188   "Generate a `User-Agent:' string suitable for notmuch."
 189   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
 190                              (notmuch-cli-version)
 191                            notmuch-emacs-version)))
 192     (concat "Notmuch/" notmuch-version " (https://notmuchmail.org)")))
 193
 194 (defun notmuch-mua-user-agent-emacs ()
 195   "Generate a `User-Agent:' string suitable for notmuch."
 196   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 197
 198 (defun notmuch-mua-add-more-hidden-headers ()
 199   "Add some headers to the list that are hidden by default."
 200   (mapc (lambda (header)
 201           (unless (member header message-hidden-headers)
 202             (push header message-hidden-headers)))
 203         notmuch-mua-hidden-headers))
 204
 205 (defun notmuch-mua-reply-crypto (parts)
 206   "Add mml sign-encrypt flag if any part of original message is encrypted."
 207   (cl-loop for part in parts
 208            if (notmuch-match-content-type (plist-get part :content-type)
 209                                           "multipart/encrypted")
 210            do (mml-secure-message-sign-encrypt)
 211            else if (notmuch-match-content-type (plist-get part :content-type)
 212                                                "multipart/*")
 213            do (notmuch-mua-reply-crypto (plist-get part :content))))
 214
 215 ;; There is a bug in emacs 23's message.el that results in a newline
 216 ;; not being inserted after the References header, so the next header
 217 ;; is concatenated to the end of it. This function fixes the problem,
 218 ;; while guarding against the possibility that some current or future
 219 ;; version of emacs has the bug fixed.
 220 (defun notmuch-mua-insert-references (original-func header references)
 221   (funcall original-func header references)
 222   (unless (bolp) (insert "\n")))
 223
 224 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 225   (let ((args '("reply" "--format=sexp" "--format-version=4"))
 226         (process-crypto notmuch-show-process-crypto)
 227         reply
 228         original)
 229     (when process-crypto
 230       (setq args (append args '("--decrypt=true"))))
 231     (if reply-all
 232         (setq args (append args '("--reply-to=all")))
 233       (setq args (append args '("--reply-to=sender"))))
 234     (setq args (append args (list query-string)))
 235     ;; Get the reply object as SEXP, and parse it into an elisp object.
 236     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 237     ;; Extract the original message to simplify the following code.
 238     (setq original (plist-get reply :original))
 239     ;; Extract the headers of both the reply and the original message.
 240     (let* ((original-headers (plist-get original :headers))
 241            (reply-headers (plist-get reply :reply-headers)))
 242       ;; If sender is non-nil, set the From: header to its value.
 243       (when sender
 244         (plist-put reply-headers :From sender))
 245       (let
 246           ;; Overlay the composition window on that being used to read
 247           ;; the original message.
 248           ((same-window-regexps '("\\*mail .*")))
 249         ;; We modify message-header-format-alist to get around
 250         ;; a bug in message.el.  See the comment above on
 251         ;; notmuch-mua-insert-references.
 252         (let ((message-header-format-alist
 253                (cl-loop for pair in message-header-format-alist
 254                         if (eq (car pair) 'References)
 255                         collect (cons 'References
 256                                       (apply-partially
 257                                        'notmuch-mua-insert-references
 258                                        (cdr pair)))
 259                         else
 260                         collect pair)))
 261           (notmuch-mua-mail (plist-get reply-headers :To)
 262                             (notmuch-sanitize (plist-get reply-headers :Subject))
 263                             (notmuch-headers-plist-to-alist reply-headers)
 264                             nil (notmuch-mua-get-switch-function))))
 265       ;; Create a buffer-local queue for tag changes triggered when
 266       ;; sending the reply.
 267       (when notmuch-message-replied-tags
 268         (setq-local notmuch-message-queued-tag-changes
 269                     (list (cons query-string notmuch-message-replied-tags))))
 270       ;; Insert the message body - but put it in front of the signature
 271       ;; if one is present, and after any other content
 272       ;; message*setup-hooks may have added to the message body already.
 273       (save-restriction
 274         (message-goto-body)
 275         (narrow-to-region (point) (point-max))
 276         (goto-char (point-max))
 277         (if (re-search-backward message-signature-separator nil t)
 278             (when message-signature-insert-empty-line
 279               (forward-line -1))
 280           (goto-char (point-max))))
 281       (let ((from (plist-get original-headers :From))
 282             (date (plist-get original-headers :Date))
 283             (start (point)))
 284         ;; notmuch-mua-cite-function constructs a citation line based
 285         ;; on the From and Date headers of the original message, which
 286         ;; are assumed to be in the buffer.
 287         (insert "From: " from "\n")
 288         (insert "Date: " date "\n\n")
 289         (insert
 290          (with-temp-buffer
 291            (let
 292                ;; Don't attempt to clean up messages, excerpt
 293                ;; citations, etc. in the original message before
 294                ;; quoting.
 295                ((notmuch-show-insert-text/plain-hook nil)
 296                 ;; Don't omit long parts.
 297                 (notmuch-show-max-text-part-size 0)
 298                 ;; Insert headers for parts as appropriate for replying.
 299                 (notmuch-show-insert-header-p-function
 300                  notmuch-mua-reply-insert-header-p-function)
 301                 ;; Ensure that any encrypted parts are
 302                 ;; decrypted during the generation of the reply
 303                 ;; text.
 304                 (notmuch-show-process-crypto process-crypto)
 305                 ;; Don't indent multipart sub-parts.
 306                 (notmuch-show-indent-multipart nil))
 307              ;; We don't want sigstatus buttons (an information leak and usually wrong anyway).
 308              (cl-letf (((symbol-function 'notmuch-crypto-insert-sigstatus-button) #'ignore)
 309                        ((symbol-function 'notmuch-crypto-insert-encstatus-button) #'ignore))
 310                (notmuch-show-insert-body original (plist-get original :body) 0)
 311                (buffer-substring-no-properties (point-min) (point-max))))))
 312         (set-mark (point))
 313         (goto-char start)
 314         ;; Quote the original message according to the user's configured style.
 315         (funcall notmuch-mua-cite-function)))
 316     ;; Crypto processing based crypto content of the original message
 317     (when process-crypto
 318       (notmuch-mua-reply-crypto (plist-get original :body))))
 319   ;; Push mark right before signature, if any.
 320   (message-goto-signature)
 321   (unless (eobp)
 322     (end-of-line -1))
 323   (push-mark)
 324   (message-goto-body)
 325   (set-buffer-modified-p nil))
 326
 327 (defvar notmuch-message-mode-map
 328   (let ((map (make-sparse-keymap)))
 329     (define-key map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
 330     (define-key map (kbd "C-c C-s") #'notmuch-mua-send)
 331     (define-key map (kbd "C-c C-p") #'notmuch-draft-postpone)
 332     (define-key map (kbd "C-x C-s") #'notmuch-draft-save)
 333     map)
 334   "Keymap for `notmuch-message-mode'.")
 335
 336 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
 337   "Notmuch message composition mode. Mostly like `message-mode'."
 338   (notmuch-address-setup))
 339
 340 (put 'notmuch-message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 341
 342 (defun notmuch-mua-pop-to-buffer (name switch-function)
 343   "Pop to buffer NAME, and warn if it already exists and is
 344 modified. This function is notmuch adaptation of
 345 `message-pop-to-buffer'."
 346   (let ((buffer (get-buffer name)))
 347     (if (and buffer
 348              (buffer-name buffer))
 349         (let ((window (get-buffer-window buffer 0)))
 350           (if window
 351               ;; Raise the frame already displaying the message buffer.
 352               (progn
 353                 (select-frame-set-input-focus (window-frame window))
 354                 (select-window window))
 355             (funcall switch-function buffer)
 356             (set-buffer buffer))
 357           (when (and (buffer-modified-p)
 358                      (not (prog1
 359                               (y-or-n-p
 360                                "Message already being composed; erase? ")
 361                             (message nil))))
 362             (error "Message being composed")))
 363       (funcall switch-function name)
 364       (set-buffer name))
 365     (erase-buffer)
 366     (notmuch-message-mode)))
 367
 368 (defun notmuch-mua-mail (&optional to subject other-headers continue
 369                                    switch-function yank-action send-actions
 370                                    return-action &rest ignored)
 371   "Invoke the notmuch mail composition window."
 372   (interactive)
 373   (when notmuch-mua-user-agent-function
 374     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 375       (unless (string= "" user-agent)
 376         (push (cons 'User-Agent user-agent) other-headers))))
 377   (unless (assq 'From other-headers)
 378     (push (cons 'From (message-make-from
 379                        (notmuch-user-name)
 380                        (notmuch-user-primary-email)))
 381           other-headers))
 382   (notmuch-mua-pop-to-buffer (message-buffer-name "mail" to)
 383                              (or switch-function
 384                                  (notmuch-mua-get-switch-function)))
 385   (let ((headers
 386          (append
 387           ;; The following is copied from `message-mail'
 388           `((To . ,(or to "")) (Subject . ,(or subject "")))
 389           ;; C-h f compose-mail says that headers should be specified as
 390           ;; (string . value); however all the rest of message expects
 391           ;; headers to be symbols, not strings (eg message-header-format-alist).
 392           ;; https://lists.gnu.org/archive/html/emacs-devel/2011-01/msg00337.html
 393           ;; We need to convert any string input, eg from rmail-start-mail.
 394           (dolist (h other-headers other-headers)
 395             (when (stringp (car h))
 396               (setcar h (intern (capitalize (car h))))))))
 397         (args (list yank-action send-actions))
 398         ;; Cause `message-setup-1' to do things relevant for mail,
 399         ;; such as observe `message-default-mail-headers'.
 400         (message-this-is-mail t))
 401     ;; message-setup-1 in Emacs 23 does not accept return-action
 402     ;; argument. Pass it only if it is supplied by the caller. This
 403     ;; will never be the case when we're called by `compose-mail' in
 404     ;; Emacs 23.
 405     (when return-action (nconc args '(return-action)))
 406     (apply 'message-setup-1 headers args))
 407   (notmuch-fcc-header-setup)
 408   (message-sort-headers)
 409   (message-hide-headers)
 410   (set-buffer-modified-p nil)
 411   (notmuch-mua-maybe-set-window-dedicated)
 412   (message-goto-to))
 413
 414 (defcustom notmuch-identities nil
 415   "Identities that can be used as the From: address when composing a new message.
 416
 417 If this variable is left unset, then a list will be constructed from the
 418 name and addresses configured in the notmuch configuration file."
 419   :type '(repeat string)
 420   :group 'notmuch-send)
 421
 422 (defcustom notmuch-always-prompt-for-sender nil
 423   "Always prompt for the From: address when composing or forwarding a message.
 424
 425 This is not taken into account when replying to a message, because in that case
 426 the From: header is already filled in by notmuch."
 427   :type 'boolean
 428   :group 'notmuch-send)
 429
 430 (defvar notmuch-mua-sender-history nil)
 431
 432 (defun notmuch-mua-prompt-for-sender ()
 433   "Prompt for a sender from the user's configured identities."
 434   (if notmuch-identities
 435       (ido-completing-read "Send mail from: " notmuch-identities
 436                            nil nil nil 'notmuch-mua-sender-history
 437                            (car notmuch-identities))
 438     (let* ((name (notmuch-user-name))
 439            (addrs (cons (notmuch-user-primary-email)
 440                         (notmuch-user-other-email)))
 441            (address
 442             (ido-completing-read (concat "Sender address for " name ": ") addrs
 443                                  nil nil nil 'notmuch-mua-sender-history
 444                                  (car addrs))))
 445       (message-make-from name address))))
 446
 447 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 448 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 449   "Compose new mail.
 450
 451 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 452 the From: address first."
 453   (interactive "P")
 454   (let ((other-headers
 455          (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 456               (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 457     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 458
 459 (defun notmuch-mua-new-forward-messages (messages &optional prompt-for-sender)
 460   "Compose a new message forwarding MESSAGES.
 461
 462 If PROMPT-FOR-SENDER is non-nil, the user will be prompteed for
 463 the From: address."
 464   (let* ((other-headers
 465           (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 466                (list (cons 'From (notmuch-mua-prompt-for-sender)))))
 467          ;; Comes from the first message and is applied later.
 468          forward-subject
 469          ;; List of accumulated message-references of forwarded messages.
 470          forward-references
 471          ;; List of corresponding message-query.
 472          forward-queries)
 473     ;; Generate the template for the outgoing message.
 474     (notmuch-mua-mail nil "" other-headers nil (notmuch-mua-get-switch-function))
 475     (save-excursion
 476       ;; Insert all of the forwarded messages.
 477       (mapc (lambda (id)
 478               (let ((temp-buffer (get-buffer-create
 479                                   (concat "*notmuch-fwd-raw-" id "*"))))
 480                 ;; Get the raw version of this message in the buffer.
 481                 (with-current-buffer temp-buffer
 482                   (erase-buffer)
 483                   (let ((coding-system-for-read 'no-conversion))
 484                     (call-process notmuch-command nil t nil
 485                                   "show" "--format=raw" id))
 486                   ;; Because we process the messages in reverse order,
 487                   ;; always generate a forwarded subject, then use the
 488                   ;; last (i.e. first) one.
 489                   (setq forward-subject (message-make-forward-subject))
 490                   (push (message-fetch-field "Message-ID") forward-references)
 491                   (push id forward-queries))
 492                 ;; Make a copy ready to be forwarded in the
 493                 ;; composition buffer.
 494                 (message-forward-make-body temp-buffer)
 495                 ;; Kill the temporary buffer.
 496                 (kill-buffer temp-buffer)))
 497             ;; `message-forward-make-body' always puts the message at
 498             ;; the top, so do them in reverse order.
 499             (reverse messages))
 500       ;; Add in the appropriate subject.
 501       (save-restriction
 502         (message-narrow-to-headers)
 503         (message-remove-header "Subject")
 504         (message-add-header (concat "Subject: " forward-subject))
 505         (message-remove-header "References")
 506         (message-add-header (concat "References: "
 507                                     (mapconcat 'identity forward-references " "))))
 508       ;; Create a buffer-local queue for tag changes triggered when
 509       ;; sending the message.
 510       (when notmuch-message-forwarded-tags
 511         (setq-local notmuch-message-queued-tag-changes
 512                     (cl-loop for id in forward-queries
 513                              collect
 514                              (cons id notmuch-message-forwarded-tags))))
 515       ;; `message-forward-make-body' shows the User-agent header.  Hide
 516       ;; it again.
 517       (message-hide-headers)
 518       (set-buffer-modified-p nil))))
 519
 520 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 521   "Compose a reply to the message identified by QUERY-STRING.
 522
 523 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 524 the From: address first.  If REPLY-ALL is non-nil, the message
 525 will be addressed to all recipients of the source message."
 526   ;; In current emacs (24.3) select-active-regions is set to t by
 527   ;; default. The reply insertion code sets the region to the quoted
 528   ;; message to make it easy to delete (kill-region or C-w). These two
 529   ;; things combine to put the quoted message in the primary selection.
 530   ;;
 531   ;; This is not what the user wanted and is a privacy risk (accidental
 532   ;; pasting of the quoted message). We can avoid some of the problems
 533   ;; by let-binding select-active-regions to nil. This fixes if the
 534   ;; primary selection was previously in a non-emacs window but not if
 535   ;; it was in an emacs window. To avoid the problem in the latter case
 536   ;; we deactivate mark.
 537   (let ((sender (and prompt-for-sender
 538                      (notmuch-mua-prompt-for-sender)))
 539         (select-active-regions nil))
 540     (notmuch-mua-reply query-string sender reply-all)
 541     (deactivate-mark)))
 542
 543 (defun notmuch-mua-check-no-misplaced-secure-tag ()
 544   "Query user if there is a misplaced secure mml tag.
 545
 546 Emacs message-send will (probably) ignore a secure mml tag unless
 547 it is at the start of the body. Returns t if there is no such
 548 tag, or the user confirms they mean it."
 549   (save-excursion
 550     (let ((body-start (progn (message-goto-body) (point))))
 551       (goto-char (point-max))
 552       (or
 553        ;; We are always fine if there is no secure tag.
 554        (not (search-backward "<#secure" nil 't))
 555        ;; There is a secure tag, so it must be at the start of the
 556        ;; body, with no secure tag earlier (i.e., in the headers).
 557        (and (= (point) body-start)
 558             (not (search-backward "<#secure" nil 't)))
 559        ;; The user confirms they means it.
 560        (yes-or-no-p "\
 561 There is a <#secure> tag not at the start of the body. It is
 562 likely that the message will be sent unsigned and unencrypted.
 563 Really send? ")))))
 564
 565 (defun notmuch-mua-check-secure-tag-has-newline ()
 566   "Query if the secure mml tag has a newline following it.
 567
 568 Emacs message-send will (probably) ignore a correctly placed
 569 secure mml tag unless it is followed by a newline. Returns t if
 570 any secure tag is followed by a newline, or the user confirms
 571 they mean it."
 572   (save-excursion
 573     (message-goto-body)
 574     (or
 575      ;; There is no (correctly placed) secure tag.
 576      (not (looking-at "<#secure"))
 577      ;; The secure tag is followed by a newline.
 578      (looking-at "<#secure[^\n>]*>\n")
 579      ;; The user confirms they means it.
 580      (yes-or-no-p "\
 581 The <#secure> tag at the start of the body is not followed by a
 582 newline. It is likely that the message will be sent unsigned and
 583 unencrypted.  Really send? "))))
 584
 585 (defun notmuch-mua-send-common (arg &optional exit)
 586   (interactive "P")
 587   (run-hooks 'notmuch-mua-send-hook)
 588   (when (and (notmuch-mua-check-no-misplaced-secure-tag)
 589              (notmuch-mua-check-secure-tag-has-newline))
 590     (cl-letf (((symbol-function 'message-do-fcc)
 591                #'notmuch-maildir-message-do-fcc))
 592       (if exit
 593           (message-send-and-exit arg)
 594         (message-send arg)))))
 595
 596 (defun notmuch-mua-send-and-exit (&optional arg)
 597   (interactive "P")
 598   (notmuch-mua-send-common arg 't))
 599
 600 (defun notmuch-mua-send (&optional arg)
 601   (interactive "P")
 602   (notmuch-mua-send-common arg))
 603
 604 (defun notmuch-mua-kill-buffer ()
 605   (interactive)
 606   (message-kill-buffer))
 607
 608 ;;
 609
 610 (define-mail-user-agent 'notmuch-user-agent
 611   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 612   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 613
 614 ;; Add some more headers to the list that `message-mode' hides when
 615 ;; composing a message.
 616 (notmuch-mua-add-more-hidden-headers)
 617
 618 ;;
 619
 620 (provide 'notmuch-mua)
 621
 622 ;;; notmuch-mua.el ends here