git.notmuchmail.org Git - notmuch/blob - contrib/notmuch-pick/notmuch-pick.el

   1 ;; notmuch-pick.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 (require 'mail-parse)
  26
  27 (require 'notmuch-lib)
  28 (require 'notmuch-query)
  29 (require 'notmuch-show)
  30 (require 'notmuch) ;; XXX ATM, as notmuch-search-mode-map is defined here
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  35 (declare-function notmuch-show "notmuch-show" (&rest args))
  36 (declare-function notmuch-tag "notmuch" (query &rest tags))
  37 (declare-function notmuch-show-strip-re "notmuch-show" (subject))
  38 (declare-function notmuch-show-spaces-n "notmuch-show" (n))
  39 (declare-function notmuch-read-query "notmuch" (prompt))
  40 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
  41 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
  42 (declare-function notmuch-hello-trim "notmuch-hello" (search))
  43 (declare-function notmuch-search-find-thread-id "notmuch" ())
  44 (declare-function notmuch-search-find-subject "notmuch" ())
  45
  46 ;; the following variable is defined in notmuch.el
  47 (defvar notmuch-search-query-string)
  48
  49 (defgroup notmuch-pick nil
  50   "Showing message and thread structure."
  51   :group 'notmuch)
  52
  53 ;; This is ugly. We can't run setup-show-out until it has been defined
  54 ;; which needs the keymap to be defined. So we defer setting up to
  55 ;; notmuch-pick-init.
  56 (defcustom notmuch-pick-show-out nil
  57   "View selected messages in new window rather than split-pane."
  58   :type 'boolean
  59   :group 'notmuch-pick
  60   :set (lambda (symbol value)
  61          (set-default symbol value)
  62          (when (fboundp 'notmuch-pick-setup-show-out)
  63            (notmuch-pick-setup-show-out))))
  64
  65 (defcustom notmuch-pick-result-format
  66   `(("date" . "%12s  ")
  67     ("authors" . "%-20s")
  68     ("subject" . " %-54s ")
  69     ("tags" . "(%s)"))
  70   "Result formatting for Pick. Supported fields are: date,
  71         authors, subject, tags Note: subject includes the tree
  72         structure graphics, and the author string should not
  73         contain whitespace (put it in the neighbouring fields
  74         instead).  For example:
  75         (setq notmuch-pick-result-format \(\(\"authors\" . \"%-40s\"\)
  76                                              \(\"subject\" . \"%s\"\)\)\)"
  77   :type '(alist :key-type (string) :value-type (string))
  78   :group 'notmuch-pick)
  79
  80 (defcustom notmuch-pick-asynchronous-parser t
  81   "Use the asynchronous parser."
  82   :type 'boolean
  83   :group 'notmuch-pick)
  84
  85 ;; Faces for messages that match the query.
  86 (defface notmuch-pick-match-date-face
  87   '((t :inherit default))
  88   "Face used in pick mode for the date in messages matching the query."
  89   :group 'notmuch-pick
  90   :group 'notmuch-faces)
  91
  92 (defface notmuch-pick-match-author-face
  93   '((((class color)
  94       (background dark))
  95      (:foreground "OliveDrab1"))
  96     (((class color)
  97       (background light))
  98      (:foreground "dark blue"))
  99     (t
 100      (:bold t)))
 101   "Face used in pick mode for the date in messages matching the query."
 102   :group 'notmuch-pick
 103   :group 'notmuch-faces)
 104
 105 (defface notmuch-pick-match-subject-face
 106   '((t :inherit default))
 107   "Face used in pick mode for the subject in messages matching the query."
 108   :group 'notmuch-pick
 109   :group 'notmuch-faces)
 110
 111 (defface notmuch-pick-match-tag-face
 112   '((((class color)
 113       (background dark))
 114      (:foreground "OliveDrab1"))
 115     (((class color)
 116       (background light))
 117      (:foreground "navy blue" :bold t))
 118     (t
 119      (:bold t)))
 120   "Face used in pick mode for tags in messages matching the query."
 121   :group 'notmuch-pick
 122   :group 'notmuch-faces)
 123
 124 ;; Faces for messages that do not match the query.
 125 (defface notmuch-pick-no-match-date-face
 126   '((t (:foreground "gray")))
 127   "Face used in pick mode for non-matching dates."
 128   :group 'notmuch-pick
 129   :group 'notmuch-faces)
 130
 131 (defface notmuch-pick-no-match-subject-face
 132   '((t (:foreground "gray")))
 133   "Face used in pick mode for non-matching subjects."
 134   :group 'notmuch-pick
 135   :group 'notmuch-faces)
 136
 137 (defface notmuch-pick-no-match-author-face
 138   '((t (:foreground "gray")))
 139   "Face used in pick mode for the date in messages matching the query."
 140   :group 'notmuch-pick
 141   :group 'notmuch-faces)
 142
 143 (defface notmuch-pick-no-match-tag-face
 144   '((t (:foreground "gray")))
 145   "Face used in pick mode face for non-matching tags."
 146   :group 'notmuch-pick
 147   :group 'notmuch-faces)
 148
 149 (defvar notmuch-pick-previous-subject "")
 150 (make-variable-buffer-local 'notmuch-pick-previous-subject)
 151
 152 ;; The basic query i.e. the key part of the search request.
 153 (defvar notmuch-pick-basic-query nil)
 154 (make-variable-buffer-local 'notmuch-pick-basic-query)
 155 ;; The context of the search: i.e., useful but can be dropped.
 156 (defvar notmuch-pick-query-context nil)
 157 (make-variable-buffer-local 'notmuch-pick-query-context)
 158 (defvar notmuch-pick-target-msg nil)
 159 (make-variable-buffer-local 'notmuch-pick-target-msg)
 160 (defvar notmuch-pick-buffer-name nil)
 161 (make-variable-buffer-local 'notmuch-pick-buffer-name)
 162 ;; This variable is the window used for the message pane. It is set
 163 ;; in both the parent pick buffer and the child show buffer. It is
 164 ;; used to try and close the message pane when quitting pick or the
 165 ;; child show buffer.
 166 (defvar notmuch-pick-message-window nil)
 167 (make-variable-buffer-local 'notmuch-pick-message-window)
 168 (put 'notmuch-pick-message-window 'permanent-local t)
 169 (defvar notmuch-pick-message-buffer nil)
 170 (make-variable-buffer-local 'notmuch-pick-message-buffer-name)
 171 (put 'notmuch-pick-message-buffer-name 'permanent-local t)
 172 (defvar notmuch-pick-process-state nil
 173   "Parsing state of the search process filter.")
 174
 175
 176 (defvar notmuch-pick-mode-map
 177   (let ((map (make-sparse-keymap)))
 178     (define-key map [mouse-1] 'notmuch-pick-show-message)
 179     (define-key map "q" 'notmuch-pick-quit)
 180     (define-key map "x" 'notmuch-pick-quit)
 181     (define-key map "?" 'notmuch-help)
 182     (define-key map "a" 'notmuch-pick-archive-message-then-next)
 183     (define-key map "=" 'notmuch-pick-refresh-view)
 184     (define-key map "s" 'notmuch-pick-to-search)
 185     (define-key map "z" 'notmuch-pick-to-pick)
 186     (define-key map "m" 'notmuch-pick-new-mail)
 187     (define-key map "f" 'notmuch-pick-forward-message)
 188     (define-key map "r" 'notmuch-pick-reply-sender)
 189     (define-key map "R" 'notmuch-pick-reply)
 190     (define-key map "n" 'notmuch-pick-next-matching-message)
 191     (define-key map "p" 'notmuch-pick-prev-matching-message)
 192     (define-key map "N" 'notmuch-pick-next-message)
 193     (define-key map "P" 'notmuch-pick-prev-message)
 194     (define-key map "|" 'notmuch-pick-pipe-message)
 195     (define-key map "-" 'notmuch-pick-remove-tag)
 196     (define-key map "+" 'notmuch-pick-add-tag)
 197     (define-key map " " 'notmuch-pick-scroll-or-next)
 198     (define-key map "b" 'notmuch-pick-scroll-message-window-back)
 199     map))
 200 (fset 'notmuch-pick-mode-map notmuch-pick-mode-map)
 201
 202 (defun notmuch-pick-setup-show-out ()
 203   (let ((map notmuch-pick-mode-map))
 204     (if notmuch-pick-show-out
 205         (progn
 206           (define-key map (kbd "M-RET") 'notmuch-pick-show-message)
 207           (define-key map (kbd "RET") 'notmuch-pick-show-message-out))
 208       (progn
 209         (define-key map (kbd "RET") 'notmuch-pick-show-message)
 210         (define-key map (kbd "M-RET") 'notmuch-pick-show-message-out)))))
 211
 212 (defun notmuch-pick-get-message-properties ()
 213   "Return the properties of the current message as a plist.
 214
 215 Some useful entries are:
 216 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 217 :tags - Tags for this message"
 218   (save-excursion
 219     (beginning-of-line)
 220     (get-text-property (point) :notmuch-message-properties)))
 221
 222 (defun notmuch-pick-set-message-properties (props)
 223   (save-excursion
 224     (beginning-of-line)
 225     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 226
 227 (defun notmuch-pick-set-prop (prop val &optional props)
 228   (let ((inhibit-read-only t)
 229         (props (or props
 230                    (notmuch-pick-get-message-properties))))
 231     (plist-put props prop val)
 232     (notmuch-pick-set-message-properties props)))
 233
 234 (defun notmuch-pick-get-prop (prop &optional props)
 235   (let ((props (or props
 236                    (notmuch-pick-get-message-properties))))
 237     (plist-get props prop)))
 238
 239 (defun notmuch-pick-set-tags (tags)
 240   "Set the tags of the current message."
 241   (notmuch-pick-set-prop :tags tags))
 242
 243 (defun notmuch-pick-get-tags ()
 244   "Return the tags of the current message."
 245   (notmuch-pick-get-prop :tags))
 246
 247 (defun notmuch-pick-get-message-id ()
 248   "Return the message id of the current message."
 249   (let ((id (notmuch-pick-get-prop :id)))
 250     (if id
 251         (notmuch-id-to-query id)
 252       nil)))
 253
 254 (defun notmuch-pick-get-match ()
 255   "Return whether the current message is a match."
 256   (interactive)
 257   (notmuch-pick-get-prop :match))
 258
 259 (defun notmuch-pick-refresh-result ()
 260   (let ((init-point (point))
 261         (end (line-end-position))
 262         (msg (notmuch-pick-get-message-properties))
 263         (inhibit-read-only t))
 264     (beginning-of-line)
 265     (delete-region (point) (1+ (line-end-position)))
 266     (notmuch-pick-insert-msg msg)
 267     (let ((new-end (line-end-position)))
 268       (goto-char (if (= init-point end)
 269                      new-end
 270                    (min init-point (- new-end 1)))))))
 271
 272 (defun notmuch-pick-tag-update-display (&optional tag-changes)
 273   "Update display for TAG-CHANGES to current message.
 274
 275 Does NOT change the database."
 276   (let* ((current-tags (notmuch-pick-get-tags))
 277          (new-tags (notmuch-update-tags current-tags tag-changes)))
 278     (unless (equal current-tags new-tags)
 279       (notmuch-pick-set-tags new-tags)
 280       (notmuch-pick-refresh-result))))
 281
 282 (defun notmuch-pick-tag (&optional tag-changes)
 283   "Change tags for the current message"
 284   (interactive)
 285   (setq tag-changes (notmuch-tag (notmuch-pick-get-message-id) tag-changes))
 286   (notmuch-pick-tag-update-display tag-changes))
 287
 288 (defun notmuch-pick-add-tag ()
 289   "Same as `notmuch-pick-tag' but sets initial input to '+'."
 290   (interactive)
 291   (notmuch-pick-tag "+"))
 292
 293 (defun notmuch-pick-remove-tag ()
 294   "Same as `notmuch-pick-tag' but sets initial input to '-'."
 295   (interactive)
 296   (notmuch-pick-tag "-"))
 297
 298 ;; The next two functions close the message window before searching or
 299 ;; picking but they do so after the user has entered the query (in
 300 ;; case the user was basing the query on something in the message
 301 ;; window).
 302
 303 (defun notmuch-pick-to-search ()
 304   "Run \"notmuch search\" with the given `query' and display results."
 305   (interactive)
 306   (let ((query (notmuch-read-query "Notmuch search: ")))
 307     (notmuch-pick-close-message-window)
 308     (notmuch-search query)))
 309
 310 (defun notmuch-pick-to-pick ()
 311   "Run a query and display results in experimental notmuch-pick mode"
 312   (interactive)
 313   (let ((query (notmuch-read-query "Notmuch pick: ")))
 314     (notmuch-pick-close-message-window)
 315     (notmuch-pick query)))
 316
 317 ;; This function should be in notmuch-hello.el but we are trying to
 318 ;; minimise impact on the rest of the codebase.
 319 (defun notmuch-pick-from-hello (&optional search)
 320   "Run a query and display results in experimental notmuch-pick mode"
 321   (interactive)
 322   (unless (null search)
 323     (setq search (notmuch-hello-trim search))
 324     (let ((history-delete-duplicates t))
 325       (add-to-history 'notmuch-search-history search)))
 326   (notmuch-pick search))
 327
 328 ;; This function should be in notmuch-show.el but be we trying to
 329 ;; minimise impact on the rest of the codebase.
 330 (defun notmuch-pick-from-show-current-query ()
 331   "Call notmuch pick with the current query"
 332   (interactive)
 333   (notmuch-pick notmuch-show-thread-id
 334                 notmuch-show-query-context
 335                 (notmuch-show-get-message-id)))
 336
 337 ;; This function should be in notmuch.el but be we trying to minimise
 338 ;; impact on the rest of the codebase.
 339 (defun notmuch-pick-from-search-current-query ()
 340   "Call notmuch pick with the current query"
 341   (interactive)
 342   (notmuch-pick notmuch-search-query-string))
 343
 344 ;; This function should be in notmuch.el but be we trying to minimise
 345 ;; impact on the rest of the codebase.
 346 (defun notmuch-pick-from-search-thread ()
 347   "Show the selected thread with notmuch-pick"
 348   (interactive)
 349   (notmuch-pick (notmuch-search-find-thread-id)
 350                 notmuch-search-query-string
 351                 nil
 352                 (notmuch-prettify-subject (notmuch-search-find-subject)))
 353   (notmuch-pick-show-match-message-with-wait))
 354
 355 (defun notmuch-pick-message-window-kill-hook ()
 356   (let ((buffer (current-buffer)))
 357     (when (and (window-live-p notmuch-pick-message-window)
 358                (eq (window-buffer notmuch-pick-message-window) buffer))
 359       ;; We do not want an error if this is the sole window in the
 360       ;; frame and I do not know how to test for that in emacs pre
 361       ;; 24. Hence we just ignore-errors.
 362       (ignore-errors
 363         (delete-window notmuch-pick-message-window)))))
 364
 365 (defun notmuch-pick-show-message ()
 366   "Show the current message (in split-pane)."
 367   (interactive)
 368   (let ((id (notmuch-pick-get-message-id))
 369         (inhibit-read-only t)
 370         buffer)
 371     (when id
 372       ;; We close and reopen the window to kill off un-needed buffers
 373       ;; this might cause flickering but seems ok.
 374       (notmuch-pick-close-message-window)
 375       (setq notmuch-pick-message-window
 376             (split-window-vertically (/ (window-height) 4)))
 377       (with-selected-window notmuch-pick-message-window
 378         ;; Since we are only displaying one message do not indent.
 379         (let ((notmuch-show-indent-messages-width 0)
 380               (notmuch-show-only-matching-messages t))
 381           (setq buffer (notmuch-show id nil nil nil))))
 382       ;; We need the `let' as notmuch-pick-message-window is buffer local.
 383       (let ((window notmuch-pick-message-window))
 384         (with-current-buffer buffer
 385           (setq notmuch-pick-message-window window)
 386           (add-hook 'kill-buffer-hook 'notmuch-pick-message-window-kill-hook)))
 387       (when notmuch-show-mark-read-tags
 388         (notmuch-pick-tag-update-display notmuch-show-mark-read-tags))
 389       (setq notmuch-pick-message-buffer buffer))))
 390
 391 (defun notmuch-pick-show-message-out ()
 392   "Show the current message (in whole window)."
 393   (interactive)
 394   (let ((id (notmuch-pick-get-message-id))
 395         (inhibit-read-only t)
 396         buffer)
 397     (when id
 398       ;; We close the window to kill off un-needed buffers.
 399       (notmuch-pick-close-message-window)
 400       (notmuch-show id nil nil nil))))
 401
 402 (defun notmuch-pick-scroll-message-window ()
 403   "Scroll the message window (if it exists)"
 404   (interactive)
 405   (when (window-live-p notmuch-pick-message-window)
 406     (with-selected-window notmuch-pick-message-window
 407       (if (pos-visible-in-window-p (point-max))
 408           t
 409         (scroll-up)))))
 410
 411 (defun notmuch-pick-scroll-message-window-back ()
 412   "Scroll the message window back(if it exists)"
 413   (interactive)
 414   (when (window-live-p notmuch-pick-message-window)
 415     (with-selected-window notmuch-pick-message-window
 416       (if (pos-visible-in-window-p (point-min))
 417           t
 418         (scroll-down)))))
 419
 420 (defun notmuch-pick-scroll-or-next ()
 421   "Scroll the message window. If it at end go to next message."
 422   (interactive)
 423   (when (notmuch-pick-scroll-message-window)
 424     (notmuch-pick-next-matching-message)))
 425
 426 (defun notmuch-pick-quit ()
 427   "Close the split view or exit pick."
 428   (interactive)
 429   (unless (notmuch-pick-close-message-window)
 430     (kill-buffer (current-buffer))))
 431
 432 (defun notmuch-pick-close-message-window ()
 433   "Close the message-window. Return t if close succeeds."
 434   (interactive)
 435   (when (and (window-live-p notmuch-pick-message-window)
 436              (eq (window-buffer notmuch-pick-message-window) notmuch-pick-message-buffer))
 437     (delete-window notmuch-pick-message-window)
 438     (unless (get-buffer-window-list notmuch-pick-message-buffer)
 439       (kill-buffer notmuch-pick-message-buffer))
 440     t))
 441
 442 (defun notmuch-pick-archive-message (&optional unarchive)
 443   "Archive the current message.
 444
 445 Archive the current message by applying the tag changes in
 446 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
 447 default). If a prefix argument is given, the message will be
 448 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
 449 will be reversed."
 450   (interactive "P")
 451   (when notmuch-archive-tags
 452     (apply 'notmuch-pick-tag
 453            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 454
 455 (defun notmuch-pick-archive-message-then-next (&optional unarchive)
 456   "Archive the current message and move to next matching message."
 457   (interactive "P")
 458   (notmuch-pick-archive-message unarchive)
 459   (notmuch-pick-next-matching-message))
 460
 461 (defun notmuch-pick-next-message ()
 462   "Move to next message."
 463   (interactive)
 464   (forward-line)
 465   (when (window-live-p notmuch-pick-message-window)
 466     (notmuch-pick-show-message)))
 467
 468 (defun notmuch-pick-prev-message ()
 469   "Move to previous message."
 470   (interactive)
 471   (forward-line -1)
 472   (when (window-live-p notmuch-pick-message-window)
 473     (notmuch-pick-show-message)))
 474
 475 (defun notmuch-pick-prev-matching-message ()
 476   "Move to previous matching message."
 477   (interactive)
 478   (forward-line -1)
 479   (while (and (not (bobp)) (not (notmuch-pick-get-match)))
 480     (forward-line -1))
 481   (when (window-live-p notmuch-pick-message-window)
 482     (notmuch-pick-show-message)))
 483
 484 (defun notmuch-pick-next-matching-message ()
 485   "Move to next matching message."
 486   (interactive)
 487   (forward-line)
 488   (while (and (not (eobp)) (not (notmuch-pick-get-match)))
 489     (forward-line))
 490   (when (window-live-p notmuch-pick-message-window)
 491     (notmuch-pick-show-message)))
 492
 493 (defun notmuch-pick-show-match-message-with-wait ()
 494   "Show the first matching message but wait for it to appear or search to finish."
 495   (interactive)
 496   (unless (notmuch-pick-get-match)
 497     (notmuch-pick-next-matching-message))
 498   (while (and (not (notmuch-pick-get-match))
 499               (get-buffer-process (current-buffer)))
 500     (message "waiting for message")
 501     (sit-for 0.1)
 502     (goto-char (point-min))
 503     (unless (notmuch-pick-get-match)
 504       (notmuch-pick-next-matching-message)))
 505   (message nil)
 506   (when (notmuch-pick-get-match)
 507     (notmuch-pick-show-message)))
 508
 509 (defun notmuch-pick-refresh-view ()
 510   "Refresh view."
 511   (interactive)
 512   (let ((inhibit-read-only t)
 513         (basic-query notmuch-pick-basic-query)
 514         (query-context notmuch-pick-query-context)
 515         (target (notmuch-pick-get-message-id))
 516         (buffer-name notmuch-pick-buffer-name))
 517     (erase-buffer)
 518     (notmuch-pick-worker basic-query
 519                          query-context
 520                          target
 521                          (get-buffer buffer-name))))
 522
 523 (defmacro with-current-notmuch-pick-message (&rest body)
 524   "Evaluate body with current buffer set to the text of current message"
 525   `(save-excursion
 526      (let ((id (notmuch-pick-get-message-id)))
 527        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 528          (with-current-buffer buf
 529             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 530            ,@body)
 531          (kill-buffer buf)))))
 532
 533 (defun notmuch-pick-new-mail (&optional prompt-for-sender)
 534   "Compose new mail."
 535   (interactive "P")
 536   (notmuch-pick-close-message-window)
 537   (notmuch-mua-new-mail prompt-for-sender ))
 538
 539 (defun notmuch-pick-forward-message (&optional prompt-for-sender)
 540   "Forward the current message."
 541   (interactive "P")
 542   (notmuch-pick-close-message-window)
 543   (with-current-notmuch-pick-message
 544    (notmuch-mua-new-forward-message prompt-for-sender)))
 545
 546 (defun notmuch-pick-reply (&optional prompt-for-sender)
 547   "Reply to the sender and all recipients of the current message."
 548   (interactive "P")
 549   (notmuch-pick-close-message-window)
 550   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender t))
 551
 552 (defun notmuch-pick-reply-sender (&optional prompt-for-sender)
 553   "Reply to the sender of the current message."
 554   (interactive "P")
 555   (notmuch-pick-close-message-window)
 556   (notmuch-mua-new-reply (notmuch-pick-get-message-id) prompt-for-sender nil))
 557
 558 ;; Shamelessly stolen from notmuch-show.el: maybe should be unified.
 559 (defun notmuch-pick-pipe-message (command)
 560   "Pipe the contents of the current message to the given command.
 561
 562 The given command will be executed with the raw contents of the
 563 current email message as stdin. Anything printed by the command
 564 to stdout or stderr will appear in the *notmuch-pipe* buffer.
 565
 566 When invoked with a prefix argument, the command will receive all
 567 open messages in the current thread (formatted as an mbox) rather
 568 than only the current message."
 569   (interactive "sPipe message to command: ")
 570   (let ((shell-command
 571          (concat notmuch-command " show --format=raw "
 572                  (shell-quote-argument (notmuch-pick-get-message-id)) " | " command))
 573          (buf (get-buffer-create (concat "*notmuch-pipe*"))))
 574     (with-current-buffer buf
 575       (setq buffer-read-only nil)
 576       (erase-buffer)
 577       (let ((exit-code (call-process-shell-command shell-command nil buf)))
 578         (goto-char (point-max))
 579         (set-buffer-modified-p nil)
 580         (setq buffer-read-only t)
 581         (unless (zerop exit-code)
 582           (switch-to-buffer-other-window buf)
 583           (message (format "Command '%s' exited abnormally with code %d"
 584                            shell-command exit-code)))))))
 585
 586 (defun notmuch-pick-clean-address (address)
 587   "Try to clean a single email ADDRESS for display. Return
 588 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 589 unchanged ADDRESS if parsing fails."
 590   (let* ((clean-address (notmuch-clean-address address))
 591          (p-address (car clean-address))
 592          (p-name (cdr clean-address)))
 593
 594     ;; If we have a name return that otherwise return the address.
 595     (or p-name p-address)))
 596
 597 (defun notmuch-pick-insert-field (field format-string msg)
 598   (let* ((headers (plist-get msg :headers))
 599         (match (plist-get msg :match)))
 600     (cond
 601      ((string-equal field "date")
 602       (let ((face (if match
 603                       'notmuch-pick-match-date-face
 604                     'notmuch-pick-no-match-date-face)))
 605         (insert (propertize (format format-string (plist-get msg :date_relative))
 606                             'face face))))
 607
 608      ((string-equal field "subject")
 609       (let ((tree-status (plist-get msg :tree-status))
 610             (bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 611             (face (if match
 612                       'notmuch-pick-match-subject-face
 613                     'notmuch-pick-no-match-subject-face)))
 614         (insert (propertize (format format-string
 615                                     (concat
 616                                      (mapconcat #'identity (reverse tree-status) "")
 617                                      (if (string= notmuch-pick-previous-subject bare-subject)
 618                                          " ..."
 619                                        bare-subject)))
 620                             'face face))
 621         (setq notmuch-pick-previous-subject bare-subject)))
 622
 623      ((string-equal field "authors")
 624       (let ((author (notmuch-pick-clean-address (plist-get headers :From)))
 625             (len (length (format format-string "")))
 626             (face (if match
 627                       'notmuch-pick-match-author-face
 628                     'notmuch-pick-no-match-author-face)))
 629         (when (> (length author) len)
 630           (setq author (substring author 0 len)))
 631         (insert (propertize (format format-string author)
 632                             'face face))))
 633
 634      ((string-equal field "tags")
 635       (let ((tags (plist-get msg :tags))
 636             (face (if match
 637                           'notmuch-pick-match-tag-face
 638                         'notmuch-pick-no-match-tag-face)))
 639         (when tags
 640           (insert (propertize (format format-string
 641                                       (mapconcat #'identity tags ", "))
 642                               'face face))))))))
 643
 644 (defun notmuch-pick-insert-msg (msg)
 645   "Insert the message MSG according to notmuch-pick-result-format"
 646   (dolist (spec notmuch-pick-result-format)
 647     (notmuch-pick-insert-field (car spec) (cdr spec) msg))
 648   (notmuch-pick-set-message-properties msg)
 649   (insert "\n"))
 650
 651 (defun notmuch-pick-goto-and-insert-msg (msg)
 652   "Insert msg at the end of the buffer. Move point to msg if it is the target"
 653   (save-excursion
 654     (goto-char (point-max))
 655     (notmuch-pick-insert-msg msg))
 656   (let ((msg-id (notmuch-id-to-query (plist-get msg :id))))
 657     (when (string= msg-id notmuch-pick-target-msg)
 658       (setq notmuch-pick-target-msg "found")
 659       (goto-char (point-max))
 660       (forward-line -1))))
 661
 662 (defun notmuch-pick-insert-tree (tree depth tree-status first last)
 663   "Insert the message tree TREE at depth DEPTH in the current thread."
 664   (let ((msg (car tree))
 665         (replies (cadr tree)))
 666
 667       (cond
 668        ((and (< 0 depth) (not last))
 669         (push "├" tree-status))
 670        ((and (< 0 depth) last)
 671         (push "╰" tree-status))
 672        ((and (eq 0 depth) first last)
 673 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
 674         (push " " tree-status))
 675        ((and (eq 0 depth) first (not last))
 676           (push "┬" tree-status))
 677        ((and (eq 0 depth) (not first) last)
 678         (push "╰" tree-status))
 679        ((and (eq 0 depth) (not first) (not last))
 680         (push "├" tree-status)))
 681
 682       (push (concat (if replies "┬" "─") "►") tree-status)
 683       (notmuch-pick-goto-and-insert-msg (plist-put msg :tree-status tree-status))
 684       (pop tree-status)
 685       (pop tree-status)
 686
 687       (if last
 688           (push " " tree-status)
 689         (push "│" tree-status))
 690
 691     (notmuch-pick-insert-thread replies (1+ depth) tree-status)))
 692
 693 (defun notmuch-pick-insert-thread (thread depth tree-status)
 694   "Insert the thread THREAD at depth DEPTH >= 1 in the current forest."
 695   (let ((n (length thread)))
 696     (loop for tree in thread
 697           for count from 1 to n
 698
 699           do (notmuch-pick-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
 700
 701 (defun notmuch-pick-insert-forest-thread (forest-thread)
 702   (let (tree-status)
 703     ;; Reset at the start of each main thread.
 704     (setq notmuch-pick-previous-subject nil)
 705     (notmuch-pick-insert-thread forest-thread 0 tree-status)))
 706
 707 (defun notmuch-pick-insert-forest (forest)
 708   (mapc 'notmuch-pick-insert-forest-thread forest))
 709
 710 (defun notmuch-pick-mode ()
 711   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
 712
 713 This buffer contains the results of a \"notmuch pick\" of your
 714 email archives. Each line in the buffer represents a single
 715 message giving the relative date, the author, subject, and any
 716 tags.
 717
 718 Pressing \\[notmuch-pick-show-message] on any line displays that message.
 719
 720 Complete list of currently available key bindings:
 721
 722 \\{notmuch-pick-mode-map}"
 723
 724   (interactive)
 725   (kill-all-local-variables)
 726   (use-local-map notmuch-pick-mode-map)
 727   (setq major-mode 'notmuch-pick-mode
 728         mode-name "notmuch-pick")
 729   (hl-line-mode 1)
 730   (setq buffer-read-only t
 731         truncate-lines t))
 732
 733 (defun notmuch-pick-process-sentinel (proc msg)
 734   "Add a message to let user know when \"notmuch pick\" exits"
 735   (let ((buffer (process-buffer proc))
 736         (status (process-status proc))
 737         (exit-status (process-exit-status proc))
 738         (never-found-target-thread nil))
 739     (when (memq status '(exit signal))
 740         (kill-buffer (process-get proc 'parse-buf))
 741         (if (buffer-live-p buffer)
 742             (with-current-buffer buffer
 743               (save-excursion
 744                 (let ((inhibit-read-only t)
 745                       (atbob (bobp)))
 746                   (goto-char (point-max))
 747                   (if (eq status 'signal)
 748                       (insert "Incomplete search results (pick process was killed).\n"))
 749                   (when (eq status 'exit)
 750                     (insert "End of search results.")
 751                     (unless (= exit-status 0)
 752                       (insert (format " (process returned %d)" exit-status)))
 753                     (insert "\n")))))))))
 754
 755
 756 (defun notmuch-pick-show-error (string &rest objects)
 757   (save-excursion
 758     (goto-char (point-max))
 759     (insert "Error: Unexpected output from notmuch search:\n")
 760     (insert (apply #'format string objects))
 761     (insert "\n")))
 762
 763
 764 (defun notmuch-pick-process-filter (proc string)
 765   "Process and filter the output of \"notmuch show\" (for pick)"
 766   (let ((results-buf (process-buffer proc))
 767         (parse-buf (process-get proc 'parse-buf))
 768         (inhibit-read-only t)
 769         done)
 770     (if (not (buffer-live-p results-buf))
 771         (delete-process proc)
 772       (with-current-buffer parse-buf
 773         ;; Insert new data
 774         (save-excursion
 775           (goto-char (point-max))
 776           (insert string))
 777         (notmuch-sexp-parse-partial-list 'notmuch-pick-insert-forest-thread
 778                                          results-buf)))))
 779
 780 (defun notmuch-pick-worker (basic-query &optional query-context target buffer)
 781   (interactive)
 782   (notmuch-pick-mode)
 783   (setq notmuch-pick-basic-query basic-query)
 784   (setq notmuch-pick-query-context query-context)
 785   (setq notmuch-pick-buffer-name (buffer-name buffer))
 786   (setq notmuch-pick-target-msg target)
 787
 788   (erase-buffer)
 789   (goto-char (point-min))
 790   (let* ((search-args (concat basic-query
 791                        (if query-context (concat " and (" query-context ")"))
 792                        ))
 793          (message-arg "--entire-thread"))
 794     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
 795         (setq search-args basic-query))
 796     (if notmuch-pick-asynchronous-parser
 797         (let ((proc (start-process
 798                      "notmuch-pick" buffer
 799                      notmuch-command "show" "--body=false" "--format=sexp"
 800                      message-arg search-args))
 801               ;; Use a scratch buffer to accumulate partial output.
 802               ;; This buffer will be killed by the sentinel, which
 803               ;; should be called no matter how the process dies.
 804               (parse-buf (generate-new-buffer " *notmuch pick parse*")))
 805           (process-put proc 'parse-buf parse-buf)
 806           (set-process-sentinel proc 'notmuch-pick-process-sentinel)
 807           (set-process-filter proc 'notmuch-pick-process-filter)
 808           (set-process-query-on-exit-flag proc nil))
 809       (progn
 810         (notmuch-pick-insert-forest
 811          (notmuch-query-get-threads
 812           (list "--body=false" message-arg search-args)))
 813         (save-excursion
 814           (goto-char (point-max))
 815           (insert "End of search results.\n"))))))
 816
 817
 818 (defun notmuch-pick (&optional query query-context target buffer-name show-first-match)
 819   "Run notmuch pick with the given `query' and display the results"
 820   (interactive "sNotmuch pick: ")
 821   (if (null query)
 822       (setq query (notmuch-read-query "Notmuch pick: ")))
 823   (let ((buffer (get-buffer-create (generate-new-buffer-name
 824                                     (or buffer-name
 825                                         (concat "*notmuch-pick-" query "*")))))
 826         (inhibit-read-only t))
 827
 828     (switch-to-buffer buffer)
 829     ;; Don't track undo information for this buffer
 830     (set 'buffer-undo-list t)
 831
 832     (notmuch-pick-worker query query-context target buffer)
 833
 834     (setq truncate-lines t)
 835     (when show-first-match
 836       (notmuch-pick-show-match-message-with-wait))))
 837
 838
 839 ;; Set up key bindings from the rest of notmuch.
 840 (define-key 'notmuch-search-mode-map "z" 'notmuch-pick)
 841 (define-key 'notmuch-search-mode-map "Z" 'notmuch-pick-from-search-current-query)
 842 (define-key 'notmuch-search-mode-map (kbd "M-RET") 'notmuch-pick-from-search-thread)
 843 (define-key 'notmuch-hello-mode-map "z" 'notmuch-pick-from-hello)
 844 (define-key 'notmuch-show-mode-map "z" 'notmuch-pick)
 845 (define-key 'notmuch-show-mode-map "Z" 'notmuch-pick-from-show-current-query)
 846 (notmuch-pick-setup-show-out)
 847 (message "Initialised notmuch-pick")
 848
 849 (provide 'notmuch-pick)