git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23 (require 'mm-view)
  24 (require 'format-spec)
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-address)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth &optional hide))
  32
  33 ;;
  34
  35 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  36   "Hook run before sending messages."
  37   :type 'hook
  38   :group 'notmuch-send
  39   :group 'notmuch-hooks)
  40
  41 (defcustom notmuch-mua-compose-in 'current-window
  42   (concat
  43    "Where to create the mail buffer used to compose a new message.
  44 Possible values are `current-window' (default), `new-window' and
  45 `new-frame'. If set to `current-window', the mail buffer will be
  46 displayed in the current window, so the old buffer will be
  47 restored when the mail buffer is killed. If set to `new-window'
  48 or `new-frame', the mail buffer will be displayed in a new
  49 window/frame that will be destroyed when the buffer is killed.
  50 You may want to customize `message-kill-buffer-on-exit'
  51 accordingly."
  52    (when (< emacs-major-version 24)
  53            " Due to a known bug in Emacs 23, you should not set
  54 this to `new-window' if `message-kill-buffer-on-exit' is
  55 disabled: this would result in an incorrect behavior."))
  56   :group 'notmuch-send
  57   :type '(choice (const :tag "Compose in the current window" current-window)
  58                  (const :tag "Compose mail in a new window"  new-window)
  59                  (const :tag "Compose mail in a new frame"   new-frame)))
  60
  61 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  62   "Function used to generate a `User-Agent:' string. If this is
  63 `nil' then no `User-Agent:' will be generated."
  64   :type '(choice (const :tag "No user agent string" nil)
  65                  (const :tag "Full" notmuch-mua-user-agent-full)
  66                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  67                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  68                  (function :tag "Custom user agent function"
  69                            :value notmuch-mua-user-agent-full))
  70   :group 'notmuch-send)
  71
  72 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  73   "Headers that are added to the `message-mode' hidden headers
  74 list."
  75   :type '(repeat string)
  76   :group 'notmuch-send)
  77
  78 ;;
  79
  80 (defun notmuch-mua-get-switch-function ()
  81   "Get a switch function according to `notmuch-mua-compose-in'."
  82   (cond ((eq notmuch-mua-compose-in 'current-window)
  83          'switch-to-buffer)
  84         ((eq notmuch-mua-compose-in 'new-window)
  85          'switch-to-buffer-other-window)
  86         ((eq notmuch-mua-compose-in 'new-frame)
  87          'switch-to-buffer-other-frame)
  88         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
  89
  90 (defun notmuch-mua-maybe-set-window-dedicated ()
  91   "Set the selected window as dedicated according to
  92 `notmuch-mua-compose-in'."
  93   (when (or (eq notmuch-mua-compose-in 'new-frame)
  94             (eq notmuch-mua-compose-in 'new-window))
  95     (set-window-dedicated-p (selected-window) t)))
  96
  97 (defun notmuch-mua-user-agent-full ()
  98   "Generate a `User-Agent:' string suitable for notmuch."
  99   (concat (notmuch-mua-user-agent-notmuch)
 100           " "
 101           (notmuch-mua-user-agent-emacs)))
 102
 103 (defun notmuch-mua-user-agent-notmuch ()
 104   "Generate a `User-Agent:' string suitable for notmuch."
 105   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
 106
 107 (defun notmuch-mua-user-agent-emacs ()
 108   "Generate a `User-Agent:' string suitable for notmuch."
 109   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 110
 111 (defun notmuch-mua-add-more-hidden-headers ()
 112   "Add some headers to the list that are hidden by default."
 113   (mapc (lambda (header)
 114           (when (not (member header message-hidden-headers))
 115             (push header message-hidden-headers)))
 116         notmuch-mua-hidden-headers))
 117
 118 (defun notmuch-mua-get-quotable-parts (parts)
 119   (loop for part in parts
 120         if (notmuch-match-content-type (plist-get part :content-type) "multipart/alternative")
 121           collect (let* ((subparts (plist-get part :content))
 122                         (types (mapcar (lambda (part) (plist-get part :content-type)) subparts))
 123                         (chosen-type (car (notmuch-multipart/alternative-choose types))))
 124                    (loop for part in (reverse subparts)
 125                          if (notmuch-match-content-type (plist-get part :content-type) chosen-type)
 126                          return part))
 127         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 128           append (notmuch-mua-get-quotable-parts (plist-get part :content))
 129         else if (notmuch-match-content-type (plist-get part :content-type) "text/*")
 130           collect part))
 131
 132 (defun notmuch-mua-insert-quotable-part (message part)
 133   ;; We don't want text properties leaking from the show renderer into
 134   ;; the reply so we use a temp buffer. Also we don't want hooks, such
 135   ;; as notmuch-wash-*, to be run on the quotable part so we set
 136   ;; notmuch-show-insert-text/plain-hook to nil.
 137   (insert (with-temp-buffer
 138             (let ((notmuch-show-insert-text/plain-hook nil))
 139               ;; Show the part but do not add buttons.
 140               (notmuch-show-insert-bodypart message part 0 'no-buttons))
 141             (buffer-substring-no-properties (point-min) (point-max)))))
 142
 143 ;; There is a bug in emacs 23's message.el that results in a newline
 144 ;; not being inserted after the References header, so the next header
 145 ;; is concatenated to the end of it. This function fixes the problem,
 146 ;; while guarding against the possibility that some current or future
 147 ;; version of emacs has the bug fixed.
 148 (defun notmuch-mua-insert-references (original-func header references)
 149   (funcall original-func header references)
 150   (unless (bolp) (insert "\n")))
 151
 152 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 153   (let ((args '("reply" "--format=sexp" "--format-version=1"))
 154         reply
 155         original)
 156     (when notmuch-show-process-crypto
 157       (setq args (append args '("--decrypt"))))
 158
 159     (if reply-all
 160         (setq args (append args '("--reply-to=all")))
 161       (setq args (append args '("--reply-to=sender"))))
 162     (setq args (append args (list query-string)))
 163
 164     ;; Get the reply object as SEXP, and parse it into an elisp object.
 165     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 166
 167     ;; Extract the original message to simplify the following code.
 168     (setq original (plist-get reply :original))
 169
 170     ;; Extract the headers of both the reply and the original message.
 171     (let* ((original-headers (plist-get original :headers))
 172            (reply-headers (plist-get reply :reply-headers)))
 173
 174       ;; If sender is non-nil, set the From: header to its value.
 175       (when sender
 176         (plist-put reply-headers :From sender))
 177       (let
 178           ;; Overlay the composition window on that being used to read
 179           ;; the original message.
 180           ((same-window-regexps '("\\*mail .*")))
 181
 182         ;; We modify message-header-format-alist to get around a bug in message.el.
 183         ;; See the comment above on notmuch-mua-insert-references.
 184         (let ((message-header-format-alist
 185                (loop for pair in message-header-format-alist
 186                      if (eq (car pair) 'References)
 187                      collect (cons 'References
 188                                    (apply-partially
 189                                     'notmuch-mua-insert-references
 190                                     (cdr pair)))
 191                      else
 192                      collect pair)))
 193           (notmuch-mua-mail (plist-get reply-headers :To)
 194                             (plist-get reply-headers :Subject)
 195                             (notmuch-headers-plist-to-alist reply-headers)
 196                             nil (notmuch-mua-get-switch-function))))
 197
 198       ;; Insert the message body - but put it in front of the signature
 199       ;; if one is present, and after any other content
 200       ;; message*setup-hooks may have added to the message body already.
 201       (save-restriction
 202         (message-goto-body)
 203         (narrow-to-region (point) (point-max))
 204         (goto-char (point-max))
 205         (if (re-search-backward message-signature-separator nil t)
 206             (if message-signature-insert-empty-line
 207                 (forward-line -1))
 208           (goto-char (point-max))))
 209
 210       (let ((from (plist-get original-headers :From))
 211             (date (plist-get original-headers :Date))
 212             (start (point)))
 213
 214         ;; message-cite-original constructs a citation line based on the From and Date
 215         ;; headers of the original message, which are assumed to be in the buffer.
 216         (insert "From: " from "\n")
 217         (insert "Date: " date "\n\n")
 218
 219         ;; Get the parts of the original message that should be quoted; this includes
 220         ;; all the text parts, except the non-preferred ones in a multipart/alternative.
 221         (let ((quotable-parts (notmuch-mua-get-quotable-parts (plist-get original :body))))
 222           (mapc (apply-partially 'notmuch-mua-insert-quotable-part original) quotable-parts))
 223
 224         (set-mark (point))
 225         (goto-char start)
 226         ;; Quote the original message according to the user's configured style.
 227         (message-cite-original))))
 228
 229   (goto-char (point-max))
 230   (push-mark)
 231   (message-goto-body)
 232   (set-buffer-modified-p nil))
 233
 234 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 235   "Invoke the notmuch mail composition window.
 236
 237 OTHER-ARGS are passed through to `message-mail'."
 238   (interactive)
 239
 240   (when notmuch-mua-user-agent-function
 241     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 242       (when (not (string= "" user-agent))
 243         (push (cons 'User-Agent user-agent) other-headers))))
 244
 245   (unless (assq 'From other-headers)
 246     (push (cons 'From (concat
 247                        (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 248
 249   (apply #'message-mail to subject other-headers other-args)
 250   (message-sort-headers)
 251   (message-hide-headers)
 252   (set-buffer-modified-p nil)
 253   (notmuch-mua-maybe-set-window-dedicated)
 254
 255   (message-goto-to))
 256
 257 (defcustom notmuch-identities nil
 258   "Identities that can be used as the From: address when composing a new message.
 259
 260 If this variable is left unset, then a list will be constructed from the
 261 name and addresses configured in the notmuch configuration file."
 262   :type '(repeat string)
 263   :group 'notmuch-send)
 264
 265 (defcustom notmuch-always-prompt-for-sender nil
 266   "Always prompt for the From: address when composing or forwarding a message.
 267
 268 This is not taken into account when replying to a message, because in that case
 269 the From: header is already filled in by notmuch."
 270   :type 'boolean
 271   :group 'notmuch-send)
 272
 273 (defvar notmuch-mua-sender-history nil)
 274
 275 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
 276 ;; without some explicit initialization fill freeze the operation.
 277 ;; Hence, we advice `ido-completing-read' to ensure required initialization
 278 ;; is done.
 279 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
 280     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
 281       (ido-init-completion-maps)
 282       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
 283       (add-hook 'choose-completion-string-functions
 284                 'ido-choose-completion-string)
 285       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
 286       (ad-activate 'ido-completing-read)))
 287
 288 (defun notmuch-mua-prompt-for-sender ()
 289   (interactive)
 290   (let (name addresses one-name-only)
 291     ;; If notmuch-identities is non-nil, check if there is a fixed user name.
 292     (if notmuch-identities
 293         (let ((components (mapcar 'mail-extract-address-components notmuch-identities)))
 294           (setq name          (caar components)
 295                 addresses     (mapcar 'cadr components)
 296                 one-name-only (eval
 297                                (cons 'and
 298                                      (mapcar (lambda (identity)
 299                                                (string-equal name (car identity)))
 300                                              components)))))
 301       ;; If notmuch-identities is nil, use values from the notmuch configuration file.
 302       (setq name          (notmuch-user-name)
 303             addresses     (cons (notmuch-user-primary-email) (notmuch-user-other-email))
 304             one-name-only t))
 305     ;; Now prompt the user, either for an email address only or for a full identity.
 306     (if one-name-only
 307         (let ((address
 308                (ido-completing-read (concat "Sender address for " name ": ") addresses
 309                                     nil nil nil 'notmuch-mua-sender-history (car addresses))))
 310           (concat name " <" address ">"))
 311       (ido-completing-read "Send mail From: " notmuch-identities
 312                            nil nil nil 'notmuch-mua-sender-history (car notmuch-identities)))))
 313
 314 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 315 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 316   "Compose new mail.
 317
 318 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 319 the From: address first."
 320   (interactive "P")
 321   (let ((other-headers
 322          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 323            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 324     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 325
 326 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 327   "Invoke the notmuch message forwarding window.
 328
 329 The current buffer must contain an RFC2822 message to forward.
 330
 331 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 332 the From: address first."
 333   (let* ((cur (current-buffer))
 334          (message-forward-decoded-p nil)
 335          (subject (message-make-forward-subject))
 336          (other-headers
 337           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 338             (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 339     (notmuch-mua-mail nil subject other-headers nil (notmuch-mua-get-switch-function))
 340     (message-forward-make-body cur)
 341     ;; `message-forward-make-body' shows the User-agent header.  Hide
 342     ;; it again.
 343     (message-hide-headers)))
 344
 345 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 346   "Compose a reply to the message identified by QUERY-STRING.
 347
 348 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 349 the From: address first.  If REPLY-ALL is non-nil, the message
 350 will be addressed to all recipients of the source message."
 351
 352 ;; In current emacs (24.3) select-active-regions is set to t by
 353 ;; default. The reply insertion code sets the region to the quoted
 354 ;; message to make it easy to delete (kill-region or C-w). These two
 355 ;; things combine to put the quoted message in the primary selection.
 356 ;;
 357 ;; This is not what the user wanted and is a privacy risk (accidental
 358 ;; pasting of the quoted message). We can avoid some of the problems
 359 ;; by let-binding select-active-regions to nil. This fixes if the
 360 ;; primary selection was previously in a non-emacs window but not if
 361 ;; it was in an emacs window. To avoid the problem in the latter case
 362 ;; we deactivate mark.
 363
 364   (let ((sender
 365          (when prompt-for-sender
 366            (notmuch-mua-prompt-for-sender)))
 367         (select-active-regions nil))
 368     (notmuch-mua-reply query-string sender reply-all)
 369     (deactivate-mark)))
 370
 371 (defun notmuch-mua-send-and-exit (&optional arg)
 372   (interactive "P")
 373   (message-send-and-exit arg))
 374
 375 (defun notmuch-mua-kill-buffer ()
 376   (interactive)
 377   (message-kill-buffer))
 378
 379 (defun notmuch-mua-message-send-hook ()
 380   "The default function used for `notmuch-mua-send-hook', this
 381 simply runs the corresponding `message-mode' hook functions."
 382   (run-hooks 'message-send-hook))
 383
 384 ;;
 385
 386 (define-mail-user-agent 'notmuch-user-agent
 387   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 388   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 389
 390 ;; Add some more headers to the list that `message-mode' hides when
 391 ;; composing a message.
 392 (notmuch-mua-add-more-hidden-headers)
 393
 394 ;;
 395
 396 (provide 'notmuch-mua)