git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-search-next-thread "notmuch" nil)
  42 (declare-function notmuch-search-previous-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts nil
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ("LKML" . "http://lkml.kernel.org/r/")
 162     ;; FIXME: can these services be searched by `Message-Id' ?
 163     ;; ("MarkMail" . "http://markmail.org/")
 164     ;; ("Nabble" . "http://nabble.com/")
 165     ;; ("opensubscriber" . "http://opensubscriber.com/")
 166     )
 167   "List of Mailing List Archives to use when stashing links.
 168
 169 These URIs are concatenated with the current message's
 170 Message-Id in `notmuch-show-stash-mlarchive-link'."
 171   :type '(alist :key-type (string :tag "Name")
 172                 :value-type (string :tag "URL"))
 173   :group 'notmuch-show)
 174
 175 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 176   "Default Mailing List Archive to use when stashing links.
 177
 178 This is used when `notmuch-show-stash-mlarchive-link' isn't
 179 provided with an MLA argument nor `completing-read' input."
 180   :type `(choice
 181           ,@(mapcar
 182              (lambda (mla)
 183                (list 'const :tag (car mla) :value (car mla)))
 184              notmuch-show-stash-mlarchive-link-alist))
 185   :group 'notmuch-show)
 186
 187 (defcustom notmuch-show-mark-read-tags '("-unread")
 188   "List of tag changes to apply to a message when it is marked as read.
 189
 190 Tags starting with \"+\" (or not starting with either \"+\" or
 191 \"-\") in the list will be added, and tags starting with \"-\"
 192 will be removed from the message being marked as read.
 193
 194 For example, if you wanted to remove an \"unread\" tag and add a
 195 \"read\" tag (which would make little sense), you would set:
 196     (\"-unread\" \"+read\")"
 197   :type '(repeat string)
 198   :group 'notmuch-show)
 199
 200
 201 (defmacro with-current-notmuch-show-message (&rest body)
 202   "Evaluate body with current buffer set to the text of current message"
 203   `(save-excursion
 204      (let ((id (notmuch-show-get-message-id)))
 205        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 206          (with-current-buffer buf
 207            (let ((coding-system-for-read 'no-conversion))
 208              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 209              ,@body)
 210            (kill-buffer buf))))))
 211
 212 (defun notmuch-show-turn-on-visual-line-mode ()
 213   "Enable Visual Line mode."
 214   (visual-line-mode t))
 215
 216 (defun notmuch-show-view-all-mime-parts ()
 217   "Use external viewers to view all attachments from the current message."
 218   (interactive)
 219   (with-current-notmuch-show-message
 220    ;; We override the mm-inline-media-tests to indicate which message
 221    ;; parts are already sufficiently handled by the original
 222    ;; presentation of the message in notmuch-show mode. These parts
 223    ;; will be inserted directly into the temporary buffer of
 224    ;; with-current-notmuch-show-message and silently discarded.
 225    ;;
 226    ;; Any MIME part not explicitly mentioned here will be handled by an
 227    ;; external viewer as configured in the various mailcap files.
 228    (let ((mm-inline-media-tests '(
 229                                   ("text/.*" ignore identity)
 230                                   ("application/pgp-signature" ignore identity)
 231                                   ("multipart/alternative" ignore identity)
 232                                   ("multipart/mixed" ignore identity)
 233                                   ("multipart/related" ignore identity)
 234                                  )))
 235      (mm-display-parts (mm-dissect-buffer)))))
 236
 237 (defun notmuch-foreach-mime-part (function mm-handle)
 238   (cond ((stringp (car mm-handle))
 239          (dolist (part (cdr mm-handle))
 240            (notmuch-foreach-mime-part function part)))
 241         ((bufferp (car mm-handle))
 242          (funcall function mm-handle))
 243         (t (dolist (part mm-handle)
 244              (notmuch-foreach-mime-part function part)))))
 245
 246 (defun notmuch-count-attachments (mm-handle)
 247   (let ((count 0))
 248     (notmuch-foreach-mime-part
 249      (lambda (p)
 250        (let ((disposition (mm-handle-disposition p)))
 251          (and (listp disposition)
 252               (or (equal (car disposition) "attachment")
 253                   (and (equal (car disposition) "inline")
 254                        (assq 'filename disposition)))
 255               (incf count))))
 256      mm-handle)
 257     count))
 258
 259 (defun notmuch-save-attachments (mm-handle &optional queryp)
 260   (notmuch-foreach-mime-part
 261    (lambda (p)
 262      (let ((disposition (mm-handle-disposition p)))
 263        (and (listp disposition)
 264             (or (equal (car disposition) "attachment")
 265                 (and (equal (car disposition) "inline")
 266                      (assq 'filename disposition)))
 267             (or (not queryp)
 268                 (y-or-n-p
 269                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 270             (mm-save-part p))))
 271    mm-handle))
 272
 273 (defun notmuch-show-save-attachments ()
 274   "Save all attachments from the current message."
 275   (interactive)
 276   (with-current-notmuch-show-message
 277    (let ((mm-handle (mm-dissect-buffer)))
 278      (notmuch-save-attachments
 279       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 280   (message "Done"))
 281
 282 (defun notmuch-show-with-message-as-text (fn)
 283   "Apply FN to a text representation of the current message.
 284
 285 FN is called with one argument, the message properties. It should
 286 operation on the contents of the current buffer."
 287
 288   ;; Remake the header to ensure that all information is available.
 289   (let* ((to (notmuch-show-get-to))
 290          (cc (notmuch-show-get-cc))
 291          (from (notmuch-show-get-from))
 292          (subject (notmuch-show-get-subject))
 293          (date (notmuch-show-get-date))
 294          (tags (notmuch-show-get-tags))
 295          (depth (notmuch-show-get-depth))
 296
 297          (header (concat
 298                   "Subject: " subject "\n"
 299                   "To: " to "\n"
 300                   (if (not (string= cc ""))
 301                       (concat "Cc: " cc "\n")
 302                     "")
 303                   "From: " from "\n"
 304                   "Date: " date "\n"
 305                   (if tags
 306                       (concat "Tags: "
 307                               (mapconcat #'identity tags ", ") "\n")
 308                     "")))
 309          (all (buffer-substring (notmuch-show-message-top)
 310                                 (notmuch-show-message-bottom)))
 311
 312          (props (notmuch-show-get-message-properties))
 313          (indenting notmuch-show-indent-content))
 314     (with-temp-buffer
 315       (insert all)
 316       (if indenting
 317           (indent-rigidly (point-min) (point-max) (- depth)))
 318       ;; Remove the original header.
 319       (goto-char (point-min))
 320       (re-search-forward "^$" (point-max) nil)
 321       (delete-region (point-min) (point))
 322       (insert header)
 323       (funcall fn props))))
 324
 325 (defun notmuch-show-print-message ()
 326   "Print the current message."
 327   (interactive)
 328   (notmuch-show-with-message-as-text 'notmuch-print-message))
 329
 330 (defun notmuch-show-fontify-header ()
 331   (let ((face (cond
 332                ((looking-at "[Tt]o:")
 333                 'message-header-to)
 334                ((looking-at "[Bb]?[Cc][Cc]:")
 335                 'message-header-cc)
 336                ((looking-at "[Ss]ubject:")
 337                 'message-header-subject)
 338                ((looking-at "[Ff]rom:")
 339                 'message-header-from)
 340                (t
 341                 'message-header-other))))
 342
 343     (overlay-put (make-overlay (point) (re-search-forward ":"))
 344                  'face 'message-header-name)
 345     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 346                  'face face)))
 347
 348 (defun notmuch-show-colour-headers ()
 349   "Apply some colouring to the current headers."
 350   (goto-char (point-min))
 351   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 352     (notmuch-show-fontify-header)
 353     (forward-line)))
 354
 355 (defun notmuch-show-spaces-n (n)
 356   "Return a string comprised of `n' spaces."
 357   (make-string n ? ))
 358
 359 (defun notmuch-show-update-tags (tags)
 360   "Update the displayed tags of the current message."
 361   (save-excursion
 362     (goto-char (notmuch-show-message-top))
 363     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 364         (let ((inhibit-read-only t))
 365           (replace-match (concat "("
 366                                  (notmuch-tag-format-tags tags)
 367                                  ")"))))))
 368
 369 (defun notmuch-clean-address (address)
 370   "Try to clean a single email ADDRESS for display. Return a cons
 371 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 372 parsing fails."
 373   (condition-case nil
 374     (let (p-name p-address)
 375       ;; It would be convenient to use `mail-header-parse-address',
 376       ;; but that expects un-decoded mailbox parts, whereas our
 377       ;; mailbox parts are already decoded (and hence may contain
 378       ;; UTF-8). Given that notmuch should handle most of the awkward
 379       ;; cases, some simple string deconstruction should be sufficient
 380       ;; here.
 381       (cond
 382        ;; "User <user@dom.ain>" style.
 383        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 384         (setq p-name (match-string 1 address)
 385               p-address (match-string 2 address)))
 386
 387        ;; "<user@dom.ain>" style.
 388        ((string-match "<\\(.*\\)>" address)
 389         (setq p-address (match-string 1 address)))
 390
 391        ;; Everything else.
 392        (t
 393         (setq p-address address)))
 394
 395       (when p-name
 396         ;; Remove elements of the mailbox part that are not relevant for
 397         ;; display, even if they are required during transport:
 398         ;;
 399         ;; Backslashes.
 400         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 401
 402         ;; Outer single and double quotes, which might be nested.
 403         (loop
 404          with start-of-loop
 405          do (setq start-of-loop p-name)
 406
 407          when (string-match "^\"\\(.*\\)\"$" p-name)
 408          do (setq p-name (match-string 1 p-name))
 409
 410          when (string-match "^'\\(.*\\)'$" p-name)
 411          do (setq p-name (match-string 1 p-name))
 412
 413          until (string= start-of-loop p-name)))
 414
 415       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 416       ;; 'foo@bar.com'.
 417       (when (string= p-name p-address)
 418         (setq p-name nil))
 419
 420       (cons p-address p-name))
 421     (error (cons address nil))))
 422
 423 (defun notmuch-show-clean-address (address)
 424   "Try to clean a single email ADDRESS for display.  Return
 425 unchanged ADDRESS if parsing fails."
 426   (let* ((clean-address (notmuch-clean-address address))
 427          (p-address (car clean-address))
 428          (p-name (cdr clean-address)))
 429     ;; If no name, return just the address.
 430     (if (not p-name)
 431         p-address
 432       ;; Otherwise format the name and address together.
 433       (concat p-name " <" p-address ">"))))
 434
 435 (defun notmuch-show-insert-headerline (headers date tags depth)
 436   "Insert a notmuch style headerline based on HEADERS for a
 437 message at DEPTH in the current thread."
 438   (let ((start (point)))
 439     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 440             (notmuch-show-clean-address (plist-get headers :From))
 441             " ("
 442             date
 443             ") ("
 444             (notmuch-tag-format-tags tags)
 445             ")\n")
 446     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 447
 448 (defun notmuch-show-insert-header (header header-value)
 449   "Insert a single header."
 450   (insert header ": " header-value "\n"))
 451
 452 (defun notmuch-show-insert-headers (headers)
 453   "Insert the headers of the current message."
 454   (let ((start (point)))
 455     (mapc (lambda (header)
 456             (let* ((header-symbol (intern (concat ":" header)))
 457                    (header-value (plist-get headers header-symbol)))
 458               (if (and header-value
 459                        (not (string-equal "" header-value)))
 460                   (notmuch-show-insert-header header header-value))))
 461           notmuch-message-headers)
 462     (save-excursion
 463       (save-restriction
 464         (narrow-to-region start (point-max))
 465         (run-hooks 'notmuch-show-markup-headers-hook)))))
 466
 467 (define-button-type 'notmuch-show-part-button-type
 468   'action 'notmuch-show-part-button-default
 469   'follow-link t
 470   'face 'message-mml
 471   :supertype 'notmuch-button-type)
 472
 473 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 474   (let ((button)
 475         (base-label (concat (when name (concat name ": "))
 476                             declared-type
 477                             (unless (string-equal declared-type content-type)
 478                               (concat " (as " content-type ")"))
 479                             comment)))
 480
 481     (setq button
 482           (insert-button
 483            (concat "[ " base-label " ]")
 484            :base-label base-label
 485            :type 'notmuch-show-part-button-type
 486            :notmuch-part-hidden nil))
 487     (insert "\n")
 488     ;; return button
 489     button))
 490
 491 ;; This is taken from notmuch-wash: maybe it should be unified?
 492 (defun notmuch-show-toggle-part-invisibility (&optional button)
 493   (interactive)
 494   (let* ((button (or button (button-at (point))))
 495          (overlay (button-get button 'overlay)))
 496     (when overlay
 497       (let* ((show (button-get button :notmuch-part-hidden))
 498              (new-start (button-start button))
 499              (button-label (button-get button :base-label))
 500              (old-point (point))
 501              (properties (text-properties-at (point)))
 502              (inhibit-read-only t))
 503         ;; Toggle the button itself.
 504         (button-put button :notmuch-part-hidden (not show))
 505         (goto-char new-start)
 506         (insert "[ " button-label (if show " ]" " (hidden) ]"))
 507         (set-text-properties new-start (point) properties)
 508         (let ((old-end (button-end button)))
 509           (move-overlay button new-start (point))
 510           (delete-region (point) old-end))
 511         (goto-char (min old-point (1- (button-end button))))
 512         (overlay-put overlay 'invisible (not show))))))
 513
 514 ;; MIME part renderers
 515
 516 (defun notmuch-show-multipart/*-to-list (part)
 517   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 518           (plist-get part :content)))
 519
 520 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
 521   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 522         (inner-parts (plist-get part :content))
 523         (start (point)))
 524     ;; This inserts all parts of the chosen type rather than just one,
 525     ;; but it's not clear that this is the wrong thing to do - which
 526     ;; should be chosen if there are more than one that match?
 527     (mapc (lambda (inner-part)
 528             (let* ((inner-type (plist-get inner-part :content-type))
 529                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 530                            (string= chosen-type inner-type)))))
 531               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 532           inner-parts)
 533
 534     (when notmuch-show-indent-multipart
 535       (indent-rigidly start (point) 1)))
 536   t)
 537
 538 (defun notmuch-show-setup-w3m ()
 539   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 540   (interactive)
 541   (if (boundp 'w3m-cid-retrieve-function-alist)
 542     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 543       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 544             w3m-cid-retrieve-function-alist)))
 545   (setq mm-inline-text-html-with-images t))
 546
 547 (defvar w3m-current-buffer) ;; From `w3m.el'.
 548 (defvar notmuch-show-w3m-cid-store nil)
 549 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 550
 551 (defun notmuch-show-w3m-cid-store-internal (content-id
 552                                             message-id
 553                                             part-number
 554                                             content-type
 555                                             content)
 556   (push (list content-id
 557               message-id
 558               part-number
 559               content-type
 560               content)
 561         notmuch-show-w3m-cid-store))
 562
 563 (defun notmuch-show-w3m-cid-store (msg part)
 564   (let ((content-id (plist-get part :content-id)))
 565     (when content-id
 566       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 567                                            (plist-get msg :id)
 568                                            (plist-get part :id)
 569                                            (plist-get part :content-type)
 570                                            nil))))
 571
 572 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 573   (let ((matching-part (with-current-buffer w3m-current-buffer
 574                          (assoc url notmuch-show-w3m-cid-store))))
 575     (if matching-part
 576         (let ((message-id (nth 1 matching-part))
 577               (part-number (nth 2 matching-part))
 578               (content-type (nth 3 matching-part))
 579               (content (nth 4 matching-part)))
 580           ;; If we don't already have the content, get it and cache
 581           ;; it, as some messages reference the same cid: part many
 582           ;; times (hundreds!), which results in many calls to
 583           ;; `notmuch part'.
 584           (unless content
 585             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 586                                                               part-number notmuch-show-process-crypto))
 587             (with-current-buffer w3m-current-buffer
 588               (notmuch-show-w3m-cid-store-internal url
 589                                                    message-id
 590                                                    part-number
 591                                                    content-type
 592                                                    content)))
 593           (insert content)
 594           content-type)
 595       nil)))
 596
 597 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
 598   (let ((inner-parts (plist-get part :content))
 599         (start (point)))
 600
 601     ;; We assume that the first part is text/html and the remainder
 602     ;; things that it references.
 603
 604     ;; Stash the non-primary parts.
 605     (mapc (lambda (part)
 606             (notmuch-show-w3m-cid-store msg part))
 607           (cdr inner-parts))
 608
 609     ;; Render the primary part.
 610     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 611
 612     (when notmuch-show-indent-multipart
 613       (indent-rigidly start (point) 1)))
 614   t)
 615
 616 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
 617   (button-put button 'face 'notmuch-crypto-part-header)
 618   ;; add signature status button if sigstatus provided
 619   (if (plist-member part :sigstatus)
 620       (let* ((from (notmuch-show-get-header :From msg))
 621              (sigstatus (car (plist-get part :sigstatus))))
 622         (notmuch-crypto-insert-sigstatus-button sigstatus from))
 623     ;; if we're not adding sigstatus, tell the user how they can get it
 624     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 625
 626   (let ((inner-parts (plist-get part :content))
 627         (start (point)))
 628     ;; Show all of the parts.
 629     (mapc (lambda (inner-part)
 630             (notmuch-show-insert-bodypart msg inner-part depth))
 631           inner-parts)
 632
 633     (when notmuch-show-indent-multipart
 634       (indent-rigidly start (point) 1)))
 635   t)
 636
 637 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
 638   (button-put button 'face 'notmuch-crypto-part-header)
 639   ;; add encryption status button if encstatus specified
 640   (if (plist-member part :encstatus)
 641       (let ((encstatus (car (plist-get part :encstatus))))
 642         (notmuch-crypto-insert-encstatus-button encstatus)
 643         ;; add signature status button if sigstatus specified
 644         (if (plist-member part :sigstatus)
 645             (let* ((from (notmuch-show-get-header :From msg))
 646                    (sigstatus (car (plist-get part :sigstatus))))
 647               (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 648     ;; if we're not adding encstatus, tell the user how they can get it
 649     (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts."))
 650
 651   (let ((inner-parts (plist-get part :content))
 652         (start (point)))
 653     ;; Show all of the parts.
 654     (mapc (lambda (inner-part)
 655             (notmuch-show-insert-bodypart msg inner-part depth))
 656           inner-parts)
 657
 658     (when notmuch-show-indent-multipart
 659       (indent-rigidly start (point) 1)))
 660   t)
 661
 662 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
 663   (let ((inner-parts (plist-get part :content))
 664         (start (point)))
 665     ;; Show all of the parts.
 666     (mapc (lambda (inner-part)
 667             (notmuch-show-insert-bodypart msg inner-part depth))
 668           inner-parts)
 669
 670     (when notmuch-show-indent-multipart
 671       (indent-rigidly start (point) 1)))
 672   t)
 673
 674 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
 675   (let* ((message (car (plist-get part :content)))
 676          (body (car (plist-get message :body)))
 677          (start (point)))
 678
 679     ;; Override `notmuch-message-headers' to force `From' to be
 680     ;; displayed.
 681     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 682       (notmuch-show-insert-headers (plist-get message :headers)))
 683
 684     ;; Blank line after headers to be compatible with the normal
 685     ;; message display.
 686     (insert "\n")
 687
 688     ;; Show the body
 689     (notmuch-show-insert-bodypart msg body depth)
 690
 691     (when notmuch-show-indent-multipart
 692       (indent-rigidly start (point) 1)))
 693   t)
 694
 695 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
 696   ;; For backward compatibility we want to apply the text/plain hook
 697   ;; to the whole of the part including the part button if there is
 698   ;; one.
 699   (let ((start (if button
 700                    (button-start button)
 701                  (point))))
 702     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 703     (save-excursion
 704       (save-restriction
 705         (narrow-to-region start (point-max))
 706         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 707   t)
 708
 709 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
 710   (insert (with-temp-buffer
 711             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 712             ;; notmuch-get-bodypart-content provides "raw", non-converted
 713             ;; data. Replace CRLF with LF before icalendar can use it.
 714             (goto-char (point-min))
 715             (while (re-search-forward "\r\n" nil t)
 716               (replace-match "\n" nil nil))
 717             (let ((file (make-temp-file "notmuch-ical"))
 718                   result)
 719               (unwind-protect
 720                   (progn
 721                     (unless (icalendar-import-buffer file t)
 722                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 723                     (set-buffer (get-file-buffer file))
 724                     (setq result (buffer-substring (point-min) (point-max)))
 725                     (set-buffer-modified-p nil)
 726                     (kill-buffer (current-buffer)))
 727                 (delete-file file))
 728               result)))
 729   t)
 730
 731 ;; For backwards compatibility.
 732 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
 733   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
 734
 735 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 736   ;; If we can deduce a MIME type from the filename of the attachment,
 737   ;; we return that.
 738   (if (plist-get part :filename)
 739       (let ((extension (file-name-extension (plist-get part :filename)))
 740             mime-type)
 741         (if extension
 742             (progn
 743               (mailcap-parse-mimetypes)
 744               (setq mime-type (mailcap-extension-to-mime extension))
 745               (if (and mime-type
 746                        (not (string-equal mime-type "application/octet-stream")))
 747                   mime-type
 748                 nil))
 749           nil))))
 750
 751 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
 752   ;; text/html handler to work around bugs in renderers and our
 753   ;; invisibile parts code. In particular w3m sets up a keymap which
 754   ;; "leaks" outside the invisible region and causes strange effects
 755   ;; in notmuch. We set mm-inline-text-html-with-w3m-keymap to nil to
 756   ;; tell w3m not to set a keymap (so the normal notmuch-show-mode-map
 757   ;; remains).
 758   (let ((mm-inline-text-html-with-w3m-keymap nil))
 759     (notmuch-show-insert-part-*/* msg part content-type nth depth button)))
 760
 761 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
 762   ;; This handler _must_ succeed - it is the handler of last resort.
 763   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 764   t)
 765
 766 ;; Functions for determining how to handle MIME parts.
 767
 768 (defun notmuch-show-handlers-for (content-type)
 769   "Return a list of content handlers for a part of type CONTENT-TYPE."
 770   (let (result)
 771     (mapc (lambda (func)
 772             (if (functionp func)
 773                 (push func result)))
 774           ;; Reverse order of prefrence.
 775           (list (intern (concat "notmuch-show-insert-part-*/*"))
 776                 (intern (concat
 777                          "notmuch-show-insert-part-"
 778                          (car (notmuch-split-content-type content-type))
 779                          "/*"))
 780                 (intern (concat "notmuch-show-insert-part-" content-type))))
 781     result))
 782
 783 ;; \f
 784
 785 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
 786   (let ((handlers (notmuch-show-handlers-for content-type)))
 787     ;; Run the content handlers until one of them returns a non-nil
 788     ;; value.
 789     (while (and handlers
 790                 (not (condition-case err
 791                          (funcall (car handlers) msg part content-type nth depth button)
 792                        (error (progn
 793                                 (insert "!!! Bodypart insert error: ")
 794                                 (insert (error-message-string err))
 795                                 (insert " !!!\n") nil)))))
 796       (setq handlers (cdr handlers))))
 797   t)
 798
 799 (defun notmuch-show-create-part-overlays (button beg end)
 800   "Add an overlay to the part between BEG and END"
 801
 802   ;; If there is no button (i.e., the part is text/plain and the first
 803   ;; part) or if the part has no content then we don't make the part
 804   ;; toggleable.
 805   (when (and button (/= beg end))
 806     (button-put button 'overlay (make-overlay beg end))
 807     ;; Return true if we created an overlay.
 808     t))
 809
 810 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 811   "Insert the body part PART at depth DEPTH in the current thread.
 812
 813 If HIDE is non-nil then initially hide this part."
 814
 815   (let* ((content-type (downcase (plist-get part :content-type)))
 816          (mime-type (or (and (string= content-type "application/octet-stream")
 817                              (notmuch-show-get-mime-type-of-application/octet-stream part))
 818                         (and (string= content-type "inline patch")
 819                              "text/x-diff")
 820                         content-type))
 821          (nth (plist-get part :id))
 822          (beg (point))
 823          ;; We omit the part button for the first (or only) part if this is text/plain.
 824          (button (unless (and (string= mime-type "text/plain") (<= nth 1))
 825                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
 826          (content-beg (point)))
 827
 828     (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
 829     ;; Some of the body part handlers leave point somewhere up in the
 830     ;; part, so we make sure that we're down at the end.
 831     (goto-char (point-max))
 832     ;; Ensure that the part ends with a carriage return.
 833     (unless (bolp)
 834       (insert "\n"))
 835     (notmuch-show-create-part-overlays button content-beg (point))
 836     (when hide
 837       (save-excursion
 838         (notmuch-show-toggle-part-invisibility button)))
 839     ;; Record part information.  Since we already inserted subparts,
 840     ;; don't override existing :notmuch-part properties.
 841     (notmuch-map-text-property beg (point) :notmuch-part
 842                                (lambda (v) (or v part)))
 843     ;; Make :notmuch-part front sticky and rear non-sticky so it stays
 844     ;; applied to the beginning of each line when we indent the
 845     ;; message.  Since we're operating on arbitrary renderer output,
 846     ;; watch out for sticky specs of t, which means all properties are
 847     ;; front-sticky/rear-nonsticky.
 848     (notmuch-map-text-property beg (point) 'front-sticky
 849                                (lambda (v) (if (listp v)
 850                                                (pushnew :notmuch-part v)
 851                                              v)))
 852     (notmuch-map-text-property beg (point) 'rear-nonsticky
 853                                (lambda (v) (if (listp v)
 854                                                (pushnew :notmuch-part v)
 855                                              v)))))
 856
 857 (defun notmuch-show-insert-body (msg body depth)
 858   "Insert the body BODY at depth DEPTH in the current thread."
 859   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 860
 861 (defun notmuch-show-make-symbol (type)
 862   (make-symbol (concat "notmuch-show-" type)))
 863
 864 (defun notmuch-show-strip-re (string)
 865   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 866
 867 (defvar notmuch-show-previous-subject "")
 868 (make-variable-buffer-local 'notmuch-show-previous-subject)
 869
 870 (defun notmuch-show-insert-msg (msg depth)
 871   "Insert the message MSG at depth DEPTH in the current thread."
 872   (let* ((headers (plist-get msg :headers))
 873          ;; Indentation causes the buffer offset of the start/end
 874          ;; points to move, so we must use markers.
 875          message-start message-end
 876          content-start content-end
 877          headers-start headers-end
 878          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 879
 880     (setq message-start (point-marker))
 881
 882     (notmuch-show-insert-headerline headers
 883                                     (or (if notmuch-show-relative-dates
 884                                             (plist-get msg :date_relative)
 885                                           nil)
 886                                         (plist-get headers :Date))
 887                                     (plist-get msg :tags) depth)
 888
 889     (setq content-start (point-marker))
 890
 891     ;; Set `headers-start' to point after the 'Subject:' header to be
 892     ;; compatible with the existing implementation. This just sets it
 893     ;; to after the first header.
 894     (notmuch-show-insert-headers headers)
 895     (save-excursion
 896       (goto-char content-start)
 897       ;; If the subject of this message is the same as that of the
 898       ;; previous message, don't display it when this message is
 899       ;; collapsed.
 900       (when (not (string= notmuch-show-previous-subject
 901                           bare-subject))
 902         (forward-line 1))
 903       (setq headers-start (point-marker)))
 904     (setq headers-end (point-marker))
 905
 906     (setq notmuch-show-previous-subject bare-subject)
 907
 908     ;; A blank line between the headers and the body.
 909     (insert "\n")
 910     (notmuch-show-insert-body msg (plist-get msg :body)
 911                               (if notmuch-show-indent-content depth 0))
 912     ;; Ensure that the body ends with a newline.
 913     (unless (bolp)
 914       (insert "\n"))
 915     (setq content-end (point-marker))
 916
 917     ;; Indent according to the depth in the thread.
 918     (if notmuch-show-indent-content
 919         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 920
 921     (setq message-end (point-max-marker))
 922
 923     ;; Save the extents of this message over the whole text of the
 924     ;; message.
 925     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 926
 927     ;; Create overlays used to control visibility
 928     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
 929     (plist-put msg :message-overlay (make-overlay headers-start content-end))
 930
 931     (plist-put msg :depth depth)
 932
 933     ;; Save the properties for this message. Currently this saves the
 934     ;; entire message (augmented it with other stuff), which seems
 935     ;; like overkill. We might save a reduced subset (for example, not
 936     ;; the content).
 937     (notmuch-show-set-message-properties msg)
 938
 939     ;; Set header visibility.
 940     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 941
 942     ;; Message visibility depends on whether it matched the search
 943     ;; criteria.
 944     (notmuch-show-message-visible msg (and (plist-get msg :match)
 945                                            (not (plist-get msg :excluded))))))
 946
 947 (defun notmuch-show-toggle-process-crypto ()
 948   "Toggle the processing of cryptographic MIME parts."
 949   (interactive)
 950   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 951   (message (if notmuch-show-process-crypto
 952                "Processing cryptographic MIME parts."
 953              "Not processing cryptographic MIME parts."))
 954   (notmuch-show-refresh-view))
 955
 956 (defun notmuch-show-toggle-elide-non-matching ()
 957   "Toggle the display of non-matching messages."
 958   (interactive)
 959   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 960   (message (if notmuch-show-elide-non-matching-messages
 961                "Showing matching messages only."
 962              "Showing all messages."))
 963   (notmuch-show-refresh-view))
 964
 965 (defun notmuch-show-toggle-thread-indentation ()
 966   "Toggle the indentation of threads."
 967   (interactive)
 968   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 969   (message (if notmuch-show-indent-content
 970                "Content is indented."
 971              "Content is not indented."))
 972   (notmuch-show-refresh-view))
 973
 974 (defun notmuch-show-insert-tree (tree depth)
 975   "Insert the message tree TREE at depth DEPTH in the current thread."
 976   (let ((msg (car tree))
 977         (replies (cadr tree)))
 978     ;; We test whether there is a message or just some replies.
 979     (when msg
 980       (notmuch-show-insert-msg msg depth))
 981     (notmuch-show-insert-thread replies (1+ depth))))
 982
 983 (defun notmuch-show-insert-thread (thread depth)
 984   "Insert the thread THREAD at depth DEPTH in the current forest."
 985   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 986
 987 (defun notmuch-show-insert-forest (forest)
 988   "Insert the forest of threads FOREST."
 989   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 990
 991 (defvar notmuch-id-regexp
 992   (concat
 993    ;; Match the id: prefix only if it begins a word (to disallow, for
 994    ;; example, matching cid:).
 995    "\\<id:\\("
 996    ;; If the term starts with a ", then parse Xapian's quoted boolean
 997    ;; term syntax, which allows for anything as long as embedded
 998    ;; double quotes escaped by doubling them.  We also disallow
 999    ;; newlines (which Xapian allows) to prevent runaway terms.
1000    "\"\\([^\"\n]\\|\"\"\\)*\""
1001    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1002    ;; next space or ).  We disallow [.,;] as the last character
1003    ;; because these are probably part of the surrounding text, and not
1004    ;; part of the id.  This doesn't match single character ids; meh.
1005    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1006    "\\)")
1007   "The regexp used to match id: links in messages.")
1008
1009 (defvar notmuch-mid-regexp
1010   ;; goto-address-url-regexp matched cid: links, which have the same
1011   ;; grammar as the message ID part of a mid: link.  Construct the
1012   ;; regexp using the same technique as goto-address-url-regexp.
1013   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1014   "The regexp used to match mid: links in messages.
1015
1016 See RFC 2392.")
1017
1018 (defun notmuch-show-buttonise-links (start end)
1019   "Buttonise URLs and mail addresses between START and END.
1020
1021 This also turns id:\"<message id>\"-parts and mid: links into
1022 buttons for a corresponding notmuch search."
1023   (goto-address-fontify-region start end)
1024   (save-excursion
1025     (let (links)
1026       (goto-char start)
1027       (while (re-search-forward notmuch-id-regexp end t)
1028         (push (list (match-beginning 0) (match-end 0)
1029                     (match-string-no-properties 0)) links))
1030       (goto-char start)
1031       (while (re-search-forward notmuch-mid-regexp end t)
1032         (let* ((mid-cid (match-string-no-properties 1))
1033                (mid (save-match-data
1034                       (string-match "^[^/]*" mid-cid)
1035                       (url-unhex-string (match-string 0 mid-cid)))))
1036           (push (list (match-beginning 0) (match-end 0)
1037                       (notmuch-id-to-query mid)) links)))
1038       (dolist (link links)
1039         ;; Remove the overlay created by goto-address-mode
1040         (remove-overlays (first link) (second link) 'goto-address t)
1041         (make-text-button (first link) (second link)
1042                           :type 'notmuch-button-type
1043                           'action `(lambda (arg)
1044                                      (notmuch-show ,(third link)))
1045                           'follow-link t
1046                           'help-echo "Mouse-1, RET: search for this message"
1047                           'face goto-address-mail-face)))))
1048
1049 ;;;###autoload
1050 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1051   "Run \"notmuch show\" with the given thread ID and display results.
1052
1053 The optional PARENT-BUFFER is the notmuch-search buffer from
1054 which this notmuch-show command was executed, (so that the
1055 next thread from that buffer can be show when done with this
1056 one).
1057
1058 The optional QUERY-CONTEXT is a notmuch search term. Only
1059 messages from the thread matching this search term are shown if
1060 non-nil.
1061
1062 The optional BUFFER-NAME provides the name of the buffer in
1063 which the message thread is shown. If it is nil (which occurs
1064 when the command is called interactively) the argument to the
1065 function is used."
1066   (interactive "sNotmuch show: ")
1067   (let ((buffer-name (generate-new-buffer-name
1068                       (or buffer-name
1069                           (concat "*notmuch-" thread-id "*")))))
1070     (switch-to-buffer (get-buffer-create buffer-name))
1071     ;; Set the default value for `notmuch-show-process-crypto' in this
1072     ;; buffer.
1073     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1074     ;; Set the default value for
1075     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1076     ;; there is a prefix argument, invert the default.
1077     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1078     (if current-prefix-arg
1079         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1080
1081     (setq notmuch-show-thread-id thread-id
1082           notmuch-show-parent-buffer parent-buffer
1083           notmuch-show-query-context query-context)
1084     (notmuch-show-build-buffer)
1085     (notmuch-show-goto-first-wanted-message)
1086     (current-buffer)))
1087
1088 (defun notmuch-show-build-buffer ()
1089   (let ((inhibit-read-only t))
1090
1091     (notmuch-show-mode)
1092     ;; Don't track undo information for this buffer
1093     (set 'buffer-undo-list t)
1094
1095     (erase-buffer)
1096     (goto-char (point-min))
1097     (save-excursion
1098       (let* ((basic-args (list notmuch-show-thread-id))
1099              (args (if notmuch-show-query-context
1100                        (append (list "\'") basic-args
1101                                (list "and (" notmuch-show-query-context ")\'"))
1102                      (append (list "\'") basic-args (list "\'"))))
1103              (cli-args (cons "--exclude=false"
1104                              (when notmuch-show-elide-non-matching-messages
1105                                (list "--entire-thread=false")))))
1106
1107         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1108         ;; If the query context reduced the results to nothing, run
1109         ;; the basic query.
1110         (when (and (eq (buffer-size) 0)
1111                    notmuch-show-query-context)
1112           (notmuch-show-insert-forest
1113            (notmuch-query-get-threads (append cli-args basic-args)))))
1114
1115       (jit-lock-register #'notmuch-show-buttonise-links)
1116
1117       ;; Set the header line to the subject of the first message.
1118       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1119
1120       (run-hooks 'notmuch-show-hook))))
1121
1122 (defun notmuch-show-capture-state ()
1123   "Capture the state of the current buffer.
1124
1125 This includes:
1126  - the list of open messages,
1127  - the current message."
1128   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1129
1130 (defun notmuch-show-apply-state (state)
1131   "Apply STATE to the current buffer.
1132
1133 This includes:
1134  - opening the messages previously opened,
1135  - closing all other messages,
1136  - moving to the correct current message."
1137   (let ((current (car state))
1138         (open (cadr state)))
1139
1140     ;; Open those that were open.
1141     (goto-char (point-min))
1142     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1143                                            (member (notmuch-show-get-message-id) open))
1144           until (not (notmuch-show-goto-message-next)))
1145
1146     ;; Go to the previously open message.
1147     (goto-char (point-min))
1148     (unless (loop if (string= current (notmuch-show-get-message-id))
1149                   return t
1150                   until (not (notmuch-show-goto-message-next)))
1151       (goto-char (point-min))
1152       (message "Previously current message not found."))
1153     (notmuch-show-message-adjust)))
1154
1155 (defun notmuch-show-refresh-view (&optional reset-state)
1156   "Refresh the current view.
1157
1158 Refreshes the current view, observing changes in display
1159 preferences. If invoked with a prefix argument (or RESET-STATE is
1160 non-nil) then the state of the buffer (open/closed messages) is
1161 reset based on the original query."
1162   (interactive "P")
1163   (let ((inhibit-read-only t)
1164         (state (unless reset-state
1165                  (notmuch-show-capture-state))))
1166     ;; erase-buffer does not seem to remove overlays, which can lead
1167     ;; to weird effects such as remaining images, so remove them
1168     ;; manually.
1169     (remove-overlays)
1170     (erase-buffer)
1171     (notmuch-show-build-buffer)
1172     (if state
1173         (notmuch-show-apply-state state)
1174       ;; We're resetting state, so navigate to the first open message
1175       ;; and mark it read, just like opening a new show buffer.
1176       (notmuch-show-goto-first-wanted-message))))
1177
1178 (defvar notmuch-show-stash-map
1179   (let ((map (make-sparse-keymap)))
1180     (define-key map "c" 'notmuch-show-stash-cc)
1181     (define-key map "d" 'notmuch-show-stash-date)
1182     (define-key map "F" 'notmuch-show-stash-filename)
1183     (define-key map "f" 'notmuch-show-stash-from)
1184     (define-key map "i" 'notmuch-show-stash-message-id)
1185     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1186     (define-key map "s" 'notmuch-show-stash-subject)
1187     (define-key map "T" 'notmuch-show-stash-tags)
1188     (define-key map "t" 'notmuch-show-stash-to)
1189     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1190     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1191     map)
1192   "Submap for stash commands")
1193 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1194
1195 (defvar notmuch-show-part-map
1196   (let ((map (make-sparse-keymap)))
1197     (define-key map "s" 'notmuch-show-save-part)
1198     (define-key map "v" 'notmuch-show-view-part)
1199     (define-key map "o" 'notmuch-show-interactively-view-part)
1200     (define-key map "|" 'notmuch-show-pipe-part)
1201     map)
1202   "Submap for part commands")
1203 (fset 'notmuch-show-part-map notmuch-show-part-map)
1204
1205 (defvar notmuch-show-mode-map
1206       (let ((map (make-sparse-keymap)))
1207         (define-key map "?" 'notmuch-help)
1208         (define-key map "q" 'notmuch-kill-this-buffer)
1209         (define-key map (kbd "<C-tab>") 'widget-backward)
1210         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1211         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1212         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1213         (define-key map "s" 'notmuch-search)
1214         (define-key map "m" 'notmuch-mua-new-mail)
1215         (define-key map "f" 'notmuch-show-forward-message)
1216         (define-key map "r" 'notmuch-show-reply-sender)
1217         (define-key map "R" 'notmuch-show-reply)
1218         (define-key map "|" 'notmuch-show-pipe-message)
1219         (define-key map "w" 'notmuch-show-save-attachments)
1220         (define-key map "V" 'notmuch-show-view-raw-message)
1221         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1222         (define-key map "c" 'notmuch-show-stash-map)
1223         (define-key map "=" 'notmuch-show-refresh-view)
1224         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1225         (define-key map "*" 'notmuch-show-tag-all)
1226         (define-key map "-" 'notmuch-show-remove-tag)
1227         (define-key map "+" 'notmuch-show-add-tag)
1228         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1229         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1230         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1231         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1232         (define-key map "N" 'notmuch-show-next-message)
1233         (define-key map "P" 'notmuch-show-previous-message)
1234         (define-key map "n" 'notmuch-show-next-open-message)
1235         (define-key map "p" 'notmuch-show-previous-open-message)
1236         (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1237         (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1238         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1239         (define-key map " " 'notmuch-show-advance-and-archive)
1240         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1241         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1242         (define-key map "#" 'notmuch-show-print-message)
1243         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1244         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1245         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1246         (define-key map "t" 'toggle-truncate-lines)
1247         (define-key map "." 'notmuch-show-part-map)
1248         map)
1249       "Keymap for \"notmuch show\" buffers.")
1250 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1251
1252 (defun notmuch-show-mode ()
1253   "Major mode for viewing a thread with notmuch.
1254
1255 This buffer contains the results of the \"notmuch show\" command
1256 for displaying a single thread of email from your email archives.
1257
1258 By default, various components of email messages, (citations,
1259 signatures, already-read messages), are hidden. You can make
1260 these parts visible by clicking with the mouse button or by
1261 pressing RET after positioning the cursor on a hidden part, (for
1262 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1263
1264 Reading the thread sequentially is well-supported by pressing
1265 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1266 to the next message, or advance to the next thread (if already on
1267 the last message of a thread).
1268
1269 Other commands are available to read or manipulate the thread
1270 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1271 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1272 without scrolling through with \\[notmuch-show-advance-and-archive]).
1273
1274 You can add or remove arbitrary tags from the current message with
1275 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1276
1277 All currently available key bindings:
1278
1279 \\{notmuch-show-mode-map}"
1280   (interactive)
1281   (kill-all-local-variables)
1282   (use-local-map notmuch-show-mode-map)
1283   (setq major-mode 'notmuch-show-mode
1284         mode-name "notmuch-show")
1285   (setq buffer-read-only t
1286         truncate-lines t))
1287
1288 (defun notmuch-show-move-to-message-top ()
1289   (goto-char (notmuch-show-message-top)))
1290
1291 (defun notmuch-show-move-to-message-bottom ()
1292   (goto-char (notmuch-show-message-bottom)))
1293
1294 (defun notmuch-show-message-adjust ()
1295   (recenter 0))
1296
1297 ;; Movement related functions.
1298
1299 ;; There's some strangeness here where a text property applied to a
1300 ;; region a->b is not found when point is at b. We walk backwards
1301 ;; until finding the property.
1302 (defun notmuch-show-message-extent ()
1303   (let (r)
1304     (save-excursion
1305       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1306         (backward-char)))
1307     r))
1308
1309 (defun notmuch-show-message-top ()
1310   (car (notmuch-show-message-extent)))
1311
1312 (defun notmuch-show-message-bottom ()
1313   (cdr (notmuch-show-message-extent)))
1314
1315 (defun notmuch-show-goto-message-next ()
1316   (let ((start (point)))
1317     (notmuch-show-move-to-message-bottom)
1318     (if (not (eobp))
1319         t
1320       (goto-char start)
1321       nil)))
1322
1323 (defun notmuch-show-goto-message-previous ()
1324   (notmuch-show-move-to-message-top)
1325   (if (bobp)
1326       nil
1327     (backward-char)
1328     (notmuch-show-move-to-message-top)
1329     t))
1330
1331 (defun notmuch-show-mapc (function)
1332   "Iterate through all messages in the current thread with
1333 `notmuch-show-goto-message-next' and call FUNCTION for side
1334 effects."
1335   (save-excursion
1336     (goto-char (point-min))
1337     (loop do (funcall function)
1338           while (notmuch-show-goto-message-next))))
1339
1340 ;; Functions relating to the visibility of messages and their
1341 ;; components.
1342
1343 (defun notmuch-show-message-visible (props visible-p)
1344   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1345   (notmuch-show-set-prop :message-visible visible-p props))
1346
1347 (defun notmuch-show-headers-visible (props visible-p)
1348   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1349   (notmuch-show-set-prop :headers-visible visible-p props))
1350
1351 ;; Functions for setting and getting attributes of the current
1352 ;; message.
1353
1354 (defun notmuch-show-set-message-properties (props)
1355   (save-excursion
1356     (notmuch-show-move-to-message-top)
1357     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1358
1359 (defun notmuch-show-get-message-properties ()
1360   "Return the properties of the current message as a plist.
1361
1362 Some useful entries are:
1363 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1364 :body - Body of the message
1365 :tags - Tags for this message"
1366   (save-excursion
1367     (notmuch-show-move-to-message-top)
1368     (get-text-property (point) :notmuch-message-properties)))
1369
1370 (defun notmuch-show-get-part-properties ()
1371   "Return the properties of the innermost part containing point.
1372
1373 This is the part property list retrieved from the CLI.  Signals
1374 an error if there is no part containing point."
1375   (or (get-text-property (point) :notmuch-part)
1376       (error "No message part here")))
1377
1378 (defun notmuch-show-set-prop (prop val &optional props)
1379   (let ((inhibit-read-only t)
1380         (props (or props
1381                    (notmuch-show-get-message-properties))))
1382     (plist-put props prop val)
1383     (notmuch-show-set-message-properties props)))
1384
1385 (defun notmuch-show-get-prop (prop &optional props)
1386   (let ((props (or props
1387                    (notmuch-show-get-message-properties))))
1388     (plist-get props prop)))
1389
1390 (defun notmuch-show-get-message-id (&optional bare)
1391   "Return an id: query for the Message-Id of the current message.
1392
1393 If optional argument BARE is non-nil, return
1394 the Message-Id without id: prefix and escaping."
1395   (if bare
1396       (notmuch-show-get-prop :id)
1397     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1398
1399 (defun notmuch-show-get-messages-ids ()
1400   "Return all id: queries of messages in the current thread."
1401   (let ((message-ids))
1402     (notmuch-show-mapc
1403      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1404     message-ids))
1405
1406 (defun notmuch-show-get-messages-ids-search ()
1407   "Return a search string for all message ids of messages in the
1408 current thread."
1409   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1410
1411 ;; dme: Would it make sense to use a macro for many of these?
1412
1413 (defun notmuch-show-get-filename ()
1414   "Return the filename of the current message."
1415   (notmuch-show-get-prop :filename))
1416
1417 (defun notmuch-show-get-header (header &optional props)
1418   "Return the named header of the current message, if any."
1419   (plist-get (notmuch-show-get-prop :headers props) header))
1420
1421 (defun notmuch-show-get-cc ()
1422   (notmuch-show-get-header :Cc))
1423
1424 (defun notmuch-show-get-date ()
1425   (notmuch-show-get-header :Date))
1426
1427 (defun notmuch-show-get-from ()
1428   (notmuch-show-get-header :From))
1429
1430 (defun notmuch-show-get-subject ()
1431   (notmuch-show-get-header :Subject))
1432
1433 (defun notmuch-show-get-to ()
1434   (notmuch-show-get-header :To))
1435
1436 (defun notmuch-show-get-depth ()
1437   (notmuch-show-get-prop :depth))
1438
1439 (defun notmuch-show-set-tags (tags)
1440   "Set the tags of the current message."
1441   (notmuch-show-set-prop :tags tags)
1442   (notmuch-show-update-tags tags))
1443
1444 (defun notmuch-show-get-tags ()
1445   "Return the tags of the current message."
1446   (notmuch-show-get-prop :tags))
1447
1448 (defun notmuch-show-message-visible-p ()
1449   "Is the current message visible?"
1450   (notmuch-show-get-prop :message-visible))
1451
1452 (defun notmuch-show-headers-visible-p ()
1453   "Are the headers of the current message visible?"
1454   (notmuch-show-get-prop :headers-visible))
1455
1456 (defun notmuch-show-mark-read (&optional unread)
1457   "Mark the current message as read.
1458
1459 Mark the current message as read by applying the tag changes in
1460 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1461 default). If a prefix argument is given, the message will be
1462 marked as unread, i.e. the tag changes in
1463 `notmuch-show-mark-read-tags' will be reversed."
1464   (interactive "P")
1465   (when notmuch-show-mark-read-tags
1466     (apply 'notmuch-show-tag-message
1467            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1468
1469 ;; Functions for getting attributes of several messages in the current
1470 ;; thread.
1471
1472 (defun notmuch-show-get-message-ids-for-open-messages ()
1473   "Return a list of all id: queries for open messages in the current thread."
1474   (save-excursion
1475     (let (message-ids done)
1476       (goto-char (point-min))
1477       (while (not done)
1478         (if (notmuch-show-message-visible-p)
1479             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1480         (setq done (not (notmuch-show-goto-message-next)))
1481         )
1482       message-ids
1483       )))
1484
1485 ;; Commands typically bound to keys.
1486
1487 (defun notmuch-show-advance ()
1488   "Advance through thread.
1489
1490 If the current message in the thread is not yet fully visible,
1491 scroll by a near screenful to read more of the message.
1492
1493 Otherwise, (the end of the current message is already within the
1494 current window), advance to the next open message."
1495   (interactive)
1496   (let* ((end-of-this-message (notmuch-show-message-bottom))
1497          (visible-end-of-this-message (1- end-of-this-message))
1498          (ret nil))
1499     (while (invisible-p visible-end-of-this-message)
1500       (setq visible-end-of-this-message
1501             (max (point-min)
1502                  (1- (previous-single-char-property-change
1503                       visible-end-of-this-message 'invisible)))))
1504     (cond
1505      ;; Ideally we would test `end-of-this-message' against the result
1506      ;; of `window-end', but that doesn't account for the fact that
1507      ;; the end of the message might be hidden.
1508      ((and visible-end-of-this-message
1509            (> visible-end-of-this-message (window-end)))
1510       ;; The bottom of this message is not visible - scroll.
1511       (scroll-up nil))
1512
1513      ((not (= end-of-this-message (point-max)))
1514       ;; This is not the last message - move to the next visible one.
1515       (notmuch-show-next-open-message))
1516
1517      ((not (= (point) (point-max)))
1518       ;; This is the last message, but the cursor is not at the end of
1519       ;; the buffer. Move it there.
1520       (goto-char (point-max)))
1521
1522      (t
1523       ;; This is the last message - change the return value
1524       (setq ret t)))
1525     ret))
1526
1527 (defun notmuch-show-advance-and-archive ()
1528   "Advance through thread and archive.
1529
1530 This command is intended to be one of the simplest ways to
1531 process a thread of email. It works exactly like
1532 notmuch-show-advance, in that it scrolls through messages in a
1533 show buffer, except that when it gets to the end of the buffer it
1534 archives the entire current thread, (apply changes in
1535 `notmuch-archive-tags'), kills the buffer, and displays the next
1536 thread from the search from which this thread was originally
1537 shown."
1538   (interactive)
1539   (if (notmuch-show-advance)
1540       (notmuch-show-archive-thread-then-next)))
1541
1542 (defun notmuch-show-rewind ()
1543   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1544
1545 Specifically, if the beginning of the previous email is fewer
1546 than `window-height' lines from the current point, move to it
1547 just like `notmuch-show-previous-message'.
1548
1549 Otherwise, just scroll down a screenful of the current message.
1550
1551 This command does not modify any message tags, (it does not undo
1552 any effects from previous calls to
1553 `notmuch-show-advance-and-archive'."
1554   (interactive)
1555   (let ((start-of-message (notmuch-show-message-top))
1556         (start-of-window (window-start)))
1557     (cond
1558       ;; Either this message is properly aligned with the start of the
1559       ;; window or the start of this message is not visible on the
1560       ;; screen - scroll.
1561      ((or (= start-of-message start-of-window)
1562           (< start-of-message start-of-window))
1563       (scroll-down)
1564       ;; If a small number of lines from the previous message are
1565       ;; visible, realign so that the top of the current message is at
1566       ;; the top of the screen.
1567       (when (<= (count-screen-lines (window-start) start-of-message)
1568                 next-screen-context-lines)
1569         (goto-char (notmuch-show-message-top))
1570         (notmuch-show-message-adjust))
1571       ;; Move to the top left of the window.
1572       (goto-char (window-start)))
1573      (t
1574       ;; Move to the previous message.
1575       (notmuch-show-previous-message)))))
1576
1577 (defun notmuch-show-reply (&optional prompt-for-sender)
1578   "Reply to the sender and all recipients of the current message."
1579   (interactive "P")
1580   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1581
1582 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1583   "Reply to the sender of the current message."
1584   (interactive "P")
1585   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1586
1587 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1588   "Forward the current message."
1589   (interactive "P")
1590   (with-current-notmuch-show-message
1591    (notmuch-mua-new-forward-message prompt-for-sender)))
1592
1593 (defun notmuch-show-next-message (&optional pop-at-end)
1594   "Show the next message.
1595
1596 If a prefix argument is given and this is the last message in the
1597 thread, navigate to the next thread in the parent search buffer."
1598   (interactive "P")
1599   (if (notmuch-show-goto-message-next)
1600       (progn
1601         (notmuch-show-mark-read)
1602         (notmuch-show-message-adjust))
1603     (if pop-at-end
1604         (notmuch-show-next-thread)
1605       (goto-char (point-max)))))
1606
1607 (defun notmuch-show-previous-message ()
1608   "Show the previous message or the start of the current message."
1609   (interactive)
1610   (if (= (point) (notmuch-show-message-top))
1611       (notmuch-show-goto-message-previous)
1612     (notmuch-show-move-to-message-top))
1613   (notmuch-show-mark-read)
1614   (notmuch-show-message-adjust))
1615
1616 (defun notmuch-show-next-open-message (&optional pop-at-end)
1617   "Show the next open message.
1618
1619 If a prefix argument is given and this is the last open message
1620 in the thread, navigate to the next thread in the parent search
1621 buffer. Return t if there was a next open message in the thread
1622 to show, nil otherwise."
1623   (interactive "P")
1624   (let (r)
1625     (while (and (setq r (notmuch-show-goto-message-next))
1626                 (not (notmuch-show-message-visible-p))))
1627     (if r
1628         (progn
1629           (notmuch-show-mark-read)
1630           (notmuch-show-message-adjust))
1631       (if pop-at-end
1632           (notmuch-show-next-thread)
1633         (goto-char (point-max))))
1634     r))
1635
1636 (defun notmuch-show-next-matching-message ()
1637   "Show the next matching message."
1638   (interactive)
1639   (let (r)
1640     (while (and (setq r (notmuch-show-goto-message-next))
1641                 (not (notmuch-show-get-prop :match))))
1642     (if r
1643         (progn
1644           (notmuch-show-mark-read)
1645           (notmuch-show-message-adjust))
1646       (goto-char (point-max)))))
1647
1648 (defun notmuch-show-open-if-matched ()
1649   "Open a message if it is matched (whether or not excluded)."
1650   (let ((props (notmuch-show-get-message-properties)))
1651     (notmuch-show-message-visible props (plist-get props :match))))
1652
1653 (defun notmuch-show-goto-first-wanted-message ()
1654   "Move to the first open message and mark it read"
1655   (goto-char (point-min))
1656   (if (notmuch-show-message-visible-p)
1657       (notmuch-show-mark-read)
1658     (notmuch-show-next-open-message))
1659   (when (eobp)
1660     ;; There are no matched non-excluded messages so open all matched
1661     ;; (necessarily excluded) messages and go to the first.
1662     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1663     (force-window-update)
1664     (goto-char (point-min))
1665     (if (notmuch-show-message-visible-p)
1666         (notmuch-show-mark-read)
1667       (notmuch-show-next-open-message))))
1668
1669 (defun notmuch-show-previous-open-message ()
1670   "Show the previous open message."
1671   (interactive)
1672   (while (and (if (= (point) (notmuch-show-message-top))
1673                   (notmuch-show-goto-message-previous)
1674                 (notmuch-show-move-to-message-top))
1675               (not (notmuch-show-message-visible-p))))
1676   (notmuch-show-mark-read)
1677   (notmuch-show-message-adjust))
1678
1679 (defun notmuch-show-view-raw-message ()
1680   "View the file holding the current message."
1681   (interactive)
1682   (let* ((id (notmuch-show-get-message-id))
1683          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1684     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1685     (switch-to-buffer buf)
1686     (goto-char (point-min))
1687     (set-buffer-modified-p nil)
1688     (view-buffer buf 'kill-buffer-if-not-modified)))
1689
1690 (defun notmuch-show-pipe-message (entire-thread command)
1691   "Pipe the contents of the current message (or thread) to the given command.
1692
1693 The given command will be executed with the raw contents of the
1694 current email message as stdin. Anything printed by the command
1695 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1696
1697 When invoked with a prefix argument, the command will receive all
1698 open messages in the current thread (formatted as an mbox) rather
1699 than only the current message."
1700   (interactive "P\nsPipe message to command: ")
1701   (let (shell-command)
1702     (if entire-thread
1703         (setq shell-command
1704               (concat notmuch-command " show --format=mbox --exclude=false "
1705                       (shell-quote-argument
1706                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1707                       " | " command))
1708       (setq shell-command
1709             (concat notmuch-command " show --format=raw "
1710                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1711     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1712       (with-current-buffer buf
1713         (setq buffer-read-only nil)
1714         (erase-buffer)
1715         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1716           (goto-char (point-max))
1717           (set-buffer-modified-p nil)
1718           (setq buffer-read-only t)
1719           (unless (zerop exit-code)
1720             (switch-to-buffer-other-window buf)
1721             (message (format "Command '%s' exited abnormally with code %d"
1722                              shell-command exit-code))))))))
1723
1724 (defun notmuch-show-tag-message (&rest tag-changes)
1725   "Change tags for the current message.
1726
1727 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1728   (let* ((current-tags (notmuch-show-get-tags))
1729          (new-tags (notmuch-update-tags current-tags tag-changes)))
1730     (unless (equal current-tags new-tags)
1731       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
1732       (notmuch-show-set-tags new-tags))))
1733
1734 (defun notmuch-show-tag (&optional tag-changes)
1735   "Change tags for the current message.
1736
1737 See `notmuch-tag' for information on the format of TAG-CHANGES."
1738   (interactive)
1739   (let* ((tag-changes (notmuch-tag (notmuch-show-get-message-id) tag-changes))
1740          (current-tags (notmuch-show-get-tags))
1741          (new-tags (notmuch-update-tags current-tags tag-changes)))
1742     (unless (equal current-tags new-tags)
1743       (notmuch-show-set-tags new-tags))))
1744
1745 (defun notmuch-show-tag-all (&optional tag-changes)
1746   "Change tags for all messages in the current show buffer.
1747
1748 See `notmuch-tag' for information on the format of TAG-CHANGES."
1749   (interactive)
1750   (setq tag-changes (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1751   (notmuch-show-mapc
1752    (lambda ()
1753      (let* ((current-tags (notmuch-show-get-tags))
1754             (new-tags (notmuch-update-tags current-tags tag-changes)))
1755        (unless (equal current-tags new-tags)
1756          (notmuch-show-set-tags new-tags))))))
1757
1758 (defun notmuch-show-add-tag ()
1759   "Same as `notmuch-show-tag' but sets initial input to '+'."
1760   (interactive)
1761   (notmuch-show-tag "+"))
1762
1763 (defun notmuch-show-remove-tag ()
1764   "Same as `notmuch-show-tag' but sets initial input to '-'."
1765   (interactive)
1766   (notmuch-show-tag "-"))
1767
1768 (defun notmuch-show-toggle-visibility-headers ()
1769   "Toggle the visibility of the current message headers."
1770   (interactive)
1771   (let ((props (notmuch-show-get-message-properties)))
1772     (notmuch-show-headers-visible
1773      props
1774      (not (plist-get props :headers-visible))))
1775   (force-window-update))
1776
1777 (defun notmuch-show-toggle-message ()
1778   "Toggle the visibility of the current message."
1779   (interactive)
1780   (let ((props (notmuch-show-get-message-properties)))
1781     (notmuch-show-message-visible
1782      props
1783      (not (plist-get props :message-visible))))
1784   (force-window-update))
1785
1786 (defun notmuch-show-open-or-close-all ()
1787   "Set the visibility all of the messages in the current thread.
1788 By default make all of the messages visible. With a prefix
1789 argument, hide all of the messages."
1790   (interactive)
1791   (save-excursion
1792     (goto-char (point-min))
1793     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1794                                            (not current-prefix-arg))
1795           until (not (notmuch-show-goto-message-next))))
1796   (force-window-update))
1797
1798 (defun notmuch-show-next-button ()
1799   "Advance point to the next button in the buffer."
1800   (interactive)
1801   (forward-button 1))
1802
1803 (defun notmuch-show-previous-button ()
1804   "Move point back to the previous button in the buffer."
1805   (interactive)
1806   (backward-button 1))
1807
1808 (defun notmuch-show-next-thread (&optional show previous)
1809   "Move to the next item in the search results, if any.
1810
1811 If SHOW is non-nil, open the next item in a show
1812 buffer. Otherwise just highlight the next item in the search
1813 buffer. If PREVIOUS is non-nil, move to the previous item in the
1814 search results instead."
1815   (interactive "P")
1816   (let ((parent-buffer notmuch-show-parent-buffer))
1817     (notmuch-kill-this-buffer)
1818     (when (buffer-live-p parent-buffer)
1819       (switch-to-buffer parent-buffer)
1820       (and (if previous
1821                (notmuch-search-previous-thread)
1822              (notmuch-search-next-thread))
1823            show
1824            (notmuch-search-show-thread)))))
1825
1826 (defun notmuch-show-next-thread-show ()
1827   "Show the next thread in the search results, if any."
1828   (interactive)
1829   (notmuch-show-next-thread t))
1830
1831 (defun notmuch-show-previous-thread-show ()
1832   "Show the previous thread in the search results, if any."
1833   (interactive)
1834   (notmuch-show-next-thread t t))
1835
1836 (defun notmuch-show-archive-thread (&optional unarchive)
1837   "Archive each message in thread.
1838
1839 Archive each message currently shown by applying the tag changes
1840 in `notmuch-archive-tags' to each. If a prefix argument is given,
1841 the messages will be \"unarchived\", i.e. the tag changes in
1842 `notmuch-archive-tags' will be reversed.
1843
1844 Note: This command is safe from any race condition of new messages
1845 being delivered to the same thread. It does not archive the
1846 entire thread, but only the messages shown in the current
1847 buffer."
1848   (interactive "P")
1849   (when notmuch-archive-tags
1850     (notmuch-show-tag-all
1851      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1852
1853 (defun notmuch-show-archive-thread-then-next ()
1854   "Archive all messages in the current buffer, then show next thread from search."
1855   (interactive)
1856   (notmuch-show-archive-thread)
1857   (notmuch-show-next-thread t))
1858
1859 (defun notmuch-show-archive-thread-then-exit ()
1860   "Archive all messages in the current buffer, then exit back to search results."
1861   (interactive)
1862   (notmuch-show-archive-thread)
1863   (notmuch-show-next-thread))
1864
1865 (defun notmuch-show-archive-message (&optional unarchive)
1866   "Archive the current message.
1867
1868 Archive the current message by applying the tag changes in
1869 `notmuch-archive-tags' to it. If a prefix argument is given, the
1870 message will be \"unarchived\", i.e. the tag changes in
1871 `notmuch-archive-tags' will be reversed."
1872   (interactive "P")
1873   (when notmuch-archive-tags
1874     (apply 'notmuch-show-tag-message
1875            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1876
1877 (defun notmuch-show-archive-message-then-next-or-exit ()
1878   "Archive the current message, then show the next open message in the current thread.
1879
1880 If at the last open message in the current thread, then exit back
1881 to search results."
1882   (interactive)
1883   (notmuch-show-archive-message)
1884   (notmuch-show-next-open-message t))
1885
1886 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1887   "Archive the current message, then show the next open message in the current thread.
1888
1889 If at the last open message in the current thread, then show next
1890 thread from search."
1891   (interactive)
1892   (notmuch-show-archive-message)
1893   (unless (notmuch-show-next-open-message)
1894     (notmuch-show-next-thread t)))
1895
1896 (defun notmuch-show-stash-cc ()
1897   "Copy CC field of current message to kill-ring."
1898   (interactive)
1899   (notmuch-common-do-stash (notmuch-show-get-cc)))
1900
1901 (defun notmuch-show-stash-date ()
1902   "Copy date of current message to kill-ring."
1903   (interactive)
1904   (notmuch-common-do-stash (notmuch-show-get-date)))
1905
1906 (defun notmuch-show-stash-filename ()
1907   "Copy filename of current message to kill-ring."
1908   (interactive)
1909   (notmuch-common-do-stash (notmuch-show-get-filename)))
1910
1911 (defun notmuch-show-stash-from ()
1912   "Copy From address of current message to kill-ring."
1913   (interactive)
1914   (notmuch-common-do-stash (notmuch-show-get-from)))
1915
1916 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
1917   "Copy id: query matching the current message to kill-ring.
1918
1919 If invoked with a prefix argument (or STASH-THREAD-ID is
1920 non-nil), copy thread: query matching the current thread to
1921 kill-ring."
1922   (interactive "P")
1923   (if stash-thread-id
1924       (notmuch-common-do-stash notmuch-show-thread-id)
1925     (notmuch-common-do-stash (notmuch-show-get-message-id))))
1926
1927 (defun notmuch-show-stash-message-id-stripped ()
1928   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1929   (interactive)
1930   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1931
1932 (defun notmuch-show-stash-subject ()
1933   "Copy Subject field of current message to kill-ring."
1934   (interactive)
1935   (notmuch-common-do-stash (notmuch-show-get-subject)))
1936
1937 (defun notmuch-show-stash-tags ()
1938   "Copy tags of current message to kill-ring as a comma separated list."
1939   (interactive)
1940   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1941
1942 (defun notmuch-show-stash-to ()
1943   "Copy To address of current message to kill-ring."
1944   (interactive)
1945   (notmuch-common-do-stash (notmuch-show-get-to)))
1946
1947 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1948   "Copy an ML Archive URI for the current message to the kill-ring.
1949
1950 This presumes that the message is available at the selected Mailing List Archive.
1951
1952 If optional argument MLA is non-nil, use the provided key instead of prompting
1953 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1954   (interactive)
1955   (notmuch-common-do-stash
1956    (concat (cdr (assoc
1957                  (or mla
1958                      (let ((completion-ignore-case t))
1959                        (completing-read
1960                         "Mailing List Archive: "
1961                         notmuch-show-stash-mlarchive-link-alist
1962                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1963                  notmuch-show-stash-mlarchive-link-alist))
1964            (notmuch-show-get-message-id t))))
1965
1966 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1967   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1968
1969 This presumes that the message is available at the selected Mailing List Archive.
1970
1971 If optional argument MLA is non-nil, use the provided key instead of prompting
1972 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1973   (interactive)
1974   (notmuch-show-stash-mlarchive-link mla)
1975   (browse-url (current-kill 0 t)))
1976
1977 ;; Interactive part functions and their helpers
1978
1979 (defun notmuch-show-generate-part-buffer (message-id nth)
1980   "Return a temporary buffer containing the specified part's content."
1981   (let ((buf (generate-new-buffer " *notmuch-part*"))
1982         (process-crypto notmuch-show-process-crypto))
1983     (with-current-buffer buf
1984       (setq notmuch-show-process-crypto process-crypto)
1985       ;; Always acquires the part via `notmuch part', even if it is
1986       ;; available in the JSON output.
1987       (insert (notmuch-get-bodypart-internal message-id nth notmuch-show-process-crypto)))
1988     buf))
1989
1990 (defun notmuch-show-current-part-handle ()
1991   "Return an mm-handle for the part containing point.
1992
1993 This creates a temporary buffer for the part's content; the
1994 caller is responsible for killing this buffer as appropriate."
1995   (let* ((part (notmuch-show-get-part-properties))
1996          (message-id (notmuch-show-get-message-id))
1997          (nth (plist-get part :id))
1998          (buf (notmuch-show-generate-part-buffer message-id nth))
1999          (content-type (plist-get part :content-type))
2000          (filename (plist-get part :filename))
2001          (disposition (if filename `(attachment (filename . ,filename)))))
2002     (mm-make-handle buf (list content-type) nil nil disposition)))
2003
2004 (defun notmuch-show-apply-to-current-part-handle (fn)
2005   "Apply FN to an mm-handle for the part containing point.
2006
2007 This ensures that the temporary buffer created for the mm-handle
2008 is destroyed when FN returns."
2009   (let ((handle (notmuch-show-current-part-handle)))
2010     (unwind-protect
2011         (funcall fn handle)
2012       (kill-buffer (mm-handle-buffer handle)))))
2013
2014 (defun notmuch-show-part-button-default (&optional button)
2015   (interactive)
2016   (let ((button (or button (button-at (point)))))
2017     (if (button-get button 'overlay)
2018         (notmuch-show-toggle-part-invisibility button)
2019       (call-interactively notmuch-show-part-button-default-action))))
2020
2021 (defun notmuch-show-save-part ()
2022   "Save the MIME part containing point to a file."
2023   (interactive)
2024   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2025
2026 (defun notmuch-show-view-part ()
2027   "View the MIME part containing point in an external viewer."
2028   (interactive)
2029   ;; Set mm-inlined-types to nil to force an external viewer
2030   (let ((mm-inlined-types nil))
2031     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2032
2033 (defun notmuch-show-interactively-view-part ()
2034   "View the MIME part containing point, prompting for a viewer."
2035   (interactive)
2036   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2037
2038 (defun notmuch-show-pipe-part ()
2039   "Pipe the MIME part containing point to an external command."
2040   (interactive)
2041   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2042
2043
2044 (provide 'notmuch-show)