git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28
  29 (require 'notmuch-lib)
  30 (require 'notmuch-query)
  31 (require 'notmuch-show)
  32 (require 'notmuch-tag)
  33 (require 'notmuch-parser)
  34
  35 (eval-when-compile (require 'cl))
  36 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line))
  37 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  38 (declare-function notmuch-read-query "notmuch" (prompt))
  39 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  40 (declare-function notmuch-search-find-subject "notmuch" ())
  41
  42 ;; the following variable is defined in notmuch.el
  43 (defvar notmuch-search-query-string)
  44
  45 ;; this variable distinguishes the unthreaded display from the normal tree display
  46 (defvar notmuch-tree-unthreaded nil
  47   "A buffer local copy of argument unthreaded to the function notmuch-tree")
  48 (make-variable-buffer-local 'notmuch-tree-unthreaded)
  49
  50 (defgroup notmuch-tree nil
  51   "Showing message and thread structure."
  52   :group 'notmuch)
  53
  54 (defcustom notmuch-tree-show-out nil
  55   "View selected messages in new window rather than split-pane."
  56   :type 'boolean
  57   :group 'notmuch-tree)
  58
  59 (defcustom notmuch-unthreaded-show-out t
  60   "View selected messages in new window rather than split-pane."
  61   :type 'boolean
  62   :group 'notmuch-tree)
  63
  64 (defun notmuch-tree-show-out ()
  65   (if notmuch-tree-unthreaded
  66       notmuch-unthreaded-show-out
  67     notmuch-tree-show-out))
  68
  69 (defcustom notmuch-tree-result-format
  70   `(("date" . "%12s  ")
  71     ("authors" . "%-20s")
  72     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  73     ("tags" . "(%s)"))
  74   "Result formatting for Tree view. Supported fields are: date,
  75         authors, subject, tree, tags.  Tree means the thread tree
  76         box graphics. The field may also be a list in which case
  77         the formatting rules are applied recursively and then the
  78         output of all the fields in the list is inserted
  79         according to format-string.
  80
  81 Note the author string should not contain
  82         whitespace (put it in the neighbouring fields instead).
  83         For example:
  84         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  85                                              \(\"subject\" . \"%s\"\)\)\)"
  86   :type '(alist :key-type (string) :value-type (string))
  87   :group 'notmuch-tree)
  88
  89 (defcustom notmuch-unthreaded-result-format
  90   `(("date" . "%12s  ")
  91     ("authors" . "%-20s")
  92     ((("subject" . "%s")) ." %-54s ")
  93     ("tags" . "(%s)"))
  94   "Result formatting for unthreaded Tree view. Supported fields are: date,
  95         authors, subject, tree, tags.  Tree means the thread tree
  96         box graphics. The field may also be a list in which case
  97         the formatting rules are applied recursively and then the
  98         output of all the fields in the list is inserted
  99         according to format-string.
 100
 101 Note the author string should not contain
 102         whitespace (put it in the neighbouring fields instead).
 103         For example:
 104         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 105                                              \(\"subject\" . \"%s\"\)\)\)"
 106   :type '(alist :key-type (string) :value-type (string))
 107   :group 'notmuch-tree)
 108
 109 (defun notmuch-tree-result-format ()
 110   (if notmuch-tree-unthreaded
 111       notmuch-unthreaded-result-format
 112     notmuch-tree-result-format))
 113
 114 ;; Faces for messages that match the query.
 115 (defface notmuch-tree-match-face
 116   '((t :inherit default))
 117   "Default face used in tree mode face for matching messages"
 118   :group 'notmuch-tree
 119   :group 'notmuch-faces)
 120
 121 (defface notmuch-tree-match-date-face
 122   nil
 123   "Face used in tree mode for the date in messages matching the query."
 124   :group 'notmuch-tree
 125   :group 'notmuch-faces)
 126
 127 (defface notmuch-tree-match-author-face
 128   '((((class color)
 129       (background dark))
 130      (:foreground "OliveDrab1"))
 131     (((class color)
 132       (background light))
 133      (:foreground "dark blue"))
 134     (t
 135      (:bold t)))
 136   "Face used in tree mode for the date in messages matching the query."
 137   :group 'notmuch-tree
 138   :group 'notmuch-faces)
 139
 140 (defface notmuch-tree-match-subject-face
 141   nil
 142   "Face used in tree mode for the subject in messages matching the query."
 143   :group 'notmuch-tree
 144   :group 'notmuch-faces)
 145
 146 (defface notmuch-tree-match-tree-face
 147   nil
 148   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 149   :group 'notmuch-tree
 150   :group 'notmuch-faces)
 151
 152 (defface notmuch-tree-match-tag-face
 153   '((((class color)
 154       (background dark))
 155      (:foreground "OliveDrab1"))
 156     (((class color)
 157       (background light))
 158      (:foreground "navy blue" :bold t))
 159     (t
 160      (:bold t)))
 161   "Face used in tree mode for tags in messages matching the query."
 162   :group 'notmuch-tree
 163   :group 'notmuch-faces)
 164
 165 ;; Faces for messages that do not match the query.
 166 (defface notmuch-tree-no-match-face
 167   '((t (:foreground "gray")))
 168   "Default face used in tree mode face for non-matching messages"
 169   :group 'notmuch-tree
 170   :group 'notmuch-faces)
 171
 172 (defface notmuch-tree-no-match-date-face
 173   nil
 174   "Face used in tree mode for non-matching dates."
 175   :group 'notmuch-tree
 176   :group 'notmuch-faces)
 177
 178 (defface notmuch-tree-no-match-subject-face
 179   nil
 180   "Face used in tree mode for non-matching subjects."
 181   :group 'notmuch-tree
 182   :group 'notmuch-faces)
 183
 184 (defface notmuch-tree-no-match-tree-face
 185   nil
 186   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 187   :group 'notmuch-tree
 188   :group 'notmuch-faces)
 189
 190 (defface notmuch-tree-no-match-author-face
 191   nil
 192   "Face used in tree mode for the date in messages matching the query."
 193   :group 'notmuch-tree
 194   :group 'notmuch-faces)
 195
 196 (defface notmuch-tree-no-match-tag-face
 197   nil
 198   "Face used in tree mode face for non-matching tags."
 199   :group 'notmuch-tree
 200   :group 'notmuch-faces)
 201
 202 (defvar notmuch-tree-previous-subject
 203   "The subject of the most recent result shown during the async display")
 204 (make-variable-buffer-local 'notmuch-tree-previous-subject)
 205
 206 (defvar notmuch-tree-basic-query nil
 207   "A buffer local copy of argument query to the function notmuch-tree")
 208 (make-variable-buffer-local 'notmuch-tree-basic-query)
 209
 210 (defvar notmuch-tree-query-context nil
 211   "A buffer local copy of argument query-context to the function notmuch-tree")
 212 (make-variable-buffer-local 'notmuch-tree-query-context)
 213
 214 (defvar notmuch-tree-target-msg nil
 215   "A buffer local copy of argument target to the function notmuch-tree")
 216 (make-variable-buffer-local 'notmuch-tree-target-msg)
 217
 218 (defvar notmuch-tree-open-target nil
 219   "A buffer local copy of argument open-target to the function notmuch-tree")
 220 (make-variable-buffer-local 'notmuch-tree-open-target)
 221
 222 (defvar notmuch-tree-message-window nil
 223   "The window of the message pane.
 224
 225 It is set in both the tree buffer and the child show buffer. It
 226 is used to try and close the message pane when quitting tree view
 227 or the child show buffer.")
 228 (make-variable-buffer-local 'notmuch-tree-message-window)
 229 (put 'notmuch-tree-message-window 'permanent-local t)
 230
 231 (defvar notmuch-tree-message-buffer nil
 232   "The buffer name of the show buffer in the message pane.
 233
 234 This is used to try and make sure we don't close the message pane
 235 if the user has loaded a different buffer in that window.")
 236 (make-variable-buffer-local 'notmuch-tree-message-buffer)
 237 (put 'notmuch-tree-message-buffer 'permanent-local t)
 238
 239 (defun notmuch-tree-to-message-pane (func)
 240   "Execute FUNC in message pane.
 241
 242 This function returns a function (so can be used as a keybinding)
 243 which executes function FUNC in the message pane if it is
 244 open (if the message pane is closed it does nothing)."
 245   `(lambda ()
 246       ,(concat "(In message pane) " (documentation func t))
 247      (interactive)
 248      (when (window-live-p notmuch-tree-message-window)
 249        (with-selected-window notmuch-tree-message-window
 250          (call-interactively #',func)))))
 251
 252 (defun notmuch-tree-inherit-from-message-pane (sym)
 253   "Return value of SYM in message-pane if open, or tree-pane if not"
 254   (if (window-live-p notmuch-tree-message-window)
 255       (with-selected-window notmuch-tree-message-window
 256         (symbol-value sym))
 257     (symbol-value sym)))
 258
 259 (defun notmuch-tree-button-activate (&optional button)
 260   "Activate BUTTON or button at point
 261
 262 This function does not give an error if there is no button."
 263   (interactive)
 264   (let ((button (or button (button-at (point)))))
 265     (when button (button-activate button))))
 266
 267 (defun notmuch-tree-close-message-pane-and (func)
 268   "Close message pane and execute FUNC.
 269
 270 This function returns a function (so can be used as a keybinding)
 271 which closes the message pane if open and then executes function
 272 FUNC."
 273   `(lambda ()
 274       ,(concat "(Close message pane and) " (documentation func t))
 275      (interactive)
 276      (let ((notmuch-show-process-crypto
 277             (notmuch-tree-inherit-from-message-pane 'notmuch-show-process-crypto)))
 278        (notmuch-tree-close-message-window)
 279        (call-interactively #',func))))
 280
 281 (defvar notmuch-tree-mode-map
 282   (let ((map (make-sparse-keymap)))
 283     (set-keymap-parent map notmuch-common-keymap)
 284     ;; The following override the global keymap.
 285     ;; Override because we want to close message pane first.
 286     (define-key map [remap notmuch-help] (notmuch-tree-close-message-pane-and #'notmuch-help))
 287     ;; Override because we first close message pane and then close tree buffer.
 288     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 289     ;; Override because we close message pane after the search query is entered.
 290     (define-key map [remap notmuch-search] 'notmuch-tree-to-search)
 291     ;; Override because we want to close message pane first.
 292     (define-key map [remap notmuch-mua-new-mail] (notmuch-tree-close-message-pane-and #'notmuch-mua-new-mail))
 293     ;; Override because we want to close message pane first.
 294     (define-key map [remap notmuch-jump-search] (notmuch-tree-close-message-pane-and #'notmuch-jump-search))
 295
 296     (define-key map "S" 'notmuch-search-from-tree-current-query)
 297     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 298     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 299
 300     ;; these use notmuch-show functions directly
 301     (define-key map "|" 'notmuch-show-pipe-message)
 302     (define-key map "w" 'notmuch-show-save-attachments)
 303     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 304     (define-key map "c" 'notmuch-show-stash-map)
 305     (define-key map "b" 'notmuch-show-resend-message)
 306
 307     ;; these apply to the message pane
 308     (define-key map (kbd "M-TAB") (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 309     (define-key map (kbd "<backtab>")  (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 310     (define-key map (kbd "TAB") (notmuch-tree-to-message-pane #'notmuch-show-next-button))
 311     (define-key map "$" (notmuch-tree-to-message-pane #'notmuch-show-toggle-process-crypto))
 312
 313     ;; bindings from show (or elsewhere) but we close the message pane first.
 314     (define-key map "f" (notmuch-tree-close-message-pane-and #'notmuch-show-forward-message))
 315     (define-key map "r" (notmuch-tree-close-message-pane-and #'notmuch-show-reply-sender))
 316     (define-key map "R" (notmuch-tree-close-message-pane-and #'notmuch-show-reply))
 317     (define-key map "V" (notmuch-tree-close-message-pane-and #'notmuch-show-view-raw-message))
 318
 319     ;; The main tree view bindings
 320     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 321     (define-key map [mouse-1] 'notmuch-tree-show-message)
 322     (define-key map "x" 'notmuch-tree-quit)
 323     (define-key map "A" 'notmuch-tree-archive-thread)
 324     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 325     (define-key map "z" 'notmuch-tree-to-tree)
 326     (define-key map "n" 'notmuch-tree-next-matching-message)
 327     (define-key map "p" 'notmuch-tree-prev-matching-message)
 328     (define-key map "N" 'notmuch-tree-next-message)
 329     (define-key map "P" 'notmuch-tree-prev-message)
 330     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 331     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 332     (define-key map "k" 'notmuch-tag-jump)
 333     (define-key map "-" 'notmuch-tree-remove-tag)
 334     (define-key map "+" 'notmuch-tree-add-tag)
 335     (define-key map "*" 'notmuch-tree-tag-thread)
 336     (define-key map " " 'notmuch-tree-scroll-or-next)
 337     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 338     (define-key map "e" 'notmuch-tree-resume-message)
 339     map))
 340 (fset 'notmuch-tree-mode-map notmuch-tree-mode-map)
 341
 342 (defun notmuch-tree-get-message-properties ()
 343   "Return the properties of the current message as a plist.
 344
 345 Some useful entries are:
 346 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 347 :tags - Tags for this message"
 348   (save-excursion
 349     (beginning-of-line)
 350     (get-text-property (point) :notmuch-message-properties)))
 351
 352 (defun notmuch-tree-set-message-properties (props)
 353   (save-excursion
 354     (beginning-of-line)
 355     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 356
 357 (defun notmuch-tree-set-prop (prop val &optional props)
 358   (let ((inhibit-read-only t)
 359         (props (or props
 360                    (notmuch-tree-get-message-properties))))
 361     (plist-put props prop val)
 362     (notmuch-tree-set-message-properties props)))
 363
 364 (defun notmuch-tree-get-prop (prop &optional props)
 365   (let ((props (or props
 366                    (notmuch-tree-get-message-properties))))
 367     (plist-get props prop)))
 368
 369 (defun notmuch-tree-set-tags (tags)
 370   "Set the tags of the current message."
 371   (notmuch-tree-set-prop :tags tags))
 372
 373 (defun notmuch-tree-get-tags ()
 374   "Return the tags of the current message."
 375   (notmuch-tree-get-prop :tags))
 376
 377 (defun notmuch-tree-get-message-id (&optional bare)
 378   "Return the message id of the current message."
 379   (let ((id (notmuch-tree-get-prop :id)))
 380     (if id
 381         (if bare
 382             id
 383           (notmuch-id-to-query id))
 384       nil)))
 385
 386 (defun notmuch-tree-get-match ()
 387   "Return whether the current message is a match."
 388   (interactive)
 389   (notmuch-tree-get-prop :match))
 390
 391 (defun notmuch-tree-refresh-result ()
 392   "Redisplay the current message line.
 393
 394 This redisplays the current line based on the messages
 395 properties (as they are now). This is used when tags are
 396 updated."
 397   (let ((init-point (point))
 398         (end (line-end-position))
 399         (msg (notmuch-tree-get-message-properties))
 400         (inhibit-read-only t))
 401     (beginning-of-line)
 402     ;; This is a little tricky: we override
 403     ;; notmuch-tree-previous-subject to get the decision between
 404     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 405     ;; from overwriting the buffer local copy of
 406     ;; notmuch-tree-previous-subject if this is called while the
 407     ;; buffer is displaying.
 408     (let ((notmuch-tree-previous-subject (notmuch-tree-get-prop :previous-subject)))
 409       (delete-region (point) (1+ (line-end-position)))
 410       (notmuch-tree-insert-msg msg))
 411     (let ((new-end (line-end-position)))
 412       (goto-char (if (= init-point end)
 413                      new-end
 414                    (min init-point (- new-end 1)))))))
 415
 416 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 417   "Update display for TAG-CHANGES to current message.
 418
 419 Updates the message in the message pane if appropriate, but does
 420 NOT change the database."
 421   (let* ((current-tags (notmuch-tree-get-tags))
 422          (new-tags (notmuch-update-tags current-tags tag-changes))
 423          (tree-msg-id (notmuch-tree-get-message-id)))
 424     (unless (equal current-tags new-tags)
 425       (notmuch-tree-set-tags new-tags)
 426       (notmuch-tree-refresh-result)
 427       (when (window-live-p notmuch-tree-message-window)
 428         (with-selected-window notmuch-tree-message-window
 429           (when (string= tree-msg-id (notmuch-show-get-message-id))
 430             (notmuch-show-update-tags new-tags)))))))
 431
 432 (defun notmuch-tree-tag (tag-changes)
 433   "Change tags for the current message"
 434   (interactive
 435    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 436   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 437   (notmuch-tree-tag-update-display tag-changes))
 438
 439 (defun notmuch-tree-add-tag (tag-changes)
 440   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 441   (interactive
 442    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 443   (notmuch-tree-tag tag-changes))
 444
 445 (defun notmuch-tree-remove-tag (tag-changes)
 446   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 447   (interactive
 448    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 449   (notmuch-tree-tag tag-changes))
 450
 451 (defun notmuch-tree-resume-message ()
 452   "Resume EDITING the current draft message."
 453   (interactive)
 454   (notmuch-tree-close-message-window)
 455   (let ((id (notmuch-tree-get-message-id)))
 456     (if id
 457         (notmuch-draft-resume id)
 458       (message "No message to resume!"))))
 459
 460 ;; The next two functions close the message window before calling
 461 ;; notmuch-search or notmuch-tree but they do so after the user has
 462 ;; entered the query (in case the user was basing the query on
 463 ;; something in the message window).
 464
 465 (defun notmuch-tree-to-search ()
 466   "Run \"notmuch search\" with the given `query' and display results."
 467   (interactive)
 468   (let ((query (notmuch-read-query "Notmuch search: ")))
 469     (notmuch-tree-close-message-window)
 470     (notmuch-search query)))
 471
 472 (defun notmuch-tree-to-tree ()
 473   "Run a query and display results in Tree view"
 474   (interactive)
 475   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 476     (notmuch-tree-close-message-window)
 477     (notmuch-tree query)))
 478
 479 (defun notmuch-unthreaded-from-tree-current-query ()
 480   "Switch from tree view to unthreaded view"
 481   (interactive)
 482   (unless notmuch-tree-unthreaded
 483     (notmuch-tree-refresh-view 'unthreaded)))
 484
 485 (defun notmuch-tree-from-unthreaded-current-query ()
 486   "Switch from unthreaded view to tree view"
 487   (interactive)
 488   (when notmuch-tree-unthreaded
 489     (notmuch-tree-refresh-view 'tree)))
 490
 491 (defun notmuch-search-from-tree-current-query ()
 492   "Call notmuch search with the current query"
 493   (interactive)
 494   (notmuch-tree-close-message-window)
 495   (notmuch-search (notmuch-tree-get-query)))
 496
 497 (defun notmuch-tree-message-window-kill-hook ()
 498   "Close the message pane when exiting the show buffer."
 499   (let ((buffer (current-buffer)))
 500     (when (and (window-live-p notmuch-tree-message-window)
 501                (eq (window-buffer notmuch-tree-message-window) buffer))
 502       ;; We do not want an error if this is the sole window in the
 503       ;; frame and I do not know how to test for that in emacs pre
 504       ;; 24. Hence we just ignore-errors.
 505       (ignore-errors
 506         (delete-window notmuch-tree-message-window)))))
 507
 508 (defun notmuch-tree-command-hook ()
 509   (when (eq major-mode 'notmuch-tree-mode)
 510     ;; We just run the notmuch-show-command-hook on the message pane.
 511     (when (buffer-live-p notmuch-tree-message-buffer)
 512       (with-current-buffer notmuch-tree-message-buffer
 513         (notmuch-show-command-hook)))))
 514
 515 (defun notmuch-tree-show-message-in ()
 516   "Show the current message (in split-pane)."
 517   (interactive)
 518   (let ((id (notmuch-tree-get-message-id))
 519         (inhibit-read-only t)
 520         buffer)
 521     (when id
 522       ;; We close and reopen the window to kill off un-needed buffers
 523       ;; this might cause flickering but seems ok.
 524       (notmuch-tree-close-message-window)
 525       (setq notmuch-tree-message-window
 526             (split-window-vertically (/ (window-height) 4)))
 527       (with-selected-window notmuch-tree-message-window
 528         ;; Since we are only displaying one message do not indent.
 529         (let ((notmuch-show-indent-messages-width 0)
 530               (notmuch-show-only-matching-messages t))
 531           (setq buffer (notmuch-show id))))
 532       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 533       (let ((window notmuch-tree-message-window))
 534         (with-current-buffer buffer
 535           (setq notmuch-tree-message-window window)
 536           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 537       (when notmuch-show-mark-read-tags
 538         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 539       (setq notmuch-tree-message-buffer buffer))))
 540
 541 (defun notmuch-tree-show-message-out ()
 542   "Show the current message (in whole window)."
 543   (interactive)
 544   (let ((id (notmuch-tree-get-message-id))
 545         (inhibit-read-only t)
 546         buffer)
 547     (when id
 548       ;; We close the window to kill off un-needed buffers.
 549       (notmuch-tree-close-message-window)
 550       (notmuch-show id))))
 551
 552 (defun notmuch-tree-show-message (arg)
 553   "Show the current message.
 554
 555 Shows in split pane or whole window according to value of
 556 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 557   (interactive "P")
 558   (if (or (and (notmuch-tree-show-out) (not arg))
 559           (and (not (notmuch-tree-show-out)) arg))
 560       (notmuch-tree-show-message-out)
 561     (notmuch-tree-show-message-in)))
 562
 563 (defun notmuch-tree-scroll-message-window ()
 564   "Scroll the message window (if it exists)"
 565   (interactive)
 566   (when (window-live-p notmuch-tree-message-window)
 567     (with-selected-window notmuch-tree-message-window
 568       (if (pos-visible-in-window-p (point-max))
 569           t
 570         (scroll-up)))))
 571
 572 (defun notmuch-tree-scroll-message-window-back ()
 573   "Scroll the message window back(if it exists)"
 574   (interactive)
 575   (when (window-live-p notmuch-tree-message-window)
 576     (with-selected-window notmuch-tree-message-window
 577       (if (pos-visible-in-window-p (point-min))
 578           t
 579         (scroll-down)))))
 580
 581 (defun notmuch-tree-scroll-or-next ()
 582   "Scroll the message window. If it at end go to next message."
 583   (interactive)
 584   (when (notmuch-tree-scroll-message-window)
 585     (notmuch-tree-next-matching-message)))
 586
 587 (defun notmuch-tree-quit (&optional kill-both)
 588   "Close the split view or exit tree."
 589   (interactive "P")
 590   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 591     (kill-buffer (current-buffer))))
 592
 593 (defun notmuch-tree-close-message-window ()
 594   "Close the message-window. Return t if close succeeds."
 595   (interactive)
 596   (when (and (window-live-p notmuch-tree-message-window)
 597              (eq (window-buffer notmuch-tree-message-window) notmuch-tree-message-buffer))
 598     (delete-window notmuch-tree-message-window)
 599     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 600       (kill-buffer notmuch-tree-message-buffer))
 601     t))
 602
 603 (defun notmuch-tree-archive-message (&optional unarchive)
 604   "Archive the current message.
 605
 606 Archive the current message by applying the tag changes in
 607 `notmuch-archive-tags' to it. If a prefix argument is given, the
 608 message will be \"unarchived\", i.e. the tag changes in
 609 `notmuch-archive-tags' will be reversed."
 610   (interactive "P")
 611   (when notmuch-archive-tags
 612     (notmuch-tree-tag (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 613
 614 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 615   "Archive the current message and move to next matching message."
 616   (interactive "P")
 617   (notmuch-tree-archive-message unarchive)
 618   (notmuch-tree-next-matching-message))
 619
 620 (defun notmuch-tree-archive-message-then-next-or-exit ()
 621   "Archive current message, then show next open message in current thread.
 622
 623 If at the last open message in the current thread, then exit back
 624 to search results."
 625   (interactive)
 626   (notmuch-tree-archive-message)
 627   (notmuch-tree-next-matching-message t))
 628
 629 (defun notmuch-tree-next-message ()
 630   "Move to next message."
 631   (interactive)
 632   (forward-line)
 633   (when (window-live-p notmuch-tree-message-window)
 634     (notmuch-tree-show-message-in)))
 635
 636 (defun notmuch-tree-prev-message ()
 637   "Move to previous message."
 638   (interactive)
 639   (forward-line -1)
 640   (when (window-live-p notmuch-tree-message-window)
 641     (notmuch-tree-show-message-in)))
 642
 643 (defun notmuch-tree-goto-matching-message (&optional prev)
 644   "Move to the next or previous matching message.
 645
 646 Returns t if there was a next matching message in the thread to show,
 647 nil otherwise."
 648   (let ((dir (if prev -1 nil))
 649         (eobfn (if prev #'bobp #'eobp)))
 650     (while (and (not (funcall eobfn))
 651                 (not (notmuch-tree-get-match)))
 652       (forward-line dir))
 653     (not (funcall eobfn))))
 654
 655 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 656   "Move to the next or previous matching message"
 657   (interactive "P")
 658   (forward-line (if prev -1 nil))
 659   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 660       (notmuch-tree-quit pop-at-end)
 661     (when (window-live-p notmuch-tree-message-window)
 662       (notmuch-tree-show-message-in))))
 663
 664 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 665   "Move to previous matching message."
 666   (interactive "P")
 667   (notmuch-tree-matching-message t pop-at-end))
 668
 669 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 670   "Move to next matching message."
 671   (interactive "P")
 672   (notmuch-tree-matching-message nil pop-at-end))
 673
 674 (defun notmuch-tree-refresh-view (&optional view)
 675   "Refresh view."
 676   (interactive)
 677   (when (get-buffer-process (current-buffer))
 678     (error "notmuch tree process already running for current buffer"))
 679   (let ((inhibit-read-only t)
 680         (basic-query notmuch-tree-basic-query)
 681         (unthreaded (cond ((eq view 'unthreaded) t)
 682                           ((eq view 'tree) nil)
 683                           (t notmuch-tree-unthreaded)))
 684         (query-context notmuch-tree-query-context)
 685         (target (notmuch-tree-get-message-id)))
 686     (erase-buffer)
 687     (notmuch-tree-worker basic-query
 688                          query-context
 689                          target
 690                          nil
 691                          unthreaded)))
 692
 693 (defun notmuch-tree-thread-top ()
 694   (when (notmuch-tree-get-message-properties)
 695     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 696       (forward-line -1))))
 697
 698 (defun notmuch-tree-prev-thread ()
 699   (interactive)
 700   (forward-line -1)
 701   (notmuch-tree-thread-top))
 702
 703 (defun notmuch-tree-next-thread ()
 704   "Get the next thread in the current tree. Returns t if a thread was
 705 found or nil if not."
 706   (interactive)
 707   (forward-line 1)
 708   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 709     (forward-line 1))
 710   (not (eobp)))
 711
 712 (defun notmuch-tree-thread-mapcar (function)
 713   "Iterate through all messages in the current thread
 714  and call FUNCTION for side effects."
 715   (save-excursion
 716     (notmuch-tree-thread-top)
 717     (loop collect (funcall function)
 718           do (forward-line)
 719           while (and (notmuch-tree-get-message-properties)
 720                      (not (notmuch-tree-get-prop :first))))))
 721
 722 (defun notmuch-tree-get-messages-ids-thread-search ()
 723   "Return a search string for all message ids of messages in the current thread."
 724   (mapconcat 'identity
 725              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 726              " or "))
 727
 728 (defun notmuch-tree-tag-thread (tag-changes)
 729   "Tag all messages in the current thread"
 730   (interactive
 731    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 732                                 (lambda () (notmuch-tree-get-tags))))))
 733      (list (notmuch-read-tag-changes tags "Tag thread"))))
 734   (when (notmuch-tree-get-message-properties)
 735     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 736     (notmuch-tree-thread-mapcar
 737      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 738
 739 (defun notmuch-tree-archive-thread (&optional unarchive)
 740   "Archive each message in thread.
 741
 742 Archive each message currently shown by applying the tag changes
 743 in `notmuch-archive-tags' to each. If a prefix argument is given,
 744 the messages will be \"unarchived\", i.e. the tag changes in
 745 `notmuch-archive-tags' will be reversed.
 746
 747 Note: This command is safe from any race condition of new messages
 748 being delivered to the same thread. It does not archive the
 749 entire thread, but only the messages shown in the current
 750 buffer."
 751   (interactive "P")
 752   (when notmuch-archive-tags
 753     (notmuch-tree-tag-thread
 754      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 755
 756 ;; Functions below here display the tree buffer itself.
 757
 758 (defun notmuch-tree-clean-address (address)
 759   "Try to clean a single email ADDRESS for display. Return
 760 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 761 unchanged ADDRESS if parsing fails."
 762   (let* ((clean-address (notmuch-clean-address address))
 763          (p-address (car clean-address))
 764          (p-name (cdr clean-address)))
 765
 766     ;; If we have a name return that otherwise return the address.
 767     (or p-name p-address)))
 768
 769 (defun notmuch-tree-format-field (field format-string msg)
 770   "Format a FIELD of MSG according to FORMAT-STRING and return string"
 771   (let* ((headers (plist-get msg :headers))
 772          (match (plist-get msg :match)))
 773     (cond
 774      ((listp field)
 775       (format format-string (notmuch-tree-format-field-list field msg)))
 776
 777      ((string-equal field "date")
 778       (let ((face (if match
 779                       'notmuch-tree-match-date-face
 780                     'notmuch-tree-no-match-date-face)))
 781         (propertize (format format-string (plist-get msg :date_relative)) 'face face)))
 782
 783      ((string-equal field "tree")
 784       (let ((tree-status (plist-get msg :tree-status))
 785             (face (if match
 786                       'notmuch-tree-match-tree-face
 787                     'notmuch-tree-no-match-tree-face)))
 788
 789         (propertize (format format-string
 790                             (mapconcat #'identity (reverse tree-status) ""))
 791                     'face face)))
 792
 793      ((string-equal field "subject")
 794       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 795             (previous-subject notmuch-tree-previous-subject)
 796             (face (if match
 797                       'notmuch-tree-match-subject-face
 798                     'notmuch-tree-no-match-subject-face)))
 799
 800         (setq notmuch-tree-previous-subject bare-subject)
 801         (propertize (format format-string
 802                             (if (string= previous-subject bare-subject)
 803                                 " ..."
 804                               bare-subject))
 805                     'face face)))
 806
 807      ((string-equal field "authors")
 808       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 809             (len (length (format format-string "")))
 810             (face (if match
 811                       'notmuch-tree-match-author-face
 812                     'notmuch-tree-no-match-author-face)))
 813         (when (> (length author) len)
 814           (setq author (substring author 0 len)))
 815         (propertize (format format-string author) 'face face)))
 816
 817      ((string-equal field "tags")
 818       (let ((tags (plist-get msg :tags))
 819             (orig-tags (plist-get msg :orig-tags))
 820             (face (if match
 821                       'notmuch-tree-match-tag-face
 822                     'notmuch-tree-no-match-tag-face)))
 823         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 824
 825 (defun notmuch-tree-format-field-list (field-list msg)
 826   "Format fields of MSG according to FIELD-LIST and return string"
 827   (let ((face (if (plist-get msg :match)
 828                   'notmuch-tree-match-face
 829                 'notmuch-tree-no-match-face))
 830         (result-string))
 831     (dolist (spec field-list result-string)
 832       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 833         (setq result-string (concat result-string field-string))))
 834     (notmuch-apply-face result-string face t)))
 835
 836 (defun notmuch-tree-insert-msg (msg)
 837   "Insert the message MSG according to notmuch-tree-result-format"
 838   ;; We need to save the previous subject as it will get overwritten
 839   ;; by the insert-field calls.
 840   (let ((previous-subject notmuch-tree-previous-subject))
 841     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 842     (notmuch-tree-set-message-properties msg)
 843     (notmuch-tree-set-prop :previous-subject previous-subject)
 844     (insert "\n")))
 845
 846 (defun notmuch-tree-goto-and-insert-msg (msg)
 847   "Insert msg at the end of the buffer. Move point to msg if it is the target"
 848   (save-excursion
 849     (goto-char (point-max))
 850     (notmuch-tree-insert-msg msg))
 851   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 852         (target notmuch-tree-target-msg))
 853     (when (or (and (not target) (plist-get msg :match))
 854               (string= msg-id target))
 855       (setq notmuch-tree-target-msg "found")
 856       (goto-char (point-max))
 857       (forward-line -1)
 858       (when notmuch-tree-open-target
 859         (notmuch-tree-show-message-in)))))
 860
 861 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 862   "Insert the message tree TREE at depth DEPTH in the current thread.
 863
 864 A message tree is another name for a single sub-thread: i.e., a
 865 message together with all its descendents."
 866   (let ((msg (car tree))
 867         (replies (cadr tree)))
 868
 869       (cond
 870        ((and (< 0 depth) (not last))
 871         (push "├" tree-status))
 872        ((and (< 0 depth) last)
 873         (push "╰" tree-status))
 874        ((and (eq 0 depth) first last)
 875 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
 876         (push " " tree-status))
 877        ((and (eq 0 depth) first (not last))
 878           (push "┬" tree-status))
 879        ((and (eq 0 depth) (not first) last)
 880         (push "╰" tree-status))
 881        ((and (eq 0 depth) (not first) (not last))
 882         (push "├" tree-status)))
 883
 884       (push (concat (if replies "┬" "─") "►") tree-status)
 885       (setq msg (plist-put msg :first (and first (eq 0 depth))))
 886       (setq msg (plist-put msg :tree-status tree-status))
 887       (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 888       (notmuch-tree-goto-and-insert-msg msg)
 889       (pop tree-status)
 890       (pop tree-status)
 891
 892       (if last
 893           (push " " tree-status)
 894         (push "│" tree-status))
 895
 896     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 897
 898 (defun notmuch-tree-insert-thread (thread depth tree-status)
 899   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 900   (let ((n (length thread)))
 901     (loop for tree in thread
 902           for count from 1 to n
 903
 904           do (notmuch-tree-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
 905
 906 (defun notmuch-tree-insert-forest-thread (forest-thread)
 907   "Insert a single complete thread."
 908   (let (tree-status)
 909     ;; Reset at the start of each main thread.
 910     (setq notmuch-tree-previous-subject nil)
 911     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
 912
 913 (defun notmuch-tree-insert-forest (forest)
 914   "Insert a forest of threads.
 915
 916 This function inserts a collection of several complete threads as
 917 passed to it by notmuch-tree-process-filter."
 918   (mapc 'notmuch-tree-insert-forest-thread forest))
 919
 920 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
 921   "Major mode displaying messages (as opposed to threads) of a notmuch search.
 922
 923 This buffer contains the results of a \"notmuch tree\" of your
 924 email archives. Each line in the buffer represents a single
 925 message giving the relative date, the author, subject, and any
 926 tags.
 927
 928 Pressing \\[notmuch-tree-show-message] on any line displays that message.
 929
 930 Complete list of currently available key bindings:
 931
 932 \\{notmuch-tree-mode-map}"
 933
 934   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
 935   (hl-line-mode 1)
 936   (setq buffer-read-only t
 937         truncate-lines t))
 938
 939 (defun notmuch-tree-process-sentinel (proc msg)
 940   "Add a message to let user know when \"notmuch tree\" exits"
 941   (let ((buffer (process-buffer proc))
 942         (status (process-status proc))
 943         (exit-status (process-exit-status proc))
 944         (never-found-target-thread nil))
 945     (when (memq status '(exit signal))
 946         (kill-buffer (process-get proc 'parse-buf))
 947         (if (buffer-live-p buffer)
 948             (with-current-buffer buffer
 949               (save-excursion
 950                 (let ((inhibit-read-only t)
 951                       (atbob (bobp)))
 952                   (goto-char (point-max))
 953                   (if (eq status 'signal)
 954                       (insert "Incomplete search results (tree view process was killed).\n"))
 955                   (when (eq status 'exit)
 956                     (insert "End of search results.")
 957                     (unless (= exit-status 0)
 958                       (insert (format " (process returned %d)" exit-status)))
 959                     (insert "\n")))))))))
 960
 961 (defun notmuch-tree-process-filter (proc string)
 962   "Process and filter the output of \"notmuch show\" for tree view"
 963   (let ((results-buf (process-buffer proc))
 964         (parse-buf (process-get proc 'parse-buf))
 965         (inhibit-read-only t)
 966         done)
 967     (if (not (buffer-live-p results-buf))
 968         (delete-process proc)
 969       (with-current-buffer parse-buf
 970         ;; Insert new data
 971         (save-excursion
 972           (goto-char (point-max))
 973           (insert string))
 974         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
 975                                          results-buf)))))
 976
 977 (defun notmuch-tree-worker (basic-query &optional query-context target open-target unthreaded)
 978   "Insert the tree view of the search in the current buffer.
 979
 980 This is is a helper function for notmuch-tree. The arguments are
 981 the same as for the function notmuch-tree."
 982   (interactive)
 983   (notmuch-tree-mode)
 984   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
 985   (setq notmuch-tree-unthreaded unthreaded)
 986   (setq notmuch-tree-basic-query basic-query)
 987   (setq notmuch-tree-query-context (if (or (string= query-context "")
 988                                            (string= query-context "*"))
 989                                        nil query-context))
 990   (setq notmuch-tree-target-msg target)
 991   (setq notmuch-tree-open-target open-target)
 992   ;; Set the default value for `notmuch-show-process-crypto' in this
 993   ;; buffer. Although we don't use this some of the functions we call
 994   ;; (such as reply) do. It is a buffer local variable so setting it
 995   ;; will not affect genuine show buffers.
 996   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
 997
 998   (erase-buffer)
 999   (goto-char (point-min))
1000   (let* ((search-args (concat basic-query
1001                        (if query-context (concat " and (" query-context ")"))
1002                        ))
1003          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1004     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
1005         (setq search-args basic-query))
1006     (notmuch-tag-clear-cache)
1007     (let ((proc (notmuch-start-notmuch
1008                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1009                  "show" "--body=false" "--format=sexp" "--format-version=4"
1010                  message-arg search-args))
1011           ;; Use a scratch buffer to accumulate partial output.
1012           ;; This buffer will be killed by the sentinel, which
1013           ;; should be called no matter how the process dies.
1014           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1015       (process-put proc 'parse-buf parse-buf)
1016       (set-process-filter proc 'notmuch-tree-process-filter)
1017       (set-process-query-on-exit-flag proc nil))))
1018
1019 (defun notmuch-tree-get-query ()
1020   "Return the current query in this tree buffer"
1021   (if notmuch-tree-query-context
1022       (concat notmuch-tree-basic-query
1023               " and ("
1024               notmuch-tree-query-context
1025               ")")
1026     notmuch-tree-basic-query))
1027
1028 (defun notmuch-tree (&optional query query-context target buffer-name open-target unthreaded)
1029   "Display threads matching QUERY in Tree View.
1030
1031 The arguments are:
1032   QUERY: the main query. This can be any query but in many cases will be
1033       a single thread. If nil this is read interactively from the minibuffer.
1034   QUERY-CONTEXT: is an additional term for the query. The query used
1035       is QUERY and QUERY-CONTEXT unless that does not match any messages
1036       in which case we fall back to just QUERY.
1037   TARGET: A message ID (with the id: prefix) that will be made
1038       current if it appears in the tree view results.
1039   BUFFER-NAME: the name of the buffer to display the tree view. If
1040       it is nil \"*notmuch-tree\" followed by QUERY is used.
1041   OPEN-TARGET: If TRUE open the target message in the message pane.
1042   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1043   (interactive)
1044   (if (null query)
1045       (setq query (notmuch-read-query (concat "Notmuch "
1046                                               (if unthreaded "unthreaded " "tree ")
1047                                               "view search: "))))
1048   (let ((buffer (get-buffer-create (generate-new-buffer-name
1049                                     (or buffer-name
1050                                         (concat "*notmuch-"
1051                                                 (if unthreaded "unthreaded-" "tree-")
1052                                                 query "*")))))
1053         (inhibit-read-only t))
1054
1055     (switch-to-buffer buffer))
1056   ;; Don't track undo information for this buffer
1057   (set 'buffer-undo-list t)
1058
1059   (notmuch-tree-worker query query-context target open-target unthreaded)
1060
1061   (setq truncate-lines t))
1062
1063 (defun notmuch-unthreaded (&optional query query-context target buffer-name open-target)
1064   (interactive)
1065   (notmuch-tree query query-context target buffer-name open-target t))
1066
1067 ;;
1068
1069 (provide 'notmuch-tree)
1070
1071 ;;; notmuch-tree.el ends here