git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 ;;; Code:
  23
  24 (eval-when-compile (require 'cl-lib))
  25
  26 (require 'message)
  27 (require 'mm-view)
  28 (require 'format-spec)
  29
  30 (require 'notmuch-lib)
  31 (require 'notmuch-address)
  32 (require 'notmuch-draft)
  33 (require 'notmuch-message)
  34
  35 (declare-function notmuch-show-insert-body "notmuch-show" (msg body depth))
  36 (declare-function notmuch-fcc-header-setup "notmuch-maildir-fcc" ())
  37 (declare-function notmuch-maildir-message-do-fcc "notmuch-maildir-fcc" ())
  38 (declare-function notmuch-draft-postpone "notmuch-draft" ())
  39 (declare-function notmuch-draft-save "notmuch-draft" ())
  40
  41 ;;
  42
  43 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  44   "Hook run before sending messages."
  45   :type 'hook
  46   :group 'notmuch-send
  47   :group 'notmuch-hooks)
  48
  49 (defcustom notmuch-mua-compose-in 'current-window
  50   (concat
  51    "Where to create the mail buffer used to compose a new message.
  52 Possible values are `current-window' (default), `new-window' and
  53 `new-frame'. If set to `current-window', the mail buffer will be
  54 displayed in the current window, so the old buffer will be
  55 restored when the mail buffer is killed. If set to `new-window'
  56 or `new-frame', the mail buffer will be displayed in a new
  57 window/frame that will be destroyed when the buffer is killed.
  58 You may want to customize `message-kill-buffer-on-exit'
  59 accordingly."
  60    (when (< emacs-major-version 24)
  61      " Due to a known bug in Emacs 23, you should not set
  62 this to `new-window' if `message-kill-buffer-on-exit' is
  63 disabled: this would result in an incorrect behavior."))
  64   :group 'notmuch-send
  65   :type '(choice (const :tag "Compose in the current window" current-window)
  66                  (const :tag "Compose mail in a new window"  new-window)
  67                  (const :tag "Compose mail in a new frame"   new-frame)))
  68
  69 (defcustom notmuch-mua-user-agent-function nil
  70   "Function used to generate a `User-Agent:' string. If this is
  71 `nil' then no `User-Agent:' will be generated."
  72   :type '(choice (const :tag "No user agent string" nil)
  73                  (const :tag "Full" notmuch-mua-user-agent-full)
  74                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  75                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  76                  (function :tag "Custom user agent function"
  77                            :value notmuch-mua-user-agent-full))
  78   :group 'notmuch-send)
  79
  80 (defcustom notmuch-mua-hidden-headers nil
  81   "Headers that are added to the `message-mode' hidden headers
  82 list."
  83   :type '(repeat string)
  84   :group 'notmuch-send)
  85
  86 (defgroup notmuch-reply nil
  87   "Replying to messages in notmuch"
  88   :group 'notmuch)
  89
  90 (defcustom notmuch-mua-cite-function 'message-cite-original
  91   "*Function for citing an original message.
  92 Predefined functions include `message-cite-original' and
  93 `message-cite-original-without-signature'.
  94 Note that these functions use `mail-citation-hook' if that is non-nil."
  95   :type '(radio (function-item message-cite-original)
  96                 (function-item message-cite-original-without-signature)
  97                 (function-item sc-cite-original)
  98                 (function :tag "Other"))
  99   :link '(custom-manual "(message)Insertion Variables")
 100   :group 'notmuch-reply)
 101
 102 (defcustom notmuch-mua-reply-insert-header-p-function
 103   'notmuch-show-reply-insert-header-p-never
 104   "Function to decide which parts get a header when replying.
 105
 106 This function specifies which parts of a mime message with
 107 multiple parts get a header."
 108   :type '(radio (const :tag "No part headers"
 109                        notmuch-show-reply-insert-header-p-never)
 110                 (const :tag "All except multipart/* and hidden parts"
 111                        notmuch-show-reply-insert-header-p-trimmed)
 112                 (const :tag "Only for included text parts"
 113                        notmuch-show-reply-insert-header-p-minimal)
 114                 (const :tag "Exactly as in show view"
 115                        notmuch-show-insert-header-p)
 116                 (function :tag "Other"))
 117   :group 'notmuch-reply)
 118
 119 (defcustom notmuch-mua-attachment-regexp
 120   "\\b\\(attache\?ment\\|attached\\|attach\\|pi[èe]ce\s+jointe?\\)\\b"
 121   "Message body text indicating that an attachment is expected.
 122
 123 This is not used unless `notmuch-mua-attachment-check' is added
 124 to `notmuch-mua-send-hook'."
 125   :type 'regexp
 126   :group 'notmuch-send)
 127
 128 ;;
 129
 130 (defun notmuch-mua-attachment-check ()
 131   "Signal an error if the message text indicates that an
 132 attachment is expected but no MML referencing an attachment is
 133 found.
 134
 135 Typically this is added to `notmuch-mua-send-hook'."
 136   (when (and
 137          ;; When the message mentions attachment...
 138          (save-excursion
 139            (message-goto-body)
 140            ;; Limit search from reaching other possible parts of the message
 141            (let ((search-limit (search-forward "\n<#" nil t)))
 142              (message-goto-body)
 143              (cl-loop while (re-search-forward notmuch-mua-attachment-regexp
 144                                                search-limit t)
 145                       ;; For every instance of the "attachment" string
 146                       ;; found, examine the text properties. If the text
 147                       ;; has either a `face' or `syntax-table' property
 148                       ;; then it is quoted text and should *not* cause the
 149                       ;; user to be asked about a missing attachment.
 150                       if (let ((props (text-properties-at (match-beginning 0))))
 151                            (not (or (memq 'syntax-table props)
 152                                     (memq 'face props))))
 153                       return t
 154                       finally return nil)))
 155          ;; ...but doesn't have a part with a filename...
 156          (save-excursion
 157            (message-goto-body)
 158            (not (re-search-forward "^<#part [^>]*filename=" nil t)))
 159          ;; ...and that's not okay...
 160          (not (y-or-n-p "Attachment mentioned, but no attachment - is that okay?")))
 161     ;; ...signal an error.
 162     (error "Missing attachment")))
 163
 164 (defun notmuch-mua-get-switch-function ()
 165   "Get a switch function according to `notmuch-mua-compose-in'."
 166   (cond ((eq notmuch-mua-compose-in 'current-window)
 167          'switch-to-buffer)
 168         ((eq notmuch-mua-compose-in 'new-window)
 169          'switch-to-buffer-other-window)
 170         ((eq notmuch-mua-compose-in 'new-frame)
 171          'switch-to-buffer-other-frame)
 172         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
 173
 174 (defun notmuch-mua-maybe-set-window-dedicated ()
 175   "Set the selected window as dedicated according to
 176 `notmuch-mua-compose-in'."
 177   (when (or (eq notmuch-mua-compose-in 'new-frame)
 178             (eq notmuch-mua-compose-in 'new-window))
 179     (set-window-dedicated-p (selected-window) t)))
 180
 181 (defun notmuch-mua-user-agent-full ()
 182   "Generate a `User-Agent:' string suitable for notmuch."
 183   (concat (notmuch-mua-user-agent-notmuch)
 184           " "
 185           (notmuch-mua-user-agent-emacs)))
 186
 187 (defun notmuch-mua-user-agent-notmuch ()
 188   "Generate a `User-Agent:' string suitable for notmuch."
 189   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
 190                              (notmuch-cli-version)
 191                            notmuch-emacs-version)))
 192     (concat "Notmuch/" notmuch-version " (https://notmuchmail.org)")))
 193
 194 (defun notmuch-mua-user-agent-emacs ()
 195   "Generate a `User-Agent:' string suitable for notmuch."
 196   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 197
 198 (defun notmuch-mua-add-more-hidden-headers ()
 199   "Add some headers to the list that are hidden by default."
 200   (mapc (lambda (header)
 201           (unless (member header message-hidden-headers)
 202             (push header message-hidden-headers)))
 203         notmuch-mua-hidden-headers))
 204
 205 (defun notmuch-mua-reply-crypto (parts)
 206   "Add mml sign-encrypt flag if any part of original message is encrypted."
 207   (cl-loop for part in parts
 208            if (notmuch-match-content-type (plist-get part :content-type)
 209                                           "multipart/encrypted")
 210            do (mml-secure-message-sign-encrypt)
 211            else if (notmuch-match-content-type (plist-get part :content-type)
 212                                                "multipart/*")
 213            do (notmuch-mua-reply-crypto (plist-get part :content))))
 214
 215 ;; There is a bug in emacs 23's message.el that results in a newline
 216 ;; not being inserted after the References header, so the next header
 217 ;; is concatenated to the end of it. This function fixes the problem,
 218 ;; while guarding against the possibility that some current or future
 219 ;; version of emacs has the bug fixed.
 220 (defun notmuch-mua-insert-references (original-func header references)
 221   (funcall original-func header references)
 222   (unless (bolp) (insert "\n")))
 223
 224 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 225   (let ((args '("reply" "--format=sexp" "--format-version=4"))
 226         (process-crypto notmuch-show-process-crypto)
 227         reply
 228         original)
 229     (when process-crypto
 230       (setq args (append args '("--decrypt=true"))))
 231     (if reply-all
 232         (setq args (append args '("--reply-to=all")))
 233       (setq args (append args '("--reply-to=sender"))))
 234     (setq args (append args (list query-string)))
 235     ;; Get the reply object as SEXP, and parse it into an elisp object.
 236     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 237     ;; Extract the original message to simplify the following code.
 238     (setq original (plist-get reply :original))
 239     ;; Extract the headers of both the reply and the original message.
 240     (let* ((original-headers (plist-get original :headers))
 241            (reply-headers (plist-get reply :reply-headers)))
 242       ;; If sender is non-nil, set the From: header to its value.
 243       (when sender
 244         (plist-put reply-headers :From sender))
 245       (let
 246           ;; Overlay the composition window on that being used to read
 247           ;; the original message.
 248           ((same-window-regexps '("\\*mail .*")))
 249         ;; We modify message-header-format-alist to get around
 250         ;; a bug in message.el.  See the comment above on
 251         ;; notmuch-mua-insert-references.
 252         (let ((message-header-format-alist
 253                (cl-loop for pair in message-header-format-alist
 254                         if (eq (car pair) 'References)
 255                         collect (cons 'References
 256                                       (apply-partially
 257                                        'notmuch-mua-insert-references
 258                                        (cdr pair)))
 259                         else
 260                         collect pair)))
 261           (notmuch-mua-mail (plist-get reply-headers :To)
 262                             (notmuch-sanitize (plist-get reply-headers :Subject))
 263                             (notmuch-headers-plist-to-alist reply-headers)
 264                             nil (notmuch-mua-get-switch-function))))
 265       ;; Create a buffer-local queue for tag changes triggered when
 266       ;; sending the reply.
 267       (when notmuch-message-replied-tags
 268         (setq-local notmuch-message-queued-tag-changes
 269                     (list (cons query-string notmuch-message-replied-tags))))
 270       ;; Insert the message body - but put it in front of the signature
 271       ;; if one is present, and after any other content
 272       ;; message*setup-hooks may have added to the message body already.
 273       (save-restriction
 274         (message-goto-body)
 275         (narrow-to-region (point) (point-max))
 276         (goto-char (point-max))
 277         (if (re-search-backward message-signature-separator nil t)
 278             (when message-signature-insert-empty-line
 279               (forward-line -1))
 280           (goto-char (point-max))))
 281       (let ((from (plist-get original-headers :From))
 282             (date (plist-get original-headers :Date))
 283             (start (point)))
 284         ;; notmuch-mua-cite-function constructs a citation line based
 285         ;; on the From and Date headers of the original message, which
 286         ;; are assumed to be in the buffer.
 287         (insert "From: " from "\n")
 288         (insert "Date: " date "\n\n")
 289         (insert
 290          (with-temp-buffer
 291            (let
 292                ;; Don't attempt to clean up messages, excerpt
 293                ;; citations, etc. in the original message before
 294                ;; quoting.
 295                ((notmuch-show-insert-text/plain-hook nil)
 296                 ;; Don't omit long parts.
 297                 (notmuch-show-max-text-part-size 0)
 298                 ;; Insert headers for parts as appropriate for replying.
 299                 (notmuch-show-insert-header-p-function
 300                  notmuch-mua-reply-insert-header-p-function)
 301                 ;; Ensure that any encrypted parts are
 302                 ;; decrypted during the generation of the reply
 303                 ;; text.
 304                 (notmuch-show-process-crypto process-crypto)
 305                 ;; Don't indent multipart sub-parts.
 306                 (notmuch-show-indent-multipart nil))
 307              ;; We don't want sigstatus buttons (an information leak and usually wrong anyway).
 308              (cl-letf (((symbol-function 'notmuch-crypto-insert-sigstatus-button) #'ignore)
 309                        ((symbol-function 'notmuch-crypto-insert-encstatus-button) #'ignore))
 310                (notmuch-show-insert-body original (plist-get original :body) 0)
 311                (buffer-substring-no-properties (point-min) (point-max))))))
 312         (set-mark (point))
 313         (goto-char start)
 314         ;; Quote the original message according to the user's configured style.
 315         (funcall notmuch-mua-cite-function)))
 316     ;; Crypto processing based crypto content of the original message
 317     (when process-crypto
 318       (notmuch-mua-reply-crypto (plist-get original :body))))
 319   ;; Push mark right before signature, if any.
 320   (message-goto-signature)
 321   (unless (eobp)
 322     (end-of-line -1))
 323   (push-mark)
 324   (message-goto-body)
 325   (set-buffer-modified-p nil))
 326
 327 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
 328   "Notmuch message composition mode. Mostly like `message-mode'."
 329   (notmuch-address-setup))
 330
 331 (put 'notmuch-message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 332
 333 (define-key notmuch-message-mode-map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
 334 (define-key notmuch-message-mode-map (kbd "C-c C-s") #'notmuch-mua-send)
 335 (define-key notmuch-message-mode-map (kbd "C-c C-p") #'notmuch-draft-postpone)
 336 (define-key notmuch-message-mode-map (kbd "C-x C-s") #'notmuch-draft-save)
 337
 338 (defun notmuch-mua-pop-to-buffer (name switch-function)
 339   "Pop to buffer NAME, and warn if it already exists and is
 340 modified. This function is notmuch adaptation of
 341 `message-pop-to-buffer'."
 342   (let ((buffer (get-buffer name)))
 343     (if (and buffer
 344              (buffer-name buffer))
 345         (let ((window (get-buffer-window buffer 0)))
 346           (if window
 347               ;; Raise the frame already displaying the message buffer.
 348               (progn
 349                 (select-frame-set-input-focus (window-frame window))
 350                 (select-window window))
 351             (funcall switch-function buffer)
 352             (set-buffer buffer))
 353           (when (and (buffer-modified-p)
 354                      (not (prog1
 355                               (y-or-n-p
 356                                "Message already being composed; erase? ")
 357                             (message nil))))
 358             (error "Message being composed")))
 359       (funcall switch-function name)
 360       (set-buffer name))
 361     (erase-buffer)
 362     (notmuch-message-mode)))
 363
 364 (defun notmuch-mua-mail (&optional to subject other-headers continue
 365                                    switch-function yank-action send-actions
 366                                    return-action &rest ignored)
 367   "Invoke the notmuch mail composition window."
 368   (interactive)
 369   (when notmuch-mua-user-agent-function
 370     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 371       (unless (string= "" user-agent)
 372         (push (cons 'User-Agent user-agent) other-headers))))
 373   (unless (assq 'From other-headers)
 374     (push (cons 'From (message-make-from
 375                        (notmuch-user-name)
 376                        (notmuch-user-primary-email)))
 377           other-headers))
 378   (notmuch-mua-pop-to-buffer (message-buffer-name "mail" to)
 379                              (or switch-function
 380                                  (notmuch-mua-get-switch-function)))
 381   (let ((headers
 382          (append
 383           ;; The following is copied from `message-mail'
 384           `((To . ,(or to "")) (Subject . ,(or subject "")))
 385           ;; C-h f compose-mail says that headers should be specified as
 386           ;; (string . value); however all the rest of message expects
 387           ;; headers to be symbols, not strings (eg message-header-format-alist).
 388           ;; https://lists.gnu.org/archive/html/emacs-devel/2011-01/msg00337.html
 389           ;; We need to convert any string input, eg from rmail-start-mail.
 390           (dolist (h other-headers other-headers)
 391             (when (stringp (car h))
 392               (setcar h (intern (capitalize (car h))))))))
 393         (args (list yank-action send-actions))
 394         ;; Cause `message-setup-1' to do things relevant for mail,
 395         ;; such as observe `message-default-mail-headers'.
 396         (message-this-is-mail t))
 397     ;; message-setup-1 in Emacs 23 does not accept return-action
 398     ;; argument. Pass it only if it is supplied by the caller. This
 399     ;; will never be the case when we're called by `compose-mail' in
 400     ;; Emacs 23.
 401     (when return-action (nconc args '(return-action)))
 402     (apply 'message-setup-1 headers args))
 403   (notmuch-fcc-header-setup)
 404   (message-sort-headers)
 405   (message-hide-headers)
 406   (set-buffer-modified-p nil)
 407   (notmuch-mua-maybe-set-window-dedicated)
 408   (message-goto-to))
 409
 410 (defcustom notmuch-identities nil
 411   "Identities that can be used as the From: address when composing a new message.
 412
 413 If this variable is left unset, then a list will be constructed from the
 414 name and addresses configured in the notmuch configuration file."
 415   :type '(repeat string)
 416   :group 'notmuch-send)
 417
 418 (defcustom notmuch-always-prompt-for-sender nil
 419   "Always prompt for the From: address when composing or forwarding a message.
 420
 421 This is not taken into account when replying to a message, because in that case
 422 the From: header is already filled in by notmuch."
 423   :type 'boolean
 424   :group 'notmuch-send)
 425
 426 (defvar notmuch-mua-sender-history nil)
 427
 428 (defun notmuch-mua-prompt-for-sender ()
 429   "Prompt for a sender from the user's configured identities."
 430   (if notmuch-identities
 431       (ido-completing-read "Send mail from: " notmuch-identities
 432                            nil nil nil 'notmuch-mua-sender-history
 433                            (car notmuch-identities))
 434     (let* ((name (notmuch-user-name))
 435            (addrs (cons (notmuch-user-primary-email)
 436                         (notmuch-user-other-email)))
 437            (address
 438             (ido-completing-read (concat "Sender address for " name ": ") addrs
 439                                  nil nil nil 'notmuch-mua-sender-history
 440                                  (car addrs))))
 441       (message-make-from name address))))
 442
 443 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 444 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 445   "Compose new mail.
 446
 447 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 448 the From: address first."
 449   (interactive "P")
 450   (let ((other-headers
 451          (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 452               (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 453     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 454
 455 (defun notmuch-mua-new-forward-messages (messages &optional prompt-for-sender)
 456   "Compose a new message forwarding MESSAGES.
 457
 458 If PROMPT-FOR-SENDER is non-nil, the user will be prompteed for
 459 the From: address."
 460   (let* ((other-headers
 461           (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 462                (list (cons 'From (notmuch-mua-prompt-for-sender)))))
 463          ;; Comes from the first message and is applied later.
 464          forward-subject
 465          ;; List of accumulated message-references of forwarded messages.
 466          forward-references
 467          ;; List of corresponding message-query.
 468          forward-queries)
 469     ;; Generate the template for the outgoing message.
 470     (notmuch-mua-mail nil "" other-headers nil (notmuch-mua-get-switch-function))
 471     (save-excursion
 472       ;; Insert all of the forwarded messages.
 473       (mapc (lambda (id)
 474               (let ((temp-buffer (get-buffer-create
 475                                   (concat "*notmuch-fwd-raw-" id "*"))))
 476                 ;; Get the raw version of this message in the buffer.
 477                 (with-current-buffer temp-buffer
 478                   (erase-buffer)
 479                   (let ((coding-system-for-read 'no-conversion))
 480                     (call-process notmuch-command nil t nil
 481                                   "show" "--format=raw" id))
 482                   ;; Because we process the messages in reverse order,
 483                   ;; always generate a forwarded subject, then use the
 484                   ;; last (i.e. first) one.
 485                   (setq forward-subject (message-make-forward-subject))
 486                   (push (message-fetch-field "Message-ID") forward-references)
 487                   (push id forward-queries))
 488                 ;; Make a copy ready to be forwarded in the
 489                 ;; composition buffer.
 490                 (message-forward-make-body temp-buffer)
 491                 ;; Kill the temporary buffer.
 492                 (kill-buffer temp-buffer)))
 493             ;; `message-forward-make-body' always puts the message at
 494             ;; the top, so do them in reverse order.
 495             (reverse messages))
 496       ;; Add in the appropriate subject.
 497       (save-restriction
 498         (message-narrow-to-headers)
 499         (message-remove-header "Subject")
 500         (message-add-header (concat "Subject: " forward-subject))
 501         (message-remove-header "References")
 502         (message-add-header (concat "References: "
 503                                     (mapconcat 'identity forward-references " "))))
 504       ;; Create a buffer-local queue for tag changes triggered when
 505       ;; sending the message.
 506       (when notmuch-message-forwarded-tags
 507         (setq-local notmuch-message-queued-tag-changes
 508                     (cl-loop for id in forward-queries
 509                              collect
 510                              (cons id notmuch-message-forwarded-tags))))
 511       ;; `message-forward-make-body' shows the User-agent header.  Hide
 512       ;; it again.
 513       (message-hide-headers)
 514       (set-buffer-modified-p nil))))
 515
 516 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 517   "Compose a reply to the message identified by QUERY-STRING.
 518
 519 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 520 the From: address first.  If REPLY-ALL is non-nil, the message
 521 will be addressed to all recipients of the source message."
 522   ;; In current emacs (24.3) select-active-regions is set to t by
 523   ;; default. The reply insertion code sets the region to the quoted
 524   ;; message to make it easy to delete (kill-region or C-w). These two
 525   ;; things combine to put the quoted message in the primary selection.
 526   ;;
 527   ;; This is not what the user wanted and is a privacy risk (accidental
 528   ;; pasting of the quoted message). We can avoid some of the problems
 529   ;; by let-binding select-active-regions to nil. This fixes if the
 530   ;; primary selection was previously in a non-emacs window but not if
 531   ;; it was in an emacs window. To avoid the problem in the latter case
 532   ;; we deactivate mark.
 533   (let ((sender (and prompt-for-sender
 534                      (notmuch-mua-prompt-for-sender)))
 535         (select-active-regions nil))
 536     (notmuch-mua-reply query-string sender reply-all)
 537     (deactivate-mark)))
 538
 539 (defun notmuch-mua-check-no-misplaced-secure-tag ()
 540   "Query user if there is a misplaced secure mml tag.
 541
 542 Emacs message-send will (probably) ignore a secure mml tag unless
 543 it is at the start of the body. Returns t if there is no such
 544 tag, or the user confirms they mean it."
 545   (save-excursion
 546     (let ((body-start (progn (message-goto-body) (point))))
 547       (goto-char (point-max))
 548       (or
 549        ;; We are always fine if there is no secure tag.
 550        (not (search-backward "<#secure" nil 't))
 551        ;; There is a secure tag, so it must be at the start of the
 552        ;; body, with no secure tag earlier (i.e., in the headers).
 553        (and (= (point) body-start)
 554             (not (search-backward "<#secure" nil 't)))
 555        ;; The user confirms they means it.
 556        (yes-or-no-p "\
 557 There is a <#secure> tag not at the start of the body. It is
 558 likely that the message will be sent unsigned and unencrypted.
 559 Really send? ")))))
 560
 561 (defun notmuch-mua-check-secure-tag-has-newline ()
 562   "Query if the secure mml tag has a newline following it.
 563
 564 Emacs message-send will (probably) ignore a correctly placed
 565 secure mml tag unless it is followed by a newline. Returns t if
 566 any secure tag is followed by a newline, or the user confirms
 567 they mean it."
 568   (save-excursion
 569     (message-goto-body)
 570     (or
 571      ;; There is no (correctly placed) secure tag.
 572      (not (looking-at "<#secure"))
 573      ;; The secure tag is followed by a newline.
 574      (looking-at "<#secure[^\n>]*>\n")
 575      ;; The user confirms they means it.
 576      (yes-or-no-p "\
 577 The <#secure> tag at the start of the body is not followed by a
 578 newline. It is likely that the message will be sent unsigned and
 579 unencrypted.  Really send? "))))
 580
 581 (defun notmuch-mua-send-common (arg &optional exit)
 582   (interactive "P")
 583   (run-hooks 'notmuch-mua-send-hook)
 584   (when (and (notmuch-mua-check-no-misplaced-secure-tag)
 585              (notmuch-mua-check-secure-tag-has-newline))
 586     (cl-letf (((symbol-function 'message-do-fcc)
 587                #'notmuch-maildir-message-do-fcc))
 588       (if exit
 589           (message-send-and-exit arg)
 590         (message-send arg)))))
 591
 592 (defun notmuch-mua-send-and-exit (&optional arg)
 593   (interactive "P")
 594   (notmuch-mua-send-common arg 't))
 595
 596 (defun notmuch-mua-send (&optional arg)
 597   (interactive "P")
 598   (notmuch-mua-send-common arg))
 599
 600 (defun notmuch-mua-kill-buffer ()
 601   (interactive)
 602   (message-kill-buffer))
 603
 604 (defun notmuch-mua-message-send-hook ()
 605   "The default function used for `notmuch-mua-send-hook', this
 606 simply runs the corresponding `message-mode' hook functions."
 607   (run-hooks 'message-send-hook))
 608
 609 ;;
 610
 611 (define-mail-user-agent 'notmuch-user-agent
 612   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 613   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 614
 615 ;; Add some more headers to the list that `message-mode' hides when
 616 ;; composing a message.
 617 (notmuch-mua-add-more-hidden-headers)
 618
 619 ;;
 620
 621 (provide 'notmuch-mua)
 622
 623 ;;; notmuch-mua.el ends here