git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 ;;; Code:
  25
  26 (eval-when-compile (require 'cl))
  27 (require 'mm-view)
  28 (require 'message)
  29 (require 'mm-decode)
  30 (require 'mailcap)
  31 (require 'icalendar)
  32 (require 'goto-addr)
  33
  34 (require 'notmuch-lib)
  35 (require 'notmuch-tag)
  36 (require 'notmuch-query)
  37 (require 'notmuch-wash)
  38 (require 'notmuch-mua)
  39 (require 'notmuch-crypto)
  40 (require 'notmuch-print)
  41
  42 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  43 (declare-function notmuch-search-next-thread "notmuch" nil)
  44 (declare-function notmuch-search-previous-thread "notmuch" nil)
  45 (declare-function notmuch-search-show-thread "notmuch" nil)
  46 (declare-function notmuch-foreach-mime-part "notmuch" (function mm-handle))
  47 (declare-function notmuch-count-attachments "notmuch" (mm-handle))
  48 (declare-function notmuch-save-attachments "notmuch" (mm-handle &optional queryp))
  49 (declare-function notmuch-tree "notmuch-tree"
  50                   (&optional query query-context target buffer-name open-target))
  51 (declare-function notmuch-tree-get-message-properties "notmuch-tree" nil)
  52 (declare-function notmuch-read-query "notmuch" (prompt))
  53
  54 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  55   "Headers that should be shown in a message, in this order.
  56
  57 For an open message, all of these headers will be made visible
  58 according to `notmuch-message-headers-visible' or can be toggled
  59 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  60 only the first header in the list will be visible."
  61   :type '(repeat string)
  62   :group 'notmuch-show)
  63
  64 (defcustom notmuch-message-headers-visible t
  65   "Should the headers be visible by default?
  66
  67 If this value is non-nil, then all of the headers defined in
  68 `notmuch-message-headers' will be visible by default in the display
  69 of each message. Otherwise, these headers will be hidden and
  70 `notmuch-show-toggle-visibility-headers' can be used to make them
  71 visible for any given message."
  72   :type 'boolean
  73   :group 'notmuch-show)
  74
  75 (defcustom notmuch-show-relative-dates t
  76   "Display relative dates in the message summary line."
  77   :type 'boolean
  78   :group 'notmuch-show)
  79
  80 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  81   "A list of functions called to decorate the headers listed in
  82 `notmuch-message-headers'.")
  83
  84 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  85   "Functions called after populating a `notmuch-show' buffer."
  86   :type 'hook
  87   :options '(notmuch-show-turn-on-visual-line-mode)
  88   :group 'notmuch-show
  89   :group 'notmuch-hooks)
  90
  91 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  92                                                  notmuch-wash-tidy-citations
  93                                                  notmuch-wash-elide-blank-lines
  94                                                  notmuch-wash-excerpt-citations)
  95   "Functions used to improve the display of text/plain parts."
  96   :type 'hook
  97   :options '(notmuch-wash-convert-inline-patch-to-part
  98              notmuch-wash-wrap-long-lines
  99              notmuch-wash-tidy-citations
 100              notmuch-wash-elide-blank-lines
 101              notmuch-wash-excerpt-citations)
 102   :group 'notmuch-show
 103   :group 'notmuch-hooks)
 104
 105 (defcustom notmuch-show-max-text-part-size 100000
 106   "Maximum size of a text part to be shown by default in characters.
 107
 108 Set to 0 to show the part regardless of size."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 ;; Mostly useful for debugging.
 113 (defcustom notmuch-show-all-multipart/alternative-parts nil
 114   "Should all parts of multipart/alternative parts be shown?"
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-indent-messages-width 1
 119   "Width of message indentation in threads.
 120
 121 Messages are shown indented according to their depth in a thread.
 122 This variable determines the width of this indentation measured
 123 in number of blanks.  Defaults to `1', choose `0' to disable
 124 indentation."
 125   :type 'integer
 126   :group 'notmuch-show)
 127
 128 (defcustom notmuch-show-indent-multipart nil
 129   "Should the sub-parts of a multipart/* part be indented?"
 130   ;; dme: Not sure which is a good default.
 131   :type 'boolean
 132   :group 'notmuch-show)
 133
 134 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 135   "Default part header button action (on ENTER or mouse click)."
 136   :group 'notmuch-show
 137   :type '(choice (const :tag "Save part"
 138                         notmuch-show-save-part)
 139                  (const :tag "View part"
 140                         notmuch-show-view-part)
 141                  (const :tag "View interactively"
 142                         notmuch-show-interactively-view-part)))
 143
 144 (defcustom notmuch-show-only-matching-messages nil
 145   "Only matching messages are shown by default."
 146   :type 'boolean
 147   :group 'notmuch-show)
 148
 149 ;; By default, block all external images to prevent privacy leaks and
 150 ;; potential attacks.
 151 (defcustom notmuch-show-text/html-blocked-images "."
 152   "Remote images that have URLs matching this regexp will be blocked."
 153   :type '(choice (const nil) regexp)
 154   :group 'notmuch-show)
 155
 156 (defvar notmuch-show-thread-id nil)
 157 (make-variable-buffer-local 'notmuch-show-thread-id)
 158
 159 (defvar notmuch-show-parent-buffer nil)
 160 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 161
 162 (defvar notmuch-show-query-context nil)
 163 (make-variable-buffer-local 'notmuch-show-query-context)
 164
 165 (defvar notmuch-show-process-crypto nil)
 166 (make-variable-buffer-local 'notmuch-show-process-crypto)
 167
 168 (defvar notmuch-show-elide-non-matching-messages nil)
 169 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 170
 171 (defvar notmuch-show-indent-content t)
 172 (make-variable-buffer-local 'notmuch-show-indent-content)
 173
 174 (defvar notmuch-show-attachment-debug nil
 175   "If t log stdout and stderr from attachment handlers
 176
 177 When set to nil (the default) stdout and stderr from attachment
 178 handlers is discarded. When set to t the stdout and stderr from
 179 each attachment handler is logged in buffers with names beginning
 180 \" *notmuch-part*\". This option requires emacs version at least
 181 24.3 to work.")
 182
 183 (defcustom notmuch-show-stash-mlarchive-link-alist
 184   '(("Gmane" . "http://mid.gmane.org/")
 185     ("MARC" . "https://marc.info/?i=")
 186     ("Mail Archive, The" . "https://mid.mail-archive.com/")
 187     ("LKML" . "https://lkml.kernel.org/r/")
 188     ;; FIXME: can these services be searched by `Message-Id' ?
 189     ;; ("MarkMail" . "http://markmail.org/")
 190     ;; ("Nabble" . "http://nabble.com/")
 191     ;; ("opensubscriber" . "http://opensubscriber.com/")
 192     )
 193   "List of Mailing List Archives to use when stashing links.
 194
 195 This list is used for generating a Mailing List Archive reference
 196 URI with the current message's Message-Id in
 197 `notmuch-show-stash-mlarchive-link'.
 198
 199 If the cdr of the alist element is not a function, the cdr is
 200 expected to contain a URI that is concatenated with the current
 201 message's Message-Id to create a ML archive reference URI.
 202
 203 If the cdr is a function, the function is called with the
 204 Message-Id as the argument, and the function is expected to
 205 return the ML archive reference URI."
 206   :type '(alist :key-type (string :tag "Name")
 207                 :value-type (choice
 208                              (string :tag "URL")
 209                              (function :tag "Function returning the URL")))
 210   :group 'notmuch-show)
 211
 212 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 213   "Default Mailing List Archive to use when stashing links.
 214
 215 This is used when `notmuch-show-stash-mlarchive-link' isn't
 216 provided with an MLA argument nor `completing-read' input."
 217   :type `(choice
 218           ,@(mapcar
 219              (lambda (mla)
 220                (list 'const :tag (car mla) :value (car mla)))
 221              notmuch-show-stash-mlarchive-link-alist))
 222   :group 'notmuch-show)
 223
 224 (defcustom notmuch-show-mark-read-tags '("-unread")
 225   "List of tag changes to apply to a message when it is marked as read.
 226
 227 Tags starting with \"+\" (or not starting with either \"+\" or
 228 \"-\") in the list will be added, and tags starting with \"-\"
 229 will be removed from the message being marked as read.
 230
 231 For example, if you wanted to remove an \"unread\" tag and add a
 232 \"read\" tag (which would make little sense), you would set:
 233     (\"-unread\" \"+read\")"
 234   :type '(repeat string)
 235   :group 'notmuch-show)
 236
 237 (defcustom notmuch-show-mark-read-function #'notmuch-show-seen-current-message
 238   "Function to control which messages are marked read.
 239
 240 The function should take two arguments START and END which will
 241 be the start and end of the visible portion of the buffer and
 242 should mark the appropriate messages read by applying
 243 `notmuch-show-mark-read'. This function will be called after
 244 every user interaction with notmuch."
 245   :type 'function
 246   :group 'notmuch-show)
 247
 248 (defmacro with-current-notmuch-show-message (&rest body)
 249   "Evaluate body with current buffer set to the text of current message"
 250   `(save-excursion
 251      (let ((id (notmuch-show-get-message-id)))
 252        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 253          (with-current-buffer buf
 254            (let ((coding-system-for-read 'no-conversion))
 255              (call-process notmuch-command nil t nil "show" "--format=raw" id))
 256            ,@body)
 257          (kill-buffer buf)))))
 258
 259 (defun notmuch-show-turn-on-visual-line-mode ()
 260   "Enable Visual Line mode."
 261   (visual-line-mode t))
 262
 263 ;; DEPRECATED in Notmuch 0.16 since we now have convenient part
 264 ;; commands.  We'll keep the command around for a version or two in
 265 ;; case people want to bind it themselves.
 266 (defun notmuch-show-view-all-mime-parts ()
 267   "Use external viewers to view all attachments from the current message."
 268   (interactive)
 269   (with-current-notmuch-show-message
 270    ;; We override the mm-inline-media-tests to indicate which message
 271    ;; parts are already sufficiently handled by the original
 272    ;; presentation of the message in notmuch-show mode. These parts
 273    ;; will be inserted directly into the temporary buffer of
 274    ;; with-current-notmuch-show-message and silently discarded.
 275    ;;
 276    ;; Any MIME part not explicitly mentioned here will be handled by an
 277    ;; external viewer as configured in the various mailcap files.
 278    (let ((mm-inline-media-tests '(
 279                                   ("text/.*" ignore identity)
 280                                   ("application/pgp-signature" ignore identity)
 281                                   ("multipart/alternative" ignore identity)
 282                                   ("multipart/mixed" ignore identity)
 283                                   ("multipart/related" ignore identity)
 284                                  )))
 285      (mm-display-parts (mm-dissect-buffer)))))
 286
 287 (defun notmuch-show-save-attachments ()
 288   "Save all attachments from the current message."
 289   (interactive)
 290   (with-current-notmuch-show-message
 291    (let ((mm-handle (mm-dissect-buffer)))
 292      (notmuch-save-attachments
 293       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 294   (message "Done"))
 295
 296 (defun notmuch-show-with-message-as-text (fn)
 297   "Apply FN to a text representation of the current message.
 298
 299 FN is called with one argument, the message properties. It should
 300 operation on the contents of the current buffer."
 301
 302   ;; Remake the header to ensure that all information is available.
 303   (let* ((to (notmuch-show-get-to))
 304          (cc (notmuch-show-get-cc))
 305          (from (notmuch-show-get-from))
 306          (subject (notmuch-show-get-subject))
 307          (date (notmuch-show-get-date))
 308          (tags (notmuch-show-get-tags))
 309          (depth (notmuch-show-get-depth))
 310
 311          (header (concat
 312                   "Subject: " subject "\n"
 313                   "To: " to "\n"
 314                   (if (not (string= cc ""))
 315                       (concat "Cc: " cc "\n")
 316                     "")
 317                   "From: " from "\n"
 318                   "Date: " date "\n"
 319                   (if tags
 320                       (concat "Tags: "
 321                               (mapconcat #'identity tags ", ") "\n")
 322                     "")))
 323          (all (buffer-substring (notmuch-show-message-top)
 324                                 (notmuch-show-message-bottom)))
 325
 326          (props (notmuch-show-get-message-properties))
 327          (indenting notmuch-show-indent-content))
 328     (with-temp-buffer
 329       (insert all)
 330       (if indenting
 331           (indent-rigidly (point-min) (point-max) (- depth)))
 332       ;; Remove the original header.
 333       (goto-char (point-min))
 334       (re-search-forward "^$" (point-max) nil)
 335       (delete-region (point-min) (point))
 336       (insert header)
 337       (funcall fn props))))
 338
 339 (defun notmuch-show-print-message ()
 340   "Print the current message."
 341   (interactive)
 342   (notmuch-show-with-message-as-text 'notmuch-print-message))
 343
 344 (defun notmuch-show-fontify-header ()
 345   (let ((face (cond
 346                ((looking-at "[Tt]o:")
 347                 'message-header-to)
 348                ((looking-at "[Bb]?[Cc][Cc]:")
 349                 'message-header-cc)
 350                ((looking-at "[Ss]ubject:")
 351                 'message-header-subject)
 352                (t
 353                 'message-header-other))))
 354
 355     (overlay-put (make-overlay (point) (re-search-forward ":"))
 356                  'face 'message-header-name)
 357     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 358                  'face face)))
 359
 360 (defun notmuch-show-colour-headers ()
 361   "Apply some colouring to the current headers."
 362   (goto-char (point-min))
 363   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 364     (notmuch-show-fontify-header)
 365     (forward-line)))
 366
 367 (defun notmuch-show-spaces-n (n)
 368   "Return a string comprised of `n' spaces."
 369   (make-string n ? ))
 370
 371 (defun notmuch-show-update-tags (tags)
 372   "Update the displayed tags of the current message."
 373   (save-excursion
 374     (goto-char (notmuch-show-message-top))
 375     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 376         (let ((inhibit-read-only t))
 377           (replace-match (concat "("
 378                                  (notmuch-tag-format-tags tags (notmuch-show-get-prop :orig-tags))
 379                                  ")"))))))
 380
 381 (defun notmuch-clean-address (address)
 382   "Try to clean a single email ADDRESS for display. Return a cons
 383 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 384 parsing fails."
 385   (condition-case nil
 386     (let (p-name p-address)
 387       ;; It would be convenient to use `mail-header-parse-address',
 388       ;; but that expects un-decoded mailbox parts, whereas our
 389       ;; mailbox parts are already decoded (and hence may contain
 390       ;; UTF-8). Given that notmuch should handle most of the awkward
 391       ;; cases, some simple string deconstruction should be sufficient
 392       ;; here.
 393       (cond
 394        ;; "User <user@dom.ain>" style.
 395        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 396         (setq p-name (match-string 1 address)
 397               p-address (match-string 2 address)))
 398
 399        ;; "<user@dom.ain>" style.
 400        ((string-match "<\\(.*\\)>" address)
 401         (setq p-address (match-string 1 address)))
 402
 403        ;; Everything else.
 404        (t
 405         (setq p-address address)))
 406
 407       (when p-name
 408         ;; Remove elements of the mailbox part that are not relevant for
 409         ;; display, even if they are required during transport:
 410         ;;
 411         ;; Backslashes.
 412         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 413
 414         ;; Outer single and double quotes, which might be nested.
 415         (loop
 416          with start-of-loop
 417          do (setq start-of-loop p-name)
 418
 419          when (string-match "^\"\\(.*\\)\"$" p-name)
 420          do (setq p-name (match-string 1 p-name))
 421
 422          when (string-match "^'\\(.*\\)'$" p-name)
 423          do (setq p-name (match-string 1 p-name))
 424
 425          until (string= start-of-loop p-name)))
 426
 427       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 428       ;; 'foo@bar.com'.
 429       (when (string= p-name p-address)
 430         (setq p-name nil))
 431
 432       (cons p-address p-name))
 433     (error (cons address nil))))
 434
 435 (defun notmuch-show-clean-address (address)
 436   "Try to clean a single email ADDRESS for display.  Return
 437 unchanged ADDRESS if parsing fails."
 438   (let* ((clean-address (notmuch-clean-address address))
 439          (p-address (car clean-address))
 440          (p-name (cdr clean-address)))
 441     ;; If no name, return just the address.
 442     (if (not p-name)
 443         p-address
 444       ;; Otherwise format the name and address together.
 445       (concat p-name " <" p-address ">"))))
 446
 447 (defun notmuch-show-insert-headerline (headers date tags depth)
 448   "Insert a notmuch style headerline based on HEADERS for a
 449 message at DEPTH in the current thread."
 450   (let ((start (point)))
 451     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 452             (notmuch-sanitize
 453              (notmuch-show-clean-address (plist-get headers :From)))
 454             " ("
 455             date
 456             ") ("
 457             (notmuch-tag-format-tags tags tags)
 458             ")\n")
 459     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 460
 461 (defun notmuch-show-insert-header (header header-value)
 462   "Insert a single header."
 463   (insert header ": " (notmuch-sanitize header-value) "\n"))
 464
 465 (defun notmuch-show-insert-headers (headers)
 466   "Insert the headers of the current message."
 467   (let ((start (point)))
 468     (mapc (lambda (header)
 469             (let* ((header-symbol (intern (concat ":" header)))
 470                    (header-value (plist-get headers header-symbol)))
 471               (if (and header-value
 472                        (not (string-equal "" header-value)))
 473                   (notmuch-show-insert-header header header-value))))
 474           notmuch-message-headers)
 475     (save-excursion
 476       (save-restriction
 477         (narrow-to-region start (point-max))
 478         (run-hooks 'notmuch-show-markup-headers-hook)))))
 479
 480 (define-button-type 'notmuch-show-part-button-type
 481   'action 'notmuch-show-part-button-default
 482   'follow-link t
 483   'face 'message-mml
 484   :supertype 'notmuch-button-type)
 485
 486 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 487   (let ((button)
 488         (base-label (concat (when name (concat name ": "))
 489                             declared-type
 490                             (unless (string-equal declared-type content-type)
 491                               (concat " (as " content-type ")"))
 492                             comment)))
 493
 494     (setq button
 495           (insert-button
 496            (concat "[ " base-label " ]")
 497            :base-label base-label
 498            :type 'notmuch-show-part-button-type
 499            :notmuch-part-hidden nil))
 500     (insert "\n")
 501     ;; return button
 502     button))
 503
 504 (defun notmuch-show-toggle-part-invisibility (&optional button)
 505   (interactive)
 506   (let ((button (or button (button-at (point)))))
 507     (when button
 508       (let ((overlay (button-get button 'overlay))
 509             (lazy-part (button-get button :notmuch-lazy-part)))
 510         ;; We have a part to toggle if there is an overlay or if there is a lazy part.
 511         ;; If neither is present we cannot toggle the part so we just return nil.
 512         (when (or overlay lazy-part)
 513           (let* ((show (button-get button :notmuch-part-hidden))
 514                  (new-start (button-start button))
 515                  (button-label (button-get button :base-label))
 516                  (old-point (point))
 517                  (properties (text-properties-at (button-start button)))
 518                  (inhibit-read-only t))
 519             ;; Toggle the button itself.
 520             (button-put button :notmuch-part-hidden (not show))
 521             (goto-char new-start)
 522             (insert "[ " button-label (if show " ]" " (hidden) ]"))
 523             (set-text-properties new-start (point) properties)
 524             (let ((old-end (button-end button)))
 525               (move-overlay button new-start (point))
 526               (delete-region (point) old-end))
 527             (goto-char (min old-point (1- (button-end button))))
 528             ;; Return nil if there is a lazy-part, it is empty, and we are
 529             ;; trying to show it.  In all other cases return t.
 530             (if lazy-part
 531                 (when show
 532                   (button-put button :notmuch-lazy-part nil)
 533                   (notmuch-show-lazy-part lazy-part button))
 534               ;; else there must be an overlay.
 535               (overlay-put overlay 'invisible (not show))
 536               t)))))))
 537
 538 ;; Part content ID handling
 539
 540 (defvar notmuch-show--cids nil
 541   "Alist from raw content ID to (MSG PART).")
 542 (make-variable-buffer-local 'notmuch-show--cids)
 543
 544 (defun notmuch-show--register-cids (msg part)
 545   "Register content-IDs in PART and all of PART's sub-parts."
 546   (let ((content-id (plist-get part :content-id)))
 547     (when content-id
 548       ;; Note that content-IDs are globally unique, except when they
 549       ;; aren't: RFC 2046 section 5.1.4 permits children of a
 550       ;; multipart/alternative to have the same content-ID, in which
 551       ;; case the MUA is supposed to pick the best one it can render.
 552       ;; We simply add the content-ID to the beginning of our alist;
 553       ;; so if this happens, we'll take the last (and "best")
 554       ;; alternative (even if we can't render it).
 555       (push (list content-id msg part) notmuch-show--cids)))
 556   ;; Recurse on sub-parts
 557   (let ((ctype (notmuch-split-content-type
 558                 (downcase (plist-get part :content-type)))))
 559     (cond ((equal (first ctype) "multipart")
 560            (mapc (apply-partially #'notmuch-show--register-cids msg)
 561                  (plist-get part :content)))
 562           ((equal ctype '("message" "rfc822"))
 563            (notmuch-show--register-cids
 564             msg
 565             (first (plist-get (first (plist-get part :content)) :body)))))))
 566
 567 (defun notmuch-show--get-cid-content (cid)
 568   "Return a list (CID-content content-type) or nil.
 569
 570 This will only find parts from messages that have been inserted
 571 into the current buffer.  CID must be a raw content ID, without
 572 enclosing angle brackets, a cid: prefix, or URL encoding.  This
 573 will return nil if the CID is unknown or cannot be retrieved."
 574   (let ((descriptor (cdr (assoc cid notmuch-show--cids))))
 575     (when descriptor
 576       (let* ((msg (first descriptor))
 577              (part (second descriptor))
 578              ;; Request caching for this content, as some messages
 579              ;; reference the same cid: part many times (hundreds!).
 580              (content (notmuch-get-bodypart-binary
 581                        msg part notmuch-show-process-crypto 'cache))
 582              (content-type (plist-get part :content-type)))
 583         (list content content-type)))))
 584
 585 (defun notmuch-show-setup-w3m ()
 586   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 587   (interactive)
 588   (if (boundp 'w3m-cid-retrieve-function-alist)
 589     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 590       (push (cons 'notmuch-show-mode #'notmuch-show--cid-w3m-retrieve)
 591             w3m-cid-retrieve-function-alist)))
 592   (setq mm-inline-text-html-with-images t))
 593
 594 (defvar w3m-current-buffer) ;; From `w3m.el'.
 595 (defun notmuch-show--cid-w3m-retrieve (url &rest args)
 596   ;; url includes the cid: prefix and is URL encoded (see RFC 2392).
 597   (let* ((cid (url-unhex-string (substring url 4)))
 598          (content-and-type
 599           (with-current-buffer w3m-current-buffer
 600             (notmuch-show--get-cid-content cid))))
 601     (when content-and-type
 602       (insert (first content-and-type))
 603       (second content-and-type))))
 604
 605 ;; MIME part renderers
 606
 607 (defun notmuch-show-multipart/*-to-list (part)
 608   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 609           (plist-get part :content)))
 610
 611 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth button)
 612   (let ((chosen-type (car (notmuch-multipart/alternative-choose msg (notmuch-show-multipart/*-to-list part))))
 613         (inner-parts (plist-get part :content))
 614         (start (point)))
 615     ;; This inserts all parts of the chosen type rather than just one,
 616     ;; but it's not clear that this is the wrong thing to do - which
 617     ;; should be chosen if there are more than one that match?
 618     (mapc (lambda (inner-part)
 619             (let* ((inner-type (plist-get inner-part :content-type))
 620                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 621                            (string= chosen-type inner-type)))))
 622               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 623           inner-parts)
 624
 625     (when notmuch-show-indent-multipart
 626       (indent-rigidly start (point) 1)))
 627   t)
 628
 629 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth button)
 630   (let ((inner-parts (plist-get part :content))
 631         (start (point)))
 632
 633     ;; Render the primary part.  FIXME: Support RFC 2387 Start header.
 634     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 635     ;; Add hidden buttons for the rest
 636     (mapc (lambda (inner-part)
 637             (notmuch-show-insert-bodypart msg inner-part depth t))
 638           (cdr inner-parts))
 639
 640     (when notmuch-show-indent-multipart
 641       (indent-rigidly start (point) 1)))
 642   t)
 643
 644 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth button)
 645   (when button
 646     (button-put button 'face 'notmuch-crypto-part-header))
 647
 648   ;; Insert a button detailing the signature status.
 649   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
 650                                           (notmuch-show-get-header :From msg))
 651
 652   (let ((inner-parts (plist-get part :content))
 653         (start (point)))
 654     ;; Show all of the parts.
 655     (mapc (lambda (inner-part)
 656             (notmuch-show-insert-bodypart msg inner-part depth))
 657           inner-parts)
 658
 659     (when notmuch-show-indent-multipart
 660       (indent-rigidly start (point) 1)))
 661   t)
 662
 663 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth button)
 664   (when button
 665     (button-put button 'face 'notmuch-crypto-part-header))
 666
 667   ;; Insert a button detailing the encryption status.
 668   (notmuch-crypto-insert-encstatus-button (car (plist-get part :encstatus)))
 669
 670   ;; Insert a button detailing the signature status.
 671   (notmuch-crypto-insert-sigstatus-button (car (plist-get part :sigstatus))
 672                                           (notmuch-show-get-header :From msg))
 673
 674   (let ((inner-parts (plist-get part :content))
 675         (start (point)))
 676     ;; Show all of the parts.
 677     (mapc (lambda (inner-part)
 678             (notmuch-show-insert-bodypart msg inner-part depth))
 679           inner-parts)
 680
 681     (when notmuch-show-indent-multipart
 682       (indent-rigidly start (point) 1)))
 683   t)
 684
 685 (defun notmuch-show-insert-part-application/pgp-encrypted (msg part content-type nth depth button)
 686   t)
 687
 688 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth button)
 689   (let ((inner-parts (plist-get part :content))
 690         (start (point)))
 691     ;; Show all of the parts.
 692     (mapc (lambda (inner-part)
 693             (notmuch-show-insert-bodypart msg inner-part depth))
 694           inner-parts)
 695
 696     (when notmuch-show-indent-multipart
 697       (indent-rigidly start (point) 1)))
 698   t)
 699
 700 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth button)
 701   (let* ((message (car (plist-get part :content)))
 702          (body (car (plist-get message :body)))
 703          (start (point)))
 704
 705     ;; Override `notmuch-message-headers' to force `From' to be
 706     ;; displayed.
 707     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 708       (notmuch-show-insert-headers (plist-get message :headers)))
 709
 710     ;; Blank line after headers to be compatible with the normal
 711     ;; message display.
 712     (insert "\n")
 713
 714     ;; Show the body
 715     (notmuch-show-insert-bodypart msg body depth)
 716
 717     (when notmuch-show-indent-multipart
 718       (indent-rigidly start (point) 1)))
 719   t)
 720
 721 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth button)
 722   ;; For backward compatibility we want to apply the text/plain hook
 723   ;; to the whole of the part including the part button if there is
 724   ;; one.
 725   (let ((start (if button
 726                    (button-start button)
 727                  (point))))
 728     (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
 729     (save-excursion
 730       (save-restriction
 731         (narrow-to-region start (point-max))
 732         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 733   t)
 734
 735 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth button)
 736   (insert (with-temp-buffer
 737             (insert (notmuch-get-bodypart-text msg part notmuch-show-process-crypto))
 738             ;; notmuch-get-bodypart-text does no newline conversion.
 739             ;; Replace CRLF with LF before icalendar can use it.
 740             (goto-char (point-min))
 741             (while (re-search-forward "\r\n" nil t)
 742               (replace-match "\n" nil nil))
 743             (let ((file (make-temp-file "notmuch-ical"))
 744                   result)
 745               (unwind-protect
 746                   (progn
 747                     (unless (icalendar-import-buffer file t)
 748                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 749                     (set-buffer (get-file-buffer file))
 750                     (setq result (buffer-substring (point-min) (point-max)))
 751                     (set-buffer-modified-p nil)
 752                     (kill-buffer (current-buffer)))
 753                 (delete-file file))
 754               result)))
 755   t)
 756
 757 ;; For backwards compatibility.
 758 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth button)
 759   (notmuch-show-insert-part-text/calendar msg part content-type nth depth button))
 760
 761 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 762   ;; If we can deduce a MIME type from the filename of the attachment,
 763   ;; we return that.
 764   (if (plist-get part :filename)
 765       (let ((extension (file-name-extension (plist-get part :filename)))
 766             mime-type)
 767         (if extension
 768             (progn
 769               (mailcap-parse-mimetypes)
 770               (setq mime-type (mailcap-extension-to-mime extension))
 771               (if (and mime-type
 772                        (not (string-equal mime-type "application/octet-stream")))
 773                   mime-type
 774                 nil))
 775           nil))))
 776
 777 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth button)
 778   (if (eq mm-text-html-renderer 'shr)
 779       ;; It's easier to drive shr ourselves than to work around the
 780       ;; goofy things `mm-shr' does (like irreversibly taking over
 781       ;; content ID handling).
 782
 783       ;; FIXME: If we block an image, offer a button to load external
 784       ;; images.
 785       (let ((shr-blocked-images notmuch-show-text/html-blocked-images))
 786         (notmuch-show--insert-part-text/html-shr msg part))
 787     ;; Otherwise, let message-mode do the heavy lifting
 788     ;;
 789     ;; w3m sets up a keymap which "leaks" outside the invisible region
 790     ;; and causes strange effects in notmuch. We set
 791     ;; mm-inline-text-html-with-w3m-keymap to nil to tell w3m not to
 792     ;; set a keymap (so the normal notmuch-show-mode-map remains).
 793     (let ((mm-inline-text-html-with-w3m-keymap nil)
 794           ;; FIXME: If we block an image, offer a button to load external
 795           ;; images.
 796           (gnus-blocked-images notmuch-show-text/html-blocked-images))
 797       (notmuch-show-insert-part-*/* msg part content-type nth depth button))))
 798
 799 ;; These functions are used by notmuch-show--insert-part-text/html-shr
 800 (declare-function libxml-parse-html-region "xml.c")
 801 (declare-function shr-insert-document "shr")
 802
 803 (defun notmuch-show--insert-part-text/html-shr (msg part)
 804   ;; Make sure shr is loaded before we start let-binding its globals
 805   (require 'shr)
 806   (let ((dom (let ((process-crypto notmuch-show-process-crypto))
 807                (with-temp-buffer
 808                  (insert (notmuch-get-bodypart-text msg part process-crypto))
 809                  (libxml-parse-html-region (point-min) (point-max)))))
 810         (shr-content-function
 811          (lambda (url)
 812            ;; shr strips the "cid:" part of URL, but doesn't
 813            ;; URL-decode it (see RFC 2392).
 814            (let ((cid (url-unhex-string url)))
 815              (first (notmuch-show--get-cid-content cid))))))
 816     (shr-insert-document dom)
 817     t))
 818
 819 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth button)
 820   ;; This handler _must_ succeed - it is the handler of last resort.
 821   (notmuch-mm-display-part-inline msg part content-type notmuch-show-process-crypto)
 822   t)
 823
 824 ;; Functions for determining how to handle MIME parts.
 825
 826 (defun notmuch-show-handlers-for (content-type)
 827   "Return a list of content handlers for a part of type CONTENT-TYPE."
 828   (let (result)
 829     (mapc (lambda (func)
 830             (if (functionp func)
 831                 (push func result)))
 832           ;; Reverse order of prefrence.
 833           (list (intern (concat "notmuch-show-insert-part-*/*"))
 834                 (intern (concat
 835                          "notmuch-show-insert-part-"
 836                          (car (notmuch-split-content-type content-type))
 837                          "/*"))
 838                 (intern (concat "notmuch-show-insert-part-" content-type))))
 839     result))
 840
 841 ;; \f
 842
 843 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth button)
 844   ;; Run the handlers until one of them succeeds.
 845   (loop for handler in (notmuch-show-handlers-for content-type)
 846         until (condition-case err
 847                   (funcall handler msg part content-type nth depth button)
 848                 ;; Specifying `debug' here lets the debugger run if
 849                 ;; `debug-on-error' is non-nil.
 850                 ((debug error)
 851                  (insert "!!! Bodypart handler `" (prin1-to-string handler) "' threw an error:\n"
 852                          "!!! " (error-message-string err) "\n")
 853                  nil))))
 854
 855 (defun notmuch-show-create-part-overlays (button beg end)
 856   "Add an overlay to the part between BEG and END"
 857
 858   ;; If there is no button (i.e., the part is text/plain and the first
 859   ;; part) or if the part has no content then we don't make the part
 860   ;; toggleable.
 861   (when (and button (/= beg end))
 862     (button-put button 'overlay (make-overlay beg end))
 863     ;; Return true if we created an overlay.
 864     t))
 865
 866 (defun notmuch-show-record-part-information (part beg end)
 867   "Store PART as a text property from BEG to END"
 868
 869   ;; Record part information.  Since we already inserted subparts,
 870   ;; don't override existing :notmuch-part properties.
 871   (notmuch-map-text-property beg end :notmuch-part
 872                              (lambda (v) (or v part)))
 873   ;; Make :notmuch-part front sticky and rear non-sticky so it stays
 874   ;; applied to the beginning of each line when we indent the
 875   ;; message.  Since we're operating on arbitrary renderer output,
 876   ;; watch out for sticky specs of t, which means all properties are
 877   ;; front-sticky/rear-nonsticky.
 878   (notmuch-map-text-property beg end 'front-sticky
 879                              (lambda (v) (if (listp v)
 880                                              (pushnew :notmuch-part v)
 881                                            v)))
 882   (notmuch-map-text-property beg end 'rear-nonsticky
 883                              (lambda (v) (if (listp v)
 884                                              (pushnew :notmuch-part v)
 885                                            v))))
 886
 887 (defun notmuch-show-lazy-part (part-args button)
 888   ;; Insert the lazy part after the button for the part. We would just
 889   ;; move to the start of the new line following the button and insert
 890   ;; the part but that point might have text properties (eg colours
 891   ;; from a message header etc) so instead we start from the last
 892   ;; character of the button by adding a newline and finish by
 893   ;; removing the extra newline from the end of the part.
 894   (save-excursion
 895     (goto-char (button-end button))
 896     (insert "\n")
 897     (let* ((inhibit-read-only t)
 898            ;; We need to use markers for the start and end of the part
 899            ;; because the part insertion functions do not guarantee
 900            ;; to leave point at the end of the part.
 901            (part-beg (copy-marker (point) nil))
 902            (part-end (copy-marker (point) t))
 903            ;; We have to save the depth as we can't find the depth
 904            ;; when narrowed.
 905            (depth (notmuch-show-get-depth)))
 906       (save-restriction
 907         (narrow-to-region part-beg part-end)
 908         (delete-region part-beg part-end)
 909         (apply #'notmuch-show-insert-bodypart-internal part-args)
 910         (indent-rigidly part-beg part-end depth))
 911       (goto-char part-end)
 912       (delete-char 1)
 913       (notmuch-show-record-part-information (second part-args)
 914                                             (button-start button)
 915                                             part-end)
 916       ;; Create the overlay. If the lazy-part turned out to be empty/not
 917       ;; showable this returns nil.
 918       (notmuch-show-create-part-overlays button part-beg part-end))))
 919
 920 (defun notmuch-show-mime-type (part)
 921   "Return the correct mime-type to use for PART."
 922   (let ((content-type (downcase (plist-get part :content-type))))
 923     (or (and (string= content-type "application/octet-stream")
 924              (notmuch-show-get-mime-type-of-application/octet-stream part))
 925         (and (string= content-type "inline patch")
 926              "text/x-diff")
 927         content-type)))
 928
 929 ;; The following variable can be overridden by let bindings.
 930 (defvar notmuch-show-insert-header-p-function 'notmuch-show-insert-header-p
 931   "Specify which function decides which part headers get inserted.
 932
 933 The function should take two parameters, PART and HIDE, and
 934 should return non-NIL if a header button should be inserted for
 935 this part.")
 936
 937 (defun notmuch-show-insert-header-p (part hide)
 938   ;; Show all part buttons except for the first part if it is text/plain.
 939   (let ((mime-type (notmuch-show-mime-type part)))
 940     (not (and (string= mime-type "text/plain")
 941               (<= (plist-get part :id) 1)))))
 942
 943 (defun notmuch-show-reply-insert-header-p-never (part hide)
 944   nil)
 945
 946 (defun notmuch-show-reply-insert-header-p-trimmed (part hide)
 947   (let ((mime-type (notmuch-show-mime-type part)))
 948     (and (not (notmuch-match-content-type mime-type "multipart/*"))
 949          (not hide))))
 950
 951 (defun notmuch-show-reply-insert-header-p-minimal (part hide)
 952   (let ((mime-type (notmuch-show-mime-type part)))
 953     (and (notmuch-match-content-type mime-type "text/*")
 954          (not hide))))
 955
 956 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 957   "Insert the body part PART at depth DEPTH in the current thread.
 958
 959 HIDE determines whether to show or hide the part and the button
 960 as follows: If HIDE is nil, show the part and the button. If HIDE
 961 is t, hide the part initially and show the button."
 962
 963   (let* ((content-type (downcase (plist-get part :content-type)))
 964          (mime-type (notmuch-show-mime-type part))
 965          (nth (plist-get part :id))
 966          (long (and (notmuch-match-content-type mime-type "text/*")
 967                     (> notmuch-show-max-text-part-size 0)
 968                     (> (length (plist-get part :content)) notmuch-show-max-text-part-size)))
 969          (beg (point))
 970          ;; This default header-p function omits the part button for
 971          ;; the first (or only) part if this is text/plain.
 972          (button (when (funcall notmuch-show-insert-header-p-function part hide)
 973                    (notmuch-show-insert-part-header nth mime-type content-type (plist-get part :filename))))
 974          ;; Hide the part initially if HIDE is t, or if it is too long
 975          ;; and we have a button to allow toggling.
 976          (show-part (not (or (equal hide t)
 977                              (and long button))))
 978          (content-beg (point)))
 979
 980     ;; Store the computed mime-type for later use (e.g. by attachment handlers).
 981     (plist-put part :computed-type mime-type)
 982
 983     (if show-part
 984         (notmuch-show-insert-bodypart-internal msg part mime-type nth depth button)
 985       (when button
 986         (button-put button :notmuch-lazy-part
 987                     (list msg part mime-type nth depth button))))
 988
 989     ;; Some of the body part handlers leave point somewhere up in the
 990     ;; part, so we make sure that we're down at the end.
 991     (goto-char (point-max))
 992     ;; Ensure that the part ends with a carriage return.
 993     (unless (bolp)
 994       (insert "\n"))
 995     ;; We do not create the overlay for hidden (lazy) parts until
 996     ;; they are inserted.
 997     (if show-part
 998         (notmuch-show-create-part-overlays button content-beg (point))
 999       (save-excursion
1000         (notmuch-show-toggle-part-invisibility button)))
1001     (notmuch-show-record-part-information part beg (point))))
1002
1003 (defun notmuch-show-insert-body (msg body depth)
1004   "Insert the body BODY at depth DEPTH in the current thread."
1005
1006   ;; Register all content IDs for this message.  According to RFC
1007   ;; 2392, content IDs are *global*, but it's okay if an MUA treats
1008   ;; them as only global within a message.
1009   (notmuch-show--register-cids msg (first body))
1010
1011   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
1012
1013 (defun notmuch-show-make-symbol (type)
1014   (make-symbol (concat "notmuch-show-" type)))
1015
1016 (defun notmuch-show-strip-re (string)
1017   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
1018
1019 (defvar notmuch-show-previous-subject "")
1020 (make-variable-buffer-local 'notmuch-show-previous-subject)
1021
1022 (defun notmuch-show-insert-msg (msg depth)
1023   "Insert the message MSG at depth DEPTH in the current thread."
1024   (let* ((headers (plist-get msg :headers))
1025          ;; Indentation causes the buffer offset of the start/end
1026          ;; points to move, so we must use markers.
1027          message-start message-end
1028          content-start content-end
1029          headers-start headers-end
1030          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
1031
1032     (setq message-start (point-marker))
1033
1034     (notmuch-show-insert-headerline headers
1035                                     (or (if notmuch-show-relative-dates
1036                                             (plist-get msg :date_relative)
1037                                           nil)
1038                                         (plist-get headers :Date))
1039                                     (plist-get msg :tags) depth)
1040
1041     (setq content-start (point-marker))
1042
1043     ;; Set `headers-start' to point after the 'Subject:' header to be
1044     ;; compatible with the existing implementation. This just sets it
1045     ;; to after the first header.
1046     (notmuch-show-insert-headers headers)
1047     (save-excursion
1048       (goto-char content-start)
1049       ;; If the subject of this message is the same as that of the
1050       ;; previous message, don't display it when this message is
1051       ;; collapsed.
1052       (when (not (string= notmuch-show-previous-subject
1053                           bare-subject))
1054         (forward-line 1))
1055       (setq headers-start (point-marker)))
1056     (setq headers-end (point-marker))
1057
1058     (setq notmuch-show-previous-subject bare-subject)
1059
1060     ;; A blank line between the headers and the body.
1061     (insert "\n")
1062     (notmuch-show-insert-body msg (plist-get msg :body)
1063                               (if notmuch-show-indent-content depth 0))
1064     ;; Ensure that the body ends with a newline.
1065     (unless (bolp)
1066       (insert "\n"))
1067     (setq content-end (point-marker))
1068
1069     ;; Indent according to the depth in the thread.
1070     (if notmuch-show-indent-content
1071         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
1072
1073     (setq message-end (point-max-marker))
1074
1075     ;; Save the extents of this message over the whole text of the
1076     ;; message.
1077     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
1078
1079     ;; Create overlays used to control visibility
1080     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
1081     (plist-put msg :message-overlay (make-overlay headers-start content-end))
1082
1083     (plist-put msg :depth depth)
1084
1085     ;; Save the properties for this message. Currently this saves the
1086     ;; entire message (augmented it with other stuff), which seems
1087     ;; like overkill. We might save a reduced subset (for example, not
1088     ;; the content).
1089     (notmuch-show-set-message-properties msg)
1090
1091     ;; Set header visibility.
1092     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
1093
1094     ;; Message visibility depends on whether it matched the search
1095     ;; criteria.
1096     (notmuch-show-message-visible msg (and (plist-get msg :match)
1097                                            (not (plist-get msg :excluded))))))
1098
1099 (defun notmuch-show-toggle-process-crypto ()
1100   "Toggle the processing of cryptographic MIME parts."
1101   (interactive)
1102   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
1103   (message (if notmuch-show-process-crypto
1104                "Processing cryptographic MIME parts."
1105              "Not processing cryptographic MIME parts."))
1106   (notmuch-show-refresh-view))
1107
1108 (defun notmuch-show-toggle-elide-non-matching ()
1109   "Toggle the display of non-matching messages."
1110   (interactive)
1111   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1112   (message (if notmuch-show-elide-non-matching-messages
1113                "Showing matching messages only."
1114              "Showing all messages."))
1115   (notmuch-show-refresh-view))
1116
1117 (defun notmuch-show-toggle-thread-indentation ()
1118   "Toggle the indentation of threads."
1119   (interactive)
1120   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1121   (message (if notmuch-show-indent-content
1122                "Content is indented."
1123              "Content is not indented."))
1124   (notmuch-show-refresh-view))
1125
1126 (defun notmuch-show-insert-tree (tree depth)
1127   "Insert the message tree TREE at depth DEPTH in the current thread."
1128   (let ((msg (car tree))
1129         (replies (cadr tree)))
1130     ;; We test whether there is a message or just some replies.
1131     (when msg
1132       (notmuch-show-insert-msg msg depth))
1133     (notmuch-show-insert-thread replies (1+ depth))))
1134
1135 (defun notmuch-show-insert-thread (thread depth)
1136   "Insert the thread THREAD at depth DEPTH in the current forest."
1137   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1138
1139 (defun notmuch-show-insert-forest (forest)
1140   "Insert the forest of threads FOREST."
1141   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1142
1143 (defvar notmuch-id-regexp
1144   (concat
1145    ;; Match the id: prefix only if it begins a word (to disallow, for
1146    ;; example, matching cid:).
1147    "\\<id:\\("
1148    ;; If the term starts with a ", then parse Xapian's quoted boolean
1149    ;; term syntax, which allows for anything as long as embedded
1150    ;; double quotes escaped by doubling them.  We also disallow
1151    ;; newlines (which Xapian allows) to prevent runaway terms.
1152    "\"\\([^\"\n]\\|\"\"\\)*\""
1153    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1154    ;; next space or ).  We disallow [.,;] as the last character
1155    ;; because these are probably part of the surrounding text, and not
1156    ;; part of the id.  This doesn't match single character ids; meh.
1157    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1158    "\\)")
1159   "The regexp used to match id: links in messages.")
1160
1161 (defvar notmuch-mid-regexp
1162   ;; goto-address-url-regexp matched cid: links, which have the same
1163   ;; grammar as the message ID part of a mid: link.  Construct the
1164   ;; regexp using the same technique as goto-address-url-regexp.
1165   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1166   "The regexp used to match mid: links in messages.
1167
1168 See RFC 2392.")
1169
1170 (defun notmuch-show-buttonise-links (start end)
1171   "Buttonise URLs and mail addresses between START and END.
1172
1173 This also turns id:\"<message id>\"-parts and mid: links into
1174 buttons for a corresponding notmuch search."
1175   (goto-address-fontify-region start end)
1176   (save-excursion
1177     (let (links
1178           (beg-line (progn (goto-char start) (line-beginning-position)))
1179           (end-line (progn (goto-char end) (line-end-position))))
1180       (goto-char beg-line)
1181       (while (re-search-forward notmuch-id-regexp end-line t)
1182         (push (list (match-beginning 0) (match-end 0)
1183                     (match-string-no-properties 0)) links))
1184       (goto-char beg-line)
1185       (while (re-search-forward notmuch-mid-regexp end-line t)
1186         (let* ((mid-cid (match-string-no-properties 1))
1187                (mid (save-match-data
1188                       (string-match "^[^/]*" mid-cid)
1189                       (url-unhex-string (match-string 0 mid-cid)))))
1190           (push (list (match-beginning 0) (match-end 0)
1191                       (notmuch-id-to-query mid)) links)))
1192       (dolist (link links)
1193         ;; Remove the overlay created by goto-address-mode
1194         (remove-overlays (first link) (second link) 'goto-address t)
1195         (make-text-button (first link) (second link)
1196                           :type 'notmuch-button-type
1197                           'action `(lambda (arg)
1198                                      (notmuch-show ,(third link) current-prefix-arg))
1199                           'follow-link t
1200                           'help-echo "Mouse-1, RET: search for this message"
1201                           'face goto-address-mail-face)))))
1202
1203 ;;;###autoload
1204 (defun notmuch-show (thread-id &optional elide-toggle parent-buffer query-context buffer-name)
1205   "Run \"notmuch show\" with the given thread ID and display results.
1206
1207 ELIDE-TOGGLE, if non-nil, inverts the default elide behavior.
1208
1209 The optional PARENT-BUFFER is the notmuch-search buffer from
1210 which this notmuch-show command was executed, (so that the
1211 next thread from that buffer can be show when done with this
1212 one).
1213
1214 The optional QUERY-CONTEXT is a notmuch search term. Only
1215 messages from the thread matching this search term are shown if
1216 non-nil.
1217
1218 The optional BUFFER-NAME provides the name of the buffer in
1219 which the message thread is shown. If it is nil (which occurs
1220 when the command is called interactively) the argument to the
1221 function is used.
1222
1223 Returns the buffer containing the messages, or NIL if no messages
1224 matched."
1225   (interactive "sNotmuch show: \nP")
1226   (let ((buffer-name (generate-new-buffer-name
1227                       (or buffer-name
1228                           (concat "*notmuch-" thread-id "*")))))
1229     (switch-to-buffer (get-buffer-create buffer-name))
1230     ;; No need to track undo information for this buffer.
1231     (setq buffer-undo-list t)
1232
1233     (notmuch-show-mode)
1234
1235     ;; Set various buffer local variables to their appropriate initial
1236     ;; state. Do this after enabling `notmuch-show-mode' so that they
1237     ;; aren't wiped out.
1238     (setq notmuch-show-thread-id thread-id
1239           notmuch-show-parent-buffer parent-buffer
1240           notmuch-show-query-context query-context
1241
1242           notmuch-show-process-crypto notmuch-crypto-process-mime
1243           ;; If `elide-toggle', invert the default value.
1244           notmuch-show-elide-non-matching-messages
1245           (if elide-toggle
1246               (not notmuch-show-only-matching-messages)
1247             notmuch-show-only-matching-messages))
1248
1249     (add-hook 'post-command-hook #'notmuch-show-command-hook nil t)
1250     (jit-lock-register #'notmuch-show-buttonise-links)
1251
1252     (notmuch-tag-clear-cache)
1253
1254     (let ((inhibit-read-only t))
1255       (if (notmuch-show--build-buffer)
1256           ;; Messages were inserted into the buffer.
1257           (current-buffer)
1258
1259         ;; No messages were inserted - presumably none matched the
1260         ;; query.
1261         (kill-buffer (current-buffer))
1262         (ding)
1263         (message "No messages matched the query!")
1264         nil))))
1265
1266 (defun notmuch-show--build-buffer (&optional state)
1267   "Display messages matching the current buffer context.
1268
1269 Apply the previously saved STATE if supplied, otherwise show the
1270 first relevant message.
1271
1272 If no messages match the query return NIL."
1273   (let* ((basic-args (list notmuch-show-thread-id))
1274          (args (if notmuch-show-query-context
1275                    (append (list "\'") basic-args
1276                            (list "and (" notmuch-show-query-context ")\'"))
1277                  (append (list "\'") basic-args (list "\'"))))
1278          (cli-args (cons "--exclude=false"
1279                          (when notmuch-show-elide-non-matching-messages
1280                            (list "--entire-thread=false"))))
1281
1282          (forest (or (notmuch-query-get-threads (append cli-args args))
1283                      ;; If a query context reduced the number of
1284                      ;; results to zero, try again without it.
1285                      (and notmuch-show-query-context
1286                           (notmuch-query-get-threads (append cli-args basic-args)))))
1287
1288          ;; Must be reset every time we are going to start inserting
1289          ;; messages into the buffer.
1290          (notmuch-show-previous-subject ""))
1291
1292     (when forest
1293       (notmuch-show-insert-forest forest)
1294
1295       ;; Store the original tags for each message so that we can
1296       ;; display changes.
1297       (notmuch-show-mapc
1298        (lambda () (notmuch-show-set-prop :orig-tags (notmuch-show-get-tags))))
1299
1300       ;; Set the header line to the subject of the first message.
1301       (setq header-line-format
1302             (replace-regexp-in-string "%" "%%"
1303                                       (notmuch-sanitize
1304                                        (notmuch-show-strip-re
1305                                         (notmuch-show-get-subject)))))
1306
1307       (run-hooks 'notmuch-show-hook)
1308
1309       (if state
1310           (notmuch-show-apply-state state)
1311         ;; With no state to apply, just go to the first message.
1312         (notmuch-show-goto-first-wanted-message)))
1313
1314     ;; Report back to the caller whether any messages matched.
1315     forest))
1316
1317 (defun notmuch-show-capture-state ()
1318   "Capture the state of the current buffer.
1319
1320 This includes:
1321  - the list of open messages,
1322  - the current message."
1323   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1324
1325 (defun notmuch-show-get-query ()
1326   "Return the current query in this show buffer"
1327   (if notmuch-show-query-context
1328       (concat notmuch-show-thread-id
1329               " and ("
1330               notmuch-show-query-context
1331               ")")
1332     notmuch-show-thread-id))
1333
1334 (defun notmuch-show-goto-message (msg-id)
1335   "Go to message with msg-id."
1336   (goto-char (point-min))
1337   (unless (loop if (string= msg-id (notmuch-show-get-message-id))
1338                 return t
1339                 until (not (notmuch-show-goto-message-next)))
1340     (goto-char (point-min))
1341     (message "Message-id not found."))
1342   (notmuch-show-message-adjust))
1343
1344 (defun notmuch-show-apply-state (state)
1345   "Apply STATE to the current buffer.
1346
1347 This includes:
1348  - opening the messages previously opened,
1349  - closing all other messages,
1350  - moving to the correct current message."
1351   (let ((current (car state))
1352         (open (cadr state)))
1353
1354     ;; Open those that were open.
1355     (goto-char (point-min))
1356     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1357                                            (member (notmuch-show-get-message-id) open))
1358           until (not (notmuch-show-goto-message-next)))
1359
1360     ;; Go to the previously open message.
1361     (notmuch-show-goto-message current)))
1362
1363 (defun notmuch-show-refresh-view (&optional reset-state)
1364   "Refresh the current view.
1365
1366 Refreshes the current view, observing changes in display
1367 preferences. If invoked with a prefix argument (or RESET-STATE is
1368 non-nil) then the state of the buffer (open/closed messages) is
1369 reset based on the original query."
1370   (interactive "P")
1371   (let ((inhibit-read-only t)
1372         (state (unless reset-state
1373                  (notmuch-show-capture-state))))
1374     ;; `erase-buffer' does not seem to remove overlays, which can lead
1375     ;; to weird effects such as remaining images, so remove them
1376     ;; manually.
1377     (remove-overlays)
1378     (erase-buffer)
1379
1380     (unless (notmuch-show--build-buffer state)
1381       ;; No messages were inserted.
1382       (kill-buffer (current-buffer))
1383       (ding)
1384       (message "Refreshing the buffer resulted in no messages!"))))
1385
1386 (defvar notmuch-show-stash-map
1387   (let ((map (make-sparse-keymap)))
1388     (define-key map "c" 'notmuch-show-stash-cc)
1389     (define-key map "d" 'notmuch-show-stash-date)
1390     (define-key map "F" 'notmuch-show-stash-filename)
1391     (define-key map "f" 'notmuch-show-stash-from)
1392     (define-key map "i" 'notmuch-show-stash-message-id)
1393     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1394     (define-key map "s" 'notmuch-show-stash-subject)
1395     (define-key map "T" 'notmuch-show-stash-tags)
1396     (define-key map "t" 'notmuch-show-stash-to)
1397     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1398     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1399     (define-key map "G" 'notmuch-show-stash-git-send-email)
1400     (define-key map "?" 'notmuch-subkeymap-help)
1401     map)
1402   "Submap for stash commands")
1403 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1404
1405 (defvar notmuch-show-part-map
1406   (let ((map (make-sparse-keymap)))
1407     (define-key map "s" 'notmuch-show-save-part)
1408     (define-key map "v" 'notmuch-show-view-part)
1409     (define-key map "o" 'notmuch-show-interactively-view-part)
1410     (define-key map "|" 'notmuch-show-pipe-part)
1411     (define-key map "m" 'notmuch-show-choose-mime-of-part)
1412     (define-key map "?" 'notmuch-subkeymap-help)
1413     map)
1414   "Submap for part commands")
1415 (fset 'notmuch-show-part-map notmuch-show-part-map)
1416
1417 (defvar notmuch-show-mode-map
1418   (let ((map (make-sparse-keymap)))
1419     (set-keymap-parent map notmuch-common-keymap)
1420     (define-key map "Z" 'notmuch-tree-from-show-current-query)
1421     (define-key map (kbd "<C-tab>") 'widget-backward)
1422     (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1423     (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1424     (define-key map (kbd "TAB") 'notmuch-show-next-button)
1425     (define-key map "f" 'notmuch-show-forward-message)
1426     (define-key map "F" 'notmuch-show-forward-open-messages)
1427     (define-key map "b" 'notmuch-show-resend-message)
1428     (define-key map "l" 'notmuch-show-filter-thread)
1429     (define-key map "r" 'notmuch-show-reply-sender)
1430     (define-key map "R" 'notmuch-show-reply)
1431     (define-key map "|" 'notmuch-show-pipe-message)
1432     (define-key map "w" 'notmuch-show-save-attachments)
1433     (define-key map "V" 'notmuch-show-view-raw-message)
1434     (define-key map "c" 'notmuch-show-stash-map)
1435     (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1436     (define-key map "*" 'notmuch-show-tag-all)
1437     (define-key map "-" 'notmuch-show-remove-tag)
1438     (define-key map "+" 'notmuch-show-add-tag)
1439     (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1440     (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1441     (define-key map "A" 'notmuch-show-archive-thread-then-next)
1442     (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1443     (define-key map "N" 'notmuch-show-next-message)
1444     (define-key map "P" 'notmuch-show-previous-message)
1445     (define-key map "n" 'notmuch-show-next-open-message)
1446     (define-key map "p" 'notmuch-show-previous-open-message)
1447     (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1448     (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1449     (define-key map (kbd "DEL") 'notmuch-show-rewind)
1450     (define-key map " " 'notmuch-show-advance-and-archive)
1451     (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1452     (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1453     (define-key map "#" 'notmuch-show-print-message)
1454     (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1455     (define-key map "$" 'notmuch-show-toggle-process-crypto)
1456     (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1457     (define-key map "t" 'toggle-truncate-lines)
1458     (define-key map "." 'notmuch-show-part-map)
1459     map)
1460   "Keymap for \"notmuch show\" buffers.")
1461 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1462
1463 (define-derived-mode notmuch-show-mode fundamental-mode "notmuch-show"
1464   "Major mode for viewing a thread with notmuch.
1465
1466 This buffer contains the results of the \"notmuch show\" command
1467 for displaying a single thread of email from your email archives.
1468
1469 By default, various components of email messages, (citations,
1470 signatures, already-read messages), are hidden. You can make
1471 these parts visible by clicking with the mouse button or by
1472 pressing RET after positioning the cursor on a hidden part, (for
1473 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1474
1475 Reading the thread sequentially is well-supported by pressing
1476 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1477 to the next message, or advance to the next thread (if already on
1478 the last message of a thread).
1479
1480 Other commands are available to read or manipulate the thread
1481 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1482 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1483 without scrolling through with \\[notmuch-show-advance-and-archive]).
1484
1485 You can add or remove arbitrary tags from the current message with
1486 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1487
1488 All currently available key bindings:
1489
1490 \\{notmuch-show-mode-map}"
1491   (setq notmuch-buffer-refresh-function #'notmuch-show-refresh-view)
1492   (setq buffer-read-only t
1493         truncate-lines t))
1494
1495 (defun notmuch-tree-from-show-current-query ()
1496   "Call notmuch tree with the current query"
1497   (interactive)
1498   (notmuch-tree notmuch-show-thread-id
1499                 notmuch-show-query-context
1500                 (notmuch-show-get-message-id)))
1501
1502 (defun notmuch-show-move-to-message-top ()
1503   (goto-char (notmuch-show-message-top)))
1504
1505 (defun notmuch-show-move-to-message-bottom ()
1506   (goto-char (notmuch-show-message-bottom)))
1507
1508 (defun notmuch-show-message-adjust ()
1509   (recenter 0))
1510
1511 ;; Movement related functions.
1512
1513 ;; There's some strangeness here where a text property applied to a
1514 ;; region a->b is not found when point is at b. We walk backwards
1515 ;; until finding the property.
1516 (defun notmuch-show-message-extent ()
1517   (let (r)
1518     (save-excursion
1519       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1520         (backward-char)))
1521     r))
1522
1523 (defun notmuch-show-message-top ()
1524   (car (notmuch-show-message-extent)))
1525
1526 (defun notmuch-show-message-bottom ()
1527   (cdr (notmuch-show-message-extent)))
1528
1529 (defun notmuch-show-goto-message-next ()
1530   (let ((start (point)))
1531     (notmuch-show-move-to-message-bottom)
1532     (if (not (eobp))
1533         t
1534       (goto-char start)
1535       nil)))
1536
1537 (defun notmuch-show-goto-message-previous ()
1538   (notmuch-show-move-to-message-top)
1539   (if (bobp)
1540       nil
1541     (backward-char)
1542     (notmuch-show-move-to-message-top)
1543     t))
1544
1545 (defun notmuch-show-mapc (function)
1546   "Iterate through all messages in the current thread with
1547 `notmuch-show-goto-message-next' and call FUNCTION for side
1548 effects."
1549   (save-excursion
1550     (goto-char (point-min))
1551     (loop do (funcall function)
1552           while (notmuch-show-goto-message-next))))
1553
1554 ;; Functions relating to the visibility of messages and their
1555 ;; components.
1556
1557 (defun notmuch-show-message-visible (props visible-p)
1558   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1559   (notmuch-show-set-prop :message-visible visible-p props))
1560
1561 (defun notmuch-show-headers-visible (props visible-p)
1562   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1563   (notmuch-show-set-prop :headers-visible visible-p props))
1564
1565 ;; Functions for setting and getting attributes of the current
1566 ;; message.
1567
1568 (defun notmuch-show-set-message-properties (props)
1569   (save-excursion
1570     (notmuch-show-move-to-message-top)
1571     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1572
1573 (defun notmuch-show-get-message-properties ()
1574   "Return the properties of the current message as a plist.
1575
1576 Some useful entries are:
1577 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1578 :body - Body of the message
1579 :tags - Tags for this message"
1580   (save-excursion
1581     (notmuch-show-move-to-message-top)
1582     (get-text-property (point) :notmuch-message-properties)))
1583
1584 (defun notmuch-show-get-part-properties ()
1585   "Return the properties of the innermost part containing point.
1586
1587 This is the part property list retrieved from the CLI.  Signals
1588 an error if there is no part containing point."
1589   (or (get-text-property (point) :notmuch-part)
1590       (error "No message part here")))
1591
1592 (defun notmuch-show-set-prop (prop val &optional props)
1593   (let ((inhibit-read-only t)
1594         (props (or props
1595                    (notmuch-show-get-message-properties))))
1596     (plist-put props prop val)
1597     (notmuch-show-set-message-properties props)))
1598
1599 (defun notmuch-show-get-prop (prop &optional props)
1600   "Get property PROP from current message in show or tree mode.
1601
1602 It gets property PROP from PROPS or, if PROPS is nil, the current
1603 message in either tree or show. This means that several utility
1604 functions in notmuch-show can be used directly by notmuch-tree as
1605 they just need the correct message properties."
1606   (let ((props (or props
1607                    (cond ((eq major-mode 'notmuch-show-mode)
1608                           (notmuch-show-get-message-properties))
1609                          ((eq major-mode 'notmuch-tree-mode)
1610                           (notmuch-tree-get-message-properties))
1611                          (t nil)))))
1612     (plist-get props prop)))
1613
1614 (defun notmuch-show-get-message-id (&optional bare)
1615   "Return an id: query for the Message-Id of the current message.
1616
1617 If optional argument BARE is non-nil, return
1618 the Message-Id without id: prefix and escaping."
1619   (if bare
1620       (notmuch-show-get-prop :id)
1621     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1622
1623 (defun notmuch-show-get-messages-ids ()
1624   "Return all id: queries of messages in the current thread."
1625   (let ((message-ids))
1626     (notmuch-show-mapc
1627      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1628     message-ids))
1629
1630 (defun notmuch-show-get-messages-ids-search ()
1631   "Return a search string for all message ids of messages in the
1632 current thread."
1633   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1634
1635 ;; dme: Would it make sense to use a macro for many of these?
1636
1637 (defun notmuch-show-get-filename ()
1638   "Return the filename of the current message."
1639   (notmuch-show-get-prop :filename))
1640
1641 (defun notmuch-show-get-header (header &optional props)
1642   "Return the named header of the current message, if any."
1643   (plist-get (notmuch-show-get-prop :headers props) header))
1644
1645 (defun notmuch-show-get-cc ()
1646   (notmuch-show-get-header :Cc))
1647
1648 (defun notmuch-show-get-date ()
1649   (notmuch-show-get-header :Date))
1650
1651 (defun notmuch-show-get-from ()
1652   (notmuch-show-get-header :From))
1653
1654 (defun notmuch-show-get-subject ()
1655   (notmuch-show-get-header :Subject))
1656
1657 (defun notmuch-show-get-to ()
1658   (notmuch-show-get-header :To))
1659
1660 (defun notmuch-show-get-depth ()
1661   (notmuch-show-get-prop :depth))
1662
1663 (defun notmuch-show-set-tags (tags)
1664   "Set the tags of the current message."
1665   (notmuch-show-set-prop :tags tags)
1666   (notmuch-show-update-tags tags))
1667
1668 (defun notmuch-show-get-tags ()
1669   "Return the tags of the current message."
1670   (notmuch-show-get-prop :tags))
1671
1672 (defun notmuch-show-message-visible-p ()
1673   "Is the current message visible?"
1674   (notmuch-show-get-prop :message-visible))
1675
1676 (defun notmuch-show-headers-visible-p ()
1677   "Are the headers of the current message visible?"
1678   (notmuch-show-get-prop :headers-visible))
1679
1680 (put 'notmuch-show-mark-read 'notmuch-prefix-doc
1681      "Mark the current message as unread.")
1682 (defun notmuch-show-mark-read (&optional unread)
1683   "Mark the current message as read.
1684
1685 Mark the current message as read by applying the tag changes in
1686 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1687 default). If a prefix argument is given, the message will be
1688 marked as unread, i.e. the tag changes in
1689 `notmuch-show-mark-read-tags' will be reversed."
1690   (interactive "P")
1691   (when notmuch-show-mark-read-tags
1692     (apply 'notmuch-show-tag-message
1693            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1694
1695 (defun notmuch-show-seen-current-message (start end)
1696   "Mark the current message read if it is open.
1697
1698 We only mark it read once: if it is changed back then that is a
1699 user decision and we should not override it."
1700   (when (and (notmuch-show-message-visible-p)
1701              (not (notmuch-show-get-prop :seen)))
1702         (notmuch-show-mark-read)
1703         (notmuch-show-set-prop :seen t)))
1704
1705 (defvar notmuch-show--seen-has-errored nil)
1706 (make-variable-buffer-local 'notmuch-show--seen-has-errored)
1707
1708 (defun notmuch-show-command-hook ()
1709   (when (eq major-mode 'notmuch-show-mode)
1710     ;; We need to redisplay to get window-start and window-end correct.
1711     (redisplay)
1712     (save-excursion
1713       (condition-case err
1714           (funcall notmuch-show-mark-read-function (window-start) (window-end))
1715         ((debug error)
1716          (unless notmuch-show--seen-has-errored
1717            (setq notmuch-show--seen-has-errored 't)
1718            (setq header-line-format
1719                  (concat header-line-format
1720                          (propertize "  [some mark read tag changes may have failed]"
1721                                      'face font-lock-warning-face)))))))))
1722
1723 (defun notmuch-show-filter-thread (query)
1724   "Filter or LIMIT the current thread based on a new query string.
1725
1726 Reshows the current thread with matches defined by the new query-string."
1727   (interactive (list (notmuch-read-query "Filter thread: ")))
1728   (let ((msg-id (notmuch-show-get-message-id)))
1729     (setq notmuch-show-query-context (if (string= query "") nil query))
1730     (notmuch-show-refresh-view t)
1731     (notmuch-show-goto-message msg-id)))
1732
1733 ;; Functions for getting attributes of several messages in the current
1734 ;; thread.
1735
1736 (defun notmuch-show-get-message-ids-for-open-messages ()
1737   "Return a list of all id: queries for open messages in the current thread."
1738   (save-excursion
1739     (let (message-ids done)
1740       (goto-char (point-min))
1741       (while (not done)
1742         (if (notmuch-show-message-visible-p)
1743             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1744         (setq done (not (notmuch-show-goto-message-next)))
1745         )
1746       message-ids
1747       )))
1748
1749 ;; Commands typically bound to keys.
1750
1751 (defun notmuch-show-advance ()
1752   "Advance through thread.
1753
1754 If the current message in the thread is not yet fully visible,
1755 scroll by a near screenful to read more of the message.
1756
1757 Otherwise, (the end of the current message is already within the
1758 current window), advance to the next open message."
1759   (interactive)
1760   (let* ((end-of-this-message (notmuch-show-message-bottom))
1761          (visible-end-of-this-message (1- end-of-this-message))
1762          (ret nil))
1763     (while (invisible-p visible-end-of-this-message)
1764       (setq visible-end-of-this-message
1765             (max (point-min)
1766                  (1- (previous-single-char-property-change
1767                       visible-end-of-this-message 'invisible)))))
1768     (cond
1769      ;; Ideally we would test `end-of-this-message' against the result
1770      ;; of `window-end', but that doesn't account for the fact that
1771      ;; the end of the message might be hidden.
1772      ((and visible-end-of-this-message
1773            (> visible-end-of-this-message (window-end)))
1774       ;; The bottom of this message is not visible - scroll.
1775       (scroll-up nil))
1776
1777      ((not (= end-of-this-message (point-max)))
1778       ;; This is not the last message - move to the next visible one.
1779       (notmuch-show-next-open-message))
1780
1781      ((not (= (point) (point-max)))
1782       ;; This is the last message, but the cursor is not at the end of
1783       ;; the buffer. Move it there.
1784       (goto-char (point-max)))
1785
1786      (t
1787       ;; This is the last message - change the return value
1788       (setq ret t)))
1789     ret))
1790
1791 (defun notmuch-show-advance-and-archive ()
1792   "Advance through thread and archive.
1793
1794 This command is intended to be one of the simplest ways to
1795 process a thread of email. It works exactly like
1796 notmuch-show-advance, in that it scrolls through messages in a
1797 show buffer, except that when it gets to the end of the buffer it
1798 archives the entire current thread, (apply changes in
1799 `notmuch-archive-tags'), kills the buffer, and displays the next
1800 thread from the search from which this thread was originally
1801 shown."
1802   (interactive)
1803   (if (notmuch-show-advance)
1804       (notmuch-show-archive-thread-then-next)))
1805
1806 (defun notmuch-show-rewind ()
1807   "Backup through the thread (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1808
1809 Specifically, if the beginning of the previous email is fewer
1810 than `window-height' lines from the current point, move to it
1811 just like `notmuch-show-previous-message'.
1812
1813 Otherwise, just scroll down a screenful of the current message.
1814
1815 This command does not modify any message tags, (it does not undo
1816 any effects from previous calls to
1817 `notmuch-show-advance-and-archive'."
1818   (interactive)
1819   (let ((start-of-message (notmuch-show-message-top))
1820         (start-of-window (window-start)))
1821     (cond
1822       ;; Either this message is properly aligned with the start of the
1823       ;; window or the start of this message is not visible on the
1824       ;; screen - scroll.
1825      ((or (= start-of-message start-of-window)
1826           (< start-of-message start-of-window))
1827       (scroll-down)
1828       ;; If a small number of lines from the previous message are
1829       ;; visible, realign so that the top of the current message is at
1830       ;; the top of the screen.
1831       (when (<= (count-screen-lines (window-start) start-of-message)
1832                 next-screen-context-lines)
1833         (goto-char (notmuch-show-message-top))
1834         (notmuch-show-message-adjust))
1835       ;; Move to the top left of the window.
1836       (goto-char (window-start)))
1837      (t
1838       ;; Move to the previous message.
1839       (notmuch-show-previous-message)))))
1840
1841 (put 'notmuch-show-reply 'notmuch-prefix-doc "... and prompt for sender")
1842 (defun notmuch-show-reply (&optional prompt-for-sender)
1843   "Reply to the sender and all recipients of the current message."
1844   (interactive "P")
1845   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1846
1847 (put 'notmuch-show-reply-sender 'notmuch-prefix-doc "... and prompt for sender")
1848 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1849   "Reply to the sender of the current message."
1850   (interactive "P")
1851   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1852
1853 (put 'notmuch-show-forward-message 'notmuch-prefix-doc
1854      "... and prompt for sender")
1855 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1856   "Forward the current message."
1857   (interactive "P")
1858   (notmuch-mua-new-forward-messages (list (notmuch-show-get-message-id))
1859                                     prompt-for-sender))
1860
1861 (put 'notmuch-show-forward-open-messages 'notmuch-prefix-doc
1862      "... and prompt for sender")
1863 (defun notmuch-show-forward-open-messages (&optional prompt-for-sender)
1864   "Forward the currently open messages."
1865   (interactive "P")
1866   (let ((open-messages (notmuch-show-get-message-ids-for-open-messages)))
1867     (unless open-messages
1868       (error "No open messages to forward."))
1869     (notmuch-mua-new-forward-messages open-messages prompt-for-sender)))
1870
1871 (defun notmuch-show-resend-message (addresses)
1872   "Resend the current message."
1873   (interactive (list (notmuch-address-from-minibuffer "Resend to: ")))
1874   (when (y-or-n-p (concat "Confirm resend to " addresses " "))
1875     (notmuch-show-view-raw-message)
1876     (message-resend addresses)
1877     (notmuch-bury-or-kill-this-buffer)))
1878
1879 (defun notmuch-show-next-message (&optional pop-at-end)
1880   "Show the next message.
1881
1882 If a prefix argument is given and this is the last message in the
1883 thread, navigate to the next thread in the parent search buffer."
1884   (interactive "P")
1885   (if (notmuch-show-goto-message-next)
1886       (notmuch-show-message-adjust)
1887     (if pop-at-end
1888         (notmuch-show-next-thread)
1889       (goto-char (point-max)))))
1890
1891 (defun notmuch-show-previous-message ()
1892   "Show the previous message or the start of the current message."
1893   (interactive)
1894   (if (= (point) (notmuch-show-message-top))
1895       (notmuch-show-goto-message-previous)
1896     (notmuch-show-move-to-message-top))
1897   (notmuch-show-message-adjust))
1898
1899 (defun notmuch-show-next-open-message (&optional pop-at-end)
1900   "Show the next open message.
1901
1902 If a prefix argument is given and this is the last open message
1903 in the thread, navigate to the next thread in the parent search
1904 buffer. Return t if there was a next open message in the thread
1905 to show, nil otherwise."
1906   (interactive "P")
1907   (let (r)
1908     (while (and (setq r (notmuch-show-goto-message-next))
1909                 (not (notmuch-show-message-visible-p))))
1910     (if r
1911         (notmuch-show-message-adjust)
1912       (if pop-at-end
1913           (notmuch-show-next-thread)
1914         (goto-char (point-max))))
1915     r))
1916
1917 (defun notmuch-show-next-matching-message ()
1918   "Show the next matching message."
1919   (interactive)
1920   (let (r)
1921     (while (and (setq r (notmuch-show-goto-message-next))
1922                 (not (notmuch-show-get-prop :match))))
1923     (if r
1924         (notmuch-show-message-adjust)
1925       (goto-char (point-max)))))
1926
1927 (defun notmuch-show-open-if-matched ()
1928   "Open a message if it is matched (whether or not excluded)."
1929   (let ((props (notmuch-show-get-message-properties)))
1930     (notmuch-show-message-visible props (plist-get props :match))))
1931
1932 (defun notmuch-show-goto-first-wanted-message ()
1933   "Move to the first open message and mark it read"
1934   (goto-char (point-min))
1935   (unless (notmuch-show-message-visible-p)
1936     (notmuch-show-next-open-message))
1937   (when (eobp)
1938     ;; There are no matched non-excluded messages so open all matched
1939     ;; (necessarily excluded) messages and go to the first.
1940     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1941     (force-window-update)
1942     (goto-char (point-min))
1943     (unless (notmuch-show-message-visible-p)
1944       (notmuch-show-next-open-message))))
1945
1946 (defun notmuch-show-previous-open-message ()
1947   "Show the previous open message."
1948   (interactive)
1949   (while (and (if (= (point) (notmuch-show-message-top))
1950                   (notmuch-show-goto-message-previous)
1951                 (notmuch-show-move-to-message-top))
1952               (not (notmuch-show-message-visible-p))))
1953   (notmuch-show-message-adjust))
1954
1955 (defun notmuch-show-view-raw-message ()
1956   "View the original source of the current message."
1957   (interactive)
1958   (let* ((id (notmuch-show-get-message-id))
1959          (buf (get-buffer-create (concat "*notmuch-raw-" id "*")))
1960          (inhibit-read-only t))
1961     (switch-to-buffer buf)
1962     (erase-buffer)
1963     (let ((coding-system-for-read 'no-conversion))
1964       (call-process notmuch-command nil t nil "show" "--format=raw" id))
1965     (goto-char (point-min))
1966     (set-buffer-modified-p nil)
1967     (setq buffer-read-only t)
1968     (view-buffer buf 'kill-buffer-if-not-modified)))
1969
1970 (put 'notmuch-show-pipe-message 'notmuch-doc
1971      "Pipe the contents of the current message to a command.")
1972 (put 'notmuch-show-pipe-message 'notmuch-prefix-doc
1973      "Pipe the thread as an mbox to a command.")
1974 (defun notmuch-show-pipe-message (entire-thread command)
1975   "Pipe the contents of the current message (or thread) to COMMAND.
1976
1977 COMMAND will be executed with the raw contents of the current
1978 email message as stdin. Anything printed by the command to stdout
1979 or stderr will appear in the *notmuch-pipe* buffer.
1980
1981 If ENTIRE-THREAD is non-nil (or when invoked with a prefix
1982 argument), COMMAND will receive all open messages in the current
1983 thread (formatted as an mbox) rather than only the current
1984 message."
1985   (interactive (let ((query-string (if current-prefix-arg
1986                                        "Pipe all open messages to command: "
1987                                      "Pipe message to command: ")))
1988                  (list current-prefix-arg (read-string query-string))))
1989   (let (shell-command)
1990     (if entire-thread
1991         (setq shell-command
1992               (concat notmuch-command " show --format=mbox --exclude=false "
1993                       (shell-quote-argument
1994                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1995                       " | " command))
1996       (setq shell-command
1997             (concat notmuch-command " show --format=raw "
1998                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1999     (let ((cwd default-directory)
2000           (buf (get-buffer-create (concat "*notmuch-pipe*"))))
2001       (with-current-buffer buf
2002         (setq buffer-read-only nil)
2003         (erase-buffer)
2004         ;; Use the originating buffer's working directory instead of
2005         ;; that of the pipe buffer.
2006         (cd cwd)
2007         (let ((exit-code (call-process-shell-command shell-command nil buf)))
2008           (goto-char (point-max))
2009           (set-buffer-modified-p nil)
2010           (setq buffer-read-only t)
2011           (unless (zerop exit-code)
2012             (switch-to-buffer-other-window buf)
2013             (message (format "Command '%s' exited abnormally with code %d"
2014                              shell-command exit-code))))))))
2015
2016 (defun notmuch-show-tag-message (&rest tag-changes)
2017   "Change tags for the current message.
2018
2019 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
2020   (let* ((current-tags (notmuch-show-get-tags))
2021          (new-tags (notmuch-update-tags current-tags tag-changes)))
2022     (unless (equal current-tags new-tags)
2023       (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2024       (notmuch-show-set-tags new-tags))))
2025
2026 (defun notmuch-show-tag (tag-changes)
2027   "Change tags for the current message.
2028
2029 See `notmuch-tag' for information on the format of TAG-CHANGES."
2030   (interactive (list (notmuch-read-tag-changes (notmuch-show-get-tags)
2031                                                "Tag message")))
2032   (notmuch-tag (notmuch-show-get-message-id) tag-changes)
2033   (let* ((current-tags (notmuch-show-get-tags))
2034          (new-tags (notmuch-update-tags current-tags tag-changes)))
2035     (unless (equal current-tags new-tags)
2036       (notmuch-show-set-tags new-tags))))
2037
2038 (defun notmuch-show-tag-all (tag-changes)
2039   "Change tags for all messages in the current show buffer.
2040
2041 See `notmuch-tag' for information on the format of TAG-CHANGES."
2042   (interactive
2043    (list (let (tags)
2044            (notmuch-show-mapc
2045             (lambda () (setq tags (append (notmuch-show-get-tags) tags))))
2046            (notmuch-read-tag-changes tags "Tag thread"))))
2047   (notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
2048   (notmuch-show-mapc
2049    (lambda ()
2050      (let* ((current-tags (notmuch-show-get-tags))
2051             (new-tags (notmuch-update-tags current-tags tag-changes)))
2052        (unless (equal current-tags new-tags)
2053          (notmuch-show-set-tags new-tags))))))
2054
2055 (defun notmuch-show-add-tag (tag-changes)
2056   "Change tags for the current message (defaulting to add).
2057
2058 Same as `notmuch-show-tag' but sets initial input to '+'."
2059   (interactive
2060    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "+")))
2061   (notmuch-show-tag tag-changes))
2062
2063 (defun notmuch-show-remove-tag (tag-changes)
2064   "Change tags for the current message (defaulting to remove).
2065
2066 Same as `notmuch-show-tag' but sets initial input to '-'."
2067   (interactive
2068    (list (notmuch-read-tag-changes (notmuch-show-get-tags) "Tag message" "-")))
2069   (notmuch-show-tag tag-changes))
2070
2071 (defun notmuch-show-toggle-visibility-headers ()
2072   "Toggle the visibility of the current message headers."
2073   (interactive)
2074   (let ((props (notmuch-show-get-message-properties)))
2075     (notmuch-show-headers-visible
2076      props
2077      (not (plist-get props :headers-visible))))
2078   (force-window-update))
2079
2080 (defun notmuch-show-toggle-message ()
2081   "Toggle the visibility of the current message."
2082   (interactive)
2083   (let ((props (notmuch-show-get-message-properties)))
2084     (notmuch-show-message-visible
2085      props
2086      (not (plist-get props :message-visible))))
2087   (force-window-update))
2088
2089 (put 'notmuch-show-open-or-close-all 'notmuch-doc "Show all messages.")
2090 (put 'notmuch-show-open-or-close-all 'notmuch-prefix-doc "Hide all messages.")
2091 (defun notmuch-show-open-or-close-all ()
2092   "Set the visibility all of the messages in the current thread.
2093
2094 By default make all of the messages visible. With a prefix
2095 argument, hide all of the messages."
2096   (interactive)
2097   (save-excursion
2098     (goto-char (point-min))
2099     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
2100                                            (not current-prefix-arg))
2101           until (not (notmuch-show-goto-message-next))))
2102   (force-window-update))
2103
2104 (defun notmuch-show-next-button ()
2105   "Advance point to the next button in the buffer."
2106   (interactive)
2107   (forward-button 1))
2108
2109 (defun notmuch-show-previous-button ()
2110   "Move point back to the previous button in the buffer."
2111   (interactive)
2112   (backward-button 1))
2113
2114 (defun notmuch-show-next-thread (&optional show previous)
2115   "Move to the next item in the search results, if any.
2116
2117 If SHOW is non-nil, open the next item in a show
2118 buffer. Otherwise just highlight the next item in the search
2119 buffer. If PREVIOUS is non-nil, move to the previous item in the
2120 search results instead."
2121   (interactive "P")
2122   (let ((parent-buffer notmuch-show-parent-buffer))
2123     (notmuch-bury-or-kill-this-buffer)
2124     (when (buffer-live-p parent-buffer)
2125       (switch-to-buffer parent-buffer)
2126       (and (if previous
2127                (notmuch-search-previous-thread)
2128              (notmuch-search-next-thread))
2129            show
2130            (notmuch-search-show-thread)))))
2131
2132 (defun notmuch-show-next-thread-show ()
2133   "Show the next thread in the search results, if any."
2134   (interactive)
2135   (notmuch-show-next-thread t))
2136
2137 (defun notmuch-show-previous-thread-show ()
2138   "Show the previous thread in the search results, if any."
2139   (interactive)
2140   (notmuch-show-next-thread t t))
2141
2142 (put 'notmuch-show-archive-thread 'notmuch-prefix-doc
2143      "Un-archive each message in thread.")
2144 (defun notmuch-show-archive-thread (&optional unarchive)
2145   "Archive each message in thread.
2146
2147 Archive each message currently shown by applying the tag changes
2148 in `notmuch-archive-tags' to each. If a prefix argument is given,
2149 the messages will be \"unarchived\", i.e. the tag changes in
2150 `notmuch-archive-tags' will be reversed.
2151
2152 Note: This command is safe from any race condition of new messages
2153 being delivered to the same thread. It does not archive the
2154 entire thread, but only the messages shown in the current
2155 buffer."
2156   (interactive "P")
2157   (when notmuch-archive-tags
2158     (notmuch-show-tag-all
2159      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2160
2161 (defun notmuch-show-archive-thread-then-next ()
2162   "Archive all messages in the current buffer, then show next thread from search."
2163   (interactive)
2164   (notmuch-show-archive-thread)
2165   (notmuch-show-next-thread t))
2166
2167 (defun notmuch-show-archive-thread-then-exit ()
2168   "Archive all messages in the current buffer, then exit back to search results."
2169   (interactive)
2170   (notmuch-show-archive-thread)
2171   (notmuch-show-next-thread))
2172
2173 (put 'notmuch-show-archive-message 'notmuch-prefix-doc
2174      "Un-archive the current message.")
2175 (defun notmuch-show-archive-message (&optional unarchive)
2176   "Archive the current message.
2177
2178 Archive the current message by applying the tag changes in
2179 `notmuch-archive-tags' to it. If a prefix argument is given, the
2180 message will be \"unarchived\", i.e. the tag changes in
2181 `notmuch-archive-tags' will be reversed."
2182   (interactive "P")
2183   (when notmuch-archive-tags
2184     (apply 'notmuch-show-tag-message
2185            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
2186
2187 (defun notmuch-show-archive-message-then-next-or-exit ()
2188   "Archive the current message, then show the next open message in the current thread.
2189
2190 If at the last open message in the current thread, then exit back
2191 to search results."
2192   (interactive)
2193   (notmuch-show-archive-message)
2194   (notmuch-show-next-open-message t))
2195
2196 (defun notmuch-show-archive-message-then-next-or-next-thread ()
2197   "Archive the current message, then show the next open message in the current thread.
2198
2199 If at the last open message in the current thread, then show next
2200 thread from search."
2201   (interactive)
2202   (notmuch-show-archive-message)
2203   (unless (notmuch-show-next-open-message)
2204     (notmuch-show-next-thread t)))
2205
2206 (defun notmuch-show-stash-cc ()
2207   "Copy CC field of current message to kill-ring."
2208   (interactive)
2209   (notmuch-common-do-stash (notmuch-show-get-cc)))
2210
2211 (defun notmuch-show-stash-date ()
2212   "Copy date of current message to kill-ring."
2213   (interactive)
2214   (notmuch-common-do-stash (notmuch-show-get-date)))
2215
2216 (defun notmuch-show-stash-filename ()
2217   "Copy filename of current message to kill-ring."
2218   (interactive)
2219   (notmuch-common-do-stash (notmuch-show-get-filename)))
2220
2221 (defun notmuch-show-stash-from ()
2222   "Copy From address of current message to kill-ring."
2223   (interactive)
2224   (notmuch-common-do-stash (notmuch-show-get-from)))
2225
2226 (put 'notmuch-show-stash-message-id 'notmuch-prefix-doc
2227      "Copy thread: query matching current thread to kill-ring.")
2228 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
2229   "Copy id: query matching the current message to kill-ring.
2230
2231 If invoked with a prefix argument (or STASH-THREAD-ID is
2232 non-nil), copy thread: query matching the current thread to
2233 kill-ring."
2234   (interactive "P")
2235   (if stash-thread-id
2236       (notmuch-common-do-stash notmuch-show-thread-id)
2237     (notmuch-common-do-stash (notmuch-show-get-message-id))))
2238
2239 (defun notmuch-show-stash-message-id-stripped ()
2240   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
2241   (interactive)
2242   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
2243
2244 (defun notmuch-show-stash-subject ()
2245   "Copy Subject field of current message to kill-ring."
2246   (interactive)
2247   (notmuch-common-do-stash (notmuch-show-get-subject)))
2248
2249 (defun notmuch-show-stash-tags ()
2250   "Copy tags of current message to kill-ring as a comma separated list."
2251   (interactive)
2252   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
2253
2254 (defun notmuch-show-stash-to ()
2255   "Copy To address of current message to kill-ring."
2256   (interactive)
2257   (notmuch-common-do-stash (notmuch-show-get-to)))
2258
2259 (defun notmuch-show-stash-mlarchive-link (&optional mla)
2260   "Copy an ML Archive URI for the current message to the kill-ring.
2261
2262 This presumes that the message is available at the selected Mailing List Archive.
2263
2264 If optional argument MLA is non-nil, use the provided key instead of prompting
2265 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2266   (interactive)
2267   (let ((url (cdr (assoc
2268                    (or mla
2269                        (let ((completion-ignore-case t))
2270                          (completing-read
2271                           "Mailing List Archive: "
2272                           notmuch-show-stash-mlarchive-link-alist
2273                           nil t nil nil
2274                           notmuch-show-stash-mlarchive-link-default)))
2275                    notmuch-show-stash-mlarchive-link-alist))))
2276     (notmuch-common-do-stash
2277      (if (functionp url)
2278          (funcall url (notmuch-show-get-message-id t))
2279        (concat url (notmuch-show-get-message-id t))))))
2280
2281 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
2282   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
2283
2284 This presumes that the message is available at the selected Mailing List Archive.
2285
2286 If optional argument MLA is non-nil, use the provided key instead of prompting
2287 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2288   (interactive)
2289   (notmuch-show-stash-mlarchive-link mla)
2290   (browse-url (current-kill 0 t)))
2291
2292 (defun notmuch-show-stash-git-helper (addresses prefix)
2293   "Escape, trim, quote, and add PREFIX to each address in list of ADDRESSES, and return the result as a single string."
2294   (mapconcat (lambda (x)
2295                (concat prefix "\""
2296                        ;; escape double-quotes
2297                        (replace-regexp-in-string
2298                         "\"" "\\\\\""
2299                         ;; trim leading and trailing spaces
2300                         (replace-regexp-in-string
2301                          "\\(^ *\\| *$\\)" ""
2302                          x)) "\""))
2303              addresses " "))
2304
2305 (put 'notmuch-show-stash-git-send-email 'notmuch-prefix-doc
2306      "Copy From/To/Cc of current message to kill-ring in a form suitable for pasting to git send-email command line.")
2307
2308 (defun notmuch-show-stash-git-send-email (&optional no-in-reply-to)
2309   "Copy From/To/Cc/Message-Id of current message to kill-ring in a form suitable for pasting to git send-email command line.
2310
2311 If invoked with a prefix argument (or NO-IN-REPLY-TO is non-nil),
2312 omit --in-reply-to=<Message-Id>."
2313   (interactive "P")
2314   (notmuch-common-do-stash
2315    (mapconcat 'identity
2316               (remove ""
2317                       (list
2318                        (notmuch-show-stash-git-helper
2319                         (message-tokenize-header (notmuch-show-get-from)) "--to=")
2320                        (notmuch-show-stash-git-helper
2321                         (message-tokenize-header (notmuch-show-get-to)) "--to=")
2322                        (notmuch-show-stash-git-helper
2323                         (message-tokenize-header (notmuch-show-get-cc)) "--cc=")
2324                        (unless no-in-reply-to
2325                          (notmuch-show-stash-git-helper
2326                           (list (notmuch-show-get-message-id t)) "--in-reply-to="))))
2327               " ")))
2328
2329 ;; Interactive part functions and their helpers
2330
2331 (defun notmuch-show-generate-part-buffer (msg part)
2332   "Return a temporary buffer containing the specified part's content."
2333   (let ((buf (generate-new-buffer " *notmuch-part*"))
2334         (process-crypto notmuch-show-process-crypto))
2335     (with-current-buffer buf
2336       ;; This is always used in the content of mm handles, which
2337       ;; expect undecoded, binary part content.
2338       (insert (notmuch-get-bodypart-binary msg part process-crypto)))
2339     buf))
2340
2341 (defun notmuch-show-current-part-handle (&optional mime-type)
2342   "Return an mm-handle for the part containing point.
2343
2344 This creates a temporary buffer for the part's content; the
2345 caller is responsible for killing this buffer as appropriate.  If
2346 MIME-TYPE is given then set the handle's mime-type to MIME-TYPE."
2347   (let* ((msg (notmuch-show-get-message-properties))
2348          (part (notmuch-show-get-part-properties))
2349          (buf (notmuch-show-generate-part-buffer msg part))
2350          (computed-type (or mime-type (plist-get part :computed-type)))
2351          (filename (plist-get part :filename))
2352          (disposition (if filename `(attachment (filename . ,filename)))))
2353     (mm-make-handle buf (list computed-type) nil nil disposition)))
2354
2355 (defun notmuch-show-apply-to-current-part-handle (fn &optional mime-type)
2356   "Apply FN to an mm-handle for the part containing point.
2357
2358 This ensures that the temporary buffer created for the mm-handle
2359 is destroyed when FN returns. If MIME-TYPE is given then force
2360 part to be treated as if it had that mime-type."
2361   (let ((handle (notmuch-show-current-part-handle mime-type)))
2362     ;; emacs 24.3+ puts stdout/stderr into the calling buffer so we
2363     ;; call it from a temp-buffer, unless
2364     ;; notmuch-show-attachment-debug is non-nil in which case we put
2365     ;; it in " *notmuch-part*".
2366     (unwind-protect
2367         (if notmuch-show-attachment-debug
2368             (with-current-buffer (generate-new-buffer " *notmuch-part*")
2369               (funcall fn handle))
2370           (with-temp-buffer
2371             (funcall fn handle)))
2372       (kill-buffer (mm-handle-buffer handle)))))
2373
2374 (defun notmuch-show-part-button-default (&optional button)
2375   (interactive)
2376   (let ((button (or button (button-at (point)))))
2377     ;; Try to toggle the part, if that fails then call the default
2378     ;; action. The toggle fails if the part has no emacs renderable
2379     ;; content.
2380     (unless (notmuch-show-toggle-part-invisibility button)
2381       (call-interactively notmuch-show-part-button-default-action))))
2382
2383 (defun notmuch-show-save-part ()
2384   "Save the MIME part containing point to a file."
2385   (interactive)
2386   (notmuch-show-apply-to-current-part-handle #'mm-save-part))
2387
2388 (defun notmuch-show-view-part ()
2389   "View the MIME part containing point in an external viewer."
2390   (interactive)
2391   ;; Set mm-inlined-types to nil to force an external viewer
2392   (let ((mm-inlined-types nil))
2393     (notmuch-show-apply-to-current-part-handle #'mm-display-part)))
2394
2395 (defun notmuch-show-interactively-view-part ()
2396   "View the MIME part containing point, prompting for a viewer."
2397   (interactive)
2398   (notmuch-show-apply-to-current-part-handle #'mm-interactively-view-part))
2399
2400 (defun notmuch-show-pipe-part ()
2401   "Pipe the MIME part containing point to an external command."
2402   (interactive)
2403   (notmuch-show-apply-to-current-part-handle #'mm-pipe-part))
2404
2405
2406 (defun notmuch-show--mm-display-part (handle)
2407   "Use mm-display-part to display HANDLE in a new buffer.
2408
2409 If the part is displayed in an external application then close
2410 the new buffer."
2411   (let ((buf (get-buffer-create (generate-new-buffer-name
2412                                  (concat " *notmuch-internal-part*")))))
2413     (switch-to-buffer buf)
2414     (if (eq (mm-display-part handle) 'external)
2415         (kill-buffer buf)
2416       (goto-char (point-min))
2417       (set-buffer-modified-p nil)
2418       (view-buffer buf 'kill-buffer-if-not-modified))))
2419
2420 (defun notmuch-show-choose-mime-of-part (mime-type)
2421   "Choose the mime type to use for displaying part"
2422   (interactive
2423    (list (completing-read "Mime type to use (default text/plain): "
2424                           (mailcap-mime-types) nil nil nil nil "text/plain")))
2425   (notmuch-show-apply-to-current-part-handle #'notmuch-show--mm-display-part mime-type))
2426
2427 (provide 'notmuch-show)
2428
2429 ;;; notmuch-show.el ends here