git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-fontify-headers "notmuch" nil)
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts t
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ;; FIXME: can these services be searched by `Message-Id' ?
 162     ;; ("MarkMail" . "http://markmail.org/")
 163     ;; ("Nabble" . "http://nabble.com/")
 164     ;; ("opensubscriber" . "http://opensubscriber.com/")
 165     )
 166   "List of Mailing List Archives to use when stashing links.
 167
 168 These URIs are concatenated with the current message's
 169 Message-Id in `notmuch-show-stash-mlarchive-link'."
 170   :type '(alist :key-type (string :tag "Name")
 171                 :value-type (string :tag "URL"))
 172   :group 'notmuch-show)
 173
 174 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 175   "Default Mailing List Archive to use when stashing links.
 176
 177 This is used when `notmuch-show-stash-mlarchive-link' isn't
 178 provided with an MLA argument nor `completing-read' input."
 179   :type `(choice
 180           ,@(mapcar
 181              (lambda (mla)
 182                (list 'const :tag (car mla) :value (car mla)))
 183              notmuch-show-stash-mlarchive-link-alist))
 184   :group 'notmuch-show)
 185
 186 (defcustom notmuch-show-mark-read-tags '("-unread")
 187   "List of tag changes to apply to a message when it is marked as read.
 188
 189 Tags starting with \"+\" (or not starting with either \"+\" or
 190 \"-\") in the list will be added, and tags starting with \"-\"
 191 will be removed from the message being marked as read.
 192
 193 For example, if you wanted to remove an \"unread\" tag and add a
 194 \"read\" tag (which would make little sense), you would set:
 195     (\"-unread\" \"+read\")"
 196   :type '(repeat string)
 197   :group 'notmuch-show)
 198
 199
 200 (defmacro with-current-notmuch-show-message (&rest body)
 201   "Evaluate body with current buffer set to the text of current message"
 202   `(save-excursion
 203      (let ((id (notmuch-show-get-message-id)))
 204        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 205          (with-current-buffer buf
 206            (let ((coding-system-for-read 'no-conversion))
 207              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 208              ,@body)
 209            (kill-buffer buf))))))
 210
 211 (defun notmuch-show-turn-on-visual-line-mode ()
 212   "Enable Visual Line mode."
 213   (visual-line-mode t))
 214
 215 (defun notmuch-show-view-all-mime-parts ()
 216   "Use external viewers to view all attachments from the current message."
 217   (interactive)
 218   (with-current-notmuch-show-message
 219    ;; We override the mm-inline-media-tests to indicate which message
 220    ;; parts are already sufficiently handled by the original
 221    ;; presentation of the message in notmuch-show mode. These parts
 222    ;; will be inserted directly into the temporary buffer of
 223    ;; with-current-notmuch-show-message and silently discarded.
 224    ;;
 225    ;; Any MIME part not explicitly mentioned here will be handled by an
 226    ;; external viewer as configured in the various mailcap files.
 227    (let ((mm-inline-media-tests '(
 228                                   ("text/.*" ignore identity)
 229                                   ("application/pgp-signature" ignore identity)
 230                                   ("multipart/alternative" ignore identity)
 231                                   ("multipart/mixed" ignore identity)
 232                                   ("multipart/related" ignore identity)
 233                                  )))
 234      (mm-display-parts (mm-dissect-buffer)))))
 235
 236 (defun notmuch-foreach-mime-part (function mm-handle)
 237   (cond ((stringp (car mm-handle))
 238          (dolist (part (cdr mm-handle))
 239            (notmuch-foreach-mime-part function part)))
 240         ((bufferp (car mm-handle))
 241          (funcall function mm-handle))
 242         (t (dolist (part mm-handle)
 243              (notmuch-foreach-mime-part function part)))))
 244
 245 (defun notmuch-count-attachments (mm-handle)
 246   (let ((count 0))
 247     (notmuch-foreach-mime-part
 248      (lambda (p)
 249        (let ((disposition (mm-handle-disposition p)))
 250          (and (listp disposition)
 251               (or (equal (car disposition) "attachment")
 252                   (and (equal (car disposition) "inline")
 253                        (assq 'filename disposition)))
 254               (incf count))))
 255      mm-handle)
 256     count))
 257
 258 (defun notmuch-save-attachments (mm-handle &optional queryp)
 259   (notmuch-foreach-mime-part
 260    (lambda (p)
 261      (let ((disposition (mm-handle-disposition p)))
 262        (and (listp disposition)
 263             (or (equal (car disposition) "attachment")
 264                 (and (equal (car disposition) "inline")
 265                      (assq 'filename disposition)))
 266             (or (not queryp)
 267                 (y-or-n-p
 268                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 269             (mm-save-part p))))
 270    mm-handle))
 271
 272 (defun notmuch-show-save-attachments ()
 273   "Save all attachments from the current message."
 274   (interactive)
 275   (with-current-notmuch-show-message
 276    (let ((mm-handle (mm-dissect-buffer)))
 277      (notmuch-save-attachments
 278       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 279   (message "Done"))
 280
 281 (defun notmuch-show-with-message-as-text (fn)
 282   "Apply FN to a text representation of the current message.
 283
 284 FN is called with one argument, the message properties. It should
 285 operation on the contents of the current buffer."
 286
 287   ;; Remake the header to ensure that all information is available.
 288   (let* ((to (notmuch-show-get-to))
 289          (cc (notmuch-show-get-cc))
 290          (from (notmuch-show-get-from))
 291          (subject (notmuch-show-get-subject))
 292          (date (notmuch-show-get-date))
 293          (tags (notmuch-show-get-tags))
 294          (depth (notmuch-show-get-depth))
 295
 296          (header (concat
 297                   "Subject: " subject "\n"
 298                   "To: " to "\n"
 299                   (if (not (string= cc ""))
 300                       (concat "Cc: " cc "\n")
 301                     "")
 302                   "From: " from "\n"
 303                   "Date: " date "\n"
 304                   (if tags
 305                       (concat "Tags: "
 306                               (mapconcat #'identity tags ", ") "\n")
 307                     "")))
 308          (all (buffer-substring (notmuch-show-message-top)
 309                                 (notmuch-show-message-bottom)))
 310
 311          (props (notmuch-show-get-message-properties))
 312          (indenting notmuch-show-indent-content))
 313     (with-temp-buffer
 314       (insert all)
 315       (if indenting
 316           (indent-rigidly (point-min) (point-max) (- depth)))
 317       ;; Remove the original header.
 318       (goto-char (point-min))
 319       (re-search-forward "^$" (point-max) nil)
 320       (delete-region (point-min) (point))
 321       (insert header)
 322       (funcall fn props))))
 323
 324 (defun notmuch-show-print-message ()
 325   "Print the current message."
 326   (interactive)
 327   (notmuch-show-with-message-as-text 'notmuch-print-message))
 328
 329 (defun notmuch-show-fontify-header ()
 330   (let ((face (cond
 331                ((looking-at "[Tt]o:")
 332                 'message-header-to)
 333                ((looking-at "[Bb]?[Cc][Cc]:")
 334                 'message-header-cc)
 335                ((looking-at "[Ss]ubject:")
 336                 'message-header-subject)
 337                ((looking-at "[Ff]rom:")
 338                 'message-header-from)
 339                (t
 340                 'message-header-other))))
 341
 342     (overlay-put (make-overlay (point) (re-search-forward ":"))
 343                  'face 'message-header-name)
 344     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 345                  'face face)))
 346
 347 (defun notmuch-show-colour-headers ()
 348   "Apply some colouring to the current headers."
 349   (goto-char (point-min))
 350   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 351     (notmuch-show-fontify-header)
 352     (forward-line)))
 353
 354 (defun notmuch-show-spaces-n (n)
 355   "Return a string comprised of `n' spaces."
 356   (make-string n ? ))
 357
 358 (defun notmuch-show-update-tags (tags)
 359   "Update the displayed tags of the current message."
 360   (save-excursion
 361     (goto-char (notmuch-show-message-top))
 362     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 363         (let ((inhibit-read-only t))
 364           (replace-match (concat "("
 365                                  (propertize (mapconcat 'identity tags " ")
 366                                              'face 'notmuch-tag-face)
 367                                  ")"))))))
 368
 369 (defun notmuch-clean-address (address)
 370   "Try to clean a single email ADDRESS for display. Return a cons
 371 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 372 parsing fails."
 373   (condition-case nil
 374     (let (p-name p-address)
 375       ;; It would be convenient to use `mail-header-parse-address',
 376       ;; but that expects un-decoded mailbox parts, whereas our
 377       ;; mailbox parts are already decoded (and hence may contain
 378       ;; UTF-8). Given that notmuch should handle most of the awkward
 379       ;; cases, some simple string deconstruction should be sufficient
 380       ;; here.
 381       (cond
 382        ;; "User <user@dom.ain>" style.
 383        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 384         (setq p-name (match-string 1 address)
 385               p-address (match-string 2 address)))
 386
 387        ;; "<user@dom.ain>" style.
 388        ((string-match "<\\(.*\\)>" address)
 389         (setq p-address (match-string 1 address)))
 390
 391        ;; Everything else.
 392        (t
 393         (setq p-address address)))
 394
 395       (when p-name
 396         ;; Remove elements of the mailbox part that are not relevant for
 397         ;; display, even if they are required during transport:
 398         ;;
 399         ;; Backslashes.
 400         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 401
 402         ;; Outer single and double quotes, which might be nested.
 403         (loop
 404          with start-of-loop
 405          do (setq start-of-loop p-name)
 406
 407          when (string-match "^\"\\(.*\\)\"$" p-name)
 408          do (setq p-name (match-string 1 p-name))
 409
 410          when (string-match "^'\\(.*\\)'$" p-name)
 411          do (setq p-name (match-string 1 p-name))
 412
 413          until (string= start-of-loop p-name)))
 414
 415       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 416       ;; 'foo@bar.com'.
 417       (when (string= p-name p-address)
 418         (setq p-name nil))
 419
 420       (cons p-address p-name))
 421     (error (cons address nil))))
 422
 423 (defun notmuch-show-clean-address (address)
 424   "Try to clean a single email ADDRESS for display.  Return
 425 unchanged ADDRESS if parsing fails."
 426   (let* ((clean-address (notmuch-clean-address address))
 427          (p-address (car clean-address))
 428          (p-name (cdr clean-address)))
 429     ;; If no name, return just the address.
 430     (if (not p-name)
 431         p-address
 432       ;; Otherwise format the name and address together.
 433       (concat p-name " <" p-address ">"))))
 434
 435 (defun notmuch-show-insert-headerline (headers date tags depth)
 436   "Insert a notmuch style headerline based on HEADERS for a
 437 message at DEPTH in the current thread."
 438   (let ((start (point)))
 439     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 440             (notmuch-show-clean-address (plist-get headers :From))
 441             " ("
 442             date
 443             ") ("
 444             (propertize (mapconcat 'identity tags " ")
 445                         'face 'notmuch-tag-face)
 446             ")\n")
 447     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 448
 449 (defun notmuch-show-insert-header (header header-value)
 450   "Insert a single header."
 451   (insert header ": " header-value "\n"))
 452
 453 (defun notmuch-show-insert-headers (headers)
 454   "Insert the headers of the current message."
 455   (let ((start (point)))
 456     (mapc (lambda (header)
 457             (let* ((header-symbol (intern (concat ":" header)))
 458                    (header-value (plist-get headers header-symbol)))
 459               (if (and header-value
 460                        (not (string-equal "" header-value)))
 461                   (notmuch-show-insert-header header header-value))))
 462           notmuch-message-headers)
 463     (save-excursion
 464       (save-restriction
 465         (narrow-to-region start (point-max))
 466         (run-hooks 'notmuch-show-markup-headers-hook)))))
 467
 468 (define-button-type 'notmuch-show-part-button-type
 469   'action 'notmuch-show-part-button-default
 470   'keymap 'notmuch-show-part-button-map
 471   'follow-link t
 472   'face 'message-mml)
 473
 474 (defvar notmuch-show-part-button-map
 475   (let ((map (make-sparse-keymap)))
 476     (set-keymap-parent map button-map)
 477     (define-key map "s" 'notmuch-show-part-button-save)
 478     (define-key map "v" 'notmuch-show-part-button-view)
 479     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 480     (define-key map "|" 'notmuch-show-part-button-pipe)
 481     map)
 482   "Submap for button commands")
 483 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 484
 485 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 486   (let ((button))
 487     (setq button
 488           (insert-button
 489            (concat "[ "
 490                    (if name (concat name ": ") "")
 491                    declared-type
 492                    (if (not (string-equal declared-type content-type))
 493                        (concat " (as " content-type ")")
 494                      "")
 495                    (or comment "")
 496                    " ]")
 497            :type 'notmuch-show-part-button-type
 498            :notmuch-part nth
 499            :notmuch-filename name
 500            :notmuch-content-type content-type))
 501     (insert "\n")
 502     ;; return button
 503     button))
 504
 505 ;; Functions handling particular MIME parts.
 506
 507 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 508   (declare (indent 2))
 509   (let ((process-crypto (make-symbol "process-crypto")))
 510     `(let ((,process-crypto notmuch-show-process-crypto))
 511        (with-temp-buffer
 512          (setq notmuch-show-process-crypto ,process-crypto)
 513          ;; Always acquires the part via `notmuch part', even if it is
 514          ;; available in the JSON output.
 515          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 516          ,@body))))
 517
 518 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 519   (notmuch-with-temp-part-buffer message-id nth
 520     (let ((file (read-file-name
 521                  "Filename to save as: "
 522                  (or mailcap-download-directory "~/")
 523                  nil nil
 524                  filename)))
 525       ;; Don't re-compress .gz & al.  Arguably we should make
 526       ;; `file-name-handler-alist' nil, but that would chop
 527       ;; ange-ftp, which is reasonable to use here.
 528       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 529
 530 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 531   (notmuch-with-temp-part-buffer message-id nth
 532     ;; set mm-inlined-types to nil to force an external viewer
 533     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 534           (mm-inlined-types nil))
 535       ;; We override mm-save-part as notmuch-show-save-part is better
 536       ;; since it offers the filename. We need to lexically bind
 537       ;; everything we need for notmuch-show-save-part to prevent
 538       ;; potential dynamic shadowing.
 539       (lexical-let ((message-id message-id)
 540                     (nth nth)
 541                     (filename filename)
 542                     (content-type content-type))
 543         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 544                                            message-id nth filename content-type)))
 545           (mm-display-part handle))))))
 546
 547 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 548   (notmuch-with-temp-part-buffer message-id nth
 549     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 550       (mm-interactively-view-part handle))))
 551
 552 (defun notmuch-show-pipe-part (message-id nth &optional filename content-type)
 553   (notmuch-with-temp-part-buffer message-id nth
 554     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 555       (mm-pipe-part handle))))
 556
 557 (defun notmuch-show-multipart/*-to-list (part)
 558   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 559           (plist-get part :content)))
 560
 561 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 562   (notmuch-show-insert-part-header nth declared-type content-type nil)
 563   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 564         (inner-parts (plist-get part :content))
 565         (start (point)))
 566     ;; This inserts all parts of the chosen type rather than just one,
 567     ;; but it's not clear that this is the wrong thing to do - which
 568     ;; should be chosen if there are more than one that match?
 569     (mapc (lambda (inner-part)
 570             (let ((inner-type (plist-get inner-part :content-type)))
 571               (if (or notmuch-show-all-multipart/alternative-parts
 572                       (string= chosen-type inner-type))
 573                   (notmuch-show-insert-bodypart msg inner-part depth)
 574                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 575           inner-parts)
 576
 577     (when notmuch-show-indent-multipart
 578       (indent-rigidly start (point) 1)))
 579   t)
 580
 581 (defun notmuch-show-setup-w3m ()
 582   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 583   (interactive)
 584   (if (boundp 'w3m-cid-retrieve-function-alist)
 585     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 586       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 587             w3m-cid-retrieve-function-alist)))
 588   (setq mm-inline-text-html-with-images t))
 589
 590 (defvar w3m-current-buffer) ;; From `w3m.el'.
 591 (defvar notmuch-show-w3m-cid-store nil)
 592 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 593
 594 (defun notmuch-show-w3m-cid-store-internal (content-id
 595                                             message-id
 596                                             part-number
 597                                             content-type
 598                                             content)
 599   (push (list content-id
 600               message-id
 601               part-number
 602               content-type
 603               content)
 604         notmuch-show-w3m-cid-store))
 605
 606 (defun notmuch-show-w3m-cid-store (msg part)
 607   (let ((content-id (plist-get part :content-id)))
 608     (when content-id
 609       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 610                                            (plist-get msg :id)
 611                                            (plist-get part :id)
 612                                            (plist-get part :content-type)
 613                                            nil))))
 614
 615 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 616   (let ((matching-part (with-current-buffer w3m-current-buffer
 617                          (assoc url notmuch-show-w3m-cid-store))))
 618     (if matching-part
 619         (let ((message-id (nth 1 matching-part))
 620               (part-number (nth 2 matching-part))
 621               (content-type (nth 3 matching-part))
 622               (content (nth 4 matching-part)))
 623           ;; If we don't already have the content, get it and cache
 624           ;; it, as some messages reference the same cid: part many
 625           ;; times (hundreds!), which results in many calls to
 626           ;; `notmuch part'.
 627           (unless content
 628             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 629                                                               part-number notmuch-show-process-crypto))
 630             (with-current-buffer w3m-current-buffer
 631               (notmuch-show-w3m-cid-store-internal url
 632                                                    message-id
 633                                                    part-number
 634                                                    content-type
 635                                                    content)))
 636           (insert content)
 637           content-type)
 638       nil)))
 639
 640 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 641   (notmuch-show-insert-part-header nth declared-type content-type nil)
 642   (let ((inner-parts (plist-get part :content))
 643         (start (point)))
 644
 645     ;; We assume that the first part is text/html and the remainder
 646     ;; things that it references.
 647
 648     ;; Stash the non-primary parts.
 649     (mapc (lambda (part)
 650             (notmuch-show-w3m-cid-store msg part))
 651           (cdr inner-parts))
 652
 653     ;; Render the primary part.
 654     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 655
 656     (when notmuch-show-indent-multipart
 657       (indent-rigidly start (point) 1)))
 658   t)
 659
 660 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 661   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 662     (button-put button 'face 'notmuch-crypto-part-header)
 663     ;; add signature status button if sigstatus provided
 664     (if (plist-member part :sigstatus)
 665         (let* ((from (notmuch-show-get-header :From msg))
 666                (sigstatus (car (plist-get part :sigstatus))))
 667           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 668       ;; if we're not adding sigstatus, tell the user how they can get it
 669       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 670
 671   (let ((inner-parts (plist-get part :content))
 672         (start (point)))
 673     ;; Show all of the parts.
 674     (mapc (lambda (inner-part)
 675             (notmuch-show-insert-bodypart msg inner-part depth))
 676           inner-parts)
 677
 678     (when notmuch-show-indent-multipart
 679       (indent-rigidly start (point) 1)))
 680   t)
 681
 682 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 683   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 684     (button-put button 'face 'notmuch-crypto-part-header)
 685     ;; add encryption status button if encstatus specified
 686     (if (plist-member part :encstatus)
 687         (let ((encstatus (car (plist-get part :encstatus))))
 688           (notmuch-crypto-insert-encstatus-button encstatus)
 689           ;; add signature status button if sigstatus specified
 690           (if (plist-member part :sigstatus)
 691               (let* ((from (notmuch-show-get-header :From msg))
 692                      (sigstatus (car (plist-get part :sigstatus))))
 693                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 694       ;; if we're not adding encstatus, tell the user how they can get it
 695       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 696
 697   (let ((inner-parts (plist-get part :content))
 698         (start (point)))
 699     ;; Show all of the parts.
 700     (mapc (lambda (inner-part)
 701             (notmuch-show-insert-bodypart msg inner-part depth))
 702           inner-parts)
 703
 704     (when notmuch-show-indent-multipart
 705       (indent-rigidly start (point) 1)))
 706   t)
 707
 708 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 709   (notmuch-show-insert-part-header nth declared-type content-type nil)
 710   (let ((inner-parts (plist-get part :content))
 711         (start (point)))
 712     ;; Show all of the parts.
 713     (mapc (lambda (inner-part)
 714             (notmuch-show-insert-bodypart msg inner-part depth))
 715           inner-parts)
 716
 717     (when notmuch-show-indent-multipart
 718       (indent-rigidly start (point) 1)))
 719   t)
 720
 721 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 722   (notmuch-show-insert-part-header nth declared-type content-type nil)
 723   (let* ((message (car (plist-get part :content)))
 724          (body (car (plist-get message :body)))
 725          (start (point)))
 726
 727     ;; Override `notmuch-message-headers' to force `From' to be
 728     ;; displayed.
 729     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 730       (notmuch-show-insert-headers (plist-get message :headers)))
 731
 732     ;; Blank line after headers to be compatible with the normal
 733     ;; message display.
 734     (insert "\n")
 735
 736     ;; Show the body
 737     (notmuch-show-insert-bodypart msg body depth)
 738
 739     (when notmuch-show-indent-multipart
 740       (indent-rigidly start (point) 1)))
 741   t)
 742
 743 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 744   (let ((start (point)))
 745     ;; If this text/plain part is not the first part in the message,
 746     ;; insert a header to make this clear.
 747     (if (> nth 1)
 748         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 749     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 750     (save-excursion
 751       (save-restriction
 752         (narrow-to-region start (point-max))
 753         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 754   t)
 755
 756 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 757   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 758   (insert (with-temp-buffer
 759             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 760             ;; notmuch-get-bodypart-content provides "raw", non-converted
 761             ;; data. Replace CRLF with LF before icalendar can use it.
 762             (goto-char (point-min))
 763             (while (re-search-forward "\r\n" nil t)
 764               (replace-match "\n" nil nil))
 765             (let ((file (make-temp-file "notmuch-ical"))
 766                   result)
 767               (unwind-protect
 768                   (progn
 769                     (unless (icalendar-import-buffer file t)
 770                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 771                     (set-buffer (get-file-buffer file))
 772                     (setq result (buffer-substring (point-min) (point-max)))
 773                     (set-buffer-modified-p nil)
 774                     (kill-buffer (current-buffer)))
 775                 (delete-file file))
 776               result)))
 777   t)
 778
 779 ;; For backwards compatibility.
 780 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 781   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 782
 783 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 784   ;; If we can deduce a MIME type from the filename of the attachment,
 785   ;; do so and pass it on to the handler for that type.
 786   (if (plist-get part :filename)
 787       (let ((extension (file-name-extension (plist-get part :filename)))
 788             mime-type)
 789         (if extension
 790             (progn
 791               (mailcap-parse-mimetypes)
 792               (setq mime-type (mailcap-extension-to-mime extension))
 793               (if (and mime-type
 794                        (not (string-equal mime-type "application/octet-stream")))
 795                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 796                 nil))
 797           nil))))
 798
 799 ;; Handler for wash generated inline patch fake parts.
 800 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 801   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 802
 803 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 804   ;; This handler _must_ succeed - it is the handler of last resort.
 805   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 806   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 807   t)
 808
 809 ;; Functions for determining how to handle MIME parts.
 810
 811 (defun notmuch-show-handlers-for (content-type)
 812   "Return a list of content handlers for a part of type CONTENT-TYPE."
 813   (let (result)
 814     (mapc (lambda (func)
 815             (if (functionp func)
 816                 (push func result)))
 817           ;; Reverse order of prefrence.
 818           (list (intern (concat "notmuch-show-insert-part-*/*"))
 819                 (intern (concat
 820                          "notmuch-show-insert-part-"
 821                          (car (notmuch-split-content-type content-type))
 822                          "/*"))
 823                 (intern (concat "notmuch-show-insert-part-" content-type))))
 824     result))
 825
 826 ;; \f
 827
 828 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 829   (let ((handlers (notmuch-show-handlers-for content-type)))
 830     ;; Run the content handlers until one of them returns a non-nil
 831     ;; value.
 832     (while (and handlers
 833                 (not (condition-case err
 834                          (funcall (car handlers) msg part content-type nth depth declared-type)
 835                        (error (progn
 836                                 (insert "!!! Bodypart insert error: ")
 837                                 (insert (error-message-string err))
 838                                 (insert " !!!\n") nil)))))
 839       (setq handlers (cdr handlers))))
 840   t)
 841
 842 (defun notmuch-show-insert-bodypart (msg part depth)
 843   "Insert the body part PART at depth DEPTH in the current thread."
 844   (let ((content-type (downcase (plist-get part :content-type)))
 845         (nth (plist-get part :id)))
 846     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 847   ;; Some of the body part handlers leave point somewhere up in the
 848   ;; part, so we make sure that we're down at the end.
 849   (goto-char (point-max))
 850   ;; Ensure that the part ends with a carriage return.
 851   (unless (bolp)
 852     (insert "\n")))
 853
 854 (defun notmuch-show-insert-body (msg body depth)
 855   "Insert the body BODY at depth DEPTH in the current thread."
 856   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 857
 858 (defun notmuch-show-make-symbol (type)
 859   (make-symbol (concat "notmuch-show-" type)))
 860
 861 (defun notmuch-show-strip-re (string)
 862   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 863
 864 (defvar notmuch-show-previous-subject "")
 865 (make-variable-buffer-local 'notmuch-show-previous-subject)
 866
 867 (defun notmuch-show-insert-msg (msg depth)
 868   "Insert the message MSG at depth DEPTH in the current thread."
 869   (let* ((headers (plist-get msg :headers))
 870          ;; Indentation causes the buffer offset of the start/end
 871          ;; points to move, so we must use markers.
 872          message-start message-end
 873          content-start content-end
 874          headers-start headers-end
 875          body-start body-end
 876          (headers-invis-spec (notmuch-show-make-symbol "header"))
 877          (message-invis-spec (notmuch-show-make-symbol "message"))
 878          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 879
 880     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 881     ;; removing items from `buffer-invisibility-spec' (which is what
 882     ;; `notmuch-show-headers-visible' and
 883     ;; `notmuch-show-message-visible' do) is a no-op and has no
 884     ;; effect. This caused threads with only matching messages to have
 885     ;; those messages hidden initially because
 886     ;; `buffer-invisibility-spec' stayed `t'.
 887     ;;
 888     ;; This needs to be set here (rather than just above the call to
 889     ;; `notmuch-show-headers-visible') because some of the part
 890     ;; rendering or body washing functions
 891     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 892     ;; `buffer-invisibility-spec').
 893     (when (eq buffer-invisibility-spec t)
 894       (setq buffer-invisibility-spec nil))
 895
 896     (setq message-start (point-marker))
 897
 898     (notmuch-show-insert-headerline headers
 899                                     (or (if notmuch-show-relative-dates
 900                                             (plist-get msg :date_relative)
 901                                           nil)
 902                                         (plist-get headers :Date))
 903                                     (plist-get msg :tags) depth)
 904
 905     (setq content-start (point-marker))
 906
 907     (plist-put msg :headers-invis-spec headers-invis-spec)
 908     (plist-put msg :message-invis-spec message-invis-spec)
 909
 910     ;; Set `headers-start' to point after the 'Subject:' header to be
 911     ;; compatible with the existing implementation. This just sets it
 912     ;; to after the first header.
 913     (notmuch-show-insert-headers headers)
 914     (save-excursion
 915       (goto-char content-start)
 916       ;; If the subject of this message is the same as that of the
 917       ;; previous message, don't display it when this message is
 918       ;; collapsed.
 919       (when (not (string= notmuch-show-previous-subject
 920                           bare-subject))
 921         (forward-line 1))
 922       (setq headers-start (point-marker)))
 923     (setq headers-end (point-marker))
 924
 925     (setq notmuch-show-previous-subject bare-subject)
 926
 927     (setq body-start (point-marker))
 928     ;; A blank line between the headers and the body.
 929     (insert "\n")
 930     (notmuch-show-insert-body msg (plist-get msg :body)
 931                               (if notmuch-show-indent-content depth 0))
 932     ;; Ensure that the body ends with a newline.
 933     (unless (bolp)
 934       (insert "\n"))
 935     (setq body-end (point-marker))
 936     (setq content-end (point-marker))
 937
 938     ;; Indent according to the depth in the thread.
 939     (if notmuch-show-indent-content
 940         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 941
 942     (setq message-end (point-max-marker))
 943
 944     ;; Save the extents of this message over the whole text of the
 945     ;; message.
 946     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 947
 948     (let ((headers-overlay (make-overlay headers-start headers-end))
 949           (invis-specs (list headers-invis-spec message-invis-spec)))
 950       (overlay-put headers-overlay 'invisible invis-specs)
 951       (overlay-put headers-overlay 'priority 10))
 952     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 953
 954     (plist-put msg :depth depth)
 955
 956     ;; Save the properties for this message. Currently this saves the
 957     ;; entire message (augmented it with other stuff), which seems
 958     ;; like overkill. We might save a reduced subset (for example, not
 959     ;; the content).
 960     (notmuch-show-set-message-properties msg)
 961
 962     ;; Set header visibility.
 963     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 964
 965     ;; Message visibility depends on whether it matched the search
 966     ;; criteria.
 967     (notmuch-show-message-visible msg (and (plist-get msg :match)
 968                                            (not (plist-get msg :excluded))))))
 969
 970 (defun notmuch-show-toggle-process-crypto ()
 971   "Toggle the processing of cryptographic MIME parts."
 972   (interactive)
 973   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 974   (message (if notmuch-show-process-crypto
 975                "Processing cryptographic MIME parts."
 976              "Not processing cryptographic MIME parts."))
 977   (notmuch-show-refresh-view))
 978
 979 (defun notmuch-show-toggle-elide-non-matching ()
 980   "Toggle the display of non-matching messages."
 981   (interactive)
 982   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 983   (message (if notmuch-show-elide-non-matching-messages
 984                "Showing matching messages only."
 985              "Showing all messages."))
 986   (notmuch-show-refresh-view))
 987
 988 (defun notmuch-show-toggle-thread-indentation ()
 989   "Toggle the indentation of threads."
 990   (interactive)
 991   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 992   (message (if notmuch-show-indent-content
 993                "Content is indented."
 994              "Content is not indented."))
 995   (notmuch-show-refresh-view))
 996
 997 (defun notmuch-show-insert-tree (tree depth)
 998   "Insert the message tree TREE at depth DEPTH in the current thread."
 999   (let ((msg (car tree))
1000         (replies (cadr tree)))
1001     ;; We test whether there is a message or just some replies.
1002     (when msg
1003       (notmuch-show-insert-msg msg depth))
1004     (notmuch-show-insert-thread replies (1+ depth))))
1005
1006 (defun notmuch-show-insert-thread (thread depth)
1007   "Insert the thread THREAD at depth DEPTH in the current forest."
1008   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1009
1010 (defun notmuch-show-insert-forest (forest)
1011   "Insert the forest of threads FOREST."
1012   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1013
1014 (defvar notmuch-id-regexp
1015   (concat
1016    ;; Match the id: prefix only if it begins a word (to disallow, for
1017    ;; example, matching cid:).
1018    "\\<id:\\("
1019    ;; If the term starts with a ", then parse Xapian's quoted boolean
1020    ;; term syntax, which allows for anything as long as embedded
1021    ;; double quotes escaped by doubling them.  We also disallow
1022    ;; newlines (which Xapian allows) to prevent runaway terms.
1023    "\"\\([^\"\n]\\|\"\"\\)*\""
1024    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1025    ;; next space or ).  We disallow [.,;] as the last character
1026    ;; because these are probably part of the surrounding text, and not
1027    ;; part of the id.  This doesn't match single character ids; meh.
1028    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1029    "\\)")
1030   "The regexp used to match id: links in messages.")
1031
1032 (defvar notmuch-mid-regexp
1033   ;; goto-address-url-regexp matched cid: links, which have the same
1034   ;; grammar as the message ID part of a mid: link.  Construct the
1035   ;; regexp using the same technique as goto-address-url-regexp.
1036   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1037   "The regexp used to match mid: links in messages.
1038
1039 See RFC 2392.")
1040
1041 (defun notmuch-show-buttonise-links (start end)
1042   "Buttonise URLs and mail addresses between START and END.
1043
1044 This also turns id:\"<message id>\"-parts and mid: links into
1045 buttons for a corresponding notmuch search."
1046   (goto-address-fontify-region start end)
1047   (save-excursion
1048     (let (links)
1049       (goto-char start)
1050       (while (re-search-forward notmuch-id-regexp end t)
1051         (push (list (match-beginning 0) (match-end 0)
1052                     (match-string-no-properties 0)) links))
1053       (goto-char start)
1054       (while (re-search-forward notmuch-mid-regexp end t)
1055         (let* ((mid-cid (match-string-no-properties 1))
1056                (mid (save-match-data
1057                       (string-match "^[^/]*" mid-cid)
1058                       (url-unhex-string (match-string 0 mid-cid)))))
1059           (push (list (match-beginning 0) (match-end 0)
1060                       (notmuch-id-to-query mid)) links)))
1061       (dolist (link links)
1062         ;; Remove the overlay created by goto-address-mode
1063         (remove-overlays (first link) (second link) 'goto-address t)
1064         (make-text-button (first link) (second link)
1065                           'action `(lambda (arg)
1066                                      (notmuch-show ,(third link)))
1067                           'follow-link t
1068                           'help-echo "Mouse-1, RET: search for this message"
1069                           'face goto-address-mail-face)))))
1070
1071 ;;;###autoload
1072 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1073   "Run \"notmuch show\" with the given thread ID and display results.
1074
1075 The optional PARENT-BUFFER is the notmuch-search buffer from
1076 which this notmuch-show command was executed, (so that the
1077 next thread from that buffer can be show when done with this
1078 one).
1079
1080 The optional QUERY-CONTEXT is a notmuch search term. Only
1081 messages from the thread matching this search term are shown if
1082 non-nil.
1083
1084 The optional BUFFER-NAME provides the name of the buffer in
1085 which the message thread is shown. If it is nil (which occurs
1086 when the command is called interactively) the argument to the
1087 function is used."
1088   (interactive "sNotmuch show: ")
1089   (let ((buffer-name (generate-new-buffer-name
1090                       (or buffer-name
1091                           (concat "*notmuch-" thread-id "*")))))
1092     (switch-to-buffer (get-buffer-create buffer-name))
1093     ;; Set the default value for `notmuch-show-process-crypto' in this
1094     ;; buffer.
1095     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1096     ;; Set the default value for
1097     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1098     ;; there is a prefix argument, invert the default.
1099     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1100     (if current-prefix-arg
1101         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1102
1103     (setq notmuch-show-thread-id thread-id
1104           notmuch-show-parent-buffer parent-buffer
1105           notmuch-show-query-context query-context)
1106     (notmuch-show-build-buffer)
1107     (notmuch-show-goto-first-wanted-message)
1108     (current-buffer)))
1109
1110 (defun notmuch-show-build-buffer ()
1111   (let ((inhibit-read-only t))
1112
1113     (notmuch-show-mode)
1114     ;; Don't track undo information for this buffer
1115     (set 'buffer-undo-list t)
1116
1117     (erase-buffer)
1118     (goto-char (point-min))
1119     (save-excursion
1120       (let* ((basic-args (list notmuch-show-thread-id))
1121              (args (if notmuch-show-query-context
1122                        (append (list "\'") basic-args
1123                                (list "and (" notmuch-show-query-context ")\'"))
1124                      (append (list "\'") basic-args (list "\'"))))
1125              (cli-args (cons "--exclude=false"
1126                              (when notmuch-show-elide-non-matching-messages
1127                                (list "--entire-thread=false")))))
1128
1129         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1130         ;; If the query context reduced the results to nothing, run
1131         ;; the basic query.
1132         (when (and (eq (buffer-size) 0)
1133                    notmuch-show-query-context)
1134           (notmuch-show-insert-forest
1135            (notmuch-query-get-threads (append cli-args basic-args)))))
1136
1137       (jit-lock-register #'notmuch-show-buttonise-links)
1138
1139       ;; Set the header line to the subject of the first message.
1140       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1141
1142       (run-hooks 'notmuch-show-hook))))
1143
1144 (defun notmuch-show-capture-state ()
1145   "Capture the state of the current buffer.
1146
1147 This includes:
1148  - the list of open messages,
1149  - the current message."
1150   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1151
1152 (defun notmuch-show-apply-state (state)
1153   "Apply STATE to the current buffer.
1154
1155 This includes:
1156  - opening the messages previously opened,
1157  - closing all other messages,
1158  - moving to the correct current message."
1159   (let ((current (car state))
1160         (open (cadr state)))
1161
1162     ;; Open those that were open.
1163     (goto-char (point-min))
1164     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1165                                            (member (notmuch-show-get-message-id) open))
1166           until (not (notmuch-show-goto-message-next)))
1167
1168     ;; Go to the previously open message.
1169     (goto-char (point-min))
1170     (unless (loop if (string= current (notmuch-show-get-message-id))
1171                   return t
1172                   until (not (notmuch-show-goto-message-next)))
1173       (goto-char (point-min))
1174       (message "Previously current message not found."))
1175     (notmuch-show-message-adjust)))
1176
1177 (defun notmuch-show-refresh-view (&optional reset-state)
1178   "Refresh the current view.
1179
1180 Refreshes the current view, observing changes in display
1181 preferences. If invoked with a prefix argument (or RESET-STATE is
1182 non-nil) then the state of the buffer (open/closed messages) is
1183 reset based on the original query."
1184   (interactive "P")
1185   (let ((inhibit-read-only t)
1186         (state (unless reset-state
1187                  (notmuch-show-capture-state))))
1188     ;; erase-buffer does not seem to remove overlays, which can lead
1189     ;; to weird effects such as remaining images, so remove them
1190     ;; manually.
1191     (remove-overlays)
1192     (erase-buffer)
1193     (notmuch-show-build-buffer)
1194     (if state
1195         (notmuch-show-apply-state state)
1196       ;; We're resetting state, so navigate to the first open message
1197       ;; and mark it read, just like opening a new show buffer.
1198       (notmuch-show-goto-first-wanted-message))))
1199
1200 (defvar notmuch-show-stash-map
1201   (let ((map (make-sparse-keymap)))
1202     (define-key map "c" 'notmuch-show-stash-cc)
1203     (define-key map "d" 'notmuch-show-stash-date)
1204     (define-key map "F" 'notmuch-show-stash-filename)
1205     (define-key map "f" 'notmuch-show-stash-from)
1206     (define-key map "i" 'notmuch-show-stash-message-id)
1207     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1208     (define-key map "s" 'notmuch-show-stash-subject)
1209     (define-key map "T" 'notmuch-show-stash-tags)
1210     (define-key map "t" 'notmuch-show-stash-to)
1211     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1212     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1213     map)
1214   "Submap for stash commands")
1215 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1216
1217 (defvar notmuch-show-mode-map
1218       (let ((map (make-sparse-keymap)))
1219         (define-key map "?" 'notmuch-help)
1220         (define-key map "q" 'notmuch-kill-this-buffer)
1221         (define-key map (kbd "<C-tab>") 'widget-backward)
1222         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1223         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1224         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1225         (define-key map "s" 'notmuch-search)
1226         (define-key map "m" 'notmuch-mua-new-mail)
1227         (define-key map "f" 'notmuch-show-forward-message)
1228         (define-key map "r" 'notmuch-show-reply-sender)
1229         (define-key map "R" 'notmuch-show-reply)
1230         (define-key map "|" 'notmuch-show-pipe-message)
1231         (define-key map "w" 'notmuch-show-save-attachments)
1232         (define-key map "V" 'notmuch-show-view-raw-message)
1233         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1234         (define-key map "c" 'notmuch-show-stash-map)
1235         (define-key map "=" 'notmuch-show-refresh-view)
1236         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1237         (define-key map "*" 'notmuch-show-tag-all)
1238         (define-key map "-" 'notmuch-show-remove-tag)
1239         (define-key map "+" 'notmuch-show-add-tag)
1240         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1241         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1242         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1243         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1244         (define-key map "N" 'notmuch-show-next-message)
1245         (define-key map "P" 'notmuch-show-previous-message)
1246         (define-key map "n" 'notmuch-show-next-open-message)
1247         (define-key map "p" 'notmuch-show-previous-open-message)
1248         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1249         (define-key map " " 'notmuch-show-advance-and-archive)
1250         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1251         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1252         (define-key map "#" 'notmuch-show-print-message)
1253         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1254         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1255         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1256         (define-key map "t" 'toggle-truncate-lines)
1257         map)
1258       "Keymap for \"notmuch show\" buffers.")
1259 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1260
1261 (defun notmuch-show-mode ()
1262   "Major mode for viewing a thread with notmuch.
1263
1264 This buffer contains the results of the \"notmuch show\" command
1265 for displaying a single thread of email from your email archives.
1266
1267 By default, various components of email messages, (citations,
1268 signatures, already-read messages), are hidden. You can make
1269 these parts visible by clicking with the mouse button or by
1270 pressing RET after positioning the cursor on a hidden part, (for
1271 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1272
1273 Reading the thread sequentially is well-supported by pressing
1274 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1275 to the next message, or advance to the next thread (if already on
1276 the last message of a thread).
1277
1278 Other commands are available to read or manipulate the thread
1279 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1280 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1281 without scrolling through with \\[notmuch-show-advance-and-archive]).
1282
1283 You can add or remove arbitrary tags from the current message with
1284 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1285
1286 All currently available key bindings:
1287
1288 \\{notmuch-show-mode-map}"
1289   (interactive)
1290   (kill-all-local-variables)
1291   (use-local-map notmuch-show-mode-map)
1292   (setq major-mode 'notmuch-show-mode
1293         mode-name "notmuch-show")
1294   (setq buffer-read-only t
1295         truncate-lines t))
1296
1297 (defun notmuch-show-move-to-message-top ()
1298   (goto-char (notmuch-show-message-top)))
1299
1300 (defun notmuch-show-move-to-message-bottom ()
1301   (goto-char (notmuch-show-message-bottom)))
1302
1303 (defun notmuch-show-message-adjust ()
1304   (recenter 0))
1305
1306 ;; Movement related functions.
1307
1308 ;; There's some strangeness here where a text property applied to a
1309 ;; region a->b is not found when point is at b. We walk backwards
1310 ;; until finding the property.
1311 (defun notmuch-show-message-extent ()
1312   (let (r)
1313     (save-excursion
1314       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1315         (backward-char)))
1316     r))
1317
1318 (defun notmuch-show-message-top ()
1319   (car (notmuch-show-message-extent)))
1320
1321 (defun notmuch-show-message-bottom ()
1322   (cdr (notmuch-show-message-extent)))
1323
1324 (defun notmuch-show-goto-message-next ()
1325   (let ((start (point)))
1326     (notmuch-show-move-to-message-bottom)
1327     (if (not (eobp))
1328         t
1329       (goto-char start)
1330       nil)))
1331
1332 (defun notmuch-show-goto-message-previous ()
1333   (notmuch-show-move-to-message-top)
1334   (if (bobp)
1335       nil
1336     (backward-char)
1337     (notmuch-show-move-to-message-top)
1338     t))
1339
1340 (defun notmuch-show-mapc (function)
1341   "Iterate through all messages in the current thread with
1342 `notmuch-show-goto-message-next' and call FUNCTION for side
1343 effects."
1344   (save-excursion
1345     (goto-char (point-min))
1346     (loop do (funcall function)
1347           while (notmuch-show-goto-message-next))))
1348
1349 ;; Functions relating to the visibility of messages and their
1350 ;; components.
1351
1352 (defun notmuch-show-element-visible (props visible-p spec-property)
1353   (let ((spec (plist-get props spec-property)))
1354     (if visible-p
1355         (remove-from-invisibility-spec spec)
1356       (add-to-invisibility-spec spec))))
1357
1358 (defun notmuch-show-message-visible (props visible-p)
1359   (notmuch-show-element-visible props visible-p :message-invis-spec)
1360   (notmuch-show-set-prop :message-visible visible-p props))
1361
1362 (defun notmuch-show-headers-visible (props visible-p)
1363   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1364   (notmuch-show-set-prop :headers-visible visible-p props))
1365
1366 ;; Functions for setting and getting attributes of the current
1367 ;; message.
1368
1369 (defun notmuch-show-set-message-properties (props)
1370   (save-excursion
1371     (notmuch-show-move-to-message-top)
1372     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1373
1374 (defun notmuch-show-get-message-properties ()
1375   "Return the properties of the current message as a plist.
1376
1377 Some useful entries are:
1378 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1379 :body - Body of the message
1380 :tags - Tags for this message"
1381   (save-excursion
1382     (notmuch-show-move-to-message-top)
1383     (get-text-property (point) :notmuch-message-properties)))
1384
1385 (defun notmuch-show-set-prop (prop val &optional props)
1386   (let ((inhibit-read-only t)
1387         (props (or props
1388                    (notmuch-show-get-message-properties))))
1389     (plist-put props prop val)
1390     (notmuch-show-set-message-properties props)))
1391
1392 (defun notmuch-show-get-prop (prop &optional props)
1393   (let ((props (or props
1394                    (notmuch-show-get-message-properties))))
1395     (plist-get props prop)))
1396
1397 (defun notmuch-show-get-message-id (&optional bare)
1398   "Return an id: query for the Message-Id of the current message.
1399
1400 If optional argument BARE is non-nil, return
1401 the Message-Id without id: prefix and escaping."
1402   (if bare
1403       (notmuch-show-get-prop :id)
1404     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1405
1406 (defun notmuch-show-get-messages-ids ()
1407   "Return all id: queries of messages in the current thread."
1408   (let ((message-ids))
1409     (notmuch-show-mapc
1410      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1411     message-ids))
1412
1413 (defun notmuch-show-get-messages-ids-search ()
1414   "Return a search string for all message ids of messages in the
1415 current thread."
1416   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1417
1418 ;; dme: Would it make sense to use a macro for many of these?
1419
1420 (defun notmuch-show-get-filename ()
1421   "Return the filename of the current message."
1422   (notmuch-show-get-prop :filename))
1423
1424 (defun notmuch-show-get-header (header &optional props)
1425   "Return the named header of the current message, if any."
1426   (plist-get (notmuch-show-get-prop :headers props) header))
1427
1428 (defun notmuch-show-get-cc ()
1429   (notmuch-show-get-header :Cc))
1430
1431 (defun notmuch-show-get-date ()
1432   (notmuch-show-get-header :Date))
1433
1434 (defun notmuch-show-get-from ()
1435   (notmuch-show-get-header :From))
1436
1437 (defun notmuch-show-get-subject ()
1438   (notmuch-show-get-header :Subject))
1439
1440 (defun notmuch-show-get-to ()
1441   (notmuch-show-get-header :To))
1442
1443 (defun notmuch-show-get-depth ()
1444   (notmuch-show-get-prop :depth))
1445
1446 (defun notmuch-show-set-tags (tags)
1447   "Set the tags of the current message."
1448   (notmuch-show-set-prop :tags tags)
1449   (notmuch-show-update-tags tags))
1450
1451 (defun notmuch-show-get-tags ()
1452   "Return the tags of the current message."
1453   (notmuch-show-get-prop :tags))
1454
1455 (defun notmuch-show-message-visible-p ()
1456   "Is the current message visible?"
1457   (notmuch-show-get-prop :message-visible))
1458
1459 (defun notmuch-show-headers-visible-p ()
1460   "Are the headers of the current message visible?"
1461   (notmuch-show-get-prop :headers-visible))
1462
1463 (defun notmuch-show-mark-read (&optional unread)
1464   "Mark the current message as read.
1465
1466 Mark the current message as read by applying the tag changes in
1467 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1468 default). If a prefix argument is given, the message will be
1469 marked as unread, i.e. the tag changes in
1470 `notmuch-show-mark-read-tags' will be reversed."
1471   (interactive "P")
1472   (when notmuch-show-mark-read-tags
1473     (apply 'notmuch-show-tag-message
1474            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1475
1476 ;; Functions for getting attributes of several messages in the current
1477 ;; thread.
1478
1479 (defun notmuch-show-get-message-ids-for-open-messages ()
1480   "Return a list of all id: queries for open messages in the current thread."
1481   (save-excursion
1482     (let (message-ids done)
1483       (goto-char (point-min))
1484       (while (not done)
1485         (if (notmuch-show-message-visible-p)
1486             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1487         (setq done (not (notmuch-show-goto-message-next)))
1488         )
1489       message-ids
1490       )))
1491
1492 ;; Commands typically bound to keys.
1493
1494 (defun notmuch-show-advance ()
1495   "Advance through thread.
1496
1497 If the current message in the thread is not yet fully visible,
1498 scroll by a near screenful to read more of the message.
1499
1500 Otherwise, (the end of the current message is already within the
1501 current window), advance to the next open message."
1502   (interactive)
1503   (let* ((end-of-this-message (notmuch-show-message-bottom))
1504          (visible-end-of-this-message (1- end-of-this-message))
1505          (ret nil))
1506     (while (invisible-p visible-end-of-this-message)
1507       (setq visible-end-of-this-message
1508             (max (point-min)
1509                  (1- (previous-single-char-property-change
1510                       visible-end-of-this-message 'invisible)))))
1511     (cond
1512      ;; Ideally we would test `end-of-this-message' against the result
1513      ;; of `window-end', but that doesn't account for the fact that
1514      ;; the end of the message might be hidden.
1515      ((and visible-end-of-this-message
1516            (> visible-end-of-this-message (window-end)))
1517       ;; The bottom of this message is not visible - scroll.
1518       (scroll-up nil))
1519
1520      ((not (= end-of-this-message (point-max)))
1521       ;; This is not the last message - move to the next visible one.
1522       (notmuch-show-next-open-message))
1523
1524      ((not (= (point) (point-max)))
1525       ;; This is the last message, but the cursor is not at the end of
1526       ;; the buffer. Move it there.
1527       (goto-char (point-max)))
1528
1529      (t
1530       ;; This is the last message - change the return value
1531       (setq ret t)))
1532     ret))
1533
1534 (defun notmuch-show-advance-and-archive ()
1535   "Advance through thread and archive.
1536
1537 This command is intended to be one of the simplest ways to
1538 process a thread of email. It works exactly like
1539 notmuch-show-advance, in that it scrolls through messages in a
1540 show buffer, except that when it gets to the end of the buffer it
1541 archives the entire current thread, (remove the \"inbox\" tag
1542 from each message), kills the buffer, and displays the next
1543 thread from the search from which this thread was originally
1544 shown."
1545   (interactive)
1546   (if (notmuch-show-advance)
1547       (notmuch-show-archive-thread-then-next)))
1548
1549 (defun notmuch-show-rewind ()
1550   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1551
1552 Specifically, if the beginning of the previous email is fewer
1553 than `window-height' lines from the current point, move to it
1554 just like `notmuch-show-previous-message'.
1555
1556 Otherwise, just scroll down a screenful of the current message.
1557
1558 This command does not modify any message tags, (it does not undo
1559 any effects from previous calls to
1560 `notmuch-show-advance-and-archive'."
1561   (interactive)
1562   (let ((start-of-message (notmuch-show-message-top))
1563         (start-of-window (window-start)))
1564     (cond
1565       ;; Either this message is properly aligned with the start of the
1566       ;; window or the start of this message is not visible on the
1567       ;; screen - scroll.
1568      ((or (= start-of-message start-of-window)
1569           (< start-of-message start-of-window))
1570       (scroll-down)
1571       ;; If a small number of lines from the previous message are
1572       ;; visible, realign so that the top of the current message is at
1573       ;; the top of the screen.
1574       (when (<= (count-screen-lines (window-start) start-of-message)
1575                 next-screen-context-lines)
1576         (goto-char (notmuch-show-message-top))
1577         (notmuch-show-message-adjust))
1578       ;; Move to the top left of the window.
1579       (goto-char (window-start)))
1580      (t
1581       ;; Move to the previous message.
1582       (notmuch-show-previous-message)))))
1583
1584 (defun notmuch-show-reply (&optional prompt-for-sender)
1585   "Reply to the sender and all recipients of the current message."
1586   (interactive "P")
1587   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1588
1589 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1590   "Reply to the sender of the current message."
1591   (interactive "P")
1592   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1593
1594 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1595   "Forward the current message."
1596   (interactive "P")
1597   (with-current-notmuch-show-message
1598    (notmuch-mua-new-forward-message prompt-for-sender)))
1599
1600 (defun notmuch-show-next-message (&optional pop-at-end)
1601   "Show the next message.
1602
1603 If a prefix argument is given and this is the last message in the
1604 thread, navigate to the next thread in the parent search buffer."
1605   (interactive "P")
1606   (if (notmuch-show-goto-message-next)
1607       (progn
1608         (notmuch-show-mark-read)
1609         (notmuch-show-message-adjust))
1610     (if pop-at-end
1611         (notmuch-show-next-thread)
1612       (goto-char (point-max)))))
1613
1614 (defun notmuch-show-previous-message ()
1615   "Show the previous message or the start of the current message."
1616   (interactive)
1617   (if (= (point) (notmuch-show-message-top))
1618       (notmuch-show-goto-message-previous)
1619     (notmuch-show-move-to-message-top))
1620   (notmuch-show-mark-read)
1621   (notmuch-show-message-adjust))
1622
1623 (defun notmuch-show-next-open-message (&optional pop-at-end)
1624   "Show the next open message.
1625
1626 If a prefix argument is given and this is the last open message
1627 in the thread, navigate to the next thread in the parent search
1628 buffer. Return t if there was a next open message in the thread
1629 to show, nil otherwise."
1630   (interactive "P")
1631   (let (r)
1632     (while (and (setq r (notmuch-show-goto-message-next))
1633                 (not (notmuch-show-message-visible-p))))
1634     (if r
1635         (progn
1636           (notmuch-show-mark-read)
1637           (notmuch-show-message-adjust))
1638       (if pop-at-end
1639           (notmuch-show-next-thread)
1640         (goto-char (point-max))))
1641     r))
1642
1643 (defun notmuch-show-next-matching-message ()
1644   "Show the next matching message."
1645   (interactive)
1646   (let (r)
1647     (while (and (setq r (notmuch-show-goto-message-next))
1648                 (not (notmuch-show-get-prop :match))))
1649     (if r
1650         (progn
1651           (notmuch-show-mark-read)
1652           (notmuch-show-message-adjust))
1653       (goto-char (point-max)))))
1654
1655 (defun notmuch-show-open-if-matched ()
1656   "Open a message if it is matched (whether or not excluded)."
1657   (let ((props (notmuch-show-get-message-properties)))
1658     (notmuch-show-message-visible props (plist-get props :match))))
1659
1660 (defun notmuch-show-goto-first-wanted-message ()
1661   "Move to the first open message and mark it read"
1662   (goto-char (point-min))
1663   (if (notmuch-show-message-visible-p)
1664       (notmuch-show-mark-read)
1665     (notmuch-show-next-open-message))
1666   (when (eobp)
1667     ;; There are no matched non-excluded messages so open all matched
1668     ;; (necessarily excluded) messages and go to the first.
1669     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1670     (force-window-update)
1671     (goto-char (point-min))
1672     (if (notmuch-show-message-visible-p)
1673         (notmuch-show-mark-read)
1674       (notmuch-show-next-open-message))))
1675
1676 (defun notmuch-show-previous-open-message ()
1677   "Show the previous open message."
1678   (interactive)
1679   (while (and (if (= (point) (notmuch-show-message-top))
1680                   (notmuch-show-goto-message-previous)
1681                 (notmuch-show-move-to-message-top))
1682               (not (notmuch-show-message-visible-p))))
1683   (notmuch-show-mark-read)
1684   (notmuch-show-message-adjust))
1685
1686 (defun notmuch-show-view-raw-message ()
1687   "View the file holding the current message."
1688   (interactive)
1689   (let* ((id (notmuch-show-get-message-id))
1690          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1691     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1692     (switch-to-buffer buf)
1693     (goto-char (point-min))
1694     (set-buffer-modified-p nil)
1695     (view-buffer buf 'kill-buffer-if-not-modified)))
1696
1697 (defun notmuch-show-pipe-message (entire-thread command)
1698   "Pipe the contents of the current message (or thread) to the given command.
1699
1700 The given command will be executed with the raw contents of the
1701 current email message as stdin. Anything printed by the command
1702 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1703
1704 When invoked with a prefix argument, the command will receive all
1705 open messages in the current thread (formatted as an mbox) rather
1706 than only the current message."
1707   (interactive "P\nsPipe message to command: ")
1708   (let (shell-command)
1709     (if entire-thread
1710         (setq shell-command
1711               (concat notmuch-command " show --format=mbox --exclude=false "
1712                       (shell-quote-argument
1713                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1714                       " | " command))
1715       (setq shell-command
1716             (concat notmuch-command " show --format=raw "
1717                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1718     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1719       (with-current-buffer buf
1720         (setq buffer-read-only nil)
1721         (erase-buffer)
1722         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1723           (goto-char (point-max))
1724           (set-buffer-modified-p nil)
1725           (setq buffer-read-only t)
1726           (unless (zerop exit-code)
1727             (switch-to-buffer-other-window buf)
1728             (message (format "Command '%s' exited abnormally with code %d"
1729                              shell-command exit-code))))))))
1730
1731 (defun notmuch-show-tag-message (&rest tag-changes)
1732   "Change tags for the current message.
1733
1734 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1735   (let* ((current-tags (notmuch-show-get-tags))
1736          (new-tags (notmuch-update-tags current-tags tag-changes)))
1737     (unless (equal current-tags new-tags)
1738       (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1739       (notmuch-show-set-tags new-tags))))
1740
1741 (defun notmuch-show-tag (&optional tag-changes)
1742   "Change tags for the current message.
1743
1744 See `notmuch-tag' for information on the format of TAG-CHANGES."
1745   (interactive)
1746   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes))
1747   (let* ((current-tags (notmuch-show-get-tags))
1748          (new-tags (notmuch-update-tags current-tags tag-changes)))
1749     (unless (equal current-tags new-tags)
1750       (notmuch-show-set-tags new-tags))))
1751
1752 (defun notmuch-show-tag-all (&optional tag-changes)
1753   "Change tags for all messages in the current show buffer.
1754
1755 See `notmuch-tag' for information on the format of TAG-CHANGES."
1756   (interactive)
1757   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1758   (notmuch-show-mapc
1759    (lambda ()
1760      (let* ((current-tags (notmuch-show-get-tags))
1761             (new-tags (notmuch-update-tags current-tags tag-changes)))
1762        (unless (equal current-tags new-tags)
1763          (notmuch-show-set-tags new-tags))))))
1764
1765 (defun notmuch-show-add-tag ()
1766   "Same as `notmuch-show-tag' but sets initial input to '+'."
1767   (interactive)
1768   (notmuch-show-tag "+"))
1769
1770 (defun notmuch-show-remove-tag ()
1771   "Same as `notmuch-show-tag' but sets initial input to '-'."
1772   (interactive)
1773   (notmuch-show-tag "-"))
1774
1775 (defun notmuch-show-toggle-visibility-headers ()
1776   "Toggle the visibility of the current message headers."
1777   (interactive)
1778   (let ((props (notmuch-show-get-message-properties)))
1779     (notmuch-show-headers-visible
1780      props
1781      (not (plist-get props :headers-visible))))
1782   (force-window-update))
1783
1784 (defun notmuch-show-toggle-message ()
1785   "Toggle the visibility of the current message."
1786   (interactive)
1787   (let ((props (notmuch-show-get-message-properties)))
1788     (notmuch-show-message-visible
1789      props
1790      (not (plist-get props :message-visible))))
1791   (force-window-update))
1792
1793 (defun notmuch-show-open-or-close-all ()
1794   "Set the visibility all of the messages in the current thread.
1795 By default make all of the messages visible. With a prefix
1796 argument, hide all of the messages."
1797   (interactive)
1798   (save-excursion
1799     (goto-char (point-min))
1800     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1801                                            (not current-prefix-arg))
1802           until (not (notmuch-show-goto-message-next))))
1803   (force-window-update))
1804
1805 (defun notmuch-show-next-button ()
1806   "Advance point to the next button in the buffer."
1807   (interactive)
1808   (forward-button 1))
1809
1810 (defun notmuch-show-previous-button ()
1811   "Move point back to the previous button in the buffer."
1812   (interactive)
1813   (backward-button 1))
1814
1815 (defun notmuch-show-next-thread (&optional show-next)
1816   "Move to the next item in the search results, if any."
1817   (interactive "P")
1818   (let ((parent-buffer notmuch-show-parent-buffer))
1819     (notmuch-kill-this-buffer)
1820     (when (buffer-live-p parent-buffer)
1821       (switch-to-buffer parent-buffer)
1822       (notmuch-search-next-thread)
1823       (if show-next
1824           (notmuch-search-show-thread)))))
1825
1826 (defun notmuch-show-archive-thread (&optional unarchive)
1827   "Archive each message in thread.
1828
1829 Archive each message currently shown by applying the tag changes
1830 in `notmuch-archive-tags' to each (remove the \"inbox\" tag by
1831 default). If a prefix argument is given, the messages will be
1832 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1833 will be reversed.
1834
1835 Note: This command is safe from any race condition of new messages
1836 being delivered to the same thread. It does not archive the
1837 entire thread, but only the messages shown in the current
1838 buffer."
1839   (interactive "P")
1840   (when notmuch-archive-tags
1841     (notmuch-show-tag-all
1842      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1843
1844 (defun notmuch-show-archive-thread-then-next ()
1845   "Archive all messages in the current buffer, then show next thread from search."
1846   (interactive)
1847   (notmuch-show-archive-thread)
1848   (notmuch-show-next-thread t))
1849
1850 (defun notmuch-show-archive-thread-then-exit ()
1851   "Archive all messages in the current buffer, then exit back to search results."
1852   (interactive)
1853   (notmuch-show-archive-thread)
1854   (notmuch-show-next-thread))
1855
1856 (defun notmuch-show-archive-message (&optional unarchive)
1857   "Archive the current message.
1858
1859 Archive the current message by applying the tag changes in
1860 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
1861 default). If a prefix argument is given, the message will be
1862 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1863 will be reversed."
1864   (interactive "P")
1865   (when notmuch-archive-tags
1866     (apply 'notmuch-show-tag-message
1867            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1868
1869 (defun notmuch-show-archive-message-then-next-or-exit ()
1870   "Archive the current message, then show the next open message in the current thread.
1871
1872 If at the last open message in the current thread, then exit back
1873 to search results."
1874   (interactive)
1875   (notmuch-show-archive-message)
1876   (notmuch-show-next-open-message t))
1877
1878 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1879   "Archive the current message, then show the next open message in the current thread.
1880
1881 If at the last open message in the current thread, then show next
1882 thread from search."
1883   (interactive)
1884   (notmuch-show-archive-message)
1885   (unless (notmuch-show-next-open-message)
1886     (notmuch-show-next-thread t)))
1887
1888 (defun notmuch-show-stash-cc ()
1889   "Copy CC field of current message to kill-ring."
1890   (interactive)
1891   (notmuch-common-do-stash (notmuch-show-get-cc)))
1892
1893 (defun notmuch-show-stash-date ()
1894   "Copy date of current message to kill-ring."
1895   (interactive)
1896   (notmuch-common-do-stash (notmuch-show-get-date)))
1897
1898 (defun notmuch-show-stash-filename ()
1899   "Copy filename of current message to kill-ring."
1900   (interactive)
1901   (notmuch-common-do-stash (notmuch-show-get-filename)))
1902
1903 (defun notmuch-show-stash-from ()
1904   "Copy From address of current message to kill-ring."
1905   (interactive)
1906   (notmuch-common-do-stash (notmuch-show-get-from)))
1907
1908 (defun notmuch-show-stash-message-id ()
1909   "Copy id: query matching the current message to kill-ring."
1910   (interactive)
1911   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1912
1913 (defun notmuch-show-stash-message-id-stripped ()
1914   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1915   (interactive)
1916   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1917
1918 (defun notmuch-show-stash-subject ()
1919   "Copy Subject field of current message to kill-ring."
1920   (interactive)
1921   (notmuch-common-do-stash (notmuch-show-get-subject)))
1922
1923 (defun notmuch-show-stash-tags ()
1924   "Copy tags of current message to kill-ring as a comma separated list."
1925   (interactive)
1926   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1927
1928 (defun notmuch-show-stash-to ()
1929   "Copy To address of current message to kill-ring."
1930   (interactive)
1931   (notmuch-common-do-stash (notmuch-show-get-to)))
1932
1933 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1934   "Copy an ML Archive URI for the current message to the kill-ring.
1935
1936 This presumes that the message is available at the selected Mailing List Archive.
1937
1938 If optional argument MLA is non-nil, use the provided key instead of prompting
1939 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1940   (interactive)
1941   (notmuch-common-do-stash
1942    (concat (cdr (assoc
1943                  (or mla
1944                      (let ((completion-ignore-case t))
1945                        (completing-read
1946                         "Mailing List Archive: "
1947                         notmuch-show-stash-mlarchive-link-alist
1948                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1949                  notmuch-show-stash-mlarchive-link-alist))
1950            (notmuch-show-get-message-id t))))
1951
1952 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1953   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1954
1955 This presumes that the message is available at the selected Mailing List Archive.
1956
1957 If optional argument MLA is non-nil, use the provided key instead of prompting
1958 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1959   (interactive)
1960   (notmuch-show-stash-mlarchive-link mla)
1961   (browse-url (current-kill 0 t)))
1962
1963 ;; Commands typically bound to buttons.
1964
1965 (defun notmuch-show-part-button-default (&optional button)
1966   (interactive)
1967   (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))
1968
1969 (defun notmuch-show-part-button-save (&optional button)
1970   (interactive)
1971   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1972
1973 (defun notmuch-show-part-button-view (&optional button)
1974   (interactive)
1975   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1976
1977 (defun notmuch-show-part-button-interactively-view (&optional button)
1978   (interactive)
1979   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1980
1981 (defun notmuch-show-part-button-pipe (&optional button)
1982   (interactive)
1983   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
1984
1985 (defun notmuch-show-part-button-internal (button handler)
1986   (let ((button (or button (button-at (point)))))
1987     (if button
1988         (let ((nth (button-get button :notmuch-part)))
1989           (if nth
1990               (funcall handler (notmuch-show-get-message-id) nth
1991                        (button-get button :notmuch-filename)
1992                        (button-get button :notmuch-content-type)))))))
1993
1994 ;;
1995
1996 (provide 'notmuch-show)