git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl-lib))
  28
  29 (require 'mail-parse)
  30
  31 (require 'notmuch-lib)
  32 (require 'notmuch-query)
  33 (require 'notmuch-show)
  34 (require 'notmuch-tag)
  35 (require 'notmuch-parser)
  36 (require 'notmuch-jump)
  37
  38 (declare-function notmuch-search "notmuch"
  39                   (&optional query oldest-first target-thread target-line))
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-read-query "notmuch" (prompt))
  42 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  43 (declare-function notmuch-search-find-subject "notmuch" ())
  44
  45 ;; the following variable is defined in notmuch.el
  46 (defvar notmuch-search-query-string)
  47
  48 ;; this variable distinguishes the unthreaded display from the normal tree display
  49 (defvar notmuch-tree-unthreaded nil
  50   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  51 (make-variable-buffer-local 'notmuch-tree-unthreaded)
  52
  53 (defgroup notmuch-tree nil
  54   "Showing message and thread structure."
  55   :group 'notmuch)
  56
  57 (defcustom notmuch-tree-show-out nil
  58   "View selected messages in new window rather than split-pane."
  59   :type 'boolean
  60   :group 'notmuch-tree)
  61
  62 (defcustom notmuch-unthreaded-show-out t
  63   "View selected messages in new window rather than split-pane."
  64   :type 'boolean
  65   :group 'notmuch-tree)
  66
  67 (defun notmuch-tree-show-out ()
  68   (if notmuch-tree-unthreaded
  69       notmuch-unthreaded-show-out
  70     notmuch-tree-show-out))
  71
  72 (defcustom notmuch-tree-result-format
  73   `(("date" . "%12s  ")
  74     ("authors" . "%-20s")
  75     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  76     ("tags" . "(%s)"))
  77   "Result formatting for tree view. Supported fields are: date,
  78 authors, subject, tree, tags.  Tree means the thread tree
  79 box graphics. The field may also be a list in which case
  80 the formatting rules are applied recursively and then the
  81 output of all the fields in the list is inserted
  82 according to format-string.
  83
  84 Note the author string should not contain
  85 whitespace (put it in the neighbouring fields instead).
  86 For example:
  87         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  88                                           \(\"subject\" . \"%s\"\)\)\)"
  89   :type '(alist :key-type (string) :value-type (string))
  90   :group 'notmuch-tree)
  91
  92 (defcustom notmuch-unthreaded-result-format
  93   `(("date" . "%12s  ")
  94     ("authors" . "%-20s")
  95     ((("subject" . "%s")) ." %-54s ")
  96     ("tags" . "(%s)"))
  97   "Result formatting for unthreaded tree view. Supported fields are: date,
  98 authors, subject, tree, tags.  Tree means the thread tree
  99 box graphics. The field may also be a list in which case
 100 the formatting rules are applied recursively and then the
 101 output of all the fields in the list is inserted
 102 according to format-string.
 103
 104 Note the author string should not contain
 105 whitespace (put it in the neighbouring fields instead).
 106 For example:
 107         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 108                                           \(\"subject\" . \"%s\"\)\)\)"
 109   :type '(alist :key-type (string) :value-type (string))
 110   :group 'notmuch-tree)
 111
 112 (defun notmuch-tree-result-format ()
 113   (if notmuch-tree-unthreaded
 114       notmuch-unthreaded-result-format
 115     notmuch-tree-result-format))
 116
 117 ;; Faces for messages that match the query.
 118 (defface notmuch-tree-match-face
 119   '((t :inherit default))
 120   "Default face used in tree mode face for matching messages"
 121   :group 'notmuch-tree
 122   :group 'notmuch-faces)
 123
 124 (defface notmuch-tree-match-date-face
 125   nil
 126   "Face used in tree mode for the date in messages matching the query."
 127   :group 'notmuch-tree
 128   :group 'notmuch-faces)
 129
 130 (defface notmuch-tree-match-author-face
 131   '((((class color)
 132       (background dark))
 133      (:foreground "OliveDrab1"))
 134     (((class color)
 135       (background light))
 136      (:foreground "dark blue"))
 137     (t
 138      (:bold t)))
 139   "Face used in tree mode for the date in messages matching the query."
 140   :group 'notmuch-tree
 141   :group 'notmuch-faces)
 142
 143 (defface notmuch-tree-match-subject-face
 144   nil
 145   "Face used in tree mode for the subject in messages matching the query."
 146   :group 'notmuch-tree
 147   :group 'notmuch-faces)
 148
 149 (defface notmuch-tree-match-tree-face
 150   nil
 151   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 152   :group 'notmuch-tree
 153   :group 'notmuch-faces)
 154
 155 (defface notmuch-tree-match-tag-face
 156   '((((class color)
 157       (background dark))
 158      (:foreground "OliveDrab1"))
 159     (((class color)
 160       (background light))
 161      (:foreground "navy blue" :bold t))
 162     (t
 163      (:bold t)))
 164   "Face used in tree mode for tags in messages matching the query."
 165   :group 'notmuch-tree
 166   :group 'notmuch-faces)
 167
 168 ;; Faces for messages that do not match the query.
 169 (defface notmuch-tree-no-match-face
 170   '((t (:foreground "gray")))
 171   "Default face used in tree mode face for non-matching messages."
 172   :group 'notmuch-tree
 173   :group 'notmuch-faces)
 174
 175 (defface notmuch-tree-no-match-date-face
 176   nil
 177   "Face used in tree mode for non-matching dates."
 178   :group 'notmuch-tree
 179   :group 'notmuch-faces)
 180
 181 (defface notmuch-tree-no-match-subject-face
 182   nil
 183   "Face used in tree mode for non-matching subjects."
 184   :group 'notmuch-tree
 185   :group 'notmuch-faces)
 186
 187 (defface notmuch-tree-no-match-tree-face
 188   nil
 189   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 190   :group 'notmuch-tree
 191   :group 'notmuch-faces)
 192
 193 (defface notmuch-tree-no-match-author-face
 194   nil
 195   "Face used in tree mode for the date in messages matching the query."
 196   :group 'notmuch-tree
 197   :group 'notmuch-faces)
 198
 199 (defface notmuch-tree-no-match-tag-face
 200   nil
 201   "Face used in tree mode face for non-matching tags."
 202   :group 'notmuch-tree
 203   :group 'notmuch-faces)
 204
 205 (defvar notmuch-tree-previous-subject
 206   "The subject of the most recent result shown during the async display.")
 207 (make-variable-buffer-local 'notmuch-tree-previous-subject)
 208
 209 (defvar notmuch-tree-basic-query nil
 210   "A buffer local copy of argument query to the function notmuch-tree.")
 211 (make-variable-buffer-local 'notmuch-tree-basic-query)
 212
 213 (defvar notmuch-tree-query-context nil
 214   "A buffer local copy of argument query-context to the function notmuch-tree.")
 215 (make-variable-buffer-local 'notmuch-tree-query-context)
 216
 217 (defvar notmuch-tree-target-msg nil
 218   "A buffer local copy of argument target to the function notmuch-tree.")
 219 (make-variable-buffer-local 'notmuch-tree-target-msg)
 220
 221 (defvar notmuch-tree-open-target nil
 222   "A buffer local copy of argument open-target to the function notmuch-tree.")
 223 (make-variable-buffer-local 'notmuch-tree-open-target)
 224
 225 (defvar notmuch-tree-parent-buffer nil)
 226 (make-variable-buffer-local 'notmuch-tree-parent-buffer)
 227
 228 (defvar notmuch-tree-message-window nil
 229   "The window of the message pane.
 230
 231 It is set in both the tree buffer and the child show buffer. It
 232 is used to try and close the message pane when quitting tree view
 233 or the child show buffer.")
 234 (make-variable-buffer-local 'notmuch-tree-message-window)
 235 (put 'notmuch-tree-message-window 'permanent-local t)
 236
 237 (defvar notmuch-tree-message-buffer nil
 238   "The buffer name of the show buffer in the message pane.
 239
 240 This is used to try and make sure we don't close the message pane
 241 if the user has loaded a different buffer in that window.")
 242 (make-variable-buffer-local 'notmuch-tree-message-buffer)
 243 (put 'notmuch-tree-message-buffer 'permanent-local t)
 244
 245 (defun notmuch-tree-to-message-pane (func)
 246   "Execute FUNC in message pane.
 247
 248 This function returns a function (so can be used as a keybinding)
 249 which executes function FUNC in the message pane if it is
 250 open (if the message pane is closed it does nothing)."
 251   `(lambda ()
 252      ,(concat "(In message pane) " (documentation func t))
 253      (interactive)
 254      (when (window-live-p notmuch-tree-message-window)
 255        (with-selected-window notmuch-tree-message-window
 256          (call-interactively #',func)))))
 257
 258 (defun notmuch-tree-inherit-from-message-pane (sym)
 259   "Return value of SYM in message-pane if open, or tree-pane if not."
 260   (if (window-live-p notmuch-tree-message-window)
 261       (with-selected-window notmuch-tree-message-window
 262         (symbol-value sym))
 263     (symbol-value sym)))
 264
 265 (defun notmuch-tree-button-activate (&optional button)
 266   "Activate BUTTON or button at point.
 267
 268 This function does not give an error if there is no button."
 269   (interactive)
 270   (let ((button (or button (button-at (point)))))
 271     (when button (button-activate button))))
 272
 273 (defun notmuch-tree-close-message-pane-and (func)
 274   "Close message pane and execute FUNC.
 275
 276 This function returns a function (so can be used as a keybinding)
 277 which closes the message pane if open and then executes function
 278 FUNC."
 279   `(lambda ()
 280      ,(concat "(Close message pane and) " (documentation func t))
 281      (interactive)
 282      (let ((notmuch-show-process-crypto
 283             (notmuch-tree-inherit-from-message-pane 'notmuch-show-process-crypto)))
 284        (notmuch-tree-close-message-window)
 285        (call-interactively #',func))))
 286
 287 (defvar notmuch-tree-mode-map
 288   (let ((map (make-sparse-keymap)))
 289     (set-keymap-parent map notmuch-common-keymap)
 290     ;; The following override the global keymap.
 291     ;; Override because we want to close message pane first.
 292     (define-key map [remap notmuch-help]
 293       (notmuch-tree-close-message-pane-and #'notmuch-help))
 294     ;; Override because we first close message pane and then close tree buffer.
 295     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 296     ;; Override because we close message pane after the search query is entered.
 297     (define-key map [remap notmuch-search] 'notmuch-tree-to-search)
 298     ;; Override because we want to close message pane first.
 299     (define-key map [remap notmuch-mua-new-mail]
 300       (notmuch-tree-close-message-pane-and #'notmuch-mua-new-mail))
 301     ;; Override because we want to close message pane first.
 302     (define-key map [remap notmuch-jump-search]
 303       (notmuch-tree-close-message-pane-and #'notmuch-jump-search))
 304
 305     (define-key map "S" 'notmuch-search-from-tree-current-query)
 306     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 307     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 308
 309     ;; these use notmuch-show functions directly
 310     (define-key map "|" 'notmuch-show-pipe-message)
 311     (define-key map "w" 'notmuch-show-save-attachments)
 312     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 313     (define-key map "c" 'notmuch-show-stash-map)
 314     (define-key map "b" 'notmuch-show-resend-message)
 315
 316     ;; these apply to the message pane
 317     (define-key map (kbd "M-TAB")
 318       (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 319     (define-key map (kbd "<backtab>")
 320       (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 321     (define-key map (kbd "TAB")
 322       (notmuch-tree-to-message-pane #'notmuch-show-next-button))
 323     (define-key map "$"
 324       (notmuch-tree-to-message-pane #'notmuch-show-toggle-process-crypto))
 325
 326     ;; bindings from show (or elsewhere) but we close the message pane first.
 327     (define-key map "f"
 328       (notmuch-tree-close-message-pane-and #'notmuch-show-forward-message))
 329     (define-key map "r"
 330       (notmuch-tree-close-message-pane-and #'notmuch-show-reply-sender))
 331     (define-key map "R"
 332       (notmuch-tree-close-message-pane-and #'notmuch-show-reply))
 333     (define-key map "V"
 334       (notmuch-tree-close-message-pane-and #'notmuch-show-view-raw-message))
 335
 336     ;; The main tree view bindings
 337     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 338     (define-key map [mouse-1] 'notmuch-tree-show-message)
 339     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 340     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 341     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 342     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 343     (define-key map "z" 'notmuch-tree-to-tree)
 344     (define-key map "n" 'notmuch-tree-next-matching-message)
 345     (define-key map "p" 'notmuch-tree-prev-matching-message)
 346     (define-key map "N" 'notmuch-tree-next-message)
 347     (define-key map "P" 'notmuch-tree-prev-message)
 348     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 349     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 350     (define-key map "k" 'notmuch-tag-jump)
 351     (define-key map "-" 'notmuch-tree-remove-tag)
 352     (define-key map "+" 'notmuch-tree-add-tag)
 353     (define-key map "*" 'notmuch-tree-tag-thread)
 354     (define-key map " " 'notmuch-tree-scroll-or-next)
 355     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 356     (define-key map "e" 'notmuch-tree-resume-message)
 357     map))
 358 (fset 'notmuch-tree-mode-map notmuch-tree-mode-map)
 359
 360 (defun notmuch-tree-get-message-properties ()
 361   "Return the properties of the current message as a plist.
 362
 363 Some useful entries are:
 364 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 365 :tags - Tags for this message."
 366   (save-excursion
 367     (beginning-of-line)
 368     (get-text-property (point) :notmuch-message-properties)))
 369
 370 (defun notmuch-tree-set-message-properties (props)
 371   (save-excursion
 372     (beginning-of-line)
 373     (put-text-property (point)
 374                        (+ (point) 1)
 375                        :notmuch-message-properties props)))
 376
 377 (defun notmuch-tree-set-prop (prop val &optional props)
 378   (let ((inhibit-read-only t)
 379         (props (or props
 380                    (notmuch-tree-get-message-properties))))
 381     (plist-put props prop val)
 382     (notmuch-tree-set-message-properties props)))
 383
 384 (defun notmuch-tree-get-prop (prop &optional props)
 385   (let ((props (or props
 386                    (notmuch-tree-get-message-properties))))
 387     (plist-get props prop)))
 388
 389 (defun notmuch-tree-set-tags (tags)
 390   "Set the tags of the current message."
 391   (notmuch-tree-set-prop :tags tags))
 392
 393 (defun notmuch-tree-get-tags ()
 394   "Return the tags of the current message."
 395   (notmuch-tree-get-prop :tags))
 396
 397 (defun notmuch-tree-get-message-id (&optional bare)
 398   "Return the message id of the current message."
 399   (let ((id (notmuch-tree-get-prop :id)))
 400     (if id
 401         (if bare
 402             id
 403           (notmuch-id-to-query id))
 404       nil)))
 405
 406 (defun notmuch-tree-get-match ()
 407   "Return whether the current message is a match."
 408   (interactive)
 409   (notmuch-tree-get-prop :match))
 410
 411 (defun notmuch-tree-refresh-result ()
 412   "Redisplay the current message line.
 413
 414 This redisplays the current line based on the messages
 415 properties (as they are now). This is used when tags are
 416 updated."
 417   (let ((init-point (point))
 418         (end (line-end-position))
 419         (msg (notmuch-tree-get-message-properties))
 420         (inhibit-read-only t))
 421     (beginning-of-line)
 422     ;; This is a little tricky: we override
 423     ;; notmuch-tree-previous-subject to get the decision between
 424     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 425     ;; from overwriting the buffer local copy of
 426     ;; notmuch-tree-previous-subject if this is called while the
 427     ;; buffer is displaying.
 428     (let ((notmuch-tree-previous-subject
 429            (notmuch-tree-get-prop :previous-subject)))
 430       (delete-region (point) (1+ (line-end-position)))
 431       (notmuch-tree-insert-msg msg))
 432     (let ((new-end (line-end-position)))
 433       (goto-char (if (= init-point end)
 434                      new-end
 435                    (min init-point (- new-end 1)))))))
 436
 437 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 438   "Update display for TAG-CHANGES to current message.
 439
 440 Updates the message in the message pane if appropriate, but does
 441 NOT change the database."
 442   (let* ((current-tags (notmuch-tree-get-tags))
 443          (new-tags (notmuch-update-tags current-tags tag-changes))
 444          (tree-msg-id (notmuch-tree-get-message-id)))
 445     (unless (equal current-tags new-tags)
 446       (notmuch-tree-set-tags new-tags)
 447       (notmuch-tree-refresh-result)
 448       (when (window-live-p notmuch-tree-message-window)
 449         (with-selected-window notmuch-tree-message-window
 450           (when (string= tree-msg-id (notmuch-show-get-message-id))
 451             (notmuch-show-update-tags new-tags)))))))
 452
 453 (defun notmuch-tree-tag (tag-changes)
 454   "Change tags for the current message."
 455   (interactive
 456    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 457   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 458   (notmuch-tree-tag-update-display tag-changes))
 459
 460 (defun notmuch-tree-add-tag (tag-changes)
 461   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 462   (interactive
 463    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 464   (notmuch-tree-tag tag-changes))
 465
 466 (defun notmuch-tree-remove-tag (tag-changes)
 467   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 468   (interactive
 469    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 470   (notmuch-tree-tag tag-changes))
 471
 472 (defun notmuch-tree-resume-message ()
 473   "Resume EDITING the current draft message."
 474   (interactive)
 475   (notmuch-tree-close-message-window)
 476   (let ((id (notmuch-tree-get-message-id)))
 477     (if id
 478         (notmuch-draft-resume id)
 479       (message "No message to resume!"))))
 480
 481 ;; The next two functions close the message window before calling
 482 ;; notmuch-search or notmuch-tree but they do so after the user has
 483 ;; entered the query (in case the user was basing the query on
 484 ;; something in the message window).
 485
 486 (defun notmuch-tree-to-search ()
 487   "Run \"notmuch search\" with the given `query' and display results."
 488   (interactive)
 489   (let ((query (notmuch-read-query "Notmuch search: ")))
 490     (notmuch-tree-close-message-window)
 491     (notmuch-search query)))
 492
 493 (defun notmuch-tree-to-tree ()
 494   "Run a query and display results in tree view."
 495   (interactive)
 496   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 497     (notmuch-tree-close-message-window)
 498     (notmuch-tree query)))
 499
 500 (defun notmuch-tree-archive-thread-then-next ()
 501   "Archive all messages in the current buffer, then show next thread from search."
 502   (interactive)
 503   (notmuch-tree-archive-thread)
 504   (notmuch-tree-next-thread))
 505
 506 (defun notmuch-unthreaded-from-tree-current-query ()
 507   "Switch from tree view to unthreaded view."
 508   (interactive)
 509   (unless notmuch-tree-unthreaded
 510     (notmuch-tree-refresh-view 'unthreaded)))
 511
 512 (defun notmuch-tree-from-unthreaded-current-query ()
 513   "Switch from unthreaded view to tree view."
 514   (interactive)
 515   (when notmuch-tree-unthreaded
 516     (notmuch-tree-refresh-view 'tree)))
 517
 518 (defun notmuch-search-from-tree-current-query ()
 519   "Call notmuch search with the current query."
 520   (interactive)
 521   (notmuch-tree-close-message-window)
 522   (notmuch-search (notmuch-tree-get-query)))
 523
 524 (defun notmuch-tree-message-window-kill-hook ()
 525   "Close the message pane when exiting the show buffer."
 526   (let ((buffer (current-buffer)))
 527     (when (and (window-live-p notmuch-tree-message-window)
 528                (eq (window-buffer notmuch-tree-message-window) buffer))
 529       ;; We do not want an error if this is the sole window in the
 530       ;; frame and I do not know how to test for that in emacs pre
 531       ;; 24. Hence we just ignore-errors.
 532       (ignore-errors
 533         (delete-window notmuch-tree-message-window)))))
 534
 535 (defun notmuch-tree-command-hook ()
 536   (when (eq major-mode 'notmuch-tree-mode)
 537     ;; We just run the notmuch-show-command-hook on the message pane.
 538     (when (buffer-live-p notmuch-tree-message-buffer)
 539       (with-current-buffer notmuch-tree-message-buffer
 540         (notmuch-show-command-hook)))))
 541
 542 (defun notmuch-tree-show-message-in ()
 543   "Show the current message (in split-pane)."
 544   (interactive)
 545   (let ((id (notmuch-tree-get-message-id))
 546         (inhibit-read-only t)
 547         buffer)
 548     (when id
 549       ;; We close and reopen the window to kill off un-needed buffers
 550       ;; this might cause flickering but seems ok.
 551       (notmuch-tree-close-message-window)
 552       (setq notmuch-tree-message-window
 553             (split-window-vertically (/ (window-height) 4)))
 554       (with-selected-window notmuch-tree-message-window
 555         (let (;; Since we are only displaying one message do not indent.
 556               (notmuch-show-indent-messages-width 0)
 557               (notmuch-show-only-matching-messages t)
 558               ;; Ensure that `pop-to-buffer-same-window' uses the
 559               ;; window we want it to use.
 560               (display-buffer-overriding-action
 561                  '((display-buffer-same-window)
 562                    (inhibit-same-window . nil))))
 563           (setq buffer (notmuch-show id))))
 564       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 565       (let ((window notmuch-tree-message-window))
 566         (with-current-buffer buffer
 567           (setq notmuch-tree-message-window window)
 568           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 569       (when notmuch-show-mark-read-tags
 570         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 571       (setq notmuch-tree-message-buffer buffer))))
 572
 573 (defun notmuch-tree-show-message-out ()
 574   "Show the current message (in whole window)."
 575   (interactive)
 576   (let ((id (notmuch-tree-get-message-id))
 577         (inhibit-read-only t)
 578         buffer)
 579     (when id
 580       ;; We close the window to kill off un-needed buffers.
 581       (notmuch-tree-close-message-window)
 582       (notmuch-show id))))
 583
 584 (defun notmuch-tree-show-message (arg)
 585   "Show the current message.
 586
 587 Shows in split pane or whole window according to value of
 588 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 589   (interactive "P")
 590   (if (or (and (notmuch-tree-show-out) (not arg))
 591           (and (not (notmuch-tree-show-out)) arg))
 592       (notmuch-tree-show-message-out)
 593     (notmuch-tree-show-message-in)))
 594
 595 (defun notmuch-tree-scroll-message-window ()
 596   "Scroll the message window (if it exists)."
 597   (interactive)
 598   (when (window-live-p notmuch-tree-message-window)
 599     (with-selected-window notmuch-tree-message-window
 600       (if (pos-visible-in-window-p (point-max))
 601           t
 602         (scroll-up)))))
 603
 604 (defun notmuch-tree-scroll-message-window-back ()
 605   "Scroll the message window back (if it exists)."
 606   (interactive)
 607   (when (window-live-p notmuch-tree-message-window)
 608     (with-selected-window notmuch-tree-message-window
 609       (if (pos-visible-in-window-p (point-min))
 610           t
 611         (scroll-down)))))
 612
 613 (defun notmuch-tree-scroll-or-next ()
 614   "Scroll the message window.
 615 If it at end go to next message."
 616   (interactive)
 617   (when (notmuch-tree-scroll-message-window)
 618     (notmuch-tree-next-matching-message)))
 619
 620 (defun notmuch-tree-quit (&optional kill-both)
 621   "Close the split view or exit tree."
 622   (interactive "P")
 623   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 624     (kill-buffer (current-buffer))))
 625
 626 (defun notmuch-tree-close-message-window ()
 627   "Close the message-window. Return t if close succeeds."
 628   (interactive)
 629   (when (and (window-live-p notmuch-tree-message-window)
 630              (eq (window-buffer notmuch-tree-message-window)
 631                  notmuch-tree-message-buffer))
 632     (delete-window notmuch-tree-message-window)
 633     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 634       (kill-buffer notmuch-tree-message-buffer))
 635     t))
 636
 637 (defun notmuch-tree-archive-message (&optional unarchive)
 638   "Archive the current message.
 639
 640 Archive the current message by applying the tag changes in
 641 `notmuch-archive-tags' to it. If a prefix argument is given, the
 642 message will be \"unarchived\", i.e. the tag changes in
 643 `notmuch-archive-tags' will be reversed."
 644   (interactive "P")
 645   (when notmuch-archive-tags
 646     (notmuch-tree-tag
 647      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 648
 649 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 650   "Archive the current message and move to next matching message."
 651   (interactive "P")
 652   (notmuch-tree-archive-message unarchive)
 653   (notmuch-tree-next-matching-message))
 654
 655 (defun notmuch-tree-archive-thread-then-exit ()
 656   "Archive all messages in the current buffer, then exit notmuch-tree."
 657   (interactive)
 658   (notmuch-tree-archive-thread)
 659   (notmuch-tree-quit t))
 660
 661 (defun notmuch-tree-archive-message-then-next-or-exit ()
 662   "Archive current message, then show next open message in current thread.
 663
 664 If at the last open message in the current thread, then exit back
 665 to search results."
 666   (interactive)
 667   (notmuch-tree-archive-message)
 668   (notmuch-tree-next-matching-message t))
 669
 670 (defun notmuch-tree-next-message ()
 671   "Move to next message."
 672   (interactive)
 673   (forward-line)
 674   (when (window-live-p notmuch-tree-message-window)
 675     (notmuch-tree-show-message-in)))
 676
 677 (defun notmuch-tree-prev-message ()
 678   "Move to previous message."
 679   (interactive)
 680   (forward-line -1)
 681   (when (window-live-p notmuch-tree-message-window)
 682     (notmuch-tree-show-message-in)))
 683
 684 (defun notmuch-tree-goto-matching-message (&optional prev)
 685   "Move to the next or previous matching message.
 686
 687 Returns t if there was a next matching message in the thread to show,
 688 nil otherwise."
 689   (let ((dir (if prev -1 nil))
 690         (eobfn (if prev #'bobp #'eobp)))
 691     (while (and (not (funcall eobfn))
 692                 (not (notmuch-tree-get-match)))
 693       (forward-line dir))
 694     (not (funcall eobfn))))
 695
 696 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 697   "Move to the next or previous matching message."
 698   (interactive "P")
 699   (forward-line (if prev -1 nil))
 700   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 701       (notmuch-tree-quit pop-at-end)
 702     (when (window-live-p notmuch-tree-message-window)
 703       (notmuch-tree-show-message-in))))
 704
 705 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 706   "Move to previous matching message."
 707   (interactive "P")
 708   (notmuch-tree-matching-message t pop-at-end))
 709
 710 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 711   "Move to next matching message."
 712   (interactive "P")
 713   (notmuch-tree-matching-message nil pop-at-end))
 714
 715 (defun notmuch-tree-refresh-view (&optional view)
 716   "Refresh view."
 717   (interactive)
 718   (when (get-buffer-process (current-buffer))
 719     (error "notmuch tree process already running for current buffer"))
 720   (let ((inhibit-read-only t)
 721         (basic-query notmuch-tree-basic-query)
 722         (unthreaded (cond ((eq view 'unthreaded) t)
 723                           ((eq view 'tree) nil)
 724                           (t notmuch-tree-unthreaded)))
 725         (query-context notmuch-tree-query-context)
 726         (target (notmuch-tree-get-message-id)))
 727     (erase-buffer)
 728     (notmuch-tree-worker basic-query
 729                          query-context
 730                          target
 731                          nil
 732                          unthreaded)))
 733
 734 (defun notmuch-tree-thread-top ()
 735   (when (notmuch-tree-get-message-properties)
 736     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 737       (forward-line -1))))
 738
 739 (defun notmuch-tree-prev-thread-in-tree ()
 740   "Move to the previous thread in the current tree"
 741   (interactive)
 742   (forward-line -1)
 743   (notmuch-tree-thread-top)
 744   (not (bobp)))
 745
 746 (defun notmuch-tree-next-thread-in-tree ()
 747   "Get the next thread in the current tree. Returns t if a thread was
 748 found or nil if not."
 749   (interactive)
 750   (forward-line 1)
 751   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 752     (forward-line 1))
 753   (not (eobp)))
 754
 755 (defun notmuch-tree-next-thread-from-search (&optional previous)
 756   "Move to the next thread in the parent search results, if any.
 757
 758 If PREVIOUS is non-nil, move to the previous item in the
 759 search results instead."
 760   (interactive "P")
 761   (let ((parent-buffer notmuch-tree-parent-buffer))
 762     (notmuch-tree-quit t)
 763     (when (buffer-live-p parent-buffer)
 764       (switch-to-buffer parent-buffer)
 765       (if previous
 766           (notmuch-search-previous-thread)
 767         (notmuch-search-next-thread))
 768       (notmuch-tree-from-search-thread))))
 769
 770 (defun notmuch-tree-next-thread (&optional previous)
 771   "Move to the next thread in the current tree or parent search
 772 results
 773
 774 If PREVIOUS is non-nil, move to the previous thread in the tree or
 775 search results instead."
 776   (interactive)
 777   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 778             (notmuch-tree-next-thread-in-tree))
 779     (notmuch-tree-next-thread-from-search previous)))
 780
 781 (defun notmuch-tree-prev-thread ()
 782   "Move to the previous thread in the current tree or parent search
 783 results"
 784   (interactive)
 785   (notmuch-tree-next-thread t))
 786
 787 (defun notmuch-tree-thread-mapcar (function)
 788   "Iterate through all messages in the current thread
 789  and call FUNCTION for side effects."
 790   (save-excursion
 791     (notmuch-tree-thread-top)
 792     (cl-loop collect (funcall function)
 793              do (forward-line)
 794              while (and (notmuch-tree-get-message-properties)
 795                         (not (notmuch-tree-get-prop :first))))))
 796
 797 (defun notmuch-tree-get-messages-ids-thread-search ()
 798   "Return a search string for all message ids of messages in the current thread."
 799   (mapconcat 'identity
 800              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 801              " or "))
 802
 803 (defun notmuch-tree-tag-thread (tag-changes)
 804   "Tag all messages in the current thread."
 805   (interactive
 806    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 807                                 (lambda () (notmuch-tree-get-tags))))))
 808      (list (notmuch-read-tag-changes tags "Tag thread"))))
 809   (when (notmuch-tree-get-message-properties)
 810     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 811     (notmuch-tree-thread-mapcar
 812      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 813
 814 (defun notmuch-tree-archive-thread (&optional unarchive)
 815   "Archive each message in thread.
 816
 817 Archive each message currently shown by applying the tag changes
 818 in `notmuch-archive-tags' to each. If a prefix argument is given,
 819 the messages will be \"unarchived\", i.e. the tag changes in
 820 `notmuch-archive-tags' will be reversed.
 821
 822 Note: This command is safe from any race condition of new messages
 823 being delivered to the same thread. It does not archive the
 824 entire thread, but only the messages shown in the current
 825 buffer."
 826   (interactive "P")
 827   (when notmuch-archive-tags
 828     (notmuch-tree-tag-thread
 829      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 830
 831 ;; Functions below here display the tree buffer itself.
 832
 833 (defun notmuch-tree-clean-address (address)
 834   "Try to clean a single email ADDRESS for display. Return
 835 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 836 unchanged ADDRESS if parsing fails."
 837   (let* ((clean-address (notmuch-clean-address address))
 838          (p-address (car clean-address))
 839          (p-name (cdr clean-address)))
 840
 841     ;; If we have a name return that otherwise return the address.
 842     (or p-name p-address)))
 843
 844 (defun notmuch-tree-format-field (field format-string msg)
 845   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 846   (let* ((headers (plist-get msg :headers))
 847          (match (plist-get msg :match)))
 848     (cond
 849      ((listp field)
 850       (format format-string (notmuch-tree-format-field-list field msg)))
 851
 852      ((string-equal field "date")
 853       (let ((face (if match
 854                       'notmuch-tree-match-date-face
 855                     'notmuch-tree-no-match-date-face)))
 856         (propertize (format format-string (plist-get msg :date_relative))
 857                     'face face)))
 858
 859      ((string-equal field "tree")
 860       (let ((tree-status (plist-get msg :tree-status))
 861             (face (if match
 862                       'notmuch-tree-match-tree-face
 863                     'notmuch-tree-no-match-tree-face)))
 864
 865         (propertize (format format-string
 866                             (mapconcat #'identity (reverse tree-status) ""))
 867                     'face face)))
 868
 869      ((string-equal field "subject")
 870       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 871             (previous-subject notmuch-tree-previous-subject)
 872             (face (if match
 873                       'notmuch-tree-match-subject-face
 874                     'notmuch-tree-no-match-subject-face)))
 875
 876         (setq notmuch-tree-previous-subject bare-subject)
 877         (propertize (format format-string
 878                             (if (string= previous-subject bare-subject)
 879                                 " ..."
 880                               bare-subject))
 881                     'face face)))
 882
 883      ((string-equal field "authors")
 884       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 885             (len (length (format format-string "")))
 886             (face (if match
 887                       'notmuch-tree-match-author-face
 888                     'notmuch-tree-no-match-author-face)))
 889         (when (> (length author) len)
 890           (setq author (substring author 0 len)))
 891         (propertize (format format-string author) 'face face)))
 892
 893      ((string-equal field "tags")
 894       (let ((tags (plist-get msg :tags))
 895             (orig-tags (plist-get msg :orig-tags))
 896             (face (if match
 897                       'notmuch-tree-match-tag-face
 898                     'notmuch-tree-no-match-tag-face)))
 899         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 900
 901 (defun notmuch-tree-format-field-list (field-list msg)
 902   "Format fields of MSG according to FIELD-LIST and return string."
 903   (let ((face (if (plist-get msg :match)
 904                   'notmuch-tree-match-face
 905                 'notmuch-tree-no-match-face))
 906         (result-string))
 907     (dolist (spec field-list result-string)
 908       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 909         (setq result-string (concat result-string field-string))))
 910     (notmuch-apply-face result-string face t)))
 911
 912 (defun notmuch-tree-insert-msg (msg)
 913   "Insert the message MSG according to notmuch-tree-result-format."
 914   ;; We need to save the previous subject as it will get overwritten
 915   ;; by the insert-field calls.
 916   (let ((previous-subject notmuch-tree-previous-subject))
 917     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 918     (notmuch-tree-set-message-properties msg)
 919     (notmuch-tree-set-prop :previous-subject previous-subject)
 920     (insert "\n")))
 921
 922 (defun notmuch-tree-goto-and-insert-msg (msg)
 923   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 924   (save-excursion
 925     (goto-char (point-max))
 926     (notmuch-tree-insert-msg msg))
 927   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 928         (target notmuch-tree-target-msg))
 929     (when (or (and (not target) (plist-get msg :match))
 930               (string= msg-id target))
 931       (setq notmuch-tree-target-msg "found")
 932       (goto-char (point-max))
 933       (forward-line -1)
 934       (when notmuch-tree-open-target
 935         (notmuch-tree-show-message-in)))))
 936
 937 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 938   "Insert the message tree TREE at depth DEPTH in the current thread.
 939
 940 A message tree is another name for a single sub-thread: i.e., a
 941 message together with all its descendents."
 942   (let ((msg (car tree))
 943         (replies (cadr tree)))
 944     (cond
 945      ((and (< 0 depth) (not last))
 946       (push "├" tree-status))
 947      ((and (< 0 depth) last)
 948       (push "╰" tree-status))
 949      ((and (eq 0 depth) first last)
 950       ;; Choice between these two variants is a matter of taste.
 951       ;; (push "─" tree-status))
 952       (push " " tree-status))
 953      ((and (eq 0 depth) first (not last))
 954       (push "┬" tree-status))
 955      ((and (eq 0 depth) (not first) last)
 956       (push "╰" tree-status))
 957      ((and (eq 0 depth) (not first) (not last))
 958       (push "├" tree-status)))
 959     (push (concat (if replies "┬" "─") "►") tree-status)
 960     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 961     (setq msg (plist-put msg :tree-status tree-status))
 962     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 963     (notmuch-tree-goto-and-insert-msg msg)
 964     (pop tree-status)
 965     (pop tree-status)
 966     (if last
 967         (push " " tree-status)
 968       (push "│" tree-status))
 969     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 970
 971 (defun notmuch-tree-insert-thread (thread depth tree-status)
 972   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 973   (let ((n (length thread)))
 974     (cl-loop for tree in thread
 975              for count from 1 to n
 976              do (notmuch-tree-insert-tree tree depth tree-status
 977                                           (eq count 1)
 978                                           (eq count n)))))
 979
 980 (defun notmuch-tree-insert-forest-thread (forest-thread)
 981   "Insert a single complete thread."
 982   (let (tree-status)
 983     ;; Reset at the start of each main thread.
 984     (setq notmuch-tree-previous-subject nil)
 985     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
 986
 987 (defun notmuch-tree-insert-forest (forest)
 988   "Insert a forest of threads.
 989
 990 This function inserts a collection of several complete threads as
 991 passed to it by notmuch-tree-process-filter."
 992   (mapc 'notmuch-tree-insert-forest-thread forest))
 993
 994 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
 995   "Major mode displaying messages (as opposed to threads) of a notmuch search.
 996
 997 This buffer contains the results of a \"notmuch tree\" of your
 998 email archives. Each line in the buffer represents a single
 999 message giving the relative date, the author, subject, and any
1000 tags.
1001
1002 Pressing \\[notmuch-tree-show-message] on any line displays that message.
1003
1004 Complete list of currently available key bindings:
1005
1006 \\{notmuch-tree-mode-map}"
1007   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1008   (hl-line-mode 1)
1009   (setq buffer-read-only t)
1010   (setq truncate-lines t))
1011
1012 (defun notmuch-tree-process-sentinel (proc msg)
1013   "Add a message to let user know when \"notmuch tree\" exits."
1014   (let ((buffer (process-buffer proc))
1015         (status (process-status proc))
1016         (exit-status (process-exit-status proc))
1017         (never-found-target-thread nil))
1018     (when (memq status '(exit signal))
1019       (kill-buffer (process-get proc 'parse-buf))
1020       (when (buffer-live-p buffer)
1021         (with-current-buffer buffer
1022           (save-excursion
1023             (let ((inhibit-read-only t)
1024                   (atbob (bobp)))
1025               (goto-char (point-max))
1026               (when (eq status 'signal)
1027                 (insert "Incomplete search results (tree view process was killed).\n"))
1028               (when (eq status 'exit)
1029                 (insert "End of search results.")
1030                 (unless (= exit-status 0)
1031                   (insert (format " (process returned %d)" exit-status)))
1032                 (insert "\n")))))))))
1033
1034 (defun notmuch-tree-process-filter (proc string)
1035   "Process and filter the output of \"notmuch show\" for tree view."
1036   (let ((results-buf (process-buffer proc))
1037         (parse-buf (process-get proc 'parse-buf))
1038         (inhibit-read-only t)
1039         done)
1040     (if (not (buffer-live-p results-buf))
1041         (delete-process proc)
1042       (with-current-buffer parse-buf
1043         ;; Insert new data
1044         (save-excursion
1045           (goto-char (point-max))
1046           (insert string))
1047         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1048                                          results-buf)))))
1049
1050 (defun notmuch-tree-worker (basic-query &optional query-context target open-target unthreaded)
1051   "Insert the tree view of the search in the current buffer.
1052
1053 This is is a helper function for notmuch-tree. The arguments are
1054 the same as for the function notmuch-tree."
1055   (interactive)
1056   (notmuch-tree-mode)
1057   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1058   (setq notmuch-tree-unthreaded unthreaded)
1059   (setq notmuch-tree-basic-query basic-query)
1060   (setq notmuch-tree-query-context (if (or (string= query-context "")
1061                                            (string= query-context "*"))
1062                                        nil
1063                                      query-context))
1064   (setq notmuch-tree-target-msg target)
1065   (setq notmuch-tree-open-target open-target)
1066   ;; Set the default value for `notmuch-show-process-crypto' in this
1067   ;; buffer. Although we don't use this some of the functions we call
1068   ;; (such as reply) do. It is a buffer local variable so setting it
1069   ;; will not affect genuine show buffers.
1070   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1071   (erase-buffer)
1072   (goto-char (point-min))
1073   (let* ((search-args (concat basic-query
1074                               (and query-context
1075                                    (concat " and (" query-context ")"))))
1076          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1077     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1078       (setq search-args basic-query))
1079     (notmuch-tag-clear-cache)
1080     (let ((proc (notmuch-start-notmuch
1081                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1082                  "show" "--body=false" "--format=sexp" "--format-version=4"
1083                  message-arg search-args))
1084           ;; Use a scratch buffer to accumulate partial output.
1085           ;; This buffer will be killed by the sentinel, which
1086           ;; should be called no matter how the process dies.
1087           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1088       (process-put proc 'parse-buf parse-buf)
1089       (set-process-filter proc 'notmuch-tree-process-filter)
1090       (set-process-query-on-exit-flag proc nil))))
1091
1092 (defun notmuch-tree-get-query ()
1093   "Return the current query in this tree buffer."
1094   (if notmuch-tree-query-context
1095       (concat notmuch-tree-basic-query
1096               " and ("
1097               notmuch-tree-query-context
1098               ")")
1099     notmuch-tree-basic-query))
1100
1101 (defun notmuch-tree (&optional query query-context target buffer-name open-target unthreaded parent-buffer)
1102   "Display threads matching QUERY in tree view.
1103
1104 The arguments are:
1105   QUERY: the main query. This can be any query but in many cases will be
1106       a single thread. If nil this is read interactively from the minibuffer.
1107   QUERY-CONTEXT: is an additional term for the query. The query used
1108       is QUERY and QUERY-CONTEXT unless that does not match any messages
1109       in which case we fall back to just QUERY.
1110   TARGET: A message ID (with the id: prefix) that will be made
1111       current if it appears in the tree view results.
1112   BUFFER-NAME: the name of the buffer to display the tree view. If
1113       it is nil \"*notmuch-tree\" followed by QUERY is used.
1114   OPEN-TARGET: If TRUE open the target message in the message pane.
1115   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1116   (interactive)
1117   (unless query
1118     (setq query (notmuch-read-query (concat "Notmuch "
1119                                             (if unthreaded "unthreaded " "tree ")
1120                                             "view search: "))))
1121   (let ((buffer (get-buffer-create (generate-new-buffer-name
1122                                     (or buffer-name
1123                                         (concat "*notmuch-"
1124                                                 (if unthreaded "unthreaded-" "tree-")
1125                                                 query "*")))))
1126         (inhibit-read-only t))
1127     (pop-to-buffer-same-window buffer))
1128   ;; Don't track undo information for this buffer
1129   (set 'buffer-undo-list t)
1130   (notmuch-tree-worker query query-context target open-target unthreaded)
1131   (setq notmuch-tree-parent-buffer parent-buffer)
1132   (setq truncate-lines t))
1133
1134 (defun notmuch-unthreaded (&optional query query-context target buffer-name open-target)
1135   (interactive)
1136   (notmuch-tree query query-context target buffer-name open-target t))
1137
1138 ;;
1139
1140 (provide 'notmuch-tree)
1141
1142 ;;; notmuch-tree.el ends here