git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (require 'cl)
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29
  30 (require 'notmuch-lib)
  31 (require 'notmuch-query)
  32 (require 'notmuch-wash)
  33 (require 'notmuch-mua)
  34
  35 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  36 (declare-function notmuch-fontify-headers "notmuch" nil)
  37 (declare-function notmuch-select-tag-with-completion "notmuch" (prompt &rest search-terms))
  38 (declare-function notmuch-search-show-thread "notmuch" nil)
  39
  40 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  41   "Headers that should be shown in a message, in this order.
  42
  43 For an open message, all of these headers will be made visible
  44 according to `notmuch-message-headers-visible' or can be toggled
  45 with `notmuch-show-toggle-headers'. For a closed message, only
  46 the first header in the list will be visible."
  47   :group 'notmuch
  48   :type '(repeat string))
  49
  50 (defcustom notmuch-message-headers-visible t
  51   "Should the headers be visible by default?
  52
  53 If this value is non-nil, then all of the headers defined in
  54 `notmuch-message-headers' will be visible by default in the display
  55 of each message. Otherwise, these headers will be hidden and
  56 `notmuch-show-toggle-headers' can be used to make the visible for
  57 any given message."
  58   :group 'notmuch
  59   :type 'boolean)
  60
  61 (defcustom notmuch-show-relative-dates t
  62   "Display relative dates in the message summary line."
  63   :group 'notmuch
  64   :type 'boolean)
  65
  66 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  67   "A list of functions called to decorate the headers listed in
  68 `notmuch-message-headers'.")
  69
  70 (defcustom notmuch-show-hook nil
  71   "Functions called after populating a `notmuch-show' buffer."
  72   :group 'notmuch
  73   :type 'hook)
  74
  75 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-excerpt-citations)
  76   "Functions used to improve the display of text/plain parts."
  77   :group 'notmuch
  78   :type 'hook
  79   :options '(notmuch-wash-convert-inline-patch-to-part
  80              notmuch-wash-wrap-long-lines
  81              notmuch-wash-tidy-citations
  82              notmuch-wash-elide-blank-lines
  83              notmuch-wash-excerpt-citations))
  84
  85 (defmacro with-current-notmuch-show-message (&rest body)
  86   "Evaluate body with current buffer set to the text of current message"
  87   `(save-excursion
  88      (let ((filename (notmuch-show-get-filename)))
  89        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" filename "*"))))
  90          (with-current-buffer buf
  91            (insert-file-contents filename nil nil nil t)
  92            ,@body)
  93          (kill-buffer buf)))))
  94
  95 (defun notmuch-show-view-all-mime-parts ()
  96   "Use external viewers to view all attachments from the current message."
  97   (interactive)
  98   (with-current-notmuch-show-message
  99    ; We ovverride the mm-inline-media-tests to indicate which message
 100    ; parts are already sufficiently handled by the original
 101    ; presentation of the message in notmuch-show mode. These parts
 102    ; will be inserted directly into the temporary buffer of
 103    ; with-current-notmuch-show-message and silently discarded.
 104    ;
 105    ; Any MIME part not explicitly mentioned here will be handled by an
 106    ; external viewer as configured in the various mailcap files.
 107    (let ((mm-inline-media-tests '(
 108                                   ("text/.*" ignore identity)
 109                                   ("application/pgp-signature" ignore identity)
 110                                   ("multipart/alternative" ignore identity)
 111                                   ("multipart/mixed" ignore identity)
 112                                   ("multipart/related" ignore identity)
 113                                  )))
 114      (mm-display-parts (mm-dissect-buffer)))))
 115
 116 (defun notmuch-foreach-mime-part (function mm-handle)
 117   (cond ((stringp (car mm-handle))
 118          (dolist (part (cdr mm-handle))
 119            (notmuch-foreach-mime-part function part)))
 120         ((bufferp (car mm-handle))
 121          (funcall function mm-handle))
 122         (t (dolist (part mm-handle)
 123              (notmuch-foreach-mime-part function part)))))
 124
 125 (defun notmuch-count-attachments (mm-handle)
 126   (let ((count 0))
 127     (notmuch-foreach-mime-part
 128      (lambda (p)
 129        (let ((disposition (mm-handle-disposition p)))
 130          (and (listp disposition)
 131               (or (equal (car disposition) "attachment")
 132                   (and (equal (car disposition) "inline")
 133                        (assq 'filename disposition)))
 134               (incf count))))
 135      mm-handle)
 136     count))
 137
 138 (defun notmuch-save-attachments (mm-handle &optional queryp)
 139   (notmuch-foreach-mime-part
 140    (lambda (p)
 141      (let ((disposition (mm-handle-disposition p)))
 142        (and (listp disposition)
 143             (or (equal (car disposition) "attachment")
 144                 (and (equal (car disposition) "inline")
 145                      (assq 'filename disposition)))
 146             (or (not queryp)
 147                 (y-or-n-p
 148                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 149             (mm-save-part p))))
 150    mm-handle))
 151
 152 (defun notmuch-show-save-attachments ()
 153   "Save all attachments from the current message."
 154   (interactive)
 155   (with-current-notmuch-show-message
 156    (let ((mm-handle (mm-dissect-buffer)))
 157      (notmuch-save-attachments
 158       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 159   (message "Done"))
 160
 161 (defun notmuch-show-fontify-header ()
 162   (let ((face (cond
 163                ((looking-at "[Tt]o:")
 164                 'message-header-to)
 165                ((looking-at "[Bb]?[Cc][Cc]:")
 166                 'message-header-cc)
 167                ((looking-at "[Ss]ubject:")
 168                 'message-header-subject)
 169                ((looking-at "[Ff]rom:")
 170                 'message-header-from)
 171                (t
 172                 'message-header-other))))
 173
 174     (overlay-put (make-overlay (point) (re-search-forward ":"))
 175                  'face 'message-header-name)
 176     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 177                  'face face)))
 178
 179 (defun notmuch-show-colour-headers ()
 180   "Apply some colouring to the current headers."
 181   (goto-char (point-min))
 182   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 183     (notmuch-show-fontify-header)
 184     (forward-line)))
 185
 186 (defun notmuch-show-spaces-n (n)
 187   "Return a string comprised of `n' spaces."
 188   (make-string n ? ))
 189
 190 (defun notmuch-show-update-tags (tags)
 191   "Update the displayed tags of the current message."
 192   (save-excursion
 193     (goto-char (notmuch-show-message-top))
 194     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 195         (let ((inhibit-read-only t))
 196           (replace-match (concat "("
 197                                  (propertize (mapconcat 'identity tags " ")
 198                                              'face 'notmuch-tag-face)
 199                                  ")"))))))
 200
 201 (defun notmuch-show-insert-headerline (headers date tags depth)
 202   "Insert a notmuch style headerline based on HEADERS for a
 203 message at DEPTH in the current thread."
 204   (let ((start (point)))
 205     (insert (notmuch-show-spaces-n depth)
 206             (plist-get headers :From)
 207             " ("
 208             date
 209             ") ("
 210             (propertize (mapconcat 'identity tags " ")
 211                         'face 'notmuch-tag-face)
 212             ")\n")
 213     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 214
 215 (defun notmuch-show-insert-header (header header-value)
 216   "Insert a single header."
 217   (insert header ": " header-value "\n"))
 218
 219 (defun notmuch-show-insert-headers (headers)
 220   "Insert the headers of the current message."
 221   (let ((start (point)))
 222     (mapc '(lambda (header)
 223              (let* ((header-symbol (intern (concat ":" header)))
 224                     (header-value (plist-get headers header-symbol)))
 225                (if (and header-value
 226                         (not (string-equal "" header-value)))
 227                    (notmuch-show-insert-header header header-value))))
 228           notmuch-message-headers)
 229     (save-excursion
 230       (save-restriction
 231         (narrow-to-region start (point-max))
 232         (run-hooks 'notmuch-show-markup-headers-hook)))))
 233
 234 (define-button-type 'notmuch-show-part-button-type
 235   'action 'notmuch-show-part-button-action
 236   'follow-link t
 237   'face 'message-mml)
 238
 239 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name)
 240   (insert-button
 241    (concat "[ "
 242            (if name (concat name ": ") "")
 243            declared-type
 244            (if (not (string-equal declared-type content-type))
 245                (concat " (as " content-type ")")
 246              "")
 247            " ]\n")
 248    :type 'notmuch-show-part-button-type
 249    :notmuch-part nth
 250    :notmuch-filename name))
 251
 252 ;; Functions handling particular MIME parts.
 253
 254 (defun notmuch-show-save-part (message-id nth &optional filename)
 255   (with-temp-buffer
 256     ;; Always acquires the part via `notmuch part', even if it is
 257     ;; available in the JSON output.
 258     (insert (notmuch-show-get-bodypart-internal message-id nth))
 259     (let ((file (read-file-name
 260                  "Filename to save as: "
 261                  (or mailcap-download-directory "~/")
 262                  nil nil
 263                  filename))
 264           (require-final-newline nil)
 265           (coding-system-for-write 'no-conversion))
 266       (write-region (point-min) (point-max) file))))
 267
 268 (defun notmuch-show-mm-display-part-inline (msg part content-type content)
 269   "Use the mm-decode/mm-view functions to display a part in the
 270 current buffer, if possible."
 271   (let ((display-buffer (current-buffer)))
 272     (with-temp-buffer
 273       (insert content)
 274       (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 275         (set-buffer display-buffer)
 276         (if (and (mm-inlinable-p handle)
 277                  (mm-inlined-p handle))
 278             (progn
 279               (mm-display-part handle)
 280               t)
 281           nil)))))
 282
 283 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 284   (let ((start (point)))
 285     ;; If this text/plain part is not the first part in the message,
 286     ;; insert a header to make this clear.
 287     (if (> nth 1)
 288         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 289     (insert (notmuch-show-get-bodypart-content msg part nth))
 290     (save-excursion
 291       (save-restriction
 292         (narrow-to-region start (point-max))
 293         (run-hook-with-args 'notmuch-show-insert-text/plain-hook depth))))
 294   t)
 295
 296 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 297   ;; If we can deduce a MIME type from the filename of the attachment,
 298   ;; do so and pass it on to the handler for that type.
 299   (if (plist-get part :filename)
 300       (let ((extension (file-name-extension (plist-get part :filename)))
 301             mime-type)
 302         (if extension
 303             (progn
 304               (mailcap-parse-mimetypes)
 305               (setq mime-type (mailcap-extension-to-mime extension))
 306               (if (and mime-type
 307                        (not (string-equal mime-type "application/octet-stream")))
 308                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 309                 nil))
 310           nil))))
 311
 312 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 313   ;; This handler _must_ succeed - it is the handler of last resort.
 314   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 315   (let ((content (notmuch-show-get-bodypart-content msg part nth)))
 316     (if content
 317         (notmuch-show-mm-display-part-inline msg part content-type content)))
 318   t)
 319
 320 ;; Functions for determining how to handle MIME parts.
 321
 322 (defun notmuch-show-split-content-type (content-type)
 323   (split-string content-type "/"))
 324
 325 (defun notmuch-show-handlers-for (content-type)
 326   "Return a list of content handlers for a part of type CONTENT-TYPE."
 327   (let (result)
 328     (mapc (lambda (func)
 329             (if (functionp func)
 330                 (push func result)))
 331           ;; Reverse order of prefrence.
 332           (list (intern (concat "notmuch-show-insert-part-*/*"))
 333                 (intern (concat
 334                          "notmuch-show-insert-part-"
 335                          (car (notmuch-show-split-content-type content-type))
 336                          "/*"))
 337                 (intern (concat "notmuch-show-insert-part-" content-type))))
 338     result))
 339
 340 ;; Helper for parts which are generally not included in the default
 341 ;; JSON output.
 342
 343 (defun notmuch-show-get-bodypart-internal (message-id part-number)
 344   (with-temp-buffer
 345     (let ((coding-system-for-read 'no-conversion))
 346       (call-process notmuch-command nil t nil
 347                     "part" (format "--part=%s" part-number) message-id)
 348       (buffer-string))))
 349
 350 (defun notmuch-show-get-bodypart-content (msg part nth)
 351   (or (plist-get part :content)
 352       (notmuch-show-get-bodypart-internal (concat "id:" (plist-get msg :id)) nth)))
 353
 354 ;; \f
 355
 356 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 357   (let ((handlers (notmuch-show-handlers-for content-type)))
 358     ;; Run the content handlers until one of them returns a non-nil
 359     ;; value.
 360     (while (and handlers
 361                 (not (funcall (car handlers) msg part content-type nth depth declared-type)))
 362       (setq handlers (cdr handlers))))
 363   t)
 364
 365 (defun notmuch-show-insert-bodypart (msg part depth)
 366   "Insert the body part PART at depth DEPTH in the current thread."
 367   (let ((content-type (downcase (plist-get part :content-type)))
 368         (nth (plist-get part :id)))
 369     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 370   ;; Some of the body part handlers leave point somewhere up in the
 371   ;; part, so we make sure that we're down at the end.
 372   (goto-char (point-max))
 373   ;; Ensure that the part ends with a carriage return.
 374   (if (not (bolp))
 375       (insert "\n")))
 376
 377 (defun notmuch-show-insert-body (msg body depth)
 378   "Insert the body BODY at depth DEPTH in the current thread."
 379   (mapc '(lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 380
 381 (defun notmuch-show-make-symbol (type)
 382   (make-symbol (concat "notmuch-show-" type)))
 383
 384 (defun notmuch-show-insert-msg (msg depth)
 385   "Insert the message MSG at depth DEPTH in the current thread."
 386   (let ((headers (plist-get msg :headers))
 387         ;; Indentation causes the buffer offset of the start/end
 388         ;; points to move, so we must use markers.
 389         message-start message-end
 390         content-start content-end
 391         headers-start headers-end
 392         body-start body-end
 393         (headers-invis-spec (notmuch-show-make-symbol "header"))
 394         (message-invis-spec (notmuch-show-make-symbol "message")))
 395
 396     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 397     ;; removing items from `buffer-invisibility-spec' (which is what
 398     ;; `notmuch-show-headers-visible' and
 399     ;; `notmuch-show-message-visible' do) is a no-op and has no
 400     ;; effect. This caused threads with only matching messages to have
 401     ;; those messages hidden initially because
 402     ;; `buffer-invisibility-spec' stayed `t'.
 403     ;;
 404     ;; This needs to be set here (rather than just above the call to
 405     ;; `notmuch-show-headers-visible') because some of the part
 406     ;; rendering or body washing functions
 407     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 408     ;; `buffer-invisibility-spec').
 409     (when (eq buffer-invisibility-spec t)
 410       (setq buffer-invisibility-spec nil))
 411
 412     (setq message-start (point-marker))
 413
 414     (notmuch-show-insert-headerline headers
 415                                     (or (if notmuch-show-relative-dates
 416                                             (plist-get msg :date_relative)
 417                                           nil)
 418                                         (plist-get headers :Date))
 419                                     (plist-get msg :tags) depth)
 420
 421     (setq content-start (point-marker))
 422
 423     ;; Set `headers-start' to point after the 'Subject:' header to be
 424     ;; compatible with the existing implementation. This just sets it
 425     ;; to after the first header.
 426     (notmuch-show-insert-headers headers)
 427     ;; Headers should include a blank line (backwards compatibility).
 428     (insert "\n")
 429     (save-excursion
 430       (goto-char content-start)
 431       (forward-line 1)
 432       (setq headers-start (point-marker)))
 433     (setq headers-end (point-marker))
 434
 435     (setq body-start (point-marker))
 436     (notmuch-show-insert-body msg (plist-get msg :body) depth)
 437     ;; Ensure that the body ends with a newline.
 438     (if (not (bolp))
 439         (insert "\n"))
 440     (setq body-end (point-marker))
 441     (setq content-end (point-marker))
 442
 443     ;; Indent according to the depth in the thread.
 444     (indent-rigidly content-start content-end depth)
 445
 446     (setq message-end (point-max-marker))
 447
 448     ;; Save the extents of this message over the whole text of the
 449     ;; message.
 450     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 451
 452     (plist-put msg :headers-invis-spec headers-invis-spec)
 453     (overlay-put (make-overlay headers-start headers-end) 'invisible headers-invis-spec)
 454
 455     (plist-put msg :message-invis-spec message-invis-spec)
 456     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 457
 458     ;; Save the properties for this message. Currently this saves the
 459     ;; entire message (augmented it with other stuff), which seems
 460     ;; like overkill. We might save a reduced subset (for example, not
 461     ;; the content).
 462     (notmuch-show-set-message-properties msg)
 463
 464     ;; Set header visibility.
 465     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 466
 467     ;; Message visibility depends on whether it matched the search
 468     ;; criteria.
 469     (notmuch-show-message-visible msg (plist-get msg :match))))
 470
 471 (defun notmuch-show-insert-tree (tree depth)
 472   "Insert the message tree TREE at depth DEPTH in the current thread."
 473   (let ((msg (car tree))
 474         (replies (cadr tree)))
 475     (notmuch-show-insert-msg msg depth)
 476     (notmuch-show-insert-thread replies (1+ depth))))
 477
 478 (defun notmuch-show-insert-thread (thread depth)
 479   "Insert the thread THREAD at depth DEPTH in the current forest."
 480   (mapc '(lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 481
 482 (defun notmuch-show-insert-forest (forest)
 483   "Insert the forest of threads FOREST."
 484   (mapc '(lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 485
 486 (defvar notmuch-show-parent-buffer nil)
 487
 488 ;;;###autoload
 489 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
 490   "Run \"notmuch show\" with the given thread ID and display results.
 491
 492 The optional PARENT-BUFFER is the notmuch-search buffer from
 493 which this notmuch-show command was executed, (so that the
 494 next thread from that buffer can be show when done with this
 495 one).
 496
 497 The optional QUERY-CONTEXT is a notmuch search term. Only
 498 messages from the thread matching this search term are shown if
 499 non-nil.
 500
 501 The optional BUFFER-NAME provides the neame of the buffer in
 502 which the message thread is shown. If it is nil (which occurs
 503 when the command is called interactively) the argument to the
 504 function is used. "
 505   (interactive "sNotmuch show: ")
 506   (let ((buffer (get-buffer-create (generate-new-buffer-name
 507                                     (or buffer-name
 508                                         (concat "*notmuch-" thread-id "*")))))
 509         (inhibit-read-only t))
 510     (switch-to-buffer buffer)
 511     (notmuch-show-mode)
 512     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 513     (erase-buffer)
 514     (goto-char (point-min))
 515     (save-excursion
 516       (let* ((basic-args (list thread-id))
 517              (args (if query-context
 518                        (append (list "\'") basic-args (list "and (" query-context ")\'"))
 519                      (append (list "\'") basic-args (list "\'")))))
 520         (notmuch-show-insert-forest (notmuch-query-get-threads args))
 521         ;; If the query context reduced the results to nothing, run
 522         ;; the basic query.
 523         (when (and (eq (buffer-size) 0)
 524                    query-context)
 525           (notmuch-show-insert-forest
 526            (notmuch-query-get-threads basic-args))))
 527
 528       ;; Enable buttonisation of URLs and email addresses in the
 529       ;; buffer.
 530       (goto-address-mode t)
 531       ;; Act on visual lines rather than logical lines.
 532       (visual-line-mode t)
 533
 534       (run-hooks 'notmuch-show-hook))
 535
 536     ;; Move straight to the first open message
 537     (if (not (notmuch-show-message-visible-p))
 538         (notmuch-show-next-open-message))
 539     (notmuch-show-mark-read)))
 540
 541 (defvar notmuch-show-stash-map
 542   (let ((map (make-sparse-keymap)))
 543     (define-key map "c" 'notmuch-show-stash-cc)
 544     (define-key map "d" 'notmuch-show-stash-date)
 545     (define-key map "F" 'notmuch-show-stash-filename)
 546     (define-key map "f" 'notmuch-show-stash-from)
 547     (define-key map "i" 'notmuch-show-stash-message-id)
 548     (define-key map "s" 'notmuch-show-stash-subject)
 549     (define-key map "T" 'notmuch-show-stash-tags)
 550     (define-key map "t" 'notmuch-show-stash-to)
 551     map)
 552   "Submap for stash commands")
 553 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
 554
 555 (defvar notmuch-show-mode-map
 556       (let ((map (make-sparse-keymap)))
 557         (define-key map "?" 'notmuch-help)
 558         (define-key map "q" 'kill-this-buffer)
 559         (define-key map (kbd "<C-tab>") 'widget-backward)
 560         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
 561         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
 562         (define-key map (kbd "TAB") 'notmuch-show-next-button)
 563         (define-key map "s" 'notmuch-search)
 564         (define-key map "m" 'notmuch-mua-mail)
 565         (define-key map "f" 'notmuch-show-forward-message)
 566         (define-key map "r" 'notmuch-show-reply)
 567         (define-key map "|" 'notmuch-show-pipe-message)
 568         (define-key map "w" 'notmuch-show-save-attachments)
 569         (define-key map "V" 'notmuch-show-view-raw-message)
 570         (define-key map "v" 'notmuch-show-view-all-mime-parts)
 571         (define-key map "c" 'notmuch-show-stash-map)
 572         (define-key map "h" 'notmuch-show-toggle-headers)
 573         (define-key map "-" 'notmuch-show-remove-tag)
 574         (define-key map "+" 'notmuch-show-add-tag)
 575         (define-key map "x" 'notmuch-show-archive-thread-then-exit)
 576         (define-key map "a" 'notmuch-show-archive-thread)
 577         (define-key map "N" 'notmuch-show-next-message)
 578         (define-key map "P" 'notmuch-show-previous-message)
 579         (define-key map "n" 'notmuch-show-next-open-message)
 580         (define-key map "p" 'notmuch-show-previous-open-message)
 581         (define-key map (kbd "DEL") 'notmuch-show-rewind)
 582         (define-key map " " 'notmuch-show-advance-and-archive)
 583         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
 584         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
 585         map)
 586       "Keymap for \"notmuch show\" buffers.")
 587 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
 588
 589 ;;;###autoload
 590 (defun notmuch-show-mode ()
 591   "Major mode for viewing a thread with notmuch.
 592
 593 This buffer contains the results of the \"notmuch show\" command
 594 for displaying a single thread of email from your email archives.
 595
 596 By default, various components of email messages, (citations,
 597 signatures, already-read messages), are hidden. You can make
 598 these parts visible by clicking with the mouse button or by
 599 pressing RET after positioning the cursor on a hidden part, (for
 600 which \\[notmuch-show-next-button] and
 601 \\[notmuch-show-previous-button] are helpful).
 602
 603 Reading the thread sequentially is well-supported by pressing
 604 \\[notmuch-show-advance-and-archive]. This will scroll the
 605 current message (if necessary), advance to the next message, or
 606 advance to the next thread (if already on the last message of a
 607 thread).
 608
 609 Other commands are available to read or manipulate the thread
 610 more selectively, (such as '\\[notmuch-show-next-message]' and
 611 '\\[notmuch-show-previous-message]' to advance to messages
 612 without removing any tags, and '\\[notmuch-show-archive-thread]'
 613 to archive an entire thread without scrolling through with
 614 \\[notmuch-show-advance-and-archive]).
 615
 616 You can add or remove arbitary tags from the current message with
 617 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
 618
 619 All currently available key bindings:
 620
 621 \\{notmuch-show-mode-map}"
 622   (interactive)
 623   (kill-all-local-variables)
 624   (use-local-map notmuch-show-mode-map)
 625   (setq major-mode 'notmuch-show-mode
 626         mode-name "notmuch-show")
 627   (setq buffer-read-only t))
 628
 629 (defun notmuch-show-move-to-message-top ()
 630   (goto-char (notmuch-show-message-top)))
 631
 632 (defun notmuch-show-move-to-message-bottom ()
 633   (goto-char (notmuch-show-message-bottom)))
 634
 635 (defun notmuch-show-message-adjust ()
 636   (recenter 0))
 637
 638 ;; Movement related functions.
 639
 640 ;; There's some strangeness here where a text property applied to a
 641 ;; region a->b is not found when point is at b. We walk backwards
 642 ;; until finding the property.
 643 (defun notmuch-show-message-extent ()
 644   (let (r)
 645     (save-excursion
 646       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
 647         (backward-char)))
 648     r))
 649
 650 (defun notmuch-show-message-top ()
 651   (car (notmuch-show-message-extent)))
 652
 653 (defun notmuch-show-message-bottom ()
 654   (cdr (notmuch-show-message-extent)))
 655
 656 (defun notmuch-show-goto-message-next ()
 657   (let ((start (point)))
 658     (notmuch-show-move-to-message-bottom)
 659     (if (not (eobp))
 660         t
 661       (goto-char start)
 662       nil)))
 663
 664 (defun notmuch-show-goto-message-previous ()
 665   (notmuch-show-move-to-message-top)
 666   (if (bobp)
 667       nil
 668     (backward-char)
 669     (notmuch-show-move-to-message-top)
 670     t))
 671
 672 (defun notmuch-show-move-past-invisible-forward ()
 673   (while (point-invisible-p)
 674     (forward-char)))
 675
 676 (defun notmuch-show-move-past-invisible-backward ()
 677   (while (point-invisible-p)
 678     (backward-char)))
 679
 680 ;; Functions relating to the visibility of messages and their
 681 ;; components.
 682
 683 (defun notmuch-show-element-visible (props visible-p spec-property)
 684   (let ((spec (plist-get props spec-property)))
 685     (if visible-p
 686         (remove-from-invisibility-spec spec)
 687       (add-to-invisibility-spec spec))))
 688
 689 (defun notmuch-show-message-visible (props visible-p)
 690   (if visible-p
 691       ;; When making the message visible, the headers may or not be
 692       ;; visible. So we check that property separately.
 693       (let ((headers-visible (plist-get props :headers-visible)))
 694         (notmuch-show-element-visible props headers-visible :headers-invis-spec)
 695         (notmuch-show-element-visible props t :message-invis-spec))
 696     (notmuch-show-element-visible props nil :headers-invis-spec)
 697     (notmuch-show-element-visible props nil :message-invis-spec))
 698
 699   (notmuch-show-set-prop :message-visible visible-p props))
 700
 701 (defun notmuch-show-headers-visible (props visible-p)
 702   (if (plist-get props :message-visible)
 703       (notmuch-show-element-visible props visible-p :headers-invis-spec))
 704   (notmuch-show-set-prop :headers-visible visible-p props))
 705
 706 ;; Functions for setting and getting attributes of the current
 707 ;; message.
 708
 709 (defun notmuch-show-set-message-properties (props)
 710   (save-excursion
 711     (notmuch-show-move-to-message-top)
 712     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 713
 714 (defun notmuch-show-get-message-properties ()
 715   (save-excursion
 716     (notmuch-show-move-to-message-top)
 717     (get-text-property (point) :notmuch-message-properties)))
 718
 719 (defun notmuch-show-set-prop (prop val &optional props)
 720   (let ((inhibit-read-only t)
 721         (props (or props
 722                    (notmuch-show-get-message-properties))))
 723     (plist-put props prop val)
 724     (notmuch-show-set-message-properties props)))
 725
 726 (defun notmuch-show-get-prop (prop &optional props)
 727   (let ((props (or props
 728                    (notmuch-show-get-message-properties))))
 729     (plist-get props prop)))
 730
 731 (defun notmuch-show-get-message-id ()
 732   "Return the message id of the current message."
 733   (concat "id:" (notmuch-show-get-prop :id)))
 734
 735 ;; dme: Would it make sense to use a macro for many of these?
 736
 737 (defun notmuch-show-get-filename ()
 738   "Return the filename of the current message."
 739   (notmuch-show-get-prop :filename))
 740
 741 (defun notmuch-show-get-header (header)
 742   "Return the named header of the current message, if any."
 743   (plist-get (notmuch-show-get-prop :headers) header))
 744
 745 (defun notmuch-show-get-cc ()
 746   (notmuch-show-get-header :Cc))
 747
 748 (defun notmuch-show-get-date ()
 749   (notmuch-show-get-header :Date))
 750
 751 (defun notmuch-show-get-from ()
 752   (notmuch-show-get-header :From))
 753
 754 (defun notmuch-show-get-subject ()
 755   (notmuch-show-get-header :Subject))
 756
 757 (defun notmuch-show-get-to ()
 758   (notmuch-show-get-header :To))
 759
 760 (defun notmuch-show-set-tags (tags)
 761   "Set the tags of the current message."
 762   (notmuch-show-set-prop :tags tags)
 763   (notmuch-show-update-tags tags))
 764
 765 (defun notmuch-show-get-tags ()
 766   "Return the tags of the current message."
 767   (notmuch-show-get-prop :tags))
 768
 769 (defun notmuch-show-message-visible-p ()
 770   "Is the current message visible?"
 771   (notmuch-show-get-prop :message-visible))
 772
 773 (defun notmuch-show-headers-visible-p ()
 774   "Are the headers of the current message visible?"
 775   (notmuch-show-get-prop :headers-visible))
 776
 777 (defun notmuch-show-mark-read ()
 778   "Mark the current message as read."
 779   (notmuch-show-remove-tag "unread"))
 780
 781 ;; Commands typically bound to keys.
 782
 783 (defun notmuch-show-advance-and-archive ()
 784   "Advance through thread and archive.
 785
 786 This command is intended to be one of the simplest ways to
 787 process a thread of email. It does the following:
 788
 789 If the current message in the thread is not yet fully visible,
 790 scroll by a near screenful to read more of the message.
 791
 792 Otherwise, (the end of the current message is already within the
 793 current window), advance to the next open message.
 794
 795 Finally, if there is no further message to advance to, and this
 796 last message is already read, then archive the entire current
 797 thread, (remove the \"inbox\" tag from each message). Also kill
 798 this buffer, and display the next thread from the search from
 799 which this thread was originally shown."
 800   (interactive)
 801   (let ((end-of-this-message (notmuch-show-message-bottom)))
 802     (cond
 803      ;; Ideally we would test `end-of-this-message' against the result
 804      ;; of `window-end', but that doesn't account for the fact that
 805      ;; the end of the message might be hidden, so we have to actually
 806      ;; go to the end, walk back over invisible text and then see if
 807      ;; point is visible.
 808      ((save-excursion
 809         (goto-char (- end-of-this-message 1))
 810         (notmuch-show-move-past-invisible-backward)
 811         (> (point) (window-end)))
 812       ;; The bottom of this message is not visible - scroll.
 813       (scroll-up nil))
 814
 815      ((not (= end-of-this-message (point-max)))
 816       ;; This is not the last message - move to the next visible one.
 817       (notmuch-show-next-open-message))
 818
 819      (t
 820       ;; This is the last message - archive the thread.
 821       (notmuch-show-archive-thread)))))
 822
 823 (defun notmuch-show-rewind ()
 824   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
 825
 826 Specifically, if the beginning of the previous email is fewer
 827 than `window-height' lines from the current point, move to it
 828 just like `notmuch-show-previous-message'.
 829
 830 Otherwise, just scroll down a screenful of the current message.
 831
 832 This command does not modify any message tags, (it does not undo
 833 any effects from previous calls to
 834 `notmuch-show-advance-and-archive'."
 835   (interactive)
 836   (let ((start-of-message (notmuch-show-message-top))
 837         (start-of-window (window-start)))
 838     (cond
 839       ;; Either this message is properly aligned with the start of the
 840       ;; window or the start of this message is not visible on the
 841       ;; screen - scroll.
 842      ((or (= start-of-message start-of-window)
 843           (< start-of-message start-of-window))
 844       (scroll-down)
 845       ;; If a small number of lines from the previous message are
 846       ;; visible, realign so that the top of the current message is at
 847       ;; the top of the screen.
 848       (if (<= (count-screen-lines (window-start) start-of-message)
 849               next-screen-context-lines)
 850           (progn
 851             (goto-char (notmuch-show-message-top))
 852             (notmuch-show-message-adjust)))
 853       ;; Move to the top left of the window.
 854       (goto-char (window-start)))
 855      (t
 856       ;; Move to the previous message.
 857       (notmuch-show-previous-message)))))
 858
 859 (defun notmuch-show-reply ()
 860   "Reply to the current message."
 861   (interactive)
 862   (notmuch-mua-reply (notmuch-show-get-message-id)))
 863
 864 (defun notmuch-show-forward-message ()
 865   "Forward the current message."
 866   (interactive)
 867   (with-current-notmuch-show-message
 868    (notmuch-mua-forward-message)))
 869
 870 (defun notmuch-show-next-message ()
 871   "Show the next message."
 872   (interactive)
 873   (if (notmuch-show-goto-message-next)
 874       (progn
 875         (notmuch-show-mark-read)
 876         (notmuch-show-message-adjust))
 877     (goto-char (point-max))))
 878
 879 (defun notmuch-show-previous-message ()
 880   "Show the previous message."
 881   (interactive)
 882   (notmuch-show-goto-message-previous)
 883   (notmuch-show-mark-read)
 884   (notmuch-show-message-adjust))
 885
 886 (defun notmuch-show-next-open-message ()
 887   "Show the next message."
 888   (interactive)
 889   (let (r)
 890     (while (and (setq r (notmuch-show-goto-message-next))
 891                 (not (notmuch-show-message-visible-p))))
 892     (if r
 893         (progn
 894           (notmuch-show-mark-read)
 895           (notmuch-show-message-adjust))
 896       (goto-char (point-max)))))
 897
 898 (defun notmuch-show-previous-open-message ()
 899   "Show the previous message."
 900   (interactive)
 901   (while (and (notmuch-show-goto-message-previous)
 902               (not (notmuch-show-message-visible-p))))
 903   (notmuch-show-mark-read)
 904   (notmuch-show-message-adjust))
 905
 906 (defun notmuch-show-view-raw-message ()
 907   "View the file holding the current message."
 908   (interactive)
 909   (view-file (notmuch-show-get-filename)))
 910
 911 (defun notmuch-show-pipe-message (command)
 912   "Pipe the contents of the current message to the given command.
 913
 914 The given command will be executed with the raw contents of the
 915 current email message as stdin. Anything printed by the command
 916 to stdout or stderr will appear in the *Messages* buffer."
 917   (interactive "sPipe message to command: ")
 918   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*"
 919          (list command " < "
 920                (shell-quote-argument (notmuch-show-get-filename)))))
 921
 922 (defun notmuch-show-add-tag (&rest toadd)
 923   "Add a tag to the current message."
 924   (interactive
 925    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 926   (apply 'notmuch-call-notmuch-process
 927          (append (cons "tag"
 928                        (mapcar (lambda (s) (concat "+" s)) toadd))
 929                  (cons (notmuch-show-get-message-id) nil)))
 930   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 931
 932 (defun notmuch-show-remove-tag (&rest toremove)
 933   "Remove a tag from the current message."
 934   (interactive
 935    (list (notmuch-select-tag-with-completion
 936           "Tag to remove: " (notmuch-show-get-message-id))))
 937   (let ((tags (notmuch-show-get-tags)))
 938     (if (intersection tags toremove :test 'string=)
 939         (progn
 940           (apply 'notmuch-call-notmuch-process
 941                  (append (cons "tag"
 942                                (mapcar (lambda (s) (concat "-" s)) toremove))
 943                          (cons (notmuch-show-get-message-id) nil)))
 944           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 945
 946 (defun notmuch-show-toggle-headers ()
 947   "Toggle the visibility of the current message headers."
 948   (interactive)
 949   (let ((props (notmuch-show-get-message-properties)))
 950     (notmuch-show-headers-visible
 951      props
 952      (not (plist-get props :headers-visible))))
 953   (force-window-update))
 954
 955 (defun notmuch-show-toggle-message ()
 956   "Toggle the visibility of the current message."
 957   (interactive)
 958   (let ((props (notmuch-show-get-message-properties)))
 959     (notmuch-show-message-visible
 960      props
 961      (not (plist-get props :message-visible))))
 962   (force-window-update))
 963
 964 (defun notmuch-show-open-or-close-all ()
 965   "Set the visibility all of the messages in the current thread.
 966 By default make all of the messages visible. With a prefix
 967 argument, hide all of the messages."
 968   (interactive)
 969   (save-excursion
 970     (goto-char (point-min))
 971     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
 972                                            (not current-prefix-arg))
 973           until (not (notmuch-show-goto-message-next))))
 974   (force-window-update))
 975
 976 (defun notmuch-show-next-button ()
 977   "Advance point to the next button in the buffer."
 978   (interactive)
 979   (forward-button 1))
 980
 981 (defun notmuch-show-previous-button ()
 982   "Move point back to the previous button in the buffer."
 983   (interactive)
 984   (backward-button 1))
 985
 986 (defun notmuch-show-archive-thread-internal (show-next)
 987   ;; Remove the tag from the current set of messages.
 988   (goto-char (point-min))
 989   (loop do (notmuch-show-remove-tag "inbox")
 990         until (not (notmuch-show-goto-message-next)))
 991   ;; Move to the next item in the search results, if any.
 992   (let ((parent-buffer notmuch-show-parent-buffer))
 993     (kill-this-buffer)
 994     (if parent-buffer
 995         (progn
 996           (switch-to-buffer parent-buffer)
 997           (forward-line)
 998           (if show-next
 999               (notmuch-search-show-thread))))))
1000
1001 (defun notmuch-show-archive-thread ()
1002   "Archive each message in thread, then show next thread from search.
1003
1004 Archive each message currently shown by removing the \"inbox\"
1005 tag from each. Then kill this buffer and show the next thread
1006 from the search from which this thread was originally shown.
1007
1008 Note: This command is safe from any race condition of new messages
1009 being delivered to the same thread. It does not archive the
1010 entire thread, but only the messages shown in the current
1011 buffer."
1012   (interactive)
1013   (notmuch-show-archive-thread-internal t))
1014
1015 (defun notmuch-show-archive-thread-then-exit ()
1016   "Archive each message in thread, then exit back to search results."
1017   (interactive)
1018   (notmuch-show-archive-thread-internal nil))
1019
1020 (defun notmuch-show-do-stash (text)
1021   (kill-new text)
1022   (message "Saved: %s" text))
1023
1024 (defun notmuch-show-stash-cc ()
1025   "Copy CC field of current message to kill-ring."
1026   (interactive)
1027   (notmuch-show-do-stash (notmuch-show-get-cc)))
1028
1029 (defun notmuch-show-stash-date ()
1030   "Copy date of current message to kill-ring."
1031   (interactive)
1032   (notmuch-show-do-stash (notmuch-show-get-date)))
1033
1034 (defun notmuch-show-stash-filename ()
1035   "Copy filename of current message to kill-ring."
1036   (interactive)
1037   (notmuch-show-do-stash (notmuch-show-get-filename)))
1038
1039 (defun notmuch-show-stash-from ()
1040   "Copy From address of current message to kill-ring."
1041   (interactive)
1042   (notmuch-show-do-stash (notmuch-show-get-from)))
1043
1044 (defun notmuch-show-stash-message-id ()
1045   "Copy message ID of current message to kill-ring."
1046   (interactive)
1047   (notmuch-show-do-stash (notmuch-show-get-message-id)))
1048
1049 (defun notmuch-show-stash-subject ()
1050   "Copy Subject field of current message to kill-ring."
1051   (interactive)
1052   (notmuch-show-do-stash (notmuch-show-get-subject)))
1053
1054 (defun notmuch-show-stash-tags ()
1055   "Copy tags of current message to kill-ring as a comma separated list."
1056   (interactive)
1057   (notmuch-show-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1058
1059 (defun notmuch-show-stash-to ()
1060   "Copy To address of current message to kill-ring."
1061   (interactive)
1062   (notmuch-show-do-stash (notmuch-show-get-to)))
1063
1064 ;; Commands typically bound to buttons.
1065
1066 (defun notmuch-show-part-button-action (button)
1067   (let ((nth (button-get button :notmuch-part)))
1068     (if nth
1069         (notmuch-show-save-part (notmuch-show-get-message-id) nth
1070                                 (button-get button :notmuch-filename))
1071       (message "Not a valid part (is it a fake part?)."))))
1072
1073 ;;
1074
1075 (provide 'notmuch-show)