git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-query)
  34 (require 'notmuch-wash)
  35 (require 'notmuch-mua)
  36 (require 'notmuch-crypto)
  37 (require 'notmuch-print)
  38
  39 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  40 (declare-function notmuch-fontify-headers "notmuch" nil)
  41 (declare-function notmuch-read-tag-changes "notmuch" (&optional initial-input &rest search-terms))
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44 (declare-function notmuch-update-tags "notmuch" (current-tags tag-changes))
  45
  46 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  47   "Headers that should be shown in a message, in this order.
  48
  49 For an open message, all of these headers will be made visible
  50 according to `notmuch-message-headers-visible' or can be toggled
  51 with `notmuch-show-toggle-headers'. For a closed message, only
  52 the first header in the list will be visible."
  53   :type '(repeat string)
  54   :group 'notmuch-show)
  55
  56 (defcustom notmuch-message-headers-visible t
  57   "Should the headers be visible by default?
  58
  59 If this value is non-nil, then all of the headers defined in
  60 `notmuch-message-headers' will be visible by default in the display
  61 of each message. Otherwise, these headers will be hidden and
  62 `notmuch-show-toggle-headers' can be used to make the visible for
  63 any given message."
  64   :type 'boolean
  65   :group 'notmuch-show)
  66
  67 (defcustom notmuch-show-relative-dates t
  68   "Display relative dates in the message summary line."
  69   :type 'boolean
  70   :group 'notmuch-show)
  71
  72 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  73   "A list of functions called to decorate the headers listed in
  74 `notmuch-message-headers'.")
  75
  76 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  77   "Functions called after populating a `notmuch-show' buffer."
  78   :type 'hook
  79   :options '(notmuch-show-turn-on-visual-line-mode)
  80   :group 'notmuch-show
  81   :group 'notmuch-hooks)
  82
  83 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  84                                                  notmuch-wash-tidy-citations
  85                                                  notmuch-wash-elide-blank-lines
  86                                                  notmuch-wash-excerpt-citations)
  87   "Functions used to improve the display of text/plain parts."
  88   :type 'hook
  89   :options '(notmuch-wash-convert-inline-patch-to-part
  90              notmuch-wash-wrap-long-lines
  91              notmuch-wash-tidy-citations
  92              notmuch-wash-elide-blank-lines
  93              notmuch-wash-excerpt-citations)
  94   :group 'notmuch-show
  95   :group 'notmuch-hooks)
  96
  97 ;; Mostly useful for debugging.
  98 (defcustom notmuch-show-all-multipart/alternative-parts t
  99   "Should all parts of multipart/alternative parts be shown?"
 100   :type 'boolean
 101   :group 'notmuch-show)
 102
 103 (defcustom notmuch-show-indent-messages-width 1
 104   "Width of message indentation in threads.
 105
 106 Messages are shown indented according to their depth in a thread.
 107 This variable determines the width of this indentation measured
 108 in number of blanks.  Defaults to `1', choose `0' to disable
 109 indentation."
 110   :type 'integer
 111   :group 'notmuch-show)
 112
 113 (defcustom notmuch-show-indent-multipart nil
 114   "Should the sub-parts of a multipart/* part be indented?"
 115   ;; dme: Not sure which is a good default.
 116   :type 'boolean
 117   :group 'notmuch-show)
 118
 119 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 120   "Default part header button action (on ENTER or mouse click)."
 121   :group 'notmuch-show
 122   :type '(choice (const :tag "Save part"
 123                         notmuch-show-save-part)
 124                  (const :tag "View part"
 125                         notmuch-show-view-part)
 126                  (const :tag "View interactively"
 127                         notmuch-show-interactively-view-part)))
 128
 129 (defcustom notmuch-show-only-matching-messages nil
 130   "Only matching messages are shown by default."
 131   :type 'boolean
 132   :group 'notmuch-show)
 133
 134 (defvar notmuch-show-thread-id nil)
 135 (make-variable-buffer-local 'notmuch-show-thread-id)
 136 (put 'notmuch-show-thread-id 'permanent-local t)
 137
 138 (defvar notmuch-show-parent-buffer nil)
 139 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 140 (put 'notmuch-show-parent-buffer 'permanent-local t)
 141
 142 (defvar notmuch-show-query-context nil)
 143 (make-variable-buffer-local 'notmuch-show-query-context)
 144 (put 'notmuch-show-query-context 'permanent-local t)
 145
 146 (defvar notmuch-show-process-crypto nil)
 147 (make-variable-buffer-local 'notmuch-show-process-crypto)
 148 (put 'notmuch-show-process-crypto 'permanent-local t)
 149
 150 (defvar notmuch-show-elide-non-matching-messages nil)
 151 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 152 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 153
 154 (defvar notmuch-show-indent-content t)
 155 (make-variable-buffer-local 'notmuch-show-indent-content)
 156 (put 'notmuch-show-indent-content 'permanent-local t)
 157
 158 (defcustom notmuch-show-stash-mlarchive-link-alist
 159   '(("Gmane" . "http://mid.gmane.org/")
 160     ("MARC" . "http://marc.info/?i=")
 161     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 162     ;; FIXME: can these services be searched by `Message-Id' ?
 163     ;; ("MarkMail" . "http://markmail.org/")
 164     ;; ("Nabble" . "http://nabble.com/")
 165     ;; ("opensubscriber" . "http://opensubscriber.com/")
 166     )
 167   "List of Mailing List Archives to use when stashing links.
 168
 169 These URIs are concatenated with the current message's
 170 Message-Id in `notmuch-show-stash-mlarchive-link'."
 171   :type '(alist :key-type (string :tag "Name")
 172                 :value-type (string :tag "URL"))
 173   :group 'notmuch-show)
 174
 175 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 176   "Default Mailing List Archive to use when stashing links.
 177
 178 This is used when `notmuch-show-stash-mlarchive-link' isn't
 179 provided with an MLA argument nor `completing-read' input."
 180   :type `(choice
 181           ,@(mapcar
 182              (lambda (mla)
 183                (list 'const :tag (car mla) :value (car mla)))
 184              notmuch-show-stash-mlarchive-link-alist))
 185   :group 'notmuch-show)
 186
 187 (defmacro with-current-notmuch-show-message (&rest body)
 188   "Evaluate body with current buffer set to the text of current message"
 189   `(save-excursion
 190      (let ((id (notmuch-show-get-message-id)))
 191        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 192          (with-current-buffer buf
 193             (call-process notmuch-command nil t nil "show" "--format=raw" id)
 194            ,@body)
 195          (kill-buffer buf)))))
 196
 197 (defun notmuch-show-turn-on-visual-line-mode ()
 198   "Enable Visual Line mode."
 199   (visual-line-mode t))
 200
 201 (defun notmuch-show-view-all-mime-parts ()
 202   "Use external viewers to view all attachments from the current message."
 203   (interactive)
 204   (with-current-notmuch-show-message
 205    ;; We override the mm-inline-media-tests to indicate which message
 206    ;; parts are already sufficiently handled by the original
 207    ;; presentation of the message in notmuch-show mode. These parts
 208    ;; will be inserted directly into the temporary buffer of
 209    ;; with-current-notmuch-show-message and silently discarded.
 210    ;;
 211    ;; Any MIME part not explicitly mentioned here will be handled by an
 212    ;; external viewer as configured in the various mailcap files.
 213    (let ((mm-inline-media-tests '(
 214                                   ("text/.*" ignore identity)
 215                                   ("application/pgp-signature" ignore identity)
 216                                   ("multipart/alternative" ignore identity)
 217                                   ("multipart/mixed" ignore identity)
 218                                   ("multipart/related" ignore identity)
 219                                  )))
 220      (mm-display-parts (mm-dissect-buffer)))))
 221
 222 (defun notmuch-foreach-mime-part (function mm-handle)
 223   (cond ((stringp (car mm-handle))
 224          (dolist (part (cdr mm-handle))
 225            (notmuch-foreach-mime-part function part)))
 226         ((bufferp (car mm-handle))
 227          (funcall function mm-handle))
 228         (t (dolist (part mm-handle)
 229              (notmuch-foreach-mime-part function part)))))
 230
 231 (defun notmuch-count-attachments (mm-handle)
 232   (let ((count 0))
 233     (notmuch-foreach-mime-part
 234      (lambda (p)
 235        (let ((disposition (mm-handle-disposition p)))
 236          (and (listp disposition)
 237               (or (equal (car disposition) "attachment")
 238                   (and (equal (car disposition) "inline")
 239                        (assq 'filename disposition)))
 240               (incf count))))
 241      mm-handle)
 242     count))
 243
 244 (defun notmuch-save-attachments (mm-handle &optional queryp)
 245   (notmuch-foreach-mime-part
 246    (lambda (p)
 247      (let ((disposition (mm-handle-disposition p)))
 248        (and (listp disposition)
 249             (or (equal (car disposition) "attachment")
 250                 (and (equal (car disposition) "inline")
 251                      (assq 'filename disposition)))
 252             (or (not queryp)
 253                 (y-or-n-p
 254                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 255             (mm-save-part p))))
 256    mm-handle))
 257
 258 (defun notmuch-show-save-attachments ()
 259   "Save all attachments from the current message."
 260   (interactive)
 261   (with-current-notmuch-show-message
 262    (let ((mm-handle (mm-dissect-buffer)))
 263      (notmuch-save-attachments
 264       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 265   (message "Done"))
 266
 267 (defun notmuch-show-with-message-as-text (fn)
 268   "Apply FN to a text representation of the current message.
 269
 270 FN is called with one argument, the message properties. It should
 271 operation on the contents of the current buffer."
 272
 273   ;; Remake the header to ensure that all information is available.
 274   (let* ((to (notmuch-show-get-to))
 275          (cc (notmuch-show-get-cc))
 276          (from (notmuch-show-get-from))
 277          (subject (notmuch-show-get-subject))
 278          (date (notmuch-show-get-date))
 279          (tags (notmuch-show-get-tags))
 280          (depth (notmuch-show-get-depth))
 281
 282          (header (concat
 283                   "Subject: " subject "\n"
 284                   "To: " to "\n"
 285                   (if (not (string= cc ""))
 286                       (concat "Cc: " cc "\n")
 287                     "")
 288                   "From: " from "\n"
 289                   "Date: " date "\n"
 290                   (if tags
 291                       (concat "Tags: "
 292                               (mapconcat #'identity tags ", ") "\n")
 293                     "")))
 294          (all (buffer-substring (notmuch-show-message-top)
 295                                 (notmuch-show-message-bottom)))
 296
 297          (props (notmuch-show-get-message-properties))
 298          (indenting notmuch-show-indent-content))
 299     (with-temp-buffer
 300       (insert all)
 301       (if indenting
 302           (indent-rigidly (point-min) (point-max) (- depth)))
 303       ;; Remove the original header.
 304       (goto-char (point-min))
 305       (re-search-forward "^$" (point-max) nil)
 306       (delete-region (point-min) (point))
 307       (insert header)
 308       (funcall fn props))))
 309
 310 (defun notmuch-show-print-message ()
 311   "Print the current message."
 312   (interactive)
 313   (notmuch-show-with-message-as-text 'notmuch-print-message))
 314
 315 (defun notmuch-show-fontify-header ()
 316   (let ((face (cond
 317                ((looking-at "[Tt]o:")
 318                 'message-header-to)
 319                ((looking-at "[Bb]?[Cc][Cc]:")
 320                 'message-header-cc)
 321                ((looking-at "[Ss]ubject:")
 322                 'message-header-subject)
 323                ((looking-at "[Ff]rom:")
 324                 'message-header-from)
 325                (t
 326                 'message-header-other))))
 327
 328     (overlay-put (make-overlay (point) (re-search-forward ":"))
 329                  'face 'message-header-name)
 330     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 331                  'face face)))
 332
 333 (defun notmuch-show-colour-headers ()
 334   "Apply some colouring to the current headers."
 335   (goto-char (point-min))
 336   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 337     (notmuch-show-fontify-header)
 338     (forward-line)))
 339
 340 (defun notmuch-show-spaces-n (n)
 341   "Return a string comprised of `n' spaces."
 342   (make-string n ? ))
 343
 344 (defun notmuch-show-update-tags (tags)
 345   "Update the displayed tags of the current message."
 346   (save-excursion
 347     (goto-char (notmuch-show-message-top))
 348     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 349         (let ((inhibit-read-only t))
 350           (replace-match (concat "("
 351                                  (propertize (mapconcat 'identity tags " ")
 352                                              'face 'notmuch-tag-face)
 353                                  ")"))))))
 354
 355 (defun notmuch-show-clean-address (address)
 356   "Try to clean a single email ADDRESS for display.  Return
 357 unchanged ADDRESS if parsing fails."
 358   (condition-case nil
 359     (let (p-name p-address)
 360       ;; It would be convenient to use `mail-header-parse-address',
 361       ;; but that expects un-decoded mailbox parts, whereas our
 362       ;; mailbox parts are already decoded (and hence may contain
 363       ;; UTF-8). Given that notmuch should handle most of the awkward
 364       ;; cases, some simple string deconstruction should be sufficient
 365       ;; here.
 366       (cond
 367        ;; "User <user@dom.ain>" style.
 368        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 369         (setq p-name (match-string 1 address)
 370               p-address (match-string 2 address)))
 371
 372        ;; "<user@dom.ain>" style.
 373        ((string-match "<\\(.*\\)>" address)
 374         (setq p-address (match-string 1 address)))
 375
 376        ;; Everything else.
 377        (t
 378         (setq p-address address)))
 379
 380       (when p-name
 381         ;; Remove elements of the mailbox part that are not relevant for
 382         ;; display, even if they are required during transport:
 383         ;;
 384         ;; Backslashes.
 385         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 386
 387         ;; Outer single and double quotes, which might be nested.
 388         (loop
 389          with start-of-loop
 390          do (setq start-of-loop p-name)
 391
 392          when (string-match "^\"\\(.*\\)\"$" p-name)
 393          do (setq p-name (match-string 1 p-name))
 394
 395          when (string-match "^'\\(.*\\)'$" p-name)
 396          do (setq p-name (match-string 1 p-name))
 397
 398          until (string= start-of-loop p-name)))
 399
 400       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 401       ;; 'foo@bar.com'.
 402       (when (string= p-name p-address)
 403         (setq p-name nil))
 404
 405       ;; If no name results, return just the address.
 406       (if (not p-name)
 407           p-address
 408         ;; Otherwise format the name and address together.
 409         (concat p-name " <" p-address ">")))
 410     (error address)))
 411
 412 (defun notmuch-show-insert-headerline (headers date tags depth)
 413   "Insert a notmuch style headerline based on HEADERS for a
 414 message at DEPTH in the current thread."
 415   (let ((start (point)))
 416     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 417             (notmuch-show-clean-address (plist-get headers :From))
 418             " ("
 419             date
 420             ") ("
 421             (propertize (mapconcat 'identity tags " ")
 422                         'face 'notmuch-tag-face)
 423             ")\n")
 424     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 425
 426 (defun notmuch-show-insert-header (header header-value)
 427   "Insert a single header."
 428   (insert header ": " header-value "\n"))
 429
 430 (defun notmuch-show-insert-headers (headers)
 431   "Insert the headers of the current message."
 432   (let ((start (point)))
 433     (mapc (lambda (header)
 434             (let* ((header-symbol (intern (concat ":" header)))
 435                    (header-value (plist-get headers header-symbol)))
 436               (if (and header-value
 437                        (not (string-equal "" header-value)))
 438                   (notmuch-show-insert-header header header-value))))
 439           notmuch-message-headers)
 440     (save-excursion
 441       (save-restriction
 442         (narrow-to-region start (point-max))
 443         (run-hooks 'notmuch-show-markup-headers-hook)))))
 444
 445 (define-button-type 'notmuch-show-part-button-type
 446   'action 'notmuch-show-part-button-default
 447   'keymap 'notmuch-show-part-button-map
 448   'follow-link t
 449   'face 'message-mml)
 450
 451 (defvar notmuch-show-part-button-map
 452   (let ((map (make-sparse-keymap)))
 453     (set-keymap-parent map button-map)
 454     (define-key map "s" 'notmuch-show-part-button-save)
 455     (define-key map "v" 'notmuch-show-part-button-view)
 456     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 457     map)
 458   "Submap for button commands")
 459 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 460
 461 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 462   (let ((button))
 463     (setq button
 464           (insert-button
 465            (concat "[ "
 466                    (if name (concat name ": ") "")
 467                    declared-type
 468                    (if (not (string-equal declared-type content-type))
 469                        (concat " (as " content-type ")")
 470                      "")
 471                    (or comment "")
 472                    " ]")
 473            :type 'notmuch-show-part-button-type
 474            :notmuch-part nth
 475            :notmuch-filename name
 476            :notmuch-content-type content-type))
 477     (insert "\n")
 478     ;; return button
 479     button))
 480
 481 ;; Functions handling particular MIME parts.
 482
 483 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 484   (declare (indent 2))
 485   (let ((process-crypto (make-symbol "process-crypto")))
 486     `(let ((,process-crypto notmuch-show-process-crypto))
 487        (with-temp-buffer
 488          (setq notmuch-show-process-crypto ,process-crypto)
 489          ;; Always acquires the part via `notmuch part', even if it is
 490          ;; available in the JSON output.
 491          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 492          ,@body))))
 493
 494 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 495   (notmuch-with-temp-part-buffer message-id nth
 496     (let ((file (read-file-name
 497                  "Filename to save as: "
 498                  (or mailcap-download-directory "~/")
 499                  nil nil
 500                  filename)))
 501       ;; Don't re-compress .gz & al.  Arguably we should make
 502       ;; `file-name-handler-alist' nil, but that would chop
 503       ;; ange-ftp, which is reasonable to use here.
 504       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 505
 506 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 507   (notmuch-with-temp-part-buffer message-id nth
 508     ;; set mm-inlined-types to nil to force an external viewer
 509     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 510           (mm-inlined-types nil))
 511       ;; We override mm-save-part as notmuch-show-save-part is better
 512       ;; since it offers the filename. We need to lexically bind
 513       ;; everything we need for notmuch-show-save-part to prevent
 514       ;; potential dynamic shadowing.
 515       (lexical-let ((message-id message-id)
 516                     (nth nth)
 517                     (filename filename)
 518                     (content-type content-type))
 519         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 520                                            message-id nth filename content-type)))
 521           (mm-display-part handle))))))
 522
 523 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 524   (notmuch-with-temp-part-buffer message-id nth
 525     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 526       (mm-interactively-view-part handle))))
 527
 528 (defun notmuch-show-mm-display-part-inline (msg part nth content-type)
 529   "Use the mm-decode/mm-view functions to display a part in the
 530 current buffer, if possible."
 531   (let ((display-buffer (current-buffer)))
 532     (with-temp-buffer
 533       (let* ((charset (plist-get part :content-charset))
 534              (handle (mm-make-handle (current-buffer) `(,content-type (charset . ,charset)))))
 535         ;; If the user wants the part inlined, insert the content and
 536         ;; test whether we are able to inline it (which includes both
 537         ;; capability and suitability tests).
 538         (when (mm-inlined-p handle)
 539           (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 540           (when (mm-inlinable-p handle)
 541             (set-buffer display-buffer)
 542             (mm-display-part handle)
 543             t))))))
 544
 545 (defun notmuch-show-multipart/*-to-list (part)
 546   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 547           (plist-get part :content)))
 548
 549 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 550   (notmuch-show-insert-part-header nth declared-type content-type nil)
 551   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 552         (inner-parts (plist-get part :content))
 553         (start (point)))
 554     ;; This inserts all parts of the chosen type rather than just one,
 555     ;; but it's not clear that this is the wrong thing to do - which
 556     ;; should be chosen if there are more than one that match?
 557     (mapc (lambda (inner-part)
 558             (let ((inner-type (plist-get inner-part :content-type)))
 559               (if (or notmuch-show-all-multipart/alternative-parts
 560                       (string= chosen-type inner-type))
 561                   (notmuch-show-insert-bodypart msg inner-part depth)
 562                 (notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
 563           inner-parts)
 564
 565     (when notmuch-show-indent-multipart
 566       (indent-rigidly start (point) 1)))
 567   t)
 568
 569 (defun notmuch-show-setup-w3m ()
 570   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 571   (interactive)
 572   (if (boundp 'w3m-cid-retrieve-function-alist)
 573     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 574       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 575             w3m-cid-retrieve-function-alist)))
 576   (setq mm-inline-text-html-with-images t))
 577
 578 (defvar w3m-current-buffer) ;; From `w3m.el'.
 579 (defvar notmuch-show-w3m-cid-store nil)
 580 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 581
 582 (defun notmuch-show-w3m-cid-store-internal (content-id
 583                                             message-id
 584                                             part-number
 585                                             content-type
 586                                             content)
 587   (push (list content-id
 588               message-id
 589               part-number
 590               content-type
 591               content)
 592         notmuch-show-w3m-cid-store))
 593
 594 (defun notmuch-show-w3m-cid-store (msg part)
 595   (let ((content-id (plist-get part :content-id)))
 596     (when content-id
 597       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 598                                            (plist-get msg :id)
 599                                            (plist-get part :id)
 600                                            (plist-get part :content-type)
 601                                            nil))))
 602
 603 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 604   (let ((matching-part (with-current-buffer w3m-current-buffer
 605                          (assoc url notmuch-show-w3m-cid-store))))
 606     (if matching-part
 607         (let ((message-id (nth 1 matching-part))
 608               (part-number (nth 2 matching-part))
 609               (content-type (nth 3 matching-part))
 610               (content (nth 4 matching-part)))
 611           ;; If we don't already have the content, get it and cache
 612           ;; it, as some messages reference the same cid: part many
 613           ;; times (hundreds!), which results in many calls to
 614           ;; `notmuch part'.
 615           (unless content
 616             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 617                                                               part-number notmuch-show-process-crypto))
 618             (with-current-buffer w3m-current-buffer
 619               (notmuch-show-w3m-cid-store-internal url
 620                                                    message-id
 621                                                    part-number
 622                                                    content-type
 623                                                    content)))
 624           (insert content)
 625           content-type)
 626       nil)))
 627
 628 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 629   (notmuch-show-insert-part-header nth declared-type content-type nil)
 630   (let ((inner-parts (plist-get part :content))
 631         (start (point)))
 632
 633     ;; We assume that the first part is text/html and the remainder
 634     ;; things that it references.
 635
 636     ;; Stash the non-primary parts.
 637     (mapc (lambda (part)
 638             (notmuch-show-w3m-cid-store msg part))
 639           (cdr inner-parts))
 640
 641     ;; Render the primary part.
 642     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 643
 644     (when notmuch-show-indent-multipart
 645       (indent-rigidly start (point) 1)))
 646   t)
 647
 648 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 649   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 650     (button-put button 'face 'notmuch-crypto-part-header)
 651     ;; add signature status button if sigstatus provided
 652     (if (plist-member part :sigstatus)
 653         (let* ((from (notmuch-show-get-header :From msg))
 654                (sigstatus (car (plist-get part :sigstatus))))
 655           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 656       ;; if we're not adding sigstatus, tell the user how they can get it
 657       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 658
 659   (let ((inner-parts (plist-get part :content))
 660         (start (point)))
 661     ;; Show all of the parts.
 662     (mapc (lambda (inner-part)
 663             (notmuch-show-insert-bodypart msg inner-part depth))
 664           inner-parts)
 665
 666     (when notmuch-show-indent-multipart
 667       (indent-rigidly start (point) 1)))
 668   t)
 669
 670 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 671   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 672     (button-put button 'face 'notmuch-crypto-part-header)
 673     ;; add encryption status button if encstatus specified
 674     (if (plist-member part :encstatus)
 675         (let ((encstatus (car (plist-get part :encstatus))))
 676           (notmuch-crypto-insert-encstatus-button encstatus)
 677           ;; add signature status button if sigstatus specified
 678           (if (plist-member part :sigstatus)
 679               (let* ((from (notmuch-show-get-header :From msg))
 680                      (sigstatus (car (plist-get part :sigstatus))))
 681                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 682       ;; if we're not adding encstatus, tell the user how they can get it
 683       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 684
 685   (let ((inner-parts (plist-get part :content))
 686         (start (point)))
 687     ;; Show all of the parts.
 688     (mapc (lambda (inner-part)
 689             (notmuch-show-insert-bodypart msg inner-part depth))
 690           inner-parts)
 691
 692     (when notmuch-show-indent-multipart
 693       (indent-rigidly start (point) 1)))
 694   t)
 695
 696 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 697   (notmuch-show-insert-part-header nth declared-type content-type nil)
 698   (let ((inner-parts (plist-get part :content))
 699         (start (point)))
 700     ;; Show all of the parts.
 701     (mapc (lambda (inner-part)
 702             (notmuch-show-insert-bodypart msg inner-part depth))
 703           inner-parts)
 704
 705     (when notmuch-show-indent-multipart
 706       (indent-rigidly start (point) 1)))
 707   t)
 708
 709 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 710   (notmuch-show-insert-part-header nth declared-type content-type nil)
 711   (let* ((message (car (plist-get part :content)))
 712          (body (car (plist-get message :body)))
 713          (start (point)))
 714
 715     ;; Override `notmuch-message-headers' to force `From' to be
 716     ;; displayed.
 717     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 718       (notmuch-show-insert-headers (plist-get message :headers)))
 719
 720     ;; Blank line after headers to be compatible with the normal
 721     ;; message display.
 722     (insert "\n")
 723
 724     ;; Show the body
 725     (notmuch-show-insert-bodypart msg body depth)
 726
 727     (when notmuch-show-indent-multipart
 728       (indent-rigidly start (point) 1)))
 729   t)
 730
 731 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 732   (let ((start (point)))
 733     ;; If this text/plain part is not the first part in the message,
 734     ;; insert a header to make this clear.
 735     (if (> nth 1)
 736         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 737     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 738     (save-excursion
 739       (save-restriction
 740         (narrow-to-region start (point-max))
 741         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 742   t)
 743
 744 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 745   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 746   (insert (with-temp-buffer
 747             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 748             (goto-char (point-min))
 749             (let ((file (make-temp-file "notmuch-ical"))
 750                   result)
 751               (icalendar--convert-ical-to-diary
 752                (icalendar--read-element nil nil)
 753                file t)
 754               (set-buffer (get-file-buffer file))
 755               (setq result (buffer-substring (point-min) (point-max)))
 756               (set-buffer-modified-p nil)
 757               (kill-buffer (current-buffer))
 758               (delete-file file)
 759               result)))
 760   t)
 761
 762 ;; For backwards compatibility.
 763 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 764   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 765
 766 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 767   ;; If we can deduce a MIME type from the filename of the attachment,
 768   ;; do so and pass it on to the handler for that type.
 769   (if (plist-get part :filename)
 770       (let ((extension (file-name-extension (plist-get part :filename)))
 771             mime-type)
 772         (if extension
 773             (progn
 774               (mailcap-parse-mimetypes)
 775               (setq mime-type (mailcap-extension-to-mime extension))
 776               (if (and mime-type
 777                        (not (string-equal mime-type "application/octet-stream")))
 778                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 779                 nil))
 780           nil))))
 781
 782 ;; Handler for wash generated inline patch fake parts.
 783 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 784   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 785
 786 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 787   ;; This handler _must_ succeed - it is the handler of last resort.
 788   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 789   (notmuch-show-mm-display-part-inline msg part nth content-type)
 790   t)
 791
 792 ;; Functions for determining how to handle MIME parts.
 793
 794 (defun notmuch-show-handlers-for (content-type)
 795   "Return a list of content handlers for a part of type CONTENT-TYPE."
 796   (let (result)
 797     (mapc (lambda (func)
 798             (if (functionp func)
 799                 (push func result)))
 800           ;; Reverse order of prefrence.
 801           (list (intern (concat "notmuch-show-insert-part-*/*"))
 802                 (intern (concat
 803                          "notmuch-show-insert-part-"
 804                          (car (notmuch-split-content-type content-type))
 805                          "/*"))
 806                 (intern (concat "notmuch-show-insert-part-" content-type))))
 807     result))
 808
 809 ;; \f
 810
 811 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 812   (let ((handlers (notmuch-show-handlers-for content-type)))
 813     ;; Run the content handlers until one of them returns a non-nil
 814     ;; value.
 815     (while (and handlers
 816                 (not (funcall (car handlers) msg part content-type nth depth declared-type)))
 817       (setq handlers (cdr handlers))))
 818   t)
 819
 820 (defun notmuch-show-insert-bodypart (msg part depth)
 821   "Insert the body part PART at depth DEPTH in the current thread."
 822   (let ((content-type (downcase (plist-get part :content-type)))
 823         (nth (plist-get part :id)))
 824     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
 825   ;; Some of the body part handlers leave point somewhere up in the
 826   ;; part, so we make sure that we're down at the end.
 827   (goto-char (point-max))
 828   ;; Ensure that the part ends with a carriage return.
 829   (unless (bolp)
 830     (insert "\n")))
 831
 832 (defun notmuch-show-insert-body (msg body depth)
 833   "Insert the body BODY at depth DEPTH in the current thread."
 834   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 835
 836 (defun notmuch-show-make-symbol (type)
 837   (make-symbol (concat "notmuch-show-" type)))
 838
 839 (defun notmuch-show-strip-re (string)
 840   (replace-regexp-in-string "\\([Rr]e: *\\)+" "" string))
 841
 842 (defvar notmuch-show-previous-subject "")
 843 (make-variable-buffer-local 'notmuch-show-previous-subject)
 844
 845 (defun notmuch-show-insert-msg (msg depth)
 846   "Insert the message MSG at depth DEPTH in the current thread."
 847   (let* ((headers (plist-get msg :headers))
 848          ;; Indentation causes the buffer offset of the start/end
 849          ;; points to move, so we must use markers.
 850          message-start message-end
 851          content-start content-end
 852          headers-start headers-end
 853          body-start body-end
 854          (headers-invis-spec (notmuch-show-make-symbol "header"))
 855          (message-invis-spec (notmuch-show-make-symbol "message"))
 856          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 857
 858     ;; Set `buffer-invisibility-spec' to `nil' (a list), otherwise
 859     ;; removing items from `buffer-invisibility-spec' (which is what
 860     ;; `notmuch-show-headers-visible' and
 861     ;; `notmuch-show-message-visible' do) is a no-op and has no
 862     ;; effect. This caused threads with only matching messages to have
 863     ;; those messages hidden initially because
 864     ;; `buffer-invisibility-spec' stayed `t'.
 865     ;;
 866     ;; This needs to be set here (rather than just above the call to
 867     ;; `notmuch-show-headers-visible') because some of the part
 868     ;; rendering or body washing functions
 869     ;; (e.g. `notmuch-wash-text/plain-citations') manipulate
 870     ;; `buffer-invisibility-spec').
 871     (when (eq buffer-invisibility-spec t)
 872       (setq buffer-invisibility-spec nil))
 873
 874     (setq message-start (point-marker))
 875
 876     (notmuch-show-insert-headerline headers
 877                                     (or (if notmuch-show-relative-dates
 878                                             (plist-get msg :date_relative)
 879                                           nil)
 880                                         (plist-get headers :Date))
 881                                     (plist-get msg :tags) depth)
 882
 883     (setq content-start (point-marker))
 884
 885     (plist-put msg :headers-invis-spec headers-invis-spec)
 886     (plist-put msg :message-invis-spec message-invis-spec)
 887
 888     ;; Set `headers-start' to point after the 'Subject:' header to be
 889     ;; compatible with the existing implementation. This just sets it
 890     ;; to after the first header.
 891     (notmuch-show-insert-headers headers)
 892     (save-excursion
 893       (goto-char content-start)
 894       ;; If the subject of this message is the same as that of the
 895       ;; previous message, don't display it when this message is
 896       ;; collapsed.
 897       (when (not (string= notmuch-show-previous-subject
 898                           bare-subject))
 899         (forward-line 1))
 900       (setq headers-start (point-marker)))
 901     (setq headers-end (point-marker))
 902
 903     (setq notmuch-show-previous-subject bare-subject)
 904
 905     (setq body-start (point-marker))
 906     ;; A blank line between the headers and the body.
 907     (insert "\n")
 908     (notmuch-show-insert-body msg (plist-get msg :body)
 909                               (if notmuch-show-indent-content depth 0))
 910     ;; Ensure that the body ends with a newline.
 911     (unless (bolp)
 912       (insert "\n"))
 913     (setq body-end (point-marker))
 914     (setq content-end (point-marker))
 915
 916     ;; Indent according to the depth in the thread.
 917     (if notmuch-show-indent-content
 918         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 919
 920     (setq message-end (point-max-marker))
 921
 922     ;; Save the extents of this message over the whole text of the
 923     ;; message.
 924     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 925
 926     (let ((headers-overlay (make-overlay headers-start headers-end))
 927           (invis-specs (list headers-invis-spec message-invis-spec)))
 928       (overlay-put headers-overlay 'invisible invis-specs)
 929       (overlay-put headers-overlay 'priority 10))
 930     (overlay-put (make-overlay body-start body-end) 'invisible message-invis-spec)
 931
 932     (plist-put msg :depth depth)
 933
 934     ;; Save the properties for this message. Currently this saves the
 935     ;; entire message (augmented it with other stuff), which seems
 936     ;; like overkill. We might save a reduced subset (for example, not
 937     ;; the content).
 938     (notmuch-show-set-message-properties msg)
 939
 940     ;; Set header visibility.
 941     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 942
 943     ;; Message visibility depends on whether it matched the search
 944     ;; criteria.
 945     (notmuch-show-message-visible msg (and (plist-get msg :match)
 946                                            (not (plist-get msg :excluded))))))
 947
 948 (defun notmuch-show-toggle-process-crypto ()
 949   "Toggle the processing of cryptographic MIME parts."
 950   (interactive)
 951   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 952   (message (if notmuch-show-process-crypto
 953                "Processing cryptographic MIME parts."
 954              "Not processing cryptographic MIME parts."))
 955   (notmuch-show-refresh-view))
 956
 957 (defun notmuch-show-toggle-elide-non-matching ()
 958   "Toggle the display of non-matching messages."
 959   (interactive)
 960   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 961   (message (if notmuch-show-elide-non-matching-messages
 962                "Showing matching messages only."
 963              "Showing all messages."))
 964   (notmuch-show-refresh-view))
 965
 966 (defun notmuch-show-toggle-thread-indentation ()
 967   "Toggle the indentation of threads."
 968   (interactive)
 969   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
 970   (message (if notmuch-show-indent-content
 971                "Content is indented."
 972              "Content is not indented."))
 973   (notmuch-show-refresh-view))
 974
 975 (defun notmuch-show-insert-tree (tree depth)
 976   "Insert the message tree TREE at depth DEPTH in the current thread."
 977   (let ((msg (car tree))
 978         (replies (cadr tree)))
 979     (if (or (not notmuch-show-elide-non-matching-messages)
 980             (plist-get msg :match))
 981         (notmuch-show-insert-msg msg depth))
 982     (notmuch-show-insert-thread replies (1+ depth))))
 983
 984 (defun notmuch-show-insert-thread (thread depth)
 985   "Insert the thread THREAD at depth DEPTH in the current forest."
 986   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
 987
 988 (defun notmuch-show-insert-forest (forest)
 989   "Insert the forest of threads FOREST."
 990   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
 991
 992 (defun notmuch-show-buttonise-links (start end)
 993   "Buttonise URLs and mail addresses between START and END.
 994
 995 This also turns id:\"<message id>\"-parts into buttons for
 996 a corresponding notmuch search."
 997   (goto-address-fontify-region start end)
 998   (save-excursion
 999     (goto-char start)
1000     (while (re-search-forward "id:\\(\"?\\)[^[:space:]\"]+\\1" end t)
1001       ;; remove the overlay created by goto-address-mode
1002       (remove-overlays (match-beginning 0) (match-end 0) 'goto-address t)
1003       (make-text-button (match-beginning 0) (match-end 0)
1004                         'action `(lambda (arg)
1005                                    (notmuch-show ,(match-string-no-properties 0)))
1006                         'follow-link t
1007                         'help-echo "Mouse-1, RET: search for this message"
1008                         'face goto-address-mail-face))))
1009
1010 ;;;###autoload
1011 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1012   "Run \"notmuch show\" with the given thread ID and display results.
1013
1014 The optional PARENT-BUFFER is the notmuch-search buffer from
1015 which this notmuch-show command was executed, (so that the
1016 next thread from that buffer can be show when done with this
1017 one).
1018
1019 The optional QUERY-CONTEXT is a notmuch search term. Only
1020 messages from the thread matching this search term are shown if
1021 non-nil.
1022
1023 The optional BUFFER-NAME provides the name of the buffer in
1024 which the message thread is shown. If it is nil (which occurs
1025 when the command is called interactively) the argument to the
1026 function is used."
1027   (interactive "sNotmuch show: ")
1028   (let ((buffer-name (generate-new-buffer-name
1029                       (or buffer-name
1030                           (concat "*notmuch-" thread-id "*")))))
1031     (switch-to-buffer (get-buffer-create buffer-name))
1032     ;; Set the default value for `notmuch-show-process-crypto' in this
1033     ;; buffer.
1034     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1035     ;; Set the default value for
1036     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1037     ;; there is a prefix argument, invert the default.
1038     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1039     (if current-prefix-arg
1040         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1041
1042     (setq notmuch-show-thread-id thread-id
1043           notmuch-show-parent-buffer parent-buffer
1044           notmuch-show-query-context query-context)
1045     (notmuch-show-build-buffer)
1046     (notmuch-show-goto-first-wanted-message)))
1047
1048 (defun notmuch-show-build-buffer ()
1049   (let ((inhibit-read-only t))
1050
1051     (notmuch-show-mode)
1052     ;; Don't track undo information for this buffer
1053     (set 'buffer-undo-list t)
1054
1055     (erase-buffer)
1056     (goto-char (point-min))
1057     (save-excursion
1058       (let* ((basic-args (list notmuch-show-thread-id))
1059              (args (if notmuch-show-query-context
1060                        (append (list "\'") basic-args
1061                                (list "and (" notmuch-show-query-context ")\'"))
1062                      (append (list "\'") basic-args (list "\'")))))
1063         (notmuch-show-insert-forest (notmuch-query-get-threads
1064                                      (cons "--exclude=false" args)))
1065         ;; If the query context reduced the results to nothing, run
1066         ;; the basic query.
1067         (when (and (eq (buffer-size) 0)
1068                    notmuch-show-query-context)
1069           (notmuch-show-insert-forest
1070            (notmuch-query-get-threads
1071             (cons "--exclude=false" basic-args)))))
1072
1073       (jit-lock-register #'notmuch-show-buttonise-links)
1074
1075       (run-hooks 'notmuch-show-hook))
1076
1077     ;; Set the header line to the subject of the first message.
1078     (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))))
1079
1080 (defun notmuch-show-capture-state ()
1081   "Capture the state of the current buffer.
1082
1083 This includes:
1084  - the list of open messages,
1085  - the current message."
1086   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1087
1088 (defun notmuch-show-apply-state (state)
1089   "Apply STATE to the current buffer.
1090
1091 This includes:
1092  - opening the messages previously opened,
1093  - closing all other messages,
1094  - moving to the correct current message."
1095   (let ((current (car state))
1096         (open (cadr state)))
1097
1098     ;; Open those that were open.
1099     (goto-char (point-min))
1100     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1101                                            (member (notmuch-show-get-message-id) open))
1102           until (not (notmuch-show-goto-message-next)))
1103
1104     ;; Go to the previously open message.
1105     (goto-char (point-min))
1106     (unless (loop if (string= current (notmuch-show-get-message-id))
1107                   return t
1108                   until (not (notmuch-show-goto-message-next)))
1109       (goto-char (point-min))
1110       (message "Previously current message not found."))
1111     (notmuch-show-message-adjust)))
1112
1113 (defun notmuch-show-refresh-view (&optional reset-state)
1114   "Refresh the current view.
1115
1116 Refreshes the current view, observing changes in display
1117 preferences. If invoked with a prefix argument (or RESET-STATE is
1118 non-nil) then the state of the buffer (open/closed messages) is
1119 reset based on the original query."
1120   (interactive "P")
1121   (let ((inhibit-read-only t)
1122         (state (unless reset-state
1123                  (notmuch-show-capture-state))))
1124     (erase-buffer)
1125     (notmuch-show-build-buffer)
1126     (if state
1127         (notmuch-show-apply-state state)
1128       ;; We're resetting state, so navigate to the first open message
1129       ;; and mark it read, just like opening a new show buffer.
1130       (notmuch-show-goto-first-wanted-message))))
1131
1132 (defvar notmuch-show-stash-map
1133   (let ((map (make-sparse-keymap)))
1134     (define-key map "c" 'notmuch-show-stash-cc)
1135     (define-key map "d" 'notmuch-show-stash-date)
1136     (define-key map "F" 'notmuch-show-stash-filename)
1137     (define-key map "f" 'notmuch-show-stash-from)
1138     (define-key map "i" 'notmuch-show-stash-message-id)
1139     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1140     (define-key map "s" 'notmuch-show-stash-subject)
1141     (define-key map "T" 'notmuch-show-stash-tags)
1142     (define-key map "t" 'notmuch-show-stash-to)
1143     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1144     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1145     map)
1146   "Submap for stash commands")
1147 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1148
1149 (defvar notmuch-show-mode-map
1150       (let ((map (make-sparse-keymap)))
1151         (define-key map "?" 'notmuch-help)
1152         (define-key map "q" 'notmuch-kill-this-buffer)
1153         (define-key map (kbd "<C-tab>") 'widget-backward)
1154         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1155         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1156         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1157         (define-key map "s" 'notmuch-search)
1158         (define-key map "m" 'notmuch-mua-new-mail)
1159         (define-key map "f" 'notmuch-show-forward-message)
1160         (define-key map "r" 'notmuch-show-reply-sender)
1161         (define-key map "R" 'notmuch-show-reply)
1162         (define-key map "|" 'notmuch-show-pipe-message)
1163         (define-key map "w" 'notmuch-show-save-attachments)
1164         (define-key map "V" 'notmuch-show-view-raw-message)
1165         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1166         (define-key map "c" 'notmuch-show-stash-map)
1167         (define-key map "=" 'notmuch-show-refresh-view)
1168         (define-key map "h" 'notmuch-show-toggle-headers)
1169         (define-key map "*" 'notmuch-show-tag-all)
1170         (define-key map "-" 'notmuch-show-remove-tag)
1171         (define-key map "+" 'notmuch-show-add-tag)
1172         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1173         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1174         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1175         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1176         (define-key map "N" 'notmuch-show-next-message)
1177         (define-key map "P" 'notmuch-show-previous-message)
1178         (define-key map "n" 'notmuch-show-next-open-message)
1179         (define-key map "p" 'notmuch-show-previous-open-message)
1180         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1181         (define-key map " " 'notmuch-show-advance-and-archive)
1182         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1183         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1184         (define-key map "#" 'notmuch-show-print-message)
1185         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1186         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1187         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1188         (define-key map "t" 'toggle-truncate-lines)
1189         map)
1190       "Keymap for \"notmuch show\" buffers.")
1191 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1192
1193 (defun notmuch-show-mode ()
1194   "Major mode for viewing a thread with notmuch.
1195
1196 This buffer contains the results of the \"notmuch show\" command
1197 for displaying a single thread of email from your email archives.
1198
1199 By default, various components of email messages, (citations,
1200 signatures, already-read messages), are hidden. You can make
1201 these parts visible by clicking with the mouse button or by
1202 pressing RET after positioning the cursor on a hidden part, (for
1203 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1204
1205 Reading the thread sequentially is well-supported by pressing
1206 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1207 to the next message, or advance to the next thread (if already on
1208 the last message of a thread).
1209
1210 Other commands are available to read or manipulate the thread
1211 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1212 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1213 without scrolling through with \\[notmuch-show-advance-and-archive]).
1214
1215 You can add or remove arbitrary tags from the current message with
1216 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1217
1218 All currently available key bindings:
1219
1220 \\{notmuch-show-mode-map}"
1221   (interactive)
1222   (kill-all-local-variables)
1223   (use-local-map notmuch-show-mode-map)
1224   (setq major-mode 'notmuch-show-mode
1225         mode-name "notmuch-show")
1226   (setq buffer-read-only t
1227         truncate-lines t))
1228
1229 (defun notmuch-show-move-to-message-top ()
1230   (goto-char (notmuch-show-message-top)))
1231
1232 (defun notmuch-show-move-to-message-bottom ()
1233   (goto-char (notmuch-show-message-bottom)))
1234
1235 (defun notmuch-show-message-adjust ()
1236   (recenter 0))
1237
1238 ;; Movement related functions.
1239
1240 ;; There's some strangeness here where a text property applied to a
1241 ;; region a->b is not found when point is at b. We walk backwards
1242 ;; until finding the property.
1243 (defun notmuch-show-message-extent ()
1244   (let (r)
1245     (save-excursion
1246       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1247         (backward-char)))
1248     r))
1249
1250 (defun notmuch-show-message-top ()
1251   (car (notmuch-show-message-extent)))
1252
1253 (defun notmuch-show-message-bottom ()
1254   (cdr (notmuch-show-message-extent)))
1255
1256 (defun notmuch-show-goto-message-next ()
1257   (let ((start (point)))
1258     (notmuch-show-move-to-message-bottom)
1259     (if (not (eobp))
1260         t
1261       (goto-char start)
1262       nil)))
1263
1264 (defun notmuch-show-goto-message-previous ()
1265   (notmuch-show-move-to-message-top)
1266   (if (bobp)
1267       nil
1268     (backward-char)
1269     (notmuch-show-move-to-message-top)
1270     t))
1271
1272 (defun notmuch-show-mapc (function)
1273   "Iterate through all messages in the current thread with
1274 `notmuch-show-goto-message-next' and call FUNCTION for side
1275 effects."
1276   (save-excursion
1277     (goto-char (point-min))
1278     (loop do (funcall function)
1279           while (notmuch-show-goto-message-next))))
1280
1281 ;; Functions relating to the visibility of messages and their
1282 ;; components.
1283
1284 (defun notmuch-show-element-visible (props visible-p spec-property)
1285   (let ((spec (plist-get props spec-property)))
1286     (if visible-p
1287         (remove-from-invisibility-spec spec)
1288       (add-to-invisibility-spec spec))))
1289
1290 (defun notmuch-show-message-visible (props visible-p)
1291   (notmuch-show-element-visible props visible-p :message-invis-spec)
1292   (notmuch-show-set-prop :message-visible visible-p props))
1293
1294 (defun notmuch-show-headers-visible (props visible-p)
1295   (notmuch-show-element-visible props visible-p :headers-invis-spec)
1296   (notmuch-show-set-prop :headers-visible visible-p props))
1297
1298 ;; Functions for setting and getting attributes of the current
1299 ;; message.
1300
1301 (defun notmuch-show-set-message-properties (props)
1302   (save-excursion
1303     (notmuch-show-move-to-message-top)
1304     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1305
1306 (defun notmuch-show-get-message-properties ()
1307   "Return the properties of the current message as a plist.
1308
1309 Some useful entries are:
1310 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1311 :body - Body of the message
1312 :tags - Tags for this message"
1313   (save-excursion
1314     (notmuch-show-move-to-message-top)
1315     (get-text-property (point) :notmuch-message-properties)))
1316
1317 (defun notmuch-show-set-prop (prop val &optional props)
1318   (let ((inhibit-read-only t)
1319         (props (or props
1320                    (notmuch-show-get-message-properties))))
1321     (plist-put props prop val)
1322     (notmuch-show-set-message-properties props)))
1323
1324 (defun notmuch-show-get-prop (prop &optional props)
1325   (let ((props (or props
1326                    (notmuch-show-get-message-properties))))
1327     (plist-get props prop)))
1328
1329 (defun notmuch-show-get-message-id (&optional bare)
1330   "Return an id: query for the Message-Id of the current message.
1331
1332 If optional argument BARE is non-nil, return
1333 the Message-Id without id: prefix and escaping."
1334   (if bare
1335       (notmuch-show-get-prop :id)
1336     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1337
1338 (defun notmuch-show-get-messages-ids ()
1339   "Return all id: queries of messages in the current thread."
1340   (let ((message-ids))
1341     (notmuch-show-mapc
1342      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1343     message-ids))
1344
1345 (defun notmuch-show-get-messages-ids-search ()
1346   "Return a search string for all message ids of messages in the
1347 current thread."
1348   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1349
1350 ;; dme: Would it make sense to use a macro for many of these?
1351
1352 (defun notmuch-show-get-filename ()
1353   "Return the filename of the current message."
1354   (notmuch-show-get-prop :filename))
1355
1356 (defun notmuch-show-get-header (header &optional props)
1357   "Return the named header of the current message, if any."
1358   (plist-get (notmuch-show-get-prop :headers props) header))
1359
1360 (defun notmuch-show-get-cc ()
1361   (notmuch-show-get-header :Cc))
1362
1363 (defun notmuch-show-get-date ()
1364   (notmuch-show-get-header :Date))
1365
1366 (defun notmuch-show-get-from ()
1367   (notmuch-show-get-header :From))
1368
1369 (defun notmuch-show-get-subject ()
1370   (notmuch-show-get-header :Subject))
1371
1372 (defun notmuch-show-get-to ()
1373   (notmuch-show-get-header :To))
1374
1375 (defun notmuch-show-get-depth ()
1376   (notmuch-show-get-prop :depth))
1377
1378 (defun notmuch-show-set-tags (tags)
1379   "Set the tags of the current message."
1380   (notmuch-show-set-prop :tags tags)
1381   (notmuch-show-update-tags tags))
1382
1383 (defun notmuch-show-get-tags ()
1384   "Return the tags of the current message."
1385   (notmuch-show-get-prop :tags))
1386
1387 (defun notmuch-show-message-visible-p ()
1388   "Is the current message visible?"
1389   (notmuch-show-get-prop :message-visible))
1390
1391 (defun notmuch-show-headers-visible-p ()
1392   "Are the headers of the current message visible?"
1393   (notmuch-show-get-prop :headers-visible))
1394
1395 (defun notmuch-show-mark-read ()
1396   "Mark the current message as read."
1397   (notmuch-show-tag-message "-unread"))
1398
1399 ;; Functions for getting attributes of several messages in the current
1400 ;; thread.
1401
1402 (defun notmuch-show-get-message-ids-for-open-messages ()
1403   "Return a list of all id: queries for open messages in the current thread."
1404   (save-excursion
1405     (let (message-ids done)
1406       (goto-char (point-min))
1407       (while (not done)
1408         (if (notmuch-show-message-visible-p)
1409             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1410         (setq done (not (notmuch-show-goto-message-next)))
1411         )
1412       message-ids
1413       )))
1414
1415 ;; Commands typically bound to keys.
1416
1417 (defun notmuch-show-advance ()
1418   "Advance through thread.
1419
1420 If the current message in the thread is not yet fully visible,
1421 scroll by a near screenful to read more of the message.
1422
1423 Otherwise, (the end of the current message is already within the
1424 current window), advance to the next open message."
1425   (interactive)
1426   (let* ((end-of-this-message (notmuch-show-message-bottom))
1427          (visible-end-of-this-message (1- end-of-this-message))
1428          (ret nil))
1429     (while (invisible-p visible-end-of-this-message)
1430       (setq visible-end-of-this-message
1431             (max (point-min)
1432                  (1- (previous-single-char-property-change
1433                       visible-end-of-this-message 'invisible)))))
1434     (cond
1435      ;; Ideally we would test `end-of-this-message' against the result
1436      ;; of `window-end', but that doesn't account for the fact that
1437      ;; the end of the message might be hidden.
1438      ((and visible-end-of-this-message
1439            (> visible-end-of-this-message (window-end)))
1440       ;; The bottom of this message is not visible - scroll.
1441       (scroll-up nil))
1442
1443      ((not (= end-of-this-message (point-max)))
1444       ;; This is not the last message - move to the next visible one.
1445       (notmuch-show-next-open-message))
1446
1447      (t
1448       ;; This is the last message - change the return value
1449       (setq ret t)))
1450     ret))
1451
1452 (defun notmuch-show-advance-and-archive ()
1453   "Advance through thread and archive.
1454
1455 This command is intended to be one of the simplest ways to
1456 process a thread of email. It works exactly like
1457 notmuch-show-advance, in that it scrolls through messages in a
1458 show buffer, except that when it gets to the end of the buffer it
1459 archives the entire current thread, (remove the \"inbox\" tag
1460 from each message), kills the buffer, and displays the next
1461 thread from the search from which this thread was originally
1462 shown."
1463   (interactive)
1464   (if (notmuch-show-advance)
1465       (notmuch-show-archive-thread-then-next)))
1466
1467 (defun notmuch-show-rewind ()
1468   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1469
1470 Specifically, if the beginning of the previous email is fewer
1471 than `window-height' lines from the current point, move to it
1472 just like `notmuch-show-previous-message'.
1473
1474 Otherwise, just scroll down a screenful of the current message.
1475
1476 This command does not modify any message tags, (it does not undo
1477 any effects from previous calls to
1478 `notmuch-show-advance-and-archive'."
1479   (interactive)
1480   (let ((start-of-message (notmuch-show-message-top))
1481         (start-of-window (window-start)))
1482     (cond
1483       ;; Either this message is properly aligned with the start of the
1484       ;; window or the start of this message is not visible on the
1485       ;; screen - scroll.
1486      ((or (= start-of-message start-of-window)
1487           (< start-of-message start-of-window))
1488       (scroll-down)
1489       ;; If a small number of lines from the previous message are
1490       ;; visible, realign so that the top of the current message is at
1491       ;; the top of the screen.
1492       (when (<= (count-screen-lines (window-start) start-of-message)
1493                 next-screen-context-lines)
1494         (goto-char (notmuch-show-message-top))
1495         (notmuch-show-message-adjust))
1496       ;; Move to the top left of the window.
1497       (goto-char (window-start)))
1498      (t
1499       ;; Move to the previous message.
1500       (notmuch-show-previous-message)))))
1501
1502 (defun notmuch-show-reply (&optional prompt-for-sender)
1503   "Reply to the sender and all recipients of the current message."
1504   (interactive "P")
1505   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1506
1507 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1508   "Reply to the sender of the current message."
1509   (interactive "P")
1510   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1511
1512 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1513   "Forward the current message."
1514   (interactive "P")
1515   (with-current-notmuch-show-message
1516    (notmuch-mua-new-forward-message prompt-for-sender)))
1517
1518 (defun notmuch-show-next-message (&optional pop-at-end)
1519   "Show the next message.
1520
1521 If a prefix argument is given and this is the last message in the
1522 thread, navigate to the next thread in the parent search buffer."
1523   (interactive "P")
1524   (if (notmuch-show-goto-message-next)
1525       (progn
1526         (notmuch-show-mark-read)
1527         (notmuch-show-message-adjust))
1528     (if pop-at-end
1529         (notmuch-show-next-thread)
1530       (goto-char (point-max)))))
1531
1532 (defun notmuch-show-previous-message ()
1533   "Show the previous message."
1534   (interactive)
1535   (notmuch-show-goto-message-previous)
1536   (notmuch-show-mark-read)
1537   (notmuch-show-message-adjust))
1538
1539 (defun notmuch-show-next-open-message (&optional pop-at-end)
1540   "Show the next open message.
1541
1542 If a prefix argument is given and this is the last open message
1543 in the thread, navigate to the next thread in the parent search
1544 buffer. Return t if there was a next open message in the thread
1545 to show, nil otherwise."
1546   (interactive "P")
1547   (let (r)
1548     (while (and (setq r (notmuch-show-goto-message-next))
1549                 (not (notmuch-show-message-visible-p))))
1550     (if r
1551         (progn
1552           (notmuch-show-mark-read)
1553           (notmuch-show-message-adjust))
1554       (if pop-at-end
1555           (notmuch-show-next-thread)
1556         (goto-char (point-max))))
1557     r))
1558
1559 (defun notmuch-show-next-matching-message ()
1560   "Show the next matching message."
1561   (interactive)
1562   (let (r)
1563     (while (and (setq r (notmuch-show-goto-message-next))
1564                 (not (notmuch-show-get-prop :match))))
1565     (if r
1566         (progn
1567           (notmuch-show-mark-read)
1568           (notmuch-show-message-adjust))
1569       (goto-char (point-max)))))
1570
1571 (defun notmuch-show-open-if-matched ()
1572   "Open a message if it is matched (whether or not excluded)."
1573   (let ((props (notmuch-show-get-message-properties)))
1574     (notmuch-show-message-visible props (plist-get props :match))))
1575
1576 (defun notmuch-show-goto-first-wanted-message ()
1577   "Move to the first open message and mark it read"
1578   (goto-char (point-min))
1579   (if (notmuch-show-message-visible-p)
1580       (notmuch-show-mark-read)
1581     (notmuch-show-next-open-message))
1582   (when (eobp)
1583     ;; There are no matched non-excluded messages so open all matched
1584     ;; (necessarily excluded) messages and go to the first.
1585     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1586     (force-window-update)
1587     (goto-char (point-min))
1588     (if (notmuch-show-message-visible-p)
1589         (notmuch-show-mark-read)
1590       (notmuch-show-next-open-message))))
1591
1592 (defun notmuch-show-previous-open-message ()
1593   "Show the previous open message."
1594   (interactive)
1595   (while (and (notmuch-show-goto-message-previous)
1596               (not (notmuch-show-message-visible-p))))
1597   (notmuch-show-mark-read)
1598   (notmuch-show-message-adjust))
1599
1600 (defun notmuch-show-view-raw-message ()
1601   "View the file holding the current message."
1602   (interactive)
1603   (let* ((id (notmuch-show-get-message-id))
1604          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1605     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1606     (switch-to-buffer buf)
1607     (goto-char (point-min))
1608     (set-buffer-modified-p nil)
1609     (view-buffer buf 'kill-buffer-if-not-modified)))
1610
1611 (defun notmuch-show-pipe-message (entire-thread command)
1612   "Pipe the contents of the current message (or thread) to the given command.
1613
1614 The given command will be executed with the raw contents of the
1615 current email message as stdin. Anything printed by the command
1616 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1617
1618 When invoked with a prefix argument, the command will receive all
1619 open messages in the current thread (formatted as an mbox) rather
1620 than only the current message."
1621   (interactive "P\nsPipe message to command: ")
1622   (let (shell-command)
1623     (if entire-thread
1624         (setq shell-command
1625               (concat notmuch-command " show --format=mbox "
1626                       (shell-quote-argument
1627                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1628                       " | " command))
1629       (setq shell-command
1630             (concat notmuch-command " show --format=raw "
1631                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1632     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1633       (with-current-buffer buf
1634         (setq buffer-read-only nil)
1635         (erase-buffer)
1636         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1637           (goto-char (point-max))
1638           (set-buffer-modified-p nil)
1639           (setq buffer-read-only t)
1640           (unless (zerop exit-code)
1641             (switch-to-buffer-other-window buf)
1642             (message (format "Command '%s' exited abnormally with code %d"
1643                              shell-command exit-code))))))))
1644
1645 (defun notmuch-show-tag-message (&rest tag-changes)
1646   "Change tags for the current message.
1647
1648 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1649   (let* ((current-tags (notmuch-show-get-tags))
1650          (new-tags (notmuch-update-tags current-tags tag-changes)))
1651     (unless (equal current-tags new-tags)
1652       (apply 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1653       (notmuch-show-set-tags new-tags))))
1654
1655 (defun notmuch-show-tag (&optional initial-input)
1656   "Change tags for the current message, read input from the minibuffer."
1657   (interactive)
1658   (let ((tag-changes (notmuch-read-tag-changes
1659                       initial-input (notmuch-show-get-message-id))))
1660     (apply 'notmuch-show-tag-message tag-changes)))
1661
1662 (defun notmuch-show-tag-all (&rest tag-changes)
1663   "Change tags for all messages in the current buffer.
1664
1665 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1666   (interactive (notmuch-read-tag-changes nil notmuch-show-thread-id))
1667   (apply 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes)
1668   (notmuch-show-mapc
1669    (lambda ()
1670      (let* ((current-tags (notmuch-show-get-tags))
1671             (new-tags (notmuch-update-tags current-tags tag-changes)))
1672        (unless (equal current-tags new-tags)
1673          (notmuch-show-set-tags new-tags))))))
1674
1675 (defun notmuch-show-add-tag ()
1676   "Same as `notmuch-show-tag' but sets initial input to '+'."
1677   (interactive)
1678   (notmuch-show-tag "+"))
1679
1680 (defun notmuch-show-remove-tag ()
1681   "Same as `notmuch-show-tag' but sets initial input to '-'."
1682   (interactive)
1683   (notmuch-show-tag "-"))
1684
1685 (defun notmuch-show-toggle-headers ()
1686   "Toggle the visibility of the current message headers."
1687   (interactive)
1688   (let ((props (notmuch-show-get-message-properties)))
1689     (notmuch-show-headers-visible
1690      props
1691      (not (plist-get props :headers-visible))))
1692   (force-window-update))
1693
1694 (defun notmuch-show-toggle-message ()
1695   "Toggle the visibility of the current message."
1696   (interactive)
1697   (let ((props (notmuch-show-get-message-properties)))
1698     (notmuch-show-message-visible
1699      props
1700      (not (plist-get props :message-visible))))
1701   (force-window-update))
1702
1703 (defun notmuch-show-open-or-close-all ()
1704   "Set the visibility all of the messages in the current thread.
1705 By default make all of the messages visible. With a prefix
1706 argument, hide all of the messages."
1707   (interactive)
1708   (save-excursion
1709     (goto-char (point-min))
1710     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1711                                            (not current-prefix-arg))
1712           until (not (notmuch-show-goto-message-next))))
1713   (force-window-update))
1714
1715 (defun notmuch-show-next-button ()
1716   "Advance point to the next button in the buffer."
1717   (interactive)
1718   (forward-button 1))
1719
1720 (defun notmuch-show-previous-button ()
1721   "Move point back to the previous button in the buffer."
1722   (interactive)
1723   (backward-button 1))
1724
1725 (defun notmuch-show-next-thread (&optional show-next)
1726   "Move to the next item in the search results, if any."
1727   (interactive "P")
1728   (let ((parent-buffer notmuch-show-parent-buffer))
1729     (notmuch-kill-this-buffer)
1730     (when (buffer-live-p parent-buffer)
1731       (switch-to-buffer parent-buffer)
1732       (notmuch-search-next-thread)
1733       (if show-next
1734           (notmuch-search-show-thread)))))
1735
1736 (defun notmuch-show-archive-thread (&optional unarchive)
1737   "Archive each message in thread.
1738
1739 If a prefix argument is given, the messages will be
1740 \"unarchived\" (ie. the \"inbox\" tag will be added instead of
1741 removed).
1742
1743 Archive each message currently shown by removing the \"inbox\"
1744 tag from each. Then kill this buffer and show the next thread
1745 from the search from which this thread was originally shown.
1746
1747 Note: This command is safe from any race condition of new messages
1748 being delivered to the same thread. It does not archive the
1749 entire thread, but only the messages shown in the current
1750 buffer."
1751   (interactive "P")
1752   (let ((op (if unarchive "+" "-")))
1753     (notmuch-show-tag-all (concat op "inbox"))))
1754
1755 (defun notmuch-show-archive-thread-then-next ()
1756   "Archive all messages in the current buffer, then show next thread from search."
1757   (interactive)
1758   (notmuch-show-archive-thread)
1759   (notmuch-show-next-thread t))
1760
1761 (defun notmuch-show-archive-thread-then-exit ()
1762   "Archive all messages in the current buffer, then exit back to search results."
1763   (interactive)
1764   (notmuch-show-archive-thread)
1765   (notmuch-show-next-thread))
1766
1767 (defun notmuch-show-archive-message (&optional unarchive)
1768   "Archive the current message.
1769
1770 If a prefix argument is given, the message will be
1771 \"unarchived\" (ie. the \"inbox\" tag will be added instead of
1772 removed)."
1773   (interactive "P")
1774   (let ((op (if unarchive "+" "-")))
1775     (notmuch-show-tag-message (concat op "inbox"))))
1776
1777 (defun notmuch-show-archive-message-then-next-or-exit ()
1778   "Archive the current message, then show the next open message in the current thread.
1779
1780 If at the last open message in the current thread, then exit back
1781 to search results."
1782   (interactive)
1783   (notmuch-show-archive-message)
1784   (notmuch-show-next-open-message t))
1785
1786 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1787   "Archive the current message, then show the next open message in the current thread.
1788
1789 If at the last open message in the current thread, then show next
1790 thread from search."
1791   (interactive)
1792   (notmuch-show-archive-message)
1793   (unless (notmuch-show-next-open-message)
1794     (notmuch-show-next-thread t)))
1795
1796 (defun notmuch-show-stash-cc ()
1797   "Copy CC field of current message to kill-ring."
1798   (interactive)
1799   (notmuch-common-do-stash (notmuch-show-get-cc)))
1800
1801 (defun notmuch-show-stash-date ()
1802   "Copy date of current message to kill-ring."
1803   (interactive)
1804   (notmuch-common-do-stash (notmuch-show-get-date)))
1805
1806 (defun notmuch-show-stash-filename ()
1807   "Copy filename of current message to kill-ring."
1808   (interactive)
1809   (notmuch-common-do-stash (notmuch-show-get-filename)))
1810
1811 (defun notmuch-show-stash-from ()
1812   "Copy From address of current message to kill-ring."
1813   (interactive)
1814   (notmuch-common-do-stash (notmuch-show-get-from)))
1815
1816 (defun notmuch-show-stash-message-id ()
1817   "Copy id: query matching the current message to kill-ring."
1818   (interactive)
1819   (notmuch-common-do-stash (notmuch-show-get-message-id)))
1820
1821 (defun notmuch-show-stash-message-id-stripped ()
1822   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1823   (interactive)
1824   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1825
1826 (defun notmuch-show-stash-subject ()
1827   "Copy Subject field of current message to kill-ring."
1828   (interactive)
1829   (notmuch-common-do-stash (notmuch-show-get-subject)))
1830
1831 (defun notmuch-show-stash-tags ()
1832   "Copy tags of current message to kill-ring as a comma separated list."
1833   (interactive)
1834   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1835
1836 (defun notmuch-show-stash-to ()
1837   "Copy To address of current message to kill-ring."
1838   (interactive)
1839   (notmuch-common-do-stash (notmuch-show-get-to)))
1840
1841 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1842   "Copy an ML Archive URI for the current message to the kill-ring.
1843
1844 This presumes that the message is available at the selected Mailing List Archive.
1845
1846 If optional argument MLA is non-nil, use the provided key instead of prompting
1847 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1848   (interactive)
1849   (notmuch-common-do-stash
1850    (concat (cdr (assoc
1851                  (or mla
1852                      (let ((completion-ignore-case t))
1853                        (completing-read
1854                         "Mailing List Archive: "
1855                         notmuch-show-stash-mlarchive-link-alist
1856                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1857                  notmuch-show-stash-mlarchive-link-alist))
1858            (notmuch-show-get-message-id t))))
1859
1860 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1861   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1862
1863 This presumes that the message is available at the selected Mailing List Archive.
1864
1865 If optional argument MLA is non-nil, use the provided key instead of prompting
1866 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1867   (interactive)
1868   (notmuch-show-stash-mlarchive-link mla)
1869   (browse-url (current-kill 0 t)))
1870
1871 ;; Commands typically bound to buttons.
1872
1873 (defun notmuch-show-part-button-default (&optional button)
1874   (interactive)
1875   (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))
1876
1877 (defun notmuch-show-part-button-save (&optional button)
1878   (interactive)
1879   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1880
1881 (defun notmuch-show-part-button-view (&optional button)
1882   (interactive)
1883   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1884
1885 (defun notmuch-show-part-button-interactively-view (&optional button)
1886   (interactive)
1887   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1888
1889 (defun notmuch-show-part-button-internal (button handler)
1890   (let ((button (or button (button-at (point)))))
1891     (if button
1892         (let ((nth (button-get button :notmuch-part)))
1893           (if nth
1894               (funcall handler (notmuch-show-get-message-id) nth
1895                        (button-get button :notmuch-filename)
1896                        (button-get button :notmuch-content-type)))))))
1897
1898 ;;
1899
1900 (provide 'notmuch-show)