git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23
  24 (require 'notmuch-lib)
  25 (require 'notmuch-address)
  26
  27 ;;
  28
  29 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  30   "Hook run before sending messages."
  31   :group 'notmuch
  32   :type 'hook)
  33
  34 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  35   "Function used to generate a `User-Agent:' string. If this is
  36 `nil' then no `User-Agent:' will be generated."
  37   :group 'notmuch
  38   :type '(choice (const :tag "No user agent string" nil)
  39                  (const :tag "Full" notmuch-mua-user-agent-full)
  40                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  41                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  42                  (function :tag "Custom user agent function"
  43                            :value notmuch-mua-user-agent-full)))
  44
  45 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  46   "Headers that are added to the `message-mode' hidden headers
  47 list."
  48   :group 'notmuch
  49   :type '(repeat string))
  50
  51 ;;
  52
  53 (defun notmuch-mua-user-agent-full ()
  54   "Generate a `User-Agent:' string suitable for notmuch."
  55   (concat (notmuch-mua-user-agent-notmuch)
  56           " "
  57           (notmuch-mua-user-agent-emacs)))
  58
  59 (defun notmuch-mua-user-agent-notmuch ()
  60   "Generate a `User-Agent:' string suitable for notmuch."
  61   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
  62
  63 (defun notmuch-mua-user-agent-emacs ()
  64   "Generate a `User-Agent:' string suitable for notmuch."
  65   (concat "Emacs/" emacs-version " (" system-configuration ")"))
  66
  67 (defun notmuch-mua-add-more-hidden-headers ()
  68   "Add some headers to the list that are hidden by default."
  69   (mapc (lambda (header)
  70           (when (not (member header message-hidden-headers))
  71             (push header message-hidden-headers)))
  72         notmuch-mua-hidden-headers))
  73
  74 (defun notmuch-mua-reply (query-string &optional sender)
  75   (let (headers
  76         body
  77         (args '("reply")))
  78     (if notmuch-show-process-crypto
  79         (setq args (append args '("--decrypt"))))
  80     (setq args (append args (list query-string)))
  81     ;; This make assumptions about the output of `notmuch reply', but
  82     ;; really only that the headers come first followed by a blank
  83     ;; line and then the body.
  84     (with-temp-buffer
  85       (apply 'call-process (append (list notmuch-command nil (list t t) nil) args))
  86       (goto-char (point-min))
  87       (if (re-search-forward "^$" nil t)
  88           (save-excursion
  89             (save-restriction
  90               (narrow-to-region (point-min) (point))
  91               (goto-char (point-min))
  92               (setq headers (mail-header-extract)))))
  93       (forward-line 1)
  94       (setq body (buffer-substring (point) (point-max))))
  95     ;; If sender is non-nil, set the From: header to its value.
  96     (when sender
  97       (mail-header-set 'from sender headers))
  98     (let
  99         ;; Overlay the composition window on that being used to read
 100         ;; the original message.
 101         ((same-window-regexps '("\\*mail .*")))
 102       (notmuch-mua-mail (mail-header 'to headers)
 103                         (mail-header 'subject headers)
 104                         (message-headers-to-generate headers t '(to subject))))
 105     ;; insert the message body - but put it in front of the signature
 106     ;; if one is present
 107     (goto-char (point-max))
 108     (if (re-search-backward message-signature-separator nil t)
 109           (forward-line -1)
 110       (goto-char (point-max)))
 111     (insert body))
 112   (set-buffer-modified-p nil)
 113
 114   (message-goto-body)
 115   ;; Original message may contain (malicious) MML tags.  We must
 116   ;; properly quote them in the reply.  Note that using `point-max'
 117   ;; instead of `mark' here is wrong.  The buffer may include user's
 118   ;; signature which should not be MML-quoted.
 119   (mml-quote-region (point) (point-max)))
 120
 121 (defun notmuch-mua-forward-message ()
 122   (message-forward)
 123
 124   (when notmuch-mua-user-agent-function
 125     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 126       (when (not (string= "" user-agent))
 127         (message-add-header (format "User-Agent: %s" user-agent)))))
 128   (message-sort-headers)
 129   (message-hide-headers)
 130   (set-buffer-modified-p nil)
 131
 132   (message-goto-to))
 133
 134 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 135   "Invoke the notmuch mail composition window.
 136
 137 OTHER-ARGS are passed through to `message-mail'."
 138   (interactive)
 139
 140   (when notmuch-mua-user-agent-function
 141     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 142       (when (not (string= "" user-agent))
 143         (push (cons "User-Agent" user-agent) other-headers))))
 144
 145   (unless (mail-header 'from other-headers)
 146     (push (cons "From" (concat
 147                         (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 148
 149   (apply #'message-mail to subject other-headers other-args)
 150   (message-sort-headers)
 151   (message-hide-headers)
 152   (set-buffer-modified-p nil)
 153
 154   (message-goto-to))
 155
 156 (defcustom notmuch-identities nil
 157   "Identities that can be used as the From: address when composing a new message.
 158
 159 If this variable is left unset, then a list will be constructed from the
 160 name and addresses configured in the notmuch configuration file."
 161   :group 'notmuch
 162   :type '(repeat string))
 163
 164 (defcustom notmuch-always-prompt-for-sender nil
 165   "Always prompt for the From: address when composing or forwarding a message.
 166
 167 This is not taken into account when replying to a message, because in that case
 168 the From: header is already filled in by notmuch."
 169   :group 'notmuch
 170   :type 'boolean)
 171
 172 (defvar notmuch-mua-sender-history nil)
 173
 174 (defun notmuch-mua-prompt-for-sender ()
 175   (interactive)
 176   (let (name addresses one-name-only)
 177     ;; If notmuch-identities is non-nil, check if there is a fixed user name.
 178     (if notmuch-identities
 179         (let ((components (mapcar 'mail-extract-address-components notmuch-identities)))
 180           (setq name          (caar components)
 181                 addresses     (mapcar 'cadr components)
 182                 one-name-only (eval
 183                                (cons 'and
 184                                      (mapcar (lambda (identity)
 185                                                (string-equal name (car identity)))
 186                                              components)))))
 187       ;; If notmuch-identities is nil, use values from the notmuch configuration file.
 188       (setq name          (notmuch-user-name)
 189             addresses     (cons (notmuch-user-primary-email) (notmuch-user-other-email))
 190             one-name-only t))
 191     ;; Now prompt the user, either for an email address only or for a full identity.
 192     (if one-name-only
 193         (let ((address
 194                (ido-completing-read (concat "Sender address for " name ": ") addresses
 195                                     nil nil nil 'notmuch-mua-sender-history (car addresses))))
 196           (concat name " <" address ">"))
 197       (ido-completing-read "Send mail From: " notmuch-identities
 198                            nil nil nil 'notmuch-mua-sender-history (car notmuch-identities)))))
 199
 200 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 201   "Invoke the notmuch mail composition window.
 202
 203 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 204 the From: address first."
 205   (interactive "P")
 206   (let ((other-headers
 207          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 208            (list (cons 'from (notmuch-mua-prompt-for-sender))))))
 209     (notmuch-mua-mail nil nil other-headers)))
 210
 211 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 212   "Invoke the notmuch message forwarding window.
 213
 214 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 215 the From: address first."
 216   (interactive "P")
 217   (if (or prompt-for-sender notmuch-always-prompt-for-sender)
 218       (let* ((sender (notmuch-mua-prompt-for-sender))
 219              (address-components (mail-extract-address-components sender))
 220              (user-full-name (car address-components))
 221              (user-mail-address (cadr address-components)))
 222         (notmuch-mua-forward-message))
 223     (notmuch-mua-forward-message)))
 224
 225 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender)
 226   "Invoke the notmuch reply window."
 227   (interactive "P")
 228   (let ((sender
 229          (when prompt-for-sender
 230            (notmuch-mua-prompt-for-sender))))
 231     (notmuch-mua-reply query-string sender)))
 232
 233 (defun notmuch-mua-send-and-exit (&optional arg)
 234   (interactive "P")
 235   (message-send-and-exit arg))
 236
 237 (defun notmuch-mua-kill-buffer ()
 238   (interactive)
 239   (message-kill-buffer))
 240
 241 (defun notmuch-mua-message-send-hook ()
 242   "The default function used for `notmuch-mua-send-hook', this
 243 simply runs the corresponding `message-mode' hook functions."
 244   (run-hooks 'message-send-hook))
 245
 246 ;;
 247
 248 (define-mail-user-agent 'notmuch-user-agent
 249   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 250   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 251
 252 ;; Add some more headers to the list that `message-mode' hides when
 253 ;; composing a message.
 254 (notmuch-mua-add-more-hidden-headers)
 255
 256 ;;
 257
 258 (provide 'notmuch-mua)