git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl-lib))
  28
  29 (require 'mail-parse)
  30
  31 (require 'notmuch-lib)
  32 (require 'notmuch-query)
  33 (require 'notmuch-show)
  34 (require 'notmuch-tag)
  35 (require 'notmuch-parser)
  36 (require 'notmuch-jump)
  37
  38 (declare-function notmuch-search "notmuch"
  39                   (&optional query oldest-first target-thread target-line))
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-read-query "notmuch" (prompt))
  42 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  43 (declare-function notmuch-search-find-subject "notmuch" ())
  44
  45 ;; For `notmuch-tree-next-thread-from-search'.
  46 (declare-function notmuch-search-next-thread "notmuch" ())
  47 (declare-function notmuch-search-previous-thread "notmuch" ())
  48 (declare-function notmuch-tree-from-search-thread "notmuch" ())
  49
  50 ;; the following variable is defined in notmuch.el
  51 (defvar notmuch-search-query-string)
  52
  53 ;; this variable distinguishes the unthreaded display from the normal tree display
  54 (defvar-local notmuch-tree-unthreaded nil
  55   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  56
  57 ;;; Options
  58
  59 (defgroup notmuch-tree nil
  60   "Showing message and thread structure."
  61   :group 'notmuch)
  62
  63 (defcustom notmuch-tree-show-out nil
  64   "View selected messages in new window rather than split-pane."
  65   :type 'boolean
  66   :group 'notmuch-tree)
  67
  68 (defcustom notmuch-unthreaded-show-out t
  69   "View selected messages in new window rather than split-pane."
  70   :type 'boolean
  71   :group 'notmuch-tree)
  72
  73 (defun notmuch-tree-show-out ()
  74   (if notmuch-tree-unthreaded
  75       notmuch-unthreaded-show-out
  76     notmuch-tree-show-out))
  77
  78 (defcustom notmuch-tree-result-format
  79   `(("date" . "%12s  ")
  80     ("authors" . "%-20s")
  81     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  82     ("tags" . "(%s)"))
  83   "Result formatting for tree view. Supported fields are: date,
  84 authors, subject, tree, tags.  Tree means the thread tree
  85 box graphics. The field may also be a list in which case
  86 the formatting rules are applied recursively and then the
  87 output of all the fields in the list is inserted
  88 according to format-string.
  89
  90 Note the author string should not contain
  91 whitespace (put it in the neighbouring fields instead).
  92 For example:
  93         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  94                                           \(\"subject\" . \"%s\"\)\)\)"
  95   :type '(alist :key-type (string) :value-type (string))
  96   :group 'notmuch-tree)
  97
  98 (defcustom notmuch-unthreaded-result-format
  99   `(("date" . "%12s  ")
 100     ("authors" . "%-20s")
 101     ((("subject" . "%s")) ." %-54s ")
 102     ("tags" . "(%s)"))
 103   "Result formatting for unthreaded tree view. Supported fields are: date,
 104 authors, subject, tree, tags.  Tree means the thread tree
 105 box graphics. The field may also be a list in which case
 106 the formatting rules are applied recursively and then the
 107 output of all the fields in the list is inserted
 108 according to format-string.
 109
 110 Note the author string should not contain
 111 whitespace (put it in the neighbouring fields instead).
 112 For example:
 113         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 114                                           \(\"subject\" . \"%s\"\)\)\)"
 115   :type '(alist :key-type (string) :value-type (string))
 116   :group 'notmuch-tree)
 117
 118 (defun notmuch-tree-result-format ()
 119   (if notmuch-tree-unthreaded
 120       notmuch-unthreaded-result-format
 121     notmuch-tree-result-format))
 122
 123 ;;; Faces
 124 ;;;; Faces for messages that match the query
 125
 126 (defface notmuch-tree-match-face
 127   '((t :inherit default))
 128   "Default face used in tree mode face for matching messages"
 129   :group 'notmuch-tree
 130   :group 'notmuch-faces)
 131
 132 (defface notmuch-tree-match-date-face
 133   nil
 134   "Face used in tree mode for the date in messages matching the query."
 135   :group 'notmuch-tree
 136   :group 'notmuch-faces)
 137
 138 (defface notmuch-tree-match-author-face
 139   '((((class color)
 140       (background dark))
 141      (:foreground "OliveDrab1"))
 142     (((class color)
 143       (background light))
 144      (:foreground "dark blue"))
 145     (t
 146      (:bold t)))
 147   "Face used in tree mode for the date in messages matching the query."
 148   :group 'notmuch-tree
 149   :group 'notmuch-faces)
 150
 151 (defface notmuch-tree-match-subject-face
 152   nil
 153   "Face used in tree mode for the subject in messages matching the query."
 154   :group 'notmuch-tree
 155   :group 'notmuch-faces)
 156
 157 (defface notmuch-tree-match-tree-face
 158   nil
 159   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 160   :group 'notmuch-tree
 161   :group 'notmuch-faces)
 162
 163 (defface notmuch-tree-match-tag-face
 164   '((((class color)
 165       (background dark))
 166      (:foreground "OliveDrab1"))
 167     (((class color)
 168       (background light))
 169      (:foreground "navy blue" :bold t))
 170     (t
 171      (:bold t)))
 172   "Face used in tree mode for tags in messages matching the query."
 173   :group 'notmuch-tree
 174   :group 'notmuch-faces)
 175
 176 ;;;; Faces for messages that do not match the query
 177
 178 (defface notmuch-tree-no-match-face
 179   '((t (:foreground "gray")))
 180   "Default face used in tree mode face for non-matching messages."
 181   :group 'notmuch-tree
 182   :group 'notmuch-faces)
 183
 184 (defface notmuch-tree-no-match-date-face
 185   nil
 186   "Face used in tree mode for non-matching dates."
 187   :group 'notmuch-tree
 188   :group 'notmuch-faces)
 189
 190 (defface notmuch-tree-no-match-subject-face
 191   nil
 192   "Face used in tree mode for non-matching subjects."
 193   :group 'notmuch-tree
 194   :group 'notmuch-faces)
 195
 196 (defface notmuch-tree-no-match-tree-face
 197   nil
 198   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 199   :group 'notmuch-tree
 200   :group 'notmuch-faces)
 201
 202 (defface notmuch-tree-no-match-author-face
 203   nil
 204   "Face used in tree mode for the date in messages matching the query."
 205   :group 'notmuch-tree
 206   :group 'notmuch-faces)
 207
 208 (defface notmuch-tree-no-match-tag-face
 209   nil
 210   "Face used in tree mode face for non-matching tags."
 211   :group 'notmuch-tree
 212   :group 'notmuch-faces)
 213
 214 ;;; Variables
 215
 216 (defvar-local notmuch-tree-previous-subject
 217   "The subject of the most recent result shown during the async display.")
 218
 219 (defvar-local notmuch-tree-basic-query nil
 220   "A buffer local copy of argument query to the function notmuch-tree.")
 221
 222 (defvar-local notmuch-tree-query-context nil
 223   "A buffer local copy of argument query-context to the function notmuch-tree.")
 224
 225 (defvar-local notmuch-tree-target-msg nil
 226   "A buffer local copy of argument target to the function notmuch-tree.")
 227
 228 (defvar-local notmuch-tree-open-target nil
 229   "A buffer local copy of argument open-target to the function notmuch-tree.")
 230
 231 (defvar-local notmuch-tree-parent-buffer nil)
 232
 233 (defvar-local notmuch-tree-message-window nil
 234   "The window of the message pane.
 235
 236 It is set in both the tree buffer and the child show buffer. It
 237 is used to try and close the message pane when quitting tree view
 238 or the child show buffer.")
 239 (put 'notmuch-tree-message-window 'permanent-local t)
 240
 241 (defvar-local notmuch-tree-message-buffer nil
 242   "The buffer name of the show buffer in the message pane.
 243
 244 This is used to try and make sure we don't close the message pane
 245 if the user has loaded a different buffer in that window.")
 246 (put 'notmuch-tree-message-buffer 'permanent-local t)
 247
 248 ;;; Tree wrapper commands
 249
 250 (defmacro notmuch-tree--define-do-in-message-window (name cmd)
 251   "Define NAME as a command that calls CMD interactively in the message window.
 252 If the message pane is closed then this command does nothing.
 253 Avoid using this macro in new code; it will be removed."
 254   `(defun ,name ()
 255      ,(concat "(In message window) " (documentation cmd t))
 256      (interactive)
 257      (when (window-live-p notmuch-tree-message-window)
 258        (with-selected-window notmuch-tree-message-window
 259          (call-interactively #',cmd)))))
 260
 261 (notmuch-tree--define-do-in-message-window
 262  notmuch-tree-previous-message-button
 263  notmuch-show-previous-button)
 264 (notmuch-tree--define-do-in-message-window
 265  notmuch-tree-next-message-button
 266  notmuch-show-next-button)
 267 (notmuch-tree--define-do-in-message-window
 268  notmuch-tree-toggle-message-process-crypto
 269  notmuch-show-toggle-process-crypto)
 270
 271 (defun notmuch-tree--message-process-crypto ()
 272   "Return value of `notmuch-show-process-crypto' in the message window.
 273 If that window isn't alive, then return the current value.
 274 Avoid using this function in new code; it will be removed."
 275   (if (window-live-p notmuch-tree-message-window)
 276       (with-selected-window notmuch-tree-message-window
 277         notmuch-show-process-crypto)
 278     notmuch-show-process-crypto))
 279
 280 (defmacro notmuch-tree--define-close-message-window-and (name cmd)
 281   "Define NAME as a variant of CMD.
 282
 283 NAME determines the value of `notmuch-show-process-crypto' in the
 284 message window, closes the window, and then call CMD interactively
 285 with that value let-bound.  If the message window does not exist,
 286 then NAME behaves like CMD."
 287   `(defun ,name ()
 288      ,(concat "(Close message pane and) " (documentation cmd t))
 289      (interactive)
 290      (let ((notmuch-show-process-crypto
 291             (notmuch-tree--message-process-crypto)))
 292        (notmuch-tree-close-message-window)
 293        (call-interactively #',cmd))))
 294
 295 (notmuch-tree--define-close-message-window-and
 296  notmuch-tree-help
 297  notmuch-help)
 298 (notmuch-tree--define-close-message-window-and
 299  notmuch-tree-new-mail
 300  notmuch-mua-new-mail)
 301 (notmuch-tree--define-close-message-window-and
 302  notmuch-tree-jump-search
 303  notmuch-jump-search)
 304 (notmuch-tree--define-close-message-window-and
 305  notmuch-tree-forward-message
 306  notmuch-show-forward-message)
 307 (notmuch-tree--define-close-message-window-and
 308  notmuch-tree-reply-sender
 309  notmuch-show-reply-sender)
 310 (notmuch-tree--define-close-message-window-and
 311  notmuch-tree-reply
 312  notmuch-show-reply)
 313 (notmuch-tree--define-close-message-window-and
 314  notmuch-tree-view-raw-message
 315  notmuch-show-view-raw-message)
 316
 317 ;;; Keymap
 318
 319 (defvar notmuch-tree-mode-map
 320   (let ((map (make-sparse-keymap)))
 321     (set-keymap-parent map notmuch-common-keymap)
 322     ;; These bindings shadow common bindings with variants
 323     ;; that additionally close the message window.
 324     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 325     (define-key map [remap notmuch-search]       'notmuch-tree-to-search)
 326     (define-key map [remap notmuch-help]         'notmuch-tree-help)
 327     (define-key map [remap notmuch-mua-new-mail] 'notmuch-tree-new-mail)
 328     (define-key map [remap notmuch-jump-search]  'notmuch-tree-jump-search)
 329
 330     (define-key map "S" 'notmuch-search-from-tree-current-query)
 331     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 332     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 333
 334     ;; these use notmuch-show functions directly
 335     (define-key map "|" 'notmuch-show-pipe-message)
 336     (define-key map "w" 'notmuch-show-save-attachments)
 337     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 338     (define-key map "c" 'notmuch-show-stash-map)
 339     (define-key map "b" 'notmuch-show-resend-message)
 340
 341     ;; these apply to the message pane
 342     (define-key map (kbd "M-TAB")     'notmuch-tree-previous-message-button)
 343     (define-key map (kbd "<backtab>") 'notmuch-tree-previous-message-button)
 344     (define-key map (kbd "TAB")       'notmuch-tree-next-message-button)
 345     (define-key map "$" 'notmuch-tree-toggle-message-process-crypto)
 346
 347     ;; bindings from show (or elsewhere) but we close the message pane first.
 348     (define-key map "f" 'notmuch-tree-forward-message)
 349     (define-key map "r" 'notmuch-tree-reply-sender)
 350     (define-key map "R" 'notmuch-tree-reply)
 351     (define-key map "V" 'notmuch-tree-view-raw-message)
 352
 353     ;; The main tree view bindings
 354     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 355     (define-key map [mouse-1] 'notmuch-tree-show-message)
 356     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 357     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 358     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 359     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 360     (define-key map "z" 'notmuch-tree-to-tree)
 361     (define-key map "n" 'notmuch-tree-next-matching-message)
 362     (define-key map "p" 'notmuch-tree-prev-matching-message)
 363     (define-key map "N" 'notmuch-tree-next-message)
 364     (define-key map "P" 'notmuch-tree-prev-message)
 365     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 366     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 367     (define-key map "k" 'notmuch-tag-jump)
 368     (define-key map "-" 'notmuch-tree-remove-tag)
 369     (define-key map "+" 'notmuch-tree-add-tag)
 370     (define-key map "*" 'notmuch-tree-tag-thread)
 371     (define-key map " " 'notmuch-tree-scroll-or-next)
 372     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 373     (define-key map "e" 'notmuch-tree-resume-message)
 374     map)
 375   "Keymap for \"notmuch tree\" buffers.")
 376
 377 ;;; Message properties
 378
 379 (defun notmuch-tree-get-message-properties ()
 380   "Return the properties of the current message as a plist.
 381
 382 Some useful entries are:
 383 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 384 :tags - Tags for this message."
 385   (save-excursion
 386     (beginning-of-line)
 387     (get-text-property (point) :notmuch-message-properties)))
 388
 389 (defun notmuch-tree-set-message-properties (props)
 390   (save-excursion
 391     (beginning-of-line)
 392     (put-text-property (point)
 393                        (+ (point) 1)
 394                        :notmuch-message-properties props)))
 395
 396 (defun notmuch-tree-set-prop (prop val &optional props)
 397   (let ((inhibit-read-only t)
 398         (props (or props
 399                    (notmuch-tree-get-message-properties))))
 400     (plist-put props prop val)
 401     (notmuch-tree-set-message-properties props)))
 402
 403 (defun notmuch-tree-get-prop (prop &optional props)
 404   (let ((props (or props
 405                    (notmuch-tree-get-message-properties))))
 406     (plist-get props prop)))
 407
 408 (defun notmuch-tree-set-tags (tags)
 409   "Set the tags of the current message."
 410   (notmuch-tree-set-prop :tags tags))
 411
 412 (defun notmuch-tree-get-tags ()
 413   "Return the tags of the current message."
 414   (notmuch-tree-get-prop :tags))
 415
 416 (defun notmuch-tree-get-message-id (&optional bare)
 417   "Return the message id of the current message."
 418   (let ((id (notmuch-tree-get-prop :id)))
 419     (if id
 420         (if bare
 421             id
 422           (notmuch-id-to-query id))
 423       nil)))
 424
 425 (defun notmuch-tree-get-match ()
 426   "Return whether the current message is a match."
 427   (interactive)
 428   (notmuch-tree-get-prop :match))
 429
 430 ;;; Update display
 431
 432 (defun notmuch-tree-refresh-result ()
 433   "Redisplay the current message line.
 434
 435 This redisplays the current line based on the messages
 436 properties (as they are now). This is used when tags are
 437 updated."
 438   (let ((init-point (point))
 439         (end (line-end-position))
 440         (msg (notmuch-tree-get-message-properties))
 441         (inhibit-read-only t))
 442     (beginning-of-line)
 443     ;; This is a little tricky: we override
 444     ;; notmuch-tree-previous-subject to get the decision between
 445     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 446     ;; from overwriting the buffer local copy of
 447     ;; notmuch-tree-previous-subject if this is called while the
 448     ;; buffer is displaying.
 449     (let ((notmuch-tree-previous-subject
 450            (notmuch-tree-get-prop :previous-subject)))
 451       (delete-region (point) (1+ (line-end-position)))
 452       (notmuch-tree-insert-msg msg))
 453     (let ((new-end (line-end-position)))
 454       (goto-char (if (= init-point end)
 455                      new-end
 456                    (min init-point (- new-end 1)))))))
 457
 458 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 459   "Update display for TAG-CHANGES to current message.
 460
 461 Updates the message in the message pane if appropriate, but does
 462 NOT change the database."
 463   (let* ((current-tags (notmuch-tree-get-tags))
 464          (new-tags (notmuch-update-tags current-tags tag-changes))
 465          (tree-msg-id (notmuch-tree-get-message-id)))
 466     (unless (equal current-tags new-tags)
 467       (notmuch-tree-set-tags new-tags)
 468       (notmuch-tree-refresh-result)
 469       (when (window-live-p notmuch-tree-message-window)
 470         (with-selected-window notmuch-tree-message-window
 471           (when (string= tree-msg-id (notmuch-show-get-message-id))
 472             (notmuch-show-update-tags new-tags)))))))
 473
 474 ;;; Commands (and some helper functions used by them)
 475
 476 (defun notmuch-tree-tag (tag-changes)
 477   "Change tags for the current message."
 478   (interactive
 479    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 480   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 481   (notmuch-tree-tag-update-display tag-changes))
 482
 483 (defun notmuch-tree-add-tag (tag-changes)
 484   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 485   (interactive
 486    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 487   (notmuch-tree-tag tag-changes))
 488
 489 (defun notmuch-tree-remove-tag (tag-changes)
 490   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 491   (interactive
 492    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 493   (notmuch-tree-tag tag-changes))
 494
 495 (defun notmuch-tree-resume-message ()
 496   "Resume EDITING the current draft message."
 497   (interactive)
 498   (notmuch-tree-close-message-window)
 499   (let ((id (notmuch-tree-get-message-id)))
 500     (if id
 501         (notmuch-draft-resume id)
 502       (message "No message to resume!"))))
 503
 504 ;; The next two functions close the message window before calling
 505 ;; notmuch-search or notmuch-tree but they do so after the user has
 506 ;; entered the query (in case the user was basing the query on
 507 ;; something in the message window).
 508
 509 (defun notmuch-tree-to-search ()
 510   "Run \"notmuch search\" with the given `query' and display results."
 511   (interactive)
 512   (let ((query (notmuch-read-query "Notmuch search: ")))
 513     (notmuch-tree-close-message-window)
 514     (notmuch-search query)))
 515
 516 (defun notmuch-tree-to-tree ()
 517   "Run a query and display results in tree view."
 518   (interactive)
 519   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 520     (notmuch-tree-close-message-window)
 521     (notmuch-tree query)))
 522
 523 (defun notmuch-tree-archive-thread-then-next ()
 524   "Archive all messages in the current buffer, then show next thread from search."
 525   (interactive)
 526   (notmuch-tree-archive-thread)
 527   (notmuch-tree-next-thread))
 528
 529 (defun notmuch-unthreaded-from-tree-current-query ()
 530   "Switch from tree view to unthreaded view."
 531   (interactive)
 532   (unless notmuch-tree-unthreaded
 533     (notmuch-tree-refresh-view 'unthreaded)))
 534
 535 (defun notmuch-tree-from-unthreaded-current-query ()
 536   "Switch from unthreaded view to tree view."
 537   (interactive)
 538   (when notmuch-tree-unthreaded
 539     (notmuch-tree-refresh-view 'tree)))
 540
 541 (defun notmuch-search-from-tree-current-query ()
 542   "Call notmuch search with the current query."
 543   (interactive)
 544   (notmuch-tree-close-message-window)
 545   (notmuch-search (notmuch-tree-get-query)))
 546
 547 (defun notmuch-tree-message-window-kill-hook ()
 548   "Close the message pane when exiting the show buffer."
 549   (let ((buffer (current-buffer)))
 550     (when (and (window-live-p notmuch-tree-message-window)
 551                (eq (window-buffer notmuch-tree-message-window) buffer))
 552       ;; We could check whether this is the only window in its frame,
 553       ;; but simply ignoring the error that is thrown otherwise is
 554       ;; what we had to do for Emacs 24 and we stick to that because
 555       ;; it is still the simplest approach.
 556       (ignore-errors
 557         (delete-window notmuch-tree-message-window)))))
 558
 559 (defun notmuch-tree-command-hook ()
 560   (when (eq major-mode 'notmuch-tree-mode)
 561     ;; We just run the notmuch-show-command-hook on the message pane.
 562     (when (buffer-live-p notmuch-tree-message-buffer)
 563       (with-current-buffer notmuch-tree-message-buffer
 564         (notmuch-show-command-hook)))))
 565
 566 (defun notmuch-tree-show-message-in ()
 567   "Show the current message (in split-pane)."
 568   (interactive)
 569   (let ((id (notmuch-tree-get-message-id))
 570         (inhibit-read-only t)
 571         buffer)
 572     (when id
 573       ;; We close and reopen the window to kill off un-needed buffers
 574       ;; this might cause flickering but seems ok.
 575       (notmuch-tree-close-message-window)
 576       (setq notmuch-tree-message-window
 577             (split-window-vertically (/ (window-height) 4)))
 578       (with-selected-window notmuch-tree-message-window
 579         (let (;; Since we are only displaying one message do not indent.
 580               (notmuch-show-indent-messages-width 0)
 581               (notmuch-show-only-matching-messages t)
 582               ;; Ensure that `pop-to-buffer-same-window' uses the
 583               ;; window we want it to use.
 584               (display-buffer-overriding-action
 585                  '((display-buffer-same-window)
 586                    (inhibit-same-window . nil))))
 587           (setq buffer (notmuch-show id))))
 588       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 589       (let ((window notmuch-tree-message-window))
 590         (with-current-buffer buffer
 591           (setq notmuch-tree-message-window window)
 592           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 593       (when notmuch-show-mark-read-tags
 594         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 595       (setq notmuch-tree-message-buffer buffer))))
 596
 597 (defun notmuch-tree-show-message-out ()
 598   "Show the current message (in whole window)."
 599   (interactive)
 600   (let ((id (notmuch-tree-get-message-id))
 601         (inhibit-read-only t)
 602         buffer)
 603     (when id
 604       ;; We close the window to kill off un-needed buffers.
 605       (notmuch-tree-close-message-window)
 606       (notmuch-show id))))
 607
 608 (defun notmuch-tree-show-message (arg)
 609   "Show the current message.
 610
 611 Shows in split pane or whole window according to value of
 612 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 613   (interactive "P")
 614   (if (or (and (notmuch-tree-show-out) (not arg))
 615           (and (not (notmuch-tree-show-out)) arg))
 616       (notmuch-tree-show-message-out)
 617     (notmuch-tree-show-message-in)))
 618
 619 (defun notmuch-tree-scroll-message-window ()
 620   "Scroll the message window (if it exists)."
 621   (interactive)
 622   (when (window-live-p notmuch-tree-message-window)
 623     (with-selected-window notmuch-tree-message-window
 624       (if (pos-visible-in-window-p (point-max))
 625           t
 626         (scroll-up)))))
 627
 628 (defun notmuch-tree-scroll-message-window-back ()
 629   "Scroll the message window back (if it exists)."
 630   (interactive)
 631   (when (window-live-p notmuch-tree-message-window)
 632     (with-selected-window notmuch-tree-message-window
 633       (if (pos-visible-in-window-p (point-min))
 634           t
 635         (scroll-down)))))
 636
 637 (defun notmuch-tree-scroll-or-next ()
 638   "Scroll the message window.
 639 If it at end go to next message."
 640   (interactive)
 641   (when (notmuch-tree-scroll-message-window)
 642     (notmuch-tree-next-matching-message)))
 643
 644 (defun notmuch-tree-quit (&optional kill-both)
 645   "Close the split view or exit tree."
 646   (interactive "P")
 647   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 648     (kill-buffer (current-buffer))))
 649
 650 (defun notmuch-tree-close-message-window ()
 651   "Close the message-window. Return t if close succeeds."
 652   (interactive)
 653   (when (and (window-live-p notmuch-tree-message-window)
 654              (eq (window-buffer notmuch-tree-message-window)
 655                  notmuch-tree-message-buffer))
 656     (delete-window notmuch-tree-message-window)
 657     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 658       (kill-buffer notmuch-tree-message-buffer))
 659     t))
 660
 661 (defun notmuch-tree-archive-message (&optional unarchive)
 662   "Archive the current message.
 663
 664 Archive the current message by applying the tag changes in
 665 `notmuch-archive-tags' to it. If a prefix argument is given, the
 666 message will be \"unarchived\", i.e. the tag changes in
 667 `notmuch-archive-tags' will be reversed."
 668   (interactive "P")
 669   (when notmuch-archive-tags
 670     (notmuch-tree-tag
 671      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 672
 673 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 674   "Archive the current message and move to next matching message."
 675   (interactive "P")
 676   (notmuch-tree-archive-message unarchive)
 677   (notmuch-tree-next-matching-message))
 678
 679 (defun notmuch-tree-archive-thread-then-exit ()
 680   "Archive all messages in the current buffer, then exit notmuch-tree."
 681   (interactive)
 682   (notmuch-tree-archive-thread)
 683   (notmuch-tree-quit t))
 684
 685 (defun notmuch-tree-archive-message-then-next-or-exit ()
 686   "Archive current message, then show next open message in current thread.
 687
 688 If at the last open message in the current thread, then exit back
 689 to search results."
 690   (interactive)
 691   (notmuch-tree-archive-message)
 692   (notmuch-tree-next-matching-message t))
 693
 694 (defun notmuch-tree-next-message ()
 695   "Move to next message."
 696   (interactive)
 697   (forward-line)
 698   (when (window-live-p notmuch-tree-message-window)
 699     (notmuch-tree-show-message-in)))
 700
 701 (defun notmuch-tree-prev-message ()
 702   "Move to previous message."
 703   (interactive)
 704   (forward-line -1)
 705   (when (window-live-p notmuch-tree-message-window)
 706     (notmuch-tree-show-message-in)))
 707
 708 (defun notmuch-tree-goto-matching-message (&optional prev)
 709   "Move to the next or previous matching message.
 710
 711 Returns t if there was a next matching message in the thread to show,
 712 nil otherwise."
 713   (let ((dir (if prev -1 nil))
 714         (eobfn (if prev #'bobp #'eobp)))
 715     (while (and (not (funcall eobfn))
 716                 (not (notmuch-tree-get-match)))
 717       (forward-line dir))
 718     (not (funcall eobfn))))
 719
 720 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 721   "Move to the next or previous matching message."
 722   (interactive "P")
 723   (forward-line (if prev -1 nil))
 724   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 725       (notmuch-tree-quit pop-at-end)
 726     (when (window-live-p notmuch-tree-message-window)
 727       (notmuch-tree-show-message-in))))
 728
 729 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 730   "Move to previous matching message."
 731   (interactive "P")
 732   (notmuch-tree-matching-message t pop-at-end))
 733
 734 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 735   "Move to next matching message."
 736   (interactive "P")
 737   (notmuch-tree-matching-message nil pop-at-end))
 738
 739 (defun notmuch-tree-refresh-view (&optional view)
 740   "Refresh view."
 741   (interactive)
 742   (when (get-buffer-process (current-buffer))
 743     (error "notmuch tree process already running for current buffer"))
 744   (let ((inhibit-read-only t)
 745         (basic-query notmuch-tree-basic-query)
 746         (unthreaded (cond ((eq view 'unthreaded) t)
 747                           ((eq view 'tree) nil)
 748                           (t notmuch-tree-unthreaded)))
 749         (query-context notmuch-tree-query-context)
 750         (target (notmuch-tree-get-message-id)))
 751     (erase-buffer)
 752     (notmuch-tree-worker basic-query
 753                          query-context
 754                          target
 755                          nil
 756                          unthreaded)))
 757
 758 (defun notmuch-tree-thread-top ()
 759   (when (notmuch-tree-get-message-properties)
 760     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 761       (forward-line -1))))
 762
 763 (defun notmuch-tree-prev-thread-in-tree ()
 764   "Move to the previous thread in the current tree"
 765   (interactive)
 766   (forward-line -1)
 767   (notmuch-tree-thread-top)
 768   (not (bobp)))
 769
 770 (defun notmuch-tree-next-thread-in-tree ()
 771   "Get the next thread in the current tree. Returns t if a thread was
 772 found or nil if not."
 773   (interactive)
 774   (forward-line 1)
 775   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 776     (forward-line 1))
 777   (not (eobp)))
 778
 779 (defun notmuch-tree-next-thread-from-search (&optional previous)
 780   "Move to the next thread in the parent search results, if any.
 781
 782 If PREVIOUS is non-nil, move to the previous item in the
 783 search results instead."
 784   (interactive "P")
 785   (let ((parent-buffer notmuch-tree-parent-buffer))
 786     (notmuch-tree-quit t)
 787     (when (buffer-live-p parent-buffer)
 788       (switch-to-buffer parent-buffer)
 789       (if previous
 790           (notmuch-search-previous-thread)
 791         (notmuch-search-next-thread))
 792       (notmuch-tree-from-search-thread))))
 793
 794 (defun notmuch-tree-next-thread (&optional previous)
 795   "Move to the next thread in the current tree or parent search
 796 results
 797
 798 If PREVIOUS is non-nil, move to the previous thread in the tree or
 799 search results instead."
 800   (interactive)
 801   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 802             (notmuch-tree-next-thread-in-tree))
 803     (notmuch-tree-next-thread-from-search previous)))
 804
 805 (defun notmuch-tree-prev-thread ()
 806   "Move to the previous thread in the current tree or parent search
 807 results"
 808   (interactive)
 809   (notmuch-tree-next-thread t))
 810
 811 (defun notmuch-tree-thread-mapcar (function)
 812   "Iterate through all messages in the current thread
 813  and call FUNCTION for side effects."
 814   (save-excursion
 815     (notmuch-tree-thread-top)
 816     (cl-loop collect (funcall function)
 817              do (forward-line)
 818              while (and (notmuch-tree-get-message-properties)
 819                         (not (notmuch-tree-get-prop :first))))))
 820
 821 (defun notmuch-tree-get-messages-ids-thread-search ()
 822   "Return a search string for all message ids of messages in the current thread."
 823   (mapconcat 'identity
 824              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 825              " or "))
 826
 827 (defun notmuch-tree-tag-thread (tag-changes)
 828   "Tag all messages in the current thread."
 829   (interactive
 830    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 831                                 (lambda () (notmuch-tree-get-tags))))))
 832      (list (notmuch-read-tag-changes tags "Tag thread"))))
 833   (when (notmuch-tree-get-message-properties)
 834     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 835     (notmuch-tree-thread-mapcar
 836      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 837
 838 (defun notmuch-tree-archive-thread (&optional unarchive)
 839   "Archive each message in thread.
 840
 841 Archive each message currently shown by applying the tag changes
 842 in `notmuch-archive-tags' to each. If a prefix argument is given,
 843 the messages will be \"unarchived\", i.e. the tag changes in
 844 `notmuch-archive-tags' will be reversed.
 845
 846 Note: This command is safe from any race condition of new messages
 847 being delivered to the same thread. It does not archive the
 848 entire thread, but only the messages shown in the current
 849 buffer."
 850   (interactive "P")
 851   (when notmuch-archive-tags
 852     (notmuch-tree-tag-thread
 853      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 854
 855 ;;; Functions for displaying the tree buffer itself
 856
 857 (defun notmuch-tree-clean-address (address)
 858   "Try to clean a single email ADDRESS for display. Return
 859 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 860 unchanged ADDRESS if parsing fails."
 861   (let* ((clean-address (notmuch-clean-address address))
 862          (p-address (car clean-address))
 863          (p-name (cdr clean-address)))
 864
 865     ;; If we have a name return that otherwise return the address.
 866     (or p-name p-address)))
 867
 868 (defun notmuch-tree-format-field (field format-string msg)
 869   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 870   (let* ((headers (plist-get msg :headers))
 871          (match (plist-get msg :match)))
 872     (cond
 873      ((listp field)
 874       (format format-string (notmuch-tree-format-field-list field msg)))
 875
 876      ((string-equal field "date")
 877       (let ((face (if match
 878                       'notmuch-tree-match-date-face
 879                     'notmuch-tree-no-match-date-face)))
 880         (propertize (format format-string (plist-get msg :date_relative))
 881                     'face face)))
 882
 883      ((string-equal field "tree")
 884       (let ((tree-status (plist-get msg :tree-status))
 885             (face (if match
 886                       'notmuch-tree-match-tree-face
 887                     'notmuch-tree-no-match-tree-face)))
 888
 889         (propertize (format format-string
 890                             (mapconcat #'identity (reverse tree-status) ""))
 891                     'face face)))
 892
 893      ((string-equal field "subject")
 894       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 895             (previous-subject notmuch-tree-previous-subject)
 896             (face (if match
 897                       'notmuch-tree-match-subject-face
 898                     'notmuch-tree-no-match-subject-face)))
 899
 900         (setq notmuch-tree-previous-subject bare-subject)
 901         (propertize (format format-string
 902                             (if (string= previous-subject bare-subject)
 903                                 " ..."
 904                               bare-subject))
 905                     'face face)))
 906
 907      ((string-equal field "authors")
 908       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 909             (len (length (format format-string "")))
 910             (face (if match
 911                       'notmuch-tree-match-author-face
 912                     'notmuch-tree-no-match-author-face)))
 913         (when (> (length author) len)
 914           (setq author (substring author 0 len)))
 915         (propertize (format format-string author) 'face face)))
 916
 917      ((string-equal field "tags")
 918       (let ((tags (plist-get msg :tags))
 919             (orig-tags (plist-get msg :orig-tags))
 920             (face (if match
 921                       'notmuch-tree-match-tag-face
 922                     'notmuch-tree-no-match-tag-face)))
 923         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 924
 925 (defun notmuch-tree-format-field-list (field-list msg)
 926   "Format fields of MSG according to FIELD-LIST and return string."
 927   (let ((face (if (plist-get msg :match)
 928                   'notmuch-tree-match-face
 929                 'notmuch-tree-no-match-face))
 930         (result-string))
 931     (dolist (spec field-list result-string)
 932       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 933         (setq result-string (concat result-string field-string))))
 934     (notmuch-apply-face result-string face t)))
 935
 936 (defun notmuch-tree-insert-msg (msg)
 937   "Insert the message MSG according to notmuch-tree-result-format."
 938   ;; We need to save the previous subject as it will get overwritten
 939   ;; by the insert-field calls.
 940   (let ((previous-subject notmuch-tree-previous-subject))
 941     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 942     (notmuch-tree-set-message-properties msg)
 943     (notmuch-tree-set-prop :previous-subject previous-subject)
 944     (insert "\n")))
 945
 946 (defun notmuch-tree-goto-and-insert-msg (msg)
 947   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 948   (save-excursion
 949     (goto-char (point-max))
 950     (notmuch-tree-insert-msg msg))
 951   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 952         (target notmuch-tree-target-msg))
 953     (when (or (and (not target) (plist-get msg :match))
 954               (string= msg-id target))
 955       (setq notmuch-tree-target-msg "found")
 956       (goto-char (point-max))
 957       (forward-line -1)
 958       (when notmuch-tree-open-target
 959         (notmuch-tree-show-message-in)))))
 960
 961 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 962   "Insert the message tree TREE at depth DEPTH in the current thread.
 963
 964 A message tree is another name for a single sub-thread: i.e., a
 965 message together with all its descendents."
 966   (let ((msg (car tree))
 967         (replies (cadr tree)))
 968     (cond
 969      ((and (< 0 depth) (not last))
 970       (push "├" tree-status))
 971      ((and (< 0 depth) last)
 972       (push "╰" tree-status))
 973      ((and (eq 0 depth) first last)
 974       ;; Choice between these two variants is a matter of taste.
 975       ;; (push "─" tree-status))
 976       (push " " tree-status))
 977      ((and (eq 0 depth) first (not last))
 978       (push "┬" tree-status))
 979      ((and (eq 0 depth) (not first) last)
 980       (push "╰" tree-status))
 981      ((and (eq 0 depth) (not first) (not last))
 982       (push "├" tree-status)))
 983     (push (concat (if replies "┬" "─") "►") tree-status)
 984     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 985     (setq msg (plist-put msg :tree-status tree-status))
 986     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 987     (notmuch-tree-goto-and-insert-msg msg)
 988     (pop tree-status)
 989     (pop tree-status)
 990     (if last
 991         (push " " tree-status)
 992       (push "│" tree-status))
 993     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 994
 995 (defun notmuch-tree-insert-thread (thread depth tree-status)
 996   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 997   (let ((n (length thread)))
 998     (cl-loop for tree in thread
 999              for count from 1 to n
1000              do (notmuch-tree-insert-tree tree depth tree-status
1001                                           (eq count 1)
1002                                           (eq count n)))))
1003
1004 (defun notmuch-tree-insert-forest-thread (forest-thread)
1005   "Insert a single complete thread."
1006   (let (tree-status)
1007     ;; Reset at the start of each main thread.
1008     (setq notmuch-tree-previous-subject nil)
1009     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
1010
1011 (defun notmuch-tree-insert-forest (forest)
1012   "Insert a forest of threads.
1013
1014 This function inserts a collection of several complete threads as
1015 passed to it by notmuch-tree-process-filter."
1016   (mapc 'notmuch-tree-insert-forest-thread forest))
1017
1018 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
1019   "Major mode displaying messages (as opposed to threads) of a notmuch search.
1020
1021 This buffer contains the results of a \"notmuch tree\" of your
1022 email archives. Each line in the buffer represents a single
1023 message giving the relative date, the author, subject, and any
1024 tags.
1025
1026 Pressing \\[notmuch-tree-show-message] on any line displays that message.
1027
1028 Complete list of currently available key bindings:
1029
1030 \\{notmuch-tree-mode-map}"
1031   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1032   (hl-line-mode 1)
1033   (setq buffer-read-only t)
1034   (setq truncate-lines t))
1035
1036 (defun notmuch-tree-process-sentinel (proc msg)
1037   "Add a message to let user know when \"notmuch tree\" exits."
1038   (let ((buffer (process-buffer proc))
1039         (status (process-status proc))
1040         (exit-status (process-exit-status proc))
1041         (never-found-target-thread nil))
1042     (when (memq status '(exit signal))
1043       (kill-buffer (process-get proc 'parse-buf))
1044       (when (buffer-live-p buffer)
1045         (with-current-buffer buffer
1046           (save-excursion
1047             (let ((inhibit-read-only t)
1048                   (atbob (bobp)))
1049               (goto-char (point-max))
1050               (when (eq status 'signal)
1051                 (insert "Incomplete search results (tree view process was killed).\n"))
1052               (when (eq status 'exit)
1053                 (insert "End of search results.")
1054                 (unless (= exit-status 0)
1055                   (insert (format " (process returned %d)" exit-status)))
1056                 (insert "\n")))))))))
1057
1058 (defun notmuch-tree-process-filter (proc string)
1059   "Process and filter the output of \"notmuch show\" for tree view."
1060   (let ((results-buf (process-buffer proc))
1061         (parse-buf (process-get proc 'parse-buf))
1062         (inhibit-read-only t)
1063         done)
1064     (if (not (buffer-live-p results-buf))
1065         (delete-process proc)
1066       (with-current-buffer parse-buf
1067         ;; Insert new data
1068         (save-excursion
1069           (goto-char (point-max))
1070           (insert string))
1071         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1072                                          results-buf)))))
1073
1074 (defun notmuch-tree-worker (basic-query &optional query-context target open-target unthreaded)
1075   "Insert the tree view of the search in the current buffer.
1076
1077 This is is a helper function for notmuch-tree. The arguments are
1078 the same as for the function notmuch-tree."
1079   (interactive)
1080   (notmuch-tree-mode)
1081   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1082   (setq notmuch-tree-unthreaded unthreaded)
1083   (setq notmuch-tree-basic-query basic-query)
1084   (setq notmuch-tree-query-context (if (or (string= query-context "")
1085                                            (string= query-context "*"))
1086                                        nil
1087                                      query-context))
1088   (setq notmuch-tree-target-msg target)
1089   (setq notmuch-tree-open-target open-target)
1090   ;; Set the default value for `notmuch-show-process-crypto' in this
1091   ;; buffer. Although we don't use this some of the functions we call
1092   ;; (such as reply) do. It is a buffer local variable so setting it
1093   ;; will not affect genuine show buffers.
1094   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1095   (erase-buffer)
1096   (goto-char (point-min))
1097   (let* ((search-args (concat basic-query
1098                               (and query-context
1099                                    (concat " and (" query-context ")"))))
1100          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1101     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1102       (setq search-args basic-query))
1103     (notmuch-tag-clear-cache)
1104     (let ((proc (notmuch-start-notmuch
1105                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1106                  "show" "--body=false" "--format=sexp" "--format-version=4"
1107                  message-arg search-args))
1108           ;; Use a scratch buffer to accumulate partial output.
1109           ;; This buffer will be killed by the sentinel, which
1110           ;; should be called no matter how the process dies.
1111           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1112       (process-put proc 'parse-buf parse-buf)
1113       (set-process-filter proc 'notmuch-tree-process-filter)
1114       (set-process-query-on-exit-flag proc nil))))
1115
1116 (defun notmuch-tree-get-query ()
1117   "Return the current query in this tree buffer."
1118   (if notmuch-tree-query-context
1119       (concat notmuch-tree-basic-query
1120               " and ("
1121               notmuch-tree-query-context
1122               ")")
1123     notmuch-tree-basic-query))
1124
1125 (defun notmuch-tree (&optional query query-context target buffer-name open-target unthreaded parent-buffer)
1126   "Display threads matching QUERY in tree view.
1127
1128 The arguments are:
1129   QUERY: the main query. This can be any query but in many cases will be
1130       a single thread. If nil this is read interactively from the minibuffer.
1131   QUERY-CONTEXT: is an additional term for the query. The query used
1132       is QUERY and QUERY-CONTEXT unless that does not match any messages
1133       in which case we fall back to just QUERY.
1134   TARGET: A message ID (with the id: prefix) that will be made
1135       current if it appears in the tree view results.
1136   BUFFER-NAME: the name of the buffer to display the tree view. If
1137       it is nil \"*notmuch-tree\" followed by QUERY is used.
1138   OPEN-TARGET: If TRUE open the target message in the message pane.
1139   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1140   (interactive)
1141   (unless query
1142     (setq query (notmuch-read-query (concat "Notmuch "
1143                                             (if unthreaded "unthreaded " "tree ")
1144                                             "view search: "))))
1145   (let ((buffer (get-buffer-create (generate-new-buffer-name
1146                                     (or buffer-name
1147                                         (concat "*notmuch-"
1148                                                 (if unthreaded "unthreaded-" "tree-")
1149                                                 query "*")))))
1150         (inhibit-read-only t))
1151     (pop-to-buffer-same-window buffer))
1152   ;; Don't track undo information for this buffer
1153   (setq buffer-undo-list t)
1154   (notmuch-tree-worker query query-context target open-target unthreaded)
1155   (setq notmuch-tree-parent-buffer parent-buffer)
1156   (setq truncate-lines t))
1157
1158 (defun notmuch-unthreaded (&optional query query-context target buffer-name open-target)
1159   (interactive)
1160   (notmuch-tree query query-context target buffer-name open-target t))
1161
1162 ;;; _
1163
1164 (provide 'notmuch-tree)
1165
1166 ;;; notmuch-tree.el ends here