git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;;; notmuch-mua.el --- emacs style mail-user-agent  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 ;;; Code:
  23
  24 (require 'message)
  25 (require 'mm-view)
  26 (require 'format-spec)
  27
  28 (require 'notmuch-lib)
  29 (require 'notmuch-address)
  30 (require 'notmuch-draft)
  31 (require 'notmuch-message)
  32
  33 (declare-function notmuch-show-insert-body "notmuch-show" (msg body depth))
  34 (declare-function notmuch-fcc-header-setup "notmuch-maildir-fcc" ())
  35 (declare-function notmuch-maildir-message-do-fcc "notmuch-maildir-fcc" ())
  36 (declare-function notmuch-draft-postpone "notmuch-draft" ())
  37 (declare-function notmuch-draft-save "notmuch-draft" ())
  38
  39 (defvar notmuch-show-indent-multipart)
  40 (defvar notmuch-show-insert-header-p-function)
  41 (defvar notmuch-show-max-text-part-size)
  42 (defvar notmuch-show-insert-text/plain-hook)
  43
  44 ;;; Options
  45
  46 (defcustom notmuch-mua-send-hook nil
  47   "Hook run before sending messages."
  48   :type 'hook
  49   :group 'notmuch-send
  50   :group 'notmuch-hooks)
  51
  52 (defcustom notmuch-mua-compose-in 'current-window
  53   "Where to create the mail buffer used to compose a new message.
  54 Possible values are `current-window' (default), `new-window' and
  55 `new-frame'. If set to `current-window', the mail buffer will be
  56 displayed in the current window, so the old buffer will be
  57 restored when the mail buffer is killed. If set to `new-window'
  58 or `new-frame', the mail buffer will be displayed in a new
  59 window/frame that will be destroyed when the buffer is killed.
  60 You may want to customize `message-kill-buffer-on-exit'
  61 accordingly."
  62   :group 'notmuch-send
  63   :type '(choice (const :tag "Compose in the current window" current-window)
  64                  (const :tag "Compose mail in a new window"  new-window)
  65                  (const :tag "Compose mail in a new frame"   new-frame)))
  66
  67 (defcustom notmuch-mua-user-agent-function nil
  68   "Function used to generate a `User-Agent:' string.
  69 If this is `nil' then no `User-Agent:' will be generated."
  70   :type '(choice (const :tag "No user agent string" nil)
  71                  (const :tag "Full" notmuch-mua-user-agent-full)
  72                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  73                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  74                  (function :tag "Custom user agent function"
  75                            :value notmuch-mua-user-agent-full))
  76   :group 'notmuch-send)
  77
  78 (defcustom notmuch-mua-hidden-headers nil
  79   "Headers that are added to the `message-mode' hidden headers list."
  80   :type '(repeat string)
  81   :group 'notmuch-send)
  82
  83 (defcustom notmuch-identities nil
  84   "Identities that can be used as the From: address when composing a new message.
  85
  86 If this variable is left unset, then a list will be constructed from the
  87 name and addresses configured in the notmuch configuration file."
  88   :type '(repeat string)
  89   :group 'notmuch-send)
  90
  91 (defcustom notmuch-always-prompt-for-sender nil
  92   "Always prompt for the From: address when composing or forwarding a message.
  93
  94 This is not taken into account when replying to a message, because in that case
  95 the From: header is already filled in by notmuch."
  96   :type 'boolean
  97   :group 'notmuch-send)
  98
  99 (defgroup notmuch-reply nil
 100   "Replying to messages in notmuch."
 101   :group 'notmuch)
 102
 103 (defcustom notmuch-mua-cite-function 'message-cite-original
 104   "Function for citing an original message.
 105
 106 Predefined functions include `message-cite-original' and
 107 `message-cite-original-without-signature'.  Note that these
 108 functions use `mail-citation-hook' if that is non-nil."
 109   :type '(radio (function-item message-cite-original)
 110                 (function-item message-cite-original-without-signature)
 111                 (function-item sc-cite-original)
 112                 (function :tag "Other"))
 113   :link '(custom-manual "(message)Insertion Variables")
 114   :group 'notmuch-reply)
 115
 116 (defcustom notmuch-mua-reply-insert-header-p-function
 117   'notmuch-show-reply-insert-header-p-never
 118   "Function to decide which parts get a header when replying.
 119
 120 This function specifies which parts of a mime message with
 121 multiple parts get a header."
 122   :type '(radio (const :tag "No part headers"
 123                        notmuch-show-reply-insert-header-p-never)
 124                 (const :tag "All except multipart/* and hidden parts"
 125                        notmuch-show-reply-insert-header-p-trimmed)
 126                 (const :tag "Only for included text parts"
 127                        notmuch-show-reply-insert-header-p-minimal)
 128                 (const :tag "Exactly as in show view"
 129                        notmuch-show-insert-header-p)
 130                 (function :tag "Other"))
 131   :group 'notmuch-reply)
 132
 133 (defcustom notmuch-mua-attachment-regexp
 134   "\\b\\(attache\?ment\\|attached\\|attach\\|pi[èe]ce\s+jointe?\\)\\b"
 135   "Message body text indicating that an attachment is expected.
 136
 137 This is not used unless `notmuch-mua-attachment-check' is added
 138 to `notmuch-mua-send-hook'."
 139   :type 'regexp
 140   :group 'notmuch-send)
 141
 142 ;;; Various functions
 143
 144 (defun notmuch-mua-attachment-check ()
 145   "Signal an error an attachement is expected but missing.
 146
 147 Signal an error if the message text indicates that an attachment
 148 is expected but no MML referencing an attachment is found.
 149
 150 Typically this is added to `notmuch-mua-send-hook'."
 151   (when (and
 152          ;; When the message mentions attachment...
 153          (save-excursion
 154            (message-goto-body)
 155            ;; Limit search from reaching other possible parts of the message
 156            (let ((search-limit (search-forward "\n<#" nil t)))
 157              (message-goto-body)
 158              (cl-loop while (re-search-forward notmuch-mua-attachment-regexp
 159                                                search-limit t)
 160                       ;; For every instance of the "attachment" string
 161                       ;; found, examine the text properties. If the text
 162                       ;; has either a `face' or `syntax-table' property
 163                       ;; then it is quoted text and should *not* cause the
 164                       ;; user to be asked about a missing attachment.
 165                       if (let ((props (text-properties-at (match-beginning 0))))
 166                            (not (or (memq 'syntax-table props)
 167                                     (memq 'face props))))
 168                       return t
 169                       finally return nil)))
 170          ;; ...but doesn't have a part with a filename...
 171          (save-excursion
 172            (message-goto-body)
 173            (not (re-search-forward "^<#part [^>]*filename=" nil t)))
 174          ;; ...and that's not okay...
 175          (not (y-or-n-p "Attachment mentioned, but no attachment - is that okay?")))
 176     ;; ...signal an error.
 177     (error "Missing attachment")))
 178
 179 (defun notmuch-mua-get-switch-function ()
 180   "Get a switch function according to `notmuch-mua-compose-in'."
 181   (pcase notmuch-mua-compose-in
 182     ('current-window 'switch-to-buffer)
 183     ('new-window     'switch-to-buffer-other-window)
 184     ('new-frame      'switch-to-buffer-other-frame)
 185     (_ (error "Invalid value for `notmuch-mua-compose-in'"))))
 186
 187 (defun notmuch-mua-maybe-set-window-dedicated ()
 188   "Set the selected window as dedicated according to `notmuch-mua-compose-in'."
 189   (when (or (eq notmuch-mua-compose-in 'new-frame)
 190             (eq notmuch-mua-compose-in 'new-window))
 191     (set-window-dedicated-p (selected-window) t)))
 192
 193 (defun notmuch-mua-user-agent-full ()
 194   "Generate a `User-Agent:' string suitable for notmuch."
 195   (concat (notmuch-mua-user-agent-notmuch)
 196           " "
 197           (notmuch-mua-user-agent-emacs)))
 198
 199 (defun notmuch-mua-user-agent-notmuch ()
 200   "Generate a `User-Agent:' string suitable for notmuch."
 201   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
 202                              (notmuch-cli-version)
 203                            notmuch-emacs-version)))
 204     (concat "Notmuch/" notmuch-version " (https://notmuchmail.org)")))
 205
 206 (defun notmuch-mua-user-agent-emacs ()
 207   "Generate a `User-Agent:' string suitable for notmuch."
 208   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 209
 210 (defun notmuch-mua-add-more-hidden-headers ()
 211   "Add some headers to the list that are hidden by default."
 212   (mapc (lambda (header)
 213           (unless (member header message-hidden-headers)
 214             (push header message-hidden-headers)))
 215         notmuch-mua-hidden-headers))
 216
 217 (defun notmuch-mua-reply-crypto (parts)
 218   "Add mml sign-encrypt flag if any part of original message is encrypted."
 219   (cl-loop for part in parts
 220            if (notmuch-match-content-type (plist-get part :content-type)
 221                                           "multipart/encrypted")
 222            do (mml-secure-message-sign-encrypt)
 223            else if (notmuch-match-content-type (plist-get part :content-type)
 224                                                "multipart/*")
 225            do (notmuch-mua-reply-crypto (plist-get part :content))))
 226
 227 ;; There is a bug in Emacs' message.el that results in a newline
 228 ;; not being inserted after the References header, so the next header
 229 ;; is concatenated to the end of it. This function fixes the problem,
 230 ;; while guarding against the possibility that some current or future
 231 ;; version of emacs has the bug fixed.
 232 (defun notmuch-mua-insert-references (original-func header references)
 233   (funcall original-func header references)
 234   (unless (bolp) (insert "\n")))
 235
 236 ;;; Mua reply
 237
 238 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 239   (let ((args '("reply" "--format=sexp" "--format-version=4"))
 240         (process-crypto notmuch-show-process-crypto)
 241         reply
 242         original)
 243     (when process-crypto
 244       (setq args (append args '("--decrypt=true"))))
 245     (if reply-all
 246         (setq args (append args '("--reply-to=all")))
 247       (setq args (append args '("--reply-to=sender"))))
 248     (setq args (append args (list query-string)))
 249     ;; Get the reply object as SEXP, and parse it into an elisp object.
 250     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 251     ;; Extract the original message to simplify the following code.
 252     (setq original (plist-get reply :original))
 253     ;; Extract the headers of both the reply and the original message.
 254     (let* ((original-headers (plist-get original :headers))
 255            (reply-headers (plist-get reply :reply-headers)))
 256       ;; If sender is non-nil, set the From: header to its value.
 257       (when sender
 258         (plist-put reply-headers :From sender))
 259       (let
 260           ;; Overlay the composition window on that being used to read
 261           ;; the original message.
 262           ((same-window-regexps '("\\*mail .*")))
 263         ;; We modify message-header-format-alist to get around
 264         ;; a bug in message.el.  See the comment above on
 265         ;; notmuch-mua-insert-references.
 266         (let ((message-header-format-alist
 267                (cl-loop for pair in message-header-format-alist
 268                         if (eq (car pair) 'References)
 269                         collect (cons 'References
 270                                       (apply-partially
 271                                        'notmuch-mua-insert-references
 272                                        (cdr pair)))
 273                         else
 274                         collect pair)))
 275           (notmuch-mua-mail (plist-get reply-headers :To)
 276                             (notmuch-sanitize (plist-get reply-headers :Subject))
 277                             (notmuch-headers-plist-to-alist reply-headers)
 278                             nil (notmuch-mua-get-switch-function))))
 279       ;; Create a buffer-local queue for tag changes triggered when
 280       ;; sending the reply.
 281       (when notmuch-message-replied-tags
 282         (setq notmuch-message-queued-tag-changes
 283               (list (cons query-string notmuch-message-replied-tags))))
 284       ;; Insert the message body - but put it in front of the signature
 285       ;; if one is present, and after any other content
 286       ;; message*setup-hooks may have added to the message body already.
 287       (save-restriction
 288         (message-goto-body)
 289         (narrow-to-region (point) (point-max))
 290         (goto-char (point-max))
 291         (if (re-search-backward message-signature-separator nil t)
 292             (when message-signature-insert-empty-line
 293               (forward-line -1))
 294           (goto-char (point-max))))
 295       (let ((from (plist-get original-headers :From))
 296             (date (plist-get original-headers :Date))
 297             (start (point)))
 298         ;; notmuch-mua-cite-function constructs a citation line based
 299         ;; on the From and Date headers of the original message, which
 300         ;; are assumed to be in the buffer.
 301         (insert "From: " from "\n")
 302         (insert "Date: " date "\n\n")
 303         (insert
 304          (with-temp-buffer
 305            (let
 306                ;; Don't attempt to clean up messages, excerpt
 307                ;; citations, etc. in the original message before
 308                ;; quoting.
 309                ((notmuch-show-insert-text/plain-hook nil)
 310                 ;; Don't omit long parts.
 311                 (notmuch-show-max-text-part-size 0)
 312                 ;; Insert headers for parts as appropriate for replying.
 313                 (notmuch-show-insert-header-p-function
 314                  notmuch-mua-reply-insert-header-p-function)
 315                 ;; Ensure that any encrypted parts are
 316                 ;; decrypted during the generation of the reply
 317                 ;; text.
 318                 (notmuch-show-process-crypto process-crypto)
 319                 ;; Don't indent multipart sub-parts.
 320                 (notmuch-show-indent-multipart nil))
 321              ;; We don't want sigstatus buttons (an information leak and usually wrong anyway).
 322              (cl-letf (((symbol-function 'notmuch-crypto-insert-sigstatus-button) #'ignore)
 323                        ((symbol-function 'notmuch-crypto-insert-encstatus-button) #'ignore))
 324                (notmuch-show-insert-body original (plist-get original :body) 0)
 325                (buffer-substring-no-properties (point-min) (point-max))))))
 326         (set-mark (point))
 327         (goto-char start)
 328         ;; Quote the original message according to the user's configured style.
 329         (funcall notmuch-mua-cite-function)))
 330     ;; Crypto processing based crypto content of the original message
 331     (when process-crypto
 332       (notmuch-mua-reply-crypto (plist-get original :body))))
 333   ;; Push mark right before signature, if any.
 334   (message-goto-signature)
 335   (unless (eobp)
 336     (end-of-line -1))
 337   (push-mark)
 338   (message-goto-body)
 339   (set-buffer-modified-p nil))
 340
 341 ;;; Mode and keymap
 342
 343 (defvar notmuch-message-mode-map
 344   (let ((map (make-sparse-keymap)))
 345     (define-key map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
 346     (define-key map (kbd "C-c C-s") #'notmuch-mua-send)
 347     (define-key map (kbd "C-c C-p") #'notmuch-draft-postpone)
 348     (define-key map (kbd "C-x C-s") #'notmuch-draft-save)
 349     map)
 350   "Keymap for `notmuch-message-mode'.")
 351
 352 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
 353   "Notmuch message composition mode. Mostly like `message-mode'."
 354   (notmuch-address-setup))
 355
 356 (put 'notmuch-message-mode 'flyspell-mode-predicate 'mail-mode-flyspell-verify)
 357
 358 ;;; New messages
 359
 360 (defun notmuch-mua-pop-to-buffer (name switch-function)
 361   "Pop to buffer NAME, and warn if it already exists and is modified.
 362 Like `message-pop-to-buffer' but enable `notmuch-message-mode'
 363 instead of `message-mode' and SWITCH-FUNCTION is mandatory."
 364   (let ((buffer (get-buffer name)))
 365     (if (and buffer
 366              (buffer-name buffer))
 367         (let ((window (get-buffer-window buffer 0)))
 368           (if window
 369               ;; Raise the frame already displaying the message buffer.
 370               (progn
 371                 (select-frame-set-input-focus (window-frame window))
 372                 (select-window window))
 373             (funcall switch-function buffer)
 374             (set-buffer buffer))
 375           (when (buffer-modified-p)
 376             (if (y-or-n-p "Message already being composed; erase? ")
 377                 (message nil)
 378               (error "Message being composed"))))
 379       (funcall switch-function name)
 380       (set-buffer name))
 381     (erase-buffer)
 382     (notmuch-message-mode)))
 383
 384 (defun notmuch-mua-mail (&optional to subject other-headers _continue
 385                                    switch-function yank-action send-actions
 386                                    return-action &rest ignored)
 387   "Invoke the notmuch mail composition window."
 388   (interactive)
 389   (when notmuch-mua-user-agent-function
 390     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 391       (unless (string= "" user-agent)
 392         (push (cons 'User-Agent user-agent) other-headers))))
 393   (unless (assq 'From other-headers)
 394     (push (cons 'From (message-make-from
 395                        (notmuch-user-name)
 396                        (notmuch-user-primary-email)))
 397           other-headers))
 398   (notmuch-mua-pop-to-buffer (message-buffer-name "mail" to)
 399                              (or switch-function
 400                                  (notmuch-mua-get-switch-function)))
 401   (let ((headers
 402          (append
 403           ;; The following is copied from `message-mail'
 404           `((To . ,(or to "")) (Subject . ,(or subject "")))
 405           ;; C-h f compose-mail says that headers should be specified as
 406           ;; (string . value); however all the rest of message expects
 407           ;; headers to be symbols, not strings (eg message-header-format-alist).
 408           ;; https://lists.gnu.org/archive/html/emacs-devel/2011-01/msg00337.html
 409           ;; We need to convert any string input, eg from rmail-start-mail.
 410           (dolist (h other-headers other-headers)
 411             (when (stringp (car h))
 412               (setcar h (intern (capitalize (car h))))))))
 413         ;; Cause `message-setup-1' to do things relevant for mail,
 414         ;; such as observe `message-default-mail-headers'.
 415         (message-this-is-mail t))
 416     (message-setup-1 headers yank-action send-actions return-action))
 417   (notmuch-fcc-header-setup)
 418   (message-sort-headers)
 419   (message-hide-headers)
 420   (set-buffer-modified-p nil)
 421   (notmuch-mua-maybe-set-window-dedicated)
 422   (message-goto-to))
 423
 424 (defvar notmuch-mua-sender-history nil)
 425
 426 (defun notmuch-mua-prompt-for-sender ()
 427   "Prompt for a sender from the user's configured identities."
 428   (if notmuch-identities
 429       (completing-read "Send mail from: " notmuch-identities
 430                        nil nil nil 'notmuch-mua-sender-history
 431                        (car notmuch-identities))
 432     (let* ((name (notmuch-user-name))
 433            (addrs (cons (notmuch-user-primary-email)
 434                         (notmuch-user-other-email)))
 435            (address
 436             (completing-read (concat "Sender address for " name ": ") addrs
 437                              nil nil nil 'notmuch-mua-sender-history
 438                              (car addrs))))
 439       (message-make-from name address))))
 440
 441 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 442 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 443   "Compose new mail.
 444
 445 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 446 the From: address first."
 447   (interactive "P")
 448   (let ((other-headers
 449          (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 450               (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 451     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 452
 453 (defun notmuch-mua-new-forward-messages (messages &optional prompt-for-sender)
 454   "Compose a new message forwarding MESSAGES.
 455
 456 If PROMPT-FOR-SENDER is non-nil, the user will be prompteed for
 457 the From: address."
 458   (let* ((other-headers
 459           (and (or prompt-for-sender notmuch-always-prompt-for-sender)
 460                (list (cons 'From (notmuch-mua-prompt-for-sender)))))
 461          ;; Comes from the first message and is applied later.
 462          forward-subject
 463          ;; List of accumulated message-references of forwarded messages.
 464          forward-references
 465          ;; List of corresponding message-query.
 466          forward-queries)
 467     ;; Generate the template for the outgoing message.
 468     (notmuch-mua-mail nil "" other-headers nil (notmuch-mua-get-switch-function))
 469     (save-excursion
 470       ;; Insert all of the forwarded messages.
 471       (mapc (lambda (id)
 472               (let ((temp-buffer (get-buffer-create
 473                                   (concat "*notmuch-fwd-raw-" id "*"))))
 474                 ;; Get the raw version of this message in the buffer.
 475                 (with-current-buffer temp-buffer
 476                   (erase-buffer)
 477                   (let ((coding-system-for-read 'no-conversion))
 478                     (call-process notmuch-command nil t nil
 479                                   "show" "--format=raw" id))
 480                   ;; Because we process the messages in reverse order,
 481                   ;; always generate a forwarded subject, then use the
 482                   ;; last (i.e. first) one.
 483                   (setq forward-subject (message-make-forward-subject))
 484                   (push (message-fetch-field "Message-ID") forward-references)
 485                   (push id forward-queries))
 486                 ;; Make a copy ready to be forwarded in the
 487                 ;; composition buffer.
 488                 (message-forward-make-body temp-buffer)
 489                 ;; Kill the temporary buffer.
 490                 (kill-buffer temp-buffer)))
 491             ;; `message-forward-make-body' always puts the message at
 492             ;; the top, so do them in reverse order.
 493             (reverse messages))
 494       ;; Add in the appropriate subject.
 495       (save-restriction
 496         (message-narrow-to-headers)
 497         (message-remove-header "Subject")
 498         (message-add-header (concat "Subject: " forward-subject))
 499         (message-remove-header "References")
 500         (message-add-header (concat "References: "
 501                                     (mapconcat 'identity forward-references " "))))
 502       ;; Create a buffer-local queue for tag changes triggered when
 503       ;; sending the message.
 504       (when notmuch-message-forwarded-tags
 505         (setq notmuch-message-queued-tag-changes
 506               (cl-loop for id in forward-queries
 507                        collect
 508                        (cons id notmuch-message-forwarded-tags))))
 509       ;; `message-forward-make-body' shows the User-agent header.  Hide
 510       ;; it again.
 511       (message-hide-headers)
 512       (set-buffer-modified-p nil))))
 513
 514 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 515   "Compose a reply to the message identified by QUERY-STRING.
 516
 517 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 518 the From: address first.  If REPLY-ALL is non-nil, the message
 519 will be addressed to all recipients of the source message."
 520   ;; `select-active-regions' is t by default. The reply insertion code
 521   ;; sets the region to the quoted message to make it easy to delete
 522   ;; (kill-region or C-w). These two things combine to put the quoted
 523   ;; message in the primary selection.
 524   ;;
 525   ;; This is not what the user wanted and is a privacy risk (accidental
 526   ;; pasting of the quoted message). We can avoid some of the problems
 527   ;; by let-binding select-active-regions to nil. This fixes if the
 528   ;; primary selection was previously in a non-emacs window but not if
 529   ;; it was in an emacs window. To avoid the problem in the latter case
 530   ;; we deactivate mark.
 531   (let ((sender (and prompt-for-sender
 532                      (notmuch-mua-prompt-for-sender)))
 533         (select-active-regions nil))
 534     (notmuch-mua-reply query-string sender reply-all)
 535     (deactivate-mark)))
 536
 537 ;;; Checks
 538
 539 (defun notmuch-mua-check-no-misplaced-secure-tag ()
 540   "Query user if there is a misplaced secure mml tag.
 541
 542 Emacs message-send will (probably) ignore a secure mml tag unless
 543 it is at the start of the body. Returns t if there is no such
 544 tag, or the user confirms they mean it."
 545   (save-excursion
 546     (let ((body-start (progn (message-goto-body) (point))))
 547       (goto-char (point-max))
 548       (or
 549        ;; We are always fine if there is no secure tag.
 550        (not (search-backward "<#secure" nil t))
 551        ;; There is a secure tag, so it must be at the start of the
 552        ;; body, with no secure tag earlier (i.e., in the headers).
 553        (and (= (point) body-start)
 554             (not (search-backward "<#secure" nil t)))
 555        ;; The user confirms they means it.
 556        (yes-or-no-p "\
 557 There is a <#secure> tag not at the start of the body. It is
 558 likely that the message will be sent unsigned and unencrypted.
 559 Really send? ")))))
 560
 561 (defun notmuch-mua-check-secure-tag-has-newline ()
 562   "Query if the secure mml tag has a newline following it.
 563
 564 Emacs message-send will (probably) ignore a correctly placed
 565 secure mml tag unless it is followed by a newline. Returns t if
 566 any secure tag is followed by a newline, or the user confirms
 567 they mean it."
 568   (save-excursion
 569     (message-goto-body)
 570     (or
 571      ;; There is no (correctly placed) secure tag.
 572      (not (looking-at "<#secure"))
 573      ;; The secure tag is followed by a newline.
 574      (looking-at "<#secure[^\n>]*>\n")
 575      ;; The user confirms they means it.
 576      (yes-or-no-p "\
 577 The <#secure> tag at the start of the body is not followed by a
 578 newline. It is likely that the message will be sent unsigned and
 579 unencrypted.  Really send? "))))
 580
 581 ;;; Finishing commands
 582
 583 (defun notmuch-mua-send-common (arg &optional exit)
 584   (interactive "P")
 585   (run-hooks 'notmuch-mua-send-hook)
 586   (when (and (notmuch-mua-check-no-misplaced-secure-tag)
 587              (notmuch-mua-check-secure-tag-has-newline))
 588     (cl-letf (((symbol-function 'message-do-fcc)
 589                #'notmuch-maildir-message-do-fcc))
 590       (if exit
 591           (message-send-and-exit arg)
 592         (message-send arg)))))
 593
 594 (defun notmuch-mua-send-and-exit (&optional arg)
 595   (interactive "P")
 596   (notmuch-mua-send-common arg t))
 597
 598 (defun notmuch-mua-send (&optional arg)
 599   (interactive "P")
 600   (notmuch-mua-send-common arg))
 601
 602 (defun notmuch-mua-kill-buffer ()
 603   (interactive)
 604   (message-kill-buffer))
 605
 606 ;;; _
 607
 608 (define-mail-user-agent 'notmuch-user-agent
 609   'notmuch-mua-mail
 610   'notmuch-mua-send-and-exit
 611   'notmuch-mua-kill-buffer
 612   'notmuch-mua-send-hook)
 613
 614 ;; Add some more headers to the list that `message-mode' hides when
 615 ;; composing a message.
 616 (notmuch-mua-add-more-hidden-headers)
 617
 618 (provide 'notmuch-mua)
 619
 620 ;;; notmuch-mua.el ends here