git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-fontify-headers "notmuch" nil)
  42 (declare-function notmuch-search-next-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts t
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ;; FIXME: can these services be searched by `Message-Id' ?
 162     ;; ("MarkMail" . "http://markmail.org/")
 163     ;; ("Nabble" . "http://nabble.com/")
 164     ;; ("opensubscriber" . "http://opensubscriber.com/")
 165     )
 166   "List of Mailing List Archives to use when stashing links.
 167
 168 These URIs are concatenated with the current message's
 169 Message-Id in `notmuch-show-stash-mlarchive-link'."
 170   :type '(alist :key-type (string :tag "Name")
 171                 :value-type (string :tag "URL"))
 172   :group 'notmuch-show)
 173
 174 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 175   "Default Mailing List Archive to use when stashing links.
 176
 177 This is used when `notmuch-show-stash-mlarchive-link' isn't
 178 provided with an MLA argument nor `completing-read' input."
 179   :type `(choice
 180           ,@(mapcar
 181              (lambda (mla)
 182                (list 'const :tag (car mla) :value (car mla)))
 183              notmuch-show-stash-mlarchive-link-alist))
 184   :group 'notmuch-show)
 185
 186 (defcustom notmuch-show-mark-read-tags '("-unread")
 187   "List of tag changes to apply to a message when it is marked as read.
 188
 189 Tags starting with \"+\" (or not starting with either \"+\" or
 190 \"-\") in the list will be added, and tags starting with \"-\"
 191 will be removed from the message being marked as read.
 192
 193 For example, if you wanted to remove an \"unread\" tag and add a
 194 \"read\" tag (which would make little sense), you would set:
 195     (\"-unread\" \"+read\")"
 196   :type '(repeat string)
 197   :group 'notmuch-show)
 198
 199
 200 (defmacro with-current-notmuch-show-message (&rest body)
 201   "Evaluate body with current buffer set to the text of current message"
 202   `(save-excursion
 203      (let ((id (notmuch-show-get-message-id)))
 204        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 205          (with-current-buffer buf
 206            (let ((coding-system-for-read 'no-conversion))
 207              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 208              ,@body)
 209            (kill-buffer buf))))))
 210
 211 (defun notmuch-show-turn-on-visual-line-mode ()
 212   "Enable Visual Line mode."
 213   (visual-line-mode t))
 214
 215 (defun notmuch-show-view-all-mime-parts ()
 216   "Use external viewers to view all attachments from the current message."
 217   (interactive)
 218   (with-current-notmuch-show-message
 219    ;; We override the mm-inline-media-tests to indicate which message
 220    ;; parts are already sufficiently handled by the original
 221    ;; presentation of the message in notmuch-show mode. These parts
 222    ;; will be inserted directly into the temporary buffer of
 223    ;; with-current-notmuch-show-message and silently discarded.
 224    ;;
 225    ;; Any MIME part not explicitly mentioned here will be handled by an
 226    ;; external viewer as configured in the various mailcap files.
 227    (let ((mm-inline-media-tests '(
 228                                   ("text/.*" ignore identity)
 229                                   ("application/pgp-signature" ignore identity)
 230                                   ("multipart/alternative" ignore identity)
 231                                   ("multipart/mixed" ignore identity)
 232                                   ("multipart/related" ignore identity)
 233                                  )))
 234      (mm-display-parts (mm-dissect-buffer)))))
 235
 236 (defun notmuch-foreach-mime-part (function mm-handle)
 237   (cond ((stringp (car mm-handle))
 238          (dolist (part (cdr mm-handle))
 239            (notmuch-foreach-mime-part function part)))
 240         ((bufferp (car mm-handle))
 241          (funcall function mm-handle))
 242         (t (dolist (part mm-handle)
 243              (notmuch-foreach-mime-part function part)))))
 244
 245 (defun notmuch-count-attachments (mm-handle)
 246   (let ((count 0))
 247     (notmuch-foreach-mime-part
 248      (lambda (p)
 249        (let ((disposition (mm-handle-disposition p)))
 250          (and (listp disposition)
 251               (or (equal (car disposition) "attachment")
 252                   (and (equal (car disposition) "inline")
 253                        (assq 'filename disposition)))
 254               (incf count))))
 255      mm-handle)
 256     count))
 257
 258 (defun notmuch-save-attachments (mm-handle &optional queryp)
 259   (notmuch-foreach-mime-part
 260    (lambda (p)
 261      (let ((disposition (mm-handle-disposition p)))
 262        (and (listp disposition)
 263             (or (equal (car disposition) "attachment")
 264                 (and (equal (car disposition) "inline")
 265                      (assq 'filename disposition)))
 266             (or (not queryp)
 267                 (y-or-n-p
 268                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 269             (mm-save-part p))))
 270    mm-handle))
 271
 272 (defun notmuch-show-save-attachments ()
 273   "Save all attachments from the current message."
 274   (interactive)
 275   (with-current-notmuch-show-message
 276    (let ((mm-handle (mm-dissect-buffer)))
 277      (notmuch-save-attachments
 278       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 279   (message "Done"))
 280
 281 (defun notmuch-show-with-message-as-text (fn)
 282   "Apply FN to a text representation of the current message.
 283
 284 FN is called with one argument, the message properties. It should
 285 operation on the contents of the current buffer."
 286
 287   ;; Remake the header to ensure that all information is available.
 288   (let* ((to (notmuch-show-get-to))
 289          (cc (notmuch-show-get-cc))
 290          (from (notmuch-show-get-from))
 291          (subject (notmuch-show-get-subject))
 292          (date (notmuch-show-get-date))
 293          (tags (notmuch-show-get-tags))
 294          (depth (notmuch-show-get-depth))
 295
 296          (header (concat
 297                   "Subject: " subject "\n"
 298                   "To: " to "\n"
 299                   (if (not (string= cc ""))
 300                       (concat "Cc: " cc "\n")
 301                     "")
 302                   "From: " from "\n"
 303                   "Date: " date "\n"
 304                   (if tags
 305                       (concat "Tags: "
 306                               (mapconcat #'identity tags ", ") "\n")
 307                     "")))
 308          (all (buffer-substring (notmuch-show-message-top)
 309                                 (notmuch-show-message-bottom)))
 310
 311          (props (notmuch-show-get-message-properties))
 312          (indenting notmuch-show-indent-content))
 313     (with-temp-buffer
 314       (insert all)
 315       (if indenting
 316           (indent-rigidly (point-min) (point-max) (- depth)))
 317       ;; Remove the original header.
 318       (goto-char (point-min))
 319       (re-search-forward "^$" (point-max) nil)
 320       (delete-region (point-min) (point))
 321       (insert header)
 322       (funcall fn props))))
 323
 324 (defun notmuch-show-print-message ()
 325   "Print the current message."
 326   (interactive)
 327   (notmuch-show-with-message-as-text 'notmuch-print-message))
 328
 329 (defun notmuch-show-fontify-header ()
 330   (let ((face (cond
 331                ((looking-at "[Tt]o:")
 332                 'message-header-to)
 333                ((looking-at "[Bb]?[Cc][Cc]:")
 334                 'message-header-cc)
 335                ((looking-at "[Ss]ubject:")
 336                 'message-header-subject)
 337                ((looking-at "[Ff]rom:")
 338                 'message-header-from)
 339                (t
 340                 'message-header-other))))
 341
 342     (overlay-put (make-overlay (point) (re-search-forward ":"))
 343                  'face 'message-header-name)
 344     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 345                  'face face)))
 346
 347 (defun notmuch-show-colour-headers ()
 348   "Apply some colouring to the current headers."
 349   (goto-char (point-min))
 350   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 351     (notmuch-show-fontify-header)
 352     (forward-line)))
 353
 354 (defun notmuch-show-spaces-n (n)
 355   "Return a string comprised of `n' spaces."
 356   (make-string n ? ))
 357
 358 (defun notmuch-show-update-tags (tags)
 359   "Update the displayed tags of the current message."
 360   (save-excursion
 361     (goto-char (notmuch-show-message-top))
 362     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 363         (let ((inhibit-read-only t))
 364           (replace-match (concat "("
 365                                  (propertize (mapconcat 'identity tags " ")
 366                                              'face 'notmuch-tag-face)
 367                                  ")"))))))
 368
 369 (defun notmuch-clean-address (address)
 370   "Try to clean a single email ADDRESS for display. Return a cons
 371 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 372 parsing fails."
 373   (condition-case nil
 374     (let (p-name p-address)
 375       ;; It would be convenient to use `mail-header-parse-address',
 376       ;; but that expects un-decoded mailbox parts, whereas our
 377       ;; mailbox parts are already decoded (and hence may contain
 378       ;; UTF-8). Given that notmuch should handle most of the awkward
 379       ;; cases, some simple string deconstruction should be sufficient
 380       ;; here.
 381       (cond
 382        ;; "User <user@dom.ain>" style.
 383        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 384         (setq p-name (match-string 1 address)
 385               p-address (match-string 2 address)))
 386
 387        ;; "<user@dom.ain>" style.
 388        ((string-match "<\\(.*\\)>" address)
 389         (setq p-address (match-string 1 address)))
 390
 391        ;; Everything else.
 392        (t
 393         (setq p-address address)))
 394
 395       (when p-name
 396         ;; Remove elements of the mailbox part that are not relevant for
 397         ;; display, even if they are required during transport:
 398         ;;
 399         ;; Backslashes.
 400         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 401
 402         ;; Outer single and double quotes, which might be nested.
 403         (loop
 404          with start-of-loop
 405          do (setq start-of-loop p-name)
 406
 407          when (string-match "^\"\\(.*\\)\"$" p-name)
 408          do (setq p-name (match-string 1 p-name))
 409
 410          when (string-match "^'\\(.*\\)'$" p-name)
 411          do (setq p-name (match-string 1 p-name))
 412
 413          until (string= start-of-loop p-name)))
 414
 415       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 416       ;; 'foo@bar.com'.
 417       (when (string= p-name p-address)
 418         (setq p-name nil))
 419
 420       (cons p-address p-name))
 421     (error (cons address nil))))
 422
 423 (defun notmuch-show-clean-address (address)
 424   "Try to clean a single email ADDRESS for display.  Return
 425 unchanged ADDRESS if parsing fails."
 426   (let* ((clean-address (notmuch-clean-address address))
 427          (p-address (car clean-address))
 428          (p-name (cdr clean-address)))
 429     ;; If no name, return just the address.
 430     (if (not p-name)
 431         p-address
 432       ;; Otherwise format the name and address together.
 433       (concat p-name " <" p-address ">"))))
 434
 435 (defun notmuch-show-insert-headerline (headers date tags depth)
 436   "Insert a notmuch style headerline based on HEADERS for a
 437 message at DEPTH in the current thread."
 438   (let ((start (point)))
 439     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 440             (notmuch-show-clean-address (plist-get headers :From))
 441             " ("
 442             date
 443             ") ("
 444             (propertize (mapconcat 'identity tags " ")
 445                         'face 'notmuch-tag-face)
 446             ")\n")
 447     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 448
 449 (defun notmuch-show-insert-header (header header-value)
 450   "Insert a single header."
 451   (insert header ": " header-value "\n"))
 452
 453 (defun notmuch-show-insert-headers (headers)
 454   "Insert the headers of the current message."
 455   (let ((start (point)))
 456     (mapc (lambda (header)
 457             (let* ((header-symbol (intern (concat ":" header)))
 458                    (header-value (plist-get headers header-symbol)))
 459               (if (and header-value
 460                        (not (string-equal "" header-value)))
 461                   (notmuch-show-insert-header header header-value))))
 462           notmuch-message-headers)
 463     (save-excursion
 464       (save-restriction
 465         (narrow-to-region start (point-max))
 466         (run-hooks 'notmuch-show-markup-headers-hook)))))
 467
 468 (define-button-type 'notmuch-show-part-button-type
 469   'action 'notmuch-show-part-button-default
 470   'keymap 'notmuch-show-part-button-map
 471   'follow-link t
 472   'face 'message-mml)
 473
 474 (defvar notmuch-show-part-button-map
 475   (let ((map (make-sparse-keymap)))
 476     (set-keymap-parent map button-map)
 477     (define-key map "s" 'notmuch-show-part-button-save)
 478     (define-key map "v" 'notmuch-show-part-button-view)
 479     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 480     (define-key map "|" 'notmuch-show-part-button-pipe)
 481     map)
 482   "Submap for button commands")
 483 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 484
 485 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 486   (let ((button)
 487         (base-label (concat (when name (concat name ": "))
 488                             declared-type
 489                             (unless (string-equal declared-type content-type)
 490                               (concat " (as " content-type ")"))
 491                             comment)))
 492
 493     (setq button
 494           (insert-button
 495            (concat "[ " base-label " ]")
 496            :base-label base-label
 497            :type 'notmuch-show-part-button-type
 498            :notmuch-part nth
 499            :notmuch-filename name
 500            :notmuch-content-type content-type))
 501     (insert "\n")
 502     ;; return button
 503     button))
 504
 505 ;; Functions handling particular MIME parts.
 506
 507 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 508   (declare (indent 2))
 509   (let ((process-crypto (make-symbol "process-crypto")))
 510     `(let ((,process-crypto notmuch-show-process-crypto))
 511        (with-temp-buffer
 512          (setq notmuch-show-process-crypto ,process-crypto)
 513          ;; Always acquires the part via `notmuch part', even if it is
 514          ;; available in the JSON output.
 515          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 516          ,@body))))
 517
 518 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 519   (notmuch-with-temp-part-buffer message-id nth
 520     (let ((file (read-file-name
 521                  "Filename to save as: "
 522                  (or mailcap-download-directory "~/")
 523                  nil nil
 524                  filename)))
 525       ;; Don't re-compress .gz & al.  Arguably we should make
 526       ;; `file-name-handler-alist' nil, but that would chop
 527       ;; ange-ftp, which is reasonable to use here.
 528       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 529
 530 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 531   (notmuch-with-temp-part-buffer message-id nth
 532     ;; set mm-inlined-types to nil to force an external viewer
 533     (let ((handle (mm-make-handle (current-buffer) (list content-type)))
 534           (mm-inlined-types nil))
 535       ;; We override mm-save-part as notmuch-show-save-part is better
 536       ;; since it offers the filename. We need to lexically bind
 537       ;; everything we need for notmuch-show-save-part to prevent
 538       ;; potential dynamic shadowing.
 539       (lexical-let ((message-id message-id)
 540                     (nth nth)
 541                     (filename filename)
 542                     (content-type content-type))
 543         (flet ((mm-save-part (&rest args) (notmuch-show-save-part
 544                                            message-id nth filename content-type)))
 545           (mm-display-part handle))))))
 546
 547 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 548   (notmuch-with-temp-part-buffer message-id nth
 549     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 550       (mm-interactively-view-part handle))))
 551
 552 (defun notmuch-show-pipe-part (message-id nth &optional filename content-type)
 553   (notmuch-with-temp-part-buffer message-id nth
 554     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 555       (mm-pipe-part handle))))
 556
 557 ;; This is taken from notmuch-wash: maybe it should be unified?
 558 (defun notmuch-show-toggle-part-invisibility (&optional button)
 559   (interactive)
 560   (let* ((button (or button (button-at (point))))
 561          (overlay (button-get button 'overlay)))
 562     (when overlay
 563       (let* ((show (overlay-get overlay 'invisible))
 564              (new-start (button-start button))
 565              (button-label (button-get button :base-label))
 566              (old-point (point))
 567              (inhibit-read-only t))
 568         (overlay-put overlay 'invisible (not show))
 569         (goto-char new-start)
 570         (insert "[ " button-label (if show " ]" " (hidden) ]"))
 571         (let ((old-end (button-end button)))
 572           (move-overlay button new-start (point))
 573           (delete-region (point) old-end))
 574         (goto-char (min old-point (1- (button-end button))))))))
 575
 576 (defun notmuch-show-multipart/*-to-list (part)
 577   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 578           (plist-get part :content)))
 579
 580 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 581   (notmuch-show-insert-part-header nth declared-type content-type nil)
 582   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 583         (inner-parts (plist-get part :content))
 584         (start (point)))
 585     ;; This inserts all parts of the chosen type rather than just one,
 586     ;; but it's not clear that this is the wrong thing to do - which
 587     ;; should be chosen if there are more than one that match?
 588     (mapc (lambda (inner-part)
 589             (let* ((inner-type (plist-get inner-part :content-type))
 590                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 591                            (string= chosen-type inner-type)))))
 592               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 593           inner-parts)
 594
 595     (when notmuch-show-indent-multipart
 596       (indent-rigidly start (point) 1)))
 597   t)
 598
 599 (defun notmuch-show-setup-w3m ()
 600   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 601   (interactive)
 602   (if (boundp 'w3m-cid-retrieve-function-alist)
 603     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 604       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 605             w3m-cid-retrieve-function-alist)))
 606   (setq mm-inline-text-html-with-images t))
 607
 608 (defvar w3m-current-buffer) ;; From `w3m.el'.
 609 (defvar notmuch-show-w3m-cid-store nil)
 610 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 611
 612 (defun notmuch-show-w3m-cid-store-internal (content-id
 613                                             message-id
 614                                             part-number
 615                                             content-type
 616                                             content)
 617   (push (list content-id
 618               message-id
 619               part-number
 620               content-type
 621               content)
 622         notmuch-show-w3m-cid-store))
 623
 624 (defun notmuch-show-w3m-cid-store (msg part)
 625   (let ((content-id (plist-get part :content-id)))
 626     (when content-id
 627       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 628                                            (plist-get msg :id)
 629                                            (plist-get part :id)
 630                                            (plist-get part :content-type)
 631                                            nil))))
 632
 633 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 634   (let ((matching-part (with-current-buffer w3m-current-buffer
 635                          (assoc url notmuch-show-w3m-cid-store))))
 636     (if matching-part
 637         (let ((message-id (nth 1 matching-part))
 638               (part-number (nth 2 matching-part))
 639               (content-type (nth 3 matching-part))
 640               (content (nth 4 matching-part)))
 641           ;; If we don't already have the content, get it and cache
 642           ;; it, as some messages reference the same cid: part many
 643           ;; times (hundreds!), which results in many calls to
 644           ;; `notmuch part'.
 645           (unless content
 646             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 647                                                               part-number notmuch-show-process-crypto))
 648             (with-current-buffer w3m-current-buffer
 649               (notmuch-show-w3m-cid-store-internal url
 650                                                    message-id
 651                                                    part-number
 652                                                    content-type
 653                                                    content)))
 654           (insert content)
 655           content-type)
 656       nil)))
 657
 658 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 659   (notmuch-show-insert-part-header nth declared-type content-type nil)
 660   (let ((inner-parts (plist-get part :content))
 661         (start (point)))
 662
 663     ;; We assume that the first part is text/html and the remainder
 664     ;; things that it references.
 665
 666     ;; Stash the non-primary parts.
 667     (mapc (lambda (part)
 668             (notmuch-show-w3m-cid-store msg part))
 669           (cdr inner-parts))
 670
 671     ;; Render the primary part.
 672     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 673
 674     (when notmuch-show-indent-multipart
 675       (indent-rigidly start (point) 1)))
 676   t)
 677
 678 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 679   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 680     (button-put button 'face 'notmuch-crypto-part-header)
 681     ;; add signature status button if sigstatus provided
 682     (if (plist-member part :sigstatus)
 683         (let* ((from (notmuch-show-get-header :From msg))
 684                (sigstatus (car (plist-get part :sigstatus))))
 685           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 686       ;; if we're not adding sigstatus, tell the user how they can get it
 687       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 688
 689   (let ((inner-parts (plist-get part :content))
 690         (start (point)))
 691     ;; Show all of the parts.
 692     (mapc (lambda (inner-part)
 693             (notmuch-show-insert-bodypart msg inner-part depth))
 694           inner-parts)
 695
 696     (when notmuch-show-indent-multipart
 697       (indent-rigidly start (point) 1)))
 698   t)
 699
 700 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 701   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 702     (button-put button 'face 'notmuch-crypto-part-header)
 703     ;; add encryption status button if encstatus specified
 704     (if (plist-member part :encstatus)
 705         (let ((encstatus (car (plist-get part :encstatus))))
 706           (notmuch-crypto-insert-encstatus-button encstatus)
 707           ;; add signature status button if sigstatus specified
 708           (if (plist-member part :sigstatus)
 709               (let* ((from (notmuch-show-get-header :From msg))
 710                      (sigstatus (car (plist-get part :sigstatus))))
 711                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 712       ;; if we're not adding encstatus, tell the user how they can get it
 713       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 714
 715   (let ((inner-parts (plist-get part :content))
 716         (start (point)))
 717     ;; Show all of the parts.
 718     (mapc (lambda (inner-part)
 719             (notmuch-show-insert-bodypart msg inner-part depth))
 720           inner-parts)
 721
 722     (when notmuch-show-indent-multipart
 723       (indent-rigidly start (point) 1)))
 724   t)
 725
 726 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 727   (notmuch-show-insert-part-header nth declared-type content-type nil)
 728   (let ((inner-parts (plist-get part :content))
 729         (start (point)))
 730     ;; Show all of the parts.
 731     (mapc (lambda (inner-part)
 732             (notmuch-show-insert-bodypart msg inner-part depth))
 733           inner-parts)
 734
 735     (when notmuch-show-indent-multipart
 736       (indent-rigidly start (point) 1)))
 737   t)
 738
 739 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 740   (notmuch-show-insert-part-header nth declared-type content-type nil)
 741   (let* ((message (car (plist-get part :content)))
 742          (body (car (plist-get message :body)))
 743          (start (point)))
 744
 745     ;; Override `notmuch-message-headers' to force `From' to be
 746     ;; displayed.
 747     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 748       (notmuch-show-insert-headers (plist-get message :headers)))
 749
 750     ;; Blank line after headers to be compatible with the normal
 751     ;; message display.
 752     (insert "\n")
 753
 754     ;; Show the body
 755     (notmuch-show-insert-bodypart msg body depth)
 756
 757     (when notmuch-show-indent-multipart
 758       (indent-rigidly start (point) 1)))
 759   t)
 760
 761 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 762   (let ((start (point)))
 763     ;; If this text/plain part is not the first part in the message,
 764     ;; insert a header to make this clear.
 765     (if (> nth 1)
 766         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 767     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 768     (save-excursion
 769       (save-restriction
 770         (narrow-to-region start (point-max))
 771         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 772   t)
 773
 774 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 775   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 776   (insert (with-temp-buffer
 777             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 778             ;; notmuch-get-bodypart-content provides "raw", non-converted
 779             ;; data. Replace CRLF with LF before icalendar can use it.
 780             (goto-char (point-min))
 781             (while (re-search-forward "\r\n" nil t)
 782               (replace-match "\n" nil nil))
 783             (let ((file (make-temp-file "notmuch-ical"))
 784                   result)
 785               (unwind-protect
 786                   (progn
 787                     (unless (icalendar-import-buffer file t)
 788                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 789                     (set-buffer (get-file-buffer file))
 790                     (setq result (buffer-substring (point-min) (point-max)))
 791                     (set-buffer-modified-p nil)
 792                     (kill-buffer (current-buffer)))
 793                 (delete-file file))
 794               result)))
 795   t)
 796
 797 ;; For backwards compatibility.
 798 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 799   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 800
 801 (defun notmuch-show-insert-part-application/octet-stream (msg part content-type nth depth declared-type)
 802   ;; If we can deduce a MIME type from the filename of the attachment,
 803   ;; do so and pass it on to the handler for that type.
 804   (if (plist-get part :filename)
 805       (let ((extension (file-name-extension (plist-get part :filename)))
 806             mime-type)
 807         (if extension
 808             (progn
 809               (mailcap-parse-mimetypes)
 810               (setq mime-type (mailcap-extension-to-mime extension))
 811               (if (and mime-type
 812                        (not (string-equal mime-type "application/octet-stream")))
 813                   (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 814                 nil))
 815           nil))))
 816
 817 ;; Handler for wash generated inline patch fake parts.
 818 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 819   (notmuch-show-insert-part-*/* msg part "text/x-diff" nth depth "inline patch"))
 820
 821 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 822   ;; This handler _must_ succeed - it is the handler of last resort.
 823   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 824   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 825   t)
 826
 827 ;; Functions for determining how to handle MIME parts.
 828
 829 (defun notmuch-show-handlers-for (content-type)
 830   "Return a list of content handlers for a part of type CONTENT-TYPE."
 831   (let (result)
 832     (mapc (lambda (func)
 833             (if (functionp func)
 834                 (push func result)))
 835           ;; Reverse order of prefrence.
 836           (list (intern (concat "notmuch-show-insert-part-*/*"))
 837                 (intern (concat
 838                          "notmuch-show-insert-part-"
 839                          (car (notmuch-split-content-type content-type))
 840                          "/*"))
 841                 (intern (concat "notmuch-show-insert-part-" content-type))))
 842     result))
 843
 844 ;; \f
 845
 846 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 847   (let ((handlers (notmuch-show-handlers-for content-type)))
 848     ;; Run the content handlers until one of them returns a non-nil
 849     ;; value.
 850     (while (and handlers
 851                 (not (condition-case err
 852                          (funcall (car handlers) msg part content-type nth depth declared-type)
 853                        (error (progn
 854                                 (insert "!!! Bodypart insert error: ")
 855                                 (insert (error-message-string err))
 856                                 (insert " !!!\n") nil)))))
 857       (setq handlers (cdr handlers))))
 858   t)
 859
 860 (defun notmuch-show-create-part-overlays (msg beg end hide)
 861   "Add an overlay to the part between BEG and END"
 862   (let* ((button (button-at beg))
 863          (part-beg (and button (1+ (button-end button)))))
 864
 865     ;; If the part contains no text we do not make it toggleable. We
 866     ;; also need to check that the button is a genuine part button not
 867     ;; a notmuch-wash button.
 868     (when (and button (/= part-beg end) (button-get button :base-label))
 869       (button-put button 'overlay (make-overlay part-beg end))
 870       ;; We toggle the button for hidden parts as that gets the
 871       ;; button label right.
 872       (save-excursion
 873         (when hide
 874           (notmuch-show-toggle-part-invisibility button))))))
 875
 876 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 877   "Insert the body part PART at depth DEPTH in the current thread.
 878
 879 If HIDE is non-nil then initially hide this part."
 880   (let ((content-type (downcase (plist-get part :content-type)))
 881         (nth (plist-get part :id))
 882         (beg (point)))
 883
 884     (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type)
 885     ;; Some of the body part handlers leave point somewhere up in the
 886     ;; part, so we make sure that we're down at the end.
 887     (goto-char (point-max))
 888     ;; Ensure that the part ends with a carriage return.
 889     (unless (bolp)
 890       (insert "\n"))
 891     (notmuch-show-create-part-overlays msg beg (point) hide)))
 892
 893 (defun notmuch-show-insert-body (msg body depth)
 894   "Insert the body BODY at depth DEPTH in the current thread."
 895   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 896
 897 (defun notmuch-show-make-symbol (type)
 898   (make-symbol (concat "notmuch-show-" type)))
 899
 900 (defun notmuch-show-strip-re (string)
 901   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 902
 903 (defvar notmuch-show-previous-subject "")
 904 (make-variable-buffer-local 'notmuch-show-previous-subject)
 905
 906 (defun notmuch-show-insert-msg (msg depth)
 907   "Insert the message MSG at depth DEPTH in the current thread."
 908   (let* ((headers (plist-get msg :headers))
 909          ;; Indentation causes the buffer offset of the start/end
 910          ;; points to move, so we must use markers.
 911          message-start message-end
 912          content-start content-end
 913          headers-start headers-end
 914          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 915
 916     (setq message-start (point-marker))
 917
 918     (notmuch-show-insert-headerline headers
 919                                     (or (if notmuch-show-relative-dates
 920                                             (plist-get msg :date_relative)
 921                                           nil)
 922                                         (plist-get headers :Date))
 923                                     (plist-get msg :tags) depth)
 924
 925     (setq content-start (point-marker))
 926
 927     ;; Set `headers-start' to point after the 'Subject:' header to be
 928     ;; compatible with the existing implementation. This just sets it
 929     ;; to after the first header.
 930     (notmuch-show-insert-headers headers)
 931     (save-excursion
 932       (goto-char content-start)
 933       ;; If the subject of this message is the same as that of the
 934       ;; previous message, don't display it when this message is
 935       ;; collapsed.
 936       (when (not (string= notmuch-show-previous-subject
 937                           bare-subject))
 938         (forward-line 1))
 939       (setq headers-start (point-marker)))
 940     (setq headers-end (point-marker))
 941
 942     (setq notmuch-show-previous-subject bare-subject)
 943
 944     ;; A blank line between the headers and the body.
 945     (insert "\n")
 946     (notmuch-show-insert-body msg (plist-get msg :body)
 947                               (if notmuch-show-indent-content depth 0))
 948     ;; Ensure that the body ends with a newline.
 949     (unless (bolp)
 950       (insert "\n"))
 951     (setq content-end (point-marker))
 952
 953     ;; Indent according to the depth in the thread.
 954     (if notmuch-show-indent-content
 955         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 956
 957     (setq message-end (point-max-marker))
 958
 959     ;; Save the extents of this message over the whole text of the
 960     ;; message.
 961     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 962
 963     ;; Create overlays used to control visibility
 964     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
 965     (plist-put msg :message-overlay (make-overlay headers-start content-end))
 966
 967     (plist-put msg :depth depth)
 968
 969     ;; Save the properties for this message. Currently this saves the
 970     ;; entire message (augmented it with other stuff), which seems
 971     ;; like overkill. We might save a reduced subset (for example, not
 972     ;; the content).
 973     (notmuch-show-set-message-properties msg)
 974
 975     ;; Set header visibility.
 976     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 977
 978     ;; Message visibility depends on whether it matched the search
 979     ;; criteria.
 980     (notmuch-show-message-visible msg (and (plist-get msg :match)
 981                                            (not (plist-get msg :excluded))))))
 982
 983 (defun notmuch-show-toggle-process-crypto ()
 984   "Toggle the processing of cryptographic MIME parts."
 985   (interactive)
 986   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 987   (message (if notmuch-show-process-crypto
 988                "Processing cryptographic MIME parts."
 989              "Not processing cryptographic MIME parts."))
 990   (notmuch-show-refresh-view))
 991
 992 (defun notmuch-show-toggle-elide-non-matching ()
 993   "Toggle the display of non-matching messages."
 994   (interactive)
 995   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
 996   (message (if notmuch-show-elide-non-matching-messages
 997                "Showing matching messages only."
 998              "Showing all messages."))
 999   (notmuch-show-refresh-view))
1000
1001 (defun notmuch-show-toggle-thread-indentation ()
1002   "Toggle the indentation of threads."
1003   (interactive)
1004   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1005   (message (if notmuch-show-indent-content
1006                "Content is indented."
1007              "Content is not indented."))
1008   (notmuch-show-refresh-view))
1009
1010 (defun notmuch-show-insert-tree (tree depth)
1011   "Insert the message tree TREE at depth DEPTH in the current thread."
1012   (let ((msg (car tree))
1013         (replies (cadr tree)))
1014     ;; We test whether there is a message or just some replies.
1015     (when msg
1016       (notmuch-show-insert-msg msg depth))
1017     (notmuch-show-insert-thread replies (1+ depth))))
1018
1019 (defun notmuch-show-insert-thread (thread depth)
1020   "Insert the thread THREAD at depth DEPTH in the current forest."
1021   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1022
1023 (defun notmuch-show-insert-forest (forest)
1024   "Insert the forest of threads FOREST."
1025   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1026
1027 (defvar notmuch-id-regexp
1028   (concat
1029    ;; Match the id: prefix only if it begins a word (to disallow, for
1030    ;; example, matching cid:).
1031    "\\<id:\\("
1032    ;; If the term starts with a ", then parse Xapian's quoted boolean
1033    ;; term syntax, which allows for anything as long as embedded
1034    ;; double quotes escaped by doubling them.  We also disallow
1035    ;; newlines (which Xapian allows) to prevent runaway terms.
1036    "\"\\([^\"\n]\\|\"\"\\)*\""
1037    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1038    ;; next space or ).  We disallow [.,;] as the last character
1039    ;; because these are probably part of the surrounding text, and not
1040    ;; part of the id.  This doesn't match single character ids; meh.
1041    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1042    "\\)")
1043   "The regexp used to match id: links in messages.")
1044
1045 (defvar notmuch-mid-regexp
1046   ;; goto-address-url-regexp matched cid: links, which have the same
1047   ;; grammar as the message ID part of a mid: link.  Construct the
1048   ;; regexp using the same technique as goto-address-url-regexp.
1049   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1050   "The regexp used to match mid: links in messages.
1051
1052 See RFC 2392.")
1053
1054 (defun notmuch-show-buttonise-links (start end)
1055   "Buttonise URLs and mail addresses between START and END.
1056
1057 This also turns id:\"<message id>\"-parts and mid: links into
1058 buttons for a corresponding notmuch search."
1059   (goto-address-fontify-region start end)
1060   (save-excursion
1061     (let (links)
1062       (goto-char start)
1063       (while (re-search-forward notmuch-id-regexp end t)
1064         (push (list (match-beginning 0) (match-end 0)
1065                     (match-string-no-properties 0)) links))
1066       (goto-char start)
1067       (while (re-search-forward notmuch-mid-regexp end t)
1068         (let* ((mid-cid (match-string-no-properties 1))
1069                (mid (save-match-data
1070                       (string-match "^[^/]*" mid-cid)
1071                       (url-unhex-string (match-string 0 mid-cid)))))
1072           (push (list (match-beginning 0) (match-end 0)
1073                       (notmuch-id-to-query mid)) links)))
1074       (dolist (link links)
1075         ;; Remove the overlay created by goto-address-mode
1076         (remove-overlays (first link) (second link) 'goto-address t)
1077         (make-text-button (first link) (second link)
1078                           'action `(lambda (arg)
1079                                      (notmuch-show ,(third link)))
1080                           'follow-link t
1081                           'help-echo "Mouse-1, RET: search for this message"
1082                           'face goto-address-mail-face)))))
1083
1084 ;;;###autoload
1085 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1086   "Run \"notmuch show\" with the given thread ID and display results.
1087
1088 The optional PARENT-BUFFER is the notmuch-search buffer from
1089 which this notmuch-show command was executed, (so that the
1090 next thread from that buffer can be show when done with this
1091 one).
1092
1093 The optional QUERY-CONTEXT is a notmuch search term. Only
1094 messages from the thread matching this search term are shown if
1095 non-nil.
1096
1097 The optional BUFFER-NAME provides the name of the buffer in
1098 which the message thread is shown. If it is nil (which occurs
1099 when the command is called interactively) the argument to the
1100 function is used."
1101   (interactive "sNotmuch show: ")
1102   (let ((buffer-name (generate-new-buffer-name
1103                       (or buffer-name
1104                           (concat "*notmuch-" thread-id "*")))))
1105     (switch-to-buffer (get-buffer-create buffer-name))
1106     ;; Set the default value for `notmuch-show-process-crypto' in this
1107     ;; buffer.
1108     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1109     ;; Set the default value for
1110     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1111     ;; there is a prefix argument, invert the default.
1112     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1113     (if current-prefix-arg
1114         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1115
1116     (setq notmuch-show-thread-id thread-id
1117           notmuch-show-parent-buffer parent-buffer
1118           notmuch-show-query-context query-context)
1119     (notmuch-show-build-buffer)
1120     (notmuch-show-goto-first-wanted-message)
1121     (current-buffer)))
1122
1123 (defun notmuch-show-build-buffer ()
1124   (let ((inhibit-read-only t))
1125
1126     (notmuch-show-mode)
1127     ;; Don't track undo information for this buffer
1128     (set 'buffer-undo-list t)
1129
1130     (erase-buffer)
1131     (goto-char (point-min))
1132     (save-excursion
1133       (let* ((basic-args (list notmuch-show-thread-id))
1134              (args (if notmuch-show-query-context
1135                        (append (list "\'") basic-args
1136                                (list "and (" notmuch-show-query-context ")\'"))
1137                      (append (list "\'") basic-args (list "\'"))))
1138              (cli-args (cons "--exclude=false"
1139                              (when notmuch-show-elide-non-matching-messages
1140                                (list "--entire-thread=false")))))
1141
1142         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1143         ;; If the query context reduced the results to nothing, run
1144         ;; the basic query.
1145         (when (and (eq (buffer-size) 0)
1146                    notmuch-show-query-context)
1147           (notmuch-show-insert-forest
1148            (notmuch-query-get-threads (append cli-args basic-args)))))
1149
1150       (jit-lock-register #'notmuch-show-buttonise-links)
1151
1152       ;; Set the header line to the subject of the first message.
1153       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1154
1155       (run-hooks 'notmuch-show-hook))))
1156
1157 (defun notmuch-show-capture-state ()
1158   "Capture the state of the current buffer.
1159
1160 This includes:
1161  - the list of open messages,
1162  - the current message."
1163   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1164
1165 (defun notmuch-show-apply-state (state)
1166   "Apply STATE to the current buffer.
1167
1168 This includes:
1169  - opening the messages previously opened,
1170  - closing all other messages,
1171  - moving to the correct current message."
1172   (let ((current (car state))
1173         (open (cadr state)))
1174
1175     ;; Open those that were open.
1176     (goto-char (point-min))
1177     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1178                                            (member (notmuch-show-get-message-id) open))
1179           until (not (notmuch-show-goto-message-next)))
1180
1181     ;; Go to the previously open message.
1182     (goto-char (point-min))
1183     (unless (loop if (string= current (notmuch-show-get-message-id))
1184                   return t
1185                   until (not (notmuch-show-goto-message-next)))
1186       (goto-char (point-min))
1187       (message "Previously current message not found."))
1188     (notmuch-show-message-adjust)))
1189
1190 (defun notmuch-show-refresh-view (&optional reset-state)
1191   "Refresh the current view.
1192
1193 Refreshes the current view, observing changes in display
1194 preferences. If invoked with a prefix argument (or RESET-STATE is
1195 non-nil) then the state of the buffer (open/closed messages) is
1196 reset based on the original query."
1197   (interactive "P")
1198   (let ((inhibit-read-only t)
1199         (state (unless reset-state
1200                  (notmuch-show-capture-state))))
1201     ;; erase-buffer does not seem to remove overlays, which can lead
1202     ;; to weird effects such as remaining images, so remove them
1203     ;; manually.
1204     (remove-overlays)
1205     (erase-buffer)
1206     (notmuch-show-build-buffer)
1207     (if state
1208         (notmuch-show-apply-state state)
1209       ;; We're resetting state, so navigate to the first open message
1210       ;; and mark it read, just like opening a new show buffer.
1211       (notmuch-show-goto-first-wanted-message))))
1212
1213 (defvar notmuch-show-stash-map
1214   (let ((map (make-sparse-keymap)))
1215     (define-key map "c" 'notmuch-show-stash-cc)
1216     (define-key map "d" 'notmuch-show-stash-date)
1217     (define-key map "F" 'notmuch-show-stash-filename)
1218     (define-key map "f" 'notmuch-show-stash-from)
1219     (define-key map "i" 'notmuch-show-stash-message-id)
1220     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1221     (define-key map "s" 'notmuch-show-stash-subject)
1222     (define-key map "T" 'notmuch-show-stash-tags)
1223     (define-key map "t" 'notmuch-show-stash-to)
1224     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1225     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1226     map)
1227   "Submap for stash commands")
1228 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1229
1230 (defvar notmuch-show-mode-map
1231       (let ((map (make-sparse-keymap)))
1232         (define-key map "?" 'notmuch-help)
1233         (define-key map "q" 'notmuch-kill-this-buffer)
1234         (define-key map (kbd "<C-tab>") 'widget-backward)
1235         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1236         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1237         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1238         (define-key map "s" 'notmuch-search)
1239         (define-key map "m" 'notmuch-mua-new-mail)
1240         (define-key map "f" 'notmuch-show-forward-message)
1241         (define-key map "r" 'notmuch-show-reply-sender)
1242         (define-key map "R" 'notmuch-show-reply)
1243         (define-key map "|" 'notmuch-show-pipe-message)
1244         (define-key map "w" 'notmuch-show-save-attachments)
1245         (define-key map "V" 'notmuch-show-view-raw-message)
1246         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1247         (define-key map "c" 'notmuch-show-stash-map)
1248         (define-key map "=" 'notmuch-show-refresh-view)
1249         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1250         (define-key map "*" 'notmuch-show-tag-all)
1251         (define-key map "-" 'notmuch-show-remove-tag)
1252         (define-key map "+" 'notmuch-show-add-tag)
1253         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1254         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1255         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1256         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1257         (define-key map "N" 'notmuch-show-next-message)
1258         (define-key map "P" 'notmuch-show-previous-message)
1259         (define-key map "n" 'notmuch-show-next-open-message)
1260         (define-key map "p" 'notmuch-show-previous-open-message)
1261         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1262         (define-key map " " 'notmuch-show-advance-and-archive)
1263         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1264         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1265         (define-key map "#" 'notmuch-show-print-message)
1266         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1267         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1268         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1269         (define-key map "t" 'toggle-truncate-lines)
1270         map)
1271       "Keymap for \"notmuch show\" buffers.")
1272 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1273
1274 (defun notmuch-show-mode ()
1275   "Major mode for viewing a thread with notmuch.
1276
1277 This buffer contains the results of the \"notmuch show\" command
1278 for displaying a single thread of email from your email archives.
1279
1280 By default, various components of email messages, (citations,
1281 signatures, already-read messages), are hidden. You can make
1282 these parts visible by clicking with the mouse button or by
1283 pressing RET after positioning the cursor on a hidden part, (for
1284 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1285
1286 Reading the thread sequentially is well-supported by pressing
1287 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1288 to the next message, or advance to the next thread (if already on
1289 the last message of a thread).
1290
1291 Other commands are available to read or manipulate the thread
1292 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1293 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1294 without scrolling through with \\[notmuch-show-advance-and-archive]).
1295
1296 You can add or remove arbitrary tags from the current message with
1297 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1298
1299 All currently available key bindings:
1300
1301 \\{notmuch-show-mode-map}"
1302   (interactive)
1303   (kill-all-local-variables)
1304   (use-local-map notmuch-show-mode-map)
1305   (setq major-mode 'notmuch-show-mode
1306         mode-name "notmuch-show")
1307   (setq buffer-read-only t
1308         truncate-lines t))
1309
1310 (defun notmuch-show-move-to-message-top ()
1311   (goto-char (notmuch-show-message-top)))
1312
1313 (defun notmuch-show-move-to-message-bottom ()
1314   (goto-char (notmuch-show-message-bottom)))
1315
1316 (defun notmuch-show-message-adjust ()
1317   (recenter 0))
1318
1319 ;; Movement related functions.
1320
1321 ;; There's some strangeness here where a text property applied to a
1322 ;; region a->b is not found when point is at b. We walk backwards
1323 ;; until finding the property.
1324 (defun notmuch-show-message-extent ()
1325   (let (r)
1326     (save-excursion
1327       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1328         (backward-char)))
1329     r))
1330
1331 (defun notmuch-show-message-top ()
1332   (car (notmuch-show-message-extent)))
1333
1334 (defun notmuch-show-message-bottom ()
1335   (cdr (notmuch-show-message-extent)))
1336
1337 (defun notmuch-show-goto-message-next ()
1338   (let ((start (point)))
1339     (notmuch-show-move-to-message-bottom)
1340     (if (not (eobp))
1341         t
1342       (goto-char start)
1343       nil)))
1344
1345 (defun notmuch-show-goto-message-previous ()
1346   (notmuch-show-move-to-message-top)
1347   (if (bobp)
1348       nil
1349     (backward-char)
1350     (notmuch-show-move-to-message-top)
1351     t))
1352
1353 (defun notmuch-show-mapc (function)
1354   "Iterate through all messages in the current thread with
1355 `notmuch-show-goto-message-next' and call FUNCTION for side
1356 effects."
1357   (save-excursion
1358     (goto-char (point-min))
1359     (loop do (funcall function)
1360           while (notmuch-show-goto-message-next))))
1361
1362 ;; Functions relating to the visibility of messages and their
1363 ;; components.
1364
1365 (defun notmuch-show-message-visible (props visible-p)
1366   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1367   (notmuch-show-set-prop :message-visible visible-p props))
1368
1369 (defun notmuch-show-headers-visible (props visible-p)
1370   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1371   (notmuch-show-set-prop :headers-visible visible-p props))
1372
1373 ;; Functions for setting and getting attributes of the current
1374 ;; message.
1375
1376 (defun notmuch-show-set-message-properties (props)
1377   (save-excursion
1378     (notmuch-show-move-to-message-top)
1379     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1380
1381 (defun notmuch-show-get-message-properties ()
1382   "Return the properties of the current message as a plist.
1383
1384 Some useful entries are:
1385 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1386 :body - Body of the message
1387 :tags - Tags for this message"
1388   (save-excursion
1389     (notmuch-show-move-to-message-top)
1390     (get-text-property (point) :notmuch-message-properties)))
1391
1392 (defun notmuch-show-set-prop (prop val &optional props)
1393   (let ((inhibit-read-only t)
1394         (props (or props
1395                    (notmuch-show-get-message-properties))))
1396     (plist-put props prop val)
1397     (notmuch-show-set-message-properties props)))
1398
1399 (defun notmuch-show-get-prop (prop &optional props)
1400   (let ((props (or props
1401                    (notmuch-show-get-message-properties))))
1402     (plist-get props prop)))
1403
1404 (defun notmuch-show-get-message-id (&optional bare)
1405   "Return an id: query for the Message-Id of the current message.
1406
1407 If optional argument BARE is non-nil, return
1408 the Message-Id without id: prefix and escaping."
1409   (if bare
1410       (notmuch-show-get-prop :id)
1411     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1412
1413 (defun notmuch-show-get-messages-ids ()
1414   "Return all id: queries of messages in the current thread."
1415   (let ((message-ids))
1416     (notmuch-show-mapc
1417      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1418     message-ids))
1419
1420 (defun notmuch-show-get-messages-ids-search ()
1421   "Return a search string for all message ids of messages in the
1422 current thread."
1423   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1424
1425 ;; dme: Would it make sense to use a macro for many of these?
1426
1427 (defun notmuch-show-get-filename ()
1428   "Return the filename of the current message."
1429   (notmuch-show-get-prop :filename))
1430
1431 (defun notmuch-show-get-header (header &optional props)
1432   "Return the named header of the current message, if any."
1433   (plist-get (notmuch-show-get-prop :headers props) header))
1434
1435 (defun notmuch-show-get-cc ()
1436   (notmuch-show-get-header :Cc))
1437
1438 (defun notmuch-show-get-date ()
1439   (notmuch-show-get-header :Date))
1440
1441 (defun notmuch-show-get-from ()
1442   (notmuch-show-get-header :From))
1443
1444 (defun notmuch-show-get-subject ()
1445   (notmuch-show-get-header :Subject))
1446
1447 (defun notmuch-show-get-to ()
1448   (notmuch-show-get-header :To))
1449
1450 (defun notmuch-show-get-depth ()
1451   (notmuch-show-get-prop :depth))
1452
1453 (defun notmuch-show-set-tags (tags)
1454   "Set the tags of the current message."
1455   (notmuch-show-set-prop :tags tags)
1456   (notmuch-show-update-tags tags))
1457
1458 (defun notmuch-show-get-tags ()
1459   "Return the tags of the current message."
1460   (notmuch-show-get-prop :tags))
1461
1462 (defun notmuch-show-message-visible-p ()
1463   "Is the current message visible?"
1464   (notmuch-show-get-prop :message-visible))
1465
1466 (defun notmuch-show-headers-visible-p ()
1467   "Are the headers of the current message visible?"
1468   (notmuch-show-get-prop :headers-visible))
1469
1470 (defun notmuch-show-mark-read (&optional unread)
1471   "Mark the current message as read.
1472
1473 Mark the current message as read by applying the tag changes in
1474 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1475 default). If a prefix argument is given, the message will be
1476 marked as unread, i.e. the tag changes in
1477 `notmuch-show-mark-read-tags' will be reversed."
1478   (interactive "P")
1479   (when notmuch-show-mark-read-tags
1480     (apply 'notmuch-show-tag-message
1481            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1482
1483 ;; Functions for getting attributes of several messages in the current
1484 ;; thread.
1485
1486 (defun notmuch-show-get-message-ids-for-open-messages ()
1487   "Return a list of all id: queries for open messages in the current thread."
1488   (save-excursion
1489     (let (message-ids done)
1490       (goto-char (point-min))
1491       (while (not done)
1492         (if (notmuch-show-message-visible-p)
1493             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1494         (setq done (not (notmuch-show-goto-message-next)))
1495         )
1496       message-ids
1497       )))
1498
1499 ;; Commands typically bound to keys.
1500
1501 (defun notmuch-show-advance ()
1502   "Advance through thread.
1503
1504 If the current message in the thread is not yet fully visible,
1505 scroll by a near screenful to read more of the message.
1506
1507 Otherwise, (the end of the current message is already within the
1508 current window), advance to the next open message."
1509   (interactive)
1510   (let* ((end-of-this-message (notmuch-show-message-bottom))
1511          (visible-end-of-this-message (1- end-of-this-message))
1512          (ret nil))
1513     (while (invisible-p visible-end-of-this-message)
1514       (setq visible-end-of-this-message
1515             (max (point-min)
1516                  (1- (previous-single-char-property-change
1517                       visible-end-of-this-message 'invisible)))))
1518     (cond
1519      ;; Ideally we would test `end-of-this-message' against the result
1520      ;; of `window-end', but that doesn't account for the fact that
1521      ;; the end of the message might be hidden.
1522      ((and visible-end-of-this-message
1523            (> visible-end-of-this-message (window-end)))
1524       ;; The bottom of this message is not visible - scroll.
1525       (scroll-up nil))
1526
1527      ((not (= end-of-this-message (point-max)))
1528       ;; This is not the last message - move to the next visible one.
1529       (notmuch-show-next-open-message))
1530
1531      ((not (= (point) (point-max)))
1532       ;; This is the last message, but the cursor is not at the end of
1533       ;; the buffer. Move it there.
1534       (goto-char (point-max)))
1535
1536      (t
1537       ;; This is the last message - change the return value
1538       (setq ret t)))
1539     ret))
1540
1541 (defun notmuch-show-advance-and-archive ()
1542   "Advance through thread and archive.
1543
1544 This command is intended to be one of the simplest ways to
1545 process a thread of email. It works exactly like
1546 notmuch-show-advance, in that it scrolls through messages in a
1547 show buffer, except that when it gets to the end of the buffer it
1548 archives the entire current thread, (remove the \"inbox\" tag
1549 from each message), kills the buffer, and displays the next
1550 thread from the search from which this thread was originally
1551 shown."
1552   (interactive)
1553   (if (notmuch-show-advance)
1554       (notmuch-show-archive-thread-then-next)))
1555
1556 (defun notmuch-show-rewind ()
1557   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1558
1559 Specifically, if the beginning of the previous email is fewer
1560 than `window-height' lines from the current point, move to it
1561 just like `notmuch-show-previous-message'.
1562
1563 Otherwise, just scroll down a screenful of the current message.
1564
1565 This command does not modify any message tags, (it does not undo
1566 any effects from previous calls to
1567 `notmuch-show-advance-and-archive'."
1568   (interactive)
1569   (let ((start-of-message (notmuch-show-message-top))
1570         (start-of-window (window-start)))
1571     (cond
1572       ;; Either this message is properly aligned with the start of the
1573       ;; window or the start of this message is not visible on the
1574       ;; screen - scroll.
1575      ((or (= start-of-message start-of-window)
1576           (< start-of-message start-of-window))
1577       (scroll-down)
1578       ;; If a small number of lines from the previous message are
1579       ;; visible, realign so that the top of the current message is at
1580       ;; the top of the screen.
1581       (when (<= (count-screen-lines (window-start) start-of-message)
1582                 next-screen-context-lines)
1583         (goto-char (notmuch-show-message-top))
1584         (notmuch-show-message-adjust))
1585       ;; Move to the top left of the window.
1586       (goto-char (window-start)))
1587      (t
1588       ;; Move to the previous message.
1589       (notmuch-show-previous-message)))))
1590
1591 (defun notmuch-show-reply (&optional prompt-for-sender)
1592   "Reply to the sender and all recipients of the current message."
1593   (interactive "P")
1594   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1595
1596 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1597   "Reply to the sender of the current message."
1598   (interactive "P")
1599   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1600
1601 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1602   "Forward the current message."
1603   (interactive "P")
1604   (with-current-notmuch-show-message
1605    (notmuch-mua-new-forward-message prompt-for-sender)))
1606
1607 (defun notmuch-show-next-message (&optional pop-at-end)
1608   "Show the next message.
1609
1610 If a prefix argument is given and this is the last message in the
1611 thread, navigate to the next thread in the parent search buffer."
1612   (interactive "P")
1613   (if (notmuch-show-goto-message-next)
1614       (progn
1615         (notmuch-show-mark-read)
1616         (notmuch-show-message-adjust))
1617     (if pop-at-end
1618         (notmuch-show-next-thread)
1619       (goto-char (point-max)))))
1620
1621 (defun notmuch-show-previous-message ()
1622   "Show the previous message or the start of the current message."
1623   (interactive)
1624   (if (= (point) (notmuch-show-message-top))
1625       (notmuch-show-goto-message-previous)
1626     (notmuch-show-move-to-message-top))
1627   (notmuch-show-mark-read)
1628   (notmuch-show-message-adjust))
1629
1630 (defun notmuch-show-next-open-message (&optional pop-at-end)
1631   "Show the next open message.
1632
1633 If a prefix argument is given and this is the last open message
1634 in the thread, navigate to the next thread in the parent search
1635 buffer. Return t if there was a next open message in the thread
1636 to show, nil otherwise."
1637   (interactive "P")
1638   (let (r)
1639     (while (and (setq r (notmuch-show-goto-message-next))
1640                 (not (notmuch-show-message-visible-p))))
1641     (if r
1642         (progn
1643           (notmuch-show-mark-read)
1644           (notmuch-show-message-adjust))
1645       (if pop-at-end
1646           (notmuch-show-next-thread)
1647         (goto-char (point-max))))
1648     r))
1649
1650 (defun notmuch-show-next-matching-message ()
1651   "Show the next matching message."
1652   (interactive)
1653   (let (r)
1654     (while (and (setq r (notmuch-show-goto-message-next))
1655                 (not (notmuch-show-get-prop :match))))
1656     (if r
1657         (progn
1658           (notmuch-show-mark-read)
1659           (notmuch-show-message-adjust))
1660       (goto-char (point-max)))))
1661
1662 (defun notmuch-show-open-if-matched ()
1663   "Open a message if it is matched (whether or not excluded)."
1664   (let ((props (notmuch-show-get-message-properties)))
1665     (notmuch-show-message-visible props (plist-get props :match))))
1666
1667 (defun notmuch-show-goto-first-wanted-message ()
1668   "Move to the first open message and mark it read"
1669   (goto-char (point-min))
1670   (if (notmuch-show-message-visible-p)
1671       (notmuch-show-mark-read)
1672     (notmuch-show-next-open-message))
1673   (when (eobp)
1674     ;; There are no matched non-excluded messages so open all matched
1675     ;; (necessarily excluded) messages and go to the first.
1676     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1677     (force-window-update)
1678     (goto-char (point-min))
1679     (if (notmuch-show-message-visible-p)
1680         (notmuch-show-mark-read)
1681       (notmuch-show-next-open-message))))
1682
1683 (defun notmuch-show-previous-open-message ()
1684   "Show the previous open message."
1685   (interactive)
1686   (while (and (if (= (point) (notmuch-show-message-top))
1687                   (notmuch-show-goto-message-previous)
1688                 (notmuch-show-move-to-message-top))
1689               (not (notmuch-show-message-visible-p))))
1690   (notmuch-show-mark-read)
1691   (notmuch-show-message-adjust))
1692
1693 (defun notmuch-show-view-raw-message ()
1694   "View the file holding the current message."
1695   (interactive)
1696   (let* ((id (notmuch-show-get-message-id))
1697          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1698     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1699     (switch-to-buffer buf)
1700     (goto-char (point-min))
1701     (set-buffer-modified-p nil)
1702     (view-buffer buf 'kill-buffer-if-not-modified)))
1703
1704 (defun notmuch-show-pipe-message (entire-thread command)
1705   "Pipe the contents of the current message (or thread) to the given command.
1706
1707 The given command will be executed with the raw contents of the
1708 current email message as stdin. Anything printed by the command
1709 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1710
1711 When invoked with a prefix argument, the command will receive all
1712 open messages in the current thread (formatted as an mbox) rather
1713 than only the current message."
1714   (interactive "P\nsPipe message to command: ")
1715   (let (shell-command)
1716     (if entire-thread
1717         (setq shell-command
1718               (concat notmuch-command " show --format=mbox --exclude=false "
1719                       (shell-quote-argument
1720                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1721                       " | " command))
1722       (setq shell-command
1723             (concat notmuch-command " show --format=raw "
1724                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1725     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1726       (with-current-buffer buf
1727         (setq buffer-read-only nil)
1728         (erase-buffer)
1729         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1730           (goto-char (point-max))
1731           (set-buffer-modified-p nil)
1732           (setq buffer-read-only t)
1733           (unless (zerop exit-code)
1734             (switch-to-buffer-other-window buf)
1735             (message (format "Command '%s' exited abnormally with code %d"
1736                              shell-command exit-code))))))))
1737
1738 (defun notmuch-show-tag-message (&rest tag-changes)
1739   "Change tags for the current message.
1740
1741 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1742   (let* ((current-tags (notmuch-show-get-tags))
1743          (new-tags (notmuch-update-tags current-tags tag-changes)))
1744     (unless (equal current-tags new-tags)
1745       (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1746       (notmuch-show-set-tags new-tags))))
1747
1748 (defun notmuch-show-tag (&optional tag-changes)
1749   "Change tags for the current message.
1750
1751 See `notmuch-tag' for information on the format of TAG-CHANGES."
1752   (interactive)
1753   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes))
1754   (let* ((current-tags (notmuch-show-get-tags))
1755          (new-tags (notmuch-update-tags current-tags tag-changes)))
1756     (unless (equal current-tags new-tags)
1757       (notmuch-show-set-tags new-tags))))
1758
1759 (defun notmuch-show-tag-all (&optional tag-changes)
1760   "Change tags for all messages in the current show buffer.
1761
1762 See `notmuch-tag' for information on the format of TAG-CHANGES."
1763   (interactive)
1764   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1765   (notmuch-show-mapc
1766    (lambda ()
1767      (let* ((current-tags (notmuch-show-get-tags))
1768             (new-tags (notmuch-update-tags current-tags tag-changes)))
1769        (unless (equal current-tags new-tags)
1770          (notmuch-show-set-tags new-tags))))))
1771
1772 (defun notmuch-show-add-tag ()
1773   "Same as `notmuch-show-tag' but sets initial input to '+'."
1774   (interactive)
1775   (notmuch-show-tag "+"))
1776
1777 (defun notmuch-show-remove-tag ()
1778   "Same as `notmuch-show-tag' but sets initial input to '-'."
1779   (interactive)
1780   (notmuch-show-tag "-"))
1781
1782 (defun notmuch-show-toggle-visibility-headers ()
1783   "Toggle the visibility of the current message headers."
1784   (interactive)
1785   (let ((props (notmuch-show-get-message-properties)))
1786     (notmuch-show-headers-visible
1787      props
1788      (not (plist-get props :headers-visible))))
1789   (force-window-update))
1790
1791 (defun notmuch-show-toggle-message ()
1792   "Toggle the visibility of the current message."
1793   (interactive)
1794   (let ((props (notmuch-show-get-message-properties)))
1795     (notmuch-show-message-visible
1796      props
1797      (not (plist-get props :message-visible))))
1798   (force-window-update))
1799
1800 (defun notmuch-show-open-or-close-all ()
1801   "Set the visibility all of the messages in the current thread.
1802 By default make all of the messages visible. With a prefix
1803 argument, hide all of the messages."
1804   (interactive)
1805   (save-excursion
1806     (goto-char (point-min))
1807     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1808                                            (not current-prefix-arg))
1809           until (not (notmuch-show-goto-message-next))))
1810   (force-window-update))
1811
1812 (defun notmuch-show-next-button ()
1813   "Advance point to the next button in the buffer."
1814   (interactive)
1815   (forward-button 1))
1816
1817 (defun notmuch-show-previous-button ()
1818   "Move point back to the previous button in the buffer."
1819   (interactive)
1820   (backward-button 1))
1821
1822 (defun notmuch-show-next-thread (&optional show-next)
1823   "Move to the next item in the search results, if any."
1824   (interactive "P")
1825   (let ((parent-buffer notmuch-show-parent-buffer))
1826     (notmuch-kill-this-buffer)
1827     (when (buffer-live-p parent-buffer)
1828       (switch-to-buffer parent-buffer)
1829       (notmuch-search-next-thread)
1830       (if show-next
1831           (notmuch-search-show-thread)))))
1832
1833 (defun notmuch-show-archive-thread (&optional unarchive)
1834   "Archive each message in thread.
1835
1836 Archive each message currently shown by applying the tag changes
1837 in `notmuch-archive-tags' to each (remove the \"inbox\" tag by
1838 default). If a prefix argument is given, the messages will be
1839 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1840 will be reversed.
1841
1842 Note: This command is safe from any race condition of new messages
1843 being delivered to the same thread. It does not archive the
1844 entire thread, but only the messages shown in the current
1845 buffer."
1846   (interactive "P")
1847   (when notmuch-archive-tags
1848     (notmuch-show-tag-all
1849      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1850
1851 (defun notmuch-show-archive-thread-then-next ()
1852   "Archive all messages in the current buffer, then show next thread from search."
1853   (interactive)
1854   (notmuch-show-archive-thread)
1855   (notmuch-show-next-thread t))
1856
1857 (defun notmuch-show-archive-thread-then-exit ()
1858   "Archive all messages in the current buffer, then exit back to search results."
1859   (interactive)
1860   (notmuch-show-archive-thread)
1861   (notmuch-show-next-thread))
1862
1863 (defun notmuch-show-archive-message (&optional unarchive)
1864   "Archive the current message.
1865
1866 Archive the current message by applying the tag changes in
1867 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
1868 default). If a prefix argument is given, the message will be
1869 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1870 will be reversed."
1871   (interactive "P")
1872   (when notmuch-archive-tags
1873     (apply 'notmuch-show-tag-message
1874            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1875
1876 (defun notmuch-show-archive-message-then-next-or-exit ()
1877   "Archive the current message, then show the next open message in the current thread.
1878
1879 If at the last open message in the current thread, then exit back
1880 to search results."
1881   (interactive)
1882   (notmuch-show-archive-message)
1883   (notmuch-show-next-open-message t))
1884
1885 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1886   "Archive the current message, then show the next open message in the current thread.
1887
1888 If at the last open message in the current thread, then show next
1889 thread from search."
1890   (interactive)
1891   (notmuch-show-archive-message)
1892   (unless (notmuch-show-next-open-message)
1893     (notmuch-show-next-thread t)))
1894
1895 (defun notmuch-show-stash-cc ()
1896   "Copy CC field of current message to kill-ring."
1897   (interactive)
1898   (notmuch-common-do-stash (notmuch-show-get-cc)))
1899
1900 (defun notmuch-show-stash-date ()
1901   "Copy date of current message to kill-ring."
1902   (interactive)
1903   (notmuch-common-do-stash (notmuch-show-get-date)))
1904
1905 (defun notmuch-show-stash-filename ()
1906   "Copy filename of current message to kill-ring."
1907   (interactive)
1908   (notmuch-common-do-stash (notmuch-show-get-filename)))
1909
1910 (defun notmuch-show-stash-from ()
1911   "Copy From address of current message to kill-ring."
1912   (interactive)
1913   (notmuch-common-do-stash (notmuch-show-get-from)))
1914
1915 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
1916   "Copy id: query matching the current message to kill-ring.
1917
1918 If invoked with a prefix argument (or STASH-THREAD-ID is
1919 non-nil), copy thread: query matching the current thread to
1920 kill-ring."
1921   (interactive "P")
1922   (if stash-thread-id
1923       (notmuch-common-do-stash notmuch-show-thread-id)
1924     (notmuch-common-do-stash (notmuch-show-get-message-id))))
1925
1926 (defun notmuch-show-stash-message-id-stripped ()
1927   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1928   (interactive)
1929   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1930
1931 (defun notmuch-show-stash-subject ()
1932   "Copy Subject field of current message to kill-ring."
1933   (interactive)
1934   (notmuch-common-do-stash (notmuch-show-get-subject)))
1935
1936 (defun notmuch-show-stash-tags ()
1937   "Copy tags of current message to kill-ring as a comma separated list."
1938   (interactive)
1939   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1940
1941 (defun notmuch-show-stash-to ()
1942   "Copy To address of current message to kill-ring."
1943   (interactive)
1944   (notmuch-common-do-stash (notmuch-show-get-to)))
1945
1946 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1947   "Copy an ML Archive URI for the current message to the kill-ring.
1948
1949 This presumes that the message is available at the selected Mailing List Archive.
1950
1951 If optional argument MLA is non-nil, use the provided key instead of prompting
1952 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1953   (interactive)
1954   (notmuch-common-do-stash
1955    (concat (cdr (assoc
1956                  (or mla
1957                      (let ((completion-ignore-case t))
1958                        (completing-read
1959                         "Mailing List Archive: "
1960                         notmuch-show-stash-mlarchive-link-alist
1961                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1962                  notmuch-show-stash-mlarchive-link-alist))
1963            (notmuch-show-get-message-id t))))
1964
1965 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1966   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1967
1968 This presumes that the message is available at the selected Mailing List Archive.
1969
1970 If optional argument MLA is non-nil, use the provided key instead of prompting
1971 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1972   (interactive)
1973   (notmuch-show-stash-mlarchive-link mla)
1974   (browse-url (current-kill 0 t)))
1975
1976 ;; Commands typically bound to buttons.
1977
1978 (defun notmuch-show-part-button-default (&optional button)
1979   (interactive)
1980   (let ((button (or button (button-at (point)))))
1981     (if (button-get button 'overlay)
1982         (notmuch-show-toggle-part-invisibility button)
1983       (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))))
1984
1985 (defun notmuch-show-part-button-save (&optional button)
1986   (interactive)
1987   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
1988
1989 (defun notmuch-show-part-button-view (&optional button)
1990   (interactive)
1991   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
1992
1993 (defun notmuch-show-part-button-interactively-view (&optional button)
1994   (interactive)
1995   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
1996
1997 (defun notmuch-show-part-button-pipe (&optional button)
1998   (interactive)
1999   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
2000
2001 (defun notmuch-show-part-button-internal (button handler)
2002   (let ((button (or button (button-at (point)))))
2003     (if button
2004         (let ((nth (button-get button :notmuch-part)))
2005           (if nth
2006               (funcall handler (notmuch-show-get-message-id) nth
2007                        (button-get button :notmuch-filename)
2008                        (button-get button :notmuch-content-type)))))))
2009
2010 ;;
2011
2012 (provide 'notmuch-show)