git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-fontify-headers "notmuch" nil)
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts t
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ;; FIXME: can these services be searched by `Message-Id' ?
 162     ;; ("MarkMail" . "http://markmail.org/")
 163     ;; ("Nabble" . "http://nabble.com/")
 164     ;; ("opensubscriber" . "http://opensubscriber.com/")
 165     )
 166   "List of Mailing List Archives to use when stashing links.
 167
 168 These URIs are concatenated with the current message's
 169 Message-Id in `notmuch-show-stash-mlarchive-link'."
 170   :type '(alist :key-type (string :tag "Name")
 171                 :value-type (string :tag "URL"))
 172   :group 'notmuch-show)
 173
 174 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 175   "Default Mailing List Archive to use when stashing links.
 176
 177 This is used when `notmuch-show-stash-mlarchive-link' isn't
 178 provided with an MLA argument nor `completing-read' input."
 179   :type `(choice
 180           ,@(mapcar
 181              (lambda (mla)
 182                (list 'const :tag (car mla) :value (car mla)))
 183              notmuch-show-stash-mlarchive-link-alist))
 184   :group 'notmuch-show)
 185
 186 (defcustom notmuch-show-mark-read-tags '("-unread")
 187   "List of tag changes to apply to a message when it is marked as read.
 188
 189 Tags starting with \"+\" (or not starting with either \"+\" or
 190 \"-\") in the list will be added, and tags starting with \"-\"
 191 will be removed from the message being marked as read.
 192
 193 For example, if you wanted to remove an \"unread\" tag and add a
 194 \"read\" tag (which would make little sense), you would set:
 195     (\"-unread\" \"+read\")"
 196   :type '(repeat string)
 197   :group 'notmuch-show)
 198
 199
 200 (defmacro with-current-notmuch-show-message (&rest body)
 201   "Evaluate body with current buffer set to the text of current message"
 202   `(save-excursion
 203      (let ((id (notmuch-show-get-message-id)))
 204        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 205          (with-current-buffer buf
 206             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 207            ,@body)
 208          (kill-buffer buf)))))
 209
 210 (defun notmuch-show-turn-on-visual-line-mode ()
 211   "Enable Visual Line mode."
 212   (visual-line-mode t))
 213
 214 (defun notmuch-show-view-all-mime-parts ()
 215   "Use external viewers to view all attachments from the current message."
 216   (interactive)
 217   (with-current-notmuch-show-message
 218    ;; We override the mm-inline-media-tests to indicate which message
 219    ;; parts are already sufficiently handled by the original
 220    ;; presentation of the message in notmuch-show mode. These parts
 221    ;; will be inserted directly into the temporary buffer of
 222    ;; with-current-notmuch-show-message and silently discarded.
 223    ;;
 224    ;; Any MIME part not explicitly mentioned here will be handled by an
 225    ;; external viewer as configured in the various mailcap files.
 226    (let ((mm-inline-media-tests '(
 227                                   ("text/.*" ignore identity)
 228                                   ("application/pgp-signature" ignore identity)
 229                                   ("multipart/alternative" ignore identity)
 230                                   ("multipart/mixed" ignore identity)
 231                                   ("multipart/related" ignore identity)
 232                                  )))
 233      (mm-display-parts (mm-dissect-buffer)))))
 234
 235 (defun notmuch-foreach-mime-part (function mm-handle)
 236   (cond ((stringp (car mm-handle))
 237          (dolist (part (cdr mm-handle))
 238            (notmuch-foreach-mime-part function part)))
 239         ((bufferp (car mm-handle))
 240          (funcall function mm-handle))
 241         (t (dolist (part mm-handle)
 242              (notmuch-foreach-mime-part function part)))))
 243
 244 (defun notmuch-count-attachments (mm-handle)
 245   (let ((count 0))
 246     (notmuch-foreach-mime-part
 247      (lambda (p)
 248        (let ((disposition (mm-handle-disposition p)))
 249          (and (listp disposition)
 250               (or (equal (car disposition) "attachment")
 251                   (and (equal (car disposition) "inline")
 252                        (assq 'filename disposition)))
 253               (incf count))))
 254      mm-handle)
 255     count))
 256
 257 (defun notmuch-save-attachments (mm-handle &optional queryp)
 258   (notmuch-foreach-mime-part
 259    (lambda (p)
 260      (let ((disposition (mm-handle-disposition p)))
 261        (and (listp disposition)
 262             (or (equal (car disposition) "attachment")
 263                 (and (equal (car disposition) "inline")
 264                      (assq 'filename disposition)))
 265             (or (not queryp)
 266                 (y-or-n-p
 267                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 268             (mm-save-part p))))
 269    mm-handle))
 270
 271 (defun notmuch-show-save-attachments ()
 272   "Save all attachments from the current message."
 273   (interactive)
 274   (with-current-notmuch-show-message
 275    (let ((mm-handle (mm-dissect-buffer)))
 276      (notmuch-save-attachments
 277       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 278   (message "Done"))
 279
 280 (defun notmuch-show-with-message-as-text (fn)
 281   "Apply FN to a text representation of the current message.
 282
 283 FN is called with one argument, the message properties. It should
 284 operation on the contents of the current buffer."
 285
 286   ;; Remake the header to ensure that all information is available.
 287   (let* ((to (notmuch-show-get-to))
 288          (cc (notmuch-show-get-cc))
 289          (from (notmuch-show-get-from))
 290          (subject (notmuch-show-get-subject))
 291          (date (notmuch-show-get-date))
 292          (tags (notmuch-show-get-tags))
 293          (depth (notmuch-show-get-depth))
 294
 295          (header (concat
 296                   "Subject: " subject "\n"
 297                   "To: " to "\n"
 298                   (if (not (string= cc ""))
 299                       (concat "Cc: " cc "\n")
 300                     "")
 301                   "From: " from "\n"
 302                   "Date: " date "\n"
 303                   (if tags
 304                       (concat "Tags: "
 305                               (mapconcat #'identity tags ", ") "\n")
 306                     "")))
 307          (all (buffer-substring (notmuch-show-message-top)
 308                                 (notmuch-show-message-bottom)))
 309
 310          (props (notmuch-show-get-message-properties))
 311          (indenting notmuch-show-indent-content))
 312     (with-temp-buffer
 313       (insert all)
 314       (if indenting
 315           (indent-rigidly (point-min) (point-max) (- depth)))
 316       ;; Remove the original header.
 317       (goto-char (point-min))
 318       (re-search-forward "^$" (point-max) nil)
 319       (delete-region (point-min) (point))
 320       (insert header)
 321       (funcall fn props))))
 322
 323 (defun notmuch-show-print-message ()
 324   "Print the current message."
 325   (interactive)
 326   (notmuch-show-with-message-as-text 'notmuch-print-message))
 327
 328 (defun notmuch-show-fontify-header ()
 329   (let ((face (cond
 330                ((looking-at "[Tt]o:")
 331                 'message-header-to)
 332                ((looking-at "[Bb]?[Cc][Cc]:")
 333                 'message-header-cc)
 334                ((looking-at "[Ss]ubject:")
 335                 'message-header-subject)
 336                ((looking-at "[Ff]rom:")
 337                 'message-header-from)
 338                (t
 339                 'message-header-other))))
 340
 341     (overlay-put (make-overlay (point) (re-search-forward ":"))
 342                  'face 'message-header-name)
 343     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 344                  'face face)))
 345
 346 (defun notmuch-show-colour-headers ()
 347   "Apply some colouring to the current headers."
 348   (goto-char (point-min))
 349   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 350     (notmuch-show-fontify-header)
 351     (forward-line)))
 352
 353 (defun notmuch-show-spaces-n (n)
 354   "Return a string comprised of `n' spaces."
 355   (make-string n ? ))
 356
 357 (defun notmuch-show-update-tags (tags)
 358   "Update the displayed tags of the current message."
 359   (save-excursion
 360     (goto-char (notmuch-show-message-top))
 361     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 362         (let ((inhibit-read-only t))
 363           (replace-match (concat "("
 364                                  (propertize (mapconcat 'identity tags " ")
 365                                              'face 'notmuch-tag-face)
 366                                  ")"))))))
 367
 368 (defun notmuch-show-clean-address (address)
 369   "Try to clean a single email ADDRESS for display.  Return
 370 unchanged ADDRESS if parsing fails."
 371   (condition-case nil
 372     (let (p-name p-address)
 373       ;; It would be convenient to use `mail-header-parse-address',
 374       ;; but that expects un-decoded mailbox parts, whereas our
 375       ;; mailbox parts are already decoded (and hence may contain
 376       ;; UTF-8). Given that notmuch should handle most of the awkward
 377       ;; cases, some simple string deconstruction should be sufficient
 378       ;; here.
 379       (cond
 380        ;; "User <user@dom.ain>" style.
 381        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 382         (setq p-name (match-string 1 address)
 383               p-address (match-string 2 address)))
 384
 385        ;; "<user@dom.ain>" style.
 386        ((string-match "<\\(.*\\)>" address)
 387         (setq p-address (match-string 1 address)))
 388
 389        ;; Everything else.
 390        (t
 391         (setq p-address address)))
 392
 393       (when p-name
 394         ;; Remove elements of the mailbox part that are not relevant for
 395         ;; display, even if they are required during transport:
 396         ;;
 397         ;; Backslashes.
 398         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 399
 400         ;; Outer single and double quotes, which might be nested.
 401         (loop
 402          with start-of-loop
 403          do (setq start-of-loop p-name)
 404
 405          when (string-match "^\"\\(.*\\)\"$" p-name)
 406          do (setq p-name (match-string 1 p-name))
 407
 408          when (string-match "^'\\(.*\\)'$" p-name)
 409          do (setq p-name (match-string 1 p-name))
 410
 411          until (string= start-of-loop p-name)))
 412
 413       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 414       ;; 'foo@bar.com'.
 415       (when (string= p-name p-address)
 416         (setq p-name nil))
 417
 418       ;; If no name results, return just the address.
 419       (if (not p-name)
 420           p-address
 421         ;; Otherwise format the name and address together.
 422         (concat p-name " <" p-address ">")))
 423     (error address)))
 424
 425 (defun notmuch-show-insert-headerline (headers date tags depth)
 426   "Insert a notmuch style headerline based on HEADERS for a
 427 message at DEPTH in the current thread."
 428   (let ((start (point)))
 429     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 430             (notmuch-show-clean-address (plist-get headers :From))
 431             " ("
 432             date
 433             ") ("
 434             (propertize (mapconcat 'identity tags " ")
 435                         'face 'notmuch-tag-face)
 436             ")\n")
 437     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 438
 439 (defun notmuch-show-insert-header (header header-value)
 440   "Insert a single header."
 441   (insert header ": " header-value "\n"))
 442
 443 (defun notmuch-show-insert-headers (headers)
 444   "Insert the headers of the current message."
 445   (let ((start (point)))
 446     (mapc (lambda (header)
 447             (let* ((header-symbol (intern (concat ":" header)))
 448                    (header-value (plist-get headers header-symbol)))
 449               (if (and header-value
 450                        (not (string-equal "" header-value)))
 451                   (notmuch-show-insert-header header header-value))))
 452           notmuch-message-headers)
 453     (save-excursion
 454       (save-restriction
 455         (narrow-to-region start (point-max))
 456         (run-hooks 'notmuch-show-markup-headers-hook)))))
 457
 458 (define-button-type 'notmuch-show-part-button-type
 459   'action 'notmuch-show-part-button-default
 460   'keymap 'notmuch-show-part-button-map
 461   'follow-link t
 462   'face 'message-mml)
 463
 464 (defvar notmuch-show-part-button-map
 465   (let ((map (make-sparse-keymap)))
 466     (set-keymap-parent map button-map)
 467     (define-key map "s" 'notmuch-show-part-button-save)
 468     (define-key map "v" 'notmuch-show-part-button-view)
 469     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 470     (define-key map "|" 'notmuch-show-part-button-pipe)
 471     map)
 472   "Submap for button commands")
 473 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 474
 475 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 476   (let ((button))
 477     (setq button
 478           (insert-button
 479            (concat "[ "
 480                    (if name (concat name ": ") "")
 481                    declared-type
 482                    (if (not (string-equal declared-type content-type))
 483                        (concat " (as " content-type ")")
 484                      "")
 485                    (or comment "")
 486                    " ]")
 487            :type 'notmuch-show-part-button-type
 488            :notmuch-part nth
 489            :notmuch-filename name
 490            :notmuch-content-type content-type))
 491     (insert "\n")
 492     ;; return button
 493     button))
 494
 495 ;; Functions handling particular MIME parts.
 496
 497 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 498   (declare (indent 2))
 499   (let ((process-crypto (make-symbol "process-crypto")))
 500     `(let ((,process-crypto notmuch-show-process-crypto))
 501        (with-temp-buffer
 502          (setq notmuch-show-process-crypto ,process-crypto)
 503          ;; Always acquires the part via `notmuch part', even if it is
 504          ;; available in the JSON output.
 505          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 506          ,@body))))
 507
 508 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 509   (notmuch-with-temp-part-buffer message-id nth
 510     (let ((file (read-file-name
 511                  "Filename to save as: "
 512                  (or mailcap-download-directory "~/")
 513                  nil nil
 514                  filename)))
 515       ;; Don't re-compress .gz & al.  Arguably we should make
 516       ;; `file-name-handler-alist' nil, but that would chop
 517       ;; ange-ftp, which is reasonable to use here.
 518       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 519
 520 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 521   (notmuch-with-temp-part-buffer message-id nth
 522     ;; set mm-inlined-types to nil to force an external viewer
 523     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 524           (mm-inlined-types nil))
 525       ;; We override mm-save-part as notmuch-show-save-part is better
 526       ;; since it offers the filename. We need to lexically bind
 527       ;; everything we need for notmuch-show-save-part to prevent
 528       ;; potential dynamic shadowing.
 529       (lexical-let ((message-id message-id)
 530                     (nth nth)
 531                     (filename filename)
 532                     (content-type content-type))
 533         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 534                                            message-id nth filename content-type)))
 535           (mm-display-part handle))))))
 536
 537 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 538   (notmuch-with-temp-part-buffer message-id nth
 539     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 540       (mm-interactively-view-part handle))))
 541
 542 (defun notmuch-show-pipe-part (message-id nth &optional filename content-type)
 543   (notmuch-with-temp-part-buffer message-id nth
 544     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 545       (mm-pipe-part handle))))
 546
 547 (defun notmuch-show-multipart/*-to-list (part)
 548   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 549           (plist-get part :content)))
 550
 551 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 552   (notmuch-show-insert-part-header nth declared-type content-type nil)
 553   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 554         (inner-parts (plist-get part :content))
 555         (start (point)))
 556     ;; This inserts all parts of the chosen type rather than just one,
 557     ;; but it's not clear that this is the wrong thing to do - which
 558     ;; should be chosen if there are more than one that match?
 559     (mapc (lambda (inner-part)
 560             (let ((inner-type (plist-get inner-part :content-type)))
 561               (if (or notmuch-show-all-multipart/alternative-parts
 562                       (string= chosen-type inner-type))
 563                   (notmuch-show-insert-bodypart msg inner-part depth)
 564                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 565           inner-parts)
 566
 567     (when notmuch-show-indent-multipart
 568       (indent-rigidly start (point) 1)))
 569   t)
 570
 571 (defun notmuch-show-setup-w3m ()
 572   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 573   (interactive)
 574   (if (boundp 'w3m-cid-retrieve-function-alist)
 575     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 576       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 577             w3m-cid-retrieve-function-alist)))
 578   (setq mm-inline-text-html-with-images t))
 579
 580 (defvar w3m-current-buffer) ;; From `w3m.el'.
 581 (defvar notmuch-show-w3m-cid-store nil)
 582 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 583
 584 (defun notmuch-show-w3m-cid-store-internal (content-id
 585                                             message-id
 586                                             part-number
 587                                             content-type
 588                                             content)
 589   (push (list content-id
 590               message-id
 591               part-number
 592               content-type
 593               content)
 594         notmuch-show-w3m-cid-store))
 595
 596 (defun notmuch-show-w3m-cid-store (msg part)
 597   (let ((content-id (plist-get part :content-id)))
 598     (when content-id
 599       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 600                                            (plist-get msg :id)
 601                                            (plist-get part :id)
 602                                            (plist-get part :content-type)
 603                                            nil))))
 604
 605 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 606   (let ((matching-part (with-current-buffer w3m-current-buffer
 607                          (assoc url notmuch-show-w3m-cid-store))))
 608     (if matching-part
 609         (let ((message-id (nth 1 matching-part))
 610               (part-number (nth 2 matching-part))
 611               (content-type (nth 3 matching-part))
 612               (content (nth 4 matching-part)))
 613           ;; If we don't already have the content, get it and cache
 614           ;; it, as some messages reference the same cid: part many
 615           ;; times (hundreds!), which results in many calls to
 616           ;; `notmuch part'.
 617           (unless content
 618             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 619                                                               part-number notmuch-show-process-crypto))
 620             (with-current-buffer w3m-current-buffer
 621               (notmuch-show-w3m-cid-store-internal url
 622                                                    message-id
 623                                                    part-number
 624                                                    content-type
 625                                                    content)))
 626           (insert content)
 627           content-type)
 628       nil)))
 629
 630 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 631   (notmuch-show-insert-part-header nth declared-type content-type nil)
 632   (let ((inner-parts (plist-get part :content))
 633         (start (point)))
 634
 635     ;; We assume that the first part is text/html and the remainder
 636     ;; things that it references.
 637
 638     ;; Stash the non-primary parts.
 639     (mapc (lambda (part)
 640             (notmuch-show-w3m-cid-store msg part))
 641           (cdr inner-parts))
 642
 643     ;; Render the primary part.
 644     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 645
 646     (when notmuch-show-indent-multipart
 647       (indent-rigidly start (point) 1)))
 648   t)
 649
 650 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 651   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 652     (button-put button 'face 'notmuch-crypto-part-header)
 653     ;; add signature status button if sigstatus provided
 654     (if (plist-member part :sigstatus)
 655         (let* ((from (notmuch-show-get-header :From msg))
 656                (sigstatus (car (plist-get part :sigstatus))))
 657           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 658       ;; if we're not adding sigstatus, tell the user how they can get it
 659       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 660
 661   (let ((inner-parts (plist-get part :content))
 662         (start (point)))
 663     ;; Show all of the parts.
 664     (mapc (lambda (inner-part)
 665             (notmuch-show-insert-bodypart msg inner-part depth))
 666           inner-parts)
 667
 668     (when notmuch-show-indent-multipart
 669       (indent-rigidly start (point) 1)))
 670   t)
 671
 672 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 673   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 674     (button-put button 'face 'notmuch-crypto-part-header)
 675     ;; add encryption status button if encstatus specified
 676     (if (plist-member part :encstatus)
 677         (let ((encstatus (car (plist-get part :encstatus))))
 678           (notmuch-crypto-insert-encstatus-button encstatus)
 679           ;; add signature status button if sigstatus specified
 680           (if (plist-member part :sigstatus)
 681               (let* ((from (notmuch-show-get-header :From msg))
 682                      (sigstatus (car (plist-get part :sigstatus))))
 683                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 684       ;; if we're not adding encstatus, tell the user how they can get it
 685       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 686
 687   (let ((inner-parts (plist-get part :content))
 688         (start (point)))
 689     ;; Show all of the parts.
 690     (mapc (lambda (inner-part)
 691             (notmuch-show-insert-bodypart msg inner-part depth))
 692           inner-parts)
 693
 694     (when notmuch-show-indent-multipart
 695       (indent-rigidly start (point) 1)))
 696   t)
 697
 698 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 699   (notmuch-show-insert-part-header nth declared-type content-type nil)
 700   (let ((inner-parts (plist-get part :content))
 701         (start (point)))
 702     ;; Show all of the parts.
 703     (mapc (lambda (inner-part)
 704             (notmuch-show-insert-bodypart msg inner-part depth))
 705           inner-parts)
 706
 707     (when notmuch-show-indent-multipart
 708       (indent-rigidly start (point) 1)))
 709   t)
 710
 711 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 712   (notmuch-show-insert-part-header nth declared-type content-type nil)
 713   (let* ((message (car (plist-get part :content)))
 714          (body (car (plist-get message :body)))
 715          (start (point)))
 716
 717     ;; Override `notmuch-message-headers' to force `From' to be
 718     ;; displayed.
 719     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 720       (notmuch-show-insert-headers (plist-get message :headers)))
 721
 722     ;; Blank line after headers to be compatible with the normal
 723     ;; message display.
 724     (insert "\n")
 725
 726     ;; Show the body
 727     (notmuch-show-insert-bodypart msg body depth)
 728
 729     (when notmuch-show-indent-multipart
 730       (indent-rigidly start (point) 1)))
 731   t)
 732
 733 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 734   (let ((start (point)))
 735     ;; If this text/plain part is not the first part in the message,
 736     ;; insert a header to make this clear.
 737     (if (> nth 1)
 738         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 739     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 740     (save-excursion
 741       (save-restriction
 742         (narrow-to-region start (point-max))
 743         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 744   t)
 745
 746 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 747   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 748   (insert (with-temp-buffer
 749             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 750             (goto-char (point-min))
 751             (let ((file (make-temp-file "notmuch-ical"))
 752                   result)
 753               (icalendar--convert-ical-to-diary
 754                (icalendar--read-element nil nil)
 755                file t)
 756               (set-buffer (get-file-buffer file))
 757               (setq result (buffer-substring (point-min) (point-max)))
 758               (set-buffer-modified-p nil)
 759               (kill-buffer (current-buffer))
 760               (delete-file file)
 761               result)))
 762   t)
 763
 764 ;; For backwards compatibility.
 765 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 766   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 767
 768 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 769   ;; If we can deduce a MIME type from the filename of the attachment,
 770   ;; do so and pass it on to the handler for that type.
 771   (if (plist-get part :filename)
 772       (let ((extension (file-name-extension (plist-get part :filename)))
 773             mime-type)
 774         (if extension
 775             (progn
 776               (mailcap-parse-mimetypes)
 777               (setq mime-type (mailcap-extension-to-mime extension))
 778               (if (and mime-type
 779                        (not (string-equal mime-type "application/octet-stream")))
 780                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 781                 nil))
 782           nil))))
 783
 784 ;; Handler for wash generated inline patch fake parts.
 785 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 786   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 787
 788 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 789   ;; This handler _must_ succeed - it is the handler of last resort.
 790   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 791   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 792   t)
 793
 794 ;; Functions for determining how to handle MIME parts.
 795
 796 (defun notmuch-show-handlers-for (content-type)
 797   "Return a list of content handlers for a part of type CONTENT-TYPE."
 798   (let (result)
 799     (mapc (lambda (func)
 800             (if (functionp func)
 801                 (push func result)))
 802           ;; Reverse order of prefrence.
 803           (list (intern (concat "notmuch-show-insert-part-*/*"))
 804                 (intern (concat
 805                          "notmuch-show-insert-part-"
 806                          (car (notmuch-split-content-type content-type))
 807                          "/*"))
 808                 (intern (concat "notmuch-show-insert-part-" content-type))))
 809     result))
 810
 811 ;; \f
 812
 813 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 814   (let ((handlers (notmuch-show-handlers-for content-type)))
 815     ;; Run the content handlers until one of them returns a non-nil
 816     ;; value.
 817     (while (and handlers
 818                 (not (condition-case err
 819                          (funcall (car handlers) msg part content-type nth depth declared-type)
 820                        (error (progn
 821                                 (insert "!!! Bodypart insert error: ")
 822                                 (insert (error-message-string err))
 823                                 (insert " !!!\n") nil)))))
 824       (setq handlers (cdr handlers))))
 825   t)
 826
 827 (defun notmuch-show-insert-bodypart (msg part depth)
 828   "Insert the body part PART at depth DEPTH in the current thread."
 829   (let ((content-type (downcase (plist-get part :content-type)))
 830         (nth (plist-get part :id)))
 831     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 832   ;; Some of the body part handlers leave point somewhere up in the
 833   ;; part, so we make sure that we're down at the end.
 834   (goto-char (point-max))
 835   ;; Ensure that the part ends with a carriage return.
 836   (unless (bolp)
 837     (insert "\n")))
 838
 839 (defun notmuch-show-insert-body (msg body depth)
 840   "Insert the body BODY at depth DEPTH in the current thread."
 841   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 842
 843 (defun notmuch-show-make-symbol (type)
 844   (make-symbol (concat "notmuch-show-" type)))
 845
 846 (defun notmuch-show-strip-re (string)
 847   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 848
 849 (defvar notmuch-show-previous-subject "")
 850 (make-variable-buffer-local 'notmuch-show-previous-subject)
 851
 852 (defun notmuch-show-insert-msg (msg depth)
 853   "Insert the message MSG at depth DEPTH in the current thread."
 854   (let* ((headers (plist-get msg :headers))
 855          ;; Indentation causes the buffer offset of the start/end
 856          ;; points to move, so we must use markers.
 857          message-start message-end
 858          content-start content-end
 859          headers-start headers-end
 860          body-start body-end
 861          (headers-invis-spec (notmuch-show-make-symbol "header"))
 862          (message-invis-spec (notmuch-show-make-symbol "message"))
 863          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 864
 865     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 866     ;; removing items from `buffer-invisibility-spec' (which is what
 867     ;; `notmuch-show-headers-visible' and
 868     ;; `notmuch-show-message-visible' do) is a no-op and has no
 869     ;; effect. This caused threads with only matching messages to have
 870     ;; those messages hidden initially because
 871     ;; `buffer-invisibility-spec' stayed `t'.
 872     ;;
 873     ;; This needs to be set here (rather than just above the call to
 874     ;; `notmuch-show-headers-visible') because some of the part
 875     ;; rendering or body washing functions
 876     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 877     ;; `buffer-invisibility-spec').
 878     (when (eq buffer-invisibility-spec t)
 879       (setq buffer-invisibility-spec nil))
 880
 881     (setq message-start (point-marker))
 882
 883     (notmuch-show-insert-headerline headers
 884                                     (or (if notmuch-show-relative-dates
 885                                             (plist-get msg :date_relative)
 886                                           nil)
 887                                         (plist-get headers :Date))
 888                                     (plist-get msg :tags) depth)
 889
 890     (setq content-start (point-marker))
 891
 892     (plist-put msg :headers-invis-spec headers-invis-spec)
 893     (plist-put msg :message-invis-spec message-invis-spec)
 894
 895     ;; Set `headers-start' to point after the 'Subject:' header to be
 896     ;; compatible with the existing implementation. This just sets it
 897     ;; to after the first header.
 898     (notmuch-show-insert-headers headers)
 899     (save-excursion
 900       (goto-char content-start)
 901       ;; If the subject of this message is the same as that of the
 902       ;; previous message, don't display it when this message is
 903       ;; collapsed.
 904       (when (not (string= notmuch-show-previous-subject
 905                           bare-subject))
 906         (forward-line 1))
 907       (setq headers-start (point-marker)))
 908     (setq headers-end (point-marker))
 909
 910     (setq notmuch-show-previous-subject bare-subject)
 911
 912     (setq body-start (point-marker))
 913     ;; A blank line between the headers and the body.
 914     (insert "\n")
 915     (notmuch-show-insert-body msg (plist-get msg :body)
 916                               (if notmuch-show-indent-content depth 0))
 917     ;; Ensure that the body ends with a newline.
 918     (unless (bolp)
 919       (insert "\n"))
 920     (setq body-end (point-marker))
 921     (setq content-end (point-marker))
 922
 923     ;; Indent according to the depth in the thread.
 924     (if notmuch-show-indent-content
 925         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 926
 927     (setq message-end (point-max-marker))
 928
 929     ;; Save the extents of this message over the whole text of the
 930     ;; message.
 931     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 932
 933     (let ((headers-overlay (make-overlay headers-start headers-end))
 934           (invis-specs (list headers-invis-spec message-invis-spec)))
 935       (overlay-put headers-overlay 'invisible invis-specs)
 936       (overlay-put headers-overlay 'priority 10))
 937     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 938
 939     (plist-put msg :depth depth)
 940
 941     ;; Save the properties for this message. Currently this saves the
 942     ;; entire message (augmented it with other stuff), which seems
 943     ;; like overkill. We might save a reduced subset (for example, not
 944     ;; the content).
 945     (notmuch-show-set-message-properties msg)
 946
 947     ;; Set header visibility.
 948     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 949
 950     ;; Message visibility depends on whether it matched the search
 951     ;; criteria.
 952     (notmuch-show-message-visible msg (and (plist-get msg :match)
 953                                            (not (plist-get msg :excluded))))))
 954
 955 (defun notmuch-show-toggle-process-crypto ()
 956   "Toggle the processing of cryptographic MIME parts."
 957   (interactive)
 958   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 959   (message (if notmuch-show-process-crypto
 960                "Processing cryptographic MIME parts."
 961              "Not processing cryptographic MIME parts."))
 962   (notmuch-show-refresh-view))
 963
 964 (defun notmuch-show-toggle-elide-non-matching ()
 965   "Toggle the display of non-matching messages."
 966   (interactive)
 967   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 968   (message (if notmuch-show-elide-non-matching-messages
 969                "Showing matching messages only."
 970              "Showing all messages."))
 971   (notmuch-show-refresh-view))
 972
 973 (defun notmuch-show-toggle-thread-indentation ()
 974   "Toggle the indentation of threads."
 975   (interactive)
 976   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 977   (message (if notmuch-show-indent-content
 978                "Content is indented."
 979              "Content is not indented."))
 980   (notmuch-show-refresh-view))
 981
 982 (defun notmuch-show-insert-tree (tree depth)
 983   "Insert the message tree TREE at depth DEPTH in the current thread."
 984   (let ((msg (car tree))
 985         (replies (cadr tree)))
 986     ;; We test whether there is a message or just some replies.
 987     (when msg
 988       (notmuch-show-insert-msg msg depth))
 989     (notmuch-show-insert-thread replies (1+ depth))))
 990
 991 (defun notmuch-show-insert-thread (thread depth)
 992   "Insert the thread THREAD at depth DEPTH in the current forest."
 993   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 994
 995 (defun notmuch-show-insert-forest (forest)
 996   "Insert the forest of threads FOREST."
 997   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 998
 999 (defvar notmuch-id-regexp
1000   (concat
1001    ;; Match the id: prefix only if it begins a word (to disallow, for
1002    ;; example, matching cid:).
1003    "\\<id:\\("
1004    ;; If the term starts with a ", then parse Xapian's quoted boolean
1005    ;; term syntax, which allows for anything as long as embedded
1006    ;; double quotes escaped by doubling them.  We also disallow
1007    ;; newlines (which Xapian allows) to prevent runaway terms.
1008    "\"\\([^\"\n]\\|\"\"\\)*\""
1009    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1010    ;; next space or ).  We disallow [.,;] as the last character
1011    ;; because these are probably part of the surrounding text, and not
1012    ;; part of the id.  This doesn't match single character ids; meh.
1013    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1014    "\\)")
1015   "The regexp used to match id: links in messages.")
1016
1017 (defun notmuch-show-buttonise-links (start end)
1018   "Buttonise URLs and mail addresses between START and END.
1019
1020 This also turns id:\"<message id>\"-parts into buttons for
1021 a corresponding notmuch search."
1022   (goto-address-fontify-region start end)
1023   (save-excursion
1024     (goto-char start)
1025     (while (re-search-forward notmuch-id-regexp end t)
1026       ;; remove the overlay created by goto-address-mode
1027       (remove-overlays (match-beginning 0) (match-end 0) 'goto-address t)
1028       (make-text-button (match-beginning 0) (match-end 0)
1029                         'action `(lambda (arg)
1030                                    (notmuch-show ,(match-string-no-properties 0)))
1031                         'follow-link t
1032                         'help-echo "Mouse-1, RET: search for this message"
1033                         'face goto-address-mail-face))))
1034
1035 ;;;###autoload
1036 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1037   "Run \"notmuch show\" with the given thread ID and display results.
1038
1039 The optional PARENT-BUFFER is the notmuch-search buffer from
1040 which this notmuch-show command was executed, (so that the
1041 next thread from that buffer can be show when done with this
1042 one).
1043
1044 The optional QUERY-CONTEXT is a notmuch search term. Only
1045 messages from the thread matching this search term are shown if
1046 non-nil.
1047
1048 The optional BUFFER-NAME provides the name of the buffer in
1049 which the message thread is shown. If it is nil (which occurs
1050 when the command is called interactively) the argument to the
1051 function is used."
1052   (interactive "sNotmuch show: ")
1053   (let ((buffer-name (generate-new-buffer-name
1054                       (or buffer-name
1055                           (concat "*notmuch-" thread-id "*")))))
1056     (switch-to-buffer (get-buffer-create buffer-name))
1057     ;; Set the default value for `notmuch-show-process-crypto' in this
1058     ;; buffer.
1059     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1060     ;; Set the default value for
1061     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1062     ;; there is a prefix argument, invert the default.
1063     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1064     (if current-prefix-arg
1065         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1066
1067     (setq notmuch-show-thread-id thread-id
1068           notmuch-show-parent-buffer parent-buffer
1069           notmuch-show-query-context query-context)
1070     (notmuch-show-build-buffer)
1071     (notmuch-show-goto-first-wanted-message)
1072     (current-buffer)))
1073
1074 (defun notmuch-show-build-buffer ()
1075   (let ((inhibit-read-only t))
1076
1077     (notmuch-show-mode)
1078     ;; Don't track undo information for this buffer
1079     (set 'buffer-undo-list t)
1080
1081     (erase-buffer)
1082     (goto-char (point-min))
1083     (save-excursion
1084       (let* ((basic-args (list notmuch-show-thread-id))
1085              (args (if notmuch-show-query-context
1086                        (append (list "\'") basic-args
1087                                (list "and (" notmuch-show-query-context ")\'"))
1088                      (append (list "\'") basic-args (list "\'"))))
1089              (cli-args (cons "--exclude=false"
1090                              (when notmuch-show-elide-non-matching-messages
1091                                (list "--entire-thread=false")))))
1092
1093         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1094         ;; If the query context reduced the results to nothing, run
1095         ;; the basic query.
1096         (when (and (eq (buffer-size) 0)
1097                    notmuch-show-query-context)
1098           (notmuch-show-insert-forest
1099            (notmuch-query-get-threads (append cli-args basic-args)))))
1100
1101       (jit-lock-register #'notmuch-show-buttonise-links)
1102
1103       ;; Set the header line to the subject of the first message.
1104       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1105
1106       (run-hooks 'notmuch-show-hook))))
1107
1108 (defun notmuch-show-capture-state ()
1109   "Capture the state of the current buffer.
1110
1111 This includes:
1112  - the list of open messages,
1113  - the current message."
1114   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1115
1116 (defun notmuch-show-apply-state (state)
1117   "Apply STATE to the current buffer.
1118
1119 This includes:
1120  - opening the messages previously opened,
1121  - closing all other messages,
1122  - moving to the correct current message."
1123   (let ((current (car state))
1124         (open (cadr state)))
1125
1126     ;; Open those that were open.
1127     (goto-char (point-min))
1128     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1129                                            (member (notmuch-show-get-message-id) open))
1130           until (not (notmuch-show-goto-message-next)))
1131
1132     ;; Go to the previously open message.
1133     (goto-char (point-min))
1134     (unless (loop if (string= current (notmuch-show-get-message-id))
1135                   return t
1136                   until (not (notmuch-show-goto-message-next)))
1137       (goto-char (point-min))
1138       (message "Previously current message not found."))
1139     (notmuch-show-message-adjust)))
1140
1141 (defun notmuch-show-refresh-view (&optional reset-state)
1142   "Refresh the current view.
1143
1144 Refreshes the current view, observing changes in display
1145 preferences. If invoked with a prefix argument (or RESET-STATE is
1146 non-nil) then the state of the buffer (open/closed messages) is
1147 reset based on the original query."
1148   (interactive "P")
1149   (let ((inhibit-read-only t)
1150         (state (unless reset-state
1151                  (notmuch-show-capture-state))))
1152     (erase-buffer)
1153     (notmuch-show-build-buffer)
1154     (if state
1155         (notmuch-show-apply-state state)
1156       ;; We're resetting state, so navigate to the first open message
1157       ;; and mark it read, just like opening a new show buffer.
1158       (notmuch-show-goto-first-wanted-message))))
1159
1160 (defvar notmuch-show-stash-map
1161   (let ((map (make-sparse-keymap)))
1162     (define-key map "c" 'notmuch-show-stash-cc)
1163     (define-key map "d" 'notmuch-show-stash-date)
1164     (define-key map "F" 'notmuch-show-stash-filename)
1165     (define-key map "f" 'notmuch-show-stash-from)
1166     (define-key map "i" 'notmuch-show-stash-message-id)
1167     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1168     (define-key map "s" 'notmuch-show-stash-subject)
1169     (define-key map "T" 'notmuch-show-stash-tags)
1170     (define-key map "t" 'notmuch-show-stash-to)
1171     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1172     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1173     map)
1174   "Submap for stash commands")
1175 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1176
1177 (defvar notmuch-show-mode-map
1178       (let ((map (make-sparse-keymap)))
1179         (define-key map "?" 'notmuch-help)
1180         (define-key map "q" 'notmuch-kill-this-buffer)
1181         (define-key map (kbd "<C-tab>") 'widget-backward)
1182         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1183         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1184         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1185         (define-key map "s" 'notmuch-search)
1186         (define-key map "m" 'notmuch-mua-new-mail)
1187         (define-key map "f" 'notmuch-show-forward-message)
1188         (define-key map "r" 'notmuch-show-reply-sender)
1189         (define-key map "R" 'notmuch-show-reply)
1190         (define-key map "|" 'notmuch-show-pipe-message)
1191         (define-key map "w" 'notmuch-show-save-attachments)
1192         (define-key map "V" 'notmuch-show-view-raw-message)
1193         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1194         (define-key map "c" 'notmuch-show-stash-map)
1195         (define-key map "=" 'notmuch-show-refresh-view)
1196         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1197         (define-key map "*" 'notmuch-show-tag-all)
1198         (define-key map "-" 'notmuch-show-remove-tag)
1199         (define-key map "+" 'notmuch-show-add-tag)
1200         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1201         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1202         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1203         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1204         (define-key map "N" 'notmuch-show-next-message)
1205         (define-key map "P" 'notmuch-show-previous-message)
1206         (define-key map "n" 'notmuch-show-next-open-message)
1207         (define-key map "p" 'notmuch-show-previous-open-message)
1208         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1209         (define-key map " " 'notmuch-show-advance-and-archive)
1210         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1211         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1212         (define-key map "#" 'notmuch-show-print-message)
1213         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1214         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1215         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1216         (define-key map "t" 'toggle-truncate-lines)
1217         map)
1218       "Keymap for \"notmuch show\" buffers.")
1219 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1220
1221 (defun notmuch-show-mode ()
1222   "Major mode for viewing a thread with notmuch.
1223
1224 This buffer contains the results of the \"notmuch show\" command
1225 for displaying a single thread of email from your email archives.
1226
1227 By default, various components of email messages, (citations,
1228 signatures, already-read messages), are hidden. You can make
1229 these parts visible by clicking with the mouse button or by
1230 pressing RET after positioning the cursor on a hidden part, (for
1231 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1232
1233 Reading the thread sequentially is well-supported by pressing
1234 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1235 to the next message, or advance to the next thread (if already on
1236 the last message of a thread).
1237
1238 Other commands are available to read or manipulate the thread
1239 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1240 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1241 without scrolling through with \\[notmuch-show-advance-and-archive]).
1242
1243 You can add or remove arbitrary tags from the current message with
1244 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1245
1246 All currently available key bindings:
1247
1248 \\{notmuch-show-mode-map}"
1249   (interactive)
1250   (kill-all-local-variables)
1251   (use-local-map notmuch-show-mode-map)
1252   (setq major-mode 'notmuch-show-mode
1253         mode-name "notmuch-show")
1254   (setq buffer-read-only t
1255         truncate-lines t))
1256
1257 (defun notmuch-show-move-to-message-top ()
1258   (goto-char (notmuch-show-message-top)))
1259
1260 (defun notmuch-show-move-to-message-bottom ()
1261   (goto-char (notmuch-show-message-bottom)))
1262
1263 (defun notmuch-show-message-adjust ()
1264   (recenter 0))
1265
1266 ;; Movement related functions.
1267
1268 ;; There's some strangeness here where a text property applied to a
1269 ;; region a->b is not found when point is at b. We walk backwards
1270 ;; until finding the property.
1271 (defun notmuch-show-message-extent ()
1272   (let (r)
1273     (save-excursion
1274       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1275         (backward-char)))
1276     r))
1277
1278 (defun notmuch-show-message-top ()
1279   (car (notmuch-show-message-extent)))
1280
1281 (defun notmuch-show-message-bottom ()
1282   (cdr (notmuch-show-message-extent)))
1283
1284 (defun notmuch-show-goto-message-next ()
1285   (let ((start (point)))
1286     (notmuch-show-move-to-message-bottom)
1287     (if (not (eobp))
1288         t
1289       (goto-char start)
1290       nil)))
1291
1292 (defun notmuch-show-goto-message-previous ()
1293   (notmuch-show-move-to-message-top)
1294   (if (bobp)
1295       nil
1296     (backward-char)
1297     (notmuch-show-move-to-message-top)
1298     t))
1299
1300 (defun notmuch-show-mapc (function)
1301   "Iterate through all messages in the current thread with
1302 `notmuch-show-goto-message-next' and call FUNCTION for side
1303 effects."
1304   (save-excursion
1305     (goto-char (point-min))
1306     (loop do (funcall function)
1307           while (notmuch-show-goto-message-next))))
1308
1309 ;; Functions relating to the visibility of messages and their
1310 ;; components.
1311
1312 (defun notmuch-show-element-visible (props visible-p spec-property)
1313   (let ((spec (plist-get props spec-property)))
1314     (if visible-p
1315         (remove-from-invisibility-spec spec)
1316       (add-to-invisibility-spec spec))))
1317
1318 (defun notmuch-show-message-visible (props visible-p)
1319   (notmuch-show-element-visible props visible-p :message-invis-spec)
1320   (notmuch-show-set-prop :message-visible visible-p props))
1321
1322 (defun notmuch-show-headers-visible (props visible-p)
1323   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1324   (notmuch-show-set-prop :headers-visible visible-p props))
1325
1326 ;; Functions for setting and getting attributes of the current
1327 ;; message.
1328
1329 (defun notmuch-show-set-message-properties (props)
1330   (save-excursion
1331     (notmuch-show-move-to-message-top)
1332     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1333
1334 (defun notmuch-show-get-message-properties ()
1335   "Return the properties of the current message as a plist.
1336
1337 Some useful entries are:
1338 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1339 :body - Body of the message
1340 :tags - Tags for this message"
1341   (save-excursion
1342     (notmuch-show-move-to-message-top)
1343     (get-text-property (point) :notmuch-message-properties)))
1344
1345 (defun notmuch-show-set-prop (prop val &optional props)
1346   (let ((inhibit-read-only t)
1347         (props (or props
1348                    (notmuch-show-get-message-properties))))
1349     (plist-put props prop val)
1350     (notmuch-show-set-message-properties props)))
1351
1352 (defun notmuch-show-get-prop (prop &optional props)
1353   (let ((props (or props
1354                    (notmuch-show-get-message-properties))))
1355     (plist-get props prop)))
1356
1357 (defun notmuch-show-get-message-id (&optional bare)
1358   "Return an id: query for the Message-Id of the current message.
1359
1360 If optional argument BARE is non-nil, return
1361 the Message-Id without id: prefix and escaping."
1362   (if bare
1363       (notmuch-show-get-prop :id)
1364     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1365
1366 (defun notmuch-show-get-messages-ids ()
1367   "Return all id: queries of messages in the current thread."
1368   (let ((message-ids))
1369     (notmuch-show-mapc
1370      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1371     message-ids))
1372
1373 (defun notmuch-show-get-messages-ids-search ()
1374   "Return a search string for all message ids of messages in the
1375 current thread."
1376   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1377
1378 ;; dme: Would it make sense to use a macro for many of these?
1379
1380 (defun notmuch-show-get-filename ()
1381   "Return the filename of the current message."
1382   (notmuch-show-get-prop :filename))
1383
1384 (defun notmuch-show-get-header (header &optional props)
1385   "Return the named header of the current message, if any."
1386   (plist-get (notmuch-show-get-prop :headers props) header))
1387
1388 (defun notmuch-show-get-cc ()
1389   (notmuch-show-get-header :Cc))
1390
1391 (defun notmuch-show-get-date ()
1392   (notmuch-show-get-header :Date))
1393
1394 (defun notmuch-show-get-from ()
1395   (notmuch-show-get-header :From))
1396
1397 (defun notmuch-show-get-subject ()
1398   (notmuch-show-get-header :Subject))
1399
1400 (defun notmuch-show-get-to ()
1401   (notmuch-show-get-header :To))
1402
1403 (defun notmuch-show-get-depth ()
1404   (notmuch-show-get-prop :depth))
1405
1406 (defun notmuch-show-set-tags (tags)
1407   "Set the tags of the current message."
1408   (notmuch-show-set-prop :tags tags)
1409   (notmuch-show-update-tags tags))
1410
1411 (defun notmuch-show-get-tags ()
1412   "Return the tags of the current message."
1413   (notmuch-show-get-prop :tags))
1414
1415 (defun notmuch-show-message-visible-p ()
1416   "Is the current message visible?"
1417   (notmuch-show-get-prop :message-visible))
1418
1419 (defun notmuch-show-headers-visible-p ()
1420   "Are the headers of the current message visible?"
1421   (notmuch-show-get-prop :headers-visible))
1422
1423 (defun notmuch-show-mark-read (&optional unread)
1424   "Mark the current message as read.
1425
1426 Mark the current message as read by applying the tag changes in
1427 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1428 default). If a prefix argument is given, the message will be
1429 marked as unread, i.e. the tag changes in
1430 `notmuch-show-mark-read-tags' will be reversed."
1431   (interactive "P")
1432   (when notmuch-show-mark-read-tags
1433     (apply 'notmuch-show-tag-message
1434            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1435
1436 ;; Functions for getting attributes of several messages in the current
1437 ;; thread.
1438
1439 (defun notmuch-show-get-message-ids-for-open-messages ()
1440   "Return a list of all id: queries for open messages in the current thread."
1441   (save-excursion
1442     (let (message-ids done)
1443       (goto-char (point-min))
1444       (while (not done)
1445         (if (notmuch-show-message-visible-p)
1446             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1447         (setq done (not (notmuch-show-goto-message-next)))
1448         )
1449       message-ids
1450       )))
1451
1452 ;; Commands typically bound to keys.
1453
1454 (defun notmuch-show-advance ()
1455   "Advance through thread.
1456
1457 If the current message in the thread is not yet fully visible,
1458 scroll by a near screenful to read more of the message.
1459
1460 Otherwise, (the end of the current message is already within the
1461 current window), advance to the next open message."
1462   (interactive)
1463   (let* ((end-of-this-message (notmuch-show-message-bottom))
1464          (visible-end-of-this-message (1- end-of-this-message))
1465          (ret nil))
1466     (while (invisible-p visible-end-of-this-message)
1467       (setq visible-end-of-this-message
1468             (max (point-min)
1469                  (1- (previous-single-char-property-change
1470                       visible-end-of-this-message 'invisible)))))
1471     (cond
1472      ;; Ideally we would test `end-of-this-message' against the result
1473      ;; of `window-end', but that doesn't account for the fact that
1474      ;; the end of the message might be hidden.
1475      ((and visible-end-of-this-message
1476            (> visible-end-of-this-message (window-end)))
1477       ;; The bottom of this message is not visible - scroll.
1478       (scroll-up nil))
1479
1480      ((not (= end-of-this-message (point-max)))
1481       ;; This is not the last message - move to the next visible one.
1482       (notmuch-show-next-open-message))
1483
1484      ((not (= (point) (point-max)))
1485       ;; This is the last message, but the cursor is not at the end of
1486       ;; the buffer. Move it there.
1487       (goto-char (point-max)))
1488
1489      (t
1490       ;; This is the last message - change the return value
1491       (setq ret t)))
1492     ret))
1493
1494 (defun notmuch-show-advance-and-archive ()
1495   "Advance through thread and archive.
1496
1497 This command is intended to be one of the simplest ways to
1498 process a thread of email. It works exactly like
1499 notmuch-show-advance, in that it scrolls through messages in a
1500 show buffer, except that when it gets to the end of the buffer it
1501 archives the entire current thread, (remove the \"inbox\" tag
1502 from each message), kills the buffer, and displays the next
1503 thread from the search from which this thread was originally
1504 shown."
1505   (interactive)
1506   (if (notmuch-show-advance)
1507       (notmuch-show-archive-thread-then-next)))
1508
1509 (defun notmuch-show-rewind ()
1510   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1511
1512 Specifically, if the beginning of the previous email is fewer
1513 than `window-height' lines from the current point, move to it
1514 just like `notmuch-show-previous-message'.
1515
1516 Otherwise, just scroll down a screenful of the current message.
1517
1518 This command does not modify any message tags, (it does not undo
1519 any effects from previous calls to
1520 `notmuch-show-advance-and-archive'."
1521   (interactive)
1522   (let ((start-of-message (notmuch-show-message-top))
1523         (start-of-window (window-start)))
1524     (cond
1525       ;; Either this message is properly aligned with the start of the
1526       ;; window or the start of this message is not visible on the
1527       ;; screen - scroll.
1528      ((or (= start-of-message start-of-window)
1529           (< start-of-message start-of-window))
1530       (scroll-down)
1531       ;; If a small number of lines from the previous message are
1532       ;; visible, realign so that the top of the current message is at
1533       ;; the top of the screen.
1534       (when (<= (count-screen-lines (window-start) start-of-message)
1535                 next-screen-context-lines)
1536         (goto-char (notmuch-show-message-top))
1537         (notmuch-show-message-adjust))
1538       ;; Move to the top left of the window.
1539       (goto-char (window-start)))
1540      (t
1541       ;; Move to the previous message.
1542       (notmuch-show-previous-message)))))
1543
1544 (defun notmuch-show-reply (&optional prompt-for-sender)
1545   "Reply to the sender and all recipients of the current message."
1546   (interactive "P")
1547   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1548
1549 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1550   "Reply to the sender of the current message."
1551   (interactive "P")
1552   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1553
1554 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1555   "Forward the current message."
1556   (interactive "P")
1557   (with-current-notmuch-show-message
1558    (notmuch-mua-new-forward-message prompt-for-sender)))
1559
1560 (defun notmuch-show-next-message (&optional pop-at-end)
1561   "Show the next message.
1562
1563 If a prefix argument is given and this is the last message in the
1564 thread, navigate to the next thread in the parent search buffer."
1565   (interactive "P")
1566   (if (notmuch-show-goto-message-next)
1567       (progn
1568         (notmuch-show-mark-read)
1569         (notmuch-show-message-adjust))
1570     (if pop-at-end
1571         (notmuch-show-next-thread)
1572       (goto-char (point-max)))))
1573
1574 (defun notmuch-show-previous-message ()
1575   "Show the previous message or the start of the current message."
1576   (interactive)
1577   (if (= (point) (notmuch-show-message-top))
1578       (notmuch-show-goto-message-previous)
1579     (notmuch-show-move-to-message-top))
1580   (notmuch-show-mark-read)
1581   (notmuch-show-message-adjust))
1582
1583 (defun notmuch-show-next-open-message (&optional pop-at-end)
1584   "Show the next open message.
1585
1586 If a prefix argument is given and this is the last open message
1587 in the thread, navigate to the next thread in the parent search
1588 buffer. Return t if there was a next open message in the thread
1589 to show, nil otherwise."
1590   (interactive "P")
1591   (let (r)
1592     (while (and (setq r (notmuch-show-goto-message-next))
1593                 (not (notmuch-show-message-visible-p))))
1594     (if r
1595         (progn
1596           (notmuch-show-mark-read)
1597           (notmuch-show-message-adjust))
1598       (if pop-at-end
1599           (notmuch-show-next-thread)
1600         (goto-char (point-max))))
1601     r))
1602
1603 (defun notmuch-show-next-matching-message ()
1604   "Show the next matching message."
1605   (interactive)
1606   (let (r)
1607     (while (and (setq r (notmuch-show-goto-message-next))
1608                 (not (notmuch-show-get-prop :match))))
1609     (if r
1610         (progn
1611           (notmuch-show-mark-read)
1612           (notmuch-show-message-adjust))
1613       (goto-char (point-max)))))
1614
1615 (defun notmuch-show-open-if-matched ()
1616   "Open a message if it is matched (whether or not excluded)."
1617   (let ((props (notmuch-show-get-message-properties)))
1618     (notmuch-show-message-visible props (plist-get props :match))))
1619
1620 (defun notmuch-show-goto-first-wanted-message ()
1621   "Move to the first open message and mark it read"
1622   (goto-char (point-min))
1623   (if (notmuch-show-message-visible-p)
1624       (notmuch-show-mark-read)
1625     (notmuch-show-next-open-message))
1626   (when (eobp)
1627     ;; There are no matched non-excluded messages so open all matched
1628     ;; (necessarily excluded) messages and go to the first.
1629     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1630     (force-window-update)
1631     (goto-char (point-min))
1632     (if (notmuch-show-message-visible-p)
1633         (notmuch-show-mark-read)
1634       (notmuch-show-next-open-message))))
1635
1636 (defun notmuch-show-previous-open-message ()
1637   "Show the previous open message."
1638   (interactive)
1639   (while (and (if (= (point) (notmuch-show-message-top))
1640                   (notmuch-show-goto-message-previous)
1641                 (notmuch-show-move-to-message-top))
1642               (not (notmuch-show-message-visible-p))))
1643   (notmuch-show-mark-read)
1644   (notmuch-show-message-adjust))
1645
1646 (defun notmuch-show-view-raw-message ()
1647   "View the file holding the current message."
1648   (interactive)
1649   (let* ((id (notmuch-show-get-message-id))
1650          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1651     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1652     (switch-to-buffer buf)
1653     (goto-char (point-min))
1654     (set-buffer-modified-p nil)
1655     (view-buffer buf 'kill-buffer-if-not-modified)))
1656
1657 (defun notmuch-show-pipe-message (entire-thread command)
1658   "Pipe the contents of the current message (or thread) to the given command.
1659
1660 The given command will be executed with the raw contents of the
1661 current email message as stdin. Anything printed by the command
1662 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1663
1664 When invoked with a prefix argument, the command will receive all
1665 open messages in the current thread (formatted as an mbox) rather
1666 than only the current message."
1667   (interactive "P\nsPipe message to command: ")
1668   (let (shell-command)
1669     (if entire-thread
1670         (setq shell-command
1671               (concat notmuch-command " show --format=mbox --exclude=false "
1672                       (shell-quote-argument
1673                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1674                       " | " command))
1675       (setq shell-command
1676             (concat notmuch-command " show --format=raw "
1677                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1678     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1679       (with-current-buffer buf
1680         (setq buffer-read-only nil)
1681         (erase-buffer)
1682         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1683           (goto-char (point-max))
1684           (set-buffer-modified-p nil)
1685           (setq buffer-read-only t)
1686           (unless (zerop exit-code)
1687             (switch-to-buffer-other-window buf)
1688             (message (format "Command '%s' exited abnormally with code %d"
1689                              shell-command exit-code))))))))
1690
1691 (defun notmuch-show-tag-message (&rest tag-changes)
1692   "Change tags for the current message.
1693
1694 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1695   (let* ((current-tags (notmuch-show-get-tags))
1696          (new-tags (notmuch-update-tags current-tags tag-changes)))
1697     (unless (equal current-tags new-tags)
1698       (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1699       (notmuch-show-set-tags new-tags))))
1700
1701 (defun notmuch-show-tag (&optional tag-changes)
1702   "Change tags for the current message.
1703
1704 See `notmuch-tag' for information on the format of TAG-CHANGES."
1705   (interactive)
1706   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes))
1707   (let* ((current-tags (notmuch-show-get-tags))
1708          (new-tags (notmuch-update-tags current-tags tag-changes)))
1709     (unless (equal current-tags new-tags)
1710       (notmuch-show-set-tags new-tags))))
1711
1712 (defun notmuch-show-tag-all (&optional tag-changes)
1713   "Change tags for all messages in the current show buffer.
1714
1715 See `notmuch-tag' for information on the format of TAG-CHANGES."
1716   (interactive)
1717   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1718   (notmuch-show-mapc
1719    (lambda ()
1720      (let* ((current-tags (notmuch-show-get-tags))
1721             (new-tags (notmuch-update-tags current-tags tag-changes)))
1722        (unless (equal current-tags new-tags)
1723          (notmuch-show-set-tags new-tags))))))
1724
1725 (defun notmuch-show-add-tag ()
1726   "Same as `notmuch-show-tag' but sets initial input to '+'."
1727   (interactive)
1728   (notmuch-show-tag "+"))
1729
1730 (defun notmuch-show-remove-tag ()
1731   "Same as `notmuch-show-tag' but sets initial input to '-'."
1732   (interactive)
1733   (notmuch-show-tag "-"))
1734
1735 (defun notmuch-show-toggle-visibility-headers ()
1736   "Toggle the visibility of the current message headers."
1737   (interactive)
1738   (let ((props (notmuch-show-get-message-properties)))
1739     (notmuch-show-headers-visible
1740      props
1741      (not (plist-get props :headers-visible))))
1742   (force-window-update))
1743
1744 (defun notmuch-show-toggle-message ()
1745   "Toggle the visibility of the current message."
1746   (interactive)
1747   (let ((props (notmuch-show-get-message-properties)))
1748     (notmuch-show-message-visible
1749      props
1750      (not (plist-get props :message-visible))))
1751   (force-window-update))
1752
1753 (defun notmuch-show-open-or-close-all ()
1754   "Set the visibility all of the messages in the current thread.
1755 By default make all of the messages visible. With a prefix
1756 argument, hide all of the messages."
1757   (interactive)
1758   (save-excursion
1759     (goto-char (point-min))
1760     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1761                                            (not current-prefix-arg))
1762           until (not (notmuch-show-goto-message-next))))
1763   (force-window-update))
1764
1765 (defun notmuch-show-next-button ()
1766   "Advance point to the next button in the buffer."
1767   (interactive)
1768   (forward-button 1))
1769
1770 (defun notmuch-show-previous-button ()
1771   "Move point back to the previous button in the buffer."
1772   (interactive)
1773   (backward-button 1))
1774
1775 (defun notmuch-show-next-thread (&optional show-next)
1776   "Move to the next item in the search results, if any."
1777   (interactive "P")
1778   (let ((parent-buffer notmuch-show-parent-buffer))
1779     (notmuch-kill-this-buffer)
1780     (when (buffer-live-p parent-buffer)
1781       (switch-to-buffer parent-buffer)
1782       (notmuch-search-next-thread)
1783       (if show-next
1784           (notmuch-search-show-thread)))))
1785
1786 (defun notmuch-show-archive-thread (&optional unarchive)
1787   "Archive each message in thread.
1788
1789 Archive each message currently shown by applying the tag changes
1790 in `notmuch-archive-tags' to each (remove the \"inbox\" tag by
1791 default). If a prefix argument is given, the messages will be
1792 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1793 will be reversed.
1794
1795 Note: This command is safe from any race condition of new messages
1796 being delivered to the same thread. It does not archive the
1797 entire thread, but only the messages shown in the current
1798 buffer."
1799   (interactive "P")
1800   (when notmuch-archive-tags
1801     (notmuch-show-tag-all
1802      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1803
1804 (defun notmuch-show-archive-thread-then-next ()
1805   "Archive all messages in the current buffer, then show next thread from search."
1806   (interactive)
1807   (notmuch-show-archive-thread)
1808   (notmuch-show-next-thread t))
1809
1810 (defun notmuch-show-archive-thread-then-exit ()
1811   "Archive all messages in the current buffer, then exit back to search results."
1812   (interactive)
1813   (notmuch-show-archive-thread)
1814   (notmuch-show-next-thread))
1815
1816 (defun notmuch-show-archive-message (&optional unarchive)
1817   "Archive the current message.
1818
1819 Archive the current message by applying the tag changes in
1820 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
1821 default). If a prefix argument is given, the message will be
1822 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1823 will be reversed."
1824   (interactive "P")
1825   (when notmuch-archive-tags
1826     (apply 'notmuch-show-tag-message
1827            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1828
1829 (defun notmuch-show-archive-message-then-next-or-exit ()
1830   "Archive the current message, then show the next open message in the current thread.
1831
1832 If at the last open message in the current thread, then exit back
1833 to search results."
1834   (interactive)
1835   (notmuch-show-archive-message)
1836   (notmuch-show-next-open-message t))
1837
1838 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1839   "Archive the current message, then show the next open message in the current thread.
1840
1841 If at the last open message in the current thread, then show next
1842 thread from search."
1843   (interactive)
1844   (notmuch-show-archive-message)
1845   (unless (notmuch-show-next-open-message)
1846     (notmuch-show-next-thread t)))
1847
1848 (defun notmuch-show-stash-cc ()
1849   "Copy CC field of current message to kill-ring."
1850   (interactive)
1851   (notmuch-common-do-stash (notmuch-show-get-cc)))
1852
1853 (defun notmuch-show-stash-date ()
1854   "Copy date of current message to kill-ring."
1855   (interactive)
1856   (notmuch-common-do-stash (notmuch-show-get-date)))
1857
1858 (defun notmuch-show-stash-filename ()
1859   "Copy filename of current message to kill-ring."
1860   (interactive)
1861   (notmuch-common-do-stash (notmuch-show-get-filename)))
1862
1863 (defun notmuch-show-stash-from ()
1864   "Copy From address of current message to kill-ring."
1865   (interactive)
1866   (notmuch-common-do-stash (notmuch-show-get-from)))
1867
1868 (defun notmuch-show-stash-message-id ()
1869   "Copy id: query matching the current message to kill-ring."
1870   (interactive)
1871   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1872
1873 (defun notmuch-show-stash-message-id-stripped ()
1874   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1875   (interactive)
1876   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1877
1878 (defun notmuch-show-stash-subject ()
1879   "Copy Subject field of current message to kill-ring."
1880   (interactive)
1881   (notmuch-common-do-stash (notmuch-show-get-subject)))
1882
1883 (defun notmuch-show-stash-tags ()
1884   "Copy tags of current message to kill-ring as a comma separated list."
1885   (interactive)
1886   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1887
1888 (defun notmuch-show-stash-to ()
1889   "Copy To address of current message to kill-ring."
1890   (interactive)
1891   (notmuch-common-do-stash (notmuch-show-get-to)))
1892
1893 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1894   "Copy an ML Archive URI for the current message to the kill-ring.
1895
1896 This presumes that the message is available at the selected Mailing List Archive.
1897
1898 If optional argument MLA is non-nil, use the provided key instead of prompting
1899 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1900   (interactive)
1901   (notmuch-common-do-stash
1902    (concat (cdr (assoc
1903                  (or mla
1904                      (let ((completion-ignore-case t))
1905                        (completing-read
1906                         "Mailing List Archive: "
1907                         notmuch-show-stash-mlarchive-link-alist
1908                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1909                  notmuch-show-stash-mlarchive-link-alist))
1910            (notmuch-show-get-message-id t))))
1911
1912 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1913   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1914
1915 This presumes that the message is available at the selected Mailing List Archive.
1916
1917 If optional argument MLA is non-nil, use the provided key instead of prompting
1918 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1919   (interactive)
1920   (notmuch-show-stash-mlarchive-link mla)
1921   (browse-url (current-kill 0 t)))
1922
1923 ;; Commands typically bound to buttons.
1924
1925 (defun notmuch-show-part-button-default (&optional button)
1926   (interactive)
1927   (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))
1928
1929 (defun notmuch-show-part-button-save (&optional button)
1930   (interactive)
1931   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1932
1933 (defun notmuch-show-part-button-view (&optional button)
1934   (interactive)
1935   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1936
1937 (defun notmuch-show-part-button-interactively-view (&optional button)
1938   (interactive)
1939   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1940
1941 (defun notmuch-show-part-button-pipe (&optional button)
1942   (interactive)
1943   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
1944
1945 (defun notmuch-show-part-button-internal (button handler)
1946   (let ((button (or button (button-at (point)))))
1947     (if button
1948         (let ((nth (button-get button :notmuch-part)))
1949           (if nth
1950               (funcall handler (notmuch-show-get-message-id) nth
1951                        (button-get button :notmuch-filename)
1952                        (button-get button :notmuch-content-type)))))))
1953
1954 ;;
1955
1956 (provide 'notmuch-show)