git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28
  29 (require 'notmuch-lib)
  30 (require 'notmuch-query)
  31 (require 'notmuch-show)
  32 (require 'notmuch-tag)
  33 (require 'notmuch-parser)
  34
  35 (eval-when-compile (require 'cl))
  36 (declare-function notmuch-search "notmuch" (&optional query oldest-first target-thread target-line))
  37 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  38 (declare-function notmuch-read-query "notmuch" (prompt))
  39 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  40 (declare-function notmuch-search-find-subject "notmuch" ())
  41
  42 ;; the following variable is defined in notmuch.el
  43 (defvar notmuch-search-query-string)
  44
  45 (defgroup notmuch-tree nil
  46   "Showing message and thread structure."
  47   :group 'notmuch)
  48
  49 (defcustom notmuch-tree-show-out nil
  50   "View selected messages in new window rather than split-pane."
  51   :type 'boolean
  52   :group 'notmuch-tree)
  53
  54 (defcustom notmuch-tree-result-format
  55   `(("date" . "%12s  ")
  56     ("authors" . "%-20s")
  57     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  58     ("tags" . "(%s)"))
  59   "Result formatting for Tree view. Supported fields are: date,
  60         authors, subject, tree, tags.  Tree means the thread tree
  61         box graphics. The field may also be a list in which case
  62         the formatting rules are applied recursively and then the
  63         output of all the fields in the list is inserted
  64         according to format-string.
  65
  66 Note the author string should not contain
  67         whitespace (put it in the neighbouring fields instead).
  68         For example:
  69         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  70                                              \(\"subject\" . \"%s\"\)\)\)"
  71   :type '(alist :key-type (string) :value-type (string))
  72   :group 'notmuch-tree)
  73
  74 ;; Faces for messages that match the query.
  75 (defface notmuch-tree-match-face
  76   '((t :inherit default))
  77   "Default face used in tree mode face for matching messages"
  78   :group 'notmuch-tree
  79   :group 'notmuch-faces)
  80
  81 (defface notmuch-tree-match-date-face
  82   nil
  83   "Face used in tree mode for the date in messages matching the query."
  84   :group 'notmuch-tree
  85   :group 'notmuch-faces)
  86
  87 (defface notmuch-tree-match-author-face
  88   '((((class color)
  89       (background dark))
  90      (:foreground "OliveDrab1"))
  91     (((class color)
  92       (background light))
  93      (:foreground "dark blue"))
  94     (t
  95      (:bold t)))
  96   "Face used in tree mode for the date in messages matching the query."
  97   :group 'notmuch-tree
  98   :group 'notmuch-faces)
  99
 100 (defface notmuch-tree-match-subject-face
 101   nil
 102   "Face used in tree mode for the subject in messages matching the query."
 103   :group 'notmuch-tree
 104   :group 'notmuch-faces)
 105
 106 (defface notmuch-tree-match-tree-face
 107   nil
 108   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 109   :group 'notmuch-tree
 110   :group 'notmuch-faces)
 111
 112 (defface notmuch-tree-match-tag-face
 113   '((((class color)
 114       (background dark))
 115      (:foreground "OliveDrab1"))
 116     (((class color)
 117       (background light))
 118      (:foreground "navy blue" :bold t))
 119     (t
 120      (:bold t)))
 121   "Face used in tree mode for tags in messages matching the query."
 122   :group 'notmuch-tree
 123   :group 'notmuch-faces)
 124
 125 ;; Faces for messages that do not match the query.
 126 (defface notmuch-tree-no-match-face
 127   '((t (:foreground "gray")))
 128   "Default face used in tree mode face for non-matching messages"
 129   :group 'notmuch-tree
 130   :group 'notmuch-faces)
 131
 132 (defface notmuch-tree-no-match-date-face
 133   nil
 134   "Face used in tree mode for non-matching dates."
 135   :group 'notmuch-tree
 136   :group 'notmuch-faces)
 137
 138 (defface notmuch-tree-no-match-subject-face
 139   nil
 140   "Face used in tree mode for non-matching subjects."
 141   :group 'notmuch-tree
 142   :group 'notmuch-faces)
 143
 144 (defface notmuch-tree-no-match-tree-face
 145   nil
 146   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 147   :group 'notmuch-tree
 148   :group 'notmuch-faces)
 149
 150 (defface notmuch-tree-no-match-author-face
 151   nil
 152   "Face used in tree mode for the date in messages matching the query."
 153   :group 'notmuch-tree
 154   :group 'notmuch-faces)
 155
 156 (defface notmuch-tree-no-match-tag-face
 157   nil
 158   "Face used in tree mode face for non-matching tags."
 159   :group 'notmuch-tree
 160   :group 'notmuch-faces)
 161
 162 (defvar notmuch-tree-previous-subject
 163   "The subject of the most recent result shown during the async display")
 164 (make-variable-buffer-local 'notmuch-tree-previous-subject)
 165
 166 (defvar notmuch-tree-basic-query nil
 167   "A buffer local copy of argument query to the function notmuch-tree")
 168 (make-variable-buffer-local 'notmuch-tree-basic-query)
 169
 170 (defvar notmuch-tree-query-context nil
 171   "A buffer local copy of argument query-context to the function notmuch-tree")
 172 (make-variable-buffer-local 'notmuch-tree-query-context)
 173
 174 (defvar notmuch-tree-target-msg nil
 175   "A buffer local copy of argument target to the function notmuch-tree")
 176 (make-variable-buffer-local 'notmuch-tree-target-msg)
 177
 178 (defvar notmuch-tree-open-target nil
 179   "A buffer local copy of argument open-target to the function notmuch-tree")
 180 (make-variable-buffer-local 'notmuch-tree-open-target)
 181
 182 (defvar notmuch-tree-message-window nil
 183   "The window of the message pane.
 184
 185 It is set in both the tree buffer and the child show buffer. It
 186 is used to try and close the message pane when quitting tree view
 187 or the child show buffer.")
 188 (make-variable-buffer-local 'notmuch-tree-message-window)
 189 (put 'notmuch-tree-message-window 'permanent-local t)
 190
 191 (defvar notmuch-tree-message-buffer nil
 192   "The buffer name of the show buffer in the message pane.
 193
 194 This is used to try and make sure we don't close the message pane
 195 if the user has loaded a different buffer in that window.")
 196 (make-variable-buffer-local 'notmuch-tree-message-buffer)
 197 (put 'notmuch-tree-message-buffer 'permanent-local t)
 198
 199 (defun notmuch-tree-to-message-pane (func)
 200   "Execute FUNC in message pane.
 201
 202 This function returns a function (so can be used as a keybinding)
 203 which executes function FUNC in the message pane if it is
 204 open (if the message pane is closed it does nothing)."
 205   `(lambda ()
 206       ,(concat "(In message pane) " (documentation func t))
 207      (interactive)
 208      (when (window-live-p notmuch-tree-message-window)
 209        (with-selected-window notmuch-tree-message-window
 210          (call-interactively #',func)))))
 211
 212 (defun notmuch-tree-inherit-from-message-pane (sym)
 213   "Return value of SYM in message-pane if open, or tree-pane if not"
 214   (if (window-live-p notmuch-tree-message-window)
 215       (with-selected-window notmuch-tree-message-window
 216         (symbol-value sym))
 217     (symbol-value sym)))
 218
 219 (defun notmuch-tree-button-activate (&optional button)
 220   "Activate BUTTON or button at point
 221
 222 This function does not give an error if there is no button."
 223   (interactive)
 224   (let ((button (or button (button-at (point)))))
 225     (when button (button-activate button))))
 226
 227 (defun notmuch-tree-close-message-pane-and (func)
 228   "Close message pane and execute FUNC.
 229
 230 This function returns a function (so can be used as a keybinding)
 231 which closes the message pane if open and then executes function
 232 FUNC."
 233   `(lambda ()
 234       ,(concat "(Close message pane and) " (documentation func t))
 235      (interactive)
 236      (let ((notmuch-show-process-crypto
 237             (notmuch-tree-inherit-from-message-pane 'notmuch-show-process-crypto)))
 238        (notmuch-tree-close-message-window)
 239        (call-interactively #',func))))
 240
 241 (defvar notmuch-tree-mode-map
 242   (let ((map (make-sparse-keymap)))
 243     (set-keymap-parent map notmuch-common-keymap)
 244     ;; The following override the global keymap.
 245     ;; Override because we want to close message pane first.
 246     (define-key map [remap notmuch-help] (notmuch-tree-close-message-pane-and #'notmuch-help))
 247     ;; Override because we first close message pane and then close tree buffer.
 248     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 249     ;; Override because we close message pane after the search query is entered.
 250     (define-key map [remap notmuch-search] 'notmuch-tree-to-search)
 251     ;; Override because we want to close message pane first.
 252     (define-key map [remap notmuch-mua-new-mail] (notmuch-tree-close-message-pane-and #'notmuch-mua-new-mail))
 253     ;; Override because we want to close message pane first.
 254     (define-key map [remap notmuch-jump-search] (notmuch-tree-close-message-pane-and #'notmuch-jump-search))
 255
 256     (define-key map "S" 'notmuch-search-from-tree-current-query)
 257
 258     ;; these use notmuch-show functions directly
 259     (define-key map "|" 'notmuch-show-pipe-message)
 260     (define-key map "w" 'notmuch-show-save-attachments)
 261     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 262     (define-key map "c" 'notmuch-show-stash-map)
 263     (define-key map "b" 'notmuch-show-resend-message)
 264
 265     ;; these apply to the message pane
 266     (define-key map (kbd "M-TAB") (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 267     (define-key map (kbd "<backtab>")  (notmuch-tree-to-message-pane #'notmuch-show-previous-button))
 268     (define-key map (kbd "TAB") (notmuch-tree-to-message-pane #'notmuch-show-next-button))
 269     (define-key map "e" (notmuch-tree-to-message-pane #'notmuch-tree-button-activate))
 270     (define-key map "$" (notmuch-tree-to-message-pane #'notmuch-show-toggle-process-crypto))
 271
 272     ;; bindings from show (or elsewhere) but we close the message pane first.
 273     (define-key map "f" (notmuch-tree-close-message-pane-and #'notmuch-show-forward-message))
 274     (define-key map "r" (notmuch-tree-close-message-pane-and #'notmuch-show-reply-sender))
 275     (define-key map "R" (notmuch-tree-close-message-pane-and #'notmuch-show-reply))
 276     (define-key map "V" (notmuch-tree-close-message-pane-and #'notmuch-show-view-raw-message))
 277
 278     ;; The main tree view bindings
 279     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 280     (define-key map [mouse-1] 'notmuch-tree-show-message)
 281     (define-key map "x" 'notmuch-tree-quit)
 282     (define-key map "A" 'notmuch-tree-archive-thread)
 283     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 284     (define-key map "z" 'notmuch-tree-to-tree)
 285     (define-key map "n" 'notmuch-tree-next-matching-message)
 286     (define-key map "p" 'notmuch-tree-prev-matching-message)
 287     (define-key map "N" 'notmuch-tree-next-message)
 288     (define-key map "P" 'notmuch-tree-prev-message)
 289     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 290     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 291     (define-key map "k" 'notmuch-tag-jump)
 292     (define-key map "-" 'notmuch-tree-remove-tag)
 293     (define-key map "+" 'notmuch-tree-add-tag)
 294     (define-key map "*" 'notmuch-tree-tag-thread)
 295     (define-key map " " 'notmuch-tree-scroll-or-next)
 296     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 297     map))
 298 (fset 'notmuch-tree-mode-map notmuch-tree-mode-map)
 299
 300 (defun notmuch-tree-get-message-properties ()
 301   "Return the properties of the current message as a plist.
 302
 303 Some useful entries are:
 304 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 305 :tags - Tags for this message"
 306   (save-excursion
 307     (beginning-of-line)
 308     (get-text-property (point) :notmuch-message-properties)))
 309
 310 (defun notmuch-tree-set-message-properties (props)
 311   (save-excursion
 312     (beginning-of-line)
 313     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
 314
 315 (defun notmuch-tree-set-prop (prop val &optional props)
 316   (let ((inhibit-read-only t)
 317         (props (or props
 318                    (notmuch-tree-get-message-properties))))
 319     (plist-put props prop val)
 320     (notmuch-tree-set-message-properties props)))
 321
 322 (defun notmuch-tree-get-prop (prop &optional props)
 323   (let ((props (or props
 324                    (notmuch-tree-get-message-properties))))
 325     (plist-get props prop)))
 326
 327 (defun notmuch-tree-set-tags (tags)
 328   "Set the tags of the current message."
 329   (notmuch-tree-set-prop :tags tags))
 330
 331 (defun notmuch-tree-get-tags ()
 332   "Return the tags of the current message."
 333   (notmuch-tree-get-prop :tags))
 334
 335 (defun notmuch-tree-get-message-id (&optional bare)
 336   "Return the message id of the current message."
 337   (let ((id (notmuch-tree-get-prop :id)))
 338     (if id
 339         (if bare
 340             id
 341           (notmuch-id-to-query id))
 342       nil)))
 343
 344 (defun notmuch-tree-get-match ()
 345   "Return whether the current message is a match."
 346   (interactive)
 347   (notmuch-tree-get-prop :match))
 348
 349 (defun notmuch-tree-refresh-result ()
 350   "Redisplay the current message line.
 351
 352 This redisplays the current line based on the messages
 353 properties (as they are now). This is used when tags are
 354 updated."
 355   (let ((init-point (point))
 356         (end (line-end-position))
 357         (msg (notmuch-tree-get-message-properties))
 358         (inhibit-read-only t))
 359     (beginning-of-line)
 360     ;; This is a little tricky: we override
 361     ;; notmuch-tree-previous-subject to get the decision between
 362     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 363     ;; from overwriting the buffer local copy of
 364     ;; notmuch-tree-previous-subject if this is called while the
 365     ;; buffer is displaying.
 366     (let ((notmuch-tree-previous-subject (notmuch-tree-get-prop :previous-subject)))
 367       (delete-region (point) (1+ (line-end-position)))
 368       (notmuch-tree-insert-msg msg))
 369     (let ((new-end (line-end-position)))
 370       (goto-char (if (= init-point end)
 371                      new-end
 372                    (min init-point (- new-end 1)))))))
 373
 374 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 375   "Update display for TAG-CHANGES to current message.
 376
 377 Updates the message in the message pane if appropriate, but does
 378 NOT change the database."
 379   (let* ((current-tags (notmuch-tree-get-tags))
 380          (new-tags (notmuch-update-tags current-tags tag-changes))
 381          (tree-msg-id (notmuch-tree-get-message-id)))
 382     (unless (equal current-tags new-tags)
 383       (notmuch-tree-set-tags new-tags)
 384       (notmuch-tree-refresh-result)
 385       (when (window-live-p notmuch-tree-message-window)
 386         (with-selected-window notmuch-tree-message-window
 387           (when (string= tree-msg-id (notmuch-show-get-message-id))
 388             (notmuch-show-update-tags new-tags)))))))
 389
 390 (defun notmuch-tree-tag (tag-changes)
 391   "Change tags for the current message"
 392   (interactive
 393    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 394   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 395   (notmuch-tree-tag-update-display tag-changes))
 396
 397 (defun notmuch-tree-add-tag (tag-changes)
 398   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 399   (interactive
 400    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 401   (notmuch-tree-tag tag-changes))
 402
 403 (defun notmuch-tree-remove-tag (tag-changes)
 404   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 405   (interactive
 406    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 407   (notmuch-tree-tag tag-changes))
 408
 409 ;; The next two functions close the message window before calling
 410 ;; notmuch-search or notmuch-tree but they do so after the user has
 411 ;; entered the query (in case the user was basing the query on
 412 ;; something in the message window).
 413
 414 (defun notmuch-tree-to-search ()
 415   "Run \"notmuch search\" with the given `query' and display results."
 416   (interactive)
 417   (let ((query (notmuch-read-query "Notmuch search: ")))
 418     (notmuch-tree-close-message-window)
 419     (notmuch-search query)))
 420
 421 (defun notmuch-tree-to-tree ()
 422   "Run a query and display results in Tree view"
 423   (interactive)
 424   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 425     (notmuch-tree-close-message-window)
 426     (notmuch-tree query)))
 427
 428 (defun notmuch-search-from-tree-current-query ()
 429   "Call notmuch search with the current query"
 430   (interactive)
 431   (notmuch-tree-close-message-window)
 432   (notmuch-search (notmuch-tree-get-query)))
 433
 434 (defun notmuch-tree-message-window-kill-hook ()
 435   "Close the message pane when exiting the show buffer."
 436   (let ((buffer (current-buffer)))
 437     (when (and (window-live-p notmuch-tree-message-window)
 438                (eq (window-buffer notmuch-tree-message-window) buffer))
 439       ;; We do not want an error if this is the sole window in the
 440       ;; frame and I do not know how to test for that in emacs pre
 441       ;; 24. Hence we just ignore-errors.
 442       (ignore-errors
 443         (delete-window notmuch-tree-message-window)))))
 444
 445 (defun notmuch-tree-command-hook ()
 446   (when (eq major-mode 'notmuch-tree-mode)
 447     ;; We just run the notmuch-show-command-hook on the message pane.
 448     (when (buffer-live-p notmuch-tree-message-buffer)
 449       (with-current-buffer notmuch-tree-message-buffer
 450         (notmuch-show-command-hook)))))
 451
 452 (defun notmuch-tree-show-message-in ()
 453   "Show the current message (in split-pane)."
 454   (interactive)
 455   (let ((id (notmuch-tree-get-message-id))
 456         (inhibit-read-only t)
 457         buffer)
 458     (when id
 459       ;; We close and reopen the window to kill off un-needed buffers
 460       ;; this might cause flickering but seems ok.
 461       (notmuch-tree-close-message-window)
 462       (setq notmuch-tree-message-window
 463             (split-window-vertically (/ (window-height) 4)))
 464       (with-selected-window notmuch-tree-message-window
 465         ;; Since we are only displaying one message do not indent.
 466         (let ((notmuch-show-indent-messages-width 0)
 467               (notmuch-show-only-matching-messages t))
 468           (setq buffer (notmuch-show id))))
 469       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 470       (let ((window notmuch-tree-message-window))
 471         (with-current-buffer buffer
 472           (setq notmuch-tree-message-window window)
 473           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 474       (when notmuch-show-mark-read-tags
 475         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 476       (setq notmuch-tree-message-buffer buffer))))
 477
 478 (defun notmuch-tree-show-message-out ()
 479   "Show the current message (in whole window)."
 480   (interactive)
 481   (let ((id (notmuch-tree-get-message-id))
 482         (inhibit-read-only t)
 483         buffer)
 484     (when id
 485       ;; We close the window to kill off un-needed buffers.
 486       (notmuch-tree-close-message-window)
 487       (notmuch-show id))))
 488
 489 (defun notmuch-tree-show-message (arg)
 490   "Show the current message.
 491
 492 Shows in split pane or whole window according to value of
 493 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 494   (interactive "P")
 495   (if (or (and notmuch-tree-show-out  (not arg))
 496           (and (not notmuch-tree-show-out) arg))
 497       (notmuch-tree-show-message-out)
 498     (notmuch-tree-show-message-in)))
 499
 500 (defun notmuch-tree-scroll-message-window ()
 501   "Scroll the message window (if it exists)"
 502   (interactive)
 503   (when (window-live-p notmuch-tree-message-window)
 504     (with-selected-window notmuch-tree-message-window
 505       (if (pos-visible-in-window-p (point-max))
 506           t
 507         (scroll-up)))))
 508
 509 (defun notmuch-tree-scroll-message-window-back ()
 510   "Scroll the message window back(if it exists)"
 511   (interactive)
 512   (when (window-live-p notmuch-tree-message-window)
 513     (with-selected-window notmuch-tree-message-window
 514       (if (pos-visible-in-window-p (point-min))
 515           t
 516         (scroll-down)))))
 517
 518 (defun notmuch-tree-scroll-or-next ()
 519   "Scroll the message window. If it at end go to next message."
 520   (interactive)
 521   (when (notmuch-tree-scroll-message-window)
 522     (notmuch-tree-next-matching-message)))
 523
 524 (defun notmuch-tree-quit ()
 525   "Close the split view or exit tree."
 526   (interactive)
 527   (unless (notmuch-tree-close-message-window)
 528     (kill-buffer (current-buffer))))
 529
 530 (defun notmuch-tree-close-message-window ()
 531   "Close the message-window. Return t if close succeeds."
 532   (interactive)
 533   (when (and (window-live-p notmuch-tree-message-window)
 534              (eq (window-buffer notmuch-tree-message-window) notmuch-tree-message-buffer))
 535     (delete-window notmuch-tree-message-window)
 536     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 537       (kill-buffer notmuch-tree-message-buffer))
 538     t))
 539
 540 (defun notmuch-tree-archive-message (&optional unarchive)
 541   "Archive the current message.
 542
 543 Archive the current message by applying the tag changes in
 544 `notmuch-archive-tags' to it. If a prefix argument is given, the
 545 message will be \"unarchived\", i.e. the tag changes in
 546 `notmuch-archive-tags' will be reversed."
 547   (interactive "P")
 548   (when notmuch-archive-tags
 549     (notmuch-tree-tag (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 550
 551 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 552   "Archive the current message and move to next matching message."
 553   (interactive "P")
 554   (notmuch-tree-archive-message unarchive)
 555   (notmuch-tree-next-matching-message))
 556
 557 (defun notmuch-tree-next-message ()
 558   "Move to next message."
 559   (interactive)
 560   (forward-line)
 561   (when (window-live-p notmuch-tree-message-window)
 562     (notmuch-tree-show-message-in)))
 563
 564 (defun notmuch-tree-prev-message ()
 565   "Move to previous message."
 566   (interactive)
 567   (forward-line -1)
 568   (when (window-live-p notmuch-tree-message-window)
 569     (notmuch-tree-show-message-in)))
 570
 571 (defun notmuch-tree-prev-matching-message ()
 572   "Move to previous matching message."
 573   (interactive)
 574   (forward-line -1)
 575   (while (and (not (bobp)) (not (notmuch-tree-get-match)))
 576     (forward-line -1))
 577   (when (window-live-p notmuch-tree-message-window)
 578     (notmuch-tree-show-message-in)))
 579
 580 (defun notmuch-tree-next-matching-message ()
 581   "Move to next matching message."
 582   (interactive)
 583   (forward-line)
 584   (while (and (not (eobp)) (not (notmuch-tree-get-match)))
 585     (forward-line))
 586   (when (window-live-p notmuch-tree-message-window)
 587     (notmuch-tree-show-message-in)))
 588
 589 (defun notmuch-tree-refresh-view ()
 590   "Refresh view."
 591   (interactive)
 592   (let ((inhibit-read-only t)
 593         (basic-query notmuch-tree-basic-query)
 594         (query-context notmuch-tree-query-context)
 595         (target (notmuch-tree-get-message-id)))
 596     (erase-buffer)
 597     (notmuch-tree-worker basic-query
 598                          query-context
 599                          target)))
 600
 601 (defun notmuch-tree-thread-top ()
 602   (when (notmuch-tree-get-message-properties)
 603     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 604       (forward-line -1))))
 605
 606 (defun notmuch-tree-prev-thread ()
 607   (interactive)
 608   (forward-line -1)
 609   (notmuch-tree-thread-top))
 610
 611 (defun notmuch-tree-next-thread ()
 612   (interactive)
 613   (forward-line 1)
 614   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 615     (forward-line 1)))
 616
 617 (defun notmuch-tree-thread-mapcar (function)
 618   "Iterate through all messages in the current thread
 619  and call FUNCTION for side effects."
 620   (save-excursion
 621     (notmuch-tree-thread-top)
 622     (loop collect (funcall function)
 623           do (forward-line)
 624           while (and (notmuch-tree-get-message-properties)
 625                      (not (notmuch-tree-get-prop :first))))))
 626
 627 (defun notmuch-tree-get-messages-ids-thread-search ()
 628   "Return a search string for all message ids of messages in the current thread."
 629   (mapconcat 'identity
 630              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 631              " or "))
 632
 633 (defun notmuch-tree-tag-thread (tag-changes)
 634   "Tag all messages in the current thread"
 635   (interactive
 636    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 637                                 (lambda () (notmuch-tree-get-tags))))))
 638      (list (notmuch-read-tag-changes tags "Tag thread"))))
 639   (when (notmuch-tree-get-message-properties)
 640     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 641     (notmuch-tree-thread-mapcar
 642      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 643
 644 (defun notmuch-tree-archive-thread (&optional unarchive)
 645   "Archive each message in thread.
 646
 647 Archive each message currently shown by applying the tag changes
 648 in `notmuch-archive-tags' to each. If a prefix argument is given,
 649 the messages will be \"unarchived\", i.e. the tag changes in
 650 `notmuch-archive-tags' will be reversed.
 651
 652 Note: This command is safe from any race condition of new messages
 653 being delivered to the same thread. It does not archive the
 654 entire thread, but only the messages shown in the current
 655 buffer."
 656   (interactive "P")
 657   (when notmuch-archive-tags
 658     (notmuch-tree-tag-thread
 659      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 660
 661 ;; Functions below here display the tree buffer itself.
 662
 663 (defun notmuch-tree-clean-address (address)
 664   "Try to clean a single email ADDRESS for display. Return
 665 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 666 unchanged ADDRESS if parsing fails."
 667   (let* ((clean-address (notmuch-clean-address address))
 668          (p-address (car clean-address))
 669          (p-name (cdr clean-address)))
 670
 671     ;; If we have a name return that otherwise return the address.
 672     (or p-name p-address)))
 673
 674 (defun notmuch-tree-format-field (field format-string msg)
 675   "Format a FIELD of MSG according to FORMAT-STRING and return string"
 676   (let* ((headers (plist-get msg :headers))
 677          (match (plist-get msg :match)))
 678     (cond
 679      ((listp field)
 680       (format format-string (notmuch-tree-format-field-list field msg)))
 681
 682      ((string-equal field "date")
 683       (let ((face (if match
 684                       'notmuch-tree-match-date-face
 685                     'notmuch-tree-no-match-date-face)))
 686         (propertize (format format-string (plist-get msg :date_relative)) 'face face)))
 687
 688      ((string-equal field "tree")
 689       (let ((tree-status (plist-get msg :tree-status))
 690             (face (if match
 691                       'notmuch-tree-match-tree-face
 692                     'notmuch-tree-no-match-tree-face)))
 693
 694         (propertize (format format-string
 695                             (mapconcat #'identity (reverse tree-status) ""))
 696                     'face face)))
 697
 698      ((string-equal field "subject")
 699       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 700             (previous-subject notmuch-tree-previous-subject)
 701             (face (if match
 702                       'notmuch-tree-match-subject-face
 703                     'notmuch-tree-no-match-subject-face)))
 704
 705         (setq notmuch-tree-previous-subject bare-subject)
 706         (propertize (format format-string
 707                             (if (string= previous-subject bare-subject)
 708                                 " ..."
 709                               bare-subject))
 710                     'face face)))
 711
 712      ((string-equal field "authors")
 713       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 714             (len (length (format format-string "")))
 715             (face (if match
 716                       'notmuch-tree-match-author-face
 717                     'notmuch-tree-no-match-author-face)))
 718         (when (> (length author) len)
 719           (setq author (substring author 0 len)))
 720         (propertize (format format-string author) 'face face)))
 721
 722      ((string-equal field "tags")
 723       (let ((tags (plist-get msg :tags))
 724             (orig-tags (plist-get msg :orig-tags))
 725             (face (if match
 726                       'notmuch-tree-match-tag-face
 727                     'notmuch-tree-no-match-tag-face)))
 728         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 729
 730 (defun notmuch-tree-format-field-list (field-list msg)
 731   "Format fields of MSG according to FIELD-LIST and return string"
 732   (let ((face (if (plist-get msg :match)
 733                   'notmuch-tree-match-face
 734                 'notmuch-tree-no-match-face))
 735         (result-string))
 736     (dolist (spec field-list result-string)
 737       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 738         (setq result-string (concat result-string field-string))))
 739     (notmuch-apply-face result-string face t)))
 740
 741 (defun notmuch-tree-insert-msg (msg)
 742   "Insert the message MSG according to notmuch-tree-result-format"
 743   ;; We need to save the previous subject as it will get overwritten
 744   ;; by the insert-field calls.
 745   (let ((previous-subject notmuch-tree-previous-subject))
 746     (insert (notmuch-tree-format-field-list notmuch-tree-result-format msg))
 747     (notmuch-tree-set-message-properties msg)
 748     (notmuch-tree-set-prop :previous-subject previous-subject)
 749     (insert "\n")))
 750
 751 (defun notmuch-tree-goto-and-insert-msg (msg)
 752   "Insert msg at the end of the buffer. Move point to msg if it is the target"
 753   (save-excursion
 754     (goto-char (point-max))
 755     (notmuch-tree-insert-msg msg))
 756   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 757         (target notmuch-tree-target-msg))
 758     (when (or (and (not target) (plist-get msg :match))
 759               (string= msg-id target))
 760       (setq notmuch-tree-target-msg "found")
 761       (goto-char (point-max))
 762       (forward-line -1)
 763       (when notmuch-tree-open-target
 764         (notmuch-tree-show-message-in)))))
 765
 766 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 767   "Insert the message tree TREE at depth DEPTH in the current thread.
 768
 769 A message tree is another name for a single sub-thread: i.e., a
 770 message together with all its descendents."
 771   (let ((msg (car tree))
 772         (replies (cadr tree)))
 773
 774       (cond
 775        ((and (< 0 depth) (not last))
 776         (push "├" tree-status))
 777        ((and (< 0 depth) last)
 778         (push "╰" tree-status))
 779        ((and (eq 0 depth) first last)
 780 ;;        (push "─" tree-status)) choice between this and next line is matter of taste.
 781         (push " " tree-status))
 782        ((and (eq 0 depth) first (not last))
 783           (push "┬" tree-status))
 784        ((and (eq 0 depth) (not first) last)
 785         (push "╰" tree-status))
 786        ((and (eq 0 depth) (not first) (not last))
 787         (push "├" tree-status)))
 788
 789       (push (concat (if replies "┬" "─") "►") tree-status)
 790       (setq msg (plist-put msg :first (and first (eq 0 depth))))
 791       (setq msg (plist-put msg :tree-status tree-status))
 792       (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 793       (notmuch-tree-goto-and-insert-msg msg)
 794       (pop tree-status)
 795       (pop tree-status)
 796
 797       (if last
 798           (push " " tree-status)
 799         (push "│" tree-status))
 800
 801     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 802
 803 (defun notmuch-tree-insert-thread (thread depth tree-status)
 804   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 805   (let ((n (length thread)))
 806     (loop for tree in thread
 807           for count from 1 to n
 808
 809           do (notmuch-tree-insert-tree tree depth tree-status (eq count 1) (eq count n)))))
 810
 811 (defun notmuch-tree-insert-forest-thread (forest-thread)
 812   "Insert a single complete thread."
 813   (let (tree-status)
 814     ;; Reset at the start of each main thread.
 815     (setq notmuch-tree-previous-subject nil)
 816     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
 817
 818 (defun notmuch-tree-insert-forest (forest)
 819   "Insert a forest of threads.
 820
 821 This function inserts a collection of several complete threads as
 822 passed to it by notmuch-tree-process-filter."
 823   (mapc 'notmuch-tree-insert-forest-thread forest))
 824
 825 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
 826   "Major mode displaying messages (as opposed to threads) of of a notmuch search.
 827
 828 This buffer contains the results of a \"notmuch tree\" of your
 829 email archives. Each line in the buffer represents a single
 830 message giving the relative date, the author, subject, and any
 831 tags.
 832
 833 Pressing \\[notmuch-tree-show-message] on any line displays that message.
 834
 835 Complete list of currently available key bindings:
 836
 837 \\{notmuch-tree-mode-map}"
 838
 839   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
 840   (hl-line-mode 1)
 841   (setq buffer-read-only t
 842         truncate-lines t))
 843
 844 (defun notmuch-tree-process-sentinel (proc msg)
 845   "Add a message to let user know when \"notmuch tree\" exits"
 846   (let ((buffer (process-buffer proc))
 847         (status (process-status proc))
 848         (exit-status (process-exit-status proc))
 849         (never-found-target-thread nil))
 850     (when (memq status '(exit signal))
 851         (kill-buffer (process-get proc 'parse-buf))
 852         (if (buffer-live-p buffer)
 853             (with-current-buffer buffer
 854               (save-excursion
 855                 (let ((inhibit-read-only t)
 856                       (atbob (bobp)))
 857                   (goto-char (point-max))
 858                   (if (eq status 'signal)
 859                       (insert "Incomplete search results (tree view process was killed).\n"))
 860                   (when (eq status 'exit)
 861                     (insert "End of search results.")
 862                     (unless (= exit-status 0)
 863                       (insert (format " (process returned %d)" exit-status)))
 864                     (insert "\n")))))))))
 865
 866 (defun notmuch-tree-process-filter (proc string)
 867   "Process and filter the output of \"notmuch show\" for tree view"
 868   (let ((results-buf (process-buffer proc))
 869         (parse-buf (process-get proc 'parse-buf))
 870         (inhibit-read-only t)
 871         done)
 872     (if (not (buffer-live-p results-buf))
 873         (delete-process proc)
 874       (with-current-buffer parse-buf
 875         ;; Insert new data
 876         (save-excursion
 877           (goto-char (point-max))
 878           (insert string))
 879         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
 880                                          results-buf)))))
 881
 882 (defun notmuch-tree-worker (basic-query &optional query-context target open-target)
 883   "Insert the tree view of the search in the current buffer.
 884
 885 This is is a helper function for notmuch-tree. The arguments are
 886 the same as for the function notmuch-tree."
 887   (interactive)
 888   (notmuch-tree-mode)
 889   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
 890   (setq notmuch-tree-basic-query basic-query)
 891   (setq notmuch-tree-query-context query-context)
 892   (setq notmuch-tree-target-msg target)
 893   (setq notmuch-tree-open-target open-target)
 894   ;; Set the default value for `notmuch-show-process-crypto' in this
 895   ;; buffer. Although we don't use this some of the functions we call
 896   ;; (such as reply) do. It is a buffer local variable so setting it
 897   ;; will not affect genuine show buffers.
 898   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
 899
 900   (erase-buffer)
 901   (goto-char (point-min))
 902   (let* ((search-args (concat basic-query
 903                        (if query-context (concat " and (" query-context ")"))
 904                        ))
 905          (message-arg "--entire-thread"))
 906     (if (equal (car (process-lines notmuch-command "count" search-args)) "0")
 907         (setq search-args basic-query))
 908     (notmuch-tag-clear-cache)
 909     (let ((proc (notmuch-start-notmuch
 910                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
 911                  "show" "--body=false" "--format=sexp"
 912                  message-arg search-args))
 913           ;; Use a scratch buffer to accumulate partial output.
 914           ;; This buffer will be killed by the sentinel, which
 915           ;; should be called no matter how the process dies.
 916           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
 917       (process-put proc 'parse-buf parse-buf)
 918       (set-process-filter proc 'notmuch-tree-process-filter)
 919       (set-process-query-on-exit-flag proc nil))))
 920
 921 (defun notmuch-tree-get-query ()
 922   "Return the current query in this tree buffer"
 923   (if notmuch-tree-query-context
 924       (concat notmuch-tree-basic-query
 925               " and ("
 926               notmuch-tree-query-context
 927               ")")
 928     notmuch-tree-basic-query))
 929
 930 (defun notmuch-tree (&optional query query-context target buffer-name open-target)
 931   "Display threads matching QUERY in Tree View.
 932
 933 The arguments are:
 934   QUERY: the main query. This can be any query but in many cases will be
 935       a single thread. If nil this is read interactively from the minibuffer.
 936   QUERY-CONTEXT: is an additional term for the query. The query used
 937       is QUERY and QUERY-CONTEXT unless that does not match any messages
 938       in which case we fall back to just QUERY.
 939   TARGET: A message ID (with the id: prefix) that will be made
 940       current if it appears in the tree view results.
 941   BUFFER-NAME: the name of the buffer to display the tree view. If
 942       it is nil \"*notmuch-tree\" followed by QUERY is used.
 943   OPEN-TARGET: If TRUE open the target message in the message pane."
 944   (interactive)
 945   (if (null query)
 946       (setq query (notmuch-read-query "Notmuch tree view search: ")))
 947   (let ((buffer (get-buffer-create (generate-new-buffer-name
 948                                     (or buffer-name
 949                                         (concat "*notmuch-tree-" query "*")))))
 950         (inhibit-read-only t))
 951
 952     (switch-to-buffer buffer))
 953   ;; Don't track undo information for this buffer
 954   (set 'buffer-undo-list t)
 955
 956   (notmuch-tree-worker query query-context target open-target)
 957
 958   (setq truncate-lines t))
 959
 960
 961 ;;
 962
 963 (provide 'notmuch-tree)
 964
 965 ;;; notmuch-tree.el ends here