git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-hello.el

   1 ;; notmuch-hello.el --- welcome to notmuch, a frontend
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (eval-when-compile (require 'cl))
  23 (require 'widget)
  24 (require 'wid-edit) ; For `widget-forward'.
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-mua)
  28
  29 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line continuation))
  30 (declare-function notmuch-poll "notmuch" ())
  31
  32 (defcustom notmuch-hello-recent-searches-max 10
  33   "The number of recent searches to display."
  34   :type 'integer
  35   :group 'notmuch-hello)
  36
  37 (defcustom notmuch-show-empty-saved-searches nil
  38   "Should saved searches with no messages be listed?"
  39   :type 'boolean
  40   :group 'notmuch-hello)
  41
  42 (defun notmuch-sort-saved-searches (alist)
  43   "Generate an alphabetically sorted saved searches alist."
  44   (sort (copy-sequence alist) (lambda (a b) (string< (car a) (car b)))))
  45
  46 (defcustom notmuch-saved-search-sort-function nil
  47   "Function used to sort the saved searches for the notmuch-hello view.
  48
  49 This variable controls how saved searches should be sorted. No
  50 sorting (nil) displays the saved searches in the order they are
  51 stored in `notmuch-saved-searches'. Sort alphabetically sorts the
  52 saved searches in alphabetical order. Custom sort function should
  53 be a function or a lambda expression that takes the saved
  54 searches alist as a parameter, and returns a new saved searches
  55 alist to be used."
  56   :type '(choice (const :tag "No sorting" nil)
  57                  (const :tag "Sort alphabetically" notmuch-sort-saved-searches)
  58                  (function :tag "Custom sort function"
  59                            :value notmuch-sort-saved-searches))
  60   :group 'notmuch-hello)
  61
  62 (defvar notmuch-hello-indent 4
  63   "How much to indent non-headers.")
  64
  65 (defcustom notmuch-show-logo t
  66   "Should the notmuch logo be shown?"
  67   :type 'boolean
  68   :group 'notmuch-hello)
  69
  70 (defcustom notmuch-show-all-tags-list nil
  71   "Should all tags be shown in the notmuch-hello view?"
  72   :type 'boolean
  73   :group 'notmuch-hello)
  74
  75 (defcustom notmuch-hello-tag-list-make-query nil
  76   "Function or string to generate queries for the all tags list.
  77
  78 This variable controls which query results are shown for each tag
  79 in the \"all tags\" list. If nil, it will use all messages with
  80 that tag. If this is set to a string, it is used as a filter for
  81 messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
  82 Finally this can be a function that will be called for each tag and
  83 should return a filter for that tag, or nil to hide the tag."
  84   :type '(choice (const :tag "All messages" nil)
  85                  (const :tag "Unread messages" "tag:unread")
  86                  (string :tag "Custom filter"
  87                          :value "tag:unread")
  88                  (function :tag "Custom filter function"))
  89   :group 'notmuch-hello)
  90
  91 (defcustom notmuch-hello-hide-tags nil
  92   "List of tags to be hidden in the \"all tags\"-section."
  93   :type '(repeat string)
  94   :group 'notmuch-hello)
  95
  96 (defface notmuch-hello-logo-background
  97   '((((class color)
  98       (background dark))
  99      (:background "#5f5f5f"))
 100     (((class color)
 101       (background light))
 102      (:background "white")))
 103   "Background colour for the notmuch logo."
 104   :group 'notmuch-hello
 105   :group 'notmuch-faces)
 106
 107 (defcustom notmuch-column-control t
 108   "Controls the number of columns for saved searches/tags in notmuch view.
 109
 110 This variable has three potential sets of values:
 111
 112 - t: automatically calculate the number of columns possible based
 113   on the tags to be shown and the window width,
 114 - an integer: a lower bound on the number of characters that will
 115   be used to display each column,
 116 - a float: a fraction of the window width that is the lower bound
 117   on the number of characters that should be used for each
 118   column.
 119
 120 So:
 121 - if you would like two columns of tags, set this to 0.5.
 122 - if you would like a single column of tags, set this to 1.0.
 123 - if you would like tags to be 30 characters wide, set this to
 124   30.
 125 - if you don't want to worry about all of this nonsense, leave
 126   this set to `t'."
 127   :type '(choice
 128           (const :tag "Automatically calculated" t)
 129           (integer :tag "Number of characters")
 130           (float :tag "Fraction of window"))
 131   :group 'notmuch-hello)
 132
 133 (defcustom notmuch-hello-thousands-separator " "
 134   "The string used as a thousands separator.
 135
 136 Typically \",\" in the US and UK and \".\" or \" \" in Europe.
 137 The latter is recommended in the SI/ISO 31-0 standard and by the
 138 International Bureau of Weights and Measures."
 139   :type 'string
 140   :group 'notmuch-hello)
 141
 142 (defcustom notmuch-hello-mode-hook nil
 143   "Functions called after entering `notmuch-hello-mode'."
 144   :type 'hook
 145   :group 'notmuch-hello
 146   :group 'notmuch-hooks)
 147
 148 (defcustom notmuch-hello-refresh-hook nil
 149   "Functions called after updating a `notmuch-hello' buffer."
 150   :type 'hook
 151   :group 'notmuch-hello
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-hello-url "http://notmuchmail.org"
 155   "The `notmuch' web site.")
 156
 157 (defvar notmuch-hello-custom-section-options
 158   '((:filter (string :tag "Filter for each tag"))
 159     (:filter-count (string :tag "Different filter to generate message counts"))
 160     (:initially-hidden (const :tag "Hide this section on startup" t))
 161     (:show-empty-searches (const :tag "Show queries with no matching messages" t))
 162     (:hide-if-empty (const :tag "Hide this section if all queries are empty
 163 \(and not shown by show-empty-searches)" t)))
 164   "Various customization-options for notmuch-hello-tags/query-section.")
 165
 166 (define-widget 'notmuch-hello-tags-section 'lazy
 167   "Customize-type for notmuch-hello tag-list sections."
 168   :tag "Customized tag-list section (see docstring for details)"
 169   :type
 170   `(list :tag ""
 171          (const :tag "" notmuch-hello-insert-tags-section)
 172          (string :tag "Title for this section")
 173          (plist
 174           :inline t
 175           :options
 176           ,(append notmuch-hello-custom-section-options
 177                    '((:hide-tags (repeat :tag "Tags that will be hidden"
 178                                          string)))))))
 179
 180 (define-widget 'notmuch-hello-query-section 'lazy
 181   "Customize-type for custom saved-search-like sections"
 182   :tag "Customized queries section (see docstring for details)"
 183   :type
 184   `(list :tag ""
 185          (const :tag "" notmuch-hello-insert-searches)
 186          (string :tag "Title for this section")
 187          (repeat :tag "Queries"
 188                  (cons (string :tag "Name") (string :tag "Query")))
 189          (plist :inline t :options ,notmuch-hello-custom-section-options)))
 190
 191 (defcustom notmuch-hello-sections
 192   (list #'notmuch-hello-insert-header
 193         #'notmuch-hello-insert-saved-searches
 194         #'notmuch-hello-insert-search
 195         #'notmuch-hello-insert-recent-searches
 196         #'notmuch-hello-insert-alltags
 197         #'notmuch-hello-insert-footer)
 198   "Sections for notmuch-hello.
 199
 200 The list contains functions which are used to construct sections in
 201 notmuch-hello buffer.  When notmuch-hello buffer is constructed,
 202 these functions are run in the order they appear in this list.  Each
 203 function produces a section simply by adding content to the current
 204 buffer.  A section should not end with an empty line, because a
 205 newline will be inserted after each section by `notmuch-hello'.
 206
 207 Each function should take no arguments. The return value is
 208 ignored.
 209
 210 For convenience an element can also be a list of the form (FUNC ARG1
 211 ARG2 .. ARGN) in which case FUNC will be applied to the rest of the
 212 list.
 213
 214 A \"Customized tag-list section\" item in the customize-interface
 215 displays a list of all tags, optionally hiding some of them. It
 216 is also possible to filter the list of messages matching each tag
 217 by an additional filter query. Similarly, the count of messages
 218 displayed next to the buttons can be generated by applying a
 219 different filter to the tag query. These filters are also
 220 supported for \"Customized queries section\" items."
 221   :group 'notmuch-hello
 222   :type
 223   '(repeat
 224     (choice (function-item notmuch-hello-insert-header)
 225             (function-item notmuch-hello-insert-saved-searches)
 226             (function-item notmuch-hello-insert-search)
 227             (function-item notmuch-hello-insert-recent-searches)
 228             (function-item notmuch-hello-insert-alltags)
 229             (function-item notmuch-hello-insert-footer)
 230             (function-item notmuch-hello-insert-inbox)
 231             notmuch-hello-tags-section
 232             notmuch-hello-query-section
 233             (function :tag "Custom section"))))
 234
 235 (defcustom notmuch-hello-auto-refresh t
 236   "Automatically refresh when returning to the notmuch-hello buffer."
 237   :group 'notmuch-hello
 238   :type 'boolean)
 239
 240 (defvar notmuch-hello-hidden-sections nil
 241   "List of sections titles whose contents are hidden")
 242
 243 (defvar notmuch-hello-first-run t
 244   "True if `notmuch-hello' is run for the first time, set to nil
 245 afterwards.")
 246
 247 (defun notmuch-hello-nice-number (n)
 248   (let (result)
 249     (while (> n 0)
 250       (push (% n 1000) result)
 251       (setq n (/ n 1000)))
 252     (setq result (or result '(0)))
 253     (apply #'concat
 254      (number-to-string (car result))
 255      (mapcar (lambda (elem)
 256               (format "%s%03d" notmuch-hello-thousands-separator elem))
 257              (cdr result)))))
 258
 259 (defun notmuch-hello-trim (search)
 260   "Trim whitespace."
 261   (if (string-match "^[[:space:]]*\\(.*[^[:space:]]\\)[[:space:]]*$" search)
 262       (match-string 1 search)
 263     search))
 264
 265 (defun notmuch-hello-search (&optional search)
 266   (unless (null search)
 267     (setq search (notmuch-hello-trim search))
 268     (let ((history-delete-duplicates t))
 269       (add-to-history 'notmuch-search-history search)))
 270   (notmuch-search search notmuch-search-oldest-first))
 271
 272 (defun notmuch-hello-add-saved-search (widget)
 273   (interactive)
 274   (let ((search (widget-value
 275                  (symbol-value
 276                   (widget-get widget :notmuch-saved-search-widget))))
 277         (name (completing-read "Name for saved search: "
 278                                notmuch-saved-searches)))
 279     ;; If an existing saved search with this name exists, remove it.
 280     (setq notmuch-saved-searches
 281           (loop for elem in notmuch-saved-searches
 282                 if (not (equal name
 283                                (car elem)))
 284                 collect elem))
 285     ;; Add the new one.
 286     (customize-save-variable 'notmuch-saved-searches
 287                              (add-to-list 'notmuch-saved-searches
 288                                           (cons name search) t))
 289     (message "Saved '%s' as '%s'." search name)
 290     (notmuch-hello-update)))
 291
 292 (defun notmuch-hello-delete-search-from-history (widget)
 293   (interactive)
 294   (let ((search (widget-value
 295                  (symbol-value
 296                   (widget-get widget :notmuch-saved-search-widget)))))
 297     (setq notmuch-search-history (delete search
 298                                          notmuch-search-history))
 299     (notmuch-hello-update)))
 300
 301 (defun notmuch-hello-longest-label (searches-alist)
 302   (or (loop for elem in searches-alist
 303             maximize (length (car elem)))
 304       0))
 305
 306 (defun notmuch-hello-reflect-generate-row (ncols nrows row list)
 307   (let ((len (length list)))
 308     (loop for col from 0 to (- ncols 1)
 309           collect (let ((offset (+ (* nrows col) row)))
 310                     (if (< offset len)
 311                         (nth offset list)
 312                       ;; Don't forget to insert an empty slot in the
 313                       ;; output matrix if there is no corresponding
 314                       ;; value in the input matrix.
 315                       nil)))))
 316
 317 (defun notmuch-hello-reflect (list ncols)
 318   "Reflect a `ncols' wide matrix represented by `list' along the
 319 diagonal."
 320   ;; Not very lispy...
 321   (let ((nrows (ceiling (length list) ncols)))
 322     (loop for row from 0 to (- nrows 1)
 323           append (notmuch-hello-reflect-generate-row ncols nrows row list))))
 324
 325 (defun notmuch-hello-widget-search (widget &rest ignore)
 326   (notmuch-search (widget-get widget
 327                               :notmuch-search-terms)
 328                   notmuch-search-oldest-first))
 329
 330 (defun notmuch-saved-search-count (search)
 331   (car (process-lines notmuch-command "count" search)))
 332
 333 (defun notmuch-hello-tags-per-line (widest)
 334   "Determine how many tags to show per line and how wide they
 335 should be. Returns a cons cell `(tags-per-line width)'."
 336   (let ((tags-per-line
 337          (cond
 338           ((integerp notmuch-column-control)
 339            (max 1
 340                 (/ (- (window-width) notmuch-hello-indent)
 341                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 342                    ;; after the name.
 343                    (+ 9 1 (max notmuch-column-control widest)))))
 344
 345           ((floatp notmuch-column-control)
 346            (let* ((available-width (- (window-width) notmuch-hello-indent))
 347                   (proposed-width (max (* available-width notmuch-column-control) widest)))
 348              (floor available-width proposed-width)))
 349
 350           (t
 351            (max 1
 352                 (/ (- (window-width) notmuch-hello-indent)
 353                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 354                    ;; after the name.
 355                    (+ 9 1 widest)))))))
 356
 357     (cons tags-per-line (/ (max 1
 358                                 (- (window-width) notmuch-hello-indent
 359                                    ;; Count is 9 wide (8 digits plus
 360                                    ;; space), 1 for the space after the
 361                                    ;; name.
 362                                    (* tags-per-line (+ 9 1))))
 363                            tags-per-line))))
 364
 365 (defun notmuch-hello-filtered-query (query filter)
 366   "Constructs a query to search all messages matching QUERY and FILTER.
 367
 368 If FILTER is a string, it is directly used in the returned query.
 369
 370 If FILTER is a function, it is called with QUERY as a parameter and
 371 the string it returns is used as the query. If nil is returned,
 372 the entry is hidden.
 373
 374 Otherwise, FILTER is ignored.
 375 "
 376   (cond
 377    ((functionp filter) (funcall filter query))
 378    ((stringp filter)
 379     (concat "(" query ") and (" filter ")"))
 380    (t query)))
 381
 382 (defun notmuch-hello-query-counts (query-alist &rest options)
 383   "Compute list of counts of matched messages from QUERY-ALIST.
 384
 385 QUERY-ALIST must be a list containing elements of the form (NAME . QUERY)
 386 or (NAME QUERY COUNT-QUERY). If the latter form is used,
 387 COUNT-QUERY specifies an alternate query to be used to generate
 388 the count for the associated query.
 389
 390 The result is the list of elements of the form (NAME QUERY COUNT).
 391
 392 The values :show-empty-searches, :filter and :filter-count from
 393 options will be handled as specified for
 394 `notmuch-hello-insert-searches'."
 395   (with-temp-buffer
 396     (dolist (elem query-alist nil)
 397       (let ((count-query (if (consp (cdr elem))
 398                              ;; do we have a different query for the message count?
 399                              (third elem)
 400                            (cdr elem))))
 401         (insert
 402          (notmuch-hello-filtered-query count-query
 403                                        (or (plist-get options :filter-count)
 404                                            (plist-get options :filter)))
 405          "\n")))
 406
 407     (unless (= (call-process-region (point-min) (point-max) notmuch-command
 408                                     t t nil "count" "--batch") 0)
 409       (notmuch-logged-error "notmuch count --batch failed"
 410                             "Please check that the notmuch CLI is new enough to support `count
 411 --batch'. In general we recommend running matching versions of
 412 the CLI and emacs interface."))
 413
 414     (goto-char (point-min))
 415
 416     (notmuch-remove-if-not
 417      #'identity
 418      (mapcar
 419       (lambda (elem)
 420         (let ((name (car elem))
 421               (search-query (if (consp (cdr elem))
 422                                  ;; do we have a different query for the message count?
 423                                  (second elem)
 424                               (cdr elem)))
 425               (message-count (prog1 (read (current-buffer))
 426                                 (forward-line 1))))
 427           (and (or (plist-get options :show-empty-searches) (> message-count 0))
 428                (list name (notmuch-hello-filtered-query
 429                            search-query (plist-get options :filter))
 430                      message-count))))
 431       query-alist))))
 432
 433 (defun notmuch-hello-insert-buttons (searches)
 434   "Insert buttons for SEARCHES.
 435
 436 SEARCHES must be a list containing lists of the form (NAME QUERY COUNT), where
 437 QUERY is the query to start when the button for the corresponding entry is
 438 activated. COUNT should be the number of messages matching the query.
 439 Such a list can be computed with `notmuch-hello-query-counts'."
 440   (let* ((widest (notmuch-hello-longest-label searches))
 441          (tags-and-width (notmuch-hello-tags-per-line widest))
 442          (tags-per-line (car tags-and-width))
 443          (column-width (cdr tags-and-width))
 444          (column-indent 0)
 445          (count 0)
 446          (reordered-list (notmuch-hello-reflect searches tags-per-line))
 447          ;; Hack the display of the buttons used.
 448          (widget-push-button-prefix "")
 449          (widget-push-button-suffix ""))
 450     ;; dme: It feels as though there should be a better way to
 451     ;; implement this loop than using an incrementing counter.
 452     (mapc (lambda (elem)
 453             ;; (not elem) indicates an empty slot in the matrix.
 454             (when elem
 455               (if (> column-indent 0)
 456                   (widget-insert (make-string column-indent ? )))
 457               (let* ((name (first elem))
 458                      (query (second elem))
 459                      (msg-count (third elem)))
 460                 (widget-insert (format "%8s "
 461                                        (notmuch-hello-nice-number msg-count)))
 462                 (widget-create 'push-button
 463                                :notify #'notmuch-hello-widget-search
 464                                :notmuch-search-terms query
 465                                name)
 466                 (setq column-indent
 467                       (1+ (max 0 (- column-width (length name)))))))
 468             (setq count (1+ count))
 469             (when (eq (% count tags-per-line) 0)
 470               (setq column-indent 0)
 471               (widget-insert "\n")))
 472           reordered-list)
 473
 474     ;; If the last line was not full (and hence did not include a
 475     ;; carriage return), insert one now.
 476     (unless (eq (% count tags-per-line) 0)
 477       (widget-insert "\n"))))
 478
 479 (defimage notmuch-hello-logo ((:type png :file "notmuch-logo.png")))
 480
 481 (defun notmuch-hello-update (&optional no-display)
 482   "Update the current notmuch view."
 483   ;; Lazy - rebuild everything.
 484   (notmuch-hello no-display))
 485
 486 (defun notmuch-hello-window-configuration-change ()
 487   "Hook function to update the hello buffer when it is switched to."
 488   (let ((hello-buf (get-buffer "*notmuch-hello*"))
 489         (do-refresh nil))
 490     ;; Consider all windows in the currently selected frame, since
 491     ;; that's where the configuration change happened.  This also
 492     ;; refreshes our snapshot of all windows, so we have to do this
 493     ;; even if we know we won't refresh (e.g., hello-buf is null).
 494     (dolist (window (window-list))
 495       (let ((last-buf (window-parameter window 'notmuch-hello-last-buffer))
 496             (cur-buf (window-buffer window)))
 497         (when (not (eq last-buf cur-buf))
 498           ;; This window changed or is new.  Update recorded buffer
 499           ;; for next time.
 500           (set-window-parameter window 'notmuch-hello-last-buffer cur-buf)
 501           (when (and (eq cur-buf hello-buf) last-buf)
 502             ;; The user just switched to hello in this window (hello
 503             ;; is currently visible, was not visible on the last
 504             ;; configuration change, and this is not a new window)
 505             (setq do-refresh t)))))
 506     (when (and do-refresh notmuch-hello-auto-refresh)
 507       ;; Refresh hello as soon as we get back to redisplay.  On Emacs
 508       ;; 24, we can't do it right here because something in this
 509       ;; hook's call stack overrides hello's point placement.
 510       (run-at-time nil nil #'notmuch-hello t))
 511     (when (null hello-buf)
 512       ;; Clean up hook
 513       (remove-hook 'window-configuration-change-hook
 514                    #'notmuch-hello-window-configuration-change))))
 515
 516
 517 (defvar notmuch-hello-mode-map
 518   (let ((map (if (fboundp 'make-composed-keymap)
 519                  ;; Inherit both widget-keymap and notmuch-common-keymap
 520                  (make-composed-keymap widget-keymap)
 521                ;; Before Emacs 24, keymaps didn't support multiple
 522                ;; inheritance,, so just copy the widget keymap since
 523                ;; it's unlikely to change.
 524                (copy-keymap widget-keymap))))
 525     (set-keymap-parent map notmuch-common-keymap)
 526     (define-key map "v" (lambda () "Display the notmuch version" (interactive)
 527                           (message "notmuch version %s" (notmuch-version))))
 528     (define-key map (kbd "<C-tab>") 'widget-backward)
 529     map)
 530   "Keymap for \"notmuch hello\" buffers.")
 531 (fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
 532
 533 (defun notmuch-hello-mode ()
 534  "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
 535
 536 Complete list of currently available key bindings:
 537
 538 \\{notmuch-hello-mode-map}"
 539  (interactive)
 540  (kill-all-local-variables)
 541  (setq notmuch-buffer-refresh-function #'notmuch-hello-update)
 542  (use-local-map notmuch-hello-mode-map)
 543  (setq major-mode 'notmuch-hello-mode
 544         mode-name "notmuch-hello")
 545  (run-mode-hooks 'notmuch-hello-mode-hook)
 546  ;;(setq buffer-read-only t)
 547 )
 548
 549 (defun notmuch-hello-generate-tag-alist (&optional hide-tags)
 550   "Return an alist from tags to queries to display in the all-tags section."
 551   (mapcar (lambda (tag)
 552             (cons tag (concat "tag:" (notmuch-escape-boolean-term tag))))
 553           (notmuch-remove-if-not
 554            (lambda (tag)
 555              (not (member tag hide-tags)))
 556            (process-lines notmuch-command "search" "--output=tags" "*"))))
 557
 558 (defun notmuch-hello-insert-header ()
 559   "Insert the default notmuch-hello header."
 560   (when notmuch-show-logo
 561     (let ((image notmuch-hello-logo))
 562       ;; The notmuch logo uses transparency. That can display poorly
 563       ;; when inserting the image into an emacs buffer (black logo on
 564       ;; a black background), so force the background colour of the
 565       ;; image. We use a face to represent the colour so that
 566       ;; `defface' can be used to declare the different possible
 567       ;; colours, which depend on whether the frame has a light or
 568       ;; dark background.
 569       (setq image (cons 'image
 570                         (append (cdr image)
 571                                 (list :background (face-background 'notmuch-hello-logo-background)))))
 572       (insert-image image))
 573     (widget-insert "  "))
 574
 575   (widget-insert "Welcome to ")
 576   ;; Hack the display of the links used.
 577   (let ((widget-link-prefix "")
 578         (widget-link-suffix ""))
 579     (widget-create 'link
 580                    :notify (lambda (&rest ignore)
 581                              (browse-url notmuch-hello-url))
 582                    :help-echo "Visit the notmuch website."
 583                    "notmuch")
 584     (widget-insert ". ")
 585     (widget-insert "You have ")
 586     (widget-create 'link
 587                    :notify (lambda (&rest ignore)
 588                              (notmuch-hello-update))
 589                    :help-echo "Refresh"
 590                    (notmuch-hello-nice-number
 591                     (string-to-number (car (process-lines notmuch-command "count")))))
 592     (widget-insert " messages.\n")))
 593
 594
 595 (defun notmuch-hello-insert-saved-searches ()
 596   "Insert the saved-searches section."
 597   (let ((searches (notmuch-hello-query-counts
 598                    (if notmuch-saved-search-sort-function
 599                        (funcall notmuch-saved-search-sort-function
 600                                 notmuch-saved-searches)
 601                      notmuch-saved-searches)
 602                    :show-empty-searches notmuch-show-empty-saved-searches)))
 603     (when searches
 604       (widget-insert "Saved searches: ")
 605       (widget-create 'push-button
 606                      :notify (lambda (&rest ignore)
 607                                (customize-variable 'notmuch-saved-searches))
 608                      "edit")
 609       (widget-insert "\n\n")
 610       (let ((start (point)))
 611         (notmuch-hello-insert-buttons searches)
 612         (indent-rigidly start (point) notmuch-hello-indent)))))
 613
 614 (defun notmuch-hello-insert-search ()
 615   "Insert a search widget."
 616   (widget-insert "Search: ")
 617   (widget-create 'editable-field
 618                  ;; Leave some space at the start and end of the
 619                  ;; search boxes.
 620                  :size (max 8 (- (window-width) notmuch-hello-indent
 621                                  (length "Search: ")))
 622                  :action (lambda (widget &rest ignore)
 623                            (notmuch-hello-search (widget-value widget))))
 624   ;; Add an invisible dot to make `widget-end-of-line' ignore
 625   ;; trailing spaces in the search widget field.  A dot is used
 626   ;; instead of a space to make `show-trailing-whitespace'
 627   ;; happy, i.e. avoid it marking the whole line as trailing
 628   ;; spaces.
 629   (widget-insert ".")
 630   (put-text-property (1- (point)) (point) 'invisible t)
 631   (widget-insert "\n"))
 632
 633 (defun notmuch-hello-insert-recent-searches ()
 634   "Insert recent searches."
 635   (when notmuch-search-history
 636     (widget-insert "Recent searches: ")
 637     (widget-create 'push-button
 638                    :notify (lambda (&rest ignore)
 639                              (when (y-or-n-p "Are you sure you want to clear the searches? ")
 640                                (setq notmuch-search-history nil)
 641                                (notmuch-hello-update)))
 642                    "clear")
 643     (widget-insert "\n\n")
 644     (let ((start (point)))
 645       (loop for i from 1 to notmuch-hello-recent-searches-max
 646             for search in notmuch-search-history do
 647             (let ((widget-symbol (intern (format "notmuch-hello-search-%d" i))))
 648               (set widget-symbol
 649                    (widget-create 'editable-field
 650                                   ;; Don't let the search boxes be
 651                                   ;; less than 8 characters wide.
 652                                   :size (max 8
 653                                              (- (window-width)
 654                                                 ;; Leave some space
 655                                                 ;; at the start and
 656                                                 ;; end of the
 657                                                 ;; boxes.
 658                                                 (* 2 notmuch-hello-indent)
 659                                                 ;; 1 for the space
 660                                                 ;; before the
 661                                                 ;; `[save]' button. 6
 662                                                 ;; for the `[save]'
 663                                                 ;; button.
 664                                                 1 6
 665                                                 ;; 1 for the space
 666                                                 ;; before the `[del]'
 667                                                 ;; button. 5 for the
 668                                                 ;; `[del]' button.
 669                                                 1 5))
 670                                   :action (lambda (widget &rest ignore)
 671                                             (notmuch-hello-search (widget-value widget)))
 672                                   search))
 673               (widget-insert " ")
 674               (widget-create 'push-button
 675                              :notify (lambda (widget &rest ignore)
 676                                        (notmuch-hello-add-saved-search widget))
 677                              :notmuch-saved-search-widget widget-symbol
 678                              "save")
 679               (widget-insert " ")
 680               (widget-create 'push-button
 681                              :notify (lambda (widget &rest ignore)
 682                                        (when (y-or-n-p "Are you sure you want to delete this search? ")
 683                                          (notmuch-hello-delete-search-from-history widget)))
 684                              :notmuch-saved-search-widget widget-symbol
 685                              "del"))
 686             (widget-insert "\n"))
 687       (indent-rigidly start (point) notmuch-hello-indent))
 688     nil))
 689
 690 (defun notmuch-hello-insert-searches (title query-alist &rest options)
 691   "Insert a section with TITLE showing a list of buttons made from QUERY-ALIST.
 692
 693 QUERY-ALIST must be a list containing elements of the form (NAME . QUERY)
 694 or (NAME QUERY COUNT-QUERY). If the latter form is used,
 695 COUNT-QUERY specifies an alternate query to be used to generate
 696 the count for the associated item.
 697
 698 Supports the following entries in OPTIONS as a plist:
 699 :initially-hidden - if non-nil, section will be hidden on startup
 700 :show-empty-searches - show buttons with no matching messages
 701 :hide-if-empty - hide if no buttons would be shown
 702    (only makes sense without :show-empty-searches)
 703 :filter - This can be a function that takes the search query as its argument and
 704    returns a filter to be used in conjuction with the query for that search or nil
 705    to hide the element. This can also be a string that is used as a combined with
 706    each query using \"and\".
 707 :filter-count - Separate filter to generate the count displayed each search. Accepts
 708    the same values as :filter. If :filter and :filter-count are specified, this
 709    will be used instead of :filter, not in conjunction with it."
 710   (widget-insert title ": ")
 711   (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
 712       (add-to-list 'notmuch-hello-hidden-sections title))
 713   (let ((is-hidden (member title notmuch-hello-hidden-sections))
 714         (start (point)))
 715     (if is-hidden
 716         (widget-create 'push-button
 717                        :notify `(lambda (widget &rest ignore)
 718                                   (setq notmuch-hello-hidden-sections
 719                                         (delete ,title notmuch-hello-hidden-sections))
 720                                   (notmuch-hello-update))
 721                        "show")
 722       (widget-create 'push-button
 723                      :notify `(lambda (widget &rest ignore)
 724                                 (add-to-list 'notmuch-hello-hidden-sections
 725                                              ,title)
 726                                 (notmuch-hello-update))
 727                      "hide"))
 728     (widget-insert "\n")
 729     (when (not is-hidden)
 730       (let ((searches (apply 'notmuch-hello-query-counts query-alist options)))
 731         (when (or (not (plist-get options :hide-if-empty))
 732                   searches)
 733           (widget-insert "\n")
 734           (notmuch-hello-insert-buttons searches)
 735           (indent-rigidly start (point) notmuch-hello-indent))))))
 736
 737 (defun notmuch-hello-insert-tags-section (&optional title &rest options)
 738   "Insert a section displaying all tags with message counts.
 739
 740 TITLE defaults to \"All tags\".
 741 Allowed options are those accepted by `notmuch-hello-insert-searches' and the
 742 following:
 743
 744 :hide-tags - List of tags that should be excluded."
 745   (apply 'notmuch-hello-insert-searches
 746          (or title "All tags")
 747          (notmuch-hello-generate-tag-alist (plist-get options :hide-tags))
 748          options))
 749
 750 (defun notmuch-hello-insert-inbox ()
 751   "Show an entry for each saved search and inboxed messages for each tag"
 752   (notmuch-hello-insert-searches "What's in your inbox"
 753                                  (append
 754                                   notmuch-saved-searches
 755                                   (notmuch-hello-generate-tag-alist))
 756                                  :filter "tag:inbox"))
 757
 758 (defun notmuch-hello-insert-alltags ()
 759   "Insert a section displaying all tags and associated message counts"
 760   (notmuch-hello-insert-tags-section
 761    nil
 762    :initially-hidden (not notmuch-show-all-tags-list)
 763    :hide-tags notmuch-hello-hide-tags
 764    :filter notmuch-hello-tag-list-make-query))
 765
 766 (defun notmuch-hello-insert-footer ()
 767   "Insert the notmuch-hello footer."
 768   (let ((start (point)))
 769     (widget-insert "Type a search query and hit RET to view matching threads.\n")
 770     (when notmuch-search-history
 771       (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
 772       (widget-insert "Save recent searches with the `save' button.\n"))
 773     (when notmuch-saved-searches
 774       (widget-insert "Edit saved searches with the `edit' button.\n"))
 775     (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
 776     (widget-insert "`=' to refresh this screen. `s' to search messages. `q' to quit.\n")
 777     (widget-create 'link
 778                    :notify (lambda (&rest ignore)
 779                              (customize-variable 'notmuch-hello-sections))
 780                    :button-prefix "" :button-suffix ""
 781                    "Customize")
 782     (widget-insert " this page.")
 783     (let ((fill-column (- (window-width) notmuch-hello-indent)))
 784       (center-region start (point)))))
 785
 786 ;;;###autoload
 787 (defun notmuch-hello (&optional no-display)
 788   "Run notmuch and display saved searches, known tags, etc."
 789   (interactive)
 790
 791   ;; This may cause a window configuration change, so if the
 792   ;; auto-refresh hook is already installed, avoid recursive refresh.
 793   (let ((notmuch-hello-auto-refresh nil))
 794     (if no-display
 795         (set-buffer "*notmuch-hello*")
 796       (switch-to-buffer "*notmuch-hello*")))
 797
 798   ;; Install auto-refresh hook
 799   (when notmuch-hello-auto-refresh
 800     (add-hook 'window-configuration-change-hook
 801               #'notmuch-hello-window-configuration-change))
 802
 803   (let ((target-line (line-number-at-pos))
 804         (target-column (current-column))
 805         (inhibit-read-only t))
 806
 807     ;; Delete all editable widget fields.  Editable widget fields are
 808     ;; tracked in a buffer local variable `widget-field-list' (and
 809     ;; others).  If we do `erase-buffer' without properly deleting the
 810     ;; widgets, some widget-related functions are confused later.
 811     (mapc 'widget-delete widget-field-list)
 812
 813     (erase-buffer)
 814
 815     (unless (eq major-mode 'notmuch-hello-mode)
 816       (notmuch-hello-mode))
 817
 818     (let ((all (overlay-lists)))
 819       ;; Delete all the overlays.
 820       (mapc 'delete-overlay (car all))
 821       (mapc 'delete-overlay (cdr all)))
 822
 823     (mapc
 824      (lambda (section)
 825        (let ((point-before (point)))
 826          (if (functionp section)
 827              (funcall section)
 828            (apply (car section) (cdr section)))
 829          ;; don't insert a newline when the previous section didn't
 830          ;; show anything.
 831          (unless (eq (point) point-before)
 832            (widget-insert "\n"))))
 833      notmuch-hello-sections)
 834     (widget-setup)
 835
 836     ;; Move point back to where it was before refresh. Use line and
 837     ;; column instead of point directly to be insensitive to additions
 838     ;; and removals of text within earlier lines.
 839     (goto-char (point-min))
 840     (forward-line (1- target-line))
 841     (move-to-column target-column))
 842   (run-hooks 'notmuch-hello-refresh-hook)
 843   (setq notmuch-hello-first-run nil))
 844
 845 (defun notmuch-folder ()
 846   "Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
 847   (interactive)
 848   (notmuch-hello))
 849
 850 ;;
 851
 852 (provide 'notmuch-hello)