git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-address.el

   1 ;;; notmuch-address.el --- address completion with notmuch
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 ;;; Code:
  23
  24 (require 'message)
  25 (require 'notmuch-parser)
  26 (require 'notmuch-lib)
  27 (require 'notmuch-company)
  28 ;;
  29 (declare-function company-manual-begin "company")
  30
  31 (defvar notmuch-address-last-harvest 0
  32   "Time of last address harvest.")
  33
  34 (defvar notmuch-address-completions (make-hash-table :test 'equal)
  35   "Hash of email addresses for completion during email composition.
  36 This variable is set by calling `notmuch-address-harvest'.")
  37
  38 (defvar notmuch-address-full-harvest-finished nil
  39   "t indicates that full completion address harvesting has been
  40 finished. Use notmuch-address--harvest-ready to access as that
  41 will load a saved hash if necessary (and available).")
  42
  43 (defun notmuch-address--harvest-ready ()
  44   "Return t if there is a full address hash available.
  45
  46 If the hash is not present it attempts to load a saved hash."
  47   (or notmuch-address-full-harvest-finished
  48       (notmuch-address--load-address-hash)))
  49
  50 (defcustom notmuch-address-command 'internal
  51   "Determines how address completion candidates are generated.
  52
  53 If it is a string then that string should be an external program
  54 which must take a single argument (searched string) and output a
  55 list of completion candidates, one per line.
  56
  57 Alternatively, it can be the symbol 'internal, in which case
  58 internal completion is used; the variable
  59 `notmuch-address-internal-completion` can be used to customize
  60 this case.
  61
  62 Finally, if this variable is nil then address completion is
  63 disabled."
  64   :type '(radio
  65           (const :tag "Use internal address completion" internal)
  66           (const :tag "Disable address completion" nil)
  67           (string :tag "Use external completion command"))
  68   :group 'notmuch-send
  69   :group 'notmuch-address
  70   :group 'notmuch-external)
  71
  72 (defcustom notmuch-address-internal-completion '(sent nil)
  73   "Determines how internal address completion generates candidates.
  74
  75 This should be a list of the form '(DIRECTION FILTER), where
  76 DIRECTION is either sent or received and specifies whether the
  77 candidates are searched in messages sent by the user or received
  78 by the user (note received by is much faster), and FILTER is
  79 either nil or a filter-string, such as \"date:1y..\" to append
  80 to the query."
  81   :type '(list :tag "Use internal address completion"
  82                (radio
  83                 :tag "Base completion on messages you have"
  84                 :value sent
  85                 (const :tag "sent (more accurate)" sent)
  86                 (const :tag "received (faster)" received))
  87                (radio :tag "Filter messages used for completion"
  88                       (const :tag "Use all messages" nil)
  89                       (string :tag "Filter query")))
  90   ;; We override set so that we can clear the cache when this changes
  91   :set (lambda (symbol value)
  92          (set-default symbol value)
  93          (setq notmuch-address-last-harvest 0)
  94          (setq notmuch-address-completions (clrhash notmuch-address-completions))
  95          (setq notmuch-address-full-harvest-finished nil))
  96   :group 'notmuch-send
  97   :group 'notmuch-address
  98   :group 'notmuch-external)
  99
 100 (defcustom notmuch-address-save-filename nil
 101   "Filename to save the cached completion addresses.
 102
 103 All the addresses notmuch uses for address completion will be
 104 cached in this file. This has obvious privacy implications so you
 105 should make sure it is not somewhere publicly readable."
 106   :type '(choice (const :tag "Off" nil)
 107                  (file :tag "Filename"))
 108   :group 'notmuch-send
 109   :group 'notmuch-address
 110   :group 'notmuch-external)
 111
 112 (defcustom notmuch-address-selection-function 'notmuch-address-selection-function
 113   "The function to select address from given list. The function is
 114 called with PROMPT, COLLECTION, and INITIAL-INPUT as arguments
 115 (subset of what `completing-read' can be called with).
 116 While executed the value of `completion-ignore-case' is t.
 117 See documentation of function `notmuch-address-selection-function'
 118 to know how address selection is made by default."
 119   :type 'function
 120   :group 'notmuch-send
 121   :group 'notmuch-address
 122   :group 'notmuch-external)
 123
 124 (defcustom notmuch-address-post-completion-functions nil
 125   "Functions called after completing address.
 126
 127 The completed address is passed as an argument to each function.
 128 Note that this hook will be invoked for completion in headers
 129 matching `notmuch-address-completion-headers-regexp'."
 130   :type 'hook
 131   :group 'notmuch-address
 132   :group 'notmuch-hooks)
 133
 134 (defun notmuch-address-selection-function (prompt collection initial-input)
 135   "Call (`completing-read'
 136       PROMPT COLLECTION nil nil INITIAL-INPUT 'notmuch-address-history)"
 137   (completing-read
 138    prompt collection nil nil initial-input 'notmuch-address-history))
 139
 140 (defvar notmuch-address-completion-headers-regexp
 141   "^\\(Resent-\\)?\\(To\\|B?Cc\\|Reply-To\\|From\\|Mail-Followup-To\\|Mail-Copies-To\\):")
 142
 143 (defvar notmuch-address-history nil)
 144
 145 (defun notmuch-address-message-insinuate ()
 146   (message "calling notmuch-address-message-insinuate is no longer needed"))
 147
 148 (defcustom notmuch-address-use-company t
 149   "If available, use company mode for address completion."
 150   :type 'boolean
 151   :group 'notmuch-send
 152   :group 'notmuch-address)
 153
 154 (defun notmuch-address-setup ()
 155   (let* ((setup-company (and notmuch-address-use-company
 156                            (require 'company nil t)))
 157          (pair (cons notmuch-address-completion-headers-regexp
 158                        #'notmuch-address-expand-name)))
 159       (when setup-company
 160         (notmuch-company-setup))
 161       (unless (member pair message-completion-alist)
 162         (setq message-completion-alist
 163               (push pair message-completion-alist)))))
 164
 165 (defun notmuch-address-toggle-internal-completion ()
 166   "Toggle use of internal completion for current buffer.
 167
 168 This overrides the global setting for address completion and
 169 toggles the setting in this buffer."
 170   (interactive)
 171   (if (local-variable-p 'notmuch-address-command)
 172       (kill-local-variable 'notmuch-address-command)
 173     (notmuch-setq-local notmuch-address-command 'internal))
 174   (if (boundp 'company-idle-delay)
 175       (if (local-variable-p 'company-idle-delay)
 176           (kill-local-variable 'company-idle-delay)
 177         (notmuch-setq-local company-idle-delay nil))))
 178
 179 (defun notmuch-address-matching (substring)
 180   "Returns a list of completion candidates matching SUBSTRING.
 181 The candidates are taken from `notmuch-address-completions'."
 182   (let ((candidates)
 183         (re (regexp-quote substring)))
 184     (maphash (lambda (key val)
 185                (when (string-match re key)
 186                  (push key candidates)))
 187              notmuch-address-completions)
 188     candidates))
 189
 190 (defun notmuch-address-options (original)
 191   "Returns a list of completion candidates. Uses either
 192 elisp-based implementation or older implementation requiring
 193 external commands."
 194   (cond
 195    ((eq notmuch-address-command 'internal)
 196     (unless (notmuch-address--harvest-ready)
 197       ;; First, run quick synchronous harvest based on what the user
 198       ;; entered so far.
 199       (notmuch-address-harvest original t))
 200     (prog1 (notmuch-address-matching original)
 201       ;; Then start the (potentially long-running) full asynchronous
 202       ;; harvest if necessary.
 203       (notmuch-address-harvest-trigger)))
 204    (t
 205     (process-lines notmuch-address-command original))))
 206
 207 (defun notmuch-address-expand-name ()
 208   (cond
 209    ((and (eq notmuch-address-command 'internal)
 210          notmuch-address-use-company
 211          (bound-and-true-p company-mode))
 212     (company-manual-begin))
 213    (notmuch-address-command
 214     (let* ((end (point))
 215            (beg (save-excursion
 216                   (re-search-backward "\\(\\`\\|[\n:,]\\)[ \t]*")
 217                   (goto-char (match-end 0))
 218                   (point)))
 219            (orig (buffer-substring-no-properties beg end))
 220            (completion-ignore-case t)
 221            (options (with-temp-message "Looking for completion candidates..."
 222                       (notmuch-address-options orig)))
 223            (num-options (length options))
 224            (chosen (cond
 225                     ((eq num-options 0)
 226                      nil)
 227                     ((eq num-options 1)
 228                      (car options))
 229                     (t
 230                      (funcall notmuch-address-selection-function
 231                               (format "Address (%s matches): " num-options)
 232                               ;; We put the first match as the initial
 233                               ;; input; we put all the matches as
 234                               ;; possible completions, moving the
 235                               ;; first match to the end of the list
 236                               ;; makes cursor up/down in the list work
 237                               ;; better.
 238                               (append (cdr options) (list (car options)))
 239                               (car options))))))
 240       (if chosen
 241           (progn
 242             (push chosen notmuch-address-history)
 243             (delete-region beg end)
 244             (insert chosen)
 245             (run-hook-with-args 'notmuch-address-post-completion-functions
 246                                 chosen))
 247         (message "No matches.")
 248         (ding))))
 249    (t nil)))
 250
 251 ;; Copied from `w3m-which-command'.
 252 (defun notmuch-address-locate-command (command)
 253   "Return non-nil if `command' is an executable either on
 254 `exec-path' or an absolute pathname."
 255   (when (stringp command)
 256     (if (and (file-name-absolute-p command)
 257              (file-executable-p command))
 258         command
 259       (setq command (file-name-nondirectory command))
 260       (catch 'found-command
 261         (let (bin)
 262           (dolist (dir exec-path)
 263             (setq bin (expand-file-name command dir))
 264             (when (or (and (file-executable-p bin)
 265                            (not (file-directory-p bin)))
 266                       (and (file-executable-p (setq bin (concat bin ".exe")))
 267                            (not (file-directory-p bin))))
 268               (throw 'found-command bin))))))))
 269
 270 (defun notmuch-address-harvest-addr (result)
 271   (let ((name-addr (plist-get result :name-addr)))
 272     (puthash name-addr t notmuch-address-completions)))
 273
 274 (defun notmuch-address-harvest-handle-result (obj)
 275   (notmuch-address-harvest-addr obj))
 276
 277 (defun notmuch-address-harvest-filter (proc string)
 278   (when (buffer-live-p (process-buffer proc))
 279     (with-current-buffer (process-buffer proc)
 280       (save-excursion
 281         (goto-char (point-max))
 282         (insert string))
 283       (notmuch-sexp-parse-partial-list
 284        'notmuch-address-harvest-handle-result (process-buffer proc)))))
 285
 286 (defvar notmuch-address-harvest-procs '(nil . nil)
 287   "The currently running harvests.
 288
 289 The car is a partial harvest, and the cdr is a full harvest.")
 290
 291 (defun notmuch-address-harvest (&optional addr-prefix synchronous callback)
 292   "Collect addresses completion candidates.
 293
 294 It queries the notmuch database for messages sent/received (as
 295 configured with `notmuch-address-command`) by the user, collects
 296 destination/source addresses from those messages and stores them
 297 in `notmuch-address-completions'.
 298
 299 If ADDR-PREFIX is not nil, only messages with to/from addresses
 300 matching ADDR-PREFIX*' are queried.
 301
 302 Address harvesting may take some time so the address collection runs
 303 asynchronously unless SYNCHRONOUS is t. In case of asynchronous
 304 execution, CALLBACK is called when harvesting finishes."
 305
 306   (let* ((sent (eq (car notmuch-address-internal-completion) 'sent))
 307          (config-query (cadr notmuch-address-internal-completion))
 308          (prefix-query (when addr-prefix
 309                          (format "%s:%s*" (if sent "to" "from") addr-prefix)))
 310          (from-or-to-me-query
 311           (mapconcat (lambda (x)
 312                        (concat (if sent "from:" "to:") x))
 313                      (notmuch-user-emails) " or "))
 314          (query (if (or prefix-query config-query)
 315                     (concat (format "(%s)" from-or-to-me-query)
 316                             (when prefix-query
 317                               (format " and (%s)" prefix-query))
 318                             (when config-query
 319                               (format " and (%s)" config-query)))
 320                   from-or-to-me-query))
 321          (args `("address" "--format=sexp" "--format-version=4"
 322                  ,(if sent "--output=recipients" "--output=sender")
 323                  "--deduplicate=address"
 324                  ,query)))
 325     (if synchronous
 326         (mapc #'notmuch-address-harvest-addr
 327                                    (apply 'notmuch-call-notmuch-sexp args))
 328       ;; Asynchronous
 329       (let* ((current-proc (if addr-prefix
 330                                (car notmuch-address-harvest-procs)
 331                              (cdr notmuch-address-harvest-procs)))
 332              (proc-name (format "notmuch-address-%s-harvest"
 333                                 (if addr-prefix "partial" "full")))
 334              (proc-buf (concat " *" proc-name "*")))
 335         ;; Kill any existing process
 336         (when current-proc
 337           (kill-buffer (process-buffer current-proc))) ; this also kills the process
 338
 339         (setq current-proc
 340               (apply 'notmuch-start-notmuch proc-name proc-buf
 341                      callback                           ; process sentinel
 342                      args))
 343         (set-process-filter current-proc 'notmuch-address-harvest-filter)
 344         (set-process-query-on-exit-flag current-proc nil)
 345         (if addr-prefix
 346             (setcar notmuch-address-harvest-procs current-proc)
 347           (setcdr notmuch-address-harvest-procs current-proc)))))
 348   ;; return value
 349   nil)
 350
 351 (defvar notmuch-address--save-hash-version 1
 352   "Version format of the save hash.")
 353
 354 (defun notmuch-address--get-address-hash ()
 355   "Returns the saved address hash as a plist.
 356
 357 Returns nil if the save file does not exist, or it does not seem
 358 to be a saved address hash."
 359   (when notmuch-address-save-filename
 360     (condition-case nil
 361         (with-temp-buffer
 362           (insert-file-contents notmuch-address-save-filename)
 363           (let ((name (read (current-buffer)))
 364                 (plist (read (current-buffer))))
 365             ;; We do two simple sanity checks on the loaded file. We just
 366             ;; check a version is specified, not that it is the current
 367             ;; version, as we are allowed to over-write and a save-file with
 368             ;; an older version.
 369             (when (and (string= name "notmuch-address-hash")
 370                        (plist-get plist :version))
 371               plist)))
 372       ;; The error case catches any of the reads failing.
 373       (error nil))))
 374
 375 (defun notmuch-address--load-address-hash ()
 376   "Read the saved address hash and set the corresponding variables."
 377   (let ((load-plist (notmuch-address--get-address-hash)))
 378     (when (and load-plist
 379                ;; If the user's setting have changed, or the version
 380                ;; has changed, return nil to make sure the new settings
 381                ;; take effect.
 382                (equal (plist-get load-plist :completion-settings)
 383                       notmuch-address-internal-completion)
 384                (equal (plist-get load-plist :version)
 385                       notmuch-address--save-hash-version))
 386       (setq notmuch-address-last-harvest (plist-get load-plist :last-harvest)
 387             notmuch-address-completions (plist-get load-plist :completions)
 388             notmuch-address-full-harvest-finished t)
 389       ;; Return t to say load was successful.
 390       t)))
 391
 392 (defun notmuch-address--save-address-hash ()
 393   (when notmuch-address-save-filename
 394     (if (or (not (file-exists-p notmuch-address-save-filename))
 395               ;; The file exists, check it is a file we saved
 396             (notmuch-address--get-address-hash))
 397         (with-temp-file notmuch-address-save-filename
 398           (let ((save-plist
 399                  (list :version notmuch-address--save-hash-version
 400                        :completion-settings notmuch-address-internal-completion
 401                        :last-harvest notmuch-address-last-harvest
 402                        :completions notmuch-address-completions)))
 403             (print "notmuch-address-hash" (current-buffer))
 404             (print save-plist (current-buffer))))
 405       (message "\
 406 Warning: notmuch-address-save-filename %s exists but doesn't
 407 appear to be an address savefile.  Not overwriting."
 408                notmuch-address-save-filename))))
 409
 410 (defun notmuch-address-harvest-trigger ()
 411   (let ((now (float-time)))
 412     (when (> (- now notmuch-address-last-harvest) 86400)
 413       (setq notmuch-address-last-harvest now)
 414       (notmuch-address-harvest
 415        nil nil
 416        (lambda (proc event)
 417          ;; If harvest fails, we want to try
 418          ;; again when the trigger is next
 419          ;; called
 420          (if (string= event "finished\n")
 421              (progn
 422                (notmuch-address--save-address-hash)
 423                (setq notmuch-address-full-harvest-finished t))
 424            (setq notmuch-address-last-harvest 0)))))))
 425
 426 ;;
 427
 428 (defun notmuch-address-from-minibuffer (prompt)
 429   (if (not notmuch-address-command)
 430       (read-string prompt)
 431     (let ((rmap (copy-keymap minibuffer-local-map))
 432           (omap minibuffer-local-map))
 433       ;; Configure TAB to start completion when executing read-string.
 434       ;; "Original" minibuffer keymap is restored just before calling
 435       ;; notmuch-address-expand-name as it may also use minibuffer-local-map
 436       ;; (completing-read probably does not but if something else is used there).
 437       (define-key rmap (kbd "TAB") (lambda ()
 438                                      (interactive)
 439                                      (let ((enable-recursive-minibuffers t)
 440                                            (minibuffer-local-map omap))
 441                                        (notmuch-address-expand-name))))
 442       (let ((minibuffer-local-map rmap))
 443         (read-string prompt)))))
 444
 445 ;;
 446
 447 (provide 'notmuch-address)
 448
 449 ;;; notmuch-address.el ends here