git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-hello.el

   1 ;; notmuch-hello.el --- welcome to notmuch, a frontend
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (eval-when-compile (require 'cl))
  23 (require 'widget)
  24 (require 'wid-edit) ; For `widget-forward'.
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-mua)
  28
  29 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line continuation))
  30 (declare-function notmuch-poll "notmuch" ())
  31
  32 (defcustom notmuch-hello-recent-searches-max 10
  33   "The number of recent searches to display."
  34   :type 'integer
  35   :group 'notmuch-hello)
  36
  37 (defcustom notmuch-show-empty-saved-searches nil
  38   "Should saved searches with no messages be listed?"
  39   :type 'boolean
  40   :group 'notmuch-hello)
  41
  42 (defun notmuch-sort-saved-searches (alist)
  43   "Generate an alphabetically sorted saved searches alist."
  44   (sort (copy-sequence alist) (lambda (a b) (string< (car a) (car b)))))
  45
  46 (defcustom notmuch-saved-search-sort-function nil
  47   "Function used to sort the saved searches for the notmuch-hello view.
  48
  49 This variable controls how saved searches should be sorted. No
  50 sorting (nil) displays the saved searches in the order they are
  51 stored in `notmuch-saved-searches'. Sort alphabetically sorts the
  52 saved searches in alphabetical order. Custom sort function should
  53 be a function or a lambda expression that takes the saved
  54 searches alist as a parameter, and returns a new saved searches
  55 alist to be used."
  56   :type '(choice (const :tag "No sorting" nil)
  57                  (const :tag "Sort alphabetically" notmuch-sort-saved-searches)
  58                  (function :tag "Custom sort function"
  59                            :value notmuch-sort-saved-searches))
  60   :group 'notmuch-hello)
  61
  62 (defvar notmuch-hello-indent 4
  63   "How much to indent non-headers.")
  64
  65 (defcustom notmuch-show-logo t
  66   "Should the notmuch logo be shown?"
  67   :type 'boolean
  68   :group 'notmuch-hello)
  69
  70 (defcustom notmuch-show-all-tags-list nil
  71   "Should all tags be shown in the notmuch-hello view?"
  72   :type 'boolean
  73   :group 'notmuch-hello)
  74
  75 (defcustom notmuch-hello-tag-list-make-query nil
  76   "Function or string to generate queries for the all tags list.
  77
  78 This variable controls which query results are shown for each tag
  79 in the \"all tags\" list. If nil, it will use all messages with
  80 that tag. If this is set to a string, it is used as a filter for
  81 messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
  82 Finally this can be a function that will be called for each tag and
  83 should return a filter for that tag, or nil to hide the tag."
  84   :type '(choice (const :tag "All messages" nil)
  85                  (const :tag "Unread messages" "tag:unread")
  86                  (string :tag "Custom filter"
  87                          :value "tag:unread")
  88                  (function :tag "Custom filter function"))
  89   :group 'notmuch-hello)
  90
  91 (defcustom notmuch-hello-hide-tags nil
  92   "List of tags to be hidden in the \"all tags\"-section."
  93   :type '(repeat string)
  94   :group 'notmuch-hello)
  95
  96 (defface notmuch-hello-logo-background
  97   '((((class color)
  98       (background dark))
  99      (:background "#5f5f5f"))
 100     (((class color)
 101       (background light))
 102      (:background "white")))
 103   "Background colour for the notmuch logo."
 104   :group 'notmuch-hello
 105   :group 'notmuch-faces)
 106
 107 (defcustom notmuch-column-control t
 108   "Controls the number of columns for saved searches/tags in notmuch view.
 109
 110 This variable has three potential sets of values:
 111
 112 - t: automatically calculate the number of columns possible based
 113   on the tags to be shown and the window width,
 114 - an integer: a lower bound on the number of characters that will
 115   be used to display each column,
 116 - a float: a fraction of the window width that is the lower bound
 117   on the number of characters that should be used for each
 118   column.
 119
 120 So:
 121 - if you would like two columns of tags, set this to 0.5.
 122 - if you would like a single column of tags, set this to 1.0.
 123 - if you would like tags to be 30 characters wide, set this to
 124   30.
 125 - if you don't want to worry about all of this nonsense, leave
 126   this set to `t'."
 127   :type '(choice
 128           (const :tag "Automatically calculated" t)
 129           (integer :tag "Number of characters")
 130           (float :tag "Fraction of window"))
 131   :group 'notmuch-hello)
 132
 133 (defcustom notmuch-hello-thousands-separator " "
 134   "The string used as a thousands separator.
 135
 136 Typically \",\" in the US and UK and \".\" or \" \" in Europe.
 137 The latter is recommended in the SI/ISO 31-0 standard and by the
 138 International Bureau of Weights and Measures."
 139   :type 'string
 140   :group 'notmuch-hello)
 141
 142 (defcustom notmuch-hello-mode-hook nil
 143   "Functions called after entering `notmuch-hello-mode'."
 144   :type 'hook
 145   :group 'notmuch-hello
 146   :group 'notmuch-hooks)
 147
 148 (defcustom notmuch-hello-refresh-hook nil
 149   "Functions called after updating a `notmuch-hello' buffer."
 150   :type 'hook
 151   :group 'notmuch-hello
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-hello-url "http://notmuchmail.org"
 155   "The `notmuch' web site.")
 156
 157 (defvar notmuch-hello-custom-section-options
 158   '((:filter (string :tag "Filter for each tag"))
 159     (:filter-count (string :tag "Different filter to generate message counts"))
 160     (:initially-hidden (const :tag "Hide this section on startup" t))
 161     (:show-empty-searches (const :tag "Show queries with no matching messages" t))
 162     (:hide-if-empty (const :tag "Hide this section if all queries are empty
 163 \(and not shown by show-empty-searches)" t)))
 164   "Various customization-options for notmuch-hello-tags/query-section.")
 165
 166 (define-widget 'notmuch-hello-tags-section 'lazy
 167   "Customize-type for notmuch-hello tag-list sections."
 168   :tag "Customized tag-list section (see docstring for details)"
 169   :type
 170   `(list :tag ""
 171          (const :tag "" notmuch-hello-insert-tags-section)
 172          (string :tag "Title for this section")
 173          (plist
 174           :inline t
 175           :options
 176           ,(append notmuch-hello-custom-section-options
 177                    '((:hide-tags (repeat :tag "Tags that will be hidden"
 178                                          string)))))))
 179
 180 (define-widget 'notmuch-hello-query-section 'lazy
 181   "Customize-type for custom saved-search-like sections"
 182   :tag "Customized queries section (see docstring for details)"
 183   :type
 184   `(list :tag ""
 185          (const :tag "" notmuch-hello-insert-searches)
 186          (string :tag "Title for this section")
 187          (repeat :tag "Queries"
 188                  (cons (string :tag "Name") (string :tag "Query")))
 189          (plist :inline t :options ,notmuch-hello-custom-section-options)))
 190
 191 (defcustom notmuch-hello-sections
 192   (list #'notmuch-hello-insert-header
 193         #'notmuch-hello-insert-saved-searches
 194         #'notmuch-hello-insert-search
 195         #'notmuch-hello-insert-recent-searches
 196         #'notmuch-hello-insert-alltags
 197         #'notmuch-hello-insert-footer)
 198   "Sections for notmuch-hello.
 199
 200 The list contains functions which are used to construct sections in
 201 notmuch-hello buffer.  When notmuch-hello buffer is constructed,
 202 these functions are run in the order they appear in this list.  Each
 203 function produces a section simply by adding content to the current
 204 buffer.  A section should not end with an empty line, because a
 205 newline will be inserted after each section by `notmuch-hello'.
 206
 207 Each function should take no arguments. The return value is
 208 ignored.
 209
 210 For convenience an element can also be a list of the form (FUNC ARG1
 211 ARG2 .. ARGN) in which case FUNC will be applied to the rest of the
 212 list.
 213
 214 A \"Customized tag-list section\" item in the customize-interface
 215 displays a list of all tags, optionally hiding some of them. It
 216 is also possible to filter the list of messages matching each tag
 217 by an additional filter query. Similarly, the count of messages
 218 displayed next to the buttons can be generated by applying a
 219 different filter to the tag query. These filters are also
 220 supported for \"Customized queries section\" items."
 221   :group 'notmuch-hello
 222   :type
 223   '(repeat
 224     (choice (function-item notmuch-hello-insert-header)
 225             (function-item notmuch-hello-insert-saved-searches)
 226             (function-item notmuch-hello-insert-search)
 227             (function-item notmuch-hello-insert-recent-searches)
 228             (function-item notmuch-hello-insert-alltags)
 229             (function-item notmuch-hello-insert-footer)
 230             (function-item notmuch-hello-insert-inbox)
 231             notmuch-hello-tags-section
 232             notmuch-hello-query-section
 233             (function :tag "Custom section"))))
 234
 235 (defvar notmuch-hello-hidden-sections nil
 236   "List of sections titles whose contents are hidden")
 237
 238 (defvar notmuch-hello-first-run t
 239   "True if `notmuch-hello' is run for the first time, set to nil
 240 afterwards.")
 241
 242 (defun notmuch-hello-nice-number (n)
 243   (let (result)
 244     (while (> n 0)
 245       (push (% n 1000) result)
 246       (setq n (/ n 1000)))
 247     (setq result (or result '(0)))
 248     (apply #'concat
 249      (number-to-string (car result))
 250      (mapcar (lambda (elem)
 251               (format "%s%03d" notmuch-hello-thousands-separator elem))
 252              (cdr result)))))
 253
 254 (defun notmuch-hello-trim (search)
 255   "Trim whitespace."
 256   (if (string-match "^[[:space:]]*\\(.*[^[:space:]]\\)[[:space:]]*$" search)
 257       (match-string 1 search)
 258     search))
 259
 260 (defun notmuch-hello-search (&optional search)
 261   (interactive)
 262   (unless (null search)
 263     (setq search (notmuch-hello-trim search))
 264     (let ((history-delete-duplicates t))
 265       (add-to-history 'notmuch-search-history search)))
 266   (notmuch-search search notmuch-search-oldest-first nil nil
 267                   #'notmuch-hello-search-continuation))
 268
 269 (defun notmuch-hello-add-saved-search (widget)
 270   (interactive)
 271   (let ((search (widget-value
 272                  (symbol-value
 273                   (widget-get widget :notmuch-saved-search-widget))))
 274         (name (completing-read "Name for saved search: "
 275                                notmuch-saved-searches)))
 276     ;; If an existing saved search with this name exists, remove it.
 277     (setq notmuch-saved-searches
 278           (loop for elem in notmuch-saved-searches
 279                 if (not (equal name
 280                                (car elem)))
 281                 collect elem))
 282     ;; Add the new one.
 283     (customize-save-variable 'notmuch-saved-searches
 284                              (add-to-list 'notmuch-saved-searches
 285                                           (cons name search) t))
 286     (message "Saved '%s' as '%s'." search name)
 287     (notmuch-hello-update)))
 288
 289 (defun notmuch-hello-delete-search-from-history (widget)
 290   (interactive)
 291   (let ((search (widget-value
 292                  (symbol-value
 293                   (widget-get widget :notmuch-saved-search-widget)))))
 294     (setq notmuch-search-history (delete search
 295                                          notmuch-search-history))
 296     (notmuch-hello-update)))
 297
 298 (defun notmuch-hello-longest-label (searches-alist)
 299   (or (loop for elem in searches-alist
 300             maximize (length (car elem)))
 301       0))
 302
 303 (defun notmuch-hello-reflect-generate-row (ncols nrows row list)
 304   (let ((len (length list)))
 305     (loop for col from 0 to (- ncols 1)
 306           collect (let ((offset (+ (* nrows col) row)))
 307                     (if (< offset len)
 308                         (nth offset list)
 309                       ;; Don't forget to insert an empty slot in the
 310                       ;; output matrix if there is no corresponding
 311                       ;; value in the input matrix.
 312                       nil)))))
 313
 314 (defun notmuch-hello-reflect (list ncols)
 315   "Reflect a `ncols' wide matrix represented by `list' along the
 316 diagonal."
 317   ;; Not very lispy...
 318   (let ((nrows (ceiling (length list) ncols)))
 319     (loop for row from 0 to (- nrows 1)
 320           append (notmuch-hello-reflect-generate-row ncols nrows row list))))
 321
 322 (defun notmuch-hello-widget-search (widget &rest ignore)
 323   (notmuch-search (widget-get widget
 324                               :notmuch-search-terms)
 325                   notmuch-search-oldest-first
 326                   nil nil #'notmuch-hello-search-continuation))
 327
 328 (defun notmuch-saved-search-count (search)
 329   (car (process-lines notmuch-command "count" search)))
 330
 331 (defun notmuch-hello-tags-per-line (widest)
 332   "Determine how many tags to show per line and how wide they
 333 should be. Returns a cons cell `(tags-per-line width)'."
 334   (let ((tags-per-line
 335          (cond
 336           ((integerp notmuch-column-control)
 337            (max 1
 338                 (/ (- (window-width) notmuch-hello-indent)
 339                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 340                    ;; after the name.
 341                    (+ 9 1 (max notmuch-column-control widest)))))
 342
 343           ((floatp notmuch-column-control)
 344            (let* ((available-width (- (window-width) notmuch-hello-indent))
 345                   (proposed-width (max (* available-width notmuch-column-control) widest)))
 346              (floor available-width proposed-width)))
 347
 348           (t
 349            (max 1
 350                 (/ (- (window-width) notmuch-hello-indent)
 351                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 352                    ;; after the name.
 353                    (+ 9 1 widest)))))))
 354
 355     (cons tags-per-line (/ (max 1
 356                                 (- (window-width) notmuch-hello-indent
 357                                    ;; Count is 9 wide (8 digits plus
 358                                    ;; space), 1 for the space after the
 359                                    ;; name.
 360                                    (* tags-per-line (+ 9 1))))
 361                            tags-per-line))))
 362
 363 (defun notmuch-hello-filtered-query (query filter)
 364   "Constructs a query to search all messages matching QUERY and FILTER.
 365
 366 If FILTER is a string, it is directly used in the returned query.
 367
 368 If FILTER is a function, it is called with QUERY as a parameter and
 369 the string it returns is used as the query. If nil is returned,
 370 the entry is hidden.
 371
 372 Otherwise, FILTER is ignored.
 373 "
 374   (cond
 375    ((functionp filter) (funcall filter query))
 376    ((stringp filter)
 377     (concat "(" query ") and (" filter ")"))
 378    (t query)))
 379
 380 (defun notmuch-hello-query-counts (query-alist &rest options)
 381   "Compute list of counts of matched messages from QUERY-ALIST.
 382
 383 QUERY-ALIST must be a list containing elements of the form (NAME . QUERY)
 384 or (NAME QUERY COUNT-QUERY). If the latter form is used,
 385 COUNT-QUERY specifies an alternate query to be used to generate
 386 the count for the associated query.
 387
 388 The result is the list of elements of the form (NAME QUERY COUNT).
 389
 390 The values :show-empty-searches, :filter and :filter-count from
 391 options will be handled as specified for
 392 `notmuch-hello-insert-searches'."
 393   (with-temp-buffer
 394     (dolist (elem query-alist nil)
 395       (let ((count-query (if (consp (cdr elem))
 396                              ;; do we have a different query for the message count?
 397                              (third elem)
 398                            (cdr elem))))
 399         (insert
 400          (notmuch-hello-filtered-query count-query
 401                                        (or (plist-get options :filter-count)
 402                                            (plist-get options :filter)))
 403          "\n")))
 404
 405     (call-process-region (point-min) (point-max) notmuch-command
 406                          t t nil "count" "--batch")
 407     (goto-char (point-min))
 408
 409     (notmuch-remove-if-not
 410      #'identity
 411      (mapcar
 412       (lambda (elem)
 413         (let ((name (car elem))
 414               (search-query (if (consp (cdr elem))
 415                                  ;; do we have a different query for the message count?
 416                                  (second elem)
 417                               (cdr elem)))
 418               (message-count (prog1 (read (current-buffer))
 419                                 (forward-line 1))))
 420           (and (or (plist-get options :show-empty-searches) (> message-count 0))
 421                (list name (notmuch-hello-filtered-query
 422                            search-query (plist-get options :filter))
 423                      message-count))))
 424       query-alist))))
 425
 426 (defun notmuch-hello-insert-buttons (searches)
 427   "Insert buttons for SEARCHES.
 428
 429 SEARCHES must be a list containing lists of the form (NAME QUERY COUNT), where
 430 QUERY is the query to start when the button for the corresponding entry is
 431 activated. COUNT should be the number of messages matching the query.
 432 Such a list can be computed with `notmuch-hello-query-counts'."
 433   (let* ((widest (notmuch-hello-longest-label searches))
 434          (tags-and-width (notmuch-hello-tags-per-line widest))
 435          (tags-per-line (car tags-and-width))
 436          (column-width (cdr tags-and-width))
 437          (column-indent 0)
 438          (count 0)
 439          (reordered-list (notmuch-hello-reflect searches tags-per-line))
 440          ;; Hack the display of the buttons used.
 441          (widget-push-button-prefix "")
 442          (widget-push-button-suffix ""))
 443     ;; dme: It feels as though there should be a better way to
 444     ;; implement this loop than using an incrementing counter.
 445     (mapc (lambda (elem)
 446             ;; (not elem) indicates an empty slot in the matrix.
 447             (when elem
 448               (if (> column-indent 0)
 449                   (widget-insert (make-string column-indent ? )))
 450               (let* ((name (first elem))
 451                      (query (second elem))
 452                      (msg-count (third elem)))
 453                 (widget-insert (format "%8s "
 454                                        (notmuch-hello-nice-number msg-count)))
 455                 (widget-create 'push-button
 456                                :notify #'notmuch-hello-widget-search
 457                                :notmuch-search-terms query
 458                                name)
 459                 (setq column-indent
 460                       (1+ (max 0 (- column-width (length name)))))))
 461             (setq count (1+ count))
 462             (when (eq (% count tags-per-line) 0)
 463               (setq column-indent 0)
 464               (widget-insert "\n")))
 465           reordered-list)
 466
 467     ;; If the last line was not full (and hence did not include a
 468     ;; carriage return), insert one now.
 469     (unless (eq (% count tags-per-line) 0)
 470       (widget-insert "\n"))))
 471
 472 (defimage notmuch-hello-logo ((:type png :file "notmuch-logo.png")))
 473
 474 (defun notmuch-hello-search-continuation()
 475   (notmuch-hello-update t))
 476
 477 (defun notmuch-hello-update (&optional no-display)
 478   "Update the current notmuch view."
 479   ;; Lazy - rebuild everything.
 480   (interactive)
 481   (notmuch-hello no-display))
 482
 483 (defun notmuch-hello-poll-and-update ()
 484   "Invoke `notmuch-poll' to import mail, then refresh the current view."
 485   (interactive)
 486   (notmuch-poll)
 487   (notmuch-hello-update))
 488
 489
 490 (defvar notmuch-hello-mode-map
 491   (let ((map (make-sparse-keymap)))
 492     (set-keymap-parent map widget-keymap)
 493     (define-key map "v" (lambda () "Display the notmuch version" (interactive)
 494                           (message "notmuch version %s" (notmuch-version))))
 495     (define-key map "?" 'notmuch-help)
 496     (define-key map "q" 'notmuch-kill-this-buffer)
 497     (define-key map "=" 'notmuch-hello-update)
 498     (define-key map "G" 'notmuch-hello-poll-and-update)
 499     (define-key map (kbd "<C-tab>") 'widget-backward)
 500     (define-key map "m" 'notmuch-mua-new-mail)
 501     (define-key map "s" 'notmuch-hello-search)
 502     map)
 503   "Keymap for \"notmuch hello\" buffers.")
 504 (fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
 505
 506 (defun notmuch-hello-mode ()
 507  "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
 508
 509 Complete list of currently available key bindings:
 510
 511 \\{notmuch-hello-mode-map}"
 512  (interactive)
 513  (kill-all-local-variables)
 514  (use-local-map notmuch-hello-mode-map)
 515  (setq major-mode 'notmuch-hello-mode
 516         mode-name "notmuch-hello")
 517  (run-mode-hooks 'notmuch-hello-mode-hook)
 518  ;;(setq buffer-read-only t)
 519 )
 520
 521 (defun notmuch-hello-generate-tag-alist (&optional hide-tags)
 522   "Return an alist from tags to queries to display in the all-tags section."
 523   (mapcar (lambda (tag)
 524             (cons tag (concat "tag:" (notmuch-escape-boolean-term tag))))
 525           (notmuch-remove-if-not
 526            (lambda (tag)
 527              (not (member tag hide-tags)))
 528            (process-lines notmuch-command "search" "--output=tags" "*"))))
 529
 530 (defun notmuch-hello-insert-header ()
 531   "Insert the default notmuch-hello header."
 532   (when notmuch-show-logo
 533     (let ((image notmuch-hello-logo))
 534       ;; The notmuch logo uses transparency. That can display poorly
 535       ;; when inserting the image into an emacs buffer (black logo on
 536       ;; a black background), so force the background colour of the
 537       ;; image. We use a face to represent the colour so that
 538       ;; `defface' can be used to declare the different possible
 539       ;; colours, which depend on whether the frame has a light or
 540       ;; dark background.
 541       (setq image (cons 'image
 542                         (append (cdr image)
 543                                 (list :background (face-background 'notmuch-hello-logo-background)))))
 544       (insert-image image))
 545     (widget-insert "  "))
 546
 547   (widget-insert "Welcome to ")
 548   ;; Hack the display of the links used.
 549   (let ((widget-link-prefix "")
 550         (widget-link-suffix ""))
 551     (widget-create 'link
 552                    :notify (lambda (&rest ignore)
 553                              (browse-url notmuch-hello-url))
 554                    :help-echo "Visit the notmuch website."
 555                    "notmuch")
 556     (widget-insert ". ")
 557     (widget-insert "You have ")
 558     (widget-create 'link
 559                    :notify (lambda (&rest ignore)
 560                              (notmuch-hello-update))
 561                    :help-echo "Refresh"
 562                    (notmuch-hello-nice-number
 563                     (string-to-number (car (process-lines notmuch-command "count")))))
 564     (widget-insert " messages.\n")))
 565
 566
 567 (defun notmuch-hello-insert-saved-searches ()
 568   "Insert the saved-searches section."
 569   (let ((searches (notmuch-hello-query-counts
 570                    (if notmuch-saved-search-sort-function
 571                        (funcall notmuch-saved-search-sort-function
 572                                 notmuch-saved-searches)
 573                      notmuch-saved-searches)
 574                    :show-empty-searches notmuch-show-empty-saved-searches)))
 575     (when searches
 576       (widget-insert "Saved searches: ")
 577       (widget-create 'push-button
 578                      :notify (lambda (&rest ignore)
 579                                (customize-variable 'notmuch-saved-searches))
 580                      "edit")
 581       (widget-insert "\n\n")
 582       (let ((start (point)))
 583         (notmuch-hello-insert-buttons searches)
 584         (indent-rigidly start (point) notmuch-hello-indent)))))
 585
 586 (defun notmuch-hello-insert-search ()
 587   "Insert a search widget."
 588   (widget-insert "Search: ")
 589   (widget-create 'editable-field
 590                  ;; Leave some space at the start and end of the
 591                  ;; search boxes.
 592                  :size (max 8 (- (window-width) notmuch-hello-indent
 593                                  (length "Search: ")))
 594                  :action (lambda (widget &rest ignore)
 595                            (notmuch-hello-search (widget-value widget))))
 596   ;; Add an invisible dot to make `widget-end-of-line' ignore
 597   ;; trailing spaces in the search widget field.  A dot is used
 598   ;; instead of a space to make `show-trailing-whitespace'
 599   ;; happy, i.e. avoid it marking the whole line as trailing
 600   ;; spaces.
 601   (widget-insert ".")
 602   (put-text-property (1- (point)) (point) 'invisible t)
 603   (widget-insert "\n"))
 604
 605 (defun notmuch-hello-insert-recent-searches ()
 606   "Insert recent searches."
 607   (when notmuch-search-history
 608     (widget-insert "Recent searches: ")
 609     (widget-create 'push-button
 610                    :notify (lambda (&rest ignore)
 611                              (when (y-or-n-p "Are you sure you want to clear the searches? ")
 612                                (setq notmuch-search-history nil)
 613                                (notmuch-hello-update)))
 614                    "clear")
 615     (widget-insert "\n\n")
 616     (let ((start (point)))
 617       (loop for i from 1 to notmuch-hello-recent-searches-max
 618             for search in notmuch-search-history do
 619             (let ((widget-symbol (intern (format "notmuch-hello-search-%d" i))))
 620               (set widget-symbol
 621                    (widget-create 'editable-field
 622                                   ;; Don't let the search boxes be
 623                                   ;; less than 8 characters wide.
 624                                   :size (max 8
 625                                              (- (window-width)
 626                                                 ;; Leave some space
 627                                                 ;; at the start and
 628                                                 ;; end of the
 629                                                 ;; boxes.
 630                                                 (* 2 notmuch-hello-indent)
 631                                                 ;; 1 for the space
 632                                                 ;; before the
 633                                                 ;; `[save]' button. 6
 634                                                 ;; for the `[save]'
 635                                                 ;; button.
 636                                                 1 6
 637                                                 ;; 1 for the space
 638                                                 ;; before the `[del]'
 639                                                 ;; button. 5 for the
 640                                                 ;; `[del]' button.
 641                                                 1 5))
 642                                   :action (lambda (widget &rest ignore)
 643                                             (notmuch-hello-search (widget-value widget)))
 644                                   search))
 645               (widget-insert " ")
 646               (widget-create 'push-button
 647                              :notify (lambda (widget &rest ignore)
 648                                        (notmuch-hello-add-saved-search widget))
 649                              :notmuch-saved-search-widget widget-symbol
 650                              "save")
 651               (widget-insert " ")
 652               (widget-create 'push-button
 653                              :notify (lambda (widget &rest ignore)
 654                                        (when (y-or-n-p "Are you sure you want to delete this search? ")
 655                                          (notmuch-hello-delete-search-from-history widget)))
 656                              :notmuch-saved-search-widget widget-symbol
 657                              "del"))
 658             (widget-insert "\n"))
 659       (indent-rigidly start (point) notmuch-hello-indent))
 660     nil))
 661
 662 (defun notmuch-hello-insert-searches (title query-alist &rest options)
 663   "Insert a section with TITLE showing a list of buttons made from QUERY-ALIST.
 664
 665 QUERY-ALIST must be a list containing elements of the form (NAME . QUERY)
 666 or (NAME QUERY COUNT-QUERY). If the latter form is used,
 667 COUNT-QUERY specifies an alternate query to be used to generate
 668 the count for the associated item.
 669
 670 Supports the following entries in OPTIONS as a plist:
 671 :initially-hidden - if non-nil, section will be hidden on startup
 672 :show-empty-searches - show buttons with no matching messages
 673 :hide-if-empty - hide if no buttons would be shown
 674    (only makes sense without :show-empty-searches)
 675 :filter - This can be a function that takes the search query as its argument and
 676    returns a filter to be used in conjuction with the query for that search or nil
 677    to hide the element. This can also be a string that is used as a combined with
 678    each query using \"and\".
 679 :filter-count - Separate filter to generate the count displayed each search. Accepts
 680    the same values as :filter. If :filter and :filter-count are specified, this
 681    will be used instead of :filter, not in conjunction with it."
 682   (widget-insert title ": ")
 683   (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
 684       (add-to-list 'notmuch-hello-hidden-sections title))
 685   (let ((is-hidden (member title notmuch-hello-hidden-sections))
 686         (start (point)))
 687     (if is-hidden
 688         (widget-create 'push-button
 689                        :notify `(lambda (widget &rest ignore)
 690                                   (setq notmuch-hello-hidden-sections
 691                                         (delete ,title notmuch-hello-hidden-sections))
 692                                   (notmuch-hello-update))
 693                        "show")
 694       (widget-create 'push-button
 695                      :notify `(lambda (widget &rest ignore)
 696                                 (add-to-list 'notmuch-hello-hidden-sections
 697                                              ,title)
 698                                 (notmuch-hello-update))
 699                      "hide"))
 700     (widget-insert "\n")
 701     (when (not is-hidden)
 702       (let ((searches (apply 'notmuch-hello-query-counts query-alist options)))
 703         (when (or (not (plist-get options :hide-if-empty))
 704                   searches)
 705           (widget-insert "\n")
 706           (notmuch-hello-insert-buttons searches)
 707           (indent-rigidly start (point) notmuch-hello-indent))))))
 708
 709 (defun notmuch-hello-insert-tags-section (&optional title &rest options)
 710   "Insert a section displaying all tags with message counts.
 711
 712 TITLE defaults to \"All tags\".
 713 Allowed options are those accepted by `notmuch-hello-insert-searches' and the
 714 following:
 715
 716 :hide-tags - List of tags that should be excluded."
 717   (apply 'notmuch-hello-insert-searches
 718          (or title "All tags")
 719          (notmuch-hello-generate-tag-alist (plist-get options :hide-tags))
 720          options))
 721
 722 (defun notmuch-hello-insert-inbox ()
 723   "Show an entry for each saved search and inboxed messages for each tag"
 724   (notmuch-hello-insert-searches "What's in your inbox"
 725                                  (append
 726                                   notmuch-saved-searches
 727                                   (notmuch-hello-generate-tag-alist))
 728                                  :filter "tag:inbox"))
 729
 730 (defun notmuch-hello-insert-alltags ()
 731   "Insert a section displaying all tags and associated message counts"
 732   (notmuch-hello-insert-tags-section
 733    nil
 734    :initially-hidden (not notmuch-show-all-tags-list)
 735    :hide-tags notmuch-hello-hide-tags
 736    :filter notmuch-hello-tag-list-make-query))
 737
 738 (defun notmuch-hello-insert-footer ()
 739   "Insert the notmuch-hello footer."
 740   (let ((start (point)))
 741     (widget-insert "Type a search query and hit RET to view matching threads.\n")
 742     (when notmuch-search-history
 743       (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
 744       (widget-insert "Save recent searches with the `save' button.\n"))
 745     (when notmuch-saved-searches
 746       (widget-insert "Edit saved searches with the `edit' button.\n"))
 747     (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
 748     (widget-insert "`=' to refresh this screen. `s' to search messages. `q' to quit.\n")
 749     (widget-create 'link
 750                    :notify (lambda (&rest ignore)
 751                              (customize-variable 'notmuch-hello-sections))
 752                    :button-prefix "" :button-suffix ""
 753                    "Customize")
 754     (widget-insert " this page.")
 755     (let ((fill-column (- (window-width) notmuch-hello-indent)))
 756       (center-region start (point)))))
 757
 758 ;;;###autoload
 759 (defun notmuch-hello (&optional no-display)
 760   "Run notmuch and display saved searches, known tags, etc."
 761   (interactive)
 762
 763   (if no-display
 764       (set-buffer "*notmuch-hello*")
 765     (switch-to-buffer "*notmuch-hello*"))
 766
 767   (let ((target-line (line-number-at-pos))
 768         (target-column (current-column))
 769         (inhibit-read-only t))
 770
 771     ;; Delete all editable widget fields.  Editable widget fields are
 772     ;; tracked in a buffer local variable `widget-field-list' (and
 773     ;; others).  If we do `erase-buffer' without properly deleting the
 774     ;; widgets, some widget-related functions are confused later.
 775     (mapc 'widget-delete widget-field-list)
 776
 777     (erase-buffer)
 778
 779     (unless (eq major-mode 'notmuch-hello-mode)
 780       (notmuch-hello-mode))
 781
 782     (let ((all (overlay-lists)))
 783       ;; Delete all the overlays.
 784       (mapc 'delete-overlay (car all))
 785       (mapc 'delete-overlay (cdr all)))
 786
 787     (mapc
 788      (lambda (section)
 789        (let ((point-before (point)))
 790          (if (functionp section)
 791              (funcall section)
 792            (apply (car section) (cdr section)))
 793          ;; don't insert a newline when the previous section didn't
 794          ;; show anything.
 795          (unless (eq (point) point-before)
 796            (widget-insert "\n"))))
 797      notmuch-hello-sections)
 798     (widget-setup)
 799
 800     ;; Move point back to where it was before refresh. Use line and
 801     ;; column instead of point directly to be insensitive to additions
 802     ;; and removals of text within earlier lines.
 803     (goto-char (point-min))
 804     (forward-line (1- target-line))
 805     (move-to-column target-column))
 806   (run-hooks 'notmuch-hello-refresh-hook)
 807   (setq notmuch-hello-first-run nil))
 808
 809 (defun notmuch-folder ()
 810   "Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
 811   (interactive)
 812   (notmuch-hello))
 813
 814 ;;
 815
 816 (provide 'notmuch-hello)