git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23
  24 (require 'notmuch-lib)
  25 (require 'notmuch-address)
  26
  27 ;;
  28
  29 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  30   "Hook run before sending messages."
  31   :group 'notmuch
  32   :type 'hook)
  33
  34 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  35   "Function used to generate a `User-Agent:' string. If this is
  36 `nil' then no `User-Agent:' will be generated."
  37   :group 'notmuch
  38   :type '(choice (const :tag "No user agent string" nil)
  39                  (const :tag "Full" notmuch-mua-user-agent-full)
  40                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  41                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  42                  (function :tag "Custom user agent function"
  43                            :value notmuch-mua-user-agent-full)))
  44
  45 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  46   "Headers that are added to the `message-mode' hidden headers
  47 list."
  48   :group 'notmuch
  49   :type '(repeat string))
  50
  51 ;;
  52
  53 (defun notmuch-mua-user-agent-full ()
  54   "Generate a `User-Agent:' string suitable for notmuch."
  55   (concat (notmuch-mua-user-agent-notmuch)
  56           " "
  57           (notmuch-mua-user-agent-emacs)))
  58
  59 (defun notmuch-mua-user-agent-notmuch ()
  60   "Generate a `User-Agent:' string suitable for notmuch."
  61   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
  62
  63 (defun notmuch-mua-user-agent-emacs ()
  64   "Generate a `User-Agent:' string suitable for notmuch."
  65   (concat "Emacs/" emacs-version " (" system-configuration ")"))
  66
  67 (defun notmuch-mua-add-more-hidden-headers ()
  68   "Add some headers to the list that are hidden by default."
  69   (mapc (lambda (header)
  70           (when (not (member header message-hidden-headers))
  71             (push header message-hidden-headers)))
  72         notmuch-mua-hidden-headers))
  73
  74 (defun notmuch-mua-reply (query-string &optional sender)
  75   (let (headers
  76         body
  77         (args '("reply")))
  78     (if notmuch-show-process-crypto
  79         (setq args (append args '("--decrypt"))))
  80     (setq args (append args (list query-string)))
  81     ;; This make assumptions about the output of `notmuch reply', but
  82     ;; really only that the headers come first followed by a blank
  83     ;; line and then the body.
  84     (with-temp-buffer
  85       (apply 'call-process (append (list notmuch-command nil (list t t) nil) args))
  86       (goto-char (point-min))
  87       (if (re-search-forward "^$" nil t)
  88           (save-excursion
  89             (save-restriction
  90               (narrow-to-region (point-min) (point))
  91               (goto-char (point-min))
  92               (setq headers (mail-header-extract)))))
  93       (forward-line 1)
  94       (setq body (buffer-substring (point) (point-max))))
  95     ;; If sender is non-nil, set the From: header to its value.
  96     (when sender
  97       (mail-header-set 'from sender headers))
  98     (let
  99         ;; Overlay the composition window on that being used to read
 100         ;; the original message.
 101         ((same-window-regexps '("\\*mail .*")))
 102       (notmuch-mua-mail (mail-header 'to headers)
 103                         (mail-header 'subject headers)
 104                         (message-headers-to-generate headers t '(to subject))))
 105     ;; insert the message body - but put it in front of the signature
 106     ;; if one is present
 107     (goto-char (point-max))
 108     (if (re-search-backward message-signature-separator nil t)
 109           (forward-line -1)
 110       (goto-char (point-max)))
 111     (insert body)
 112     (push-mark))
 113   (set-buffer-modified-p nil)
 114
 115   (message-goto-body))
 116
 117 (defun notmuch-mua-forward-message ()
 118   (message-forward)
 119
 120   (when notmuch-mua-user-agent-function
 121     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 122       (when (not (string= "" user-agent))
 123         (message-add-header (format "User-Agent: %s" user-agent)))))
 124   (message-sort-headers)
 125   (message-hide-headers)
 126   (set-buffer-modified-p nil)
 127
 128   (message-goto-to))
 129
 130 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 131   "Invoke the notmuch mail composition window.
 132
 133 OTHER-ARGS are passed through to `message-mail'."
 134   (interactive)
 135
 136   (when notmuch-mua-user-agent-function
 137     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 138       (when (not (string= "" user-agent))
 139         (push (cons "User-Agent" user-agent) other-headers))))
 140
 141   (unless (mail-header 'from other-headers)
 142     (push (cons "From" (concat
 143                         (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 144
 145   (apply #'message-mail to subject other-headers other-args)
 146   (message-sort-headers)
 147   (message-hide-headers)
 148   (set-buffer-modified-p nil)
 149
 150   (message-goto-to))
 151
 152 (defcustom notmuch-identities nil
 153   "Identities that can be used as the From: address when composing a new message.
 154
 155 If this variable is left unset, then a list will be constructed from the
 156 name and addresses configured in the notmuch configuration file."
 157   :group 'notmuch
 158   :type '(repeat string))
 159
 160 (defcustom notmuch-always-prompt-for-sender nil
 161   "Always prompt for the From: address when composing or forwarding a message.
 162
 163 This is not taken into account when replying to a message, because in that case
 164 the From: header is already filled in by notmuch."
 165   :group 'notmuch
 166   :type 'boolean)
 167
 168 (defvar notmuch-mua-sender-history nil)
 169
 170 (defun notmuch-mua-prompt-for-sender ()
 171   (interactive)
 172   (let (name addresses one-name-only)
 173     ;; If notmuch-identities is non-nil, check if there is a fixed user name.
 174     (if notmuch-identities
 175         (let ((components (mapcar 'mail-extract-address-components notmuch-identities)))
 176           (setq name          (caar components)
 177                 addresses     (mapcar 'cadr components)
 178                 one-name-only (eval
 179                                (cons 'and
 180                                      (mapcar (lambda (identity)
 181                                                (string-equal name (car identity)))
 182                                              components)))))
 183       ;; If notmuch-identities is nil, use values from the notmuch configuration file.
 184       (setq name          (notmuch-user-name)
 185             addresses     (cons (notmuch-user-primary-email) (notmuch-user-other-email))
 186             one-name-only t))
 187     ;; Now prompt the user, either for an email address only or for a full identity.
 188     (if one-name-only
 189         (let ((address
 190                (ido-completing-read (concat "Sender address for " name ": ") addresses
 191                                     nil nil nil 'notmuch-mua-sender-history (car addresses))))
 192           (concat name " <" address ">"))
 193       (ido-completing-read "Send mail From: " notmuch-identities
 194                            nil nil nil 'notmuch-mua-sender-history (car notmuch-identities)))))
 195
 196 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 197   "Invoke the notmuch mail composition window.
 198
 199 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 200 the From: address first."
 201   (interactive "P")
 202   (let ((other-headers
 203          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 204            (list (cons 'from (notmuch-mua-prompt-for-sender))))))
 205     (notmuch-mua-mail nil nil other-headers)))
 206
 207 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 208   "Invoke the notmuch message forwarding window.
 209
 210 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 211 the From: address first."
 212   (interactive "P")
 213   (if (or prompt-for-sender notmuch-always-prompt-for-sender)
 214       (let* ((sender (notmuch-mua-prompt-for-sender))
 215              (address-components (mail-extract-address-components sender))
 216              (user-full-name (car address-components))
 217              (user-mail-address (cadr address-components)))
 218         (notmuch-mua-forward-message))
 219     (notmuch-mua-forward-message)))
 220
 221 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender)
 222   "Invoke the notmuch reply window."
 223   (interactive "P")
 224   (let ((sender
 225          (when prompt-for-sender
 226            (notmuch-mua-prompt-for-sender))))
 227     (notmuch-mua-reply query-string sender)))
 228
 229 (defun notmuch-mua-send-and-exit (&optional arg)
 230   (interactive "P")
 231   (message-send-and-exit arg))
 232
 233 (defun notmuch-mua-kill-buffer ()
 234   (interactive)
 235   (message-kill-buffer))
 236
 237 (defun notmuch-mua-message-send-hook ()
 238   "The default function used for `notmuch-mua-send-hook', this
 239 simply runs the corresponding `message-mode' hook functions."
 240   (run-hooks 'message-send-hook))
 241
 242 ;;
 243
 244 (define-mail-user-agent 'notmuch-user-agent
 245   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 246   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 247
 248 ;; Add some more headers to the list that `message-mode' hides when
 249 ;; composing a message.
 250 (notmuch-mua-add-more-hidden-headers)
 251
 252 ;;
 253
 254 (provide 'notmuch-mua)