git.notmuchmail.org Git - notmuch/blob - contrib/notmuch-pick/notmuch-pick.el

   1 ;; notmuch-pick.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 (require 'mail-parse)
  26
  27 (require 'notmuch-lib)
  28 (require 'notmuch-query)
  29 (require 'notmuch-show)
  30 (require 'notmuch) ;; XXX ATM, as notmuch-search-mode-map is defined here
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  35 (declare-function notmuch-show "notmuch-show" (&rest args))
  36 (declare-function notmuch-tag "notmuch" (query &rest tags))
  37 (declare-function notmuch-show-strip-re "notmuch-show" (subject))
  38 (declare-function notmuch-show-spaces-n "notmuch-show" (n))
  39 (declare-function notmuch-read-query "notmuch" (prompt))
  40 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
  41 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
  42 (declare-function notmuch-hello-trim "notmuch-hello" (search))
  43 (declare-function notmuch-search-find-thread-id "notmuch" ())
  44 (declare-function notmuch-search-find-subject "notmuch" ())
  45
  46 ;; the following variable is defined in notmuch.el
  47 (defvar notmuch-search-query-string)
  48
  49 (defgroup notmuch-pick nil
  50   "Showing message and thread structure."
  51   :group 'notmuch)
  52
  53 ;; This is ugly. We can't run setup-show-out until it has been defined
  54 ;; which needs the keymap to be defined. So we defer setting up to
  55 ;; notmuch-pick-init.
  56 (defcustom notmuch-pick-show-out nil
  57   "View selected messages in new window rather than split-pane."
  58   :type 'boolean
  59   :group 'notmuch-pick
  60   :set (lambda (symbol value)
  61          (set-default symbol value)
  62          (when (fboundp 'notmuch-pick-setup-show-out)
  63            (notmuch-pick-setup-show-out))))
  64
  65 (defcustom notmuch-pick-result-format
  66   `(("date" . "%12s  ")
  67     ("authors" . "%-20s")
  68     ("subject" . " %-54s ")
  69     ("tags" . "(%s)"))
  70   "Result formatting for Pick. Supported fields are: date,
  71         authors, subject, tags Note: subject includes the tree
  72         structure graphics, and the author string should not
  73         contain whitespace (put it in the neighbouring fields
  74         instead).  For example:
  75         (setq notmuch-pick-result-format \(\(\"authors\" . \"%-40s\"\)
  76                                              \(\"subject\" . \"%s\"\)\)\)"
  77   :type '(alist :key-type (string) :value-type (string))
  78   :group 'notmuch-pick)
  79
  80 (defcustom notmuch-pick-asynchronous-parser t
  81   "Use the asynchronous parser."
  82   :type 'boolean
  83   :group 'notmuch-pick)
  84
  85 ;; Faces for messages that match the query.
  86 (defface notmuch-pick-match-date-face
  87   '((t :inherit default))
  88   "Face used in pick mode for the date in messages matching the query."
  89   :group 'notmuch-pick
  90   :group 'notmuch-faces)
  91
  92 (defface notmuch-pick-match-author-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "OliveDrab1"))
  96     (((class color)
  97       (background light))
  98      (:foreground "dark blue"))
  99     (t
 100      (:bold t)))
 101   "Face used in pick mode for the date in messages matching the query."
 102   :group 'notmuch-pick
 103   :group 'notmuch-faces)
 104
 105 (defface notmuch-pick-match-subject-face
 106   '((t :inherit default))
 107   "Face used in pick mode for the subject in messages matching the query."
 108   :group 'notmuch-pick
 109   :group 'notmuch-faces)
 110
 111 (defface notmuch-pick-match-tag-face
 112   '((((class color)
 113       (background dark))
 114      (:foreground "OliveDrab1"))
 115     (((class color)
 116       (background light))
 117      (:foreground "navy blue" :bold t))
 118     (t
 119      (:bold t)))
 120   "Face used in pick mode for tags in messages matching the query."
 121   :group 'notmuch-pick
 122   :group 'notmuch-faces)
 123
 124 ;; Faces for messages that do not match the query.
 125 (defface notmuch-pick-no-match-date-face
 126   '((t (:foreground "gray")))
 127   "Face used in pick mode for non-matching dates."
 128   :group 'notmuch-pick
 129   :group 'notmuch-faces)
 130
 131 (defface notmuch-pick-no-match-subject-face
 132   '((t (:foreground "gray")))
 133   "Face used in pick mode for non-matching subjects."
 134   :group 'notmuch-pick
 135   :group 'notmuch-faces)
 136
 137 (defface notmuch-pick-no-match-author-face
 138   '((t (:foreground "gray")))
 139   "Face used in pick mode for the date in messages matching the query."
 140   :group 'notmuch-pick
 141   :group 'notmuch-faces)
 142
 143 (defface notmuch-pick-no-match-tag-face
 144   '((t (:foreground "gray")))
 145   "Face used in pick mode face for non-matching tags."
 146   :group 'notmuch-pick
 147   :group 'notmuch-faces)
 148
 149 (defvar notmuch-pick-previous-subject "")
 150 (make-variable-buffer-local 'notmuch-pick-previous-subject)
 151
 152 ;; The basic query i.e. the key part of the search request.
 153 (defvar notmuch-pick-basic-query nil)
 154 (make-variable-buffer-local 'notmuch-pick-basic-query)
 155 ;; The context of the search: i.e., useful but can be dropped.
 156 (defvar notmuch-pick-query-context nil)
 157 (make-variable-buffer-local 'notmuch-pick-query-context)
 158 (defvar notmuch-pick-buffer-name nil)
 159 (make-variable-buffer-local 'notmuch-pick-buffer-name)
 160 (defvar notmuch-pick-message-window nil)
 161 (make-variable-buffer-local 'notmuch-pick-message-window)
 162 (put 'notmuch-pick-message-window 'permanent-local t)
 163 (defvar notmuch-pick-message-buffer nil)
 164 (make-variable-buffer-local 'notmuch-pick-message-buffer-name)
 165 (put 'notmuch-pick-message-buffer-name 'permanent-local t)
 166 (defvar notmuch-pick-process-state nil
 167   "Parsing state of the search process filter.")
 168
 169
 170 (defvar notmuch-pick-mode-map
 171   (let ((map (make-sparse-keymap)))
 172     (define-key map [mouse-1] 'notmuch-pick-show-message)
 173     (define-key map "q" 'notmuch-pick-quit)
 174     (define-key map "x" 'notmuch-pick-quit)
 175     (define-key map "?" 'notmuch-help)
 176     (define-key map "a" 'notmuch-pick-archive-message-then-next)
 177     (define-key map "=" 'notmuch-pick-refresh-view)
 178     (define-key map "s" 'notmuch-search)
 179     (define-key map "z" 'notmuch-pick)
 180     (define-key map "m" 'notmuch-pick-new-mail)
 181     (define-key map "f" 'notmuch-pick-forward-message)
 182     (define-key map "r" 'notmuch-pick-reply-sender)
 183     (define-key map "R" 'notmuch-pick-reply)
 184     (define-key map "n" 'notmuch-pick-next-matching-message)
 185     (define-key map "p" 'notmuch-pick-prev-matching-message)
 186     (define-key map "N" 'notmuch-pick-next-message)
 187     (define-key map "P" 'notmuch-pick-prev-message)
 188     (define-key map "|" 'notmuch-pick-pipe-message)
 189     (define-key map "-" 'notmuch-pick-remove-tag)
 190     (define-key map "+" 'notmuch-pick-add-tag)
 191     (define-key map " " 'notmuch-pick-scroll-or-next)
 192     (define-key map "b" 'notmuch-pick-scroll-message-window-back)
 193     map))
 194 (fset 'notmuch-pick-mode-map notmuch-pick-mode-map)
 195
 196 (defun notmuch-pick-setup-show-out ()
 197   (let ((map notmuch-pick-mode-map))
 198     (if notmuch-pick-show-out
 199         (progn
 200           (define-key map (kbd "M-RET") 'notmuch-pick-show-message)
 201           (define-key map (kbd "RET") 'notmuch-pick-show-message-out))
 202       (progn
 203         (define-key map (kbd "RET") 'notmuch-pick-show-message)
 204         (define-key map (kbd "M-RET") 'notmuch-pick-show-message-out)))))
 205
 206 (defun notmuch-pick-get-message-properties ()
 207   "Return the properties of the current message as a plist.
 208
 209 Some useful entries are:
 210 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 211 :tags - Tags for this message"
 212   (save-excursion
 213     (beginning-of-line)
 214     (get-text-property (point) :notmuch-message-properties)))
 215
 216 (defun notmuch-pick-set-message-properties (props)
 217   (save-excursion
 218     (beginning-of-line)
 219     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 220
 221 (defun notmuch-pick-set-prop (prop val &optional props)
 222   (let ((inhibit-read-only t)
 223         (props (or props
 224                    (notmuch-pick-get-message-properties))))
 225     (plist-put props prop val)
 226     (notmuch-pick-set-message-properties props)))
 227
 228 (defun notmuch-pick-get-prop (prop &optional props)
 229   (let ((props (or props
 230                    (notmuch-pick-get-message-properties))))
 231     (plist-get props prop)))
 232
 233 (defun notmuch-pick-set-tags (tags)
 234   "Set the tags of the current message."
 235   (notmuch-pick-set-prop :tags tags))
 236
 237 (defun notmuch-pick-get-tags ()
 238   "Return the tags of the current message."
 239   (notmuch-pick-get-prop :tags))
 240
 241 (defun notmuch-pick-get-message-id ()
 242   "Return the message id of the current message."
 243   (let ((id (notmuch-pick-get-prop :id)))
 244     (if id
 245         (notmuch-id-to-query id)
 246       nil)))
 247
 248 (defun notmuch-pick-get-match ()
 249   "Return whether the current message is a match."
 250   (interactive)
 251   (notmuch-pick-get-prop :match))
 252
 253 (defun notmuch-pick-refresh-result ()
 254   (let ((init-point (point))
 255         (end (line-end-position))
 256         (msg (notmuch-pick-get-message-properties))
 257         (inhibit-read-only t))
 258     (beginning-of-line)
 259     (delete-region (point) (1+ (line-end-position)))
 260     (notmuch-pick-insert-msg msg)
 261     (let ((new-end (line-end-position)))
 262       (goto-char (if (= init-point end)
 263                      new-end
 264                    (min init-point (- new-end 1)))))))
 265
 266 (defun notmuch-pick-tag-update-display (&optional tag-changes)
 267   "Update display for TAG-CHANGES to current message.
 268
 269 Does NOT change the database."
 270   (let* ((current-tags (notmuch-pick-get-tags))
 271          (new-tags (notmuch-update-tags current-tags tag-changes)))
 272     (unless (equal current-tags new-tags)
 273       (notmuch-pick-set-tags new-tags)
 274       (notmuch-pick-refresh-result))))
 275
 276 (defun notmuch-pick-tag (&optional tag-changes)
 277   "Change tags for the current message"
 278   (interactive)
 279   (setq tag-changes (funcall 'notmuch-tag (notmuch-pick-get-message-id) tag-changes))
 280   (notmuch-pick-tag-update-display tag-changes))
 281
 282 (defun notmuch-pick-add-tag ()
 283   "Same as `notmuch-pick-tag' but sets initial input to '+'."
 284   (interactive)
 285   (notmuch-pick-tag "+"))
 286
 287 (defun notmuch-pick-remove-tag ()
 288   "Same as `notmuch-pick-tag' but sets initial input to '-'."
 289   (interactive)
 290   (notmuch-pick-tag "-"))
 291
 292 ;; This function should be in notmuch-hello.el but we are trying to
 293 ;; minimise impact on the rest of the codebase.
 294 (defun notmuch-pick-from-hello (&optional search)
 295   "Run a query and display results in experimental notmuch-pick mode"
 296   (interactive)
 297   (unless (null search)
 298     (setq search (notmuch-hello-trim search))
 299     (let ((history-delete-duplicates t))
 300       (add-to-history 'notmuch-search-history search)))
 301   (notmuch-pick search))
 302
 303 ;; This function should be in notmuch-show.el but be we trying to
 304 ;; minimise impact on the rest of the codebase.
 305 (defun notmuch-pick-from-show-current-query ()
 306   "Call notmuch pick with the current query"
 307   (interactive)
 308   (notmuch-pick notmuch-show-thread-id notmuch-show-query-context))
 309
 310 ;; This function should be in notmuch.el but be we trying to minimise
 311 ;; impact on the rest of the codebase.
 312 (defun notmuch-pick-from-search-current-query ()
 313   "Call notmuch pick with the current query"
 314   (interactive)
 315   (notmuch-pick notmuch-search-query-string))
 316
 317 ;; This function should be in notmuch.el but be we trying to minimise
 318 ;; impact on the rest of the codebase.
 319 (defun notmuch-pick-from-search-thread ()
 320   "Show the selected thread with notmuch-pick"
 321   (interactive)
 322   (notmuch-pick (notmuch-search-find-thread-id)
 323                 notmuch-search-query-string
 324                 (notmuch-prettify-subject (notmuch-search-find-subject)))
 325   (notmuch-pick-show-match-message-with-wait))
 326
 327 (defun notmuch-pick-show-message ()
 328   "Show the current message (in split-pane)."
 329   (interactive)
 330   (let ((id (notmuch-pick-get-message-id))
 331         (inhibit-read-only t)
 332         buffer)
 333     (when id
 334       ;; We close and reopen the window to kill off un-needed buffers
 335       ;; this might cause flickering but seems ok.
 336       (notmuch-pick-close-message-window)
 337       (setq notmuch-pick-message-window
 338             (split-window-vertically (/ (window-height) 4)))
 339       (with-selected-window notmuch-pick-message-window
 340         ;; Since we are only displaying one message do not indent.
 341         (let ((notmuch-show-indent-messages-width 0))
 342           (setq current-prefix-arg '(4))
 343           (setq buffer (notmuch-show id nil nil nil))))
 344       (notmuch-pick-tag-update-display (list "-unread"))
 345       (setq notmuch-pick-message-buffer buffer))))
 346
 347 (defun notmuch-pick-show-message-out ()
 348   "Show the current message (in whole window)."
 349   (interactive)
 350   (let ((id (notmuch-pick-get-message-id))
 351         (inhibit-read-only t)
 352         buffer)
 353     (when id
 354       ;; We close the window to kill off un-needed buffers.
 355       (notmuch-pick-close-message-window)
 356       (notmuch-show id nil nil nil))))
 357
 358 (defun notmuch-pick-scroll-message-window ()
 359   "Scroll the message window (if it exists)"
 360   (interactive)
 361   (when (window-live-p notmuch-pick-message-window)
 362     (with-selected-window notmuch-pick-message-window
 363       (if (pos-visible-in-window-p (point-max))
 364           t
 365         (scroll-up)))))
 366
 367 (defun notmuch-pick-scroll-message-window-back ()
 368   "Scroll the message window back(if it exists)"
 369   (interactive)
 370   (when (window-live-p notmuch-pick-message-window)
 371     (with-selected-window notmuch-pick-message-window
 372       (if (pos-visible-in-window-p (point-min))
 373           t
 374         (scroll-down)))))
 375
 376 (defun notmuch-pick-scroll-or-next ()
 377   "Scroll the message window. If it at end go to next message."
 378   (interactive)
 379   (when (notmuch-pick-scroll-message-window)
 380     (notmuch-pick-next-matching-message)))
 381
 382 (defun notmuch-pick-quit ()
 383   "Close the split view or exit pick."
 384   (interactive)
 385   (unless (notmuch-pick-close-message-window)
 386     (kill-buffer (current-buffer))))
 387
 388 (defun notmuch-pick-close-message-window ()
 389   "Close the message-window. Return t if close succeeds."
 390   (interactive)
 391   (when (and (window-live-p notmuch-pick-message-window)
 392              (eq (window-buffer notmuch-pick-message-window) notmuch-pick-message-buffer))
 393     (delete-window notmuch-pick-message-window)
 394     (unless (get-buffer-window-list notmuch-pick-message-buffer)
 395       (kill-buffer notmuch-pick-message-buffer))
 396     t))
 397
 398 (defun notmuch-pick-archive-message (&optional unarchive)
 399   "Archive the current message.
 400
 401 Archive the current message by applying the tag changes in
 402 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
 403 default). If a prefix argument is given, the message will be
 404 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
 405 will be reversed."
 406   (interactive "P")
 407   (when notmuch-archive-tags
 408     (apply 'notmuch-pick-tag
 409            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 410
 411 (defun notmuch-pick-archive-message-then-next (&optional unarchive)
 412   "Archive the current message and move to next matching message."
 413   (interactive "P")
 414   (notmuch-pick-archive-message unarchive)
 415   (notmuch-pick-next-matching-message))
 416
 417 (defun notmuch-pick-next-message ()
 418   "Move to next message."
 419   (interactive)
 420   (forward-line)
 421   (when (window-live-p notmuch-pick-message-window)
 422     (notmuch-pick-show-message)))
 423
 424 (defun notmuch-pick-prev-message ()
 425   "Move to previous message."
 426   (interactive)
 427   (forward-line -1)
 428   (when (window-live-p notmuch-pick-message-window)
 429     (notmuch-pick-show-message)))
 430
 431 (defun notmuch-pick-prev-matching-message ()
 432   "Move to previous matching message."
 433   (interactive)
 434   (forward-line -1)
 435   (while (and (not (bobp)) (not (notmuch-pick-get-match)))
 436     (forward-line -1))
 437   (when (window-live-p notmuch-pick-message-window)
 438     (notmuch-pick-show-message)))
 439
 440 (defun notmuch-pick-next-matching-message ()
 441   "Move to next matching message."
 442   (interactive)
 443   (forward-line)
 444   (while (and (not (eobp)) (not (notmuch-pick-get-match)))
 445     (forward-line))
 446   (when (window-live-p notmuch-pick-message-window)
 447     (notmuch-pick-show-message)))
 448
 449 (defun notmuch-pick-show-match-message-with-wait ()
 450   "Show the first matching message but wait for it to appear or search to finish."
 451   (interactive)
 452   (unless (notmuch-pick-get-match)
 453     (notmuch-pick-next-matching-message))
 454   (while (and (not (notmuch-pick-get-match))
 455               (get-buffer-process (current-buffer)))
 456     (message "waiting for message")
 457     (sit-for 0.1)
 458     (goto-char (point-min))
 459     (unless (notmuch-pick-get-match)
 460       (notmuch-pick-next-matching-message)))
 461   (message nil)
 462   (when (notmuch-pick-get-match)
 463     (notmuch-pick-show-message)))
 464
 465 (defun notmuch-pick-refresh-view ()
 466   "Refresh view."
 467   (interactive)
 468   (let ((inhibit-read-only t)
 469         (basic-query notmuch-pick-basic-query)
 470         (query-context notmuch-pick-query-context)
 471         (buffer-name notmuch-pick-buffer-name))
 472     (erase-buffer)
 473     (notmuch-pick-worker basic-query query-context (get-buffer buffer-name))))
 474
 475 (defmacro with-current-notmuch-pick-message (&rest body)
 476   "Evaluate body with current buffer set to the text of current message"
 477   `(save-excursion
 478      (let ((id (notmuch-pick-get-message-id)))
 479        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 480          (with-current-buffer buf
 481             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 482            ,@body)
 483          (kill-buffer buf)))))
 484
 485 (defun notmuch-pick-new-mail (&optional prompt-for-sender)
 486   "Compose new mail."
 487   (interactive "P")
 488   (notmuch-pick-close-message-window)
 489   (notmuch-mua-new-mail prompt-for-sender ))
 490
 491 (defun notmuch-pick-forward-message (&optional prompt-for-sender)
 492   "Forward the current message."
 493   (interactive "P")
 494   (notmuch-pick-close-message-window)
 495   (with-current-notmuch-pick-message
 496    (notmuch-mua-new-forward-message prompt-for-sender)))
 497
 498 (defun notmuch-pick-reply (&optional prompt-for-sender)
 499   "Reply to the sender and all recipients of the current message."
 500   (interactive "P")
 501   (notmuch-pick-close-message-window)
 502   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender t))
 503
 504 (defun notmuch-pick-reply-sender (&optional prompt-for-sender)
 505   "Reply to the sender of the current message."
 506   (interactive "P")
 507   (notmuch-pick-close-message-window)
 508   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender nil))
 509
 510 ;; Shamelessly stolen from notmuch-show.el: maybe should be unified.
 511 (defun notmuch-pick-pipe-message (command)
 512   "Pipe the contents of the current message to the given command.
 513
 514 The given command will be executed with the raw contents of the
 515 current email message as stdin. Anything printed by the command
 516 to stdout or stderr will appear in the *notmuch-pipe* buffer.
 517
 518 When invoked with a prefix argument, the command will receive all
 519 open messages in the current thread (formatted as an mbox) rather
 520 than only the current message."
 521   (interactive "sPipe message to command: ")
 522   (let ((shell-command
 523          (concat notmuch-command " show --format=raw "
 524                  (shell-quote-argument (notmuch-pick-get-message-id)) " | " command))
 525          (buf (get-buffer-create (concat "*notmuch-pipe*"))))
 526     (with-current-buffer buf
 527       (setq buffer-read-only nil)
 528       (erase-buffer)
 529       (let ((exit-code (call-process-shell-command shell-command nil buf)))
 530         (goto-char (point-max))
 531         (set-buffer-modified-p nil)
 532         (setq buffer-read-only t)
 533         (unless (zerop exit-code)
 534           (switch-to-buffer-other-window buf)
 535           (message (format "Command '%s' exited abnormally with code %d"
 536                            shell-command exit-code)))))))
 537
 538 (defun notmuch-pick-clean-address (address)
 539   "Try to clean a single email ADDRESS for display. Return
 540 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 541 unchanged ADDRESS if parsing fails."
 542   (let* ((clean-address (notmuch-clean-address address))
 543          (p-address (car clean-address))
 544          (p-name (cdr clean-address)))
 545
 546     ;; If we have a name return that otherwise return the address.
 547     (or p-name p-address)))
 548
 549 (defun notmuch-pick-insert-field (field format-string msg)
 550   (let* ((headers (plist-get msg :headers))
 551         (match (plist-get msg :match)))
 552     (cond
 553      ((string-equal field "date")
 554       (let ((face (if match
 555                       'notmuch-pick-match-date-face
 556                     'notmuch-pick-no-match-date-face)))
 557         (insert (propertize (format format-string (plist-get msg :date_relative))
 558                             'face face))))
 559
 560      ((string-equal field "subject")
 561       (let ((tree-status (plist-get msg :tree-status))
 562             (bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 563             (face (if match
 564                       'notmuch-pick-match-subject-face
 565                     'notmuch-pick-no-match-subject-face)))
 566         (insert (propertize (format format-string
 567                                     (concat
 568                                      (mapconcat #'identity (reverse tree-status) "")
 569                                      (if (string= notmuch-pick-previous-subject bare-subject)
 570                                          " ..."
 571                                        bare-subject)))
 572                             'face face))
 573         (setq notmuch-pick-previous-subject bare-subject)))
 574
 575      ((string-equal field "authors")
 576       (let ((author (notmuch-pick-clean-address (plist-get headers :From)))
 577             (len (length (format format-string "")))
 578             (face (if match
 579                       'notmuch-pick-match-author-face
 580                     'notmuch-pick-no-match-author-face)))
 581         (when (> (length author) len)
 582           (setq author (substring author 0 len)))
 583         (insert (propertize (format format-string author)
 584                             'face face))))
 585
 586      ((string-equal field "tags")
 587       (let ((tags (plist-get msg :tags))
 588             (face (if match
 589                           'notmuch-pick-match-tag-face
 590                         'notmuch-pick-no-match-tag-face)))
 591         (when tags
 592           (insert (propertize (format format-string
 593                                       (mapconcat #'identity tags ", "))
 594                               'face face))))))))
 595
 596 (defun notmuch-pick-insert-msg (msg)
 597   "Insert the message MSG according to notmuch-pick-result-format"
 598   (dolist (spec notmuch-pick-result-format)
 599     (notmuch-pick-insert-field (car spec) (cdr spec) msg))
 600   (notmuch-pick-set-message-properties msg)
 601   (insert "\n"))
 602
 603 (defun notmuch-pick-insert-tree (tree depth tree-status first last)
 604   "Insert the message tree TREE at depth DEPTH in the current thread."
 605   (let ((msg (car tree))
 606         (replies (cadr tree)))
 607
 608       (cond
 609        ((and (< 0 depth) (not last))
 610         (push "├" tree-status))
 611        ((and (< 0 depth) last)
 612         (push "╰" tree-status))
 613        ((and (eq 0 depth) first last)
 614 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
 615         (push " " tree-status))
 616        ((and (eq 0 depth) first (not last))
 617           (push "┬" tree-status))
 618        ((and (eq 0 depth) (not first) last)
 619         (push "╰" tree-status))
 620        ((and (eq 0 depth) (not first) (not last))
 621         (push "├" tree-status)))
 622
 623       (push (concat (if replies "┬" "─") "►") tree-status)
 624       (notmuch-pick-insert-msg (plist-put msg :tree-status tree-status))
 625       (pop tree-status)
 626       (pop tree-status)
 627
 628       (if last
 629           (push " " tree-status)
 630         (push "│" tree-status))
 631
 632     (notmuch-pick-insert-thread replies (1+ depth) tree-status)))
 633
 634 (defun notmuch-pick-insert-thread (thread depth tree-status)
 635   "Insert the thread THREAD at depth DEPTH >= 1 in the current forest."
 636   (let ((n (length thread)))
 637     (loop for tree in thread
 638           for count from 1 to n
 639
 640           do (notmuch-pick-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
 641
 642 (defun notmuch-pick-insert-forest-thread (forest-thread)
 643   (save-excursion
 644     (goto-char (point-max))
 645     (let (tree-status)
 646       ;; Reset at the start of each main thread.
 647       (setq notmuch-pick-previous-subject nil)
 648       (notmuch-pick-insert-thread forest-thread 0 tree-status))))
 649
 650 (defun notmuch-pick-insert-forest (forest)
 651   (mapc 'notmuch-pick-insert-forest-thread forest))
 652
 653 (defun notmuch-pick-mode ()
 654   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
 655
 656 This buffer contains the results of a \"notmuch pick\" of your
 657 email archives. Each line in the buffer represents a single
 658 message giving the relative date, the author, subject, and any
 659 tags.
 660
 661 Pressing \\[notmuch-pick-show-message] on any line displays that message.
 662
 663 Complete list of currently available key bindings:
 664
 665 \\{notmuch-pick-mode-map}"
 666
 667   (interactive)
 668   (kill-all-local-variables)
 669   (use-local-map notmuch-pick-mode-map)
 670   (setq major-mode 'notmuch-pick-mode
 671         mode-name "notmuch-pick")
 672   (hl-line-mode 1)
 673   (setq buffer-read-only t
 674         truncate-lines t))
 675
 676 (defun notmuch-pick-process-sentinel (proc msg)
 677   "Add a message to let user know when \"notmuch pick\" exits"
 678   (let ((buffer (process-buffer proc))
 679         (status (process-status proc))
 680         (exit-status (process-exit-status proc))
 681         (never-found-target-thread nil))
 682     (when (memq status '(exit signal))
 683         (kill-buffer (process-get proc 'parse-buf))
 684         (if (buffer-live-p buffer)
 685             (with-current-buffer buffer
 686               (save-excursion
 687                 (let ((inhibit-read-only t)
 688                       (atbob (bobp)))
 689                   (goto-char (point-max))
 690                   (if (eq status 'signal)
 691                       (insert "Incomplete search results (pick process was killed).\n"))
 692                   (when (eq status 'exit)
 693                     (insert "End of search results.")
 694                     (unless (= exit-status 0)
 695                       (insert (format " (process returned %d)" exit-status)))
 696                     (insert "\n")))))))))
 697
 698
 699 (defun notmuch-pick-show-error (string &rest objects)
 700   (save-excursion
 701     (goto-char (point-max))
 702     (insert "Error: Unexpected output from notmuch search:\n")
 703     (insert (apply #'format string objects))
 704     (insert "\n")))
 705
 706
 707 (defun notmuch-pick-process-filter (proc string)
 708   "Process and filter the output of \"notmuch show\" (for pick)"
 709   (let ((results-buf (process-buffer proc))
 710         (parse-buf (process-get proc 'parse-buf))
 711         (inhibit-read-only t)
 712         done)
 713     (if (not (buffer-live-p results-buf))
 714         (delete-process proc)
 715       (with-current-buffer parse-buf
 716         ;; Insert new data
 717         (save-excursion
 718           (goto-char (point-max))
 719           (insert string))
 720         (notmuch-json-parse-partial-list 'notmuch-pick-insert-forest-thread
 721                                          'notmuch-pick-show-error
 722                                          results-buf)))))
 723
 724 (defun notmuch-pick-worker (basic-query &optional query-context buffer)
 725   (interactive)
 726   (notmuch-pick-mode)
 727   (setq notmuch-pick-basic-query basic-query)
 728   (setq notmuch-pick-query-context query-context)
 729   (setq notmuch-pick-buffer-name (buffer-name buffer))
 730
 731   (erase-buffer)
 732   (goto-char (point-min))
 733   (let* ((search-args (concat basic-query
 734                        (if query-context (concat " and (" query-context ")"))
 735                        ))
 736          (message-arg "--entire-thread"))
 737     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
 738         (setq search-args basic-query))
 739     (if notmuch-pick-asynchronous-parser
 740         (let ((proc (start-process
 741                      "notmuch-pick" buffer
 742                      notmuch-command "show" "--body=false" "--format=json"
 743                      message-arg search-args))
 744               ;; Use a scratch buffer to accumulate partial output.
 745               ;; This buffer will be killed by the sentinel, which
 746               ;; should be called no matter how the process dies.
 747               (parse-buf (generate-new-buffer " *notmuch pick parse*")))
 748           (process-put proc 'parse-buf parse-buf)
 749           (set-process-sentinel proc 'notmuch-pick-process-sentinel)
 750           (set-process-filter proc 'notmuch-pick-process-filter)
 751           (set-process-query-on-exit-flag proc nil))
 752       (progn
 753         (notmuch-pick-insert-forest
 754          (notmuch-query-get-threads
 755           (list "--body=false" message-arg search-args)))
 756         (save-excursion
 757           (goto-char (point-max))
 758           (insert "End of search results.\n"))))))
 759
 760
 761 (defun notmuch-pick (&optional query query-context buffer-name show-first-match)
 762   "Run notmuch pick with the given `query' and display the results"
 763   (interactive "sNotmuch pick: ")
 764   (if (null query)
 765       (setq query (notmuch-read-query "Notmuch pick: ")))
 766   (let ((buffer (get-buffer-create (generate-new-buffer-name
 767                                     (or buffer-name
 768                                         (concat "*notmuch-pick-" query "*")))))
 769         (inhibit-read-only t))
 770
 771     (switch-to-buffer buffer)
 772     ;; Don't track undo information for this buffer
 773     (set 'buffer-undo-list t)
 774
 775     (notmuch-pick-worker query query-context buffer)
 776
 777     (setq truncate-lines t)
 778     (when show-first-match
 779       (notmuch-pick-show-match-message-with-wait))))
 780
 781
 782 ;; Set up key bindings from the rest of notmuch.
 783 (define-key 'notmuch-search-mode-map "z" 'notmuch-pick)
 784 (define-key 'notmuch-search-mode-map "Z" 'notmuch-pick-from-search-current-query)
 785 (define-key 'notmuch-search-mode-map (kbd "M-RET") 'notmuch-pick-from-search-thread)
 786 (define-key 'notmuch-hello-mode-map "z" 'notmuch-pick-from-hello)
 787 (define-key 'notmuch-show-mode-map "z" 'notmuch-pick)
 788 (define-key 'notmuch-show-mode-map "Z" 'notmuch-pick-from-show-current-query)
 789 (notmuch-pick-setup-show-out)
 790 (message "Initialised notmuch-pick")
 791
 792 (provide 'notmuch-pick)