git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23 (require 'mm-view)
  24 (require 'format-spec)
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-address)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth &optional hide))
  32
  33 ;;
  34
  35 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  36   "Hook run before sending messages."
  37   :type 'hook
  38   :group 'notmuch-send
  39   :group 'notmuch-hooks)
  40
  41 (defcustom notmuch-mua-compose-in 'current-window
  42   (concat
  43    "Where to create the mail buffer used to compose a new message.
  44 Possible values are `current-window' (default), `new-window' and
  45 `new-frame'. If set to `current-window', the mail buffer will be
  46 displayed in the current window, so the old buffer will be
  47 restored when the mail buffer is killed. If set to `new-window'
  48 or `new-frame', the mail buffer will be displayed in a new
  49 window/frame that will be destroyed when the buffer is killed.
  50 You may want to customize `message-kill-buffer-on-exit'
  51 accordingly."
  52    (when (< emacs-major-version 24)
  53            " Due to a known bug in Emacs 23, you should not set
  54 this to `new-window' if `message-kill-buffer-on-exit' is
  55 disabled: this would result in an incorrect behavior."))
  56   :group 'notmuch-send
  57   :type '(choice (const :tag "Compose in the current window" current-window)
  58                  (const :tag "Compose mail in a new window"  new-window)
  59                  (const :tag "Compose mail in a new frame"   new-frame)))
  60
  61 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  62   "Function used to generate a `User-Agent:' string. If this is
  63 `nil' then no `User-Agent:' will be generated."
  64   :type '(choice (const :tag "No user agent string" nil)
  65                  (const :tag "Full" notmuch-mua-user-agent-full)
  66                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  67                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  68                  (function :tag "Custom user agent function"
  69                            :value notmuch-mua-user-agent-full))
  70   :group 'notmuch-send)
  71
  72 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  73   "Headers that are added to the `message-mode' hidden headers
  74 list."
  75   :type '(repeat string)
  76   :group 'notmuch-send)
  77
  78 (defgroup notmuch-reply nil
  79   "Replying to messages in notmuch"
  80   :group 'notmuch)
  81
  82 (defcustom notmuch-mua-cite-function 'message-cite-original
  83   "*Function for citing an original message.
  84 Predefined functions include `message-cite-original' and
  85 `message-cite-original-without-signature'.
  86 Note that these functions use `mail-citation-hook' if that is non-nil."
  87   :type '(radio (function-item message-cite-original)
  88                 (function-item message-cite-original-without-signature)
  89                 (function-item sc-cite-original)
  90                 (function :tag "Other"))
  91   :link '(custom-manual "(message)Insertion Variables")
  92   :group 'notmuch-reply)
  93
  94 ;;
  95
  96 (defun notmuch-mua-get-switch-function ()
  97   "Get a switch function according to `notmuch-mua-compose-in'."
  98   (cond ((eq notmuch-mua-compose-in 'current-window)
  99          'switch-to-buffer)
 100         ((eq notmuch-mua-compose-in 'new-window)
 101          'switch-to-buffer-other-window)
 102         ((eq notmuch-mua-compose-in 'new-frame)
 103          'switch-to-buffer-other-frame)
 104         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
 105
 106 (defun notmuch-mua-maybe-set-window-dedicated ()
 107   "Set the selected window as dedicated according to
 108 `notmuch-mua-compose-in'."
 109   (when (or (eq notmuch-mua-compose-in 'new-frame)
 110             (eq notmuch-mua-compose-in 'new-window))
 111     (set-window-dedicated-p (selected-window) t)))
 112
 113 (defun notmuch-mua-user-agent-full ()
 114   "Generate a `User-Agent:' string suitable for notmuch."
 115   (concat (notmuch-mua-user-agent-notmuch)
 116           " "
 117           (notmuch-mua-user-agent-emacs)))
 118
 119 (defun notmuch-mua-user-agent-notmuch ()
 120   "Generate a `User-Agent:' string suitable for notmuch."
 121   (let ((notmuch-version (if (string= notmuch-emacs-version "unknown")
 122                              (notmuch-cli-version)
 123                            notmuch-emacs-version)))
 124     (concat "Notmuch/" notmuch-version " (http://notmuchmail.org)")))
 125
 126 (defun notmuch-mua-user-agent-emacs ()
 127   "Generate a `User-Agent:' string suitable for notmuch."
 128   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 129
 130 (defun notmuch-mua-add-more-hidden-headers ()
 131   "Add some headers to the list that are hidden by default."
 132   (mapc (lambda (header)
 133           (when (not (member header message-hidden-headers))
 134             (push header message-hidden-headers)))
 135         notmuch-mua-hidden-headers))
 136
 137 (defun notmuch-mua-reply-crypto (parts)
 138   "Add mml sign-encrypt flag if any part of original message is encrypted."
 139   (loop for part in parts
 140         if (notmuch-match-content-type (plist-get part :content-type) "multipart/encrypted")
 141           do (mml-secure-message-sign-encrypt)
 142         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 143           do (notmuch-mua-reply-crypto (plist-get part :content))))
 144
 145 (defun notmuch-mua-get-quotable-parts (parts)
 146   (loop for part in parts
 147         if (notmuch-match-content-type (plist-get part :content-type) "multipart/alternative")
 148           collect (let* ((subparts (plist-get part :content))
 149                         (types (mapcar (lambda (part) (plist-get part :content-type)) subparts))
 150                         (chosen-type (car (notmuch-multipart/alternative-choose types))))
 151                    (loop for part in (reverse subparts)
 152                          if (notmuch-match-content-type (plist-get part :content-type) chosen-type)
 153                          return part))
 154         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 155           append (notmuch-mua-get-quotable-parts (plist-get part :content))
 156         else if (notmuch-match-content-type (plist-get part :content-type) "text/*")
 157           collect part))
 158
 159 (defun notmuch-mua-insert-quotable-part (message part)
 160   ;; We don't want text properties leaking from the show renderer into
 161   ;; the reply so we use a temp buffer. Also we don't want hooks, such
 162   ;; as notmuch-wash-*, to be run on the quotable part so we set
 163   ;; notmuch-show-insert-text/plain-hook to nil.
 164   (insert (with-temp-buffer
 165             (let ((notmuch-show-insert-text/plain-hook nil))
 166               ;; Show the part but do not add buttons.
 167               (notmuch-show-insert-bodypart message part 0 'no-buttons))
 168             (buffer-substring-no-properties (point-min) (point-max)))))
 169
 170 ;; There is a bug in emacs 23's message.el that results in a newline
 171 ;; not being inserted after the References header, so the next header
 172 ;; is concatenated to the end of it. This function fixes the problem,
 173 ;; while guarding against the possibility that some current or future
 174 ;; version of emacs has the bug fixed.
 175 (defun notmuch-mua-insert-references (original-func header references)
 176   (funcall original-func header references)
 177   (unless (bolp) (insert "\n")))
 178
 179 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 180   (let ((args '("reply" "--format=sexp" "--format-version=1"))
 181         (process-crypto notmuch-show-process-crypto)
 182         reply
 183         original)
 184     (when process-crypto
 185       (setq args (append args '("--decrypt"))))
 186
 187     (if reply-all
 188         (setq args (append args '("--reply-to=all")))
 189       (setq args (append args '("--reply-to=sender"))))
 190     (setq args (append args (list query-string)))
 191
 192     ;; Get the reply object as SEXP, and parse it into an elisp object.
 193     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 194
 195     ;; Extract the original message to simplify the following code.
 196     (setq original (plist-get reply :original))
 197
 198     ;; Extract the headers of both the reply and the original message.
 199     (let* ((original-headers (plist-get original :headers))
 200            (reply-headers (plist-get reply :reply-headers)))
 201
 202       ;; If sender is non-nil, set the From: header to its value.
 203       (when sender
 204         (plist-put reply-headers :From sender))
 205       (let
 206           ;; Overlay the composition window on that being used to read
 207           ;; the original message.
 208           ((same-window-regexps '("\\*mail .*")))
 209
 210         ;; We modify message-header-format-alist to get around a bug in message.el.
 211         ;; See the comment above on notmuch-mua-insert-references.
 212         (let ((message-header-format-alist
 213                (loop for pair in message-header-format-alist
 214                      if (eq (car pair) 'References)
 215                      collect (cons 'References
 216                                    (apply-partially
 217                                     'notmuch-mua-insert-references
 218                                     (cdr pair)))
 219                      else
 220                      collect pair)))
 221           (notmuch-mua-mail (plist-get reply-headers :To)
 222                             (plist-get reply-headers :Subject)
 223                             (notmuch-headers-plist-to-alist reply-headers)
 224                             nil (notmuch-mua-get-switch-function))))
 225
 226       ;; Insert the message body - but put it in front of the signature
 227       ;; if one is present, and after any other content
 228       ;; message*setup-hooks may have added to the message body already.
 229       (save-restriction
 230         (message-goto-body)
 231         (narrow-to-region (point) (point-max))
 232         (goto-char (point-max))
 233         (if (re-search-backward message-signature-separator nil t)
 234             (if message-signature-insert-empty-line
 235                 (forward-line -1))
 236           (goto-char (point-max))))
 237
 238       (let ((from (plist-get original-headers :From))
 239             (date (plist-get original-headers :Date))
 240             (start (point)))
 241
 242         ;; notmuch-mua-cite-function constructs a citation line based
 243         ;; on the From and Date headers of the original message, which
 244         ;; are assumed to be in the buffer.
 245         (insert "From: " from "\n")
 246         (insert "Date: " date "\n\n")
 247
 248         ;; Get the parts of the original message that should be quoted; this includes
 249         ;; all the text parts, except the non-preferred ones in a multipart/alternative.
 250         (let ((quotable-parts (notmuch-mua-get-quotable-parts (plist-get original :body))))
 251           (mapc (apply-partially 'notmuch-mua-insert-quotable-part original) quotable-parts))
 252
 253         (set-mark (point))
 254         (goto-char start)
 255         ;; Quote the original message according to the user's configured style.
 256         (funcall notmuch-mua-cite-function)))
 257
 258     ;; Crypto processing based crypto content of the original message
 259     (when process-crypto
 260       (notmuch-mua-reply-crypto (plist-get original :body))))
 261
 262   ;; Push mark right before signature, if any.
 263   (message-goto-signature)
 264   (unless (eobp)
 265     (end-of-line -1))
 266   (push-mark)
 267
 268   (message-goto-body)
 269   (set-buffer-modified-p nil))
 270
 271 (define-derived-mode notmuch-message-mode message-mode "Message[Notmuch]"
 272   "Notmuch message composition mode. Mostly like `message-mode'")
 273
 274 (define-key notmuch-message-mode-map (kbd "C-c C-c") #'notmuch-mua-send-and-exit)
 275 (define-key notmuch-message-mode-map (kbd "C-c C-s") #'notmuch-mua-send)
 276
 277
 278 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 279   "Invoke the notmuch mail composition window.
 280
 281 OTHER-ARGS are passed through to `message-mail'."
 282   (interactive)
 283
 284   (when notmuch-mua-user-agent-function
 285     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 286       (when (not (string= "" user-agent))
 287         (push (cons 'User-Agent user-agent) other-headers))))
 288
 289   (unless (assq 'From other-headers)
 290     (push (cons 'From (concat
 291                        (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 292
 293   (apply #'message-mail to subject other-headers other-args)
 294   (notmuch-message-mode)
 295   (notmuch-fcc-header-setup)
 296   (message-sort-headers)
 297   (message-hide-headers)
 298   (set-buffer-modified-p nil)
 299   (notmuch-mua-maybe-set-window-dedicated)
 300
 301   (message-goto-to))
 302
 303 (defcustom notmuch-identities nil
 304   "Identities that can be used as the From: address when composing a new message.
 305
 306 If this variable is left unset, then a list will be constructed from the
 307 name and addresses configured in the notmuch configuration file."
 308   :type '(repeat string)
 309   :group 'notmuch-send)
 310
 311 (defcustom notmuch-always-prompt-for-sender nil
 312   "Always prompt for the From: address when composing or forwarding a message.
 313
 314 This is not taken into account when replying to a message, because in that case
 315 the From: header is already filled in by notmuch."
 316   :type 'boolean
 317   :group 'notmuch-send)
 318
 319 (defvar notmuch-mua-sender-history nil)
 320
 321 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
 322 ;; without some explicit initialization fill freeze the operation.
 323 ;; Hence, we advice `ido-completing-read' to ensure required initialization
 324 ;; is done.
 325 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
 326     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
 327       (ido-init-completion-maps)
 328       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
 329       (add-hook 'choose-completion-string-functions
 330                 'ido-choose-completion-string)
 331       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
 332       (ad-activate 'ido-completing-read)))
 333
 334 (defun notmuch-mua-prompt-for-sender ()
 335   "Prompt for a sender from the user's configured identities."
 336   (if notmuch-identities
 337       (ido-completing-read "Send mail from: " notmuch-identities
 338                            nil nil nil 'notmuch-mua-sender-history
 339                            (car notmuch-identities))
 340     (let* ((name (notmuch-user-name))
 341            (addrs (cons (notmuch-user-primary-email)
 342                         (notmuch-user-other-email)))
 343            (address
 344             (ido-completing-read (concat "Sender address for " name ": ") addrs
 345                                  nil nil nil 'notmuch-mua-sender-history
 346                                  (car addrs))))
 347       (concat name " <" address ">"))))
 348
 349 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 350 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 351   "Compose new mail.
 352
 353 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 354 the From: address first."
 355   (interactive "P")
 356   (let ((other-headers
 357          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 358            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 359     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 360
 361 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 362   "Invoke the notmuch message forwarding window.
 363
 364 The current buffer must contain an RFC2822 message to forward.
 365
 366 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 367 the From: address first."
 368   (let* ((cur (current-buffer))
 369          (message-forward-decoded-p nil)
 370          (subject (message-make-forward-subject))
 371          (other-headers
 372           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 373             (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 374     (notmuch-mua-mail nil subject other-headers nil (notmuch-mua-get-switch-function))
 375     (message-forward-make-body cur)
 376     ;; `message-forward-make-body' shows the User-agent header.  Hide
 377     ;; it again.
 378     (message-hide-headers)
 379     (set-buffer-modified-p nil)))
 380
 381 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 382   "Compose a reply to the message identified by QUERY-STRING.
 383
 384 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 385 the From: address first.  If REPLY-ALL is non-nil, the message
 386 will be addressed to all recipients of the source message."
 387
 388 ;; In current emacs (24.3) select-active-regions is set to t by
 389 ;; default. The reply insertion code sets the region to the quoted
 390 ;; message to make it easy to delete (kill-region or C-w). These two
 391 ;; things combine to put the quoted message in the primary selection.
 392 ;;
 393 ;; This is not what the user wanted and is a privacy risk (accidental
 394 ;; pasting of the quoted message). We can avoid some of the problems
 395 ;; by let-binding select-active-regions to nil. This fixes if the
 396 ;; primary selection was previously in a non-emacs window but not if
 397 ;; it was in an emacs window. To avoid the problem in the latter case
 398 ;; we deactivate mark.
 399
 400   (let ((sender
 401          (when prompt-for-sender
 402            (notmuch-mua-prompt-for-sender)))
 403         (select-active-regions nil))
 404     (notmuch-mua-reply query-string sender reply-all)
 405     (deactivate-mark)))
 406
 407 (defun notmuch-mua-send-and-exit (&optional arg)
 408   (interactive "P")
 409   (let ((message-fcc-handler-function #'notmuch-fcc-handler))
 410     (message-send-and-exit arg)))
 411
 412 (defun notmuch-mua-send (&optional arg)
 413   (interactive "P")
 414   (let ((message-fcc-handler-function #'notmuch-fcc-handler))
 415     (message-send arg)))
 416
 417 (defun notmuch-mua-kill-buffer ()
 418   (interactive)
 419   (message-kill-buffer))
 420
 421 (defun notmuch-mua-message-send-hook ()
 422   "The default function used for `notmuch-mua-send-hook', this
 423 simply runs the corresponding `message-mode' hook functions."
 424   (run-hooks 'message-send-hook))
 425
 426 ;;
 427
 428 (define-mail-user-agent 'notmuch-user-agent
 429   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 430   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 431
 432 ;; Add some more headers to the list that `message-mode' hides when
 433 ;; composing a message.
 434 (notmuch-mua-add-more-hidden-headers)
 435
 436 ;;
 437
 438 (provide 'notmuch-mua)