git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28
  29 (require 'notmuch-lib)
  30 (require 'notmuch-query)
  31 (require 'notmuch-show)
  32 (require 'notmuch-tag)
  33 (require 'notmuch-parser)
  34 (require 'notmuch-jump)
  35
  36 (declare-function notmuch-search "notmuch"
  37                   (&optional query oldest-first target-thread target-line
  38                              no-display))
  39 (declare-function notmuch-call-notmuch-process "notmuch-lib" (&rest args))
  40 (declare-function notmuch-read-query "notmuch" (prompt))
  41 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  42 (declare-function notmuch-search-find-subject "notmuch" ())
  43
  44 ;; For `notmuch-tree-next-thread-from-search'.
  45 (declare-function notmuch-search-next-thread "notmuch" ())
  46 (declare-function notmuch-search-previous-thread "notmuch" ())
  47 (declare-function notmuch-tree-from-search-thread "notmuch" ())
  48
  49 ;; the following variable is defined in notmuch.el
  50 (defvar notmuch-search-query-string)
  51
  52 ;; this variable distinguishes the unthreaded display from the normal tree display
  53 (defvar-local notmuch-tree-unthreaded nil
  54   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  55
  56 ;;; Options
  57
  58 (defgroup notmuch-tree nil
  59   "Showing message and thread structure."
  60   :group 'notmuch)
  61
  62 (defcustom notmuch-tree-show-out nil
  63   "View selected messages in new window rather than split-pane."
  64   :type 'boolean
  65   :group 'notmuch-tree)
  66
  67 (defcustom notmuch-unthreaded-show-out t
  68   "View selected messages in new window rather than split-pane."
  69   :type 'boolean
  70   :group 'notmuch-tree)
  71
  72 (defun notmuch-tree-show-out ()
  73   (if notmuch-tree-unthreaded
  74       notmuch-unthreaded-show-out
  75     notmuch-tree-show-out))
  76
  77 (defcustom notmuch-tree-result-format
  78   `(("date" . "%12s  ")
  79     ("authors" . "%-20s")
  80     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  81     ("tags" . "(%s)"))
  82   "Result formatting for tree view. Supported fields are: date,
  83 authors, subject, tree, tags.  Tree means the thread tree
  84 box graphics. The field may also be a list in which case
  85 the formatting rules are applied recursively and then the
  86 output of all the fields in the list is inserted
  87 according to format-string.
  88
  89 Note the author string should not contain
  90 whitespace (put it in the neighbouring fields instead).
  91 For example:
  92         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  93                                           \(\"subject\" . \"%s\"\)\)\)"
  94   :type '(alist :key-type (string) :value-type (string))
  95   :group 'notmuch-tree)
  96
  97 (defcustom notmuch-unthreaded-result-format
  98   `(("date" . "%12s  ")
  99     ("authors" . "%-20s")
 100     ((("subject" . "%s")) ." %-54s ")
 101     ("tags" . "(%s)"))
 102   "Result formatting for unthreaded tree view. Supported fields are: date,
 103 authors, subject, tree, tags.  Tree means the thread tree
 104 box graphics. The field may also be a list in which case
 105 the formatting rules are applied recursively and then the
 106 output of all the fields in the list is inserted
 107 according to format-string.
 108
 109 Note the author string should not contain
 110 whitespace (put it in the neighbouring fields instead).
 111 For example:
 112         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 113                                           \(\"subject\" . \"%s\"\)\)\)"
 114   :type '(alist :key-type (string) :value-type (string))
 115   :group 'notmuch-tree)
 116
 117 (defun notmuch-tree-result-format ()
 118   (if notmuch-tree-unthreaded
 119       notmuch-unthreaded-result-format
 120     notmuch-tree-result-format))
 121
 122 ;;; Faces
 123 ;;;; Faces for messages that match the query
 124
 125 (defface notmuch-tree-match-face
 126   '((t :inherit default))
 127   "Default face used in tree mode face for matching messages"
 128   :group 'notmuch-tree
 129   :group 'notmuch-faces)
 130
 131 (defface notmuch-tree-match-date-face
 132   nil
 133   "Face used in tree mode for the date in messages matching the query."
 134   :group 'notmuch-tree
 135   :group 'notmuch-faces)
 136
 137 (defface notmuch-tree-match-author-face
 138   '((((class color)
 139       (background dark))
 140      (:foreground "OliveDrab1"))
 141     (((class color)
 142       (background light))
 143      (:foreground "dark blue"))
 144     (t
 145      (:bold t)))
 146   "Face used in tree mode for the date in messages matching the query."
 147   :group 'notmuch-tree
 148   :group 'notmuch-faces)
 149
 150 (defface notmuch-tree-match-subject-face
 151   nil
 152   "Face used in tree mode for the subject in messages matching the query."
 153   :group 'notmuch-tree
 154   :group 'notmuch-faces)
 155
 156 (defface notmuch-tree-match-tree-face
 157   nil
 158   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 159   :group 'notmuch-tree
 160   :group 'notmuch-faces)
 161
 162 (defface notmuch-tree-match-tag-face
 163   '((((class color)
 164       (background dark))
 165      (:foreground "OliveDrab1"))
 166     (((class color)
 167       (background light))
 168      (:foreground "navy blue" :bold t))
 169     (t
 170      (:bold t)))
 171   "Face used in tree mode for tags in messages matching the query."
 172   :group 'notmuch-tree
 173   :group 'notmuch-faces)
 174
 175 ;;;; Faces for messages that do not match the query
 176
 177 (defface notmuch-tree-no-match-face
 178   '((t (:foreground "gray")))
 179   "Default face used in tree mode face for non-matching messages."
 180   :group 'notmuch-tree
 181   :group 'notmuch-faces)
 182
 183 (defface notmuch-tree-no-match-date-face
 184   nil
 185   "Face used in tree mode for non-matching dates."
 186   :group 'notmuch-tree
 187   :group 'notmuch-faces)
 188
 189 (defface notmuch-tree-no-match-subject-face
 190   nil
 191   "Face used in tree mode for non-matching subjects."
 192   :group 'notmuch-tree
 193   :group 'notmuch-faces)
 194
 195 (defface notmuch-tree-no-match-tree-face
 196   nil
 197   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 198   :group 'notmuch-tree
 199   :group 'notmuch-faces)
 200
 201 (defface notmuch-tree-no-match-author-face
 202   nil
 203   "Face used in tree mode for the date in messages matching the query."
 204   :group 'notmuch-tree
 205   :group 'notmuch-faces)
 206
 207 (defface notmuch-tree-no-match-tag-face
 208   nil
 209   "Face used in tree mode face for non-matching tags."
 210   :group 'notmuch-tree
 211   :group 'notmuch-faces)
 212
 213 ;;; Variables
 214
 215 (defvar-local notmuch-tree-previous-subject
 216   "The subject of the most recent result shown during the async display.")
 217
 218 (defvar-local notmuch-tree-basic-query nil
 219   "A buffer local copy of argument query to the function notmuch-tree.")
 220
 221 (defvar-local notmuch-tree-query-context nil
 222   "A buffer local copy of argument query-context to the function notmuch-tree.")
 223
 224 (defvar-local notmuch-tree-target-msg nil
 225   "A buffer local copy of argument target to the function notmuch-tree.")
 226
 227 (defvar-local notmuch-tree-open-target nil
 228   "A buffer local copy of argument open-target to the function notmuch-tree.")
 229
 230 (defvar-local notmuch-tree-parent-buffer nil)
 231
 232 (defvar-local notmuch-tree-message-window nil
 233   "The window of the message pane.
 234
 235 It is set in both the tree buffer and the child show buffer. It
 236 is used to try and close the message pane when quitting tree view
 237 or the child show buffer.")
 238 (put 'notmuch-tree-message-window 'permanent-local t)
 239
 240 (defvar-local notmuch-tree-message-buffer nil
 241   "The buffer name of the show buffer in the message pane.
 242
 243 This is used to try and make sure we don't close the message pane
 244 if the user has loaded a different buffer in that window.")
 245 (put 'notmuch-tree-message-buffer 'permanent-local t)
 246
 247 ;;; Tree wrapper commands
 248
 249 (defmacro notmuch-tree--define-do-in-message-window (name cmd)
 250   "Define NAME as a command that calls CMD interactively in the message window.
 251 If the message pane is closed then this command does nothing.
 252 Avoid using this macro in new code; it will be removed."
 253   `(defun ,name ()
 254      ,(concat "(In message window) " (documentation cmd t))
 255      (interactive)
 256      (when (window-live-p notmuch-tree-message-window)
 257        (with-selected-window notmuch-tree-message-window
 258          (call-interactively #',cmd)))))
 259
 260 (notmuch-tree--define-do-in-message-window
 261  notmuch-tree-previous-message-button
 262  notmuch-show-previous-button)
 263 (notmuch-tree--define-do-in-message-window
 264  notmuch-tree-next-message-button
 265  notmuch-show-next-button)
 266 (notmuch-tree--define-do-in-message-window
 267  notmuch-tree-toggle-message-process-crypto
 268  notmuch-show-toggle-process-crypto)
 269
 270 (defun notmuch-tree--message-process-crypto ()
 271   "Return value of `notmuch-show-process-crypto' in the message window.
 272 If that window isn't alive, then return the current value.
 273 Avoid using this function in new code; it will be removed."
 274   (if (window-live-p notmuch-tree-message-window)
 275       (with-selected-window notmuch-tree-message-window
 276         notmuch-show-process-crypto)
 277     notmuch-show-process-crypto))
 278
 279 (defmacro notmuch-tree--define-close-message-window-and (name cmd)
 280   "Define NAME as a variant of CMD.
 281
 282 NAME determines the value of `notmuch-show-process-crypto' in the
 283 message window, closes the window, and then call CMD interactively
 284 with that value let-bound.  If the message window does not exist,
 285 then NAME behaves like CMD."
 286   `(defun ,name ()
 287      ,(concat "(Close message pane and) " (documentation cmd t))
 288      (interactive)
 289      (let ((notmuch-show-process-crypto
 290             (notmuch-tree--message-process-crypto)))
 291        (notmuch-tree-close-message-window)
 292        (call-interactively #',cmd))))
 293
 294 (notmuch-tree--define-close-message-window-and
 295  notmuch-tree-help
 296  notmuch-help)
 297 (notmuch-tree--define-close-message-window-and
 298  notmuch-tree-new-mail
 299  notmuch-mua-new-mail)
 300 (notmuch-tree--define-close-message-window-and
 301  notmuch-tree-jump-search
 302  notmuch-jump-search)
 303 (notmuch-tree--define-close-message-window-and
 304  notmuch-tree-forward-message
 305  notmuch-show-forward-message)
 306 (notmuch-tree--define-close-message-window-and
 307  notmuch-tree-reply-sender
 308  notmuch-show-reply-sender)
 309 (notmuch-tree--define-close-message-window-and
 310  notmuch-tree-reply
 311  notmuch-show-reply)
 312 (notmuch-tree--define-close-message-window-and
 313  notmuch-tree-view-raw-message
 314  notmuch-show-view-raw-message)
 315
 316 ;;; Keymap
 317
 318 (defvar notmuch-tree-mode-map
 319   (let ((map (make-sparse-keymap)))
 320     (set-keymap-parent map notmuch-common-keymap)
 321     ;; These bindings shadow common bindings with variants
 322     ;; that additionally close the message window.
 323     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 324     (define-key map [remap notmuch-search]       'notmuch-tree-to-search)
 325     (define-key map [remap notmuch-help]         'notmuch-tree-help)
 326     (define-key map [remap notmuch-mua-new-mail] 'notmuch-tree-new-mail)
 327     (define-key map [remap notmuch-jump-search]  'notmuch-tree-jump-search)
 328
 329     (define-key map "S" 'notmuch-search-from-tree-current-query)
 330     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 331     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 332
 333     ;; these use notmuch-show functions directly
 334     (define-key map "|" 'notmuch-show-pipe-message)
 335     (define-key map "w" 'notmuch-show-save-attachments)
 336     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 337     (define-key map "c" 'notmuch-show-stash-map)
 338     (define-key map "b" 'notmuch-show-resend-message)
 339
 340     ;; these apply to the message pane
 341     (define-key map (kbd "M-TAB")     'notmuch-tree-previous-message-button)
 342     (define-key map (kbd "<backtab>") 'notmuch-tree-previous-message-button)
 343     (define-key map (kbd "TAB")       'notmuch-tree-next-message-button)
 344     (define-key map "$" 'notmuch-tree-toggle-message-process-crypto)
 345
 346     ;; bindings from show (or elsewhere) but we close the message pane first.
 347     (define-key map "f" 'notmuch-tree-forward-message)
 348     (define-key map "r" 'notmuch-tree-reply-sender)
 349     (define-key map "R" 'notmuch-tree-reply)
 350     (define-key map "V" 'notmuch-tree-view-raw-message)
 351
 352     ;; The main tree view bindings
 353     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 354     (define-key map [mouse-1] 'notmuch-tree-show-message)
 355     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 356     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 357     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 358     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 359     (define-key map "z" 'notmuch-tree-to-tree)
 360     (define-key map "n" 'notmuch-tree-next-matching-message)
 361     (define-key map "p" 'notmuch-tree-prev-matching-message)
 362     (define-key map "N" 'notmuch-tree-next-message)
 363     (define-key map "P" 'notmuch-tree-prev-message)
 364     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 365     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 366     (define-key map "k" 'notmuch-tag-jump)
 367     (define-key map "-" 'notmuch-tree-remove-tag)
 368     (define-key map "+" 'notmuch-tree-add-tag)
 369     (define-key map "*" 'notmuch-tree-tag-thread)
 370     (define-key map " " 'notmuch-tree-scroll-or-next)
 371     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 372     (define-key map "e" 'notmuch-tree-resume-message)
 373     map)
 374   "Keymap for \"notmuch tree\" buffers.")
 375
 376 ;;; Message properties
 377
 378 (defun notmuch-tree-get-message-properties ()
 379   "Return the properties of the current message as a plist.
 380
 381 Some useful entries are:
 382 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 383 :tags - Tags for this message."
 384   (save-excursion
 385     (beginning-of-line)
 386     (get-text-property (point) :notmuch-message-properties)))
 387
 388 (defun notmuch-tree-set-message-properties (props)
 389   (save-excursion
 390     (beginning-of-line)
 391     (put-text-property (point)
 392                        (+ (point) 1)
 393                        :notmuch-message-properties props)))
 394
 395 (defun notmuch-tree-set-prop (prop val &optional props)
 396   (let ((inhibit-read-only t)
 397         (props (or props
 398                    (notmuch-tree-get-message-properties))))
 399     (plist-put props prop val)
 400     (notmuch-tree-set-message-properties props)))
 401
 402 (defun notmuch-tree-get-prop (prop &optional props)
 403   (plist-get (or props (notmuch-tree-get-message-properties))
 404              prop))
 405
 406 (defun notmuch-tree-set-tags (tags)
 407   "Set the tags of the current message."
 408   (notmuch-tree-set-prop :tags tags))
 409
 410 (defun notmuch-tree-get-tags ()
 411   "Return the tags of the current message."
 412   (notmuch-tree-get-prop :tags))
 413
 414 (defun notmuch-tree-get-message-id (&optional bare)
 415   "Return the message id of the current message."
 416   (let ((id (notmuch-tree-get-prop :id)))
 417     (if id
 418         (if bare
 419             id
 420           (notmuch-id-to-query id))
 421       nil)))
 422
 423 (defun notmuch-tree-get-match ()
 424   "Return whether the current message is a match."
 425   (notmuch-tree-get-prop :match))
 426
 427 ;;; Update display
 428
 429 (defun notmuch-tree-refresh-result ()
 430   "Redisplay the current message line.
 431
 432 This redisplays the current line based on the messages
 433 properties (as they are now). This is used when tags are
 434 updated."
 435   (let ((init-point (point))
 436         (end (line-end-position))
 437         (msg (notmuch-tree-get-message-properties))
 438         (inhibit-read-only t))
 439     (beginning-of-line)
 440     ;; This is a little tricky: we override
 441     ;; notmuch-tree-previous-subject to get the decision between
 442     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 443     ;; from overwriting the buffer local copy of
 444     ;; notmuch-tree-previous-subject if this is called while the
 445     ;; buffer is displaying.
 446     (let ((notmuch-tree-previous-subject
 447            (notmuch-tree-get-prop :previous-subject)))
 448       (delete-region (point) (1+ (line-end-position)))
 449       (notmuch-tree-insert-msg msg))
 450     (let ((new-end (line-end-position)))
 451       (goto-char (if (= init-point end)
 452                      new-end
 453                    (min init-point (- new-end 1)))))))
 454
 455 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 456   "Update display for TAG-CHANGES to current message.
 457
 458 Updates the message in the message pane if appropriate, but does
 459 NOT change the database."
 460   (let* ((current-tags (notmuch-tree-get-tags))
 461          (new-tags (notmuch-update-tags current-tags tag-changes))
 462          (tree-msg-id (notmuch-tree-get-message-id)))
 463     (unless (equal current-tags new-tags)
 464       (notmuch-tree-set-tags new-tags)
 465       (notmuch-tree-refresh-result)
 466       (when (window-live-p notmuch-tree-message-window)
 467         (with-selected-window notmuch-tree-message-window
 468           (when (string= tree-msg-id (notmuch-show-get-message-id))
 469             (notmuch-show-update-tags new-tags)))))))
 470
 471 ;;; Commands (and some helper functions used by them)
 472
 473 (defun notmuch-tree-tag (tag-changes)
 474   "Change tags for the current message."
 475   (interactive
 476    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 477   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 478   (notmuch-tree-tag-update-display tag-changes))
 479
 480 (defun notmuch-tree-add-tag (tag-changes)
 481   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 482   (interactive
 483    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 484   (notmuch-tree-tag tag-changes))
 485
 486 (defun notmuch-tree-remove-tag (tag-changes)
 487   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 488   (interactive
 489    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 490   (notmuch-tree-tag tag-changes))
 491
 492 (defun notmuch-tree-resume-message ()
 493   "Resume EDITING the current draft message."
 494   (interactive)
 495   (notmuch-tree-close-message-window)
 496   (let ((id (notmuch-tree-get-message-id)))
 497     (if id
 498         (notmuch-draft-resume id)
 499       (message "No message to resume!"))))
 500
 501 ;; The next two functions close the message window before calling
 502 ;; notmuch-search or notmuch-tree but they do so after the user has
 503 ;; entered the query (in case the user was basing the query on
 504 ;; something in the message window).
 505
 506 (defun notmuch-tree-to-search ()
 507   "Run \"notmuch search\" with the given `query' and display results."
 508   (interactive)
 509   (let ((query (notmuch-read-query "Notmuch search: ")))
 510     (notmuch-tree-close-message-window)
 511     (notmuch-search query)))
 512
 513 (defun notmuch-tree-to-tree ()
 514   "Run a query and display results in tree view."
 515   (interactive)
 516   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 517     (notmuch-tree-close-message-window)
 518     (notmuch-tree query)))
 519
 520 (defun notmuch-tree-archive-thread-then-next ()
 521   "Archive all messages in the current buffer, then show next thread from search."
 522   (interactive)
 523   (notmuch-tree-archive-thread)
 524   (notmuch-tree-next-thread))
 525
 526 (defun notmuch-unthreaded-from-tree-current-query ()
 527   "Switch from tree view to unthreaded view."
 528   (interactive)
 529   (unless notmuch-tree-unthreaded
 530     (notmuch-tree-refresh-view 'unthreaded)))
 531
 532 (defun notmuch-tree-from-unthreaded-current-query ()
 533   "Switch from unthreaded view to tree view."
 534   (interactive)
 535   (when notmuch-tree-unthreaded
 536     (notmuch-tree-refresh-view 'tree)))
 537
 538 (defun notmuch-search-from-tree-current-query ()
 539   "Call notmuch search with the current query."
 540   (interactive)
 541   (notmuch-tree-close-message-window)
 542   (notmuch-search (notmuch-tree-get-query)))
 543
 544 (defun notmuch-tree-message-window-kill-hook ()
 545   "Close the message pane when exiting the show buffer."
 546   (let ((buffer (current-buffer)))
 547     (when (and (window-live-p notmuch-tree-message-window)
 548                (eq (window-buffer notmuch-tree-message-window) buffer))
 549       ;; We could check whether this is the only window in its frame,
 550       ;; but simply ignoring the error that is thrown otherwise is
 551       ;; what we had to do for Emacs 24 and we stick to that because
 552       ;; it is still the simplest approach.
 553       (ignore-errors
 554         (delete-window notmuch-tree-message-window)))))
 555
 556 (defun notmuch-tree-command-hook ()
 557   (when (eq major-mode 'notmuch-tree-mode)
 558     ;; We just run the notmuch-show-command-hook on the message pane.
 559     (when (buffer-live-p notmuch-tree-message-buffer)
 560       (with-current-buffer notmuch-tree-message-buffer
 561         (notmuch-show-command-hook)))))
 562
 563 (defun notmuch-tree-show-message-in ()
 564   "Show the current message (in split-pane)."
 565   (interactive)
 566   (let ((id (notmuch-tree-get-message-id))
 567         (inhibit-read-only t)
 568         buffer)
 569     (when id
 570       ;; We close and reopen the window to kill off un-needed buffers
 571       ;; this might cause flickering but seems ok.
 572       (notmuch-tree-close-message-window)
 573       (setq notmuch-tree-message-window
 574             (split-window-vertically (/ (window-height) 4)))
 575       (with-selected-window notmuch-tree-message-window
 576         (let (;; Since we are only displaying one message do not indent.
 577               (notmuch-show-indent-messages-width 0)
 578               (notmuch-show-single-message t)
 579               ;; Ensure that `pop-to-buffer-same-window' uses the
 580               ;; window we want it to use.
 581               (display-buffer-overriding-action
 582                  '((display-buffer-same-window)
 583                    (inhibit-same-window . nil))))
 584           (setq buffer (notmuch-show id))))
 585       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 586       (let ((window notmuch-tree-message-window))
 587         (with-current-buffer buffer
 588           (setq notmuch-tree-message-window window)
 589           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 590       (when notmuch-show-mark-read-tags
 591         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 592       (setq notmuch-tree-message-buffer buffer))))
 593
 594 (defun notmuch-tree-show-message-out ()
 595   "Show the current message (in whole window)."
 596   (interactive)
 597   (let ((id (notmuch-tree-get-message-id))
 598         (inhibit-read-only t))
 599     (when id
 600       ;; We close the window to kill off un-needed buffers.
 601       (notmuch-tree-close-message-window)
 602       ;; n-s-s-m is buffer local, so use inner let.
 603       (let ((notmuch-show-single-message t))
 604         (notmuch-show id)))))
 605
 606 (defun notmuch-tree-show-message (arg)
 607   "Show the current message.
 608
 609 Shows in split pane or whole window according to value of
 610 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 611   (interactive "P")
 612   (if (or (and (notmuch-tree-show-out) (not arg))
 613           (and (not (notmuch-tree-show-out)) arg))
 614       (notmuch-tree-show-message-out)
 615     (notmuch-tree-show-message-in)))
 616
 617 (defun notmuch-tree-scroll-message-window ()
 618   "Scroll the message window (if it exists)."
 619   (interactive)
 620   (when (window-live-p notmuch-tree-message-window)
 621     (with-selected-window notmuch-tree-message-window
 622       (if (pos-visible-in-window-p (point-max))
 623           t
 624         (scroll-up)))))
 625
 626 (defun notmuch-tree-scroll-message-window-back ()
 627   "Scroll the message window back (if it exists)."
 628   (interactive)
 629   (when (window-live-p notmuch-tree-message-window)
 630     (with-selected-window notmuch-tree-message-window
 631       (if (pos-visible-in-window-p (point-min))
 632           t
 633         (scroll-down)))))
 634
 635 (defun notmuch-tree-scroll-or-next ()
 636   "Scroll the message window.
 637 If it at end go to next message."
 638   (interactive)
 639   (when (notmuch-tree-scroll-message-window)
 640     (notmuch-tree-next-matching-message)))
 641
 642 (defun notmuch-tree-quit (&optional kill-both)
 643   "Close the split view or exit tree."
 644   (interactive "P")
 645   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 646     (kill-buffer (current-buffer))))
 647
 648 (defun notmuch-tree-close-message-window ()
 649   "Close the message-window. Return t if close succeeds."
 650   (interactive)
 651   (when (and (window-live-p notmuch-tree-message-window)
 652              (eq (window-buffer notmuch-tree-message-window)
 653                  notmuch-tree-message-buffer))
 654     (delete-window notmuch-tree-message-window)
 655     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 656       (kill-buffer notmuch-tree-message-buffer))
 657     t))
 658
 659 (defun notmuch-tree-archive-message (&optional unarchive)
 660   "Archive the current message.
 661
 662 Archive the current message by applying the tag changes in
 663 `notmuch-archive-tags' to it. If a prefix argument is given, the
 664 message will be \"unarchived\", i.e. the tag changes in
 665 `notmuch-archive-tags' will be reversed."
 666   (interactive "P")
 667   (when notmuch-archive-tags
 668     (notmuch-tree-tag
 669      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 670
 671 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 672   "Archive the current message and move to next matching message."
 673   (interactive "P")
 674   (notmuch-tree-archive-message unarchive)
 675   (notmuch-tree-next-matching-message))
 676
 677 (defun notmuch-tree-archive-thread-then-exit ()
 678   "Archive all messages in the current buffer, then exit notmuch-tree."
 679   (interactive)
 680   (notmuch-tree-archive-thread)
 681   (notmuch-tree-quit t))
 682
 683 (defun notmuch-tree-archive-message-then-next-or-exit ()
 684   "Archive current message, then show next open message in current thread.
 685
 686 If at the last open message in the current thread, then exit back
 687 to search results."
 688   (interactive)
 689   (notmuch-tree-archive-message)
 690   (notmuch-tree-next-matching-message t))
 691
 692 (defun notmuch-tree-next-message ()
 693   "Move to next message."
 694   (interactive)
 695   (forward-line)
 696   (when (window-live-p notmuch-tree-message-window)
 697     (notmuch-tree-show-message-in)))
 698
 699 (defun notmuch-tree-prev-message ()
 700   "Move to previous message."
 701   (interactive)
 702   (forward-line -1)
 703   (when (window-live-p notmuch-tree-message-window)
 704     (notmuch-tree-show-message-in)))
 705
 706 (defun notmuch-tree-goto-matching-message (&optional prev)
 707   "Move to the next or previous matching message.
 708
 709 Returns t if there was a next matching message in the thread to show,
 710 nil otherwise."
 711   (let ((dir (if prev -1 nil))
 712         (eobfn (if prev #'bobp #'eobp)))
 713     (while (and (not (funcall eobfn))
 714                 (not (notmuch-tree-get-match)))
 715       (forward-line dir))
 716     (not (funcall eobfn))))
 717
 718 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 719   "Move to the next or previous matching message."
 720   (interactive "P")
 721   (forward-line (if prev -1 nil))
 722   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 723       (notmuch-tree-quit pop-at-end)
 724     (when (window-live-p notmuch-tree-message-window)
 725       (notmuch-tree-show-message-in))))
 726
 727 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 728   "Move to previous matching message."
 729   (interactive "P")
 730   (notmuch-tree-matching-message t pop-at-end))
 731
 732 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 733   "Move to next matching message."
 734   (interactive "P")
 735   (notmuch-tree-matching-message nil pop-at-end))
 736
 737 (defun notmuch-tree-refresh-view (&optional view)
 738   "Refresh view."
 739   (interactive)
 740   (when (get-buffer-process (current-buffer))
 741     (error "notmuch tree process already running for current buffer"))
 742   (let ((inhibit-read-only t)
 743         (basic-query notmuch-tree-basic-query)
 744         (unthreaded (cond ((eq view 'unthreaded) t)
 745                           ((eq view 'tree) nil)
 746                           (t notmuch-tree-unthreaded)))
 747         (query-context notmuch-tree-query-context)
 748         (target (notmuch-tree-get-message-id)))
 749     (erase-buffer)
 750     (notmuch-tree-worker basic-query
 751                          query-context
 752                          target
 753                          nil
 754                          unthreaded)))
 755
 756 (defun notmuch-tree-thread-top ()
 757   (when (notmuch-tree-get-message-properties)
 758     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 759       (forward-line -1))))
 760
 761 (defun notmuch-tree-prev-thread-in-tree ()
 762   "Move to the previous thread in the current tree"
 763   (interactive)
 764   (forward-line -1)
 765   (notmuch-tree-thread-top)
 766   (not (bobp)))
 767
 768 (defun notmuch-tree-next-thread-in-tree ()
 769   "Get the next thread in the current tree. Returns t if a thread was
 770 found or nil if not."
 771   (interactive)
 772   (forward-line 1)
 773   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 774     (forward-line 1))
 775   (not (eobp)))
 776
 777 (defun notmuch-tree-next-thread-from-search (&optional previous)
 778   "Move to the next thread in the parent search results, if any.
 779
 780 If PREVIOUS is non-nil, move to the previous item in the
 781 search results instead."
 782   (interactive "P")
 783   (let ((parent-buffer notmuch-tree-parent-buffer))
 784     (notmuch-tree-quit t)
 785     (when (buffer-live-p parent-buffer)
 786       (switch-to-buffer parent-buffer)
 787       (if previous
 788           (notmuch-search-previous-thread)
 789         (notmuch-search-next-thread))
 790       (notmuch-tree-from-search-thread))))
 791
 792 (defun notmuch-tree-next-thread (&optional previous)
 793   "Move to the next thread in the current tree or parent search results.
 794
 795 If PREVIOUS is non-nil, move to the previous thread in the tree or
 796 search results instead."
 797   (interactive)
 798   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 799             (notmuch-tree-next-thread-in-tree))
 800     (notmuch-tree-next-thread-from-search previous)))
 801
 802 (defun notmuch-tree-prev-thread ()
 803   "Move to the previous thread in the current tree or parent search results."
 804   (interactive)
 805   (notmuch-tree-next-thread t))
 806
 807 (defun notmuch-tree-thread-mapcar (function)
 808   "Call FUNCTION for each message in the current thread.
 809 FUNCTION is called for side effects only."
 810   (save-excursion
 811     (notmuch-tree-thread-top)
 812     (cl-loop collect (funcall function)
 813              do (forward-line)
 814              while (and (notmuch-tree-get-message-properties)
 815                         (not (notmuch-tree-get-prop :first))))))
 816
 817 (defun notmuch-tree-get-messages-ids-thread-search ()
 818   "Return a search string for all message ids of messages in the current thread."
 819   (mapconcat 'identity
 820              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 821              " or "))
 822
 823 (defun notmuch-tree-tag-thread (tag-changes)
 824   "Tag all messages in the current thread."
 825   (interactive
 826    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 827                                 (lambda () (notmuch-tree-get-tags))))))
 828      (list (notmuch-read-tag-changes tags "Tag thread"))))
 829   (when (notmuch-tree-get-message-properties)
 830     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 831     (notmuch-tree-thread-mapcar
 832      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 833
 834 (defun notmuch-tree-archive-thread (&optional unarchive)
 835   "Archive each message in thread.
 836
 837 Archive each message currently shown by applying the tag changes
 838 in `notmuch-archive-tags' to each. If a prefix argument is given,
 839 the messages will be \"unarchived\", i.e. the tag changes in
 840 `notmuch-archive-tags' will be reversed.
 841
 842 Note: This command is safe from any race condition of new messages
 843 being delivered to the same thread. It does not archive the
 844 entire thread, but only the messages shown in the current
 845 buffer."
 846   (interactive "P")
 847   (when notmuch-archive-tags
 848     (notmuch-tree-tag-thread
 849      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 850
 851 ;;; Functions for displaying the tree buffer itself
 852
 853 (defun notmuch-tree-clean-address (address)
 854   "Try to clean a single email ADDRESS for display. Return
 855 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 856 unchanged ADDRESS if parsing fails."
 857   (let* ((clean-address (notmuch-clean-address address))
 858          (p-address (car clean-address))
 859          (p-name (cdr clean-address)))
 860
 861     ;; If we have a name return that otherwise return the address.
 862     (or p-name p-address)))
 863
 864 (defun notmuch-tree-format-field (field format-string msg)
 865   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 866   (let* ((headers (plist-get msg :headers))
 867          (match (plist-get msg :match)))
 868     (cond
 869      ((listp field)
 870       (format format-string (notmuch-tree-format-field-list field msg)))
 871
 872      ((string-equal field "date")
 873       (let ((face (if match
 874                       'notmuch-tree-match-date-face
 875                     'notmuch-tree-no-match-date-face)))
 876         (propertize (format format-string (plist-get msg :date_relative))
 877                     'face face)))
 878
 879      ((string-equal field "tree")
 880       (let ((tree-status (plist-get msg :tree-status))
 881             (face (if match
 882                       'notmuch-tree-match-tree-face
 883                     'notmuch-tree-no-match-tree-face)))
 884
 885         (propertize (format format-string
 886                             (mapconcat #'identity (reverse tree-status) ""))
 887                     'face face)))
 888
 889      ((string-equal field "subject")
 890       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 891             (previous-subject notmuch-tree-previous-subject)
 892             (face (if match
 893                       'notmuch-tree-match-subject-face
 894                     'notmuch-tree-no-match-subject-face)))
 895
 896         (setq notmuch-tree-previous-subject bare-subject)
 897         (propertize (format format-string
 898                             (if (string= previous-subject bare-subject)
 899                                 " ..."
 900                               bare-subject))
 901                     'face face)))
 902
 903      ((string-equal field "authors")
 904       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 905             (len (length (format format-string "")))
 906             (face (if match
 907                       'notmuch-tree-match-author-face
 908                     'notmuch-tree-no-match-author-face)))
 909         (when (> (length author) len)
 910           (setq author (substring author 0 len)))
 911         (propertize (format format-string author) 'face face)))
 912
 913      ((string-equal field "tags")
 914       (let ((tags (plist-get msg :tags))
 915             (orig-tags (plist-get msg :orig-tags))
 916             (face (if match
 917                       'notmuch-tree-match-tag-face
 918                     'notmuch-tree-no-match-tag-face)))
 919         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 920
 921 (defun notmuch-tree-format-field-list (field-list msg)
 922   "Format fields of MSG according to FIELD-LIST and return string."
 923   (let ((face (if (plist-get msg :match)
 924                   'notmuch-tree-match-face
 925                 'notmuch-tree-no-match-face))
 926         (result-string))
 927     (dolist (spec field-list result-string)
 928       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 929         (setq result-string (concat result-string field-string))))
 930     (notmuch-apply-face result-string face t)))
 931
 932 (defun notmuch-tree-insert-msg (msg)
 933   "Insert the message MSG according to notmuch-tree-result-format."
 934   ;; We need to save the previous subject as it will get overwritten
 935   ;; by the insert-field calls.
 936   (let ((previous-subject notmuch-tree-previous-subject))
 937     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 938     (notmuch-tree-set-message-properties msg)
 939     (notmuch-tree-set-prop :previous-subject previous-subject)
 940     (insert "\n")))
 941
 942 (defun notmuch-tree-goto-and-insert-msg (msg)
 943   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 944   (save-excursion
 945     (goto-char (point-max))
 946     (notmuch-tree-insert-msg msg))
 947   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 948         (target notmuch-tree-target-msg))
 949     (when (or (and (not target) (plist-get msg :match))
 950               (string= msg-id target))
 951       (setq notmuch-tree-target-msg "found")
 952       (goto-char (point-max))
 953       (forward-line -1)
 954       (when notmuch-tree-open-target
 955         (notmuch-tree-show-message-in)))))
 956
 957 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 958   "Insert the message tree TREE at depth DEPTH in the current thread.
 959
 960 A message tree is another name for a single sub-thread: i.e., a
 961 message together with all its descendents."
 962   (let ((msg (car tree))
 963         (replies (cadr tree)))
 964     (cond
 965      ((and (< 0 depth) (not last))
 966       (push "├" tree-status))
 967      ((and (< 0 depth) last)
 968       (push "╰" tree-status))
 969      ((and (eq 0 depth) first last)
 970       ;; Choice between these two variants is a matter of taste.
 971       ;; (push "─" tree-status))
 972       (push " " tree-status))
 973      ((and (eq 0 depth) first (not last))
 974       (push "┬" tree-status))
 975      ((and (eq 0 depth) (not first) last)
 976       (push "╰" tree-status))
 977      ((and (eq 0 depth) (not first) (not last))
 978       (push "├" tree-status)))
 979     (push (concat (if replies "┬" "─") "►") tree-status)
 980     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 981     (setq msg (plist-put msg :tree-status tree-status))
 982     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 983     (notmuch-tree-goto-and-insert-msg msg)
 984     (pop tree-status)
 985     (pop tree-status)
 986     (if last
 987         (push " " tree-status)
 988       (push "│" tree-status))
 989     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 990
 991 (defun notmuch-tree-insert-thread (thread depth tree-status)
 992   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 993   (let ((n (length thread)))
 994     (cl-loop for tree in thread
 995              for count from 1 to n
 996              do (notmuch-tree-insert-tree tree depth tree-status
 997                                           (eq count 1)
 998                                           (eq count n)))))
 999
1000 (defun notmuch-tree-insert-forest-thread (forest-thread)
1001   "Insert a single complete thread."
1002   (let (tree-status)
1003     ;; Reset at the start of each main thread.
1004     (setq notmuch-tree-previous-subject nil)
1005     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
1006
1007 (defun notmuch-tree-insert-forest (forest)
1008   "Insert a forest of threads.
1009
1010 This function inserts a collection of several complete threads as
1011 passed to it by notmuch-tree-process-filter."
1012   (mapc 'notmuch-tree-insert-forest-thread forest))
1013
1014 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
1015   "Major mode displaying messages (as opposed to threads) of a notmuch search.
1016
1017 This buffer contains the results of a \"notmuch tree\" of your
1018 email archives. Each line in the buffer represents a single
1019 message giving the relative date, the author, subject, and any
1020 tags.
1021
1022 Pressing \\[notmuch-tree-show-message] on any line displays that message.
1023
1024 Complete list of currently available key bindings:
1025
1026 \\{notmuch-tree-mode-map}"
1027   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1028   (hl-line-mode 1)
1029   (setq buffer-read-only t)
1030   (setq truncate-lines t))
1031
1032 (defun notmuch-tree-process-sentinel (proc _msg)
1033   "Add a message to let user know when \"notmuch tree\" exits."
1034   (let ((buffer (process-buffer proc))
1035         (status (process-status proc))
1036         (exit-status (process-exit-status proc)))
1037     (when (memq status '(exit signal))
1038       (kill-buffer (process-get proc 'parse-buf))
1039       (when (buffer-live-p buffer)
1040         (with-current-buffer buffer
1041           (save-excursion
1042             (let ((inhibit-read-only t))
1043               (goto-char (point-max))
1044               (when (eq status 'signal)
1045                 (insert "Incomplete search results (tree view process was killed).\n"))
1046               (when (eq status 'exit)
1047                 (insert "End of search results.")
1048                 (unless (= exit-status 0)
1049                   (insert (format " (process returned %d)" exit-status)))
1050                 (insert "\n")))))))))
1051
1052 (defun notmuch-tree-process-filter (proc string)
1053   "Process and filter the output of \"notmuch show\" for tree view."
1054   (let ((results-buf (process-buffer proc))
1055         (parse-buf (process-get proc 'parse-buf))
1056         (inhibit-read-only t))
1057     (if (not (buffer-live-p results-buf))
1058         (delete-process proc)
1059       (with-current-buffer parse-buf
1060         ;; Insert new data
1061         (save-excursion
1062           (goto-char (point-max))
1063           (insert string))
1064         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1065                                          results-buf)))))
1066
1067 (defun notmuch-tree-worker (basic-query &optional query-context target
1068                                         open-target unthreaded oldest-first)
1069   "Insert the tree view of the search in the current buffer.
1070
1071 This is is a helper function for notmuch-tree. The arguments are
1072 the same as for the function notmuch-tree."
1073   (interactive)
1074   (notmuch-tree-mode)
1075   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1076   (setq notmuch-tree-unthreaded unthreaded)
1077   (setq notmuch-tree-basic-query basic-query)
1078   (setq notmuch-tree-query-context (if (or (string= query-context "")
1079                                            (string= query-context "*"))
1080                                        nil
1081                                      query-context))
1082   (setq notmuch-tree-target-msg target)
1083   (setq notmuch-tree-open-target open-target)
1084   ;; Set the default value for `notmuch-show-process-crypto' in this
1085   ;; buffer. Although we don't use this some of the functions we call
1086   ;; (such as reply) do. It is a buffer local variable so setting it
1087   ;; will not affect genuine show buffers.
1088   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1089   (erase-buffer)
1090   (goto-char (point-min))
1091   (let* ((search-args (concat basic-query
1092                               (and query-context
1093                                    (concat " and (" query-context ")"))))
1094          (sort-arg (if oldest-first "--sort=oldest-first" "--sort=newest-first"))
1095          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1096     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1097       (setq search-args basic-query))
1098     (notmuch-tag-clear-cache)
1099     (let ((proc (notmuch-start-notmuch
1100                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1101                  "show" "--body=false" "--format=sexp" "--format-version=4"
1102                  sort-arg message-arg search-args))
1103           ;; Use a scratch buffer to accumulate partial output.
1104           ;; This buffer will be killed by the sentinel, which
1105           ;; should be called no matter how the process dies.
1106           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1107       (process-put proc 'parse-buf parse-buf)
1108       (set-process-filter proc 'notmuch-tree-process-filter)
1109       (set-process-query-on-exit-flag proc nil))))
1110
1111 (defun notmuch-tree-get-query ()
1112   "Return the current query in this tree buffer."
1113   (if notmuch-tree-query-context
1114       (concat notmuch-tree-basic-query
1115               " and ("
1116               notmuch-tree-query-context
1117               ")")
1118     notmuch-tree-basic-query))
1119
1120 (defun notmuch-tree (&optional query query-context target buffer-name
1121                                open-target unthreaded parent-buffer oldest-first)
1122   "Display threads matching QUERY in tree view.
1123
1124 The arguments are:
1125   QUERY: the main query. This can be any query but in many cases will be
1126       a single thread. If nil this is read interactively from the minibuffer.
1127   QUERY-CONTEXT: is an additional term for the query. The query used
1128       is QUERY and QUERY-CONTEXT unless that does not match any messages
1129       in which case we fall back to just QUERY.
1130   TARGET: A message ID (with the id: prefix) that will be made
1131       current if it appears in the tree view results.
1132   BUFFER-NAME: the name of the buffer to display the tree view. If
1133       it is nil \"*notmuch-tree\" followed by QUERY is used.
1134   OPEN-TARGET: If TRUE open the target message in the message pane.
1135   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1136   (interactive)
1137   (unless query
1138     (setq query (notmuch-read-query (concat "Notmuch "
1139                                             (if unthreaded "unthreaded " "tree ")
1140                                             "view search: "))))
1141   (let ((buffer (get-buffer-create (generate-new-buffer-name
1142                                     (or buffer-name
1143                                         (concat "*notmuch-"
1144                                                 (if unthreaded "unthreaded-" "tree-")
1145                                                 query "*")))))
1146         (inhibit-read-only t))
1147     (pop-to-buffer-same-window buffer))
1148   ;; Don't track undo information for this buffer
1149   (setq buffer-undo-list t)
1150   (notmuch-tree-worker query query-context target open-target unthreaded oldest-first)
1151   (setq notmuch-tree-parent-buffer parent-buffer)
1152   (setq truncate-lines t))
1153
1154 (defun notmuch-unthreaded (&optional query query-context target buffer-name
1155                                      open-target)
1156   (interactive)
1157   (notmuch-tree query query-context target buffer-name open-target t))
1158
1159 ;;; _
1160
1161 (provide 'notmuch-tree)
1162
1163 ;;; notmuch-tree.el ends here