git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23
  24 (require 'notmuch-lib)
  25 (require 'notmuch-address)
  26
  27 ;;
  28
  29 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  30   "Hook run before sending messages."
  31   :type 'hook
  32   :group 'notmuch-send
  33   :group 'notmuch-hooks)
  34
  35 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  36   "Function used to generate a `User-Agent:' string. If this is
  37 `nil' then no `User-Agent:' will be generated."
  38   :type '(choice (const :tag "No user agent string" nil)
  39                  (const :tag "Full" notmuch-mua-user-agent-full)
  40                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  41                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  42                  (function :tag "Custom user agent function"
  43                            :value notmuch-mua-user-agent-full))
  44   :group 'notmuch-send)
  45
  46 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  47   "Headers that are added to the `message-mode' hidden headers
  48 list."
  49   :type '(repeat string)
  50   :group 'notmuch-send)
  51
  52 ;;
  53
  54 (defun notmuch-mua-user-agent-full ()
  55   "Generate a `User-Agent:' string suitable for notmuch."
  56   (concat (notmuch-mua-user-agent-notmuch)
  57           " "
  58           (notmuch-mua-user-agent-emacs)))
  59
  60 (defun notmuch-mua-user-agent-notmuch ()
  61   "Generate a `User-Agent:' string suitable for notmuch."
  62   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
  63
  64 (defun notmuch-mua-user-agent-emacs ()
  65   "Generate a `User-Agent:' string suitable for notmuch."
  66   (concat "Emacs/" emacs-version " (" system-configuration ")"))
  67
  68 (defun notmuch-mua-add-more-hidden-headers ()
  69   "Add some headers to the list that are hidden by default."
  70   (mapc (lambda (header)
  71           (when (not (member header message-hidden-headers))
  72             (push header message-hidden-headers)))
  73         notmuch-mua-hidden-headers))
  74
  75 (defun notmuch-mua-reply (query-string &optional sender reply-all)
  76   (let (headers
  77         body
  78         (args '("reply")))
  79     (if notmuch-show-process-crypto
  80         (setq args (append args '("--decrypt"))))
  81     (if reply-all
  82         (setq args (append args '("--reply-to=all")))
  83       (setq args (append args '("--reply-to=sender"))))
  84     (setq args (append args (list query-string)))
  85     ;; This make assumptions about the output of `notmuch reply', but
  86     ;; really only that the headers come first followed by a blank
  87     ;; line and then the body.
  88     (with-temp-buffer
  89       (apply 'call-process (append (list notmuch-command nil (list t t) nil) args))
  90       (goto-char (point-min))
  91       (if (re-search-forward "^$" nil t)
  92           (save-excursion
  93             (save-restriction
  94               (narrow-to-region (point-min) (point))
  95               (goto-char (point-min))
  96               (setq headers (mail-header-extract)))))
  97       (forward-line 1)
  98       ;; Original message may contain (malicious) MML tags. We must
  99       ;; properly quote them in the reply.
 100       (mml-quote-region (point) (point-max))
 101       (setq body (buffer-substring (point) (point-max))))
 102     ;; If sender is non-nil, set the From: header to its value.
 103     (when sender
 104       (mail-header-set 'from sender headers))
 105     (let
 106         ;; Overlay the composition window on that being used to read
 107         ;; the original message.
 108         ((same-window-regexps '("\\*mail .*")))
 109       (notmuch-mua-mail (mail-header 'to headers)
 110                         (mail-header 'subject headers)
 111                         (message-headers-to-generate headers t '(to subject))))
 112     ;; insert the message body - but put it in front of the signature
 113     ;; if one is present
 114     (goto-char (point-max))
 115     (if (re-search-backward message-signature-separator nil t)
 116           (forward-line -1)
 117       (goto-char (point-max)))
 118     (insert body)
 119     (push-mark))
 120   (set-buffer-modified-p nil)
 121
 122   (message-goto-body))
 123
 124 (defun notmuch-mua-forward-message ()
 125   (message-forward)
 126
 127   (when notmuch-mua-user-agent-function
 128     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 129       (when (not (string= "" user-agent))
 130         (message-add-header (format "User-Agent: %s" user-agent)))))
 131   (message-sort-headers)
 132   (message-hide-headers)
 133   (set-buffer-modified-p nil)
 134
 135   (message-goto-to))
 136
 137 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 138   "Invoke the notmuch mail composition window.
 139
 140 OTHER-ARGS are passed through to `message-mail'."
 141   (interactive)
 142
 143   (when notmuch-mua-user-agent-function
 144     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 145       (when (not (string= "" user-agent))
 146         (push (cons "User-Agent" user-agent) other-headers))))
 147
 148   (unless (mail-header 'from other-headers)
 149     (push (cons "From" (concat
 150                         (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 151
 152   (apply #'message-mail to subject other-headers other-args)
 153   (message-sort-headers)
 154   (message-hide-headers)
 155   (set-buffer-modified-p nil)
 156
 157   (message-goto-to))
 158
 159 (defcustom notmuch-identities nil
 160   "Identities that can be used as the From: address when composing a new message.
 161
 162 If this variable is left unset, then a list will be constructed from the
 163 name and addresses configured in the notmuch configuration file."
 164   :type '(repeat string)
 165   :group 'notmuch-send)
 166
 167 (defcustom notmuch-always-prompt-for-sender nil
 168   "Always prompt for the From: address when composing or forwarding a message.
 169
 170 This is not taken into account when replying to a message, because in that case
 171 the From: header is already filled in by notmuch."
 172   :type 'boolean
 173   :group 'notmuch-send)
 174
 175 (defvar notmuch-mua-sender-history nil)
 176
 177 (defun notmuch-mua-prompt-for-sender ()
 178   (interactive)
 179   (let (name addresses one-name-only)
 180     ;; If notmuch-identities is non-nil, check if there is a fixed user name.
 181     (if notmuch-identities
 182         (let ((components (mapcar 'mail-extract-address-components notmuch-identities)))
 183           (setq name          (caar components)
 184                 addresses     (mapcar 'cadr components)
 185                 one-name-only (eval
 186                                (cons 'and
 187                                      (mapcar (lambda (identity)
 188                                                (string-equal name (car identity)))
 189                                              components)))))
 190       ;; If notmuch-identities is nil, use values from the notmuch configuration file.
 191       (setq name          (notmuch-user-name)
 192             addresses     (cons (notmuch-user-primary-email) (notmuch-user-other-email))
 193             one-name-only t))
 194     ;; Now prompt the user, either for an email address only or for a full identity.
 195     (if one-name-only
 196         (let ((address
 197                (ido-completing-read (concat "Sender address for " name ": ") addresses
 198                                     nil nil nil 'notmuch-mua-sender-history (car addresses))))
 199           (concat name " <" address ">"))
 200       (ido-completing-read "Send mail From: " notmuch-identities
 201                            nil nil nil 'notmuch-mua-sender-history (car notmuch-identities)))))
 202
 203 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 204   "Invoke the notmuch mail composition window.
 205
 206 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 207 the From: address first."
 208   (interactive "P")
 209   (let ((other-headers
 210          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 211            (list (cons 'from (notmuch-mua-prompt-for-sender))))))
 212     (notmuch-mua-mail nil nil other-headers)))
 213
 214 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 215   "Invoke the notmuch message forwarding window.
 216
 217 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 218 the From: address first."
 219   (interactive "P")
 220   (if (or prompt-for-sender notmuch-always-prompt-for-sender)
 221       (let* ((sender (notmuch-mua-prompt-for-sender))
 222              (address-components (mail-extract-address-components sender))
 223              (user-full-name (car address-components))
 224              (user-mail-address (cadr address-components)))
 225         (notmuch-mua-forward-message))
 226     (notmuch-mua-forward-message)))
 227
 228 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 229   "Invoke the notmuch reply window."
 230   (interactive "P")
 231   (let ((sender
 232          (when prompt-for-sender
 233            (notmuch-mua-prompt-for-sender))))
 234     (notmuch-mua-reply query-string sender reply-all)))
 235
 236 (defun notmuch-mua-send-and-exit (&optional arg)
 237   (interactive "P")
 238   (message-send-and-exit arg))
 239
 240 (defun notmuch-mua-kill-buffer ()
 241   (interactive)
 242   (message-kill-buffer))
 243
 244 (defun notmuch-mua-message-send-hook ()
 245   "The default function used for `notmuch-mua-send-hook', this
 246 simply runs the corresponding `message-mode' hook functions."
 247   (run-hooks 'message-send-hook))
 248
 249 ;;
 250
 251 (define-mail-user-agent 'notmuch-user-agent
 252   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 253   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 254
 255 ;; Add some more headers to the list that `message-mode' hides when
 256 ;; composing a message.
 257 (notmuch-mua-add-more-hidden-headers)
 258
 259 ;;
 260
 261 (provide 'notmuch-mua)