git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;;; notmuch-show.el --- displaying notmuch forests  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 ;;; Code:
  25
  26 (require 'mm-view)
  27 (require 'message)
  28 (require 'mm-decode)
  29 (require 'mailcap)
  30 (require 'icalendar)
  31 (require 'goto-addr)
  32
  33 (require 'notmuch-lib)
  34 (require 'notmuch-tag)
  35 (require 'notmuch-query)
  36 (require 'notmuch-wash)
  37 (require 'notmuch-mua)
  38 (require 'notmuch-crypto)
  39 (require 'notmuch-print)
  40 (require 'notmuch-draft)
  41
  42 (declare-function notmuch-call-notmuch-process "notmuch-lib" (&rest args))
  43 (declare-function notmuch-search-next-thread "notmuch" nil)
  44 (declare-function notmuch-search-previous-thread "notmuch" nil)
  45 (declare-function notmuch-search-show-thread "notmuch")
  46 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
  47 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
  48 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
  49 (declare-function notmuch-tree "notmuch-tree"
  50                   (&optional query query-context target buffer-name
  51                              open-target unthreaded parent-buffer))
  52 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
  53 (declare-function notmuch-unthreaded "notmuch-tree"
  54                   (&optional query query-context target buffer-name
  55                              open-target))
  56 (declare-function notmuch-read-query "notmuch" (prompt))
  57 (declare-function notmuch-draft-resume "notmuch-draft" (id))
  58
  59 (defvar shr-blocked-images)
  60 (defvar gnus-blocked-images)
  61 (defvar shr-content-function)
  62 (defvar w3m-ignored-image-url-regexp)
  63
  64 ;;; Options
  65
  66 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  67   "Headers that should be shown in a message, in this order.
  68
  69 For an open message, all of these headers will be made visible
  70 according to `notmuch-message-headers-visible' or can be toggled
  71 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  72 only the first header in the list will be visible."
  73   :type '(repeat string)
  74   :group 'notmuch-show)
  75
  76 (defcustom notmuch-message-headers-visible t
  77   "Should the headers be visible by default?
  78
  79 If this value is non-nil, then all of the headers defined in
  80 `notmuch-message-headers' will be visible by default in the display
  81 of each message. Otherwise, these headers will be hidden and
  82 `notmuch-show-toggle-visibility-headers' can be used to make them
  83 visible for any given message."
  84   :type 'boolean
  85   :group 'notmuch-show)
  86
  87 (defcustom notmuch-show-header-line t
  88   "Show a header line with the current message's subject."
  89   :type 'boolean
  90   :group 'notmuch-show)
  91
  92 (defcustom notmuch-show-relative-dates t
  93   "Display relative dates in the message summary line."
  94   :type 'boolean
  95   :group 'notmuch-show)
  96
  97 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  98   "A list of functions called to decorate the headers listed in
  99 `notmuch-message-headers'.")
 100
 101 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
 102   "Functions called after populating a `notmuch-show' buffer."
 103   :type 'hook
 104   :options '(notmuch-show-turn-on-visual-line-mode)
 105   :group 'notmuch-show
 106   :group 'notmuch-hooks)
 107
 108 (defcustom notmuch-show-insert-text/plain-hook
 109   '(notmuch-wash-wrap-long-lines
 110     notmuch-wash-tidy-citations
 111     notmuch-wash-elide-blank-lines
 112     notmuch-wash-excerpt-citations)
 113   "Functions used to improve the display of text/plain parts."
 114   :type 'hook
 115   :options '(notmuch-wash-convert-inline-patch-to-part
 116              notmuch-wash-wrap-long-lines
 117              notmuch-wash-tidy-citations
 118              notmuch-wash-elide-blank-lines
 119              notmuch-wash-excerpt-citations)
 120   :group 'notmuch-show
 121   :group 'notmuch-hooks)
 122
 123 (defcustom notmuch-show-max-text-part-size 100000
 124   "Maximum size of a text part to be shown by default in characters.
 125
 126 Set to 0 to show the part regardless of size."
 127   :type 'integer
 128   :group 'notmuch-show)
 129
 130 ;; Mostly useful for debugging.
 131 (defcustom notmuch-show-all-multipart/alternative-parts nil
 132   "Should all parts of multipart/alternative parts be shown?"
 133   :type 'boolean
 134   :group 'notmuch-show)
 135
 136 (defcustom notmuch-show-indent-messages-width 1
 137   "Width of message indentation in threads.
 138
 139 Messages are shown indented according to their depth in a thread.
 140 This variable determines the width of this indentation measured
 141 in number of blanks.  Defaults to `1', choose `0' to disable
 142 indentation."
 143   :type 'integer
 144   :group 'notmuch-show)
 145
 146 (defcustom notmuch-show-indent-multipart nil
 147   "Should the sub-parts of a multipart/* part be indented?"
 148   ;; dme: Not sure which is a good default.
 149   :type 'boolean
 150   :group 'notmuch-show)
 151
 152 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 153   "Default part header button action (on ENTER or mouse click)."
 154   :group 'notmuch-show
 155   :type '(choice (const :tag "Save part"
 156                         notmuch-show-save-part)
 157                  (const :tag "View part"
 158                         notmuch-show-view-part)
 159                  (const :tag "View interactively"
 160                         notmuch-show-interactively-view-part)))
 161
 162 (defcustom notmuch-show-only-matching-messages nil
 163   "Only matching messages are shown by default."
 164   :type 'boolean
 165   :group 'notmuch-show)
 166
 167 ;; By default, block all external images to prevent privacy leaks and
 168 ;; potential attacks.
 169 (defcustom notmuch-show-text/html-blocked-images "."
 170   "Remote images that have URLs matching this regexp will be blocked."
 171   :type '(choice (const nil) regexp)
 172   :group 'notmuch-show)
 173
 174 ;;; Variables
 175
 176 (defvar-local notmuch-show-thread-id nil)
 177
 178 (defvar-local notmuch-show-parent-buffer nil)
 179
 180 (defvar-local notmuch-show-query-context nil)
 181
 182 (defvar-local notmuch-show-process-crypto nil)
 183
 184 (defvar-local notmuch-show-elide-non-matching-messages nil)
 185
 186 (defvar-local notmuch-show-indent-content t)
 187
 188 (defvar-local notmuch-show-single-message nil)
 189
 190 (defvar notmuch-show-attachment-debug nil
 191   "If t log stdout and stderr from attachment handlers.
 192
 193 When set to nil (the default) stdout and stderr from attachment
 194 handlers is discarded. When set to t the stdout and stderr from
 195 each attachment handler is logged in buffers with names beginning
 196 \" *notmuch-part*\".")
 197
 198 ;;; Options
 199
 200 (defcustom notmuch-show-stash-mlarchive-link-alist
 201   '(("MARC" . "https://marc.info/?i=")
 202     ("Mail Archive, The" . "https://mid.mail-archive.com/")
 203     ("Lore" . "https://lore.kernel.org/r/")
 204     ("Notmuch" . "https://nmbug.notmuchmail.org/nmweb/show/")
 205     ;; FIXME: can these services be searched by `Message-Id' ?
 206     ;; ("MarkMail" . "http://markmail.org/")
 207     ;; ("Nabble" . "http://nabble.com/")
 208     ;; ("opensubscriber" . "http://opensubscriber.com/")
 209     )
 210   "List of Mailing List Archives to use when stashing links.
 211
 212 This list is used for generating a Mailing List Archive reference
 213 URI with the current message's Message-Id in
 214 `notmuch-show-stash-mlarchive-link'.
 215
 216 If the cdr of the alist element is not a function, the cdr is
 217 expected to contain a URI that is concatenated with the current
 218 message's Message-Id to create a ML archive reference URI.
 219
 220 If the cdr is a function, the function is called with the
 221 Message-Id as the argument, and the function is expected to
 222 return the ML archive reference URI."
 223   :type '(alist :key-type (string :tag "Name")
 224                 :value-type (choice
 225                              (string :tag "URL")
 226                              (function :tag "Function returning the URL")))
 227   :group 'notmuch-show)
 228
 229 (defcustom notmuch-show-stash-mlarchive-link-default "MARC"
 230   "Default Mailing List Archive to use when stashing links.
 231
 232 This is used when `notmuch-show-stash-mlarchive-link' isn't
 233 provided with an MLA argument nor `completing-read' input."
 234   :type `(choice
 235           ,@(mapcar
 236              (lambda (mla)
 237                (list 'const :tag (car mla) :value (car mla)))
 238              notmuch-show-stash-mlarchive-link-alist))
 239   :group 'notmuch-show)
 240
 241 (defcustom notmuch-show-mark-read-tags '("-unread")
 242   "List of tag changes to apply to a message when it is marked as read.
 243
 244 Tags starting with \"+\" (or not starting with either \"+\" or
 245 \"-\") in the list will be added, and tags starting with \"-\"
 246 will be removed from the message being marked as read.
 247
 248 For example, if you wanted to remove an \"unread\" tag and add a
 249 \"read\" tag (which would make little sense), you would set:
 250     (\"-unread\" \"+read\")"
 251   :type '(repeat string)
 252   :group 'notmuch-show)
 253
 254 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
 255   "Function to control which messages are marked read.
 256
 257 The function should take two arguments START and END which will
 258 be the start and end of the visible portion of the buffer and
 259 should mark the appropriate messages read by applying
 260 `notmuch-show-mark-read'. This function will be called after
 261 every user interaction with notmuch."
 262   :type 'function
 263   :group 'notmuch-show)
 264
 265 (defcustom notmuch-show-imenu-indent nil
 266   "Should Imenu display messages indented.
 267
 268 By default, Imenu (see Info node `(emacs) Imenu') in a
 269 notmuch-show buffer displays all messages straight.  This is
 270 because the default Emacs frontend for Imenu makes it difficult
 271 to select an Imenu entry with spaces in front.  Other imenu
 272 frontends such as counsel-imenu does not have this limitation.
 273 In these cases, Imenu entries can be indented to reflect the
 274 position of the message in the thread."
 275   :type 'boolean
 276   :group 'notmuch-show)
 277
 278 ;;; Utilities
 279
 280 (defmacro with-current-notmuch-show-message (&rest body)
 281   "Evaluate body with current buffer set to the text of current message."
 282   `(save-excursion
 283      (let ((id (notmuch-show-get-message-id)))
 284        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 285          (with-current-buffer buf
 286            (let ((coding-system-for-read 'no-conversion))
 287              (notmuch--call-process notmuch-command nil t nil "show" "--format=raw" id))
 288            ,@body)
 289          (kill-buffer buf)))))
 290
 291 (defun notmuch-show-turn-on-visual-line-mode ()
 292   "Enable Visual Line mode."
 293   (visual-line-mode t))
 294
 295 ;;; Commands
 296
 297 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
 298 ;; commands.  We'll keep the command around for a version or two in
 299 ;; case people want to bind it themselves.
 300 (defun notmuch-show-view-all-mime-parts ()
 301   "Use external viewers to view all attachments from the current message."
 302   (interactive)
 303   (with-current-notmuch-show-message
 304    ;; We override the mm-inline-media-tests to indicate which message
 305    ;; parts are already sufficiently handled by the original
 306    ;; presentation of the message in notmuch-show mode. These parts
 307    ;; will be inserted directly into the temporary buffer of
 308    ;; with-current-notmuch-show-message and silently discarded.
 309    ;;
 310    ;; Any MIME part not explicitly mentioned here will be handled by an
 311    ;; external viewer as configured in the various mailcap files.
 312    (let ((mm-inline-media-tests
 313           '(("text/.*" ignore identity)
 314             ("application/pgp-signature" ignore identity)
 315             ("multipart/alternative" ignore identity)
 316             ("multipart/mixed" ignore identity)
 317             ("multipart/related" ignore identity))))
 318      (mm-display-parts (mm-dissect-buffer)))))
 319
 320 (defun notmuch-show-save-attachments ()
 321   "Save all attachments from the current message."
 322   (interactive)
 323   (with-current-notmuch-show-message
 324    (let ((mm-handle (mm-dissect-buffer)))
 325      (notmuch-save-attachments
 326       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 327   (message "Done"))
 328
 329 (defun notmuch-show-with-message-as-text (fn)
 330   "Apply FN to a text representation of the current message.
 331
 332 FN is called with one argument, the message properties. It should
 333 operation on the contents of the current buffer."
 334   ;; Remake the header to ensure that all information is available.
 335   (let* ((to (notmuch-show-get-to))
 336          (cc (notmuch-show-get-cc))
 337          (from (notmuch-show-get-from))
 338          (subject (notmuch-show-get-subject))
 339          (date (notmuch-show-get-date))
 340          (tags (notmuch-show-get-tags))
 341          (depth (notmuch-show-get-depth))
 342          (header (concat
 343                   "Subject: " subject "\n"
 344                   "To: " to "\n"
 345                   (if (not (string-empty-p cc))
 346                       (concat "Cc: " cc "\n")
 347                     "")
 348                   "From: " from "\n"
 349                   "Date: " date "\n"
 350                   (if tags
 351                       (concat "Tags: "
 352                               (mapconcat #'identity tags ", ") "\n")
 353                     "")))
 354          (all (buffer-substring (notmuch-show-message-top)
 355                                 (notmuch-show-message-bottom)))
 356
 357          (props (notmuch-show-get-message-properties))
 358          (indenting notmuch-show-indent-content))
 359     (with-temp-buffer
 360       (insert all)
 361       (when indenting
 362         (indent-rigidly (point-min)
 363                         (point-max)
 364                         (- (* notmuch-show-indent-messages-width depth))))
 365       ;; Remove the original header.
 366       (goto-char (point-min))
 367       (re-search-forward "^$" (point-max) nil)
 368       (delete-region (point-min) (point))
 369       (insert header)
 370       (funcall fn props))))
 371
 372 (defun notmuch-show-print-message ()
 373   "Print the current message."
 374   (interactive)
 375   (notmuch-show-with-message-as-text 'notmuch-print-message))
 376
 377 ;;; Headers
 378
 379 (defun notmuch-show-fontify-header ()
 380   (let ((face (cond
 381                ((looking-at "[Tt]o:")
 382                 'message-header-to)
 383                ((looking-at "[Bb]?[Cc][Cc]:")
 384                 'message-header-cc)
 385                ((looking-at "[Ss]ubject:")
 386                 'message-header-subject)
 387                (t
 388                 'message-header-other))))
 389     (overlay-put (make-overlay (point) (re-search-forward ":"))
 390                  'face 'message-header-name)
 391     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 392                  'face face)))
 393
 394 (defun notmuch-show-colour-headers ()
 395   "Apply some colouring to the current headers."
 396   (goto-char (point-min))
 397   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 398     (notmuch-show-fontify-header)
 399     (forward-line)))
 400
 401 (defun notmuch-show-spaces-n (n)
 402   "Return a string comprised of `n' spaces."
 403   (make-string n ? ))
 404
 405 (defun notmuch-show-update-tags (tags)
 406   "Update the displayed tags of the current message."
 407   (save-excursion
 408     (goto-char (notmuch-show-message-top))
 409     (when (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 410       (let ((inhibit-read-only t))
 411         (replace-match (concat "("
 412                                (notmuch-tag-format-tags
 413                                 tags
 414                                 (notmuch-show-get-prop :orig-tags))
 415                                ")"))))))
 416
 417 (defun notmuch-clean-address (address)
 418   "Try to clean a single email ADDRESS for display. Return a cons
 419 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 420 parsing fails."
 421   (condition-case nil
 422       (let (p-name p-address)
 423         ;; It would be convenient to use `mail-header-parse-address',
 424         ;; but that expects un-decoded mailbox parts, whereas our
 425         ;; mailbox parts are already decoded (and hence may contain
 426         ;; UTF-8). Given that notmuch should handle most of the awkward
 427         ;; cases, some simple string deconstruction should be sufficient
 428         ;; here.
 429         (cond
 430          ;; "User <user@dom.ain>" style.
 431          ((string-match "\\(.*\\) <\\(.*\\)>" address)
 432           (setq p-name (match-string 1 address))
 433           (setq p-address (match-string 2 address)))
 434
 435          ;; "<user@dom.ain>" style.
 436          ((string-match "<\\(.*\\)>" address)
 437           (setq p-address (match-string 1 address)))
 438          ;; Everything else.
 439          (t
 440           (setq p-address address)))
 441         (when p-name
 442           ;; Remove elements of the mailbox part that are not relevant for
 443           ;; display, even if they are required during transport:
 444           ;;
 445           ;; Backslashes.
 446           (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 447           ;; Outer single and double quotes, which might be nested.
 448           (cl-loop with start-of-loop
 449                    do   (setq start-of-loop p-name)
 450                    when (string-match "^\"\\(.*\\)\"$" p-name)
 451                    do   (setq p-name (match-string 1 p-name))
 452                    when (string-match "^'\\(.*\\)'$" p-name)
 453                    do   (setq p-name (match-string 1 p-name))
 454                    until (string= start-of-loop p-name)))
 455         ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 456         ;; 'foo@bar.com'.
 457         (when (string= p-name p-address)
 458           (setq p-name nil))
 459         (cons p-address p-name))
 460     (error (cons address nil))))
 461
 462 (defun notmuch-show-clean-address (address)
 463   "Try to clean a single email ADDRESS for display.
 464 Return unchanged ADDRESS if parsing fails."
 465   (let* ((clean-address (notmuch-clean-address address))
 466          (p-address (car clean-address))
 467          (p-name (cdr clean-address)))
 468     ;; If no name, return just the address.
 469     (if (not p-name)
 470         p-address
 471       ;; Otherwise format the name and address together.
 472       (concat p-name " <" p-address ">"))))
 473
 474 (defun notmuch-show-insert-headerline (headers date tags depth)
 475   "Insert a notmuch style headerline based on HEADERS for a
 476 message at DEPTH in the current thread."
 477   (let ((start (point))
 478         (from (notmuch-sanitize
 479                (notmuch-show-clean-address (plist-get headers :From)))))
 480     (when (string-match "\\cR" from)
 481       ;; If the From header has a right-to-left character add
 482       ;; invisible U+200E LEFT-TO-RIGHT MARK character which forces
 483       ;; the header paragraph as left-to-right text.
 484       (insert (propertize (string ?\x200e) 'invisible t)))
 485     (insert (if notmuch-show-indent-content
 486                 (notmuch-show-spaces-n (* notmuch-show-indent-messages-width
 487                                           depth))
 488               "")
 489             from
 490             " ("
 491             date
 492             ") ("
 493             (notmuch-tag-format-tags tags tags)
 494             ")\n")
 495     (overlay-put (make-overlay start (point))
 496                  'face 'notmuch-message-summary-face)))
 497
 498 (defun notmuch-show-insert-header (header header-value)
 499   "Insert a single header."
 500   (insert header ": " (notmuch-sanitize header-value) "\n"))
 501
 502 (defun notmuch-show-insert-headers (headers)
 503   "Insert the headers of the current message."
 504   (let ((start (point)))
 505     (mapc (lambda (header)
 506             (let* ((header-symbol (intern (concat ":" header)))
 507                    (header-value (plist-get headers header-symbol)))
 508               (when (and header-value
 509                          (not (string-equal "" header-value)))
 510                 (notmuch-show-insert-header header header-value))))
 511           notmuch-message-headers)
 512     (save-excursion
 513       (save-restriction
 514         (narrow-to-region start (point-max))
 515         (run-hooks 'notmuch-show-markup-headers-hook)))))
 516
 517 ;;; Parts
 518
 519 (define-button-type 'notmuch-show-part-button-type
 520   'action 'notmuch-show-part-button-default
 521   'follow-link t
 522   'face 'message-mml
 523   :supertype 'notmuch-button-type)
 524
 525 (defun notmuch-show-insert-part-header (_nth content-type declared-type
 526                                             &optional name comment)
 527   (let ((base-label (concat (and name (concat name ": "))
 528                             declared-type
 529                             (and (not (string-equal declared-type content-type))
 530                                  (concat " (as " content-type ")"))
 531                             comment)))
 532     (prog1 (insert-button
 533             (concat "[ " base-label " ]")
 534             :base-label base-label
 535             :type 'notmuch-show-part-button-type
 536             :notmuch-part-hidden nil)
 537       (insert "\n"))))
 538
 539 (defun notmuch-show-toggle-part-invisibility (&optional button)
 540   (interactive)
 541   (let ((button (or button (button-at (point)))))
 542     (when button
 543       (let ((overlay (button-get button 'overlay))
 544             (lazy-part (button-get button :notmuch-lazy-part)))
 545         ;; We have a part to toggle if there is an overlay or if there
 546         ;; is a lazy part.  If neither is present we cannot toggle the
 547         ;; part so we just return nil.
 548         (when (or overlay lazy-part)
 549           (let* ((show (button-get button :notmuch-part-hidden))
 550                  (new-start (button-start button))
 551                  (button-label (button-get button :base-label))
 552                  (old-point (point))
 553                  (properties (text-properties-at (button-start button)))
 554                  (inhibit-read-only t))
 555             ;; Toggle the button itself.
 556             (button-put button :notmuch-part-hidden (not show))
 557             (goto-char new-start)
 558             (insert "[ " button-label (if show " ]" " (hidden) ]"))
 559             (set-text-properties new-start (point) properties)
 560             (let ((old-end (button-end button)))
 561               (move-overlay button new-start (point))
 562               (delete-region (point) old-end))
 563             (goto-char (min old-point (1- (button-end button))))
 564             ;; Return nil if there is a lazy-part, it is empty, and we are
 565             ;; trying to show it.  In all other cases return t.
 566             (if lazy-part
 567                 (when show
 568                   (button-put button :notmuch-lazy-part nil)
 569                   (notmuch-show-lazy-part lazy-part button))
 570               ;; else there must be an overlay.
 571               (overlay-put overlay 'invisible (not show))
 572               t)))))))
 573
 574 ;;; Part content ID handling
 575
 576 (defvar notmuch-show--cids nil
 577   "Alist from raw content ID to (MSG PART).")
 578 (make-variable-buffer-local 'notmuch-show--cids)
 579
 580 (defun notmuch-show--register-cids (msg part)
 581   "Register content-IDs in PART and all of PART's sub-parts."
 582   (let ((content-id (plist-get part :content-id)))
 583     (when content-id
 584       ;; Note that content-IDs are globally unique, except when they
 585       ;; aren't: RFC 2046 section 5.1.4 permits children of a
 586       ;; multipart/alternative to have the same content-ID, in which
 587       ;; case the MUA is supposed to pick the best one it can render.
 588       ;; We simply add the content-ID to the beginning of our alist;
 589       ;; so if this happens, we'll take the last (and "best")
 590       ;; alternative (even if we can't render it).
 591       (push (list content-id msg part) notmuch-show--cids)))
 592   ;; Recurse on sub-parts
 593   (when-let ((type (plist-get part :content-type)))
 594     (pcase-let ((`(,type ,subtype)
 595                  (split-string (downcase type) "/")))
 596       (cond ((equal type "multipart")
 597              (mapc (apply-partially #'notmuch-show--register-cids msg)
 598                    (plist-get part :content)))
 599             ((and (equal type "message")
 600                   (equal subtype "rfc822"))
 601              (notmuch-show--register-cids
 602               msg
 603               (car (plist-get (car (plist-get part :content)) :body))))))))
 604
 605 (defun notmuch-show--get-cid-content (cid)
 606   "Return a list (CID-content content-type) or nil.
 607
 608 This will only find parts from messages that have been inserted
 609 into the current buffer.  CID must be a raw content ID, without
 610 enclosing angle brackets, a cid: prefix, or URL encoding.  This
 611 will return nil if the CID is unknown or cannot be retrieved."
 612   (when-let ((descriptor (cdr (assoc cid notmuch-show--cids))))
 613     (pcase-let ((`(,msg ,part) descriptor))
 614       ;; Request caching for this content, as some messages
 615       ;; reference the same cid: part many times (hundreds!).
 616       (list (notmuch-get-bodypart-binary
 617              msg part notmuch-show-process-crypto 'cache)
 618             (plist-get part :content-type)))))
 619
 620 (defun notmuch-show-setup-w3m ()
 621   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 622   (interactive)
 623   (when (and (boundp 'w3m-cid-retrieve-function-alist)
 624              (not (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)))
 625     (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
 626           w3m-cid-retrieve-function-alist))
 627   (setq mm-html-inhibit-images nil))
 628
 629 (defvar w3m-current-buffer) ;; From `w3m.el'.
 630 (defun notmuch-show--cid-w3m-retrieve (url &rest _args)
 631   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
 632   (let* ((cid (url-unhex-string (substring url 4)))
 633          (content-and-type
 634           (with-current-buffer w3m-current-buffer
 635             (notmuch-show--get-cid-content cid))))
 636     (when content-and-type
 637       (insert (car content-and-type))
 638       (cadr content-and-type))))
 639
 640 ;; MIME part renderers
 641
 642 (defun notmuch-show-multipart/*-to-list (part)
 643   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 644           (plist-get part :content)))
 645
 646 (defun notmuch-show-insert-part-multipart/alternative (msg part _content-type _nth depth _button)
 647   (let ((chosen-type (car (notmuch-multipart/alternative-choose
 648                            msg (notmuch-show-multipart/*-to-list part))))
 649         (inner-parts (plist-get part :content))
 650         (start (point)))
 651     ;; This inserts all parts of the chosen type rather than just one,
 652     ;; but it's not clear that this is the wrong thing to do - which
 653     ;; should be chosen if there are more than one that match?
 654     (mapc (lambda (inner-part)
 655             (let* ((inner-type (plist-get inner-part :content-type))
 656                    (hide (not (or notmuch-show-all-multipart/alternative-parts
 657                                   (string= chosen-type inner-type)))))
 658               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 659           inner-parts)
 660
 661     (when notmuch-show-indent-multipart
 662       (indent-rigidly start (point) 1)))
 663   t)
 664
 665 (defun notmuch-show-insert-part-multipart/related (msg part _content-type _nth depth _button)
 666   (let ((inner-parts (plist-get part :content))
 667         (start (point)))
 668     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
 669     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 670     ;; Add hidden buttons for the rest
 671     (mapc (lambda (inner-part)
 672             (notmuch-show-insert-bodypart msg inner-part depth t))
 673           (cdr inner-parts))
 674     (when notmuch-show-indent-multipart
 675       (indent-rigidly start (point) 1)))
 676   t)
 677
 678 (defun notmuch-show-insert-part-multipart/signed (msg part _content-type _nth depth button)
 679   (when button
 680     (button-put button 'face 'notmuch-crypto-part-header))
 681   ;; Insert a button detailing the signature status.
 682   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
 683                                           (notmuch-show-get-header :From msg))
 684   (let ((inner-parts (plist-get part :content))
 685         (start (point)))
 686     ;; Show all of the parts.
 687     (mapc (lambda (inner-part)
 688             (notmuch-show-insert-bodypart msg inner-part depth))
 689           inner-parts)
 690     (when notmuch-show-indent-multipart
 691       (indent-rigidly start (point) 1)))
 692   t)
 693
 694 (defun notmuch-show-insert-part-multipart/encrypted (msg part _content-type _nth depth button)
 695   (when button
 696     (button-put button 'face 'notmuch-crypto-part-header))
 697   ;; Insert a button detailing the encryption status.
 698   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
 699   ;; Insert a button detailing the signature status.
 700   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
 701                                           (notmuch-show-get-header :From msg))
 702   (let ((inner-parts (plist-get part :content))
 703         (start (point)))
 704     ;; Show all of the parts.
 705     (mapc (lambda (inner-part)
 706             (notmuch-show-insert-bodypart msg inner-part depth))
 707           inner-parts)
 708     (when notmuch-show-indent-multipart
 709       (indent-rigidly start (point) 1)))
 710   t)
 711
 712 (defun notmuch-show-insert-part-application/pgp-encrypted (_msg _part _content-type _nth _depth _button)
 713   t)
 714
 715 (defun notmuch-show-insert-part-multipart/* (msg part _content-type _nth depth _button)
 716   (let ((inner-parts (plist-get part :content))
 717         (start (point)))
 718     ;; Show all of the parts.
 719     (mapc (lambda (inner-part)
 720             (notmuch-show-insert-bodypart msg inner-part depth))
 721           inner-parts)
 722     (when notmuch-show-indent-multipart
 723       (indent-rigidly start (point) 1)))
 724   t)
 725
 726 (defun notmuch-show-insert-part-message/rfc822 (msg part _content-type _nth depth _button)
 727   (let ((message (car (plist-get part :content))))
 728     (and
 729      message
 730      (let ((body (car (plist-get message :body)))
 731            (start (point)))
 732        ;; Override `notmuch-message-headers' to force `From' to be
 733        ;; displayed.
 734        (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 735          (notmuch-show-insert-headers (plist-get message :headers)))
 736        ;; Blank line after headers to be compatible with the normal
 737        ;; message display.
 738        (insert "\n")
 739        ;; Show the body
 740        (notmuch-show-insert-bodypart msg body depth)
 741        (when notmuch-show-indent-multipart
 742          (indent-rigidly start (point) 1))
 743        t))))
 744
 745 (defun notmuch-show-insert-part-text/plain (msg part _content-type _nth depth button)
 746   ;; For backward compatibility we want to apply the text/plain hook
 747   ;; to the whole of the part including the part button if there is
 748   ;; one.
 749   (let ((start (if button
 750                    (button-start button)
 751                  (point))))
 752     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
 753     (save-excursion
 754       (save-restriction
 755         (narrow-to-region start (point-max))
 756         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 757   t)
 758
 759 (defun notmuch-show-insert-part-text/calendar (msg part _content-type _nth _depth _button)
 760   (insert (with-temp-buffer
 761             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
 762             ;; notmuch-get-bodypart-text does no newline conversion.
 763             ;; Replace CRLF with LF before icalendar can use it.
 764             (goto-char (point-min))
 765             (while (re-search-forward "\r\n" nil t)
 766               (replace-match "\n" nil nil))
 767             (let ((file (make-temp-file "notmuch-ical"))
 768                   result)
 769               (unwind-protect
 770                   (progn
 771                     (unless (icalendar-import-buffer file t)
 772                       (error "Icalendar import error. %s"
 773                              "See *icalendar-errors* for more information"))
 774                     (set-buffer (get-file-buffer file))
 775                     (setq result (buffer-substring (point-min) (point-max)))
 776                     (set-buffer-modified-p nil)
 777                     (kill-buffer (current-buffer)))
 778                 (delete-file file))
 779               result)))
 780   t)
 781
 782 ;; For backwards compatibility.
 783 (defun notmuch-show-insert-part-text/x-vcalendar (msg part _content-type _nth depth _button)
 784   (notmuch-show-insert-part-text/calendar msg part nil nil depth nil))
 785
 786 (when (version< emacs-version "25.3")
 787   ;; https://bugs.gnu.org/28350
 788   ;;
 789   ;; For newer emacs, we fall back to notmuch-show-insert-part-*/*
 790   ;; (see notmuch-show-handlers-for)
 791   (defun notmuch-show-insert-part-text/enriched
 792       (msg part content-type nth depth button)
 793     ;; By requiring enriched below, we ensure that the function
 794     ;; enriched-decode-display-prop is defined before it will be
 795     ;; shadowed by the letf below. Otherwise the version in
 796     ;; enriched.el may be loaded a bit later and used instead (for
 797     ;; the first time).
 798     (require 'enriched)
 799     (cl-letf (((symbol-function 'enriched-decode-display-prop)
 800                (lambda (start end &optional _param) (list start end))))
 801       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
 802
 803 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 804   ;; If we can deduce a MIME type from the filename of the attachment,
 805   ;; we return that.
 806   (and (plist-get part :filename)
 807        (let ((extension (file-name-extension (plist-get part :filename))))
 808          (and extension
 809               (progn
 810                 (mailcap-parse-mimetypes)
 811                 (let ((mime-type (mailcap-extension-to-mime extension)))
 812                   (and mime-type
 813                        (not (string-equal mime-type "application/octet-stream"))
 814                        mime-type)))))))
 815
 816 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
 817   (if (eq mm-text-html-renderer 'shr)
 818       ;; It's easier to drive shr ourselves than to work around the
 819       ;; goofy things `mm-shr' does (like irreversibly taking over
 820       ;; content ID handling).
 821       ;; FIXME: If we block an image, offer a button to load external
 822       ;; images.
 823       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
 824         (notmuch-show--insert-part-text/html-shr msg part))
 825     ;; Otherwise, let message-mode do the heavy lifting
 826     ;;
 827     ;; w3m sets up a keymap which "leaks" outside the invisible region
 828     ;; and causes strange effects in notmuch. We set
 829     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
 830     ;; set a keymap (so the normal notmuch-show-mode-map remains).
 831     (let ((mm-inline-text-html-with-w3m-keymap nil)
 832           ;; FIXME: If we block an image, offer a button to load external
 833           ;; images.
 834           (gnus-blocked-images notmuch-show-text/html-blocked-images)
 835           (w3m-ignored-image-url-regexp notmuch-show-text/html-blocked-images))
 836       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
 837
 838 ;;; Functions used by notmuch-show--insert-part-text/html-shr
 839
 840 (declare-function libxml-parse-html-region "xml.c")
 841 (declare-function shr-insert-document "shr")
 842
 843 (defun notmuch-show--insert-part-text/html-shr (msg part)
 844   ;; Make sure shr is loaded before we start let-binding its globals
 845   (require 'shr)
 846   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
 847                (with-temp-buffer
 848                  (insert (notmuch-get-bodypart-text msg part process-crypto))
 849                  (libxml-parse-html-region (point-min) (point-max)))))
 850         (shr-content-function
 851          (lambda (url)
 852            ;; shr strips the "cid:" part of URL, but doesn't
 853            ;; URL-decode it (see RFC 2392).
 854            (let ((cid (url-unhex-string url)))
 855              (car (notmuch-show--get-cid-content cid))))))
 856     (shr-insert-document dom)
 857     t))
 858
 859 (defun notmuch-show-insert-part-*/* (msg part content-type _nth _depth _button)
 860   ;; This handler _must_ succeed - it is the handler of last resort.
 861   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
 862   t)
 863
 864 ;;; Functions for determining how to handle MIME parts.
 865
 866 (defun notmuch-show-handlers-for (content-type)
 867   "Return a list of content handlers for a part of type CONTENT-TYPE."
 868   (let (result)
 869     (mapc (lambda (func)
 870             (when (functionp func)
 871               (push func result)))
 872           ;; Reverse order of prefrence.
 873           (list (intern (concat "notmuch-show-insert-part-*/*"))
 874                 (intern (concat "notmuch-show-insert-part-"
 875                                 (car (split-string content-type "/"))
 876                                 "/*"))
 877                 (intern (concat "notmuch-show-insert-part-" content-type))))
 878     result))
 879
 880 ;;; Parts
 881
 882 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
 883   ;; Run the handlers until one of them succeeds.
 884   (cl-loop for handler in (notmuch-show-handlers-for content-type)
 885            until (condition-case err
 886                      (funcall handler msg part content-type nth depth button)
 887                    ;; Specifying `debug' here lets the debugger run if
 888                    ;; `debug-on-error' is non-nil.
 889                    ((debug error)
 890                     (insert "!!! Bodypart handler `" (prin1-to-string handler)
 891                             "' threw an error:\n"
 892                             "!!! " (error-message-string err) "\n")
 893                     nil))))
 894
 895 (defun notmuch-show-create-part-overlays (button beg end)
 896   "Add an overlay to the part between BEG and END."
 897   ;; If there is no button (i.e., the part is text/plain and the first
 898   ;; part) or if the part has no content then we don't make the part
 899   ;; toggleable.
 900   (when (and button (/= beg end))
 901     (button-put button 'overlay (make-overlay beg end))
 902     ;; Return true if we created an overlay.
 903     t))
 904
 905 (defun notmuch-show-record-part-information (part beg end)
 906   "Store PART as a text property from BEG to END."
 907   ;; Record part information.  Since we already inserted subparts,
 908   ;; don't override existing :notmuch-part properties.
 909   (notmuch-map-text-property beg end :notmuch-part
 910                              (lambda (v) (or v part)))
 911   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
 912   ;; applied to the beginning of each line when we indent the
 913   ;; message.  Since we're operating on arbitrary renderer output,
 914   ;; watch out for sticky specs of t, which means all properties are
 915   ;; front-sticky/rear-nonsticky.
 916   (notmuch-map-text-property beg end 'front-sticky
 917                              (lambda (v)
 918                                (if (listp v)
 919                                    (cl-pushnew :notmuch-part v)
 920                                  v)))
 921   (notmuch-map-text-property beg end 'rear-nonsticky
 922                              (lambda (v)
 923                                (if (listp v)
 924                                    (cl-pushnew :notmuch-part v)
 925                                  v))))
 926
 927 (defun notmuch-show-lazy-part (part-args button)
 928   ;; Insert the lazy part after the button for the part. We would just
 929   ;; move to the start of the new line following the button and insert
 930   ;; the part but that point might have text properties (eg colours
 931   ;; from a message header etc) so instead we start from the last
 932   ;; character of the button by adding a newline and finish by
 933   ;; removing the extra newline from the end of the part.
 934   (save-excursion
 935     (goto-char (button-end button))
 936     (insert "\n")
 937     (let* ((inhibit-read-only t)
 938            ;; We need to use markers for the start and end of the part
 939            ;; because the part insertion functions do not guarantee
 940            ;; to leave point at the end of the part.
 941            (part-beg (copy-marker (point) nil))
 942            (part-end (copy-marker (point) t))
 943            ;; We have to save the depth as we can't find the depth
 944            ;; when narrowed.
 945            (depth (notmuch-show-get-depth)))
 946       (save-restriction
 947         (narrow-to-region part-beg part-end)
 948         (delete-region part-beg part-end)
 949         (apply #'notmuch-show-insert-bodypart-internal part-args)
 950         (indent-rigidly part-beg
 951                         part-end
 952                         (* notmuch-show-indent-messages-width depth)))
 953       (goto-char part-end)
 954       (delete-char 1)
 955       (notmuch-show-record-part-information (cadr part-args)
 956                                             (button-start button)
 957                                             part-end)
 958       ;; Create the overlay. If the lazy-part turned out to be empty/not
 959       ;; showable this returns nil.
 960       (notmuch-show-create-part-overlays button part-beg part-end))))
 961
 962 (defun notmuch-show-mime-type (part)
 963   "Return the correct mime-type to use for PART."
 964   (when-let ((content-type (plist-get part :content-type)))
 965     (setq content-type (downcase content-type))
 966     (or (and (string= content-type "application/octet-stream")
 967              (notmuch-show-get-mime-type-of-application/octet-stream part))
 968         (and (string= content-type "inline patch")
 969              "text/x-diff")
 970         content-type)))
 971
 972 ;; The following variable can be overridden by let bindings.
 973 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
 974   "Specify which function decides which part headers get inserted.
 975
 976 The function should take two parameters, PART and HIDE, and
 977 should return non-NIL if a header button should be inserted for
 978 this part.")
 979
 980 (defun notmuch-show-insert-header-p (part _hide)
 981   ;; Show all part buttons except for the first part if it is text/plain.
 982   (let ((mime-type (notmuch-show-mime-type part)))
 983     (not (and (string= mime-type "text/plain")
 984               (<= (plist-get part :id) 1)))))
 985
 986 (defun notmuch-show-reply-insert-header-p-never (_part _hide)
 987   nil)
 988
 989 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
 990   (let ((mime-type (notmuch-show-mime-type part)))
 991     (and (not (notmuch-match-content-type mime-type "multipart/*"))
 992          (not hide))))
 993
 994 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
 995   (let ((mime-type (notmuch-show-mime-type part)))
 996     (and (notmuch-match-content-type mime-type "text/*")
 997          (not hide))))
 998
 999 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
1000   "Insert the body part PART at depth DEPTH in the current thread.
1001
1002 HIDE determines whether to show or hide the part and the button
1003 as follows: If HIDE is nil, show the part and the button. If HIDE
1004 is t, hide the part initially and show the button."
1005   (let* ((content-type (plist-get part :content-type))
1006          (mime-type (notmuch-show-mime-type part))
1007          (nth (plist-get part :id))
1008          (long (and (notmuch-match-content-type mime-type "text/*")
1009                     (> notmuch-show-max-text-part-size 0)
1010                     (> (length (plist-get part :content))
1011                        notmuch-show-max-text-part-size)))
1012          (beg (point))
1013          ;; This default header-p function omits the part button for
1014          ;; the first (or only) part if this is text/plain.
1015          (button (and (funcall notmuch-show-insert-header-p-function part hide)
1016                       (notmuch-show-insert-part-header
1017                        nth mime-type
1018                        (and content-type (downcase content-type))
1019                        (plist-get part :filename))))
1020          ;; Hide the part initially if HIDE is t, or if it is too long
1021          ;; and we have a button to allow toggling.
1022          (show-part (not (or (equal hide t)
1023                              (and long button))))
1024          (content-beg (point)))
1025     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
1026     (plist-put part :computed-type mime-type)
1027     (if show-part
1028         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
1029       (when button
1030         (button-put button :notmuch-lazy-part
1031                     (list msg part mime-type nth depth button))))
1032     ;; Some of the body part handlers leave point somewhere up in the
1033     ;; part, so we make sure that we're down at the end.
1034     (goto-char (point-max))
1035     ;; Ensure that the part ends with a carriage return.
1036     (unless (bolp)
1037       (insert "\n"))
1038     ;; We do not create the overlay for hidden (lazy) parts until
1039     ;; they are inserted.
1040     (if show-part
1041         (notmuch-show-create-part-overlays button content-beg (point))
1042       (save-excursion
1043         (notmuch-show-toggle-part-invisibility button)))
1044     (notmuch-show-record-part-information part beg (point))))
1045
1046 (defun notmuch-show-insert-body (msg body depth)
1047   "Insert the body BODY at depth DEPTH in the current thread."
1048   ;; Register all content IDs for this message.  According to RFC
1049   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1050   ;; them as only global within a message.
1051   (notmuch-show--register-cids msg (car body))
1052   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1053
1054 (defun notmuch-show-make-symbol (type)
1055   (make-symbol (concat "notmuch-show-" type)))
1056
1057 (defun notmuch-show-strip-re (string)
1058   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1059
1060 (defvar notmuch-show-previous-subject "")
1061 (make-variable-buffer-local 'notmuch-show-previous-subject)
1062
1063 (defun notmuch-show-insert-msg (msg depth)
1064   "Insert the message MSG at depth DEPTH in the current thread."
1065   (let* ((headers (plist-get msg :headers))
1066          ;; Indentation causes the buffer offset of the start/end
1067          ;; points to move, so we must use markers.
1068          message-start message-end
1069          content-start content-end
1070          headers-start headers-end
1071          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1072     (setq message-start (point-marker))
1073     (notmuch-show-insert-headerline headers
1074                                     (or (and notmuch-show-relative-dates
1075                                              (plist-get msg :date_relative))
1076                                         (plist-get headers :Date))
1077                                     (plist-get msg :tags) depth)
1078     (setq content-start (point-marker))
1079     ;; Set `headers-start' to point after the 'Subject:' header to be
1080     ;; compatible with the existing implementation. This just sets it
1081     ;; to after the first header.
1082     (notmuch-show-insert-headers headers)
1083     (save-excursion
1084       (goto-char content-start)
1085       ;; If the subject of this message is the same as that of the
1086       ;; previous message, don't display it when this message is
1087       ;; collapsed.
1088       (unless (string= notmuch-show-previous-subject bare-subject)
1089         (forward-line 1))
1090       (setq headers-start (point-marker)))
1091     (setq headers-end (point-marker))
1092     (setq notmuch-show-previous-subject bare-subject)
1093     ;; A blank line between the headers and the body.
1094     (insert "\n")
1095     (notmuch-show-insert-body msg (plist-get msg :body)
1096                               (if notmuch-show-indent-content depth 0))
1097     ;; Ensure that the body ends with a newline.
1098     (unless (bolp)
1099       (insert "\n"))
1100     (setq content-end (point-marker))
1101     ;; Indent according to the depth in the thread.
1102     (when notmuch-show-indent-content
1103       (indent-rigidly content-start
1104                       content-end
1105                       (* notmuch-show-indent-messages-width depth)))
1106     (setq message-end (point-max-marker))
1107     ;; Save the extents of this message over the whole text of the
1108     ;; message.
1109     (put-text-property message-start message-end
1110                        :notmuch-message-extent
1111                        (cons message-start message-end))
1112     ;; Create overlays used to control visibility
1113     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1114     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1115     (plist-put msg :depth depth)
1116     ;; Save the properties for this message. Currently this saves the
1117     ;; entire message (augmented it with other stuff), which seems
1118     ;; like overkill. We might save a reduced subset (for example, not
1119     ;; the content).
1120     (notmuch-show-set-message-properties msg)
1121     ;; Set header visibility.
1122     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1123     ;; Message visibility depends on whether it matched the search
1124     ;; criteria.
1125     (notmuch-show-message-visible msg (and (plist-get msg :match)
1126                                            (not (plist-get msg :excluded))))))
1127
1128 ;;; Toggle commands
1129
1130 (defun notmuch-show-toggle-process-crypto ()
1131   "Toggle the processing of cryptographic MIME parts."
1132   (interactive)
1133   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1134   (message (if notmuch-show-process-crypto
1135                "Processing cryptographic MIME parts."
1136              "Not processing cryptographic MIME parts."))
1137   (notmuch-show-refresh-view))
1138
1139 (defun notmuch-show-toggle-elide-non-matching ()
1140   "Toggle the display of non-matching messages."
1141   (interactive)
1142   (setq notmuch-show-elide-non-matching-messages
1143         (not notmuch-show-elide-non-matching-messages))
1144   (message (if notmuch-show-elide-non-matching-messages
1145                "Showing matching messages only."
1146              "Showing all messages."))
1147   (notmuch-show-refresh-view))
1148
1149 (defun notmuch-show-toggle-thread-indentation ()
1150   "Toggle the indentation of threads."
1151   (interactive)
1152   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1153   (message (if notmuch-show-indent-content
1154                "Content is indented."
1155              "Content is not indented."))
1156   (notmuch-show-refresh-view))
1157
1158 ;;; Main insert functions
1159
1160 (defun notmuch-show-insert-tree (tree depth)
1161   "Insert the message tree TREE at depth DEPTH in the current thread."
1162   (let ((msg (car tree))
1163         (replies (cadr tree)))
1164     ;; We test whether there is a message or just some replies.
1165     (when msg
1166       (notmuch-show-insert-msg msg depth))
1167     (notmuch-show-insert-thread replies (1+ depth))))
1168
1169 (defun notmuch-show-insert-thread (thread depth)
1170   "Insert the thread THREAD at depth DEPTH in the current forest."
1171   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1172
1173 (defun notmuch-show-insert-forest (forest)
1174   "Insert the forest of threads FOREST."
1175   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1176
1177 ;;; Link buttons
1178
1179 (defvar notmuch-id-regexp
1180   (concat
1181    ;; Match the id: prefix only if it begins a word (to disallow, for
1182    ;; example, matching cid:).
1183    "\\<id:\\("
1184    ;; If the term starts with a ", then parse Xapian's quoted boolean
1185    ;; term syntax, which allows for anything as long as embedded
1186    ;; double quotes escaped by doubling them.  We also disallow
1187    ;; newlines (which Xapian allows) to prevent runaway terms.
1188    "\"\\([^\"\n]\\|\"\"\\)*\""
1189    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1190    ;; next space or ).  We disallow [.,;] as the last character
1191    ;; because these are probably part of the surrounding text, and not
1192    ;; part of the id.  This doesn't match single character ids; meh.
1193    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1194    "\\)")
1195   "The regexp used to match id: links in messages.")
1196
1197 (defvar notmuch-mid-regexp
1198   ;; goto-address-url-regexp matched cid: links, which have the same
1199   ;; grammar as the message ID part of a mid: link.  Construct the
1200   ;; regexp using the same technique as goto-address-url-regexp.
1201   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1202   "The regexp used to match mid: links in messages.
1203
1204 See RFC 2392.")
1205
1206 (defun notmuch-show-buttonise-links (start end)
1207   "Buttonise URLs and mail addresses between START and END.
1208
1209 This also turns id:\"<message id>\"-parts and mid: links into
1210 buttons for a corresponding notmuch search."
1211   (goto-address-fontify-region start end)
1212   (save-excursion
1213     (let (links
1214           (beg-line (progn (goto-char start) (line-beginning-position)))
1215           (end-line (progn (goto-char end) (line-end-position))))
1216       (goto-char beg-line)
1217       (while (re-search-forward notmuch-id-regexp end-line t)
1218         (push (list (match-beginning 0) (match-end 0)
1219                     (match-string-no-properties 0)) links))
1220       (goto-char beg-line)
1221       (while (re-search-forward notmuch-mid-regexp end-line t)
1222         (let* ((mid-cid (match-string-no-properties 1))
1223                (mid (save-match-data
1224                       (string-match "^[^/]*" mid-cid)
1225                       (url-unhex-string (match-string 0 mid-cid)))))
1226           (push (list (match-beginning 0) (match-end 0)
1227                       (notmuch-id-to-query mid)) links)))
1228       (pcase-dolist (`(,beg ,end ,link) links)
1229         ;; Remove the overlay created by goto-address-mode
1230         (remove-overlays beg end 'goto-address t)
1231         (make-text-button beg end
1232                           :type 'notmuch-button-type
1233                           'action `(lambda (arg)
1234                                      (notmuch-show ,link current-prefix-arg))
1235                           'follow-link t
1236                           'help-echo "Mouse-1, RET: search for this message"
1237                           'face goto-address-mail-face)))))
1238
1239 ;;; Show command
1240
1241 ;;;###autoload
1242 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1243   "Run \"notmuch show\" with the given thread ID and display results.
1244
1245 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1246
1247 The optional PARENT-BUFFER is the notmuch-search buffer from
1248 which this notmuch-show command was executed, (so that the
1249 next thread from that buffer can be show when done with this
1250 one).
1251
1252 The optional QUERY-CONTEXT is a notmuch search term. Only
1253 messages from the thread matching this search term are shown if
1254 non-nil.
1255
1256 The optional BUFFER-NAME provides the name of the buffer in
1257 which the message thread is shown. If it is nil (which occurs
1258 when the command is called interactively) the argument to the
1259 function is used.
1260
1261 Returns the buffer containing the messages, or NIL if no messages
1262 matched."
1263   (interactive "sNotmuch show: \nP")
1264   (let ((buffer-name (generate-new-buffer-name
1265                       (or buffer-name
1266                           (concat "*notmuch-" thread-id "*"))))
1267         ;; We override mm-inline-override-types to stop application/*
1268         ;; parts from being displayed unless the user has customized
1269         ;; it themselves.
1270         (mm-inline-override-types
1271          (if (equal mm-inline-override-types
1272                     (eval (car (get 'mm-inline-override-types 'standard-value))))
1273              (cons "application/*" mm-inline-override-types)
1274            mm-inline-override-types)))
1275     (pop-to-buffer-same-window (get-buffer-create buffer-name))
1276     ;; No need to track undo information for this buffer.
1277     (setq buffer-undo-list t)
1278     (notmuch-show-mode)
1279     ;; Set various buffer local variables to their appropriate initial
1280     ;; state. Do this after enabling `notmuch-show-mode' so that they
1281     ;; aren't wiped out.
1282     (setq notmuch-show-thread-id thread-id)
1283     (setq notmuch-show-parent-buffer parent-buffer)
1284     (setq notmuch-show-query-context
1285           (if (or (string= query-context "")
1286                   (string= query-context "*"))
1287               nil
1288             query-context))
1289     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1290     ;; If `elide-toggle', invert the default value.
1291     (setq notmuch-show-elide-non-matching-messages
1292           (if elide-toggle
1293               (not notmuch-show-only-matching-messages)
1294             notmuch-show-only-matching-messages))
1295     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1296     (jit-lock-register #'notmuch-show-buttonise-links)
1297     (notmuch-tag-clear-cache)
1298     (let ((inhibit-read-only t))
1299       (if (notmuch-show--build-buffer)
1300           ;; Messages were inserted into the buffer.
1301           (current-buffer)
1302         ;; No messages were inserted - presumably none matched the
1303         ;; query.
1304         (kill-buffer (current-buffer))
1305         (ding)
1306         (message "No messages matched the query!")
1307         nil))))
1308
1309 (defun notmuch-show--build-queries (thread context)
1310   "Return a list of queries to try for this search.
1311
1312 THREAD and CONTEXT are both strings, though CONTEXT may be nil.
1313 When CONTEXT is not nil, the first query is the conjunction of it
1314 and THREAD.  The next query is THREAD alone, and serves as a
1315 fallback if the prior matches no messages."
1316   (let (queries)
1317     (push (list thread) queries)
1318     (when context
1319       (push (list thread "and (" context ")") queries))
1320     queries))
1321
1322 (defun notmuch-show--build-buffer (&optional state)
1323   "Display messages matching the current buffer context.
1324
1325 Apply the previously saved STATE if supplied, otherwise show the
1326 first relevant message.
1327
1328 If no messages match the query return NIL."
1329   (let* ((cli-args (list "--exclude=false"))
1330          (cli-args (if notmuch-show-elide-non-matching-messages (cons "--entire-thread=false" cli-args) cli-args))
1331          ;; "part 0 is the whole message (headers and body)" notmuch-show(1)
1332          (cli-args (if notmuch-show-single-message (cons "--part=0" cli-args) cli-args))
1333          (queries (notmuch-show--build-queries
1334                    notmuch-show-thread-id notmuch-show-query-context))
1335          (forest nil)
1336          ;; Must be reset every time we are going to start inserting
1337          ;; messages into the buffer.
1338          (notmuch-show-previous-subject ""))
1339     ;; Use results from the first query that returns some.
1340     (while (and (not forest) queries)
1341       (setq forest (notmuch-query-get-threads
1342                     (append cli-args (list "'") (car queries) (list "'"))))
1343       (when (and forest notmuch-show-single-message)
1344         (setq forest (list (list (list forest)))))
1345       (setq queries (cdr queries)))
1346     (when forest
1347       (notmuch-show-insert-forest forest)
1348       ;; Store the original tags for each message so that we can
1349       ;; display changes.
1350       (notmuch-show-mapc
1351        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1352       ;; Set the header line to the subject of the first message.
1353       (when notmuch-show-header-line
1354         (setq header-line-format
1355               (replace-regexp-in-string "%" "%%"
1356                                         (notmuch-sanitize
1357                                          (notmuch-show-strip-re
1358                                           (notmuch-show-get-subject))))))
1359       (run-hooks 'notmuch-show-hook)
1360       (if state
1361           (notmuch-show-apply-state state)
1362         ;; With no state to apply, just go to the first message.
1363         (notmuch-show-goto-first-wanted-message)))
1364     ;; Report back to the caller whether any messages matched.
1365     forest))
1366
1367 ;;; Refresh command
1368
1369 (defun notmuch-show-capture-state ()
1370   "Capture the state of the current buffer.
1371
1372 This includes:
1373  - the list of open messages,
1374  - the combination of current message id with/for each visible window."
1375   (let* ((win-list (get-buffer-window-list (current-buffer) nil t))
1376          (win-id-combo (mapcar (lambda (win)
1377                                  (with-selected-window win
1378                                    (list win (notmuch-show-get-message-id))))
1379                                win-list)))
1380     (list win-id-combo (notmuch-show-get-message-ids-for-open-messages))))
1381
1382 (defun notmuch-show-get-query ()
1383   "Return the current query in this show buffer."
1384   (if notmuch-show-query-context
1385       (concat notmuch-show-thread-id
1386               " and ("
1387               notmuch-show-query-context
1388               ")")
1389     notmuch-show-thread-id))
1390
1391 (defun notmuch-show-goto-message (msg-id)
1392   "Go to message with msg-id."
1393   (goto-char (point-min))
1394   (unless (cl-loop if (string= msg-id (notmuch-show-get-message-id))
1395                    return t
1396                    until (not (notmuch-show-goto-message-next)))
1397     (goto-char (point-min))
1398     (message "Message-id not found."))
1399   (notmuch-show-message-adjust))
1400
1401 (defun notmuch-show-apply-state (state)
1402   "Apply STATE to the current buffer.
1403
1404 This includes:
1405  - opening the messages previously opened,
1406  - closing all other messages,
1407  - moving to the correct current message in every displayed window."
1408   (let ((win-msg-alist (car state))
1409         (open (cadr state)))
1410     ;; Open those that were open.
1411     (goto-char (point-min))
1412     (cl-loop do (notmuch-show-message-visible
1413                  (notmuch-show-get-message-properties)
1414                  (member (notmuch-show-get-message-id) open))
1415              until (not (notmuch-show-goto-message-next)))
1416     (dolist (win-msg-pair win-msg-alist)
1417       (with-selected-window (car win-msg-pair)
1418         ;; Go to the previously open message in this window
1419         (notmuch-show-goto-message (cadr win-msg-pair))))))
1420
1421 (defun notmuch-show-refresh-view (&optional reset-state)
1422   "Refresh the current view.
1423
1424 Refreshes the current view, observing changes in display
1425 preferences. If invoked with a prefix argument (or RESET-STATE is
1426 non-nil) then the state of the buffer (open/closed messages) is
1427 reset based on the original query."
1428   (interactive "P")
1429   (let ((inhibit-read-only t)
1430         (state (unless reset-state
1431                  (notmuch-show-capture-state))))
1432     ;; `erase-buffer' does not seem to remove overlays, which can lead
1433     ;; to weird effects such as remaining images, so remove them
1434     ;; manually.
1435     (remove-overlays)
1436     (erase-buffer)
1437     (unless (notmuch-show--build-buffer state)
1438       ;; No messages were inserted.
1439       (kill-buffer (current-buffer))
1440       (ding)
1441       (message "Refreshing the buffer resulted in no messages!"))))
1442
1443 ;;; Keymaps
1444
1445 (defvar notmuch-show-stash-map
1446   (let ((map (make-sparse-keymap)))
1447     (define-key map "c" 'notmuch-show-stash-cc)
1448     (define-key map "d" 'notmuch-show-stash-date)
1449     (define-key map "F" 'notmuch-show-stash-filename)
1450     (define-key map "f" 'notmuch-show-stash-from)
1451     (define-key map "i" 'notmuch-show-stash-message-id)
1452     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1453     (define-key map "s" 'notmuch-show-stash-subject)
1454     (define-key map "T" 'notmuch-show-stash-tags)
1455     (define-key map "t" 'notmuch-show-stash-to)
1456     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1457     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1458     (define-key map "G" 'notmuch-show-stash-git-send-email)
1459     (define-key map "?" 'notmuch-subkeymap-help)
1460     map)
1461   "Submap for stash commands.")
1462 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1463
1464 (defvar notmuch-show-part-map
1465   (let ((map (make-sparse-keymap)))
1466     (define-key map "s" 'notmuch-show-save-part)
1467     (define-key map "v" 'notmuch-show-view-part)
1468     (define-key map "o" 'notmuch-show-interactively-view-part)
1469     (define-key map "|" 'notmuch-show-pipe-part)
1470     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1471     (define-key map "?" 'notmuch-subkeymap-help)
1472     map)
1473   "Submap for part commands.")
1474 (fset 'notmuch-show-part-map notmuch-show-part-map)
1475
1476 (defvar notmuch-show-mode-map
1477   (let ((map (make-sparse-keymap)))
1478     (set-keymap-parent map notmuch-common-keymap)
1479     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1480     (define-key map "U" 'notmuch-unthreaded-from-show-current-query)
1481     (define-key map (kbd "<C-tab>") 'widget-backward)
1482     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1483     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1484     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1485     (define-key map "f" 'notmuch-show-forward-message)
1486     (define-key map "F" 'notmuch-show-forward-open-messages)
1487     (define-key map "b" 'notmuch-show-resend-message)
1488     (define-key map "l" 'notmuch-show-filter-thread)
1489     (define-key map "r" 'notmuch-show-reply-sender)
1490     (define-key map "R" 'notmuch-show-reply)
1491     (define-key map "|" 'notmuch-show-pipe-message)
1492     (define-key map "w" 'notmuch-show-save-attachments)
1493     (define-key map "V" 'notmuch-show-view-raw-message)
1494     (define-key map "e" 'notmuch-show-resume-message)
1495     (define-key map "c" 'notmuch-show-stash-map)
1496     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1497     (define-key map "k" 'notmuch-tag-jump)
1498     (define-key map "*" 'notmuch-show-tag-all)
1499     (define-key map "-" 'notmuch-show-remove-tag)
1500     (define-key map "+" 'notmuch-show-add-tag)
1501     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1502     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1503     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1504     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1505     (define-key map "N" 'notmuch-show-next-message)
1506     (define-key map "P" 'notmuch-show-previous-message)
1507     (define-key map "n" 'notmuch-show-next-open-message)
1508     (define-key map "p" 'notmuch-show-previous-open-message)
1509     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1510     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1511     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1512     (define-key map " " 'notmuch-show-advance-and-archive)
1513     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1514     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1515     (define-key map "#" 'notmuch-show-print-message)
1516     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1517     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1518     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1519     (define-key map "t" 'toggle-truncate-lines)
1520     (define-key map "." 'notmuch-show-part-map)
1521     (define-key map "B" 'notmuch-show-browse-urls)
1522     map)
1523   "Keymap for \"notmuch show\" buffers.")
1524
1525 ;;; Mode
1526
1527 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1528   "Major mode for viewing a thread with notmuch.
1529
1530 This buffer contains the results of the \"notmuch show\" command
1531 for displaying a single thread of email from your email archives.
1532
1533 By default, various components of email messages, (citations,
1534 signatures, already-read messages), are hidden. You can make
1535 these parts visible by clicking with the mouse button or by
1536 pressing RET after positioning the cursor on a hidden part, (for
1537 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1538
1539 Reading the thread sequentially is well-supported by pressing
1540 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1541 to the next message, or advance to the next thread (if already on
1542 the last message of a thread).
1543
1544 Other commands are available to read or manipulate the thread
1545 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1546 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1547 without scrolling through with \\[notmuch-show-advance-and-archive]).
1548
1549 You can add or remove arbitrary tags from the current message with
1550 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1551
1552 All currently available key bindings:
1553
1554 \\{notmuch-show-mode-map}"
1555   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1556   (setq buffer-read-only t)
1557   (setq truncate-lines t)
1558   (setq imenu-prev-index-position-function
1559         #'notmuch-show-imenu-prev-index-position-function)
1560   (setq imenu-extract-index-name-function
1561         #'notmuch-show-imenu-extract-index-name-function))
1562
1563 ;;; Tree commands
1564
1565 (defun notmuch-tree-from-show-current-query ()
1566   "Call notmuch tree with the current query."
1567   (interactive)
1568   (notmuch-tree notmuch-show-thread-id
1569                 notmuch-show-query-context
1570                 (notmuch-show-get-message-id)))
1571
1572 (defun notmuch-unthreaded-from-show-current-query ()
1573   "Call notmuch unthreaded with the current query."
1574   (interactive)
1575   (notmuch-unthreaded notmuch-show-thread-id
1576                       notmuch-show-query-context
1577                       (notmuch-show-get-message-id)))
1578
1579 ;;; Movement related functions.
1580
1581 (defun notmuch-show-move-to-message-top ()
1582   (goto-char (notmuch-show-message-top)))
1583
1584 (defun notmuch-show-move-to-message-bottom ()
1585   (goto-char (notmuch-show-message-bottom)))
1586
1587 ;; There's some strangeness here where a text property applied to a
1588 ;; region a->b is not found when point is at b. We walk backwards
1589 ;; until finding the property.
1590 (defun notmuch-show-message-extent ()
1591   "Return a cons cell containing the start and end buffer offset
1592 of the current message."
1593   (let (r)
1594     (save-excursion
1595       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1596         (backward-char)))
1597     r))
1598
1599 (defun notmuch-show-message-top ()
1600   (car (notmuch-show-message-extent)))
1601
1602 (defun notmuch-show-message-bottom ()
1603   (cdr (notmuch-show-message-extent)))
1604
1605 (defun notmuch-show-goto-message-next ()
1606   (let ((start (point)))
1607     (notmuch-show-move-to-message-bottom)
1608     (if (not (eobp))
1609         t
1610       (goto-char start)
1611       nil)))
1612
1613 (defun notmuch-show-goto-message-previous ()
1614   (notmuch-show-move-to-message-top)
1615   (if (bobp)
1616       nil
1617     (backward-char)
1618     (notmuch-show-move-to-message-top)
1619     t))
1620
1621 (defun notmuch-show-mapc (function)
1622   "Iterate through all messages in the current thread with
1623 `notmuch-show-goto-message-next' and call FUNCTION for side
1624 effects."
1625   (save-excursion
1626     (goto-char (point-min))
1627     (cl-loop do (funcall function)
1628              while (notmuch-show-goto-message-next))))
1629
1630 ;;; Functions relating to the visibility of messages and their components.
1631
1632 (defun notmuch-show-message-visible (props visible-p)
1633   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1634   (notmuch-show-set-prop :message-visible visible-p props))
1635
1636 (defun notmuch-show-headers-visible (props visible-p)
1637   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1638   (notmuch-show-set-prop :headers-visible visible-p props))
1639
1640 ;;; Functions for setting and getting attributes of the current message.
1641
1642 (defun notmuch-show-set-message-properties (props)
1643   (save-excursion
1644     (notmuch-show-move-to-message-top)
1645     (put-text-property (point) (+ (point) 1)
1646                        :notmuch-message-properties props)))
1647
1648 (defun notmuch-show-get-message-properties ()
1649   "Return the properties of the current message as a plist.
1650
1651 Some useful entries are:
1652 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1653 :body - Body of the message
1654 :tags - Tags for this message"
1655   (save-excursion
1656     (notmuch-show-move-to-message-top)
1657     (get-text-property (point) :notmuch-message-properties)))
1658
1659 (defun notmuch-show-get-part-properties ()
1660   "Return the properties of the innermost part containing point.
1661
1662 This is the part property list retrieved from the CLI.  Signals
1663 an error if there is no part containing point."
1664   (or (get-text-property (point) :notmuch-part)
1665       (error "No message part here")))
1666
1667 (defun notmuch-show-set-prop (prop val &optional props)
1668   (let ((inhibit-read-only t)
1669         (props (or props
1670                    (notmuch-show-get-message-properties))))
1671     (plist-put props prop val)
1672     (notmuch-show-set-message-properties props)))
1673
1674 (defun notmuch-show-get-prop (prop &optional props)
1675   "Get property PROP from current message in show or tree mode.
1676
1677 It gets property PROP from PROPS or, if PROPS is nil, the current
1678 message in either tree or show. This means that several utility
1679 functions in notmuch-show can be used directly by notmuch-tree as
1680 they just need the correct message properties."
1681   (plist-get (or props
1682                  (cond ((eq major-mode 'notmuch-show-mode)
1683                         (notmuch-show-get-message-properties))
1684                        ((eq major-mode 'notmuch-tree-mode)
1685                         (notmuch-tree-get-message-properties))
1686                        (t nil)))
1687              prop))
1688
1689 (defun notmuch-show-get-message-id (&optional bare)
1690   "Return an id: query for the Message-Id of the current message.
1691
1692 If optional argument BARE is non-nil, return
1693 the Message-Id without id: prefix and escaping."
1694   (if bare
1695       (notmuch-show-get-prop :id)
1696     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1697
1698 (defun notmuch-show-get-messages-ids ()
1699   "Return all id: queries of messages in the current thread."
1700   (let ((message-ids))
1701     (notmuch-show-mapc
1702      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1703     message-ids))
1704
1705 (defun notmuch-show-get-messages-ids-search ()
1706   "Return a search string for all message ids of messages in the
1707 current thread."
1708   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1709
1710 ;; dme: Would it make sense to use a macro for many of these?
1711
1712 ;; XXX TODO figure out what to do about multiple filenames
1713 (defun notmuch-show-get-filename ()
1714   "Return the filename of the current message."
1715   (car (notmuch-show-get-prop :filename)))
1716
1717 (defun notmuch-show-get-header (header &optional props)
1718   "Return the named header of the current message, if any."
1719   (plist-get (notmuch-show-get-prop :headers props) header))
1720
1721 (defun notmuch-show-get-cc ()
1722   (notmuch-show-get-header :Cc))
1723
1724 (defun notmuch-show-get-date ()
1725   (notmuch-show-get-header :Date))
1726
1727 (defun notmuch-show-get-timestamp ()
1728   (notmuch-show-get-prop :timestamp))
1729
1730 (defun notmuch-show-get-from ()
1731   (notmuch-show-get-header :From))
1732
1733 (defun notmuch-show-get-subject ()
1734   (notmuch-show-get-header :Subject))
1735
1736 (defun notmuch-show-get-to ()
1737   (notmuch-show-get-header :To))
1738
1739 (defun notmuch-show-get-depth ()
1740   (notmuch-show-get-prop :depth))
1741
1742 (defun notmuch-show-set-tags (tags)
1743   "Set the tags of the current message."
1744   (notmuch-show-set-prop :tags tags)
1745   (notmuch-show-update-tags tags))
1746
1747 (defun notmuch-show-get-tags ()
1748   "Return the tags of the current message."
1749   (notmuch-show-get-prop :tags))
1750
1751 (defun notmuch-show-message-visible-p ()
1752   "Is the current message visible?"
1753   (notmuch-show-get-prop :message-visible))
1754
1755 (defun notmuch-show-headers-visible-p ()
1756   "Are the headers of the current message visible?"
1757   (notmuch-show-get-prop :headers-visible))
1758
1759 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1760      "Mark the current message as unread.")
1761 (defun notmuch-show-mark-read (&optional unread)
1762   "Mark the current message as read.
1763
1764 Mark the current message as read by applying the tag changes in
1765 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1766 default). If a prefix argument is given, the message will be
1767 marked as unread, i.e. the tag changes in
1768 `notmuch-show-mark-read-tags' will be reversed."
1769   (interactive "P")
1770   (when notmuch-show-mark-read-tags
1771     (apply 'notmuch-show-tag-message
1772            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1773
1774 (defun notmuch-show-seen-current-message (_start _end)
1775   "Mark the current message read if it is open.
1776
1777 We only mark it read once: if it is changed back then that is a
1778 user decision and we should not override it."
1779   (when (and (notmuch-show-message-visible-p)
1780              (not (notmuch-show-get-prop :seen)))
1781     (notmuch-show-mark-read)
1782     (notmuch-show-set-prop :seen t)))
1783
1784 (defvar notmuch-show--seen-has-errored nil)
1785 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1786
1787 (defun notmuch-show-command-hook ()
1788   (when (eq major-mode 'notmuch-show-mode)
1789     ;; We need to redisplay to get window-start and window-end correct.
1790     (redisplay)
1791     (save-excursion
1792       (condition-case nil
1793           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1794         ((debug error)
1795          (unless notmuch-show--seen-has-errored
1796            (setq notmuch-show--seen-has-errored t)
1797            (setq header-line-format
1798                  (concat header-line-format
1799                          (propertize
1800                           "  [some mark read tag changes may have failed]"
1801                           'face font-lock-warning-face)))))))))
1802
1803 (defun notmuch-show-filter-thread (query)
1804   "Filter or LIMIT the current thread based on a new query string.
1805
1806 Reshows the current thread with matches defined by the new query-string."
1807   (interactive (list (notmuch-read-query "Filter thread: ")))
1808   (let ((msg-id (notmuch-show-get-message-id)))
1809     (setq notmuch-show-query-context (if (string-empty-p query) nil query))
1810     (notmuch-show-refresh-view t)
1811     (notmuch-show-goto-message msg-id)))
1812
1813 ;;; Functions for getting attributes of several messages in the current thread.
1814
1815 (defun notmuch-show-get-message-ids-for-open-messages ()
1816   "Return a list of all id: queries for open messages in the current thread."
1817   (save-excursion
1818     (let (message-ids done)
1819       (goto-char (point-min))
1820       (while (not done)
1821         (when (notmuch-show-message-visible-p)
1822           (setq message-ids
1823                 (append message-ids (list (notmuch-show-get-message-id)))))
1824         (setq done (not (notmuch-show-goto-message-next))))
1825       message-ids)))
1826
1827 ;;; Commands typically bound to keys.
1828
1829 (defun notmuch-show-advance ()
1830   "Advance through thread.
1831
1832 If the current message in the thread is not yet fully visible,
1833 scroll by a near screenful to read more of the message.
1834
1835 Otherwise, (the end of the current message is already within the
1836 current window), advance to the next open message."
1837   (interactive)
1838   (let* ((end-of-this-message (notmuch-show-message-bottom))
1839          (visible-end-of-this-message (1- end-of-this-message))
1840          (ret nil))
1841     (while (invisible-p visible-end-of-this-message)
1842       (setq visible-end-of-this-message
1843             (max (point-min)
1844                  (1- (previous-single-char-property-change
1845                       visible-end-of-this-message 'invisible)))))
1846     (cond
1847      ;; Ideally we would test `end-of-this-message' against the result
1848      ;; of `window-end', but that doesn't account for the fact that
1849      ;; the end of the message might be hidden.
1850      ((and visible-end-of-this-message
1851            (> visible-end-of-this-message (window-end)))
1852       ;; The bottom of this message is not visible - scroll.
1853       (scroll-up nil))
1854      ((not (= end-of-this-message (point-max)))
1855       ;; This is not the last message - move to the next visible one.
1856       (notmuch-show-next-open-message))
1857      ((not (= (point) (point-max)))
1858       ;; This is the last message, but the cursor is not at the end of
1859       ;; the buffer. Move it there.
1860       (goto-char (point-max)))
1861      (t
1862       ;; This is the last message - change the return value
1863       (setq ret t)))
1864     ret))
1865
1866 (defun notmuch-show-advance-and-archive ()
1867   "Advance through thread and archive.
1868
1869 This command is intended to be one of the simplest ways to
1870 process a thread of email. It works exactly like
1871 notmuch-show-advance, in that it scrolls through messages in a
1872 show buffer, except that when it gets to the end of the buffer it
1873 archives the entire current thread, (apply changes in
1874 `notmuch-archive-tags'), kills the buffer, and displays the next
1875 thread from the search from which this thread was originally
1876 shown."
1877   (interactive)
1878   (when (notmuch-show-advance)
1879     (notmuch-show-archive-thread-then-next)))
1880
1881 (defun notmuch-show-rewind ()
1882   "Backup through the thread (reverse scrolling compared to \
1883 \\[notmuch-show-advance-and-archive]).
1884
1885 Specifically, if the beginning of the previous email is fewer
1886 than `window-height' lines from the current point, move to it
1887 just like `notmuch-show-previous-message'.
1888
1889 Otherwise, just scroll down a screenful of the current message.
1890
1891 This command does not modify any message tags, (it does not undo
1892 any effects from previous calls to
1893 `notmuch-show-advance-and-archive'."
1894   (interactive)
1895   (let ((start-of-message (notmuch-show-message-top))
1896         (start-of-window (window-start)))
1897     (cond
1898      ;; Either this message is properly aligned with the start of the
1899      ;; window or the start of this message is not visible on the
1900      ;; screen - scroll.
1901      ((or (= start-of-message start-of-window)
1902           (< start-of-message start-of-window))
1903       (scroll-down)
1904       ;; If a small number of lines from the previous message are
1905       ;; visible, realign so that the top of the current message is at
1906       ;; the top of the screen.
1907       (when (<= (count-screen-lines (window-start) start-of-message)
1908                 next-screen-context-lines)
1909         (goto-char (notmuch-show-message-top))
1910         (notmuch-show-message-adjust))
1911       ;; Move to the top left of the window.
1912       (goto-char (window-start)))
1913      (t
1914       ;; Move to the previous message.
1915       (notmuch-show-previous-message)))))
1916
1917 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1918 (defun notmuch-show-reply (&optional prompt-for-sender)
1919   "Reply to the sender and all recipients of the current message."
1920   (interactive "P")
1921   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1922
1923 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1924 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1925   "Reply to the sender of the current message."
1926   (interactive "P")
1927   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1928
1929 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1930      "... and prompt for sender")
1931 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1932   "Forward the current message."
1933   (interactive "P")
1934   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1935                                     prompt-for-sender))
1936
1937 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1938      "... and prompt for sender")
1939 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1940   "Forward the currently open messages."
1941   (interactive "P")
1942   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1943     (unless open-messages
1944       (error "No open messages to forward."))
1945     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1946
1947 (defun notmuch-show-resend-message (addresses)
1948   "Resend the current message."
1949   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1950   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1951     (notmuch-show-view-raw-message)
1952     (message-resend addresses)
1953     (notmuch-bury-or-kill-this-buffer)))
1954
1955 (defun notmuch-show-message-adjust ()
1956   (recenter 0))
1957
1958 (defun notmuch-show-next-message (&optional pop-at-end)
1959   "Show the next message.
1960
1961 If a prefix argument is given and this is the last message in the
1962 thread, navigate to the next thread in the parent search buffer."
1963   (interactive "P")
1964   (if (notmuch-show-goto-message-next)
1965       (notmuch-show-message-adjust)
1966     (if pop-at-end
1967         (notmuch-show-next-thread)
1968       (goto-char (point-max)))))
1969
1970 (defun notmuch-show-previous-message ()
1971   "Show the previous message or the start of the current message."
1972   (interactive)
1973   (if (= (point) (notmuch-show-message-top))
1974       (notmuch-show-goto-message-previous)
1975     (notmuch-show-move-to-message-top))
1976   (notmuch-show-message-adjust))
1977
1978 (defun notmuch-show-next-open-message (&optional pop-at-end)
1979   "Show the next open message.
1980
1981 If a prefix argument is given and this is the last open message
1982 in the thread, navigate to the next thread in the parent search
1983 buffer. Return t if there was a next open message in the thread
1984 to show, nil otherwise."
1985   (interactive "P")
1986   (let (r)
1987     (while (and (setq r (notmuch-show-goto-message-next))
1988                 (not (notmuch-show-message-visible-p))))
1989     (if r
1990         (notmuch-show-message-adjust)
1991       (if pop-at-end
1992           (notmuch-show-next-thread)
1993         (goto-char (point-max))))
1994     r))
1995
1996 (defun notmuch-show-next-matching-message ()
1997   "Show the next matching message."
1998   (interactive)
1999   (let (r)
2000     (while (and (setq r (notmuch-show-goto-message-next))
2001                 (not (notmuch-show-get-prop :match))))
2002     (if r
2003         (notmuch-show-message-adjust)
2004       (goto-char (point-max)))))
2005
2006 (defun notmuch-show-open-if-matched ()
2007   "Open a message if it is matched (whether or not excluded)."
2008   (let ((props (notmuch-show-get-message-properties)))
2009     (notmuch-show-message-visible props (plist-get props :match))))
2010
2011 (defun notmuch-show-goto-first-wanted-message ()
2012   "Move to the first open message and mark it read."
2013   (goto-char (point-min))
2014   (unless (notmuch-show-message-visible-p)
2015     (notmuch-show-next-open-message))
2016   (when (eobp)
2017     ;; There are no matched non-excluded messages so open all matched
2018     ;; (necessarily excluded) messages and go to the first.
2019     (notmuch-show-mapc 'notmuch-show-open-if-matched)
2020     (force-window-update)
2021     (goto-char (point-min))
2022     (unless (notmuch-show-message-visible-p)
2023       (notmuch-show-next-open-message))))
2024
2025 (defun notmuch-show-previous-open-message ()
2026   "Show the previous open message."
2027   (interactive)
2028   (while (and (if (= (point) (notmuch-show-message-top))
2029                   (notmuch-show-goto-message-previous)
2030                 (notmuch-show-move-to-message-top))
2031               (not (notmuch-show-message-visible-p))))
2032   (notmuch-show-message-adjust))
2033
2034 (defun notmuch-show-view-raw-message ()
2035   "View the original source of the current message."
2036   (interactive)
2037   (let* ((id (notmuch-show-get-message-id))
2038          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
2039          (inhibit-read-only t))
2040     (pop-to-buffer-same-window buf)
2041     (erase-buffer)
2042     (let ((coding-system-for-read 'no-conversion))
2043       (notmuch--call-process notmuch-command nil t nil "show" "--format=raw" id))
2044     (goto-char (point-min))
2045     (set-buffer-modified-p nil)
2046     (setq buffer-read-only t)
2047     (view-buffer buf 'kill-buffer-if-not-modified)))
2048
2049 (defun notmuch-show-resume-message ()
2050   "Resume EDITING the current draft message."
2051   (interactive)
2052   (notmuch-draft-resume (notmuch-show-get-message-id)))
2053
2054 (put 'notmuch-show-pipe-message 'notmuch-doc
2055      "Pipe the contents of the current message to a command.")
2056 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
2057      "Pipe the thread as an mbox to a command.")
2058 (defun notmuch-show-pipe-message (entire-thread command)
2059   "Pipe the contents of the current message (or thread) to COMMAND.
2060
2061 COMMAND will be executed with the raw contents of the current
2062 email message as stdin. Anything printed by the command to stdout
2063 or stderr will appear in the *notmuch-pipe* buffer.
2064
2065 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
2066 argument), COMMAND will receive all open messages in the current
2067 thread (formatted as an mbox) rather than only the current
2068 message."
2069   (interactive (let ((query-string (if current-prefix-arg
2070                                        "Pipe all open messages to command: "
2071                                      "Pipe message to command: ")))
2072                  (list current-prefix-arg (read-string query-string))))
2073   (let (shell-command)
2074     (if entire-thread
2075         (setq shell-command
2076               (concat notmuch-command " show --format=mbox --exclude=false "
2077                       (shell-quote-argument
2078                        (mapconcat 'identity
2079                                   (notmuch-show-get-message-ids-for-open-messages)
2080                                   " OR "))
2081                       " | " command))
2082       (setq shell-command
2083             (concat notmuch-command " show --format=raw "
2084                     (shell-quote-argument (notmuch-show-get-message-id))
2085                     " | " command)))
2086     (let ((cwd default-directory)
2087           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2088       (with-current-buffer buf
2089         (setq buffer-read-only t)
2090         (let ((inhibit-read-only t))
2091           (erase-buffer)
2092           ;; Use the originating buffer's working directory instead of
2093           ;; that of the pipe buffer.
2094           (cd cwd)
2095           (let ((exit-code (call-process-shell-command shell-command nil buf)))
2096             (goto-char (point-max))
2097             (set-buffer-modified-p nil)
2098             (unless (zerop exit-code)
2099               (pop-to-buffer buf)
2100               (message (format "Command '%s' exited abnormally with code %d"
2101                                shell-command exit-code)))))))))
2102
2103 (defun notmuch-show-tag-message (&rest tag-changes)
2104   "Change tags for the current message.
2105
2106 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2107   (let* ((current-tags (notmuch-show-get-tags))
2108          (new-tags (notmuch-update-tags current-tags tag-changes)))
2109     (unless (equal current-tags new-tags)
2110       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2111       (notmuch-show-set-tags new-tags))))
2112
2113 (defun notmuch-show-tag (tag-changes)
2114   "Change tags for the current message.
2115
2116 See `notmuch-tag' for information on the format of TAG-CHANGES."
2117   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2118                                                "Tag message")))
2119   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2120   (let* ((current-tags (notmuch-show-get-tags))
2121          (new-tags (notmuch-update-tags current-tags tag-changes)))
2122     (unless (equal current-tags new-tags)
2123       (notmuch-show-set-tags new-tags))))
2124
2125 (defun notmuch-show-tag-all (tag-changes)
2126   "Change tags for all messages in the current show buffer.
2127
2128 See `notmuch-tag' for information on the format of TAG-CHANGES."
2129   (interactive
2130    (list (let (tags)
2131            (notmuch-show-mapc
2132             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2133            (notmuch-read-tag-changes tags "Tag thread"))))
2134   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2135   (notmuch-show-mapc
2136    (lambda ()
2137      (let* ((current-tags (notmuch-show-get-tags))
2138             (new-tags (notmuch-update-tags current-tags tag-changes)))
2139        (unless (equal current-tags new-tags)
2140          (notmuch-show-set-tags new-tags))))))
2141
2142 (defun notmuch-show-add-tag (tag-changes)
2143   "Change tags for the current message (defaulting to add).
2144
2145 Same as `notmuch-show-tag' but sets initial input to '+'."
2146   (interactive
2147    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2148   (notmuch-show-tag tag-changes))
2149
2150 (defun notmuch-show-remove-tag (tag-changes)
2151   "Change tags for the current message (defaulting to remove).
2152
2153 Same as `notmuch-show-tag' but sets initial input to '-'."
2154   (interactive
2155    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2156   (notmuch-show-tag tag-changes))
2157
2158 (defun notmuch-show-toggle-visibility-headers ()
2159   "Toggle the visibility of the current message headers."
2160   (interactive)
2161   (let ((props (notmuch-show-get-message-properties)))
2162     (notmuch-show-headers-visible
2163      props
2164      (not (plist-get props :headers-visible))))
2165   (force-window-update))
2166
2167 (defun notmuch-show-toggle-message ()
2168   "Toggle the visibility of the current message."
2169   (interactive)
2170   (let ((props (notmuch-show-get-message-properties)))
2171     (notmuch-show-message-visible
2172      props
2173      (not (plist-get props :message-visible))))
2174   (force-window-update))
2175
2176 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2177 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2178 (defun notmuch-show-open-or-close-all ()
2179   "Set the visibility all of the messages in the current thread.
2180
2181 By default make all of the messages visible. With a prefix
2182 argument, hide all of the messages."
2183   (interactive)
2184   (save-excursion
2185     (goto-char (point-min))
2186     (cl-loop do (notmuch-show-message-visible
2187                  (notmuch-show-get-message-properties)
2188                  (not current-prefix-arg))
2189              until (not (notmuch-show-goto-message-next))))
2190   (force-window-update))
2191
2192 (defun notmuch-show-next-button ()
2193   "Advance point to the next button in the buffer."
2194   (interactive)
2195   (forward-button 1))
2196
2197 (defun notmuch-show-previous-button ()
2198   "Move point back to the previous button in the buffer."
2199   (interactive)
2200   (backward-button 1))
2201
2202 (defun notmuch-show-next-thread (&optional show previous)
2203   "Move to the next item in the search results, if any.
2204
2205 If SHOW is non-nil, open the next item in a show
2206 buffer. Otherwise just highlight the next item in the search
2207 buffer. If PREVIOUS is non-nil, move to the previous item in the
2208 search results instead."
2209   (interactive "P")
2210   (let ((parent-buffer notmuch-show-parent-buffer))
2211     (notmuch-bury-or-kill-this-buffer)
2212     (when (buffer-live-p parent-buffer)
2213       (switch-to-buffer parent-buffer)
2214       (and (if previous
2215                (notmuch-search-previous-thread)
2216              (notmuch-search-next-thread))
2217            show
2218            (notmuch-search-show-thread)))))
2219
2220 (defun notmuch-show-next-thread-show ()
2221   "Show the next thread in the search results, if any."
2222   (interactive)
2223   (notmuch-show-next-thread t))
2224
2225 (defun notmuch-show-previous-thread-show ()
2226   "Show the previous thread in the search results, if any."
2227   (interactive)
2228   (notmuch-show-next-thread t t))
2229
2230 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2231      "Un-archive each message in thread.")
2232 (defun notmuch-show-archive-thread (&optional unarchive)
2233   "Archive each message in thread.
2234
2235 Archive each message currently shown by applying the tag changes
2236 in `notmuch-archive-tags' to each. If a prefix argument is given,
2237 the messages will be \"unarchived\", i.e. the tag changes in
2238 `notmuch-archive-tags' will be reversed.
2239
2240 Note: This command is safe from any race condition of new messages
2241 being delivered to the same thread. It does not archive the
2242 entire thread, but only the messages shown in the current
2243 buffer."
2244   (interactive "P")
2245   (when notmuch-archive-tags
2246     (notmuch-show-tag-all
2247      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2248
2249 (defun notmuch-show-archive-thread-then-next ()
2250   "Archive all messages in the current buffer, then show next thread from search."
2251   (interactive)
2252   (notmuch-show-archive-thread)
2253   (notmuch-show-next-thread t))
2254
2255 (defun notmuch-show-archive-thread-then-exit ()
2256   "Archive all messages in the current buffer, then exit back to search results."
2257   (interactive)
2258   (notmuch-show-archive-thread)
2259   (notmuch-show-next-thread))
2260
2261 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2262      "Un-archive the current message.")
2263 (defun notmuch-show-archive-message (&optional unarchive)
2264   "Archive the current message.
2265
2266 Archive the current message by applying the tag changes in
2267 `notmuch-archive-tags' to it. If a prefix argument is given, the
2268 message will be \"unarchived\", i.e. the tag changes in
2269 `notmuch-archive-tags' will be reversed."
2270   (interactive "P")
2271   (when notmuch-archive-tags
2272     (apply 'notmuch-show-tag-message
2273            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2274
2275 (defun notmuch-show-archive-message-then-next-or-exit ()
2276   "Archive current message, then show next open message in current thread.
2277
2278 If at the last open message in the current thread, then exit back
2279 to search results."
2280   (interactive)
2281   (notmuch-show-archive-message)
2282   (notmuch-show-next-open-message t))
2283
2284 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2285   "Archive current message, then show next open message in current or next thread.
2286
2287 If at the last open message in the current thread, then show next
2288 thread from search."
2289   (interactive)
2290   (notmuch-show-archive-message)
2291   (unless (notmuch-show-next-open-message)
2292     (notmuch-show-next-thread t)))
2293
2294 (defun notmuch-show-stash-cc ()
2295   "Copy CC field of current message to kill-ring."
2296   (interactive)
2297   (notmuch-common-do-stash (notmuch-show-get-cc)))
2298
2299 (put 'notmuch-show-stash-date 'notmuch-prefix-doc
2300      "Copy timestamp of current message to kill-ring.")
2301 (defun notmuch-show-stash-date (&optional stash-timestamp)
2302   "Copy date of current message to kill-ring.
2303
2304 If invoked with a prefix argument, copy timestamp of current
2305 message to kill-ring."
2306   (interactive "P")
2307   (if stash-timestamp
2308       (notmuch-common-do-stash (format "%d" (notmuch-show-get-timestamp)))
2309     (notmuch-common-do-stash (notmuch-show-get-date))))
2310
2311 (defun notmuch-show-stash-filename ()
2312   "Copy filename of current message to kill-ring."
2313   (interactive)
2314   (notmuch-common-do-stash (notmuch-show-get-filename)))
2315
2316 (defun notmuch-show-stash-from ()
2317   "Copy From address of current message to kill-ring."
2318   (interactive)
2319   (notmuch-common-do-stash (notmuch-show-get-from)))
2320
2321 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2322      "Copy thread: query matching current thread to kill-ring.")
2323 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2324   "Copy id: query matching the current message to kill-ring.
2325
2326 If invoked with a prefix argument (or STASH-THREAD-ID is
2327 non-nil), copy thread: query matching the current thread to
2328 kill-ring."
2329   (interactive "P")
2330   (if stash-thread-id
2331       (notmuch-common-do-stash notmuch-show-thread-id)
2332     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2333
2334 (defun notmuch-show-stash-message-id-stripped ()
2335   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2336   (interactive)
2337   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2338
2339 (defun notmuch-show-stash-subject ()
2340   "Copy Subject field of current message to kill-ring."
2341   (interactive)
2342   (notmuch-common-do-stash (notmuch-show-get-subject)))
2343
2344 (defun notmuch-show-stash-tags ()
2345   "Copy tags of current message to kill-ring as a comma separated list."
2346   (interactive)
2347   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2348
2349 (defun notmuch-show-stash-to ()
2350   "Copy To address of current message to kill-ring."
2351   (interactive)
2352   (notmuch-common-do-stash (notmuch-show-get-to)))
2353
2354 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2355   "Copy an ML Archive URI for the current message to the kill-ring.
2356
2357 This presumes that the message is available at the selected Mailing List Archive.
2358
2359 If optional argument MLA is non-nil, use the provided key instead of prompting
2360 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2361   (interactive)
2362   (let ((url (cdr (assoc
2363                    (or mla
2364                        (let ((completion-ignore-case t))
2365                          (completing-read
2366                           "Mailing List Archive: "
2367                           notmuch-show-stash-mlarchive-link-alist
2368                           nil t nil nil
2369                           notmuch-show-stash-mlarchive-link-default)))
2370                    notmuch-show-stash-mlarchive-link-alist))))
2371     (notmuch-common-do-stash
2372      (if (functionp url)
2373          (funcall url (notmuch-show-get-message-id t))
2374        (concat url (notmuch-show-get-message-id t))))))
2375
2376 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2377   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2378
2379 This presumes that the message is available at the selected Mailing List Archive.
2380
2381 If optional argument MLA is non-nil, use the provided key instead of prompting
2382 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2383   (interactive)
2384   (notmuch-show-stash-mlarchive-link mla)
2385   (browse-url (current-kill 0 t)))
2386
2387 (defun notmuch-show-stash-git-helper (addresses prefix)
2388   "Normalize all ADDRESSES while adding PREFIX.
2389 Escape, trim, quote and add PREFIX to each address in list
2390 of ADDRESSES, and return the result as a single string."
2391   (mapconcat (lambda (x)
2392                (concat prefix "\""
2393                        ;; escape double-quotes
2394                        (replace-regexp-in-string
2395                         "\"" "\\\\\""
2396                         ;; trim leading and trailing spaces
2397                         (replace-regexp-in-string
2398                          "\\(^ *\\| *$\\)" ""
2399                          x)) "\""))
2400              addresses " "))
2401
2402 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2403      "Copy From/To/Cc of current message to kill-ring.
2404 Use a form suitable for pasting to git send-email command line.")
2405
2406 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2407   "Copy From/To/Cc/Message-Id of current message to kill-ring.
2408 Use a form suitable for pasting to git send-email command line.
2409
2410 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2411 omit --in-reply-to=<Message-Id>."
2412   (interactive "P")
2413   (notmuch-common-do-stash
2414    (mapconcat 'identity
2415               (remove ""
2416                       (list
2417                        (notmuch-show-stash-git-helper
2418                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2419                        (notmuch-show-stash-git-helper
2420                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2421                        (notmuch-show-stash-git-helper
2422                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2423                        (unless no-in-reply-to
2424                          (notmuch-show-stash-git-helper
2425                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2426               " ")))
2427
2428 ;;; Interactive part functions and their helpers
2429
2430 (defun notmuch-show-generate-part-buffer (msg part)
2431   "Return a temporary buffer containing the specified part's content."
2432   (let ((buf (generate-new-buffer " *notmuch-part*"))
2433         (process-crypto notmuch-show-process-crypto))
2434     (with-current-buffer buf
2435       ;; This is always used in the content of mm handles, which
2436       ;; expect undecoded, binary part content.
2437       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2438     buf))
2439
2440 (defun notmuch-show-current-part-handle (&optional mime-type)
2441   "Return an mm-handle for the part containing point.
2442
2443 This creates a temporary buffer for the part's content; the
2444 caller is responsible for killing this buffer as appropriate.  If
2445 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2446   (let* ((msg (notmuch-show-get-message-properties))
2447          (part (notmuch-show-get-part-properties))
2448          (buf (notmuch-show-generate-part-buffer msg part))
2449          (computed-type (or mime-type (plist-get part :computed-type)))
2450          (filename (plist-get part :filename))
2451          (disposition (and filename `(attachment (filename . ,filename)))))
2452     (mm-make-handle buf (list computed-type) nil nil disposition)))
2453
2454 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2455   "Apply FN to an mm-handle for the part containing point.
2456
2457 This ensures that the temporary buffer created for the mm-handle
2458 is destroyed when FN returns. If MIME-TYPE is given then force
2459 part to be treated as if it had that mime-type."
2460   (let ((handle (notmuch-show-current-part-handle mime-type)))
2461     ;; Emacs puts stdout/stderr into the calling buffer so we call
2462     ;; it from a temp-buffer, unless notmuch-show-attachment-debug
2463     ;; is non-nil, in which case we put it in " *notmuch-part*".
2464     (unwind-protect
2465         (if notmuch-show-attachment-debug
2466             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2467               (funcall fn handle))
2468           (with-temp-buffer
2469             (funcall fn handle)))
2470       (kill-buffer (mm-handle-buffer handle)))))
2471
2472 (defun notmuch-show-part-button-default (&optional button)
2473   (interactive)
2474   (let ((button (or button (button-at (point)))))
2475     ;; Try to toggle the part, if that fails then call the default
2476     ;; action. The toggle fails if the part has no emacs renderable
2477     ;; content.
2478     (unless (notmuch-show-toggle-part-invisibility button)
2479       (call-interactively notmuch-show-part-button-default-action))))
2480
2481 (defun notmuch-show-save-part ()
2482   "Save the MIME part containing point to a file."
2483   (interactive)
2484   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2485
2486 (defun notmuch-show-view-part ()
2487   "View the MIME part containing point in an external viewer."
2488   (interactive)
2489   ;; Set mm-inlined-types to nil to force an external viewer
2490   (let ((mm-inlined-types nil))
2491     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2492
2493 (defun notmuch-show-interactively-view-part ()
2494   "View the MIME part containing point, prompting for a viewer."
2495   (interactive)
2496   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2497
2498 (defun notmuch-show-pipe-part ()
2499   "Pipe the MIME part containing point to an external command."
2500   (interactive)
2501   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2502
2503 (defun notmuch-show--mm-display-part (handle)
2504   "Use mm-display-part to display HANDLE in a new buffer.
2505
2506 If the part is displayed in an external application then close
2507 the new buffer."
2508   (let ((buf (get-buffer-create (generate-new-buffer-name
2509                                  (concat " *notmuch-internal-part*")))))
2510     (pop-to-buffer-same-window buf)
2511     (if (eq (mm-display-part handle) 'external)
2512         (kill-buffer buf)
2513       (goto-char (point-min))
2514       (set-buffer-modified-p nil)
2515       (view-buffer buf 'kill-buffer-if-not-modified))))
2516
2517 (defun notmuch-show-choose-mime-of-part (mime-type)
2518   "Choose the mime type to use for displaying part."
2519   (interactive
2520    (list (completing-read "Mime type to use (default text/plain): "
2521                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2522   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part
2523                                              mime-type))
2524
2525 (defun notmuch-show-imenu-prev-index-position-function ()
2526   "Move point to previous message in notmuch-show buffer.
2527 This function is used as a value for
2528 `imenu-prev-index-position-function'."
2529   (if (bobp)
2530       nil
2531     (notmuch-show-previous-message)
2532     t))
2533
2534 (defun notmuch-show-imenu-extract-index-name-function ()
2535   "Return imenu name for line at point.
2536 This function is used as a value for
2537 `imenu-extract-index-name-function'.  Point should be at the
2538 beginning of the line."
2539   (back-to-indentation)
2540   (buffer-substring-no-properties (if notmuch-show-imenu-indent
2541                                       (line-beginning-position)
2542                                     (point))
2543                                   (line-end-position)))
2544
2545 (defmacro notmuch-show--with-currently-shown-message (&rest body)
2546   "Evaluate BODY with display restricted to the currently shown
2547 message."
2548   `(save-excursion
2549      (save-restriction
2550        (let ((extent (notmuch-show-message-extent)))
2551          (narrow-to-region (car extent) (cdr extent))
2552          ,@body))))
2553
2554 (defun notmuch-show--gather-urls ()
2555   "Gather any URLs in the current message."
2556   (notmuch-show--with-currently-shown-message
2557    (let (urls)
2558      (goto-char (point-min))
2559      (while (re-search-forward goto-address-url-regexp (point-max) t)
2560        (push (match-string-no-properties 0) urls))
2561      (reverse urls))))
2562
2563 (defun notmuch-show-browse-urls (&optional kill)
2564   "Offer to browse any URLs in the current message.
2565 With a prefix argument, copy the URL to the kill ring rather than
2566 browsing."
2567   (interactive "P")
2568   (let ((urls (notmuch-show--gather-urls))
2569         (prompt (if kill "Copy URL to kill ring: " "Browse URL: "))
2570         (fn (if kill #'kill-new #'browse-url)))
2571     (if urls
2572         (funcall fn (completing-read prompt urls nil nil nil nil (car urls)))
2573       (message "No URLs found."))))
2574
2575 ;;; _
2576
2577 (provide 'notmuch-show)
2578
2579 ;;; notmuch-show.el ends here