git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23 (require 'mm-view)
  24 (require 'format-spec)
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-address)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth &optional hide))
  32 (declare-function notmuch-fcc-header-setup "notmuch-maildir-fcc" ())
  33 (declare-function notmuch-fcc-handler "notmuch-maildir-fcc" (destdir))
  34
  35 ;;
  36
  37 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  38   "Hook run before sending messages."
  39   :type 'hook
  40   :group 'notmuch-send
  41   :group 'notmuch-hooks)
  42
  43 (defcustom notmuch-mua-compose-in 'current-window
  44   (concat
  45    "Where to create the mail buffer used to compose a new message.
  46 Possible values are `current-window' (default), `new-window' and
  47 `new-frame'. If set to `current-window', the mail buffer will be
  48 displayed in the current window, so the old buffer will be
  49 restored when the mail buffer is killed. If set to `new-window'
  50 or `new-frame', the mail buffer will be displayed in a new
  51 window/frame that will be destroyed when the buffer is killed.
  52 You may want to customize `message-kill-buffer-on-exit'
  53 accordingly."
  54    (when (< emacs-major-version 24)
  55            " Due to a known bug in Emacs 23, you should not set
  56 this to `new-window' if `message-kill-buffer-on-exit' is
  57 disabled: this would result in an incorrect behavior."))
  58   :group 'notmuch-send
  59   :type '(choice (const :tag "Compose in the current window" current-window)
  60                  (const :tag "Compose mail in a new window"  new-window)
  61                  (const :tag "Compose mail in a new frame"   new-frame)))
  62
  63 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  64   "Function used to generate a `User-Agent:' string. If this is
  65 `nil' then no `User-Agent:' will be generated."
  66   :type '(choice (const :tag "No user agent string" nil)
  67                  (const :tag "Full" notmuch-mua-user-agent-full)
  68                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  69                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  70                  (function :tag "Custom user agent function"
  71                            :value notmuch-mua-user-agent-full))
  72   :group 'notmuch-send)
  73
  74 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  75   "Headers that are added to the `message-mode' hidden headers
  76 list."
  77   :type '(repeat string)
  78   :group 'notmuch-send)
  79
  80 (defgroup notmuch-reply nil
  81   "Replying to messages in notmuch"
  82   :group 'notmuch)
  83
  84 (defcustom notmuch-mua-cite-function 'message-cite-original
  85   "*Function for citing an original message.
  86 Predefined functions include `message-cite-original' and
  87 `message-cite-original-without-signature'.
  88 Note that these functions use `mail-citation-hook' if that is non-nil."
  89   :type '(radio (function-item message-cite-original)
  90                 (function-item message-cite-original-without-signature)
  91                 (function-item sc-cite-original)
  92                 (function :tag "Other"))
  93   :link '(custom-manual "(message)Insertion Variables")
  94   :group 'notmuch-reply)
  95
  96 ;;
  97
  98 (defun notmuch-mua-get-switch-function ()
  99   "Get a switch function according to `notmuch-mua-compose-in'."
 100   (cond ((eq notmuch-mua-compose-in 'current-window)
 101          'switch-to-buffer)
 102         ((eq notmuch-mua-compose-in 'new-window)
 103          'switch-to-buffer-other-window)
 104         ((eq notmuch-mua-compose-in 'new-frame)
 105          'switch-to-buffer-other-frame)
 106         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
 107
 108 (defun notmuch-mua-maybe-set-window-dedicated ()
 109   "Set the selected window as dedicated according to
 110 `notmuch-mua-compose-in'."
 111   (when (or (eq notmuch-mua-compose-in 'new-frame)
 112             (eq notmuch-mua-compose-in 'new-window))
 113     (set-window-dedicated-p (selected-window) t)))
 114
 115 (defun notmuch-mua-user-agent-full ()
 116   "Generate a `User-Agent:' string suitable for notmuch."
 117   (concat (notmuch-mua-user-agent-notmuch)
 118           " "
 119           (notmuch-mua-user-agent-emacs)))
 120
 121 (defun notmuch-mua-user-agent-notmuch ()
 122   "Generate a `User-Agent:' string suitable for notmuch."
 123   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
 124                              (notmuch-cli-version)
 125                            notmuch-emacs-version)))
 126     (concat "Notmuch/" notmuch-version " (http://notmuchmail.org)")))
 127
 128 (defun notmuch-mua-user-agent-emacs ()
 129   "Generate a `User-Agent:' string suitable for notmuch."
 130   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 131
 132 (defun notmuch-mua-add-more-hidden-headers ()
 133   "Add some headers to the list that are hidden by default."
 134   (mapc (lambda (header)
 135           (when (not (member header message-hidden-headers))
 136             (push header message-hidden-headers)))
 137         notmuch-mua-hidden-headers))
 138
 139 (defun notmuch-mua-reply-crypto (parts)
 140   "Add mml sign-encrypt flag if any part of original message is encrypted."
 141   (loop for part in parts
 142         if (notmuch-match-content-type (plist-get part :content-type) "multipart/encrypted")
 143           do (mml-secure-message-sign-encrypt)
 144         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 145           do (notmuch-mua-reply-crypto (plist-get part :content))))
 146
 147 (defun notmuch-mua-get-quotable-parts (parts)
 148   (loop for part in parts
 149         if (notmuch-match-content-type (plist-get part :content-type) "multipart/alternative")
 150           collect (let* ((subparts (plist-get part :content))
 151                         (types (mapcar (lambda (part) (plist-get part :content-type)) subparts))
 152                         (chosen-type (car (notmuch-multipart/alternative-choose types))))
 153                    (loop for part in (reverse subparts)
 154                          if (notmuch-match-content-type (plist-get part :content-type) chosen-type)
 155                          return part))
 156         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 157           append (notmuch-mua-get-quotable-parts (plist-get part :content))
 158         else if (notmuch-match-content-type (plist-get part :content-type) "text/*")
 159           collect part))
 160
 161 (defun notmuch-mua-insert-quotable-part (message part)
 162   ;; We don't want text properties leaking from the show renderer into
 163   ;; the reply so we use a temp buffer. Also we don't want hooks, such
 164   ;; as notmuch-wash-*, to be run on the quotable part so we set
 165   ;; notmuch-show-insert-text/plain-hook to nil.
 166   (insert (with-temp-buffer
 167             (let ((notmuch-show-insert-text/plain-hook nil))
 168               ;; Show the part but do not add buttons.
 169               (notmuch-show-insert-bodypart message part 0 'no-buttons))
 170             (buffer-substring-no-properties (point-min) (point-max)))))
 171
 172 ;; There is a bug in emacs 23's message.el that results in a newline
 173 ;; not being inserted after the References header, so the next header
 174 ;; is concatenated to the end of it. This function fixes the problem,
 175 ;; while guarding against the possibility that some current or future
 176 ;; version of emacs has the bug fixed.
 177 (defun notmuch-mua-insert-references (original-func header references)
 178   (funcall original-func header references)
 179   (unless (bolp) (insert "\n")))
 180
 181 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 182   (let ((args '("reply" "--format=sexp" "--format-version=1"))
 183         (process-crypto notmuch-show-process-crypto)
 184         reply
 185         original)
 186     (when process-crypto
 187       (setq args (append args '("--decrypt"))))
 188
 189     (if reply-all
 190         (setq args (append args '("--reply-to=all")))
 191       (setq args (append args '("--reply-to=sender"))))
 192     (setq args (append args (list query-string)))
 193
 194     ;; Get the reply object as SEXP, and parse it into an elisp object.
 195     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 196
 197     ;; Extract the original message to simplify the following code.
 198     (setq original (plist-get reply :original))
 199
 200     ;; Extract the headers of both the reply and the original message.
 201     (let* ((original-headers (plist-get original :headers))
 202            (reply-headers (plist-get reply :reply-headers)))
 203
 204       ;; If sender is non-nil, set the From: header to its value.
 205       (when sender
 206         (plist-put reply-headers :From sender))
 207       (let
 208           ;; Overlay the composition window on that being used to read
 209           ;; the original message.
 210           ((same-window-regexps '("\\*mail .*")))
 211
 212         ;; We modify message-header-format-alist to get around a bug in message.el.
 213         ;; See the comment above on notmuch-mua-insert-references.
 214         (let ((message-header-format-alist
 215                (loop for pair in message-header-format-alist
 216                      if (eq (car pair) 'References)
 217                      collect (cons 'References
 218                                    (apply-partially
 219                                     'notmuch-mua-insert-references
 220                                     (cdr pair)))
 221                      else
 222                      collect pair)))
 223           (notmuch-mua-mail (plist-get reply-headers :To)
 224                             (plist-get reply-headers :Subject)
 225                             (notmuch-headers-plist-to-alist reply-headers)
 226                             nil (notmuch-mua-get-switch-function))))
 227
 228       ;; Insert the message body - but put it in front of the signature
 229       ;; if one is present, and after any other content
 230       ;; message*setup-hooks may have added to the message body already.
 231       (save-restriction
 232         (message-goto-body)
 233         (narrow-to-region (point) (point-max))
 234         (goto-char (point-max))
 235         (if (re-search-backward message-signature-separator nil t)
 236             (if message-signature-insert-empty-line
 237                 (forward-line -1))
 238           (goto-char (point-max))))
 239
 240       (let ((from (plist-get original-headers :From))
 241             (date (plist-get original-headers :Date))
 242             (start (point)))
 243
 244         ;; notmuch-mua-cite-function constructs a citation line based
 245         ;; on the From and Date headers of the original message, which
 246         ;; are assumed to be in the buffer.
 247         (insert "From: " from "\n")
 248         (insert "Date: " date "\n\n")
 249
 250         ;; Get the parts of the original message that should be quoted; this includes
 251         ;; all the text parts, except the non-preferred ones in a multipart/alternative.
 252         (let ((quotable-parts (notmuch-mua-get-quotable-parts (plist-get original :body))))
 253           (mapc (apply-partially 'notmuch-mua-insert-quotable-part original) quotable-parts))
 254
 255         (set-mark (point))
 256         (goto-char start)
 257         ;; Quote the original message according to the user's configured style.
 258         (funcall notmuch-mua-cite-function)))
 259
 260     ;; Crypto processing based crypto content of the original message
 261     (when process-crypto
 262       (notmuch-mua-reply-crypto (plist-get original :body))))
 263
 264   ;; Push mark right before signature, if any.
 265   (message-goto-signature)
 266   (unless (eobp)
 267     (end-of-line -1))
 268   (push-mark)
 269
 270   (message-goto-body)
 271   (set-buffer-modified-p nil))
 272
 273 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
 274   "Notmuch message composition mode. Mostly like `message-mode'"
 275   (when notmuch-address-command
 276     (notmuch-address-setup)))
 277
 278 (put 'notmuch-message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 279
 280 (define-key notmuch-message-mode-map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
 281 (define-key notmuch-message-mode-map (kbd "C-c C-s") #'notmuch-mua-send)
 282
 283 (defun notmuch-mua-pop-to-buffer (name switch-function)
 284   "Pop to buffer NAME, and warn if it already exists and is
 285 modified. This function is notmuch addaptation of
 286 `message-pop-to-buffer'."
 287   (let ((buffer (get-buffer name)))
 288     (if (and buffer
 289              (buffer-name buffer))
 290         (let ((window (get-buffer-window buffer 0)))
 291           (if window
 292               ;; Raise the frame already displaying the message buffer.
 293               (progn
 294                 (gnus-select-frame-set-input-focus (window-frame window))
 295                 (select-window window))
 296             (funcall switch-function buffer)
 297             (set-buffer buffer))
 298           (when (and (buffer-modified-p)
 299                      (not (prog1
 300                               (y-or-n-p
 301                                "Message already being composed; erase? ")
 302                             (message nil))))
 303             (error "Message being composed")))
 304       (funcall switch-function name)
 305       (set-buffer name))
 306     (erase-buffer)
 307     (notmuch-message-mode)))
 308
 309 (defun notmuch-mua-mail (&optional to subject other-headers continue
 310                                    switch-function yank-action send-actions
 311                                    return-action &rest ignored)
 312   "Invoke the notmuch mail composition window."
 313   (interactive)
 314
 315   (when notmuch-mua-user-agent-function
 316     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 317       (when (not (string= "" user-agent))
 318         (push (cons 'User-Agent user-agent) other-headers))))
 319
 320   (unless (assq 'From other-headers)
 321     (push (cons 'From (concat
 322                        (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 323
 324   (notmuch-mua-pop-to-buffer (message-buffer-name "mail" to)
 325                              (or switch-function (notmuch-mua-get-switch-function)))
 326   (let ((headers
 327          (append
 328           ;; The following is copied from `message-mail'
 329           `((To . ,(or to "")) (Subject . ,(or subject "")))
 330           ;; C-h f compose-mail says that headers should be specified as
 331           ;; (string . value); however all the rest of message expects
 332           ;; headers to be symbols, not strings (eg message-header-format-alist).
 333           ;; http://lists.gnu.org/archive/html/emacs-devel/2011-01/msg00337.html
 334           ;; We need to convert any string input, eg from rmail-start-mail.
 335           (dolist (h other-headers other-headers)
 336             (if (stringp (car h)) (setcar h (intern (capitalize (car h))))))))
 337         (args (list yank-action send-actions)))
 338     ;; message-setup-1 in Emacs 23 does not accept return-action
 339     ;; argument. Pass it only if it is supplied by the caller. This
 340     ;; will never be the case when we're called by `compose-mail' in
 341     ;; Emacs 23.
 342     (when return-action (nconc args '(return-action)))
 343     (apply 'message-setup-1 headers args))
 344   (notmuch-fcc-header-setup)
 345   (message-sort-headers)
 346   (message-hide-headers)
 347   (set-buffer-modified-p nil)
 348   (notmuch-mua-maybe-set-window-dedicated)
 349
 350   (message-goto-to))
 351
 352 (defcustom notmuch-identities nil
 353   "Identities that can be used as the From: address when composing a new message.
 354
 355 If this variable is left unset, then a list will be constructed from the
 356 name and addresses configured in the notmuch configuration file."
 357   :type '(repeat string)
 358   :group 'notmuch-send)
 359
 360 (defcustom notmuch-always-prompt-for-sender nil
 361   "Always prompt for the From: address when composing or forwarding a message.
 362
 363 This is not taken into account when replying to a message, because in that case
 364 the From: header is already filled in by notmuch."
 365   :type 'boolean
 366   :group 'notmuch-send)
 367
 368 (defvar notmuch-mua-sender-history nil)
 369
 370 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
 371 ;; without some explicit initialization fill freeze the operation.
 372 ;; Hence, we advice `ido-completing-read' to ensure required initialization
 373 ;; is done.
 374 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
 375     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
 376       (ido-init-completion-maps)
 377       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
 378       (add-hook 'choose-completion-string-functions
 379                 'ido-choose-completion-string)
 380       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
 381       (ad-activate 'ido-completing-read)))
 382
 383 (defun notmuch-mua-prompt-for-sender ()
 384   "Prompt for a sender from the user's configured identities."
 385   (if notmuch-identities
 386       (ido-completing-read "Send mail from: " notmuch-identities
 387                            nil nil nil 'notmuch-mua-sender-history
 388                            (car notmuch-identities))
 389     (let* ((name (notmuch-user-name))
 390            (addrs (cons (notmuch-user-primary-email)
 391                         (notmuch-user-other-email)))
 392            (address
 393             (ido-completing-read (concat "Sender address for " name ": ") addrs
 394                                  nil nil nil 'notmuch-mua-sender-history
 395                                  (car addrs))))
 396       (concat name " <" address ">"))))
 397
 398 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 399 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 400   "Compose new mail.
 401
 402 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 403 the From: address first."
 404   (interactive "P")
 405   (let ((other-headers
 406          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 407            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 408     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 409
 410 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 411   "Invoke the notmuch message forwarding window.
 412
 413 The current buffer must contain an RFC2822 message to forward.
 414
 415 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 416 the From: address first."
 417   (let* ((cur (current-buffer))
 418          (message-forward-decoded-p nil)
 419          (subject (message-make-forward-subject))
 420          (other-headers
 421           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 422             (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 423     (notmuch-mua-mail nil subject other-headers nil (notmuch-mua-get-switch-function))
 424     (message-forward-make-body cur)
 425     ;; `message-forward-make-body' shows the User-agent header.  Hide
 426     ;; it again.
 427     (message-hide-headers)
 428     (set-buffer-modified-p nil)))
 429
 430 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 431   "Compose a reply to the message identified by QUERY-STRING.
 432
 433 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 434 the From: address first.  If REPLY-ALL is non-nil, the message
 435 will be addressed to all recipients of the source message."
 436
 437 ;; In current emacs (24.3) select-active-regions is set to t by
 438 ;; default. The reply insertion code sets the region to the quoted
 439 ;; message to make it easy to delete (kill-region or C-w). These two
 440 ;; things combine to put the quoted message in the primary selection.
 441 ;;
 442 ;; This is not what the user wanted and is a privacy risk (accidental
 443 ;; pasting of the quoted message). We can avoid some of the problems
 444 ;; by let-binding select-active-regions to nil. This fixes if the
 445 ;; primary selection was previously in a non-emacs window but not if
 446 ;; it was in an emacs window. To avoid the problem in the latter case
 447 ;; we deactivate mark.
 448
 449   (let ((sender
 450          (when prompt-for-sender
 451            (notmuch-mua-prompt-for-sender)))
 452         (select-active-regions nil))
 453     (notmuch-mua-reply query-string sender reply-all)
 454     (deactivate-mark)))
 455
 456 (defun notmuch-mua-send-and-exit (&optional arg)
 457   (interactive "P")
 458   (let ((message-fcc-handler-function #'notmuch-fcc-handler))
 459     (message-send-and-exit arg)))
 460
 461 (defun notmuch-mua-send (&optional arg)
 462   (interactive "P")
 463   (let ((message-fcc-handler-function #'notmuch-fcc-handler))
 464     (message-send arg)))
 465
 466 (defun notmuch-mua-kill-buffer ()
 467   (interactive)
 468   (message-kill-buffer))
 469
 470 (defun notmuch-mua-message-send-hook ()
 471   "The default function used for `notmuch-mua-send-hook', this
 472 simply runs the corresponding `message-mode' hook functions."
 473   (run-hooks 'message-send-hook))
 474
 475 ;;
 476
 477 (define-mail-user-agent 'notmuch-user-agent
 478   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 479   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 480
 481 ;; Add some more headers to the list that `message-mode' hides when
 482 ;; composing a message.
 483 (notmuch-mua-add-more-hidden-headers)
 484
 485 ;;
 486
 487 (provide 'notmuch-mua)