git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-hello.el

   1 ;; notmuch-hello.el --- welcome to notmuch, a frontend
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (eval-when-compile (require 'cl))
  23 (require 'widget)
  24 (require 'wid-edit) ; For `widget-forward'.
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-mua)
  28
  29 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line continuation))
  30 (declare-function notmuch-poll "notmuch" ())
  31
  32 (defcustom notmuch-hello-recent-searches-max 10
  33   "The number of recent searches to display."
  34   :type 'integer
  35   :group 'notmuch-hello)
  36
  37 (defcustom notmuch-show-empty-saved-searches nil
  38   "Should saved searches with no messages be listed?"
  39   :type 'boolean
  40   :group 'notmuch-hello)
  41
  42 (defun notmuch-sort-saved-searches (alist)
  43   "Generate an alphabetically sorted saved searches alist."
  44   (sort (copy-sequence alist) (lambda (a b) (string< (car a) (car b)))))
  45
  46 (defcustom notmuch-saved-search-sort-function nil
  47   "Function used to sort the saved searches for the notmuch-hello view.
  48
  49 This variable controls how saved searches should be sorted. No
  50 sorting (nil) displays the saved searches in the order they are
  51 stored in `notmuch-saved-searches'. Sort alphabetically sorts the
  52 saved searches in alphabetical order. Custom sort function should
  53 be a function or a lambda expression that takes the saved
  54 searches alist as a parameter, and returns a new saved searches
  55 alist to be used."
  56   :type '(choice (const :tag "No sorting" nil)
  57                  (const :tag "Sort alphabetically" notmuch-sort-saved-searches)
  58                  (function :tag "Custom sort function"
  59                            :value notmuch-sort-saved-searches))
  60   :group 'notmuch-hello)
  61
  62 (defvar notmuch-hello-indent 4
  63   "How much to indent non-headers.")
  64
  65 (defcustom notmuch-show-logo t
  66   "Should the notmuch logo be shown?"
  67   :type 'boolean
  68   :group 'notmuch-hello)
  69
  70 (defcustom notmuch-show-all-tags-list nil
  71   "Should all tags be shown in the notmuch-hello view?"
  72   :type 'boolean
  73   :group 'notmuch-hello)
  74
  75 (defcustom notmuch-hello-tag-list-make-query nil
  76   "Function or string to generate queries for the all tags list.
  77
  78 This variable controls which query results are shown for each tag
  79 in the \"all tags\" list. If nil, it will use all messages with
  80 that tag. If this is set to a string, it is used as a filter for
  81 messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
  82 Finally this can be a function that will be called for each tag and
  83 should return a filter for that tag, or nil to hide the tag."
  84   :type '(choice (const :tag "All messages" nil)
  85                  (const :tag "Unread messages" "tag:unread")
  86                  (string :tag "Custom filter"
  87                          :value "tag:unread")
  88                  (function :tag "Custom filter function"))
  89   :group 'notmuch-hello)
  90
  91 (defcustom notmuch-hello-hide-tags nil
  92   "List of tags to be hidden in the \"all tags\"-section."
  93   :type '(repeat string)
  94   :group 'notmuch-hello)
  95
  96 (defface notmuch-hello-logo-background
  97   '((((class color)
  98       (background dark))
  99      (:background "#5f5f5f"))
 100     (((class color)
 101       (background light))
 102      (:background "white")))
 103   "Background colour for the notmuch logo."
 104   :group 'notmuch-hello
 105   :group 'notmuch-faces)
 106
 107 (defcustom notmuch-column-control t
 108   "Controls the number of columns for saved searches/tags in notmuch view.
 109
 110 This variable has three potential sets of values:
 111
 112 - t: automatically calculate the number of columns possible based
 113   on the tags to be shown and the window width,
 114 - an integer: a lower bound on the number of characters that will
 115   be used to display each column,
 116 - a float: a fraction of the window width that is the lower bound
 117   on the number of characters that should be used for each
 118   column.
 119
 120 So:
 121 - if you would like two columns of tags, set this to 0.5.
 122 - if you would like a single column of tags, set this to 1.0.
 123 - if you would like tags to be 30 characters wide, set this to
 124   30.
 125 - if you don't want to worry about all of this nonsense, leave
 126   this set to `t'."
 127   :type '(choice
 128           (const :tag "Automatically calculated" t)
 129           (integer :tag "Number of characters")
 130           (float :tag "Fraction of window"))
 131   :group 'notmuch-hello)
 132
 133 (defcustom notmuch-hello-thousands-separator " "
 134   "The string used as a thousands separator.
 135
 136 Typically \",\" in the US and UK and \".\" or \" \" in Europe.
 137 The latter is recommended in the SI/ISO 31-0 standard and by the
 138 International Bureau of Weights and Measures."
 139   :type 'string
 140   :group 'notmuch-hello)
 141
 142 (defcustom notmuch-hello-mode-hook nil
 143   "Functions called after entering `notmuch-hello-mode'."
 144   :type 'hook
 145   :group 'notmuch-hello
 146   :group 'notmuch-hooks)
 147
 148 (defcustom notmuch-hello-refresh-hook nil
 149   "Functions called after updating a `notmuch-hello' buffer."
 150   :type 'hook
 151   :group 'notmuch-hello
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-hello-url "http://notmuchmail.org"
 155   "The `notmuch' web site.")
 156
 157 (defvar notmuch-hello-custom-section-options
 158   '((:filter (string :tag "Filter for each tag"))
 159     (:filter-count (string :tag "Different filter to generate message counts"))
 160     (:initially-hidden (const :tag "Hide this section on startup" t))
 161     (:show-empty-searches (const :tag "Show queries with no matching messages" t))
 162     (:hide-if-empty (const :tag "Hide this section if all queries are empty
 163 \(and not shown by show-empty-searches)" t)))
 164   "Various customization-options for notmuch-hello-tags/query-section.")
 165
 166 (define-widget 'notmuch-hello-tags-section 'lazy
 167   "Customize-type for notmuch-hello tag-list sections."
 168   :tag "Customized tag-list section (see docstring for details)"
 169   :type
 170   `(list :tag ""
 171          (const :tag "" notmuch-hello-insert-tags-section)
 172          (string :tag "Title for this section")
 173          (plist
 174           :inline t
 175           :options
 176           ,(append notmuch-hello-custom-section-options
 177                    '((:hide-tags (repeat :tag "Tags that will be hidden"
 178                                          string)))))))
 179
 180 (define-widget 'notmuch-hello-query-section 'lazy
 181   "Customize-type for custom saved-search-like sections"
 182   :tag "Customized queries section (see docstring for details)"
 183   :type
 184   `(list :tag ""
 185          (const :tag "" notmuch-hello-insert-searches)
 186          (string :tag "Title for this section")
 187          (repeat :tag "Queries"
 188                  (cons (string :tag "Name") (string :tag "Query")))
 189          (plist :inline t :options ,notmuch-hello-custom-section-options)))
 190
 191 (defcustom notmuch-hello-sections
 192   (list #'notmuch-hello-insert-header
 193         #'notmuch-hello-insert-saved-searches
 194         #'notmuch-hello-insert-search
 195         #'notmuch-hello-insert-recent-searches
 196         #'notmuch-hello-insert-alltags
 197         #'notmuch-hello-insert-footer)
 198   "Sections for notmuch-hello.
 199
 200 The list contains functions which are used to construct sections in
 201 notmuch-hello buffer.  When notmuch-hello buffer is constructed,
 202 these functions are run in the order they appear in this list.  Each
 203 function produces a section simply by adding content to the current
 204 buffer.  A section should not end with an empty line, because a
 205 newline will be inserted after each section by `notmuch-hello'.
 206
 207 Each function should take no arguments. The return value is
 208 ignored.
 209
 210 For convenience an element can also be a list of the form (FUNC ARG1
 211 ARG2 .. ARGN) in which case FUNC will be applied to the rest of the
 212 list.
 213
 214 A \"Customized tag-list section\" item in the customize-interface
 215 displays a list of all tags, optionally hiding some of them. It
 216 is also possible to filter the list of messages matching each tag
 217 by an additional filter query. Similarly, the count of messages
 218 displayed next to the buttons can be generated by applying a
 219 different filter to the tag query. These filters are also
 220 supported for \"Customized queries section\" items."
 221   :group 'notmuch-hello
 222   :type
 223   '(repeat
 224     (choice (function-item notmuch-hello-insert-header)
 225             (function-item notmuch-hello-insert-saved-searches)
 226             (function-item notmuch-hello-insert-search)
 227             (function-item notmuch-hello-insert-recent-searches)
 228             (function-item notmuch-hello-insert-alltags)
 229             (function-item notmuch-hello-insert-footer)
 230             (function-item notmuch-hello-insert-inbox)
 231             notmuch-hello-tags-section
 232             notmuch-hello-query-section
 233             (function :tag "Custom section"))))
 234
 235 (defcustom notmuch-hello-auto-refresh t
 236   "Automatically refresh when returning to the notmuch-hello buffer."
 237   :group 'notmuch-hello
 238   :type 'boolean)
 239
 240 (defvar notmuch-hello-hidden-sections nil
 241   "List of sections titles whose contents are hidden")
 242
 243 (defvar notmuch-hello-first-run t
 244   "True if `notmuch-hello' is run for the first time, set to nil
 245 afterwards.")
 246
 247 (defun notmuch-hello-nice-number (n)
 248   (let (result)
 249     (while (> n 0)
 250       (push (% n 1000) result)
 251       (setq n (/ n 1000)))
 252     (setq result (or result '(0)))
 253     (apply #'concat
 254      (number-to-string (car result))
 255      (mapcar (lambda (elem)
 256               (format "%s%03d" notmuch-hello-thousands-separator elem))
 257              (cdr result)))))
 258
 259 (defun notmuch-hello-trim (search)
 260   "Trim whitespace."
 261   (if (string-match "^[[:space:]]*\\(.*[^[:space:]]\\)[[:space:]]*$" search)
 262       (match-string 1 search)
 263     search))
 264
 265 (defun notmuch-hello-search (&optional search)
 266   (unless (null search)
 267     (setq search (notmuch-hello-trim search))
 268     (let ((history-delete-duplicates t))
 269       (add-to-history 'notmuch-search-history search)))
 270   (notmuch-search search notmuch-search-oldest-first))
 271
 272 (defun notmuch-saved-search-get (saved-search field)
 273   "Get FIELD from SAVED-SEARCH.
 274
 275 If SAVED-SEARCH is a plist, this is just `plist-get', but for
 276 backwards compatibility, this also deals with the two other
 277 possible formats for SAVED-SEARCH: cons cells (NAME . QUERY) and
 278 lists (NAME QUERY COUNT-QUERY)."
 279   (cond
 280    ((keywordp (car saved-search))
 281     (plist-get saved-search field))
 282    ;; It is not a plist so it is an old-style entry.
 283    ((consp (cdr saved-search)) ;; It is a list (NAME QUERY COUNT-QUERY)
 284     (case field
 285       (:name (first saved-search))
 286       (:query (second saved-search))
 287       (:count-query (third saved-search))
 288       (t nil)))
 289    (t  ;; It is a cons-cell (NAME . QUERY)
 290     (case field
 291       (:name (car saved-search))
 292       (:query (cdr saved-search))
 293       (t nil)))))
 294
 295 (defun notmuch-hello-saved-search-to-plist (saved-search)
 296   "Return a copy of SAVED-SEARCH in plist form.
 297
 298 If saved search is a plist then just return a copy. In other
 299 cases, for backwards compatability, convert to plist form and
 300 return that."
 301   (if (keywordp (car saved-search))
 302       (copy-seq saved-search)
 303     (let ((fields (list :name :query :count-query))
 304           plist-search)
 305       (dolist (field fields plist-search)
 306         (let ((string (notmuch-saved-search-get saved-search field)))
 307           (when string
 308             (setq plist-search (append plist-search (list field string)))))))))
 309
 310 (defun notmuch-hello-add-saved-search (widget)
 311   (interactive)
 312   (let ((search (widget-value
 313                  (symbol-value
 314                   (widget-get widget :notmuch-saved-search-widget))))
 315         (name (completing-read "Name for saved search: "
 316                                notmuch-saved-searches)))
 317     ;; If an existing saved search with this name exists, remove it.
 318     (setq notmuch-saved-searches
 319           (loop for elem in notmuch-saved-searches
 320                 if (not (equal name
 321                                (notmuch-saved-search-get elem :name)))
 322                 collect elem))
 323     ;; Add the new one.
 324     (customize-save-variable 'notmuch-saved-searches
 325                              (add-to-list 'notmuch-saved-searches
 326                                           (list :name name :query search) t))
 327     (message "Saved '%s' as '%s'." search name)
 328     (notmuch-hello-update)))
 329
 330 (defun notmuch-hello-delete-search-from-history (widget)
 331   (interactive)
 332   (let ((search (widget-value
 333                  (symbol-value
 334                   (widget-get widget :notmuch-saved-search-widget)))))
 335     (setq notmuch-search-history (delete search
 336                                          notmuch-search-history))
 337     (notmuch-hello-update)))
 338
 339 (defun notmuch-hello-longest-label (searches-alist)
 340   (or (loop for elem in searches-alist
 341             maximize (length (notmuch-saved-search-get elem :name)))
 342       0))
 343
 344 (defun notmuch-hello-reflect-generate-row (ncols nrows row list)
 345   (let ((len (length list)))
 346     (loop for col from 0 to (- ncols 1)
 347           collect (let ((offset (+ (* nrows col) row)))
 348                     (if (< offset len)
 349                         (nth offset list)
 350                       ;; Don't forget to insert an empty slot in the
 351                       ;; output matrix if there is no corresponding
 352                       ;; value in the input matrix.
 353                       nil)))))
 354
 355 (defun notmuch-hello-reflect (list ncols)
 356   "Reflect a `ncols' wide matrix represented by `list' along the
 357 diagonal."
 358   ;; Not very lispy...
 359   (let ((nrows (ceiling (length list) ncols)))
 360     (loop for row from 0 to (- nrows 1)
 361           append (notmuch-hello-reflect-generate-row ncols nrows row list))))
 362
 363 (defun notmuch-hello-widget-search (widget &rest ignore)
 364   (notmuch-search (widget-get widget
 365                               :notmuch-search-terms)
 366                   notmuch-search-oldest-first))
 367
 368 (defun notmuch-saved-search-count (search)
 369   (car (process-lines notmuch-command "count" search)))
 370
 371 (defun notmuch-hello-tags-per-line (widest)
 372   "Determine how many tags to show per line and how wide they
 373 should be. Returns a cons cell `(tags-per-line width)'."
 374   (let ((tags-per-line
 375          (cond
 376           ((integerp notmuch-column-control)
 377            (max 1
 378                 (/ (- (window-width) notmuch-hello-indent)
 379                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 380                    ;; after the name.
 381                    (+ 9 1 (max notmuch-column-control widest)))))
 382
 383           ((floatp notmuch-column-control)
 384            (let* ((available-width (- (window-width) notmuch-hello-indent))
 385                   (proposed-width (max (* available-width notmuch-column-control) widest)))
 386              (floor available-width proposed-width)))
 387
 388           (t
 389            (max 1
 390                 (/ (- (window-width) notmuch-hello-indent)
 391                    ;; Count is 9 wide (8 digits plus space), 1 for the space
 392                    ;; after the name.
 393                    (+ 9 1 widest)))))))
 394
 395     (cons tags-per-line (/ (max 1
 396                                 (- (window-width) notmuch-hello-indent
 397                                    ;; Count is 9 wide (8 digits plus
 398                                    ;; space), 1 for the space after the
 399                                    ;; name.
 400                                    (* tags-per-line (+ 9 1))))
 401                            tags-per-line))))
 402
 403 (defun notmuch-hello-filtered-query (query filter)
 404   "Constructs a query to search all messages matching QUERY and FILTER.
 405
 406 If FILTER is a string, it is directly used in the returned query.
 407
 408 If FILTER is a function, it is called with QUERY as a parameter and
 409 the string it returns is used as the query. If nil is returned,
 410 the entry is hidden.
 411
 412 Otherwise, FILTER is ignored.
 413 "
 414   (cond
 415    ((functionp filter) (funcall filter query))
 416    ((stringp filter)
 417     (concat "(" query ") and (" filter ")"))
 418    (t query)))
 419
 420 (defun notmuch-hello-query-counts (query-list &rest options)
 421   "Compute list of counts of matched messages from QUERY-LIST.
 422
 423 QUERY-LIST must be a list of saved-searches. Ideally each of
 424 these is a plist but other options are available for backwards
 425 compatibility: see `notmuch-saved-searches' for details.
 426
 427 The result is a list of plists each of which includes the
 428 properties :name NAME, :query QUERY and :count COUNT, together
 429 with any properties in the original saved-search.
 430
 431 The values :show-empty-searches, :filter and :filter-count from
 432 options will be handled as specified for
 433 `notmuch-hello-insert-searches'."
 434   (with-temp-buffer
 435     (dolist (elem query-list nil)
 436       (let ((count-query (or (notmuch-saved-search-get elem :count-query)
 437                              (notmuch-saved-search-get elem :query))))
 438         (insert
 439          (replace-regexp-in-string
 440           "\n" " "
 441           (notmuch-hello-filtered-query count-query
 442                                         (or (plist-get options :filter-count)
 443                                             (plist-get options :filter))))
 444           "\n")))
 445
 446     (unless (= (call-process-region (point-min) (point-max) notmuch-command
 447                                     t t nil "count" "--batch") 0)
 448       (notmuch-logged-error "notmuch count --batch failed"
 449                             "Please check that the notmuch CLI is new enough to support `count
 450 --batch'. In general we recommend running matching versions of
 451 the CLI and emacs interface."))
 452
 453     (goto-char (point-min))
 454
 455     (notmuch-remove-if-not
 456      #'identity
 457      (mapcar
 458       (lambda (elem)
 459         (let* ((elem-plist (notmuch-hello-saved-search-to-plist elem))
 460                (search-query (plist-get elem-plist :query))
 461                (filtered-query (notmuch-hello-filtered-query
 462                                 search-query (plist-get options :filter)))
 463                (message-count (prog1 (read (current-buffer))
 464                                 (forward-line 1))))
 465           (when (and filtered-query (or (plist-get options :show-empty-searches) (> message-count 0)))
 466             (setq elem-plist (plist-put elem-plist :query filtered-query))
 467             (plist-put elem-plist :count message-count))))
 468       query-list))))
 469
 470 (defun notmuch-hello-insert-buttons (searches)
 471   "Insert buttons for SEARCHES.
 472
 473 SEARCHES must be a list of plists each of which should contain at
 474 least the properties :name NAME :query QUERY and :count COUNT,
 475 where QUERY is the query to start when the button for the
 476 corresponding entry is activated, and COUNT should be the number
 477 of messages matching the query.  Such a plist can be computed
 478 with `notmuch-hello-query-counts'."
 479   (let* ((widest (notmuch-hello-longest-label searches))
 480          (tags-and-width (notmuch-hello-tags-per-line widest))
 481          (tags-per-line (car tags-and-width))
 482          (column-width (cdr tags-and-width))
 483          (column-indent 0)
 484          (count 0)
 485          (reordered-list (notmuch-hello-reflect searches tags-per-line))
 486          ;; Hack the display of the buttons used.
 487          (widget-push-button-prefix "")
 488          (widget-push-button-suffix ""))
 489     ;; dme: It feels as though there should be a better way to
 490     ;; implement this loop than using an incrementing counter.
 491     (mapc (lambda (elem)
 492             ;; (not elem) indicates an empty slot in the matrix.
 493             (when elem
 494               (if (> column-indent 0)
 495                   (widget-insert (make-string column-indent ? )))
 496               (let* ((name (plist-get elem :name))
 497                      (query (plist-get elem :query))
 498                      (msg-count (plist-get elem :count)))
 499                 (widget-insert (format "%8s "
 500                                        (notmuch-hello-nice-number msg-count)))
 501                 (widget-create 'push-button
 502                                :notify #'notmuch-hello-widget-search
 503                                :notmuch-search-terms query
 504                                name)
 505                 (setq column-indent
 506                       (1+ (max 0 (- column-width (length name)))))))
 507             (setq count (1+ count))
 508             (when (eq (% count tags-per-line) 0)
 509               (setq column-indent 0)
 510               (widget-insert "\n")))
 511           reordered-list)
 512
 513     ;; If the last line was not full (and hence did not include a
 514     ;; carriage return), insert one now.
 515     (unless (eq (% count tags-per-line) 0)
 516       (widget-insert "\n"))))
 517
 518 (defimage notmuch-hello-logo ((:type png :file "notmuch-logo.png")))
 519
 520 (defun notmuch-hello-update (&optional no-display)
 521   "Update the current notmuch view."
 522   ;; Lazy - rebuild everything.
 523   (notmuch-hello no-display))
 524
 525 (defun notmuch-hello-window-configuration-change ()
 526   "Hook function to update the hello buffer when it is switched to."
 527   (let ((hello-buf (get-buffer "*notmuch-hello*"))
 528         (do-refresh nil))
 529     ;; Consider all windows in the currently selected frame, since
 530     ;; that's where the configuration change happened.  This also
 531     ;; refreshes our snapshot of all windows, so we have to do this
 532     ;; even if we know we won't refresh (e.g., hello-buf is null).
 533     (dolist (window (window-list))
 534       (let ((last-buf (window-parameter window 'notmuch-hello-last-buffer))
 535             (cur-buf (window-buffer window)))
 536         (when (not (eq last-buf cur-buf))
 537           ;; This window changed or is new.  Update recorded buffer
 538           ;; for next time.
 539           (set-window-parameter window 'notmuch-hello-last-buffer cur-buf)
 540           (when (and (eq cur-buf hello-buf) last-buf)
 541             ;; The user just switched to hello in this window (hello
 542             ;; is currently visible, was not visible on the last
 543             ;; configuration change, and this is not a new window)
 544             (setq do-refresh t)))))
 545     (when (and do-refresh notmuch-hello-auto-refresh)
 546       ;; Refresh hello as soon as we get back to redisplay.  On Emacs
 547       ;; 24, we can't do it right here because something in this
 548       ;; hook's call stack overrides hello's point placement.
 549       (run-at-time nil nil #'notmuch-hello t))
 550     (when (null hello-buf)
 551       ;; Clean up hook
 552       (remove-hook 'window-configuration-change-hook
 553                    #'notmuch-hello-window-configuration-change))))
 554
 555 ;; the following variable is defined as being defconst in notmuch-version.el
 556 (defvar notmuch-emacs-version)
 557
 558 (defun notmuch-hello-versions ()
 559   "Display the notmuch version(s)"
 560   (interactive)
 561   (let ((notmuch-cli-version (notmuch-version)))
 562     (message "notmuch version %s"
 563              (if (string= notmuch-emacs-version notmuch-cli-version)
 564                  notmuch-cli-version
 565                (concat notmuch-cli-version
 566                        " (emacs mua version " notmuch-emacs-version ")")))))
 567
 568 (defvar notmuch-hello-mode-map
 569   (let ((map (if (fboundp 'make-composed-keymap)
 570                  ;; Inherit both widget-keymap and notmuch-common-keymap
 571                  (make-composed-keymap widget-keymap)
 572                ;; Before Emacs 24, keymaps didn't support multiple
 573                ;; inheritance,, so just copy the widget keymap since
 574                ;; it's unlikely to change.
 575                (copy-keymap widget-keymap))))
 576     (set-keymap-parent map notmuch-common-keymap)
 577     (define-key map "v" 'notmuch-hello-versions)
 578     (define-key map (kbd "<C-tab>") 'widget-backward)
 579     map)
 580   "Keymap for \"notmuch hello\" buffers.")
 581 (fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
 582
 583 (defun notmuch-hello-mode ()
 584  "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
 585
 586 Complete list of currently available key bindings:
 587
 588 \\{notmuch-hello-mode-map}"
 589  (interactive)
 590  (kill-all-local-variables)
 591  (setq notmuch-buffer-refresh-function #'notmuch-hello-update)
 592  (use-local-map notmuch-hello-mode-map)
 593  (setq major-mode 'notmuch-hello-mode
 594         mode-name "notmuch-hello")
 595  (run-mode-hooks 'notmuch-hello-mode-hook)
 596  ;;(setq buffer-read-only t)
 597 )
 598
 599 (defun notmuch-hello-generate-tag-alist (&optional hide-tags)
 600   "Return an alist from tags to queries to display in the all-tags section."
 601   (mapcar (lambda (tag)
 602             (cons tag (concat "tag:" (notmuch-escape-boolean-term tag))))
 603           (notmuch-remove-if-not
 604            (lambda (tag)
 605              (not (member tag hide-tags)))
 606            (process-lines notmuch-command "search" "--output=tags" "*"))))
 607
 608 (defun notmuch-hello-insert-header ()
 609   "Insert the default notmuch-hello header."
 610   (when notmuch-show-logo
 611     (let ((image notmuch-hello-logo))
 612       ;; The notmuch logo uses transparency. That can display poorly
 613       ;; when inserting the image into an emacs buffer (black logo on
 614       ;; a black background), so force the background colour of the
 615       ;; image. We use a face to represent the colour so that
 616       ;; `defface' can be used to declare the different possible
 617       ;; colours, which depend on whether the frame has a light or
 618       ;; dark background.
 619       (setq image (cons 'image
 620                         (append (cdr image)
 621                                 (list :background (face-background 'notmuch-hello-logo-background)))))
 622       (insert-image image))
 623     (widget-insert "  "))
 624
 625   (widget-insert "Welcome to ")
 626   ;; Hack the display of the links used.
 627   (let ((widget-link-prefix "")
 628         (widget-link-suffix ""))
 629     (widget-create 'link
 630                    :notify (lambda (&rest ignore)
 631                              (browse-url notmuch-hello-url))
 632                    :help-echo "Visit the notmuch website."
 633                    "notmuch")
 634     (widget-insert ". ")
 635     (widget-insert "You have ")
 636     (widget-create 'link
 637                    :notify (lambda (&rest ignore)
 638                              (notmuch-hello-update))
 639                    :help-echo "Refresh"
 640                    (notmuch-hello-nice-number
 641                     (string-to-number (car (process-lines notmuch-command "count")))))
 642     (widget-insert " messages.\n")))
 643
 644
 645 (defun notmuch-hello-insert-saved-searches ()
 646   "Insert the saved-searches section."
 647   (let ((searches (notmuch-hello-query-counts
 648                    (if notmuch-saved-search-sort-function
 649                        (funcall notmuch-saved-search-sort-function
 650                                 notmuch-saved-searches)
 651                      notmuch-saved-searches)
 652                    :show-empty-searches notmuch-show-empty-saved-searches)))
 653     (when searches
 654       (widget-insert "Saved searches: ")
 655       (widget-create 'push-button
 656                      :notify (lambda (&rest ignore)
 657                                (customize-variable 'notmuch-saved-searches))
 658                      "edit")
 659       (widget-insert "\n\n")
 660       (let ((start (point)))
 661         (notmuch-hello-insert-buttons searches)
 662         (indent-rigidly start (point) notmuch-hello-indent)))))
 663
 664 (defun notmuch-hello-insert-search ()
 665   "Insert a search widget."
 666   (widget-insert "Search: ")
 667   (widget-create 'editable-field
 668                  ;; Leave some space at the start and end of the
 669                  ;; search boxes.
 670                  :size (max 8 (- (window-width) notmuch-hello-indent
 671                                  (length "Search: ")))
 672                  :action (lambda (widget &rest ignore)
 673                            (notmuch-hello-search (widget-value widget))))
 674   ;; Add an invisible dot to make `widget-end-of-line' ignore
 675   ;; trailing spaces in the search widget field.  A dot is used
 676   ;; instead of a space to make `show-trailing-whitespace'
 677   ;; happy, i.e. avoid it marking the whole line as trailing
 678   ;; spaces.
 679   (widget-insert ".")
 680   (put-text-property (1- (point)) (point) 'invisible t)
 681   (widget-insert "\n"))
 682
 683 (defun notmuch-hello-insert-recent-searches ()
 684   "Insert recent searches."
 685   (when notmuch-search-history
 686     (widget-insert "Recent searches: ")
 687     (widget-create 'push-button
 688                    :notify (lambda (&rest ignore)
 689                              (when (y-or-n-p "Are you sure you want to clear the searches? ")
 690                                (setq notmuch-search-history nil)
 691                                (notmuch-hello-update)))
 692                    "clear")
 693     (widget-insert "\n\n")
 694     (let ((start (point)))
 695       (loop for i from 1 to notmuch-hello-recent-searches-max
 696             for search in notmuch-search-history do
 697             (let ((widget-symbol (intern (format "notmuch-hello-search-%d" i))))
 698               (set widget-symbol
 699                    (widget-create 'editable-field
 700                                   ;; Don't let the search boxes be
 701                                   ;; less than 8 characters wide.
 702                                   :size (max 8
 703                                              (- (window-width)
 704                                                 ;; Leave some space
 705                                                 ;; at the start and
 706                                                 ;; end of the
 707                                                 ;; boxes.
 708                                                 (* 2 notmuch-hello-indent)
 709                                                 ;; 1 for the space
 710                                                 ;; before the
 711                                                 ;; `[save]' button. 6
 712                                                 ;; for the `[save]'
 713                                                 ;; button.
 714                                                 1 6
 715                                                 ;; 1 for the space
 716                                                 ;; before the `[del]'
 717                                                 ;; button. 5 for the
 718                                                 ;; `[del]' button.
 719                                                 1 5))
 720                                   :action (lambda (widget &rest ignore)
 721                                             (notmuch-hello-search (widget-value widget)))
 722                                   search))
 723               (widget-insert " ")
 724               (widget-create 'push-button
 725                              :notify (lambda (widget &rest ignore)
 726                                        (notmuch-hello-add-saved-search widget))
 727                              :notmuch-saved-search-widget widget-symbol
 728                              "save")
 729               (widget-insert " ")
 730               (widget-create 'push-button
 731                              :notify (lambda (widget &rest ignore)
 732                                        (when (y-or-n-p "Are you sure you want to delete this search? ")
 733                                          (notmuch-hello-delete-search-from-history widget)))
 734                              :notmuch-saved-search-widget widget-symbol
 735                              "del"))
 736             (widget-insert "\n"))
 737       (indent-rigidly start (point) notmuch-hello-indent))
 738     nil))
 739
 740 (defun notmuch-hello-insert-searches (title query-list &rest options)
 741   "Insert a section with TITLE showing a list of buttons made from QUERY-LIST.
 742
 743 QUERY-LIST should ideally be a plist but for backwards
 744 compatibility other forms are also accepted (see
 745 `notmuch-saved-searches' for details).  The plist should
 746 contain keys :name and :query; if :count-query is also present
 747 then it specifies an alternate query to be used to generate the
 748 count for the associated search.
 749
 750 Supports the following entries in OPTIONS as a plist:
 751 :initially-hidden - if non-nil, section will be hidden on startup
 752 :show-empty-searches - show buttons with no matching messages
 753 :hide-if-empty - hide if no buttons would be shown
 754    (only makes sense without :show-empty-searches)
 755 :filter - This can be a function that takes the search query as its argument and
 756    returns a filter to be used in conjuction with the query for that search or nil
 757    to hide the element. This can also be a string that is used as a combined with
 758    each query using \"and\".
 759 :filter-count - Separate filter to generate the count displayed each search. Accepts
 760    the same values as :filter. If :filter and :filter-count are specified, this
 761    will be used instead of :filter, not in conjunction with it."
 762   (widget-insert title ": ")
 763   (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
 764       (add-to-list 'notmuch-hello-hidden-sections title))
 765   (let ((is-hidden (member title notmuch-hello-hidden-sections))
 766         (start (point)))
 767     (if is-hidden
 768         (widget-create 'push-button
 769                        :notify `(lambda (widget &rest ignore)
 770                                   (setq notmuch-hello-hidden-sections
 771                                         (delete ,title notmuch-hello-hidden-sections))
 772                                   (notmuch-hello-update))
 773                        "show")
 774       (widget-create 'push-button
 775                      :notify `(lambda (widget &rest ignore)
 776                                 (add-to-list 'notmuch-hello-hidden-sections
 777                                              ,title)
 778                                 (notmuch-hello-update))
 779                      "hide"))
 780     (widget-insert "\n")
 781     (when (not is-hidden)
 782       (let ((searches (apply 'notmuch-hello-query-counts query-list options)))
 783         (when (or (not (plist-get options :hide-if-empty))
 784                   searches)
 785           (widget-insert "\n")
 786           (notmuch-hello-insert-buttons searches)
 787           (indent-rigidly start (point) notmuch-hello-indent))))))
 788
 789 (defun notmuch-hello-insert-tags-section (&optional title &rest options)
 790   "Insert a section displaying all tags with message counts.
 791
 792 TITLE defaults to \"All tags\".
 793 Allowed options are those accepted by `notmuch-hello-insert-searches' and the
 794 following:
 795
 796 :hide-tags - List of tags that should be excluded."
 797   (apply 'notmuch-hello-insert-searches
 798          (or title "All tags")
 799          (notmuch-hello-generate-tag-alist (plist-get options :hide-tags))
 800          options))
 801
 802 (defun notmuch-hello-insert-inbox ()
 803   "Show an entry for each saved search and inboxed messages for each tag"
 804   (notmuch-hello-insert-searches "What's in your inbox"
 805                                  (append
 806                                   notmuch-saved-searches
 807                                   (notmuch-hello-generate-tag-alist))
 808                                  :filter "tag:inbox"))
 809
 810 (defun notmuch-hello-insert-alltags ()
 811   "Insert a section displaying all tags and associated message counts"
 812   (notmuch-hello-insert-tags-section
 813    nil
 814    :initially-hidden (not notmuch-show-all-tags-list)
 815    :hide-tags notmuch-hello-hide-tags
 816    :filter notmuch-hello-tag-list-make-query))
 817
 818 (defun notmuch-hello-insert-footer ()
 819   "Insert the notmuch-hello footer."
 820   (let ((start (point)))
 821     (widget-insert "Type a search query and hit RET to view matching threads.\n")
 822     (when notmuch-search-history
 823       (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
 824       (widget-insert "Save recent searches with the `save' button.\n"))
 825     (when notmuch-saved-searches
 826       (widget-insert "Edit saved searches with the `edit' button.\n"))
 827     (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
 828     (widget-insert "`=' to refresh this screen. `s' to search messages. `q' to quit.\n")
 829     (widget-create 'link
 830                    :notify (lambda (&rest ignore)
 831                              (customize-variable 'notmuch-hello-sections))
 832                    :button-prefix "" :button-suffix ""
 833                    "Customize")
 834     (widget-insert " this page.")
 835     (let ((fill-column (- (window-width) notmuch-hello-indent)))
 836       (center-region start (point)))))
 837
 838 ;;;###autoload
 839 (defun notmuch-hello (&optional no-display)
 840   "Run notmuch and display saved searches, known tags, etc."
 841   (interactive)
 842
 843   (notmuch-assert-cli-sane)
 844   ;; This may cause a window configuration change, so if the
 845   ;; auto-refresh hook is already installed, avoid recursive refresh.
 846   (let ((notmuch-hello-auto-refresh nil))
 847     (if no-display
 848         (set-buffer "*notmuch-hello*")
 849       (switch-to-buffer "*notmuch-hello*")))
 850
 851   ;; Install auto-refresh hook
 852   (when notmuch-hello-auto-refresh
 853     (add-hook 'window-configuration-change-hook
 854               #'notmuch-hello-window-configuration-change))
 855
 856   (let ((target-line (line-number-at-pos))
 857         (target-column (current-column))
 858         (inhibit-read-only t))
 859
 860     ;; Delete all editable widget fields.  Editable widget fields are
 861     ;; tracked in a buffer local variable `widget-field-list' (and
 862     ;; others).  If we do `erase-buffer' without properly deleting the
 863     ;; widgets, some widget-related functions are confused later.
 864     (mapc 'widget-delete widget-field-list)
 865
 866     (erase-buffer)
 867
 868     (unless (eq major-mode 'notmuch-hello-mode)
 869       (notmuch-hello-mode))
 870
 871     (let ((all (overlay-lists)))
 872       ;; Delete all the overlays.
 873       (mapc 'delete-overlay (car all))
 874       (mapc 'delete-overlay (cdr all)))
 875
 876     (mapc
 877      (lambda (section)
 878        (let ((point-before (point)))
 879          (if (functionp section)
 880              (funcall section)
 881            (apply (car section) (cdr section)))
 882          ;; don't insert a newline when the previous section didn't
 883          ;; show anything.
 884          (unless (eq (point) point-before)
 885            (widget-insert "\n"))))
 886      notmuch-hello-sections)
 887     (widget-setup)
 888
 889     ;; Move point back to where it was before refresh. Use line and
 890     ;; column instead of point directly to be insensitive to additions
 891     ;; and removals of text within earlier lines.
 892     (goto-char (point-min))
 893     (forward-line (1- target-line))
 894     (move-to-column target-column))
 895   (run-hooks 'notmuch-hello-refresh-hook)
 896   (setq notmuch-hello-first-run nil))
 897
 898 (defun notmuch-folder ()
 899   "Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
 900   (interactive)
 901   (notmuch-hello))
 902
 903 ;;
 904
 905 (provide 'notmuch-hello)