git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23 (require 'mm-view)
  24 (require 'format-spec)
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-address)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth &optional hide))
  32
  33 ;;
  34
  35 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  36   "Hook run before sending messages."
  37   :type 'hook
  38   :group 'notmuch-send
  39   :group 'notmuch-hooks)
  40
  41 (defcustom notmuch-mua-compose-in 'current-window
  42   (concat
  43    "Where to create the mail buffer used to compose a new message.
  44 Possible values are `current-window' (default), `new-window' and
  45 `new-frame'. If set to `current-window', the mail buffer will be
  46 displayed in the current window, so the old buffer will be
  47 restored when the mail buffer is killed. If set to `new-window'
  48 or `new-frame', the mail buffer will be displayed in a new
  49 window/frame that will be destroyed when the buffer is killed.
  50 You may want to customize `message-kill-buffer-on-exit'
  51 accordingly."
  52    (when (< emacs-major-version 24)
  53            " Due to a known bug in Emacs 23, you should not set
  54 this to `new-window' if `message-kill-buffer-on-exit' is
  55 disabled: this would result in an incorrect behavior."))
  56   :group 'notmuch-send
  57   :type '(choice (const :tag "Compose in the current window" current-window)
  58                  (const :tag "Compose mail in a new window"  new-window)
  59                  (const :tag "Compose mail in a new frame"   new-frame)))
  60
  61 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  62   "Function used to generate a `User-Agent:' string. If this is
  63 `nil' then no `User-Agent:' will be generated."
  64   :type '(choice (const :tag "No user agent string" nil)
  65                  (const :tag "Full" notmuch-mua-user-agent-full)
  66                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  67                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  68                  (function :tag "Custom user agent function"
  69                            :value notmuch-mua-user-agent-full))
  70   :group 'notmuch-send)
  71
  72 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  73   "Headers that are added to the `message-mode' hidden headers
  74 list."
  75   :type '(repeat string)
  76   :group 'notmuch-send)
  77
  78 ;;
  79
  80 (defun notmuch-mua-get-switch-function ()
  81   "Get a switch function according to `notmuch-mua-compose-in'."
  82   (cond ((eq notmuch-mua-compose-in 'current-window)
  83          'switch-to-buffer)
  84         ((eq notmuch-mua-compose-in 'new-window)
  85          'switch-to-buffer-other-window)
  86         ((eq notmuch-mua-compose-in 'new-frame)
  87          'switch-to-buffer-other-frame)
  88         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
  89
  90 (defun notmuch-mua-maybe-set-window-dedicated ()
  91   "Set the selected window as dedicated according to
  92 `notmuch-mua-compose-in'."
  93   (when (or (eq notmuch-mua-compose-in 'new-frame)
  94             (eq notmuch-mua-compose-in 'new-window))
  95     (set-window-dedicated-p (selected-window) t)))
  96
  97 (defun notmuch-mua-user-agent-full ()
  98   "Generate a `User-Agent:' string suitable for notmuch."
  99   (concat (notmuch-mua-user-agent-notmuch)
 100           " "
 101           (notmuch-mua-user-agent-emacs)))
 102
 103 (defun notmuch-mua-user-agent-notmuch ()
 104   "Generate a `User-Agent:' string suitable for notmuch."
 105   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
 106
 107 (defun notmuch-mua-user-agent-emacs ()
 108   "Generate a `User-Agent:' string suitable for notmuch."
 109   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 110
 111 (defun notmuch-mua-add-more-hidden-headers ()
 112   "Add some headers to the list that are hidden by default."
 113   (mapc (lambda (header)
 114           (when (not (member header message-hidden-headers))
 115             (push header message-hidden-headers)))
 116         notmuch-mua-hidden-headers))
 117
 118 (defun notmuch-mua-reply-crypto (parts)
 119   "Add mml sign-encrypt flag if any part of original message is encrypted."
 120   (loop for part in parts
 121         if (notmuch-match-content-type (plist-get part :content-type) "multipart/encrypted")
 122           do (mml-secure-message-sign-encrypt)
 123         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 124           do (notmuch-mua-reply-crypto (plist-get part :content))))
 125
 126 (defun notmuch-mua-get-quotable-parts (parts)
 127   (loop for part in parts
 128         if (notmuch-match-content-type (plist-get part :content-type) "multipart/alternative")
 129           collect (let* ((subparts (plist-get part :content))
 130                         (types (mapcar (lambda (part) (plist-get part :content-type)) subparts))
 131                         (chosen-type (car (notmuch-multipart/alternative-choose types))))
 132                    (loop for part in (reverse subparts)
 133                          if (notmuch-match-content-type (plist-get part :content-type) chosen-type)
 134                          return part))
 135         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 136           append (notmuch-mua-get-quotable-parts (plist-get part :content))
 137         else if (notmuch-match-content-type (plist-get part :content-type) "text/*")
 138           collect part))
 139
 140 (defun notmuch-mua-insert-quotable-part (message part)
 141   ;; We don't want text properties leaking from the show renderer into
 142   ;; the reply so we use a temp buffer. Also we don't want hooks, such
 143   ;; as notmuch-wash-*, to be run on the quotable part so we set
 144   ;; notmuch-show-insert-text/plain-hook to nil.
 145   (insert (with-temp-buffer
 146             (let ((notmuch-show-insert-text/plain-hook nil))
 147               ;; Show the part but do not add buttons.
 148               (notmuch-show-insert-bodypart message part 0 'no-buttons))
 149             (buffer-substring-no-properties (point-min) (point-max)))))
 150
 151 ;; There is a bug in emacs 23's message.el that results in a newline
 152 ;; not being inserted after the References header, so the next header
 153 ;; is concatenated to the end of it. This function fixes the problem,
 154 ;; while guarding against the possibility that some current or future
 155 ;; version of emacs has the bug fixed.
 156 (defun notmuch-mua-insert-references (original-func header references)
 157   (funcall original-func header references)
 158   (unless (bolp) (insert "\n")))
 159
 160 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 161   (let ((args '("reply" "--format=sexp" "--format-version=1"))
 162         (process-crypto notmuch-show-process-crypto)
 163         reply
 164         original)
 165     (when process-crypto
 166       (setq args (append args '("--decrypt"))))
 167
 168     (if reply-all
 169         (setq args (append args '("--reply-to=all")))
 170       (setq args (append args '("--reply-to=sender"))))
 171     (setq args (append args (list query-string)))
 172
 173     ;; Get the reply object as SEXP, and parse it into an elisp object.
 174     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 175
 176     ;; Extract the original message to simplify the following code.
 177     (setq original (plist-get reply :original))
 178
 179     ;; Extract the headers of both the reply and the original message.
 180     (let* ((original-headers (plist-get original :headers))
 181            (reply-headers (plist-get reply :reply-headers)))
 182
 183       ;; If sender is non-nil, set the From: header to its value.
 184       (when sender
 185         (plist-put reply-headers :From sender))
 186       (let
 187           ;; Overlay the composition window on that being used to read
 188           ;; the original message.
 189           ((same-window-regexps '("\\*mail .*")))
 190
 191         ;; We modify message-header-format-alist to get around a bug in message.el.
 192         ;; See the comment above on notmuch-mua-insert-references.
 193         (let ((message-header-format-alist
 194                (loop for pair in message-header-format-alist
 195                      if (eq (car pair) 'References)
 196                      collect (cons 'References
 197                                    (apply-partially
 198                                     'notmuch-mua-insert-references
 199                                     (cdr pair)))
 200                      else
 201                      collect pair)))
 202           (notmuch-mua-mail (plist-get reply-headers :To)
 203                             (plist-get reply-headers :Subject)
 204                             (notmuch-headers-plist-to-alist reply-headers)
 205                             nil (notmuch-mua-get-switch-function))))
 206
 207       ;; Insert the message body - but put it in front of the signature
 208       ;; if one is present, and after any other content
 209       ;; message*setup-hooks may have added to the message body already.
 210       (save-restriction
 211         (message-goto-body)
 212         (narrow-to-region (point) (point-max))
 213         (goto-char (point-max))
 214         (if (re-search-backward message-signature-separator nil t)
 215             (if message-signature-insert-empty-line
 216                 (forward-line -1))
 217           (goto-char (point-max))))
 218
 219       (let ((from (plist-get original-headers :From))
 220             (date (plist-get original-headers :Date))
 221             (start (point)))
 222
 223         ;; message-cite-original constructs a citation line based on the From and Date
 224         ;; headers of the original message, which are assumed to be in the buffer.
 225         (insert "From: " from "\n")
 226         (insert "Date: " date "\n\n")
 227
 228         ;; Get the parts of the original message that should be quoted; this includes
 229         ;; all the text parts, except the non-preferred ones in a multipart/alternative.
 230         (let ((quotable-parts (notmuch-mua-get-quotable-parts (plist-get original :body))))
 231           (mapc (apply-partially 'notmuch-mua-insert-quotable-part original) quotable-parts))
 232
 233         (set-mark (point))
 234         (goto-char start)
 235         ;; Quote the original message according to the user's configured style.
 236         (message-cite-original)))
 237
 238     ;; Crypto processing based crypto content of the original message
 239     (when process-crypto
 240       (notmuch-mua-reply-crypto (plist-get original :body))))
 241
 242   ;; Push mark right before signature, if any.
 243   (message-goto-signature)
 244   (unless (eobp)
 245     (end-of-line -1))
 246   (push-mark)
 247
 248   (message-goto-body)
 249   (set-buffer-modified-p nil))
 250
 251 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 252   "Invoke the notmuch mail composition window.
 253
 254 OTHER-ARGS are passed through to `message-mail'."
 255   (interactive)
 256
 257   (when notmuch-mua-user-agent-function
 258     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 259       (when (not (string= "" user-agent))
 260         (push (cons 'User-Agent user-agent) other-headers))))
 261
 262   (unless (assq 'From other-headers)
 263     (push (cons 'From (concat
 264                        (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 265
 266   (apply #'message-mail to subject other-headers other-args)
 267   (message-sort-headers)
 268   (message-hide-headers)
 269   (set-buffer-modified-p nil)
 270   (notmuch-mua-maybe-set-window-dedicated)
 271
 272   (message-goto-to))
 273
 274 (defcustom notmuch-identities nil
 275   "Identities that can be used as the From: address when composing a new message.
 276
 277 If this variable is left unset, then a list will be constructed from the
 278 name and addresses configured in the notmuch configuration file."
 279   :type '(repeat string)
 280   :group 'notmuch-send)
 281
 282 (defcustom notmuch-always-prompt-for-sender nil
 283   "Always prompt for the From: address when composing or forwarding a message.
 284
 285 This is not taken into account when replying to a message, because in that case
 286 the From: header is already filled in by notmuch."
 287   :type 'boolean
 288   :group 'notmuch-send)
 289
 290 (defvar notmuch-mua-sender-history nil)
 291
 292 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
 293 ;; without some explicit initialization fill freeze the operation.
 294 ;; Hence, we advice `ido-completing-read' to ensure required initialization
 295 ;; is done.
 296 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
 297     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
 298       (ido-init-completion-maps)
 299       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
 300       (add-hook 'choose-completion-string-functions
 301                 'ido-choose-completion-string)
 302       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
 303       (ad-activate 'ido-completing-read)))
 304
 305 (defun notmuch-mua-prompt-for-sender ()
 306   "Prompt for a sender from the user's configured identities."
 307   (if notmuch-identities
 308       (ido-completing-read "Send mail from: " notmuch-identities
 309                            nil nil nil 'notmuch-mua-sender-history
 310                            (car notmuch-identities))
 311     (let* ((name (notmuch-user-name))
 312            (addrs (cons (notmuch-user-primary-email)
 313                         (notmuch-user-other-email)))
 314            (address
 315             (ido-completing-read (concat "Sender address for " name ": ") addrs
 316                                  nil nil nil 'notmuch-mua-sender-history
 317                                  (car addrs))))
 318       (concat name " <" address ">"))))
 319
 320 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 321 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 322   "Compose new mail.
 323
 324 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 325 the From: address first."
 326   (interactive "P")
 327   (let ((other-headers
 328          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 329            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 330     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 331
 332 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 333   "Invoke the notmuch message forwarding window.
 334
 335 The current buffer must contain an RFC2822 message to forward.
 336
 337 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 338 the From: address first."
 339   (let* ((cur (current-buffer))
 340          (message-forward-decoded-p nil)
 341          (subject (message-make-forward-subject))
 342          (other-headers
 343           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 344             (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 345     (notmuch-mua-mail nil subject other-headers nil (notmuch-mua-get-switch-function))
 346     (message-forward-make-body cur)
 347     ;; `message-forward-make-body' shows the User-agent header.  Hide
 348     ;; it again.
 349     (message-hide-headers)
 350     (set-buffer-modified-p nil)))
 351
 352 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 353   "Compose a reply to the message identified by QUERY-STRING.
 354
 355 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 356 the From: address first.  If REPLY-ALL is non-nil, the message
 357 will be addressed to all recipients of the source message."
 358
 359 ;; In current emacs (24.3) select-active-regions is set to t by
 360 ;; default. The reply insertion code sets the region to the quoted
 361 ;; message to make it easy to delete (kill-region or C-w). These two
 362 ;; things combine to put the quoted message in the primary selection.
 363 ;;
 364 ;; This is not what the user wanted and is a privacy risk (accidental
 365 ;; pasting of the quoted message). We can avoid some of the problems
 366 ;; by let-binding select-active-regions to nil. This fixes if the
 367 ;; primary selection was previously in a non-emacs window but not if
 368 ;; it was in an emacs window. To avoid the problem in the latter case
 369 ;; we deactivate mark.
 370
 371   (let ((sender
 372          (when prompt-for-sender
 373            (notmuch-mua-prompt-for-sender)))
 374         (select-active-regions nil))
 375     (notmuch-mua-reply query-string sender reply-all)
 376     (deactivate-mark)))
 377
 378 (defun notmuch-mua-send-and-exit (&optional arg)
 379   (interactive "P")
 380   (message-send-and-exit arg))
 381
 382 (defun notmuch-mua-kill-buffer ()
 383   (interactive)
 384   (message-kill-buffer))
 385
 386 (defun notmuch-mua-message-send-hook ()
 387   "The default function used for `notmuch-mua-send-hook', this
 388 simply runs the corresponding `message-mode' hook functions."
 389   (run-hooks 'message-send-hook))
 390
 391 ;;
 392
 393 (define-mail-user-agent 'notmuch-user-agent
 394   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 395   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 396
 397 ;; Add some more headers to the list that `message-mode' hides when
 398 ;; composing a message.
 399 (notmuch-mua-add-more-hidden-headers)
 400
 401 ;;
 402
 403 (provide 'notmuch-mua)