git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-mua.el

   1 ;; notmuch-mua.el --- emacs style mail-user-agent
   2 ;;
   3 ;; Copyright © David Edmondson
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: David Edmondson <dme@dme.org>
  21
  22 (require 'message)
  23 (require 'mm-view)
  24 (require 'format-spec)
  25
  26 (require 'notmuch-lib)
  27 (require 'notmuch-address)
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth &optional hide))
  32
  33 ;;
  34
  35 (defcustom notmuch-mua-send-hook '(notmuch-mua-message-send-hook)
  36   "Hook run before sending messages."
  37   :type 'hook
  38   :group 'notmuch-send
  39   :group 'notmuch-hooks)
  40
  41 (defcustom notmuch-mua-compose-in 'current-window
  42   (concat
  43    "Where to create the mail buffer used to compose a new message.
  44 Possible values are `current-window' (default), `new-window' and
  45 `new-frame'. If set to `current-window', the mail buffer will be
  46 displayed in the current window, so the old buffer will be
  47 restored when the mail buffer is killed. If set to `new-window'
  48 or `new-frame', the mail buffer will be displayed in a new
  49 window/frame that will be destroyed when the buffer is killed.
  50 You may want to customize `message-kill-buffer-on-exit'
  51 accordingly."
  52    (when (< emacs-major-version 24)
  53            " Due to a known bug in Emacs 23, you should not set
  54 this to `new-window' if `message-kill-buffer-on-exit' is
  55 disabled: this would result in an incorrect behavior."))
  56   :group 'notmuch-send
  57   :type '(choice (const :tag "Compose in the current window" current-window)
  58                  (const :tag "Compose mail in a new window"  new-window)
  59                  (const :tag "Compose mail in a new frame"   new-frame)))
  60
  61 (defcustom notmuch-mua-user-agent-function 'notmuch-mua-user-agent-full
  62   "Function used to generate a `User-Agent:' string. If this is
  63 `nil' then no `User-Agent:' will be generated."
  64   :type '(choice (const :tag "No user agent string" nil)
  65                  (const :tag "Full" notmuch-mua-user-agent-full)
  66                  (const :tag "Notmuch" notmuch-mua-user-agent-notmuch)
  67                  (const :tag "Emacs" notmuch-mua-user-agent-emacs)
  68                  (function :tag "Custom user agent function"
  69                            :value notmuch-mua-user-agent-full))
  70   :group 'notmuch-send)
  71
  72 (defcustom notmuch-mua-hidden-headers '("^User-Agent:")
  73   "Headers that are added to the `message-mode' hidden headers
  74 list."
  75   :type '(repeat string)
  76   :group 'notmuch-send)
  77
  78 ;;
  79
  80 (defun notmuch-mua-get-switch-function ()
  81   "Get a switch function according to `notmuch-mua-compose-in'."
  82   (cond ((eq notmuch-mua-compose-in 'current-window)
  83          'switch-to-buffer)
  84         ((eq notmuch-mua-compose-in 'new-window)
  85          'switch-to-buffer-other-window)
  86         ((eq notmuch-mua-compose-in 'new-frame)
  87          'switch-to-buffer-other-frame)
  88         (t (error "Invalid value for `notmuch-mua-compose-in'"))))
  89
  90 (defun notmuch-mua-maybe-set-window-dedicated ()
  91   "Set the selected window as dedicated according to
  92 `notmuch-mua-compose-in'."
  93   (when (or (eq notmuch-mua-compose-in 'new-frame)
  94             (eq notmuch-mua-compose-in 'new-window))
  95     (set-window-dedicated-p (selected-window) t)))
  96
  97 (defun notmuch-mua-user-agent-full ()
  98   "Generate a `User-Agent:' string suitable for notmuch."
  99   (concat (notmuch-mua-user-agent-notmuch)
 100           " "
 101           (notmuch-mua-user-agent-emacs)))
 102
 103 (defun notmuch-mua-user-agent-notmuch ()
 104   "Generate a `User-Agent:' string suitable for notmuch."
 105   (concat "Notmuch/" (notmuch-version) " (http://notmuchmail.org)"))
 106
 107 (defun notmuch-mua-user-agent-emacs ()
 108   "Generate a `User-Agent:' string suitable for notmuch."
 109   (concat "Emacs/" emacs-version " (" system-configuration ")"))
 110
 111 (defun notmuch-mua-add-more-hidden-headers ()
 112   "Add some headers to the list that are hidden by default."
 113   (mapc (lambda (header)
 114           (when (not (member header message-hidden-headers))
 115             (push header message-hidden-headers)))
 116         notmuch-mua-hidden-headers))
 117
 118 (defun notmuch-mua-get-quotable-parts (parts)
 119   (loop for part in parts
 120         if (notmuch-match-content-type (plist-get part :content-type) "multipart/alternative")
 121           collect (let* ((subparts (plist-get part :content))
 122                         (types (mapcar (lambda (part) (plist-get part :content-type)) subparts))
 123                         (chosen-type (car (notmuch-multipart/alternative-choose types))))
 124                    (loop for part in (reverse subparts)
 125                          if (notmuch-match-content-type (plist-get part :content-type) chosen-type)
 126                          return part))
 127         else if (notmuch-match-content-type (plist-get part :content-type) "multipart/*")
 128           append (notmuch-mua-get-quotable-parts (plist-get part :content))
 129         else if (notmuch-match-content-type (plist-get part :content-type) "text/*")
 130           collect part))
 131
 132 (defun notmuch-mua-insert-quotable-part (message part)
 133   ;; We don't want text properties leaking from the show renderer into
 134   ;; the reply so we use a temp buffer. Also we don't want hooks, such
 135   ;; as notmuch-wash-*, to be run on the quotable part so we set
 136   ;; notmuch-show-insert-text/plain-hook to nil.
 137   (insert (with-temp-buffer
 138             (let ((notmuch-show-insert-text/plain-hook nil))
 139               ;; Show the part but do not add buttons.
 140               (notmuch-show-insert-bodypart message part 0 'no-buttons))
 141             (buffer-substring-no-properties (point-min) (point-max)))))
 142
 143 ;; There is a bug in emacs 23's message.el that results in a newline
 144 ;; not being inserted after the References header, so the next header
 145 ;; is concatenated to the end of it. This function fixes the problem,
 146 ;; while guarding against the possibility that some current or future
 147 ;; version of emacs has the bug fixed.
 148 (defun notmuch-mua-insert-references (original-func header references)
 149   (funcall original-func header references)
 150   (unless (bolp) (insert "\n")))
 151
 152 (defun notmuch-mua-reply (query-string &optional sender reply-all)
 153   (let ((args '("reply" "--format=sexp" "--format-version=1"))
 154         reply
 155         original)
 156     (when notmuch-show-process-crypto
 157       (setq args (append args '("--decrypt"))))
 158
 159     (if reply-all
 160         (setq args (append args '("--reply-to=all")))
 161       (setq args (append args '("--reply-to=sender"))))
 162     (setq args (append args (list query-string)))
 163
 164     ;; Get the reply object as SEXP, and parse it into an elisp object.
 165     (setq reply (apply #'notmuch-call-notmuch-sexp args))
 166
 167     ;; Extract the original message to simplify the following code.
 168     (setq original (plist-get reply :original))
 169
 170     ;; Extract the headers of both the reply and the original message.
 171     (let* ((original-headers (plist-get original :headers))
 172            (reply-headers (plist-get reply :reply-headers)))
 173
 174       ;; If sender is non-nil, set the From: header to its value.
 175       (when sender
 176         (plist-put reply-headers :From sender))
 177       (let
 178           ;; Overlay the composition window on that being used to read
 179           ;; the original message.
 180           ((same-window-regexps '("\\*mail .*")))
 181
 182         ;; We modify message-header-format-alist to get around a bug in message.el.
 183         ;; See the comment above on notmuch-mua-insert-references.
 184         (let ((message-header-format-alist
 185                (loop for pair in message-header-format-alist
 186                      if (eq (car pair) 'References)
 187                      collect (cons 'References
 188                                    (apply-partially
 189                                     'notmuch-mua-insert-references
 190                                     (cdr pair)))
 191                      else
 192                      collect pair)))
 193           (notmuch-mua-mail (plist-get reply-headers :To)
 194                             (plist-get reply-headers :Subject)
 195                             (notmuch-headers-plist-to-alist reply-headers)
 196                             nil (notmuch-mua-get-switch-function))))
 197
 198       ;; Insert the message body - but put it in front of the signature
 199       ;; if one is present, and after any other content
 200       ;; message*setup-hooks may have added to the message body already.
 201       (save-restriction
 202         (message-goto-body)
 203         (narrow-to-region (point) (point-max))
 204         (goto-char (point-max))
 205         (if (re-search-backward message-signature-separator nil t)
 206             (if message-signature-insert-empty-line
 207                 (forward-line -1))
 208           (goto-char (point-max))))
 209
 210       (let ((from (plist-get original-headers :From))
 211             (date (plist-get original-headers :Date))
 212             (start (point)))
 213
 214         ;; message-cite-original constructs a citation line based on the From and Date
 215         ;; headers of the original message, which are assumed to be in the buffer.
 216         (insert "From: " from "\n")
 217         (insert "Date: " date "\n\n")
 218
 219         ;; Get the parts of the original message that should be quoted; this includes
 220         ;; all the text parts, except the non-preferred ones in a multipart/alternative.
 221         (let ((quotable-parts (notmuch-mua-get-quotable-parts (plist-get original :body))))
 222           (mapc (apply-partially 'notmuch-mua-insert-quotable-part original) quotable-parts))
 223
 224         (set-mark (point))
 225         (goto-char start)
 226         ;; Quote the original message according to the user's configured style.
 227         (message-cite-original))))
 228
 229   ;; Push mark right before signature, if any.
 230   (message-goto-signature)
 231   (unless (eobp)
 232     (end-of-line -1))
 233   (push-mark)
 234
 235   (message-goto-body)
 236   (set-buffer-modified-p nil))
 237
 238 (defun notmuch-mua-mail (&optional to subject other-headers &rest other-args)
 239   "Invoke the notmuch mail composition window.
 240
 241 OTHER-ARGS are passed through to `message-mail'."
 242   (interactive)
 243
 244   (when notmuch-mua-user-agent-function
 245     (let ((user-agent (funcall notmuch-mua-user-agent-function)))
 246       (when (not (string= "" user-agent))
 247         (push (cons 'User-Agent user-agent) other-headers))))
 248
 249   (unless (assq 'From other-headers)
 250     (push (cons 'From (concat
 251                        (notmuch-user-name) " <" (notmuch-user-primary-email) ">")) other-headers))
 252
 253   (apply #'message-mail to subject other-headers other-args)
 254   (message-sort-headers)
 255   (message-hide-headers)
 256   (set-buffer-modified-p nil)
 257   (notmuch-mua-maybe-set-window-dedicated)
 258
 259   (message-goto-to))
 260
 261 (defcustom notmuch-identities nil
 262   "Identities that can be used as the From: address when composing a new message.
 263
 264 If this variable is left unset, then a list will be constructed from the
 265 name and addresses configured in the notmuch configuration file."
 266   :type '(repeat string)
 267   :group 'notmuch-send)
 268
 269 (defcustom notmuch-always-prompt-for-sender nil
 270   "Always prompt for the From: address when composing or forwarding a message.
 271
 272 This is not taken into account when replying to a message, because in that case
 273 the From: header is already filled in by notmuch."
 274   :type 'boolean
 275   :group 'notmuch-send)
 276
 277 (defvar notmuch-mua-sender-history nil)
 278
 279 ;; Workaround: Running `ido-completing-read' in emacs 23.1, 23.2 and 23.3
 280 ;; without some explicit initialization fill freeze the operation.
 281 ;; Hence, we advice `ido-completing-read' to ensure required initialization
 282 ;; is done.
 283 (if (and (= emacs-major-version 23) (< emacs-minor-version 4))
 284     (defadvice ido-completing-read (before notmuch-ido-mode-init activate)
 285       (ido-init-completion-maps)
 286       (add-hook 'minibuffer-setup-hook 'ido-minibuffer-setup)
 287       (add-hook 'choose-completion-string-functions
 288                 'ido-choose-completion-string)
 289       (ad-disable-advice 'ido-completing-read 'before 'notmuch-ido-mode-init)
 290       (ad-activate 'ido-completing-read)))
 291
 292 (defun notmuch-mua-prompt-for-sender ()
 293   "Prompt for a sender from the user's configured identities."
 294   (if notmuch-identities
 295       (ido-completing-read "Send mail from: " notmuch-identities
 296                            nil nil nil 'notmuch-mua-sender-history
 297                            (car notmuch-identities))
 298     (let* ((name (notmuch-user-name))
 299            (addrs (cons (notmuch-user-primary-email)
 300                         (notmuch-user-other-email)))
 301            (address
 302             (ido-completing-read (concat "Sender address for " name ": ") addrs
 303                                  nil nil nil 'notmuch-mua-sender-history
 304                                  (car addrs))))
 305       (concat name " <" address ">"))))
 306
 307 (put 'notmuch-mua-new-mail 'notmuch-prefix-doc "... and prompt for sender")
 308 (defun notmuch-mua-new-mail (&optional prompt-for-sender)
 309   "Compose new mail.
 310
 311 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 312 the From: address first."
 313   (interactive "P")
 314   (let ((other-headers
 315          (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 316            (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 317     (notmuch-mua-mail nil nil other-headers nil (notmuch-mua-get-switch-function))))
 318
 319 (defun notmuch-mua-new-forward-message (&optional prompt-for-sender)
 320   "Invoke the notmuch message forwarding window.
 321
 322 The current buffer must contain an RFC2822 message to forward.
 323
 324 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 325 the From: address first."
 326   (let* ((cur (current-buffer))
 327          (message-forward-decoded-p nil)
 328          (subject (message-make-forward-subject))
 329          (other-headers
 330           (when (or prompt-for-sender notmuch-always-prompt-for-sender)
 331             (list (cons 'From (notmuch-mua-prompt-for-sender))))))
 332     (notmuch-mua-mail nil subject other-headers nil (notmuch-mua-get-switch-function))
 333     (message-forward-make-body cur)
 334     ;; `message-forward-make-body' shows the User-agent header.  Hide
 335     ;; it again.
 336     (message-hide-headers)))
 337
 338 (defun notmuch-mua-new-reply (query-string &optional prompt-for-sender reply-all)
 339   "Compose a reply to the message identified by QUERY-STRING.
 340
 341 If PROMPT-FOR-SENDER is non-nil, the user will be prompted for
 342 the From: address first.  If REPLY-ALL is non-nil, the message
 343 will be addressed to all recipients of the source message."
 344
 345 ;; In current emacs (24.3) select-active-regions is set to t by
 346 ;; default. The reply insertion code sets the region to the quoted
 347 ;; message to make it easy to delete (kill-region or C-w). These two
 348 ;; things combine to put the quoted message in the primary selection.
 349 ;;
 350 ;; This is not what the user wanted and is a privacy risk (accidental
 351 ;; pasting of the quoted message). We can avoid some of the problems
 352 ;; by let-binding select-active-regions to nil. This fixes if the
 353 ;; primary selection was previously in a non-emacs window but not if
 354 ;; it was in an emacs window. To avoid the problem in the latter case
 355 ;; we deactivate mark.
 356
 357   (let ((sender
 358          (when prompt-for-sender
 359            (notmuch-mua-prompt-for-sender)))
 360         (select-active-regions nil))
 361     (notmuch-mua-reply query-string sender reply-all)
 362     (deactivate-mark)))
 363
 364 (defun notmuch-mua-send-and-exit (&optional arg)
 365   (interactive "P")
 366   (message-send-and-exit arg))
 367
 368 (defun notmuch-mua-kill-buffer ()
 369   (interactive)
 370   (message-kill-buffer))
 371
 372 (defun notmuch-mua-message-send-hook ()
 373   "The default function used for `notmuch-mua-send-hook', this
 374 simply runs the corresponding `message-mode' hook functions."
 375   (run-hooks 'message-send-hook))
 376
 377 ;;
 378
 379 (define-mail-user-agent 'notmuch-user-agent
 380   'notmuch-mua-mail 'notmuch-mua-send-and-exit
 381   'notmuch-mua-kill-buffer 'notmuch-mua-send-hook)
 382
 383 ;; Add some more headers to the list that `message-mode' hides when
 384 ;; composing a message.
 385 (notmuch-mua-add-more-hidden-headers)
 386
 387 ;;
 388
 389 (provide 'notmuch-mua)