git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-search-next-thread "notmuch" nil)
  42 (declare-function notmuch-search-previous-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts nil
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ("LKML" . "http://lkml.kernel.org/r/")
 162     ;; FIXME: can these services be searched by `Message-Id' ?
 163     ;; ("MarkMail" . "http://markmail.org/")
 164     ;; ("Nabble" . "http://nabble.com/")
 165     ;; ("opensubscriber" . "http://opensubscriber.com/")
 166     )
 167   "List of Mailing List Archives to use when stashing links.
 168
 169 These URIs are concatenated with the current message's
 170 Message-Id in `notmuch-show-stash-mlarchive-link'."
 171   :type '(alist :key-type (string :tag "Name")
 172                 :value-type (string :tag "URL"))
 173   :group 'notmuch-show)
 174
 175 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 176   "Default Mailing List Archive to use when stashing links.
 177
 178 This is used when `notmuch-show-stash-mlarchive-link' isn't
 179 provided with an MLA argument nor `completing-read' input."
 180   :type `(choice
 181           ,@(mapcar
 182              (lambda (mla)
 183                (list 'const :tag (car mla) :value (car mla)))
 184              notmuch-show-stash-mlarchive-link-alist))
 185   :group 'notmuch-show)
 186
 187 (defcustom notmuch-show-mark-read-tags '("-unread")
 188   "List of tag changes to apply to a message when it is marked as read.
 189
 190 Tags starting with \"+\" (or not starting with either \"+\" or
 191 \"-\") in the list will be added, and tags starting with \"-\"
 192 will be removed from the message being marked as read.
 193
 194 For example, if you wanted to remove an \"unread\" tag and add a
 195 \"read\" tag (which would make little sense), you would set:
 196     (\"-unread\" \"+read\")"
 197   :type '(repeat string)
 198   :group 'notmuch-show)
 199
 200
 201 (defmacro with-current-notmuch-show-message (&rest body)
 202   "Evaluate body with current buffer set to the text of current message"
 203   `(save-excursion
 204      (let ((id (notmuch-show-get-message-id)))
 205        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 206          (with-current-buffer buf
 207            (let ((coding-system-for-read 'no-conversion))
 208              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 209              ,@body)
 210            (kill-buffer buf))))))
 211
 212 (defun notmuch-show-turn-on-visual-line-mode ()
 213   "Enable Visual Line mode."
 214   (visual-line-mode t))
 215
 216 (defun notmuch-show-view-all-mime-parts ()
 217   "Use external viewers to view all attachments from the current message."
 218   (interactive)
 219   (with-current-notmuch-show-message
 220    ;; We override the mm-inline-media-tests to indicate which message
 221    ;; parts are already sufficiently handled by the original
 222    ;; presentation of the message in notmuch-show mode. These parts
 223    ;; will be inserted directly into the temporary buffer of
 224    ;; with-current-notmuch-show-message and silently discarded.
 225    ;;
 226    ;; Any MIME part not explicitly mentioned here will be handled by an
 227    ;; external viewer as configured in the various mailcap files.
 228    (let ((mm-inline-media-tests '(
 229                                   ("text/.*" ignore identity)
 230                                   ("application/pgp-signature" ignore identity)
 231                                   ("multipart/alternative" ignore identity)
 232                                   ("multipart/mixed" ignore identity)
 233                                   ("multipart/related" ignore identity)
 234                                  )))
 235      (mm-display-parts (mm-dissect-buffer)))))
 236
 237 (defun notmuch-foreach-mime-part (function mm-handle)
 238   (cond ((stringp (car mm-handle))
 239          (dolist (part (cdr mm-handle))
 240            (notmuch-foreach-mime-part function part)))
 241         ((bufferp (car mm-handle))
 242          (funcall function mm-handle))
 243         (t (dolist (part mm-handle)
 244              (notmuch-foreach-mime-part function part)))))
 245
 246 (defun notmuch-count-attachments (mm-handle)
 247   (let ((count 0))
 248     (notmuch-foreach-mime-part
 249      (lambda (p)
 250        (let ((disposition (mm-handle-disposition p)))
 251          (and (listp disposition)
 252               (or (equal (car disposition) "attachment")
 253                   (and (equal (car disposition) "inline")
 254                        (assq 'filename disposition)))
 255               (incf count))))
 256      mm-handle)
 257     count))
 258
 259 (defun notmuch-save-attachments (mm-handle &optional queryp)
 260   (notmuch-foreach-mime-part
 261    (lambda (p)
 262      (let ((disposition (mm-handle-disposition p)))
 263        (and (listp disposition)
 264             (or (equal (car disposition) "attachment")
 265                 (and (equal (car disposition) "inline")
 266                      (assq 'filename disposition)))
 267             (or (not queryp)
 268                 (y-or-n-p
 269                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 270             (mm-save-part p))))
 271    mm-handle))
 272
 273 (defun notmuch-show-save-attachments ()
 274   "Save all attachments from the current message."
 275   (interactive)
 276   (with-current-notmuch-show-message
 277    (let ((mm-handle (mm-dissect-buffer)))
 278      (notmuch-save-attachments
 279       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 280   (message "Done"))
 281
 282 (defun notmuch-show-with-message-as-text (fn)
 283   "Apply FN to a text representation of the current message.
 284
 285 FN is called with one argument, the message properties. It should
 286 operation on the contents of the current buffer."
 287
 288   ;; Remake the header to ensure that all information is available.
 289   (let* ((to (notmuch-show-get-to))
 290          (cc (notmuch-show-get-cc))
 291          (from (notmuch-show-get-from))
 292          (subject (notmuch-show-get-subject))
 293          (date (notmuch-show-get-date))
 294          (tags (notmuch-show-get-tags))
 295          (depth (notmuch-show-get-depth))
 296
 297          (header (concat
 298                   "Subject: " subject "\n"
 299                   "To: " to "\n"
 300                   (if (not (string= cc ""))
 301                       (concat "Cc: " cc "\n")
 302                     "")
 303                   "From: " from "\n"
 304                   "Date: " date "\n"
 305                   (if tags
 306                       (concat "Tags: "
 307                               (mapconcat #'identity tags ", ") "\n")
 308                     "")))
 309          (all (buffer-substring (notmuch-show-message-top)
 310                                 (notmuch-show-message-bottom)))
 311
 312          (props (notmuch-show-get-message-properties))
 313          (indenting notmuch-show-indent-content))
 314     (with-temp-buffer
 315       (insert all)
 316       (if indenting
 317           (indent-rigidly (point-min) (point-max) (- depth)))
 318       ;; Remove the original header.
 319       (goto-char (point-min))
 320       (re-search-forward "^$" (point-max) nil)
 321       (delete-region (point-min) (point))
 322       (insert header)
 323       (funcall fn props))))
 324
 325 (defun notmuch-show-print-message ()
 326   "Print the current message."
 327   (interactive)
 328   (notmuch-show-with-message-as-text 'notmuch-print-message))
 329
 330 (defun notmuch-show-fontify-header ()
 331   (let ((face (cond
 332                ((looking-at "[Tt]o:")
 333                 'message-header-to)
 334                ((looking-at "[Bb]?[Cc][Cc]:")
 335                 'message-header-cc)
 336                ((looking-at "[Ss]ubject:")
 337                 'message-header-subject)
 338                ((looking-at "[Ff]rom:")
 339                 'message-header-from)
 340                (t
 341                 'message-header-other))))
 342
 343     (overlay-put (make-overlay (point) (re-search-forward ":"))
 344                  'face 'message-header-name)
 345     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 346                  'face face)))
 347
 348 (defun notmuch-show-colour-headers ()
 349   "Apply some colouring to the current headers."
 350   (goto-char (point-min))
 351   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 352     (notmuch-show-fontify-header)
 353     (forward-line)))
 354
 355 (defun notmuch-show-spaces-n (n)
 356   "Return a string comprised of `n' spaces."
 357   (make-string n ? ))
 358
 359 (defun notmuch-show-update-tags (tags)
 360   "Update the displayed tags of the current message."
 361   (save-excursion
 362     (goto-char (notmuch-show-message-top))
 363     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 364         (let ((inhibit-read-only t))
 365           (replace-match (concat "("
 366                                  (notmuch-tag-format-tags tags)
 367                                  ")"))))))
 368
 369 (defun notmuch-clean-address (address)
 370   "Try to clean a single email ADDRESS for display. Return a cons
 371 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 372 parsing fails."
 373   (condition-case nil
 374     (let (p-name p-address)
 375       ;; It would be convenient to use `mail-header-parse-address',
 376       ;; but that expects un-decoded mailbox parts, whereas our
 377       ;; mailbox parts are already decoded (and hence may contain
 378       ;; UTF-8). Given that notmuch should handle most of the awkward
 379       ;; cases, some simple string deconstruction should be sufficient
 380       ;; here.
 381       (cond
 382        ;; "User <user@dom.ain>" style.
 383        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 384         (setq p-name (match-string 1 address)
 385               p-address (match-string 2 address)))
 386
 387        ;; "<user@dom.ain>" style.
 388        ((string-match "<\\(.*\\)>" address)
 389         (setq p-address (match-string 1 address)))
 390
 391        ;; Everything else.
 392        (t
 393         (setq p-address address)))
 394
 395       (when p-name
 396         ;; Remove elements of the mailbox part that are not relevant for
 397         ;; display, even if they are required during transport:
 398         ;;
 399         ;; Backslashes.
 400         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 401
 402         ;; Outer single and double quotes, which might be nested.
 403         (loop
 404          with start-of-loop
 405          do (setq start-of-loop p-name)
 406
 407          when (string-match "^\"\\(.*\\)\"$" p-name)
 408          do (setq p-name (match-string 1 p-name))
 409
 410          when (string-match "^'\\(.*\\)'$" p-name)
 411          do (setq p-name (match-string 1 p-name))
 412
 413          until (string= start-of-loop p-name)))
 414
 415       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 416       ;; 'foo@bar.com'.
 417       (when (string= p-name p-address)
 418         (setq p-name nil))
 419
 420       (cons p-address p-name))
 421     (error (cons address nil))))
 422
 423 (defun notmuch-show-clean-address (address)
 424   "Try to clean a single email ADDRESS for display.  Return
 425 unchanged ADDRESS if parsing fails."
 426   (let* ((clean-address (notmuch-clean-address address))
 427          (p-address (car clean-address))
 428          (p-name (cdr clean-address)))
 429     ;; If no name, return just the address.
 430     (if (not p-name)
 431         p-address
 432       ;; Otherwise format the name and address together.
 433       (concat p-name " <" p-address ">"))))
 434
 435 (defun notmuch-show-insert-headerline (headers date tags depth)
 436   "Insert a notmuch style headerline based on HEADERS for a
 437 message at DEPTH in the current thread."
 438   (let ((start (point)))
 439     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 440             (notmuch-show-clean-address (plist-get headers :From))
 441             " ("
 442             date
 443             ") ("
 444             (notmuch-tag-format-tags tags)
 445             ")\n")
 446     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 447
 448 (defun notmuch-show-insert-header (header header-value)
 449   "Insert a single header."
 450   (insert header ": " header-value "\n"))
 451
 452 (defun notmuch-show-insert-headers (headers)
 453   "Insert the headers of the current message."
 454   (let ((start (point)))
 455     (mapc (lambda (header)
 456             (let* ((header-symbol (intern (concat ":" header)))
 457                    (header-value (plist-get headers header-symbol)))
 458               (if (and header-value
 459                        (not (string-equal "" header-value)))
 460                   (notmuch-show-insert-header header header-value))))
 461           notmuch-message-headers)
 462     (save-excursion
 463       (save-restriction
 464         (narrow-to-region start (point-max))
 465         (run-hooks 'notmuch-show-markup-headers-hook)))))
 466
 467 (define-button-type 'notmuch-show-part-button-type
 468   'action 'notmuch-show-part-button-default
 469   'follow-link t
 470   'face 'message-mml
 471   :supertype 'notmuch-button-type)
 472
 473 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 474   (let ((button)
 475         (base-label (concat (when name (concat name ": "))
 476                             declared-type
 477                             (unless (string-equal declared-type content-type)
 478                               (concat " (as " content-type ")"))
 479                             comment)))
 480
 481     (setq button
 482           (insert-button
 483            (concat "[ " base-label " ]")
 484            :base-label base-label
 485            :type 'notmuch-show-part-button-type))
 486     (insert "\n")
 487     ;; return button
 488     button))
 489
 490 ;; This is taken from notmuch-wash: maybe it should be unified?
 491 (defun notmuch-show-toggle-part-invisibility (&optional button)
 492   (interactive)
 493   (let* ((button (or button (button-at (point))))
 494          (overlay (button-get button 'overlay)))
 495     (when overlay
 496       (let* ((show (overlay-get overlay 'invisible))
 497              (new-start (button-start button))
 498              (button-label (button-get button :base-label))
 499              (old-point (point))
 500              (properties (text-properties-at (point)))
 501              (inhibit-read-only t))
 502         (overlay-put overlay 'invisible (not show))
 503         (goto-char new-start)
 504         (insert "[ " button-label (if show " ]" " (hidden) ]"))
 505         (set-text-properties new-start (point) properties)
 506         (let ((old-end (button-end button)))
 507           (move-overlay button new-start (point))
 508           (delete-region (point) old-end))
 509         (goto-char (min old-point (1- (button-end button))))))))
 510
 511 ;; MIME part renderers
 512
 513 (defun notmuch-show-multipart/*-to-list (part)
 514   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 515           (plist-get part :content)))
 516
 517 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
 518   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 519         (inner-parts (plist-get part :content))
 520         (start (point)))
 521     ;; This inserts all parts of the chosen type rather than just one,
 522     ;; but it's not clear that this is the wrong thing to do - which
 523     ;; should be chosen if there are more than one that match?
 524     (mapc (lambda (inner-part)
 525             (let* ((inner-type (plist-get inner-part :content-type))
 526                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 527                            (string= chosen-type inner-type)))))
 528               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 529           inner-parts)
 530
 531     (when notmuch-show-indent-multipart
 532       (indent-rigidly start (point) 1)))
 533   t)
 534
 535 (defun notmuch-show-setup-w3m ()
 536   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 537   (interactive)
 538   (if (boundp 'w3m-cid-retrieve-function-alist)
 539     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 540       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 541             w3m-cid-retrieve-function-alist)))
 542   (setq mm-inline-text-html-with-images t))
 543
 544 (defvar w3m-current-buffer) ;; From `w3m.el'.
 545 (defvar notmuch-show-w3m-cid-store nil)
 546 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 547
 548 (defun notmuch-show-w3m-cid-store-internal (content-id
 549                                             message-id
 550                                             part-number
 551                                             content-type
 552                                             content)
 553   (push (list content-id
 554               message-id
 555               part-number
 556               content-type
 557               content)
 558         notmuch-show-w3m-cid-store))
 559
 560 (defun notmuch-show-w3m-cid-store (msg part)
 561   (let ((content-id (plist-get part :content-id)))
 562     (when content-id
 563       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 564                                            (plist-get msg :id)
 565                                            (plist-get part :id)
 566                                            (plist-get part :content-type)
 567                                            nil))))
 568
 569 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 570   (let ((matching-part (with-current-buffer w3m-current-buffer
 571                          (assoc url notmuch-show-w3m-cid-store))))
 572     (if matching-part
 573         (let ((message-id (nth 1 matching-part))
 574               (part-number (nth 2 matching-part))
 575               (content-type (nth 3 matching-part))
 576               (content (nth 4 matching-part)))
 577           ;; If we don't already have the content, get it and cache
 578           ;; it, as some messages reference the same cid: part many
 579           ;; times (hundreds!), which results in many calls to
 580           ;; `notmuch part'.
 581           (unless content
 582             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 583                                                               part-number notmuch-show-process-crypto))
 584             (with-current-buffer w3m-current-buffer
 585               (notmuch-show-w3m-cid-store-internal url
 586                                                    message-id
 587                                                    part-number
 588                                                    content-type
 589                                                    content)))
 590           (insert content)
 591           content-type)
 592       nil)))
 593
 594 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
 595   (let ((inner-parts (plist-get part :content))
 596         (start (point)))
 597
 598     ;; We assume that the first part is text/html and the remainder
 599     ;; things that it references.
 600
 601     ;; Stash the non-primary parts.
 602     (mapc (lambda (part)
 603             (notmuch-show-w3m-cid-store msg part))
 604           (cdr inner-parts))
 605
 606     ;; Render the primary part.
 607     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 608
 609     (when notmuch-show-indent-multipart
 610       (indent-rigidly start (point) 1)))
 611   t)
 612
 613 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
 614   (button-put button 'face 'notmuch-crypto-part-header)
 615   ;; add signature status button if sigstatus provided
 616   (if (plist-member part :sigstatus)
 617       (let* ((from (notmuch-show-get-header :From msg))
 618              (sigstatus (car (plist-get part :sigstatus))))
 619         (notmuch-crypto-insert-sigstatus-button sigstatus from))
 620     ;; if we're not adding sigstatus, tell the user how they can get it
 621     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 622
 623   (let ((inner-parts (plist-get part :content))
 624         (start (point)))
 625     ;; Show all of the parts.
 626     (mapc (lambda (inner-part)
 627             (notmuch-show-insert-bodypart msg inner-part depth))
 628           inner-parts)
 629
 630     (when notmuch-show-indent-multipart
 631       (indent-rigidly start (point) 1)))
 632   t)
 633
 634 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
 635   (button-put button 'face 'notmuch-crypto-part-header)
 636   ;; add encryption status button if encstatus specified
 637   (if (plist-member part :encstatus)
 638       (let ((encstatus (car (plist-get part :encstatus))))
 639         (notmuch-crypto-insert-encstatus-button encstatus)
 640         ;; add signature status button if sigstatus specified
 641         (if (plist-member part :sigstatus)
 642             (let* ((from (notmuch-show-get-header :From msg))
 643                    (sigstatus (car (plist-get part :sigstatus))))
 644               (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 645     ;; if we're not adding encstatus, tell the user how they can get it
 646     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 647
 648   (let ((inner-parts (plist-get part :content))
 649         (start (point)))
 650     ;; Show all of the parts.
 651     (mapc (lambda (inner-part)
 652             (notmuch-show-insert-bodypart msg inner-part depth))
 653           inner-parts)
 654
 655     (when notmuch-show-indent-multipart
 656       (indent-rigidly start (point) 1)))
 657   t)
 658
 659 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
 660   (let ((inner-parts (plist-get part :content))
 661         (start (point)))
 662     ;; Show all of the parts.
 663     (mapc (lambda (inner-part)
 664             (notmuch-show-insert-bodypart msg inner-part depth))
 665           inner-parts)
 666
 667     (when notmuch-show-indent-multipart
 668       (indent-rigidly start (point) 1)))
 669   t)
 670
 671 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
 672   (let* ((message (car (plist-get part :content)))
 673          (body (car (plist-get message :body)))
 674          (start (point)))
 675
 676     ;; Override `notmuch-message-headers' to force `From' to be
 677     ;; displayed.
 678     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 679       (notmuch-show-insert-headers (plist-get message :headers)))
 680
 681     ;; Blank line after headers to be compatible with the normal
 682     ;; message display.
 683     (insert "\n")
 684
 685     ;; Show the body
 686     (notmuch-show-insert-bodypart msg body depth)
 687
 688     (when notmuch-show-indent-multipart
 689       (indent-rigidly start (point) 1)))
 690   t)
 691
 692 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
 693   ;; For backward compatibility we want to apply the text/plain hook
 694   ;; to the whole of the part including the part button if there is
 695   ;; one.
 696   (let ((start (if button
 697                    (button-start button)
 698                  (point))))
 699     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 700     (save-excursion
 701       (save-restriction
 702         (narrow-to-region start (point-max))
 703         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 704   t)
 705
 706 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
 707   (insert (with-temp-buffer
 708             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 709             ;; notmuch-get-bodypart-content provides "raw", non-converted
 710             ;; data. Replace CRLF with LF before icalendar can use it.
 711             (goto-char (point-min))
 712             (while (re-search-forward "\r\n" nil t)
 713               (replace-match "\n" nil nil))
 714             (let ((file (make-temp-file "notmuch-ical"))
 715                   result)
 716               (unwind-protect
 717                   (progn
 718                     (unless (icalendar-import-buffer file t)
 719                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 720                     (set-buffer (get-file-buffer file))
 721                     (setq result (buffer-substring (point-min) (point-max)))
 722                     (set-buffer-modified-p nil)
 723                     (kill-buffer (current-buffer)))
 724                 (delete-file file))
 725               result)))
 726   t)
 727
 728 ;; For backwards compatibility.
 729 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
 730   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
 731
 732 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 733   ;; If we can deduce a MIME type from the filename of the attachment,
 734   ;; we return that.
 735   (if (plist-get part :filename)
 736       (let ((extension (file-name-extension (plist-get part :filename)))
 737             mime-type)
 738         (if extension
 739             (progn
 740               (mailcap-parse-mimetypes)
 741               (setq mime-type (mailcap-extension-to-mime extension))
 742               (if (and mime-type
 743                        (not (string-equal mime-type "application/octet-stream")))
 744                   mime-type
 745                 nil))
 746           nil))))
 747
 748 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
 749   ;; text/html handler to work around bugs in renderers and our
 750   ;; invisibile parts code. In particular w3m sets up a keymap which
 751   ;; "leaks" outside the invisible region and causes strange effects
 752   ;; in notmuch. We set mm-inline-text-html-with-w3m-keymap to nil to
 753   ;; tell w3m not to set a keymap (so the normal notmuch-show-mode-map
 754   ;; remains).
 755   (let ((mm-inline-text-html-with-w3m-keymap nil))
 756     (notmuch-show-insert-part-*/* msg part content-type nth depth button)))
 757
 758 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
 759   ;; This handler _must_ succeed - it is the handler of last resort.
 760   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 761   t)
 762
 763 ;; Functions for determining how to handle MIME parts.
 764
 765 (defun notmuch-show-handlers-for (content-type)
 766   "Return a list of content handlers for a part of type CONTENT-TYPE."
 767   (let (result)
 768     (mapc (lambda (func)
 769             (if (functionp func)
 770                 (push func result)))
 771           ;; Reverse order of prefrence.
 772           (list (intern (concat "notmuch-show-insert-part-*/*"))
 773                 (intern (concat
 774                          "notmuch-show-insert-part-"
 775                          (car (notmuch-split-content-type content-type))
 776                          "/*"))
 777                 (intern (concat "notmuch-show-insert-part-" content-type))))
 778     result))
 779
 780 ;; \f
 781
 782 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
 783   (let ((handlers (notmuch-show-handlers-for content-type)))
 784     ;; Run the content handlers until one of them returns a non-nil
 785     ;; value.
 786     (while (and handlers
 787                 (not (condition-case err
 788                          (funcall (car handlers) msg part content-type nth depth button)
 789                        (error (progn
 790                                 (insert "!!! Bodypart insert error: ")
 791                                 (insert (error-message-string err))
 792                                 (insert " !!!\n") nil)))))
 793       (setq handlers (cdr handlers))))
 794   t)
 795
 796 (defun notmuch-show-create-part-overlays (button beg end hide)
 797   "Add an overlay to the part between BEG and END"
 798
 799   ;; If there is no button (i.e., the part is text/plain and the first
 800   ;; part) or if the part has no content then we don't make the part
 801   ;; toggleable.
 802   (when (and button (/= beg end))
 803     (button-put button 'overlay (make-overlay beg end))
 804     ;; We toggle the button for hidden parts as that gets the
 805     ;; button label right.
 806     (save-excursion
 807       (when hide
 808         (notmuch-show-toggle-part-invisibility button)))))
 809
 810 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 811   "Insert the body part PART at depth DEPTH in the current thread.
 812
 813 If HIDE is non-nil then initially hide this part."
 814
 815   (let* ((content-type (downcase (plist-get part :content-type)))
 816          (mime-type (or (and (string= content-type "application/octet-stream")
 817                              (notmuch-show-get-mime-type-of-application/octet-stream part))
 818                         (and (string= content-type "inline patch")
 819                              "text/x-diff")
 820                         content-type))
 821          (nth (plist-get part :id))
 822          (beg (point))
 823          ;; We omit the part button for the first (or only) part if this is text/plain.
 824          (button (unless (and (string= mime-type "text/plain") (<= nth 1))
 825                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
 826          (content-beg (point)))
 827
 828     (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
 829     ;; Some of the body part handlers leave point somewhere up in the
 830     ;; part, so we make sure that we're down at the end.
 831     (goto-char (point-max))
 832     ;; Ensure that the part ends with a carriage return.
 833     (unless (bolp)
 834       (insert "\n"))
 835     (notmuch-show-create-part-overlays button content-beg (point) hide)
 836     ;; Record part information.  Since we already inserted subparts,
 837     ;; don't override existing :notmuch-part properties.
 838     (notmuch-map-text-property beg (point) :notmuch-part
 839                                (lambda (v) (or v part)))
 840     ;; Make :notmuch-part front sticky and rear non-sticky so it stays
 841     ;; applied to the beginning of each line when we indent the
 842     ;; message.  Since we're operating on arbitrary renderer output,
 843     ;; watch out for sticky specs of t, which means all properties are
 844     ;; front-sticky/rear-nonsticky.
 845     (notmuch-map-text-property beg (point) 'front-sticky
 846                                (lambda (v) (if (listp v)
 847                                                (pushnew :notmuch-part v)
 848                                              v)))
 849     (notmuch-map-text-property beg (point) 'rear-nonsticky
 850                                (lambda (v) (if (listp v)
 851                                                (pushnew :notmuch-part v)
 852                                              v)))))
 853
 854 (defun notmuch-show-insert-body (msg body depth)
 855   "Insert the body BODY at depth DEPTH in the current thread."
 856   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 857
 858 (defun notmuch-show-make-symbol (type)
 859   (make-symbol (concat "notmuch-show-" type)))
 860
 861 (defun notmuch-show-strip-re (string)
 862   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 863
 864 (defvar notmuch-show-previous-subject "")
 865 (make-variable-buffer-local 'notmuch-show-previous-subject)
 866
 867 (defun notmuch-show-insert-msg (msg depth)
 868   "Insert the message MSG at depth DEPTH in the current thread."
 869   (let* ((headers (plist-get msg :headers))
 870          ;; Indentation causes the buffer offset of the start/end
 871          ;; points to move, so we must use markers.
 872          message-start message-end
 873          content-start content-end
 874          headers-start headers-end
 875          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 876
 877     (setq message-start (point-marker))
 878
 879     (notmuch-show-insert-headerline headers
 880                                     (or (if notmuch-show-relative-dates
 881                                             (plist-get msg :date_relative)
 882                                           nil)
 883                                         (plist-get headers :Date))
 884                                     (plist-get msg :tags) depth)
 885
 886     (setq content-start (point-marker))
 887
 888     ;; Set `headers-start' to point after the 'Subject:' header to be
 889     ;; compatible with the existing implementation. This just sets it
 890     ;; to after the first header.
 891     (notmuch-show-insert-headers headers)
 892     (save-excursion
 893       (goto-char content-start)
 894       ;; If the subject of this message is the same as that of the
 895       ;; previous message, don't display it when this message is
 896       ;; collapsed.
 897       (when (not (string= notmuch-show-previous-subject
 898                           bare-subject))
 899         (forward-line 1))
 900       (setq headers-start (point-marker)))
 901     (setq headers-end (point-marker))
 902
 903     (setq notmuch-show-previous-subject bare-subject)
 904
 905     ;; A blank line between the headers and the body.
 906     (insert "\n")
 907     (notmuch-show-insert-body msg (plist-get msg :body)
 908                               (if notmuch-show-indent-content depth 0))
 909     ;; Ensure that the body ends with a newline.
 910     (unless (bolp)
 911       (insert "\n"))
 912     (setq content-end (point-marker))
 913
 914     ;; Indent according to the depth in the thread.
 915     (if notmuch-show-indent-content
 916         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 917
 918     (setq message-end (point-max-marker))
 919
 920     ;; Save the extents of this message over the whole text of the
 921     ;; message.
 922     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 923
 924     ;; Create overlays used to control visibility
 925     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
 926     (plist-put msg :message-overlay (make-overlay headers-start content-end))
 927
 928     (plist-put msg :depth depth)
 929
 930     ;; Save the properties for this message. Currently this saves the
 931     ;; entire message (augmented it with other stuff), which seems
 932     ;; like overkill. We might save a reduced subset (for example, not
 933     ;; the content).
 934     (notmuch-show-set-message-properties msg)
 935
 936     ;; Set header visibility.
 937     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 938
 939     ;; Message visibility depends on whether it matched the search
 940     ;; criteria.
 941     (notmuch-show-message-visible msg (and (plist-get msg :match)
 942                                            (not (plist-get msg :excluded))))))
 943
 944 (defun notmuch-show-toggle-process-crypto ()
 945   "Toggle the processing of cryptographic MIME parts."
 946   (interactive)
 947   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 948   (message (if notmuch-show-process-crypto
 949                "Processing cryptographic MIME parts."
 950              "Not processing cryptographic MIME parts."))
 951   (notmuch-show-refresh-view))
 952
 953 (defun notmuch-show-toggle-elide-non-matching ()
 954   "Toggle the display of non-matching messages."
 955   (interactive)
 956   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 957   (message (if notmuch-show-elide-non-matching-messages
 958                "Showing matching messages only."
 959              "Showing all messages."))
 960   (notmuch-show-refresh-view))
 961
 962 (defun notmuch-show-toggle-thread-indentation ()
 963   "Toggle the indentation of threads."
 964   (interactive)
 965   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 966   (message (if notmuch-show-indent-content
 967                "Content is indented."
 968              "Content is not indented."))
 969   (notmuch-show-refresh-view))
 970
 971 (defun notmuch-show-insert-tree (tree depth)
 972   "Insert the message tree TREE at depth DEPTH in the current thread."
 973   (let ((msg (car tree))
 974         (replies (cadr tree)))
 975     ;; We test whether there is a message or just some replies.
 976     (when msg
 977       (notmuch-show-insert-msg msg depth))
 978     (notmuch-show-insert-thread replies (1+ depth))))
 979
 980 (defun notmuch-show-insert-thread (thread depth)
 981   "Insert the thread THREAD at depth DEPTH in the current forest."
 982   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 983
 984 (defun notmuch-show-insert-forest (forest)
 985   "Insert the forest of threads FOREST."
 986   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 987
 988 (defvar notmuch-id-regexp
 989   (concat
 990    ;; Match the id: prefix only if it begins a word (to disallow, for
 991    ;; example, matching cid:).
 992    "\\<id:\\("
 993    ;; If the term starts with a ", then parse Xapian's quoted boolean
 994    ;; term syntax, which allows for anything as long as embedded
 995    ;; double quotes escaped by doubling them.  We also disallow
 996    ;; newlines (which Xapian allows) to prevent runaway terms.
 997    "\"\\([^\"\n]\\|\"\"\\)*\""
 998    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
 999    ;; next space or ).  We disallow [.,;] as the last character
1000    ;; because these are probably part of the surrounding text, and not
1001    ;; part of the id.  This doesn't match single character ids; meh.
1002    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1003    "\\)")
1004   "The regexp used to match id: links in messages.")
1005
1006 (defvar notmuch-mid-regexp
1007   ;; goto-address-url-regexp matched cid: links, which have the same
1008   ;; grammar as the message ID part of a mid: link.  Construct the
1009   ;; regexp using the same technique as goto-address-url-regexp.
1010   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1011   "The regexp used to match mid: links in messages.
1012
1013 See RFC 2392.")
1014
1015 (defun notmuch-show-buttonise-links (start end)
1016   "Buttonise URLs and mail addresses between START and END.
1017
1018 This also turns id:\"<message id>\"-parts and mid: links into
1019 buttons for a corresponding notmuch search."
1020   (goto-address-fontify-region start end)
1021   (save-excursion
1022     (let (links)
1023       (goto-char start)
1024       (while (re-search-forward notmuch-id-regexp end t)
1025         (push (list (match-beginning 0) (match-end 0)
1026                     (match-string-no-properties 0)) links))
1027       (goto-char start)
1028       (while (re-search-forward notmuch-mid-regexp end t)
1029         (let* ((mid-cid (match-string-no-properties 1))
1030                (mid (save-match-data
1031                       (string-match "^[^/]*" mid-cid)
1032                       (url-unhex-string (match-string 0 mid-cid)))))
1033           (push (list (match-beginning 0) (match-end 0)
1034                       (notmuch-id-to-query mid)) links)))
1035       (dolist (link links)
1036         ;; Remove the overlay created by goto-address-mode
1037         (remove-overlays (first link) (second link) 'goto-address t)
1038         (make-text-button (first link) (second link)
1039                           :type 'notmuch-button-type
1040                           'action `(lambda (arg)
1041                                      (notmuch-show ,(third link)))
1042                           'follow-link t
1043                           'help-echo "Mouse-1, RET: search for this message"
1044                           'face goto-address-mail-face)))))
1045
1046 ;;;###autoload
1047 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1048   "Run \"notmuch show\" with the given thread ID and display results.
1049
1050 The optional PARENT-BUFFER is the notmuch-search buffer from
1051 which this notmuch-show command was executed, (so that the
1052 next thread from that buffer can be show when done with this
1053 one).
1054
1055 The optional QUERY-CONTEXT is a notmuch search term. Only
1056 messages from the thread matching this search term are shown if
1057 non-nil.
1058
1059 The optional BUFFER-NAME provides the name of the buffer in
1060 which the message thread is shown. If it is nil (which occurs
1061 when the command is called interactively) the argument to the
1062 function is used."
1063   (interactive "sNotmuch show: ")
1064   (let ((buffer-name (generate-new-buffer-name
1065                       (or buffer-name
1066                           (concat "*notmuch-" thread-id "*")))))
1067     (switch-to-buffer (get-buffer-create buffer-name))
1068     ;; Set the default value for `notmuch-show-process-crypto' in this
1069     ;; buffer.
1070     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1071     ;; Set the default value for
1072     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1073     ;; there is a prefix argument, invert the default.
1074     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1075     (if current-prefix-arg
1076         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1077
1078     (setq notmuch-show-thread-id thread-id
1079           notmuch-show-parent-buffer parent-buffer
1080           notmuch-show-query-context query-context)
1081     (notmuch-show-build-buffer)
1082     (notmuch-show-goto-first-wanted-message)
1083     (current-buffer)))
1084
1085 (defun notmuch-show-build-buffer ()
1086   (let ((inhibit-read-only t))
1087
1088     (notmuch-show-mode)
1089     ;; Don't track undo information for this buffer
1090     (set 'buffer-undo-list t)
1091
1092     (erase-buffer)
1093     (goto-char (point-min))
1094     (save-excursion
1095       (let* ((basic-args (list notmuch-show-thread-id))
1096              (args (if notmuch-show-query-context
1097                        (append (list "\'") basic-args
1098                                (list "and (" notmuch-show-query-context ")\'"))
1099                      (append (list "\'") basic-args (list "\'"))))
1100              (cli-args (cons "--exclude=false"
1101                              (when notmuch-show-elide-non-matching-messages
1102                                (list "--entire-thread=false")))))
1103
1104         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1105         ;; If the query context reduced the results to nothing, run
1106         ;; the basic query.
1107         (when (and (eq (buffer-size) 0)
1108                    notmuch-show-query-context)
1109           (notmuch-show-insert-forest
1110            (notmuch-query-get-threads (append cli-args basic-args)))))
1111
1112       (jit-lock-register #'notmuch-show-buttonise-links)
1113
1114       ;; Set the header line to the subject of the first message.
1115       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1116
1117       (run-hooks 'notmuch-show-hook))))
1118
1119 (defun notmuch-show-capture-state ()
1120   "Capture the state of the current buffer.
1121
1122 This includes:
1123  - the list of open messages,
1124  - the current message."
1125   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1126
1127 (defun notmuch-show-apply-state (state)
1128   "Apply STATE to the current buffer.
1129
1130 This includes:
1131  - opening the messages previously opened,
1132  - closing all other messages,
1133  - moving to the correct current message."
1134   (let ((current (car state))
1135         (open (cadr state)))
1136
1137     ;; Open those that were open.
1138     (goto-char (point-min))
1139     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1140                                            (member (notmuch-show-get-message-id) open))
1141           until (not (notmuch-show-goto-message-next)))
1142
1143     ;; Go to the previously open message.
1144     (goto-char (point-min))
1145     (unless (loop if (string= current (notmuch-show-get-message-id))
1146                   return t
1147                   until (not (notmuch-show-goto-message-next)))
1148       (goto-char (point-min))
1149       (message "Previously current message not found."))
1150     (notmuch-show-message-adjust)))
1151
1152 (defun notmuch-show-refresh-view (&optional reset-state)
1153   "Refresh the current view.
1154
1155 Refreshes the current view, observing changes in display
1156 preferences. If invoked with a prefix argument (or RESET-STATE is
1157 non-nil) then the state of the buffer (open/closed messages) is
1158 reset based on the original query."
1159   (interactive "P")
1160   (let ((inhibit-read-only t)
1161         (state (unless reset-state
1162                  (notmuch-show-capture-state))))
1163     ;; erase-buffer does not seem to remove overlays, which can lead
1164     ;; to weird effects such as remaining images, so remove them
1165     ;; manually.
1166     (remove-overlays)
1167     (erase-buffer)
1168     (notmuch-show-build-buffer)
1169     (if state
1170         (notmuch-show-apply-state state)
1171       ;; We're resetting state, so navigate to the first open message
1172       ;; and mark it read, just like opening a new show buffer.
1173       (notmuch-show-goto-first-wanted-message))))
1174
1175 (defvar notmuch-show-stash-map
1176   (let ((map (make-sparse-keymap)))
1177     (define-key map "c" 'notmuch-show-stash-cc)
1178     (define-key map "d" 'notmuch-show-stash-date)
1179     (define-key map "F" 'notmuch-show-stash-filename)
1180     (define-key map "f" 'notmuch-show-stash-from)
1181     (define-key map "i" 'notmuch-show-stash-message-id)
1182     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1183     (define-key map "s" 'notmuch-show-stash-subject)
1184     (define-key map "T" 'notmuch-show-stash-tags)
1185     (define-key map "t" 'notmuch-show-stash-to)
1186     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1187     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1188     map)
1189   "Submap for stash commands")
1190 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1191
1192 (defvar notmuch-show-part-map
1193   (let ((map (make-sparse-keymap)))
1194     (define-key map "s" 'notmuch-show-save-part)
1195     (define-key map "v" 'notmuch-show-view-part)
1196     (define-key map "o" 'notmuch-show-interactively-view-part)
1197     (define-key map "|" 'notmuch-show-pipe-part)
1198     map)
1199   "Submap for part commands")
1200 (fset 'notmuch-show-part-map notmuch-show-part-map)
1201
1202 (defvar notmuch-show-mode-map
1203       (let ((map (make-sparse-keymap)))
1204         (define-key map "?" 'notmuch-help)
1205         (define-key map "q" 'notmuch-kill-this-buffer)
1206         (define-key map (kbd "<C-tab>") 'widget-backward)
1207         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1208         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1209         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1210         (define-key map "s" 'notmuch-search)
1211         (define-key map "m" 'notmuch-mua-new-mail)
1212         (define-key map "f" 'notmuch-show-forward-message)
1213         (define-key map "r" 'notmuch-show-reply-sender)
1214         (define-key map "R" 'notmuch-show-reply)
1215         (define-key map "|" 'notmuch-show-pipe-message)
1216         (define-key map "w" 'notmuch-show-save-attachments)
1217         (define-key map "V" 'notmuch-show-view-raw-message)
1218         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1219         (define-key map "c" 'notmuch-show-stash-map)
1220         (define-key map "=" 'notmuch-show-refresh-view)
1221         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1222         (define-key map "*" 'notmuch-show-tag-all)
1223         (define-key map "-" 'notmuch-show-remove-tag)
1224         (define-key map "+" 'notmuch-show-add-tag)
1225         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1226         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1227         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1228         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1229         (define-key map "N" 'notmuch-show-next-message)
1230         (define-key map "P" 'notmuch-show-previous-message)
1231         (define-key map "n" 'notmuch-show-next-open-message)
1232         (define-key map "p" 'notmuch-show-previous-open-message)
1233         (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1234         (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1235         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1236         (define-key map " " 'notmuch-show-advance-and-archive)
1237         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1238         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1239         (define-key map "#" 'notmuch-show-print-message)
1240         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1241         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1242         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1243         (define-key map "t" 'toggle-truncate-lines)
1244         (define-key map "." 'notmuch-show-part-map)
1245         map)
1246       "Keymap for \"notmuch show\" buffers.")
1247 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1248
1249 (defun notmuch-show-mode ()
1250   "Major mode for viewing a thread with notmuch.
1251
1252 This buffer contains the results of the \"notmuch show\" command
1253 for displaying a single thread of email from your email archives.
1254
1255 By default, various components of email messages, (citations,
1256 signatures, already-read messages), are hidden. You can make
1257 these parts visible by clicking with the mouse button or by
1258 pressing RET after positioning the cursor on a hidden part, (for
1259 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1260
1261 Reading the thread sequentially is well-supported by pressing
1262 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1263 to the next message, or advance to the next thread (if already on
1264 the last message of a thread).
1265
1266 Other commands are available to read or manipulate the thread
1267 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1268 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1269 without scrolling through with \\[notmuch-show-advance-and-archive]).
1270
1271 You can add or remove arbitrary tags from the current message with
1272 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1273
1274 All currently available key bindings:
1275
1276 \\{notmuch-show-mode-map}"
1277   (interactive)
1278   (kill-all-local-variables)
1279   (use-local-map notmuch-show-mode-map)
1280   (setq major-mode 'notmuch-show-mode
1281         mode-name "notmuch-show")
1282   (setq buffer-read-only t
1283         truncate-lines t))
1284
1285 (defun notmuch-show-move-to-message-top ()
1286   (goto-char (notmuch-show-message-top)))
1287
1288 (defun notmuch-show-move-to-message-bottom ()
1289   (goto-char (notmuch-show-message-bottom)))
1290
1291 (defun notmuch-show-message-adjust ()
1292   (recenter 0))
1293
1294 ;; Movement related functions.
1295
1296 ;; There's some strangeness here where a text property applied to a
1297 ;; region a->b is not found when point is at b. We walk backwards
1298 ;; until finding the property.
1299 (defun notmuch-show-message-extent ()
1300   (let (r)
1301     (save-excursion
1302       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1303         (backward-char)))
1304     r))
1305
1306 (defun notmuch-show-message-top ()
1307   (car (notmuch-show-message-extent)))
1308
1309 (defun notmuch-show-message-bottom ()
1310   (cdr (notmuch-show-message-extent)))
1311
1312 (defun notmuch-show-goto-message-next ()
1313   (let ((start (point)))
1314     (notmuch-show-move-to-message-bottom)
1315     (if (not (eobp))
1316         t
1317       (goto-char start)
1318       nil)))
1319
1320 (defun notmuch-show-goto-message-previous ()
1321   (notmuch-show-move-to-message-top)
1322   (if (bobp)
1323       nil
1324     (backward-char)
1325     (notmuch-show-move-to-message-top)
1326     t))
1327
1328 (defun notmuch-show-mapc (function)
1329   "Iterate through all messages in the current thread with
1330 `notmuch-show-goto-message-next' and call FUNCTION for side
1331 effects."
1332   (save-excursion
1333     (goto-char (point-min))
1334     (loop do (funcall function)
1335           while (notmuch-show-goto-message-next))))
1336
1337 ;; Functions relating to the visibility of messages and their
1338 ;; components.
1339
1340 (defun notmuch-show-message-visible (props visible-p)
1341   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1342   (notmuch-show-set-prop :message-visible visible-p props))
1343
1344 (defun notmuch-show-headers-visible (props visible-p)
1345   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1346   (notmuch-show-set-prop :headers-visible visible-p props))
1347
1348 ;; Functions for setting and getting attributes of the current
1349 ;; message.
1350
1351 (defun notmuch-show-set-message-properties (props)
1352   (save-excursion
1353     (notmuch-show-move-to-message-top)
1354     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1355
1356 (defun notmuch-show-get-message-properties ()
1357   "Return the properties of the current message as a plist.
1358
1359 Some useful entries are:
1360 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1361 :body - Body of the message
1362 :tags - Tags for this message"
1363   (save-excursion
1364     (notmuch-show-move-to-message-top)
1365     (get-text-property (point) :notmuch-message-properties)))
1366
1367 (defun notmuch-show-get-part-properties ()
1368   "Return the properties of the innermost part containing point.
1369
1370 This is the part property list retrieved from the CLI.  Signals
1371 an error if there is no part containing point."
1372   (or (get-text-property (point) :notmuch-part)
1373       (error "No message part here")))
1374
1375 (defun notmuch-show-set-prop (prop val &optional props)
1376   (let ((inhibit-read-only t)
1377         (props (or props
1378                    (notmuch-show-get-message-properties))))
1379     (plist-put props prop val)
1380     (notmuch-show-set-message-properties props)))
1381
1382 (defun notmuch-show-get-prop (prop &optional props)
1383   (let ((props (or props
1384                    (notmuch-show-get-message-properties))))
1385     (plist-get props prop)))
1386
1387 (defun notmuch-show-get-message-id (&optional bare)
1388   "Return an id: query for the Message-Id of the current message.
1389
1390 If optional argument BARE is non-nil, return
1391 the Message-Id without id: prefix and escaping."
1392   (if bare
1393       (notmuch-show-get-prop :id)
1394     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1395
1396 (defun notmuch-show-get-messages-ids ()
1397   "Return all id: queries of messages in the current thread."
1398   (let ((message-ids))
1399     (notmuch-show-mapc
1400      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1401     message-ids))
1402
1403 (defun notmuch-show-get-messages-ids-search ()
1404   "Return a search string for all message ids of messages in the
1405 current thread."
1406   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1407
1408 ;; dme: Would it make sense to use a macro for many of these?
1409
1410 (defun notmuch-show-get-filename ()
1411   "Return the filename of the current message."
1412   (notmuch-show-get-prop :filename))
1413
1414 (defun notmuch-show-get-header (header &optional props)
1415   "Return the named header of the current message, if any."
1416   (plist-get (notmuch-show-get-prop :headers props) header))
1417
1418 (defun notmuch-show-get-cc ()
1419   (notmuch-show-get-header :Cc))
1420
1421 (defun notmuch-show-get-date ()
1422   (notmuch-show-get-header :Date))
1423
1424 (defun notmuch-show-get-from ()
1425   (notmuch-show-get-header :From))
1426
1427 (defun notmuch-show-get-subject ()
1428   (notmuch-show-get-header :Subject))
1429
1430 (defun notmuch-show-get-to ()
1431   (notmuch-show-get-header :To))
1432
1433 (defun notmuch-show-get-depth ()
1434   (notmuch-show-get-prop :depth))
1435
1436 (defun notmuch-show-set-tags (tags)
1437   "Set the tags of the current message."
1438   (notmuch-show-set-prop :tags tags)
1439   (notmuch-show-update-tags tags))
1440
1441 (defun notmuch-show-get-tags ()
1442   "Return the tags of the current message."
1443   (notmuch-show-get-prop :tags))
1444
1445 (defun notmuch-show-message-visible-p ()
1446   "Is the current message visible?"
1447   (notmuch-show-get-prop :message-visible))
1448
1449 (defun notmuch-show-headers-visible-p ()
1450   "Are the headers of the current message visible?"
1451   (notmuch-show-get-prop :headers-visible))
1452
1453 (defun notmuch-show-mark-read (&optional unread)
1454   "Mark the current message as read.
1455
1456 Mark the current message as read by applying the tag changes in
1457 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1458 default). If a prefix argument is given, the message will be
1459 marked as unread, i.e. the tag changes in
1460 `notmuch-show-mark-read-tags' will be reversed."
1461   (interactive "P")
1462   (when notmuch-show-mark-read-tags
1463     (apply 'notmuch-show-tag-message
1464            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1465
1466 ;; Functions for getting attributes of several messages in the current
1467 ;; thread.
1468
1469 (defun notmuch-show-get-message-ids-for-open-messages ()
1470   "Return a list of all id: queries for open messages in the current thread."
1471   (save-excursion
1472     (let (message-ids done)
1473       (goto-char (point-min))
1474       (while (not done)
1475         (if (notmuch-show-message-visible-p)
1476             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1477         (setq done (not (notmuch-show-goto-message-next)))
1478         )
1479       message-ids
1480       )))
1481
1482 ;; Commands typically bound to keys.
1483
1484 (defun notmuch-show-advance ()
1485   "Advance through thread.
1486
1487 If the current message in the thread is not yet fully visible,
1488 scroll by a near screenful to read more of the message.
1489
1490 Otherwise, (the end of the current message is already within the
1491 current window), advance to the next open message."
1492   (interactive)
1493   (let* ((end-of-this-message (notmuch-show-message-bottom))
1494          (visible-end-of-this-message (1- end-of-this-message))
1495          (ret nil))
1496     (while (invisible-p visible-end-of-this-message)
1497       (setq visible-end-of-this-message
1498             (max (point-min)
1499                  (1- (previous-single-char-property-change
1500                       visible-end-of-this-message 'invisible)))))
1501     (cond
1502      ;; Ideally we would test `end-of-this-message' against the result
1503      ;; of `window-end', but that doesn't account for the fact that
1504      ;; the end of the message might be hidden.
1505      ((and visible-end-of-this-message
1506            (> visible-end-of-this-message (window-end)))
1507       ;; The bottom of this message is not visible - scroll.
1508       (scroll-up nil))
1509
1510      ((not (= end-of-this-message (point-max)))
1511       ;; This is not the last message - move to the next visible one.
1512       (notmuch-show-next-open-message))
1513
1514      ((not (= (point) (point-max)))
1515       ;; This is the last message, but the cursor is not at the end of
1516       ;; the buffer. Move it there.
1517       (goto-char (point-max)))
1518
1519      (t
1520       ;; This is the last message - change the return value
1521       (setq ret t)))
1522     ret))
1523
1524 (defun notmuch-show-advance-and-archive ()
1525   "Advance through thread and archive.
1526
1527 This command is intended to be one of the simplest ways to
1528 process a thread of email. It works exactly like
1529 notmuch-show-advance, in that it scrolls through messages in a
1530 show buffer, except that when it gets to the end of the buffer it
1531 archives the entire current thread, (apply changes in
1532 `notmuch-archive-tags'), kills the buffer, and displays the next
1533 thread from the search from which this thread was originally
1534 shown."
1535   (interactive)
1536   (if (notmuch-show-advance)
1537       (notmuch-show-archive-thread-then-next)))
1538
1539 (defun notmuch-show-rewind ()
1540   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1541
1542 Specifically, if the beginning of the previous email is fewer
1543 than `window-height' lines from the current point, move to it
1544 just like `notmuch-show-previous-message'.
1545
1546 Otherwise, just scroll down a screenful of the current message.
1547
1548 This command does not modify any message tags, (it does not undo
1549 any effects from previous calls to
1550 `notmuch-show-advance-and-archive'."
1551   (interactive)
1552   (let ((start-of-message (notmuch-show-message-top))
1553         (start-of-window (window-start)))
1554     (cond
1555       ;; Either this message is properly aligned with the start of the
1556       ;; window or the start of this message is not visible on the
1557       ;; screen - scroll.
1558      ((or (= start-of-message start-of-window)
1559           (< start-of-message start-of-window))
1560       (scroll-down)
1561       ;; If a small number of lines from the previous message are
1562       ;; visible, realign so that the top of the current message is at
1563       ;; the top of the screen.
1564       (when (<= (count-screen-lines (window-start) start-of-message)
1565                 next-screen-context-lines)
1566         (goto-char (notmuch-show-message-top))
1567         (notmuch-show-message-adjust))
1568       ;; Move to the top left of the window.
1569       (goto-char (window-start)))
1570      (t
1571       ;; Move to the previous message.
1572       (notmuch-show-previous-message)))))
1573
1574 (defun notmuch-show-reply (&optional prompt-for-sender)
1575   "Reply to the sender and all recipients of the current message."
1576   (interactive "P")
1577   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1578
1579 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1580   "Reply to the sender of the current message."
1581   (interactive "P")
1582   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1583
1584 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1585   "Forward the current message."
1586   (interactive "P")
1587   (with-current-notmuch-show-message
1588    (notmuch-mua-new-forward-message prompt-for-sender)))
1589
1590 (defun notmuch-show-next-message (&optional pop-at-end)
1591   "Show the next message.
1592
1593 If a prefix argument is given and this is the last message in the
1594 thread, navigate to the next thread in the parent search buffer."
1595   (interactive "P")
1596   (if (notmuch-show-goto-message-next)
1597       (progn
1598         (notmuch-show-mark-read)
1599         (notmuch-show-message-adjust))
1600     (if pop-at-end
1601         (notmuch-show-next-thread)
1602       (goto-char (point-max)))))
1603
1604 (defun notmuch-show-previous-message ()
1605   "Show the previous message or the start of the current message."
1606   (interactive)
1607   (if (= (point) (notmuch-show-message-top))
1608       (notmuch-show-goto-message-previous)
1609     (notmuch-show-move-to-message-top))
1610   (notmuch-show-mark-read)
1611   (notmuch-show-message-adjust))
1612
1613 (defun notmuch-show-next-open-message (&optional pop-at-end)
1614   "Show the next open message.
1615
1616 If a prefix argument is given and this is the last open message
1617 in the thread, navigate to the next thread in the parent search
1618 buffer. Return t if there was a next open message in the thread
1619 to show, nil otherwise."
1620   (interactive "P")
1621   (let (r)
1622     (while (and (setq r (notmuch-show-goto-message-next))
1623                 (not (notmuch-show-message-visible-p))))
1624     (if r
1625         (progn
1626           (notmuch-show-mark-read)
1627           (notmuch-show-message-adjust))
1628       (if pop-at-end
1629           (notmuch-show-next-thread)
1630         (goto-char (point-max))))
1631     r))
1632
1633 (defun notmuch-show-next-matching-message ()
1634   "Show the next matching message."
1635   (interactive)
1636   (let (r)
1637     (while (and (setq r (notmuch-show-goto-message-next))
1638                 (not (notmuch-show-get-prop :match))))
1639     (if r
1640         (progn
1641           (notmuch-show-mark-read)
1642           (notmuch-show-message-adjust))
1643       (goto-char (point-max)))))
1644
1645 (defun notmuch-show-open-if-matched ()
1646   "Open a message if it is matched (whether or not excluded)."
1647   (let ((props (notmuch-show-get-message-properties)))
1648     (notmuch-show-message-visible props (plist-get props :match))))
1649
1650 (defun notmuch-show-goto-first-wanted-message ()
1651   "Move to the first open message and mark it read"
1652   (goto-char (point-min))
1653   (if (notmuch-show-message-visible-p)
1654       (notmuch-show-mark-read)
1655     (notmuch-show-next-open-message))
1656   (when (eobp)
1657     ;; There are no matched non-excluded messages so open all matched
1658     ;; (necessarily excluded) messages and go to the first.
1659     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1660     (force-window-update)
1661     (goto-char (point-min))
1662     (if (notmuch-show-message-visible-p)
1663         (notmuch-show-mark-read)
1664       (notmuch-show-next-open-message))))
1665
1666 (defun notmuch-show-previous-open-message ()
1667   "Show the previous open message."
1668   (interactive)
1669   (while (and (if (= (point) (notmuch-show-message-top))
1670                   (notmuch-show-goto-message-previous)
1671                 (notmuch-show-move-to-message-top))
1672               (not (notmuch-show-message-visible-p))))
1673   (notmuch-show-mark-read)
1674   (notmuch-show-message-adjust))
1675
1676 (defun notmuch-show-view-raw-message ()
1677   "View the file holding the current message."
1678   (interactive)
1679   (let* ((id (notmuch-show-get-message-id))
1680          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1681     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1682     (switch-to-buffer buf)
1683     (goto-char (point-min))
1684     (set-buffer-modified-p nil)
1685     (view-buffer buf 'kill-buffer-if-not-modified)))
1686
1687 (defun notmuch-show-pipe-message (entire-thread command)
1688   "Pipe the contents of the current message (or thread) to the given command.
1689
1690 The given command will be executed with the raw contents of the
1691 current email message as stdin. Anything printed by the command
1692 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1693
1694 When invoked with a prefix argument, the command will receive all
1695 open messages in the current thread (formatted as an mbox) rather
1696 than only the current message."
1697   (interactive "P\nsPipe message to command: ")
1698   (let (shell-command)
1699     (if entire-thread
1700         (setq shell-command
1701               (concat notmuch-command " show --format=mbox --exclude=false "
1702                       (shell-quote-argument
1703                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1704                       " | " command))
1705       (setq shell-command
1706             (concat notmuch-command " show --format=raw "
1707                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1708     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1709       (with-current-buffer buf
1710         (setq buffer-read-only nil)
1711         (erase-buffer)
1712         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1713           (goto-char (point-max))
1714           (set-buffer-modified-p nil)
1715           (setq buffer-read-only t)
1716           (unless (zerop exit-code)
1717             (switch-to-buffer-other-window buf)
1718             (message (format "Command '%s' exited abnormally with code %d"
1719                              shell-command exit-code))))))))
1720
1721 (defun notmuch-show-tag-message (&rest tag-changes)
1722   "Change tags for the current message.
1723
1724 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1725   (let* ((current-tags (notmuch-show-get-tags))
1726          (new-tags (notmuch-update-tags current-tags tag-changes)))
1727     (unless (equal current-tags new-tags)
1728       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
1729       (notmuch-show-set-tags new-tags))))
1730
1731 (defun notmuch-show-tag (&optional tag-changes)
1732   "Change tags for the current message.
1733
1734 See `notmuch-tag' for information on the format of TAG-CHANGES."
1735   (interactive)
1736   (let* ((tag-changes (notmuch-tag (notmuch-show-get-message-id) tag-changes))
1737          (current-tags (notmuch-show-get-tags))
1738          (new-tags (notmuch-update-tags current-tags tag-changes)))
1739     (unless (equal current-tags new-tags)
1740       (notmuch-show-set-tags new-tags))))
1741
1742 (defun notmuch-show-tag-all (&optional tag-changes)
1743   "Change tags for all messages in the current show buffer.
1744
1745 See `notmuch-tag' for information on the format of TAG-CHANGES."
1746   (interactive)
1747   (setq tag-changes (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1748   (notmuch-show-mapc
1749    (lambda ()
1750      (let* ((current-tags (notmuch-show-get-tags))
1751             (new-tags (notmuch-update-tags current-tags tag-changes)))
1752        (unless (equal current-tags new-tags)
1753          (notmuch-show-set-tags new-tags))))))
1754
1755 (defun notmuch-show-add-tag ()
1756   "Same as `notmuch-show-tag' but sets initial input to '+'."
1757   (interactive)
1758   (notmuch-show-tag "+"))
1759
1760 (defun notmuch-show-remove-tag ()
1761   "Same as `notmuch-show-tag' but sets initial input to '-'."
1762   (interactive)
1763   (notmuch-show-tag "-"))
1764
1765 (defun notmuch-show-toggle-visibility-headers ()
1766   "Toggle the visibility of the current message headers."
1767   (interactive)
1768   (let ((props (notmuch-show-get-message-properties)))
1769     (notmuch-show-headers-visible
1770      props
1771      (not (plist-get props :headers-visible))))
1772   (force-window-update))
1773
1774 (defun notmuch-show-toggle-message ()
1775   "Toggle the visibility of the current message."
1776   (interactive)
1777   (let ((props (notmuch-show-get-message-properties)))
1778     (notmuch-show-message-visible
1779      props
1780      (not (plist-get props :message-visible))))
1781   (force-window-update))
1782
1783 (defun notmuch-show-open-or-close-all ()
1784   "Set the visibility all of the messages in the current thread.
1785 By default make all of the messages visible. With a prefix
1786 argument, hide all of the messages."
1787   (interactive)
1788   (save-excursion
1789     (goto-char (point-min))
1790     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1791                                            (not current-prefix-arg))
1792           until (not (notmuch-show-goto-message-next))))
1793   (force-window-update))
1794
1795 (defun notmuch-show-next-button ()
1796   "Advance point to the next button in the buffer."
1797   (interactive)
1798   (forward-button 1))
1799
1800 (defun notmuch-show-previous-button ()
1801   "Move point back to the previous button in the buffer."
1802   (interactive)
1803   (backward-button 1))
1804
1805 (defun notmuch-show-next-thread (&optional show previous)
1806   "Move to the next item in the search results, if any.
1807
1808 If SHOW is non-nil, open the next item in a show
1809 buffer. Otherwise just highlight the next item in the search
1810 buffer. If PREVIOUS is non-nil, move to the previous item in the
1811 search results instead."
1812   (interactive "P")
1813   (let ((parent-buffer notmuch-show-parent-buffer))
1814     (notmuch-kill-this-buffer)
1815     (when (buffer-live-p parent-buffer)
1816       (switch-to-buffer parent-buffer)
1817       (and (if previous
1818                (notmuch-search-previous-thread)
1819              (notmuch-search-next-thread))
1820            show
1821            (notmuch-search-show-thread)))))
1822
1823 (defun notmuch-show-next-thread-show ()
1824   "Show the next thread in the search results, if any."
1825   (interactive)
1826   (notmuch-show-next-thread t))
1827
1828 (defun notmuch-show-previous-thread-show ()
1829   "Show the previous thread in the search results, if any."
1830   (interactive)
1831   (notmuch-show-next-thread t t))
1832
1833 (defun notmuch-show-archive-thread (&optional unarchive)
1834   "Archive each message in thread.
1835
1836 Archive each message currently shown by applying the tag changes
1837 in `notmuch-archive-tags' to each. If a prefix argument is given,
1838 the messages will be \"unarchived\", i.e. the tag changes in
1839 `notmuch-archive-tags' will be reversed.
1840
1841 Note: This command is safe from any race condition of new messages
1842 being delivered to the same thread. It does not archive the
1843 entire thread, but only the messages shown in the current
1844 buffer."
1845   (interactive "P")
1846   (when notmuch-archive-tags
1847     (notmuch-show-tag-all
1848      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1849
1850 (defun notmuch-show-archive-thread-then-next ()
1851   "Archive all messages in the current buffer, then show next thread from search."
1852   (interactive)
1853   (notmuch-show-archive-thread)
1854   (notmuch-show-next-thread t))
1855
1856 (defun notmuch-show-archive-thread-then-exit ()
1857   "Archive all messages in the current buffer, then exit back to search results."
1858   (interactive)
1859   (notmuch-show-archive-thread)
1860   (notmuch-show-next-thread))
1861
1862 (defun notmuch-show-archive-message (&optional unarchive)
1863   "Archive the current message.
1864
1865 Archive the current message by applying the tag changes in
1866 `notmuch-archive-tags' to it. If a prefix argument is given, the
1867 message will be \"unarchived\", i.e. the tag changes in
1868 `notmuch-archive-tags' will be reversed."
1869   (interactive "P")
1870   (when notmuch-archive-tags
1871     (apply 'notmuch-show-tag-message
1872            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1873
1874 (defun notmuch-show-archive-message-then-next-or-exit ()
1875   "Archive the current message, then show the next open message in the current thread.
1876
1877 If at the last open message in the current thread, then exit back
1878 to search results."
1879   (interactive)
1880   (notmuch-show-archive-message)
1881   (notmuch-show-next-open-message t))
1882
1883 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1884   "Archive the current message, then show the next open message in the current thread.
1885
1886 If at the last open message in the current thread, then show next
1887 thread from search."
1888   (interactive)
1889   (notmuch-show-archive-message)
1890   (unless (notmuch-show-next-open-message)
1891     (notmuch-show-next-thread t)))
1892
1893 (defun notmuch-show-stash-cc ()
1894   "Copy CC field of current message to kill-ring."
1895   (interactive)
1896   (notmuch-common-do-stash (notmuch-show-get-cc)))
1897
1898 (defun notmuch-show-stash-date ()
1899   "Copy date of current message to kill-ring."
1900   (interactive)
1901   (notmuch-common-do-stash (notmuch-show-get-date)))
1902
1903 (defun notmuch-show-stash-filename ()
1904   "Copy filename of current message to kill-ring."
1905   (interactive)
1906   (notmuch-common-do-stash (notmuch-show-get-filename)))
1907
1908 (defun notmuch-show-stash-from ()
1909   "Copy From address of current message to kill-ring."
1910   (interactive)
1911   (notmuch-common-do-stash (notmuch-show-get-from)))
1912
1913 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
1914   "Copy id: query matching the current message to kill-ring.
1915
1916 If invoked with a prefix argument (or STASH-THREAD-ID is
1917 non-nil), copy thread: query matching the current thread to
1918 kill-ring."
1919   (interactive "P")
1920   (if stash-thread-id
1921       (notmuch-common-do-stash notmuch-show-thread-id)
1922     (notmuch-common-do-stash (notmuch-show-get-message-id))))
1923
1924 (defun notmuch-show-stash-message-id-stripped ()
1925   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1926   (interactive)
1927   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1928
1929 (defun notmuch-show-stash-subject ()
1930   "Copy Subject field of current message to kill-ring."
1931   (interactive)
1932   (notmuch-common-do-stash (notmuch-show-get-subject)))
1933
1934 (defun notmuch-show-stash-tags ()
1935   "Copy tags of current message to kill-ring as a comma separated list."
1936   (interactive)
1937   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1938
1939 (defun notmuch-show-stash-to ()
1940   "Copy To address of current message to kill-ring."
1941   (interactive)
1942   (notmuch-common-do-stash (notmuch-show-get-to)))
1943
1944 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1945   "Copy an ML Archive URI for the current message to the kill-ring.
1946
1947 This presumes that the message is available at the selected Mailing List Archive.
1948
1949 If optional argument MLA is non-nil, use the provided key instead of prompting
1950 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1951   (interactive)
1952   (notmuch-common-do-stash
1953    (concat (cdr (assoc
1954                  (or mla
1955                      (let ((completion-ignore-case t))
1956                        (completing-read
1957                         "Mailing List Archive: "
1958                         notmuch-show-stash-mlarchive-link-alist
1959                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1960                  notmuch-show-stash-mlarchive-link-alist))
1961            (notmuch-show-get-message-id t))))
1962
1963 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1964   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1965
1966 This presumes that the message is available at the selected Mailing List Archive.
1967
1968 If optional argument MLA is non-nil, use the provided key instead of prompting
1969 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1970   (interactive)
1971   (notmuch-show-stash-mlarchive-link mla)
1972   (browse-url (current-kill 0 t)))
1973
1974 ;; Interactive part functions and their helpers
1975
1976 (defun notmuch-show-generate-part-buffer (message-id nth)
1977   "Return a temporary buffer containing the specified part's content."
1978   (let ((buf (generate-new-buffer " *notmuch-part*"))
1979         (process-crypto notmuch-show-process-crypto))
1980     (with-current-buffer buf
1981       (setq notmuch-show-process-crypto process-crypto)
1982       ;; Always acquires the part via `notmuch part', even if it is
1983       ;; available in the JSON output.
1984       (insert (notmuch-get-bodypart-internal message-id nth notmuch-show-process-crypto)))
1985     buf))
1986
1987 (defun notmuch-show-current-part-handle ()
1988   "Return an mm-handle for the part containing point.
1989
1990 This creates a temporary buffer for the part's content; the
1991 caller is responsible for killing this buffer as appropriate."
1992   (let* ((part (notmuch-show-get-part-properties))
1993          (message-id (notmuch-show-get-message-id))
1994          (nth (plist-get part :id))
1995          (buf (notmuch-show-generate-part-buffer message-id nth))
1996          (content-type (plist-get part :content-type))
1997          (filename (plist-get part :filename))
1998          (disposition (if filename `(attachment (filename . ,filename)))))
1999     (mm-make-handle buf (list content-type) nil nil disposition)))
2000
2001 (defun notmuch-show-apply-to-current-part-handle (fn)
2002   "Apply FN to an mm-handle for the part containing point.
2003
2004 This ensures that the temporary buffer created for the mm-handle
2005 is destroyed when FN returns."
2006   (let ((handle (notmuch-show-current-part-handle)))
2007     (unwind-protect
2008         (funcall fn handle)
2009       (kill-buffer (mm-handle-buffer handle)))))
2010
2011 (defun notmuch-show-part-button-default (&optional button)
2012   (interactive)
2013   (let ((button (or button (button-at (point)))))
2014     (if (button-get button 'overlay)
2015         (notmuch-show-toggle-part-invisibility button)
2016       (call-interactively notmuch-show-part-button-default-action))))
2017
2018 (defun notmuch-show-save-part ()
2019   "Save the MIME part containing point to a file."
2020   (interactive)
2021   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2022
2023 (defun notmuch-show-view-part ()
2024   "View the MIME part containing point in an external viewer."
2025   (interactive)
2026   ;; Set mm-inlined-types to nil to force an external viewer
2027   (let ((mm-inlined-types nil))
2028     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2029
2030 (defun notmuch-show-interactively-view-part ()
2031   "View the MIME part containing point, prompting for a viewer."
2032   (interactive)
2033   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2034
2035 (defun notmuch-show-pipe-part ()
2036   "Pipe the MIME part containing point to an external command."
2037   (interactive)
2038   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2039
2040
2041 (provide 'notmuch-show)