git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl-lib))
  28
  29 (require 'mail-parse)
  30
  31 (require 'notmuch-lib)
  32 (require 'notmuch-query)
  33 (require 'notmuch-show)
  34 (require 'notmuch-tag)
  35 (require 'notmuch-parser)
  36 (require 'notmuch-jump)
  37
  38 (declare-function notmuch-search "notmuch"
  39                   (&optional query oldest-first target-thread target-line))
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-read-query "notmuch" (prompt))
  42 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  43 (declare-function notmuch-search-find-subject "notmuch" ())
  44
  45 ;; the following variable is defined in notmuch.el
  46 (defvar notmuch-search-query-string)
  47
  48 ;; this variable distinguishes the unthreaded display from the normal tree display
  49 (defvar notmuch-tree-unthreaded nil
  50   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  51 (make-variable-buffer-local 'notmuch-tree-unthreaded)
  52
  53 (defgroup notmuch-tree nil
  54   "Showing message and thread structure."
  55   :group 'notmuch)
  56
  57 (defcustom notmuch-tree-show-out nil
  58   "View selected messages in new window rather than split-pane."
  59   :type 'boolean
  60   :group 'notmuch-tree)
  61
  62 (defcustom notmuch-unthreaded-show-out t
  63   "View selected messages in new window rather than split-pane."
  64   :type 'boolean
  65   :group 'notmuch-tree)
  66
  67 (defun notmuch-tree-show-out ()
  68   (if notmuch-tree-unthreaded
  69       notmuch-unthreaded-show-out
  70     notmuch-tree-show-out))
  71
  72 (defcustom notmuch-tree-result-format
  73   `(("date" . "%12s  ")
  74     ("authors" . "%-20s")
  75     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  76     ("tags" . "(%s)"))
  77   "Result formatting for tree view. Supported fields are: date,
  78 authors, subject, tree, tags.  Tree means the thread tree
  79 box graphics. The field may also be a list in which case
  80 the formatting rules are applied recursively and then the
  81 output of all the fields in the list is inserted
  82 according to format-string.
  83
  84 Note the author string should not contain
  85 whitespace (put it in the neighbouring fields instead).
  86 For example:
  87         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  88                                           \(\"subject\" . \"%s\"\)\)\)"
  89   :type '(alist :key-type (string) :value-type (string))
  90   :group 'notmuch-tree)
  91
  92 (defcustom notmuch-unthreaded-result-format
  93   `(("date" . "%12s  ")
  94     ("authors" . "%-20s")
  95     ((("subject" . "%s")) ." %-54s ")
  96     ("tags" . "(%s)"))
  97   "Result formatting for unthreaded tree view. Supported fields are: date,
  98 authors, subject, tree, tags.  Tree means the thread tree
  99 box graphics. The field may also be a list in which case
 100 the formatting rules are applied recursively and then the
 101 output of all the fields in the list is inserted
 102 according to format-string.
 103
 104 Note the author string should not contain
 105 whitespace (put it in the neighbouring fields instead).
 106 For example:
 107         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 108                                           \(\"subject\" . \"%s\"\)\)\)"
 109   :type '(alist :key-type (string) :value-type (string))
 110   :group 'notmuch-tree)
 111
 112 (defun notmuch-tree-result-format ()
 113   (if notmuch-tree-unthreaded
 114       notmuch-unthreaded-result-format
 115     notmuch-tree-result-format))
 116
 117 ;; Faces for messages that match the query.
 118 (defface notmuch-tree-match-face
 119   '((t :inherit default))
 120   "Default face used in tree mode face for matching messages"
 121   :group 'notmuch-tree
 122   :group 'notmuch-faces)
 123
 124 (defface notmuch-tree-match-date-face
 125   nil
 126   "Face used in tree mode for the date in messages matching the query."
 127   :group 'notmuch-tree
 128   :group 'notmuch-faces)
 129
 130 (defface notmuch-tree-match-author-face
 131   '((((class color)
 132       (background dark))
 133      (:foreground "OliveDrab1"))
 134     (((class color)
 135       (background light))
 136      (:foreground "dark blue"))
 137     (t
 138      (:bold t)))
 139   "Face used in tree mode for the date in messages matching the query."
 140   :group 'notmuch-tree
 141   :group 'notmuch-faces)
 142
 143 (defface notmuch-tree-match-subject-face
 144   nil
 145   "Face used in tree mode for the subject in messages matching the query."
 146   :group 'notmuch-tree
 147   :group 'notmuch-faces)
 148
 149 (defface notmuch-tree-match-tree-face
 150   nil
 151   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 152   :group 'notmuch-tree
 153   :group 'notmuch-faces)
 154
 155 (defface notmuch-tree-match-tag-face
 156   '((((class color)
 157       (background dark))
 158      (:foreground "OliveDrab1"))
 159     (((class color)
 160       (background light))
 161      (:foreground "navy blue" :bold t))
 162     (t
 163      (:bold t)))
 164   "Face used in tree mode for tags in messages matching the query."
 165   :group 'notmuch-tree
 166   :group 'notmuch-faces)
 167
 168 ;; Faces for messages that do not match the query.
 169 (defface notmuch-tree-no-match-face
 170   '((t (:foreground "gray")))
 171   "Default face used in tree mode face for non-matching messages."
 172   :group 'notmuch-tree
 173   :group 'notmuch-faces)
 174
 175 (defface notmuch-tree-no-match-date-face
 176   nil
 177   "Face used in tree mode for non-matching dates."
 178   :group 'notmuch-tree
 179   :group 'notmuch-faces)
 180
 181 (defface notmuch-tree-no-match-subject-face
 182   nil
 183   "Face used in tree mode for non-matching subjects."
 184   :group 'notmuch-tree
 185   :group 'notmuch-faces)
 186
 187 (defface notmuch-tree-no-match-tree-face
 188   nil
 189   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 190   :group 'notmuch-tree
 191   :group 'notmuch-faces)
 192
 193 (defface notmuch-tree-no-match-author-face
 194   nil
 195   "Face used in tree mode for the date in messages matching the query."
 196   :group 'notmuch-tree
 197   :group 'notmuch-faces)
 198
 199 (defface notmuch-tree-no-match-tag-face
 200   nil
 201   "Face used in tree mode face for non-matching tags."
 202   :group 'notmuch-tree
 203   :group 'notmuch-faces)
 204
 205 (defvar notmuch-tree-previous-subject
 206   "The subject of the most recent result shown during the async display.")
 207 (make-variable-buffer-local 'notmuch-tree-previous-subject)
 208
 209 (defvar notmuch-tree-basic-query nil
 210   "A buffer local copy of argument query to the function notmuch-tree.")
 211 (make-variable-buffer-local 'notmuch-tree-basic-query)
 212
 213 (defvar notmuch-tree-query-context nil
 214   "A buffer local copy of argument query-context to the function notmuch-tree.")
 215 (make-variable-buffer-local 'notmuch-tree-query-context)
 216
 217 (defvar notmuch-tree-target-msg nil
 218   "A buffer local copy of argument target to the function notmuch-tree.")
 219 (make-variable-buffer-local 'notmuch-tree-target-msg)
 220
 221 (defvar notmuch-tree-open-target nil
 222   "A buffer local copy of argument open-target to the function notmuch-tree.")
 223 (make-variable-buffer-local 'notmuch-tree-open-target)
 224
 225 (defvar notmuch-tree-parent-buffer nil)
 226 (make-variable-buffer-local 'notmuch-tree-parent-buffer)
 227
 228 (defvar notmuch-tree-message-window nil
 229   "The window of the message pane.
 230
 231 It is set in both the tree buffer and the child show buffer. It
 232 is used to try and close the message pane when quitting tree view
 233 or the child show buffer.")
 234 (make-variable-buffer-local 'notmuch-tree-message-window)
 235 (put 'notmuch-tree-message-window 'permanent-local t)
 236
 237 (defvar notmuch-tree-message-buffer nil
 238   "The buffer name of the show buffer in the message pane.
 239
 240 This is used to try and make sure we don't close the message pane
 241 if the user has loaded a different buffer in that window.")
 242 (make-variable-buffer-local 'notmuch-tree-message-buffer)
 243 (put 'notmuch-tree-message-buffer 'permanent-local t)
 244
 245 (defun notmuch-tree-to-message-pane (func)
 246   "Execute FUNC in message pane.
 247
 248 This function returns a function (so can be used as a keybinding)
 249 which executes function FUNC in the message pane if it is
 250 open (if the message pane is closed it does nothing)."
 251   `(lambda ()
 252      ,(concat "(In message pane) " (documentation func t))
 253      (interactive)
 254      (when (window-live-p notmuch-tree-message-window)
 255        (with-selected-window notmuch-tree-message-window
 256          (call-interactively #',func)))))
 257
 258 (defun notmuch-tree-inherit-from-message-pane (sym)
 259   "Return value of SYM in message-pane if open, or tree-pane if not."
 260   (if (window-live-p notmuch-tree-message-window)
 261       (with-selected-window notmuch-tree-message-window
 262         (symbol-value sym))
 263     (symbol-value sym)))
 264
 265 (defun notmuch-tree-button-activate (&optional button)
 266   "Activate BUTTON or button at point.
 267
 268 This function does not give an error if there is no button."
 269   (interactive)
 270   (let ((button (or button (button-at (point)))))
 271     (when button (button-activate button))))
 272
 273 (defun notmuch-tree-close-message-pane-and (func)
 274   "Close message pane and execute FUNC.
 275
 276 This function returns a function (so can be used as a keybinding)
 277 which closes the message pane if open and then executes function
 278 FUNC."
 279   `(lambda ()
 280      ,(concat "(Close message pane and) " (documentation func t))
 281      (interactive)
 282      (let ((notmuch-show-process-crypto
 283             (notmuch-tree-inherit-from-message-pane 'notmuch-show-process-crypto)))
 284        (notmuch-tree-close-message-window)
 285        (call-interactively #',func))))
 286
 287 (defvar notmuch-tree-mode-map
 288   (let ((map (make-sparse-keymap)))
 289     (set-keymap-parent map notmuch-common-keymap)
 290     ;; The following override the global keymap.
 291     ;; Override because we want to close message pane first.
 292     (define-key map [remap notmuch-help]
 293       (notmuch-tree-close-message-pane-and #'notmuch-help))
 294     ;; Override because we first close message pane and then close tree buffer.
 295     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 296     ;; Override because we close message pane after the search query is entered.
 297     (define-key map [remap notmuch-search] 'notmuch-tree-to-search)
 298     ;; Override because we want to close message pane first.
 299     (define-key map [remap notmuch-mua-new-mail]
 300       (notmuch-tree-close-message-pane-and #'notmuch-mua-new-mail))
 301     ;; Override because we want to close message pane first.
 302     (define-key map [remap notmuch-jump-search]
 303       (notmuch-tree-close-message-pane-and #'notmuch-jump-search))
 304
 305     (define-key map "S" 'notmuch-search-from-tree-current-query)
 306     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 307     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 308
 309     ;; these use notmuch-show functions directly
 310     (define-key map "|" 'notmuch-show-pipe-message)
 311     (define-key map "w" 'notmuch-show-save-attachments)
 312     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 313     (define-key map "c" 'notmuch-show-stash-map)
 314     (define-key map "b" 'notmuch-show-resend-message)
 315
 316     ;; these apply to the message pane
 317     (define-key map (kbd "M-TAB")
 318       (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 319     (define-key map (kbd "<backtab>")
 320       (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 321     (define-key map (kbd "TAB")
 322       (notmuch-tree-to-message-pane #'notmuch-show-next-button))
 323     (define-key map "$"
 324       (notmuch-tree-to-message-pane #'notmuch-show-toggle-process-crypto))
 325
 326     ;; bindings from show (or elsewhere) but we close the message pane first.
 327     (define-key map "f"
 328       (notmuch-tree-close-message-pane-and #'notmuch-show-forward-message))
 329     (define-key map "r"
 330       (notmuch-tree-close-message-pane-and #'notmuch-show-reply-sender))
 331     (define-key map "R"
 332       (notmuch-tree-close-message-pane-and #'notmuch-show-reply))
 333     (define-key map "V"
 334       (notmuch-tree-close-message-pane-and #'notmuch-show-view-raw-message))
 335
 336     ;; The main tree view bindings
 337     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 338     (define-key map [mouse-1] 'notmuch-tree-show-message)
 339     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 340     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 341     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 342     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 343     (define-key map "z" 'notmuch-tree-to-tree)
 344     (define-key map "n" 'notmuch-tree-next-matching-message)
 345     (define-key map "p" 'notmuch-tree-prev-matching-message)
 346     (define-key map "N" 'notmuch-tree-next-message)
 347     (define-key map "P" 'notmuch-tree-prev-message)
 348     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 349     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 350     (define-key map "k" 'notmuch-tag-jump)
 351     (define-key map "-" 'notmuch-tree-remove-tag)
 352     (define-key map "+" 'notmuch-tree-add-tag)
 353     (define-key map "*" 'notmuch-tree-tag-thread)
 354     (define-key map " " 'notmuch-tree-scroll-or-next)
 355     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 356     (define-key map "e" 'notmuch-tree-resume-message)
 357     map))
 358 (fset 'notmuch-tree-mode-map notmuch-tree-mode-map)
 359
 360 (defun notmuch-tree-get-message-properties ()
 361   "Return the properties of the current message as a plist.
 362
 363 Some useful entries are:
 364 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 365 :tags - Tags for this message."
 366   (save-excursion
 367     (beginning-of-line)
 368     (get-text-property (point) :notmuch-message-properties)))
 369
 370 (defun notmuch-tree-set-message-properties (props)
 371   (save-excursion
 372     (beginning-of-line)
 373     (put-text-property (point)
 374                        (+ (point) 1)
 375                        :notmuch-message-properties props)))
 376
 377 (defun notmuch-tree-set-prop (prop val &optional props)
 378   (let ((inhibit-read-only t)
 379         (props (or props
 380                    (notmuch-tree-get-message-properties))))
 381     (plist-put props prop val)
 382     (notmuch-tree-set-message-properties props)))
 383
 384 (defun notmuch-tree-get-prop (prop &optional props)
 385   (let ((props (or props
 386                    (notmuch-tree-get-message-properties))))
 387     (plist-get props prop)))
 388
 389 (defun notmuch-tree-set-tags (tags)
 390   "Set the tags of the current message."
 391   (notmuch-tree-set-prop :tags tags))
 392
 393 (defun notmuch-tree-get-tags ()
 394   "Return the tags of the current message."
 395   (notmuch-tree-get-prop :tags))
 396
 397 (defun notmuch-tree-get-message-id (&optional bare)
 398   "Return the message id of the current message."
 399   (let ((id (notmuch-tree-get-prop :id)))
 400     (if id
 401         (if bare
 402             id
 403           (notmuch-id-to-query id))
 404       nil)))
 405
 406 (defun notmuch-tree-get-match ()
 407   "Return whether the current message is a match."
 408   (interactive)
 409   (notmuch-tree-get-prop :match))
 410
 411 (defun notmuch-tree-refresh-result ()
 412   "Redisplay the current message line.
 413
 414 This redisplays the current line based on the messages
 415 properties (as they are now). This is used when tags are
 416 updated."
 417   (let ((init-point (point))
 418         (end (line-end-position))
 419         (msg (notmuch-tree-get-message-properties))
 420         (inhibit-read-only t))
 421     (beginning-of-line)
 422     ;; This is a little tricky: we override
 423     ;; notmuch-tree-previous-subject to get the decision between
 424     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 425     ;; from overwriting the buffer local copy of
 426     ;; notmuch-tree-previous-subject if this is called while the
 427     ;; buffer is displaying.
 428     (let ((notmuch-tree-previous-subject
 429            (notmuch-tree-get-prop :previous-subject)))
 430       (delete-region (point) (1+ (line-end-position)))
 431       (notmuch-tree-insert-msg msg))
 432     (let ((new-end (line-end-position)))
 433       (goto-char (if (= init-point end)
 434                      new-end
 435                    (min init-point (- new-end 1)))))))
 436
 437 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 438   "Update display for TAG-CHANGES to current message.
 439
 440 Updates the message in the message pane if appropriate, but does
 441 NOT change the database."
 442   (let* ((current-tags (notmuch-tree-get-tags))
 443          (new-tags (notmuch-update-tags current-tags tag-changes))
 444          (tree-msg-id (notmuch-tree-get-message-id)))
 445     (unless (equal current-tags new-tags)
 446       (notmuch-tree-set-tags new-tags)
 447       (notmuch-tree-refresh-result)
 448       (when (window-live-p notmuch-tree-message-window)
 449         (with-selected-window notmuch-tree-message-window
 450           (when (string= tree-msg-id (notmuch-show-get-message-id))
 451             (notmuch-show-update-tags new-tags)))))))
 452
 453 (defun notmuch-tree-tag (tag-changes)
 454   "Change tags for the current message."
 455   (interactive
 456    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 457   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 458   (notmuch-tree-tag-update-display tag-changes))
 459
 460 (defun notmuch-tree-add-tag (tag-changes)
 461   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 462   (interactive
 463    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 464   (notmuch-tree-tag tag-changes))
 465
 466 (defun notmuch-tree-remove-tag (tag-changes)
 467   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 468   (interactive
 469    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 470   (notmuch-tree-tag tag-changes))
 471
 472 (defun notmuch-tree-resume-message ()
 473   "Resume EDITING the current draft message."
 474   (interactive)
 475   (notmuch-tree-close-message-window)
 476   (let ((id (notmuch-tree-get-message-id)))
 477     (if id
 478         (notmuch-draft-resume id)
 479       (message "No message to resume!"))))
 480
 481 ;; The next two functions close the message window before calling
 482 ;; notmuch-search or notmuch-tree but they do so after the user has
 483 ;; entered the query (in case the user was basing the query on
 484 ;; something in the message window).
 485
 486 (defun notmuch-tree-to-search ()
 487   "Run \"notmuch search\" with the given `query' and display results."
 488   (interactive)
 489   (let ((query (notmuch-read-query "Notmuch search: ")))
 490     (notmuch-tree-close-message-window)
 491     (notmuch-search query)))
 492
 493 (defun notmuch-tree-to-tree ()
 494   "Run a query and display results in tree view."
 495   (interactive)
 496   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 497     (notmuch-tree-close-message-window)
 498     (notmuch-tree query)))
 499
 500 (defun notmuch-tree-archive-thread-then-next ()
 501   "Archive all messages in the current buffer, then show next thread from search."
 502   (interactive)
 503   (notmuch-tree-archive-thread)
 504   (notmuch-tree-next-thread))
 505
 506 (defun notmuch-unthreaded-from-tree-current-query ()
 507   "Switch from tree view to unthreaded view."
 508   (interactive)
 509   (unless notmuch-tree-unthreaded
 510     (notmuch-tree-refresh-view 'unthreaded)))
 511
 512 (defun notmuch-tree-from-unthreaded-current-query ()
 513   "Switch from unthreaded view to tree view."
 514   (interactive)
 515   (when notmuch-tree-unthreaded
 516     (notmuch-tree-refresh-view 'tree)))
 517
 518 (defun notmuch-search-from-tree-current-query ()
 519   "Call notmuch search with the current query."
 520   (interactive)
 521   (notmuch-tree-close-message-window)
 522   (notmuch-search (notmuch-tree-get-query)))
 523
 524 (defun notmuch-tree-message-window-kill-hook ()
 525   "Close the message pane when exiting the show buffer."
 526   (let ((buffer (current-buffer)))
 527     (when (and (window-live-p notmuch-tree-message-window)
 528                (eq (window-buffer notmuch-tree-message-window) buffer))
 529       ;; We do not want an error if this is the sole window in the
 530       ;; frame and I do not know how to test for that in emacs pre
 531       ;; 24. Hence we just ignore-errors.
 532       (ignore-errors
 533         (delete-window notmuch-tree-message-window)))))
 534
 535 (defun notmuch-tree-command-hook ()
 536   (when (eq major-mode 'notmuch-tree-mode)
 537     ;; We just run the notmuch-show-command-hook on the message pane.
 538     (when (buffer-live-p notmuch-tree-message-buffer)
 539       (with-current-buffer notmuch-tree-message-buffer
 540         (notmuch-show-command-hook)))))
 541
 542 (defun notmuch-tree-show-message-in ()
 543   "Show the current message (in split-pane)."
 544   (interactive)
 545   (let ((id (notmuch-tree-get-message-id))
 546         (inhibit-read-only t)
 547         buffer)
 548     (when id
 549       ;; We close and reopen the window to kill off un-needed buffers
 550       ;; this might cause flickering but seems ok.
 551       (notmuch-tree-close-message-window)
 552       (setq notmuch-tree-message-window
 553             (split-window-vertically (/ (window-height) 4)))
 554       (with-selected-window notmuch-tree-message-window
 555         ;; Since we are only displaying one message do not indent.
 556         (let ((notmuch-show-indent-messages-width 0)
 557               (notmuch-show-only-matching-messages t))
 558           (setq buffer (notmuch-show id))))
 559       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 560       (let ((window notmuch-tree-message-window))
 561         (with-current-buffer buffer
 562           (setq notmuch-tree-message-window window)
 563           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 564       (when notmuch-show-mark-read-tags
 565         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 566       (setq notmuch-tree-message-buffer buffer))))
 567
 568 (defun notmuch-tree-show-message-out ()
 569   "Show the current message (in whole window)."
 570   (interactive)
 571   (let ((id (notmuch-tree-get-message-id))
 572         (inhibit-read-only t)
 573         buffer)
 574     (when id
 575       ;; We close the window to kill off un-needed buffers.
 576       (notmuch-tree-close-message-window)
 577       (notmuch-show id))))
 578
 579 (defun notmuch-tree-show-message (arg)
 580   "Show the current message.
 581
 582 Shows in split pane or whole window according to value of
 583 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 584   (interactive "P")
 585   (if (or (and (notmuch-tree-show-out) (not arg))
 586           (and (not (notmuch-tree-show-out)) arg))
 587       (notmuch-tree-show-message-out)
 588     (notmuch-tree-show-message-in)))
 589
 590 (defun notmuch-tree-scroll-message-window ()
 591   "Scroll the message window (if it exists)."
 592   (interactive)
 593   (when (window-live-p notmuch-tree-message-window)
 594     (with-selected-window notmuch-tree-message-window
 595       (if (pos-visible-in-window-p (point-max))
 596           t
 597         (scroll-up)))))
 598
 599 (defun notmuch-tree-scroll-message-window-back ()
 600   "Scroll the message window back (if it exists)."
 601   (interactive)
 602   (when (window-live-p notmuch-tree-message-window)
 603     (with-selected-window notmuch-tree-message-window
 604       (if (pos-visible-in-window-p (point-min))
 605           t
 606         (scroll-down)))))
 607
 608 (defun notmuch-tree-scroll-or-next ()
 609   "Scroll the message window.
 610 If it at end go to next message."
 611   (interactive)
 612   (when (notmuch-tree-scroll-message-window)
 613     (notmuch-tree-next-matching-message)))
 614
 615 (defun notmuch-tree-quit (&optional kill-both)
 616   "Close the split view or exit tree."
 617   (interactive "P")
 618   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 619     (kill-buffer (current-buffer))))
 620
 621 (defun notmuch-tree-close-message-window ()
 622   "Close the message-window. Return t if close succeeds."
 623   (interactive)
 624   (when (and (window-live-p notmuch-tree-message-window)
 625              (eq (window-buffer notmuch-tree-message-window)
 626                  notmuch-tree-message-buffer))
 627     (delete-window notmuch-tree-message-window)
 628     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 629       (kill-buffer notmuch-tree-message-buffer))
 630     t))
 631
 632 (defun notmuch-tree-archive-message (&optional unarchive)
 633   "Archive the current message.
 634
 635 Archive the current message by applying the tag changes in
 636 `notmuch-archive-tags' to it. If a prefix argument is given, the
 637 message will be \"unarchived\", i.e. the tag changes in
 638 `notmuch-archive-tags' will be reversed."
 639   (interactive "P")
 640   (when notmuch-archive-tags
 641     (notmuch-tree-tag
 642      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 643
 644 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 645   "Archive the current message and move to next matching message."
 646   (interactive "P")
 647   (notmuch-tree-archive-message unarchive)
 648   (notmuch-tree-next-matching-message))
 649
 650 (defun notmuch-tree-archive-thread-then-exit ()
 651   "Archive all messages in the current buffer, then exit notmuch-tree."
 652   (interactive)
 653   (notmuch-tree-archive-thread)
 654   (notmuch-tree-quit t))
 655
 656 (defun notmuch-tree-archive-message-then-next-or-exit ()
 657   "Archive current message, then show next open message in current thread.
 658
 659 If at the last open message in the current thread, then exit back
 660 to search results."
 661   (interactive)
 662   (notmuch-tree-archive-message)
 663   (notmuch-tree-next-matching-message t))
 664
 665 (defun notmuch-tree-next-message ()
 666   "Move to next message."
 667   (interactive)
 668   (forward-line)
 669   (when (window-live-p notmuch-tree-message-window)
 670     (notmuch-tree-show-message-in)))
 671
 672 (defun notmuch-tree-prev-message ()
 673   "Move to previous message."
 674   (interactive)
 675   (forward-line -1)
 676   (when (window-live-p notmuch-tree-message-window)
 677     (notmuch-tree-show-message-in)))
 678
 679 (defun notmuch-tree-goto-matching-message (&optional prev)
 680   "Move to the next or previous matching message.
 681
 682 Returns t if there was a next matching message in the thread to show,
 683 nil otherwise."
 684   (let ((dir (if prev -1 nil))
 685         (eobfn (if prev #'bobp #'eobp)))
 686     (while (and (not (funcall eobfn))
 687                 (not (notmuch-tree-get-match)))
 688       (forward-line dir))
 689     (not (funcall eobfn))))
 690
 691 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 692   "Move to the next or previous matching message."
 693   (interactive "P")
 694   (forward-line (if prev -1 nil))
 695   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 696       (notmuch-tree-quit pop-at-end)
 697     (when (window-live-p notmuch-tree-message-window)
 698       (notmuch-tree-show-message-in))))
 699
 700 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 701   "Move to previous matching message."
 702   (interactive "P")
 703   (notmuch-tree-matching-message t pop-at-end))
 704
 705 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 706   "Move to next matching message."
 707   (interactive "P")
 708   (notmuch-tree-matching-message nil pop-at-end))
 709
 710 (defun notmuch-tree-refresh-view (&optional view)
 711   "Refresh view."
 712   (interactive)
 713   (when (get-buffer-process (current-buffer))
 714     (error "notmuch tree process already running for current buffer"))
 715   (let ((inhibit-read-only t)
 716         (basic-query notmuch-tree-basic-query)
 717         (unthreaded (cond ((eq view 'unthreaded) t)
 718                           ((eq view 'tree) nil)
 719                           (t notmuch-tree-unthreaded)))
 720         (query-context notmuch-tree-query-context)
 721         (target (notmuch-tree-get-message-id)))
 722     (erase-buffer)
 723     (notmuch-tree-worker basic-query
 724                          query-context
 725                          target
 726                          nil
 727                          unthreaded)))
 728
 729 (defun notmuch-tree-thread-top ()
 730   (when (notmuch-tree-get-message-properties)
 731     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 732       (forward-line -1))))
 733
 734 (defun notmuch-tree-prev-thread-in-tree ()
 735   "Move to the previous thread in the current tree"
 736   (interactive)
 737   (forward-line -1)
 738   (notmuch-tree-thread-top)
 739   (not (bobp)))
 740
 741 (defun notmuch-tree-next-thread-in-tree ()
 742   "Get the next thread in the current tree. Returns t if a thread was
 743 found or nil if not."
 744   (interactive)
 745   (forward-line 1)
 746   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 747     (forward-line 1))
 748   (not (eobp)))
 749
 750 (defun notmuch-tree-next-thread-from-search (&optional previous)
 751   "Move to the next thread in the parent search results, if any.
 752
 753 If PREVIOUS is non-nil, move to the previous item in the
 754 search results instead."
 755   (interactive "P")
 756   (let ((parent-buffer notmuch-tree-parent-buffer))
 757     (notmuch-tree-quit t)
 758     (when (buffer-live-p parent-buffer)
 759       (switch-to-buffer parent-buffer)
 760       (if previous
 761           (notmuch-search-previous-thread)
 762         (notmuch-search-next-thread))
 763       (notmuch-tree-from-search-thread))))
 764
 765 (defun notmuch-tree-next-thread (&optional previous)
 766   "Move to the next thread in the current tree or parent search
 767 results
 768
 769 If PREVIOUS is non-nil, move to the previous thread in the tree or
 770 search results instead."
 771   (interactive)
 772   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 773             (notmuch-tree-next-thread-in-tree))
 774     (notmuch-tree-next-thread-from-search previous)))
 775
 776 (defun notmuch-tree-prev-thread ()
 777   "Move to the previous thread in the current tree or parent search
 778 results"
 779   (interactive)
 780   (notmuch-tree-next-thread t))
 781
 782 (defun notmuch-tree-thread-mapcar (function)
 783   "Iterate through all messages in the current thread
 784  and call FUNCTION for side effects."
 785   (save-excursion
 786     (notmuch-tree-thread-top)
 787     (cl-loop collect (funcall function)
 788              do (forward-line)
 789              while (and (notmuch-tree-get-message-properties)
 790                         (not (notmuch-tree-get-prop :first))))))
 791
 792 (defun notmuch-tree-get-messages-ids-thread-search ()
 793   "Return a search string for all message ids of messages in the current thread."
 794   (mapconcat 'identity
 795              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 796              " or "))
 797
 798 (defun notmuch-tree-tag-thread (tag-changes)
 799   "Tag all messages in the current thread."
 800   (interactive
 801    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 802                                 (lambda () (notmuch-tree-get-tags))))))
 803      (list (notmuch-read-tag-changes tags "Tag thread"))))
 804   (when (notmuch-tree-get-message-properties)
 805     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 806     (notmuch-tree-thread-mapcar
 807      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 808
 809 (defun notmuch-tree-archive-thread (&optional unarchive)
 810   "Archive each message in thread.
 811
 812 Archive each message currently shown by applying the tag changes
 813 in `notmuch-archive-tags' to each. If a prefix argument is given,
 814 the messages will be \"unarchived\", i.e. the tag changes in
 815 `notmuch-archive-tags' will be reversed.
 816
 817 Note: This command is safe from any race condition of new messages
 818 being delivered to the same thread. It does not archive the
 819 entire thread, but only the messages shown in the current
 820 buffer."
 821   (interactive "P")
 822   (when notmuch-archive-tags
 823     (notmuch-tree-tag-thread
 824      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 825
 826 ;; Functions below here display the tree buffer itself.
 827
 828 (defun notmuch-tree-clean-address (address)
 829   "Try to clean a single email ADDRESS for display. Return
 830 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 831 unchanged ADDRESS if parsing fails."
 832   (let* ((clean-address (notmuch-clean-address address))
 833          (p-address (car clean-address))
 834          (p-name (cdr clean-address)))
 835
 836     ;; If we have a name return that otherwise return the address.
 837     (or p-name p-address)))
 838
 839 (defun notmuch-tree-format-field (field format-string msg)
 840   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 841   (let* ((headers (plist-get msg :headers))
 842          (match (plist-get msg :match)))
 843     (cond
 844      ((listp field)
 845       (format format-string (notmuch-tree-format-field-list field msg)))
 846
 847      ((string-equal field "date")
 848       (let ((face (if match
 849                       'notmuch-tree-match-date-face
 850                     'notmuch-tree-no-match-date-face)))
 851         (propertize (format format-string (plist-get msg :date_relative))
 852                     'face face)))
 853
 854      ((string-equal field "tree")
 855       (let ((tree-status (plist-get msg :tree-status))
 856             (face (if match
 857                       'notmuch-tree-match-tree-face
 858                     'notmuch-tree-no-match-tree-face)))
 859
 860         (propertize (format format-string
 861                             (mapconcat #'identity (reverse tree-status) ""))
 862                     'face face)))
 863
 864      ((string-equal field "subject")
 865       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 866             (previous-subject notmuch-tree-previous-subject)
 867             (face (if match
 868                       'notmuch-tree-match-subject-face
 869                     'notmuch-tree-no-match-subject-face)))
 870
 871         (setq notmuch-tree-previous-subject bare-subject)
 872         (propertize (format format-string
 873                             (if (string= previous-subject bare-subject)
 874                                 " ..."
 875                               bare-subject))
 876                     'face face)))
 877
 878      ((string-equal field "authors")
 879       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 880             (len (length (format format-string "")))
 881             (face (if match
 882                       'notmuch-tree-match-author-face
 883                     'notmuch-tree-no-match-author-face)))
 884         (when (> (length author) len)
 885           (setq author (substring author 0 len)))
 886         (propertize (format format-string author) 'face face)))
 887
 888      ((string-equal field "tags")
 889       (let ((tags (plist-get msg :tags))
 890             (orig-tags (plist-get msg :orig-tags))
 891             (face (if match
 892                       'notmuch-tree-match-tag-face
 893                     'notmuch-tree-no-match-tag-face)))
 894         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 895
 896 (defun notmuch-tree-format-field-list (field-list msg)
 897   "Format fields of MSG according to FIELD-LIST and return string."
 898   (let ((face (if (plist-get msg :match)
 899                   'notmuch-tree-match-face
 900                 'notmuch-tree-no-match-face))
 901         (result-string))
 902     (dolist (spec field-list result-string)
 903       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 904         (setq result-string (concat result-string field-string))))
 905     (notmuch-apply-face result-string face t)))
 906
 907 (defun notmuch-tree-insert-msg (msg)
 908   "Insert the message MSG according to notmuch-tree-result-format."
 909   ;; We need to save the previous subject as it will get overwritten
 910   ;; by the insert-field calls.
 911   (let ((previous-subject notmuch-tree-previous-subject))
 912     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 913     (notmuch-tree-set-message-properties msg)
 914     (notmuch-tree-set-prop :previous-subject previous-subject)
 915     (insert "\n")))
 916
 917 (defun notmuch-tree-goto-and-insert-msg (msg)
 918   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 919   (save-excursion
 920     (goto-char (point-max))
 921     (notmuch-tree-insert-msg msg))
 922   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 923         (target notmuch-tree-target-msg))
 924     (when (or (and (not target) (plist-get msg :match))
 925               (string= msg-id target))
 926       (setq notmuch-tree-target-msg "found")
 927       (goto-char (point-max))
 928       (forward-line -1)
 929       (when notmuch-tree-open-target
 930         (notmuch-tree-show-message-in)))))
 931
 932 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 933   "Insert the message tree TREE at depth DEPTH in the current thread.
 934
 935 A message tree is another name for a single sub-thread: i.e., a
 936 message together with all its descendents."
 937   (let ((msg (car tree))
 938         (replies (cadr tree)))
 939     (cond
 940      ((and (< 0 depth) (not last))
 941       (push "├" tree-status))
 942      ((and (< 0 depth) last)
 943       (push "╰" tree-status))
 944      ((and (eq 0 depth) first last)
 945       ;; Choice between these two variants is a matter of taste.
 946       ;; (push "─" tree-status))
 947       (push " " tree-status))
 948      ((and (eq 0 depth) first (not last))
 949       (push "┬" tree-status))
 950      ((and (eq 0 depth) (not first) last)
 951       (push "╰" tree-status))
 952      ((and (eq 0 depth) (not first) (not last))
 953       (push "├" tree-status)))
 954     (push (concat (if replies "┬" "─") "►") tree-status)
 955     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 956     (setq msg (plist-put msg :tree-status tree-status))
 957     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 958     (notmuch-tree-goto-and-insert-msg msg)
 959     (pop tree-status)
 960     (pop tree-status)
 961     (if last
 962         (push " " tree-status)
 963       (push "│" tree-status))
 964     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 965
 966 (defun notmuch-tree-insert-thread (thread depth tree-status)
 967   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 968   (let ((n (length thread)))
 969     (cl-loop for tree in thread
 970              for count from 1 to n
 971              do (notmuch-tree-insert-tree tree depth tree-status
 972                                           (eq count 1)
 973                                           (eq count n)))))
 974
 975 (defun notmuch-tree-insert-forest-thread (forest-thread)
 976   "Insert a single complete thread."
 977   (let (tree-status)
 978     ;; Reset at the start of each main thread.
 979     (setq notmuch-tree-previous-subject nil)
 980     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
 981
 982 (defun notmuch-tree-insert-forest (forest)
 983   "Insert a forest of threads.
 984
 985 This function inserts a collection of several complete threads as
 986 passed to it by notmuch-tree-process-filter."
 987   (mapc 'notmuch-tree-insert-forest-thread forest))
 988
 989 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
 990   "Major mode displaying messages (as opposed to threads) of a notmuch search.
 991
 992 This buffer contains the results of a \"notmuch tree\" of your
 993 email archives. Each line in the buffer represents a single
 994 message giving the relative date, the author, subject, and any
 995 tags.
 996
 997 Pressing \\[notmuch-tree-show-message] on any line displays that message.
 998
 999 Complete list of currently available key bindings:
1000
1001 \\{notmuch-tree-mode-map}"
1002   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1003   (hl-line-mode 1)
1004   (setq buffer-read-only t)
1005   (setq truncate-lines t))
1006
1007 (defun notmuch-tree-process-sentinel (proc msg)
1008   "Add a message to let user know when \"notmuch tree\" exits."
1009   (let ((buffer (process-buffer proc))
1010         (status (process-status proc))
1011         (exit-status (process-exit-status proc))
1012         (never-found-target-thread nil))
1013     (when (memq status '(exit signal))
1014       (kill-buffer (process-get proc 'parse-buf))
1015       (when (buffer-live-p buffer)
1016         (with-current-buffer buffer
1017           (save-excursion
1018             (let ((inhibit-read-only t)
1019                   (atbob (bobp)))
1020               (goto-char (point-max))
1021               (when (eq status 'signal)
1022                 (insert "Incomplete search results (tree view process was killed).\n"))
1023               (when (eq status 'exit)
1024                 (insert "End of search results.")
1025                 (unless (= exit-status 0)
1026                   (insert (format " (process returned %d)" exit-status)))
1027                 (insert "\n")))))))))
1028
1029 (defun notmuch-tree-process-filter (proc string)
1030   "Process and filter the output of \"notmuch show\" for tree view."
1031   (let ((results-buf (process-buffer proc))
1032         (parse-buf (process-get proc 'parse-buf))
1033         (inhibit-read-only t)
1034         done)
1035     (if (not (buffer-live-p results-buf))
1036         (delete-process proc)
1037       (with-current-buffer parse-buf
1038         ;; Insert new data
1039         (save-excursion
1040           (goto-char (point-max))
1041           (insert string))
1042         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1043                                          results-buf)))))
1044
1045 (defun notmuch-tree-worker (basic-query &optional query-context target open-target unthreaded)
1046   "Insert the tree view of the search in the current buffer.
1047
1048 This is is a helper function for notmuch-tree. The arguments are
1049 the same as for the function notmuch-tree."
1050   (interactive)
1051   (notmuch-tree-mode)
1052   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1053   (setq notmuch-tree-unthreaded unthreaded)
1054   (setq notmuch-tree-basic-query basic-query)
1055   (setq notmuch-tree-query-context (if (or (string= query-context "")
1056                                            (string= query-context "*"))
1057                                        nil
1058                                      query-context))
1059   (setq notmuch-tree-target-msg target)
1060   (setq notmuch-tree-open-target open-target)
1061   ;; Set the default value for `notmuch-show-process-crypto' in this
1062   ;; buffer. Although we don't use this some of the functions we call
1063   ;; (such as reply) do. It is a buffer local variable so setting it
1064   ;; will not affect genuine show buffers.
1065   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1066   (erase-buffer)
1067   (goto-char (point-min))
1068   (let* ((search-args (concat basic-query
1069                               (and query-context
1070                                    (concat " and (" query-context ")"))))
1071          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1072     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1073       (setq search-args basic-query))
1074     (notmuch-tag-clear-cache)
1075     (let ((proc (notmuch-start-notmuch
1076                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1077                  "show" "--body=false" "--format=sexp" "--format-version=4"
1078                  message-arg search-args))
1079           ;; Use a scratch buffer to accumulate partial output.
1080           ;; This buffer will be killed by the sentinel, which
1081           ;; should be called no matter how the process dies.
1082           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1083       (process-put proc 'parse-buf parse-buf)
1084       (set-process-filter proc 'notmuch-tree-process-filter)
1085       (set-process-query-on-exit-flag proc nil))))
1086
1087 (defun notmuch-tree-get-query ()
1088   "Return the current query in this tree buffer."
1089   (if notmuch-tree-query-context
1090       (concat notmuch-tree-basic-query
1091               " and ("
1092               notmuch-tree-query-context
1093               ")")
1094     notmuch-tree-basic-query))
1095
1096 (defun notmuch-tree (&optional query query-context target buffer-name open-target unthreaded parent-buffer)
1097   "Display threads matching QUERY in tree view.
1098
1099 The arguments are:
1100   QUERY: the main query. This can be any query but in many cases will be
1101       a single thread. If nil this is read interactively from the minibuffer.
1102   QUERY-CONTEXT: is an additional term for the query. The query used
1103       is QUERY and QUERY-CONTEXT unless that does not match any messages
1104       in which case we fall back to just QUERY.
1105   TARGET: A message ID (with the id: prefix) that will be made
1106       current if it appears in the tree view results.
1107   BUFFER-NAME: the name of the buffer to display the tree view. If
1108       it is nil \"*notmuch-tree\" followed by QUERY is used.
1109   OPEN-TARGET: If TRUE open the target message in the message pane.
1110   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1111   (interactive)
1112   (unless query
1113     (setq query (notmuch-read-query (concat "Notmuch "
1114                                             (if unthreaded "unthreaded " "tree ")
1115                                             "view search: "))))
1116   (let ((buffer (get-buffer-create (generate-new-buffer-name
1117                                     (or buffer-name
1118                                         (concat "*notmuch-"
1119                                                 (if unthreaded "unthreaded-" "tree-")
1120                                                 query "*")))))
1121         (inhibit-read-only t))
1122     (switch-to-buffer buffer))
1123   ;; Don't track undo information for this buffer
1124   (set 'buffer-undo-list t)
1125   (notmuch-tree-worker query query-context target open-target unthreaded)
1126   (setq notmuch-tree-parent-buffer parent-buffer)
1127   (setq truncate-lines t))
1128
1129 (defun notmuch-unthreaded (&optional query query-context target buffer-name open-target)
1130   (interactive)
1131   (notmuch-tree query query-context target buffer-name open-target t))
1132
1133 ;;
1134
1135 (provide 'notmuch-tree)
1136
1137 ;;; notmuch-tree.el ends here