git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-tree.el

   1 ;;; notmuch-tree.el --- displaying notmuch forests  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;; Copyright © Mark Walters
   6 ;;
   7 ;; This file is part of Notmuch.
   8 ;;
   9 ;; Notmuch is free software: you can redistribute it and/or modify it
  10 ;; under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13 ;;
  14 ;; Notmuch is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18 ;;
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  21 ;;
  22 ;; Authors: David Edmondson <dme@dme.org>
  23 ;;          Mark Walters <markwalters1009@gmail.com>
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl-lib))
  28
  29 (require 'mail-parse)
  30
  31 (require 'notmuch-lib)
  32 (require 'notmuch-query)
  33 (require 'notmuch-show)
  34 (require 'notmuch-tag)
  35 (require 'notmuch-parser)
  36 (require 'notmuch-jump)
  37
  38 (declare-function notmuch-search "notmuch"
  39                   (&optional query oldest-first target-thread target-line))
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-read-query "notmuch" (prompt))
  42 (declare-function notmuch-search-find-thread-id "notmuch" (&optional bare))
  43 (declare-function notmuch-search-find-subject "notmuch" ())
  44
  45 ;; For `notmuch-tree-next-thread-from-search'.
  46 (declare-function notmuch-search-next-thread "notmuch" ())
  47 (declare-function notmuch-search-previous-thread "notmuch" ())
  48 (declare-function notmuch-tree-from-search-thread "notmuch" ())
  49
  50 ;; the following variable is defined in notmuch.el
  51 (defvar notmuch-search-query-string)
  52
  53 ;; this variable distinguishes the unthreaded display from the normal tree display
  54 (defvar-local notmuch-tree-unthreaded nil
  55   "A buffer local copy of argument unthreaded to the function notmuch-tree.")
  56
  57 ;;; Options
  58
  59 (defgroup notmuch-tree nil
  60   "Showing message and thread structure."
  61   :group 'notmuch)
  62
  63 (defcustom notmuch-tree-show-out nil
  64   "View selected messages in new window rather than split-pane."
  65   :type 'boolean
  66   :group 'notmuch-tree)
  67
  68 (defcustom notmuch-unthreaded-show-out t
  69   "View selected messages in new window rather than split-pane."
  70   :type 'boolean
  71   :group 'notmuch-tree)
  72
  73 (defun notmuch-tree-show-out ()
  74   (if notmuch-tree-unthreaded
  75       notmuch-unthreaded-show-out
  76     notmuch-tree-show-out))
  77
  78 (defcustom notmuch-tree-result-format
  79   `(("date" . "%12s  ")
  80     ("authors" . "%-20s")
  81     ((("tree" . "%s")("subject" . "%s")) ." %-54s ")
  82     ("tags" . "(%s)"))
  83   "Result formatting for tree view. Supported fields are: date,
  84 authors, subject, tree, tags.  Tree means the thread tree
  85 box graphics. The field may also be a list in which case
  86 the formatting rules are applied recursively and then the
  87 output of all the fields in the list is inserted
  88 according to format-string.
  89
  90 Note the author string should not contain
  91 whitespace (put it in the neighbouring fields instead).
  92 For example:
  93         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
  94                                           \(\"subject\" . \"%s\"\)\)\)"
  95   :type '(alist :key-type (string) :value-type (string))
  96   :group 'notmuch-tree)
  97
  98 (defcustom notmuch-unthreaded-result-format
  99   `(("date" . "%12s  ")
 100     ("authors" . "%-20s")
 101     ((("subject" . "%s")) ." %-54s ")
 102     ("tags" . "(%s)"))
 103   "Result formatting for unthreaded tree view. Supported fields are: date,
 104 authors, subject, tree, tags.  Tree means the thread tree
 105 box graphics. The field may also be a list in which case
 106 the formatting rules are applied recursively and then the
 107 output of all the fields in the list is inserted
 108 according to format-string.
 109
 110 Note the author string should not contain
 111 whitespace (put it in the neighbouring fields instead).
 112 For example:
 113         (setq notmuch-tree-result-format \(\(\"authors\" . \"%-40s\"\)
 114                                           \(\"subject\" . \"%s\"\)\)\)"
 115   :type '(alist :key-type (string) :value-type (string))
 116   :group 'notmuch-tree)
 117
 118 (defun notmuch-tree-result-format ()
 119   (if notmuch-tree-unthreaded
 120       notmuch-unthreaded-result-format
 121     notmuch-tree-result-format))
 122
 123 ;;; Faces
 124 ;;;; Faces for messages that match the query
 125
 126 (defface notmuch-tree-match-face
 127   '((t :inherit default))
 128   "Default face used in tree mode face for matching messages"
 129   :group 'notmuch-tree
 130   :group 'notmuch-faces)
 131
 132 (defface notmuch-tree-match-date-face
 133   nil
 134   "Face used in tree mode for the date in messages matching the query."
 135   :group 'notmuch-tree
 136   :group 'notmuch-faces)
 137
 138 (defface notmuch-tree-match-author-face
 139   '((((class color)
 140       (background dark))
 141      (:foreground "OliveDrab1"))
 142     (((class color)
 143       (background light))
 144      (:foreground "dark blue"))
 145     (t
 146      (:bold t)))
 147   "Face used in tree mode for the date in messages matching the query."
 148   :group 'notmuch-tree
 149   :group 'notmuch-faces)
 150
 151 (defface notmuch-tree-match-subject-face
 152   nil
 153   "Face used in tree mode for the subject in messages matching the query."
 154   :group 'notmuch-tree
 155   :group 'notmuch-faces)
 156
 157 (defface notmuch-tree-match-tree-face
 158   nil
 159   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 160   :group 'notmuch-tree
 161   :group 'notmuch-faces)
 162
 163 (defface notmuch-tree-match-tag-face
 164   '((((class color)
 165       (background dark))
 166      (:foreground "OliveDrab1"))
 167     (((class color)
 168       (background light))
 169      (:foreground "navy blue" :bold t))
 170     (t
 171      (:bold t)))
 172   "Face used in tree mode for tags in messages matching the query."
 173   :group 'notmuch-tree
 174   :group 'notmuch-faces)
 175
 176 ;;;; Faces for messages that do not match the query
 177
 178 (defface notmuch-tree-no-match-face
 179   '((t (:foreground "gray")))
 180   "Default face used in tree mode face for non-matching messages."
 181   :group 'notmuch-tree
 182   :group 'notmuch-faces)
 183
 184 (defface notmuch-tree-no-match-date-face
 185   nil
 186   "Face used in tree mode for non-matching dates."
 187   :group 'notmuch-tree
 188   :group 'notmuch-faces)
 189
 190 (defface notmuch-tree-no-match-subject-face
 191   nil
 192   "Face used in tree mode for non-matching subjects."
 193   :group 'notmuch-tree
 194   :group 'notmuch-faces)
 195
 196 (defface notmuch-tree-no-match-tree-face
 197   nil
 198   "Face used in tree mode for the thread tree block graphics in messages matching the query."
 199   :group 'notmuch-tree
 200   :group 'notmuch-faces)
 201
 202 (defface notmuch-tree-no-match-author-face
 203   nil
 204   "Face used in tree mode for the date in messages matching the query."
 205   :group 'notmuch-tree
 206   :group 'notmuch-faces)
 207
 208 (defface notmuch-tree-no-match-tag-face
 209   nil
 210   "Face used in tree mode face for non-matching tags."
 211   :group 'notmuch-tree
 212   :group 'notmuch-faces)
 213
 214 ;;; Variables
 215
 216 (defvar-local notmuch-tree-previous-subject
 217   "The subject of the most recent result shown during the async display.")
 218
 219 (defvar-local notmuch-tree-basic-query nil
 220   "A buffer local copy of argument query to the function notmuch-tree.")
 221
 222 (defvar-local notmuch-tree-query-context nil
 223   "A buffer local copy of argument query-context to the function notmuch-tree.")
 224
 225 (defvar-local notmuch-tree-target-msg nil
 226   "A buffer local copy of argument target to the function notmuch-tree.")
 227
 228 (defvar-local notmuch-tree-open-target nil
 229   "A buffer local copy of argument open-target to the function notmuch-tree.")
 230
 231 (defvar-local notmuch-tree-parent-buffer nil)
 232
 233 (defvar-local notmuch-tree-message-window nil
 234   "The window of the message pane.
 235
 236 It is set in both the tree buffer and the child show buffer. It
 237 is used to try and close the message pane when quitting tree view
 238 or the child show buffer.")
 239 (put 'notmuch-tree-message-window 'permanent-local t)
 240
 241 (defvar-local notmuch-tree-message-buffer nil
 242   "The buffer name of the show buffer in the message pane.
 243
 244 This is used to try and make sure we don't close the message pane
 245 if the user has loaded a different buffer in that window.")
 246 (put 'notmuch-tree-message-buffer 'permanent-local t)
 247
 248 ;;; Tree wrapper commands
 249
 250 (defmacro notmuch-tree--define-do-in-message-window (name cmd)
 251   "Define NAME as a command that calls CMD interactively in the message window.
 252 If the message pane is closed then this command does nothing.
 253 Avoid using this macro in new code; it will be removed."
 254   `(defun ,name ()
 255      ,(concat "(In message window) " (documentation cmd t))
 256      (interactive)
 257      (when (window-live-p notmuch-tree-message-window)
 258        (with-selected-window notmuch-tree-message-window
 259          (call-interactively #',cmd)))))
 260
 261 (notmuch-tree--define-do-in-message-window
 262  notmuch-tree-previous-message-button
 263  notmuch-show-previous-button)
 264 (notmuch-tree--define-do-in-message-window
 265  notmuch-tree-next-message-button
 266  notmuch-show-next-button)
 267 (notmuch-tree--define-do-in-message-window
 268  notmuch-tree-toggle-message-process-crypto
 269  notmuch-show-toggle-process-crypto)
 270
 271 (defun notmuch-tree--message-process-crypto ()
 272   "Return value of `notmuch-show-process-crypto' in the message window.
 273 If that window isn't alive, then return the current value.
 274 Avoid using this function in new code; it will be removed."
 275   (if (window-live-p notmuch-tree-message-window)
 276       (with-selected-window notmuch-tree-message-window
 277         notmuch-show-process-crypto)
 278     notmuch-show-process-crypto))
 279
 280 (defmacro notmuch-tree--define-close-message-window-and (name cmd)
 281   "Define NAME as a variant of CMD.
 282
 283 NAME determines the value of `notmuch-show-process-crypto' in the
 284 message window, closes the window, and then call CMD interactively
 285 with that value let-bound.  If the message window does not exist,
 286 then NAME behaves like CMD."
 287   `(defun ,name ()
 288      ,(concat "(Close message pane and) " (documentation cmd t))
 289      (interactive)
 290      (let ((notmuch-show-process-crypto
 291             (notmuch-tree--message-process-crypto)))
 292        (notmuch-tree-close-message-window)
 293        (call-interactively #',cmd))))
 294
 295 (notmuch-tree--define-close-message-window-and
 296  notmuch-tree-help
 297  notmuch-help)
 298 (notmuch-tree--define-close-message-window-and
 299  notmuch-tree-new-mail
 300  notmuch-mua-new-mail)
 301 (notmuch-tree--define-close-message-window-and
 302  notmuch-tree-jump-search
 303  notmuch-jump-search)
 304 (notmuch-tree--define-close-message-window-and
 305  notmuch-tree-forward-message
 306  notmuch-show-forward-message)
 307 (notmuch-tree--define-close-message-window-and
 308  notmuch-tree-reply-sender
 309  notmuch-show-reply-sender)
 310 (notmuch-tree--define-close-message-window-and
 311  notmuch-tree-reply
 312  notmuch-show-reply)
 313 (notmuch-tree--define-close-message-window-and
 314  notmuch-tree-view-raw-message
 315  notmuch-show-view-raw-message)
 316
 317 ;;; Keymap
 318
 319 (defvar notmuch-tree-mode-map
 320   (let ((map (make-sparse-keymap)))
 321     (set-keymap-parent map notmuch-common-keymap)
 322     ;; These bindings shadow common bindings with variants
 323     ;; that additionally close the message window.
 324     (define-key map [remap notmuch-bury-or-kill-this-buffer] 'notmuch-tree-quit)
 325     (define-key map [remap notmuch-search]       'notmuch-tree-to-search)
 326     (define-key map [remap notmuch-help]         'notmuch-tree-help)
 327     (define-key map [remap notmuch-mua-new-mail] 'notmuch-tree-new-mail)
 328     (define-key map [remap notmuch-jump-search]  'notmuch-tree-jump-search)
 329
 330     (define-key map "S" 'notmuch-search-from-tree-current-query)
 331     (define-key map "U" 'notmuch-unthreaded-from-tree-current-query)
 332     (define-key map "Z" 'notmuch-tree-from-unthreaded-current-query)
 333
 334     ;; these use notmuch-show functions directly
 335     (define-key map "|" 'notmuch-show-pipe-message)
 336     (define-key map "w" 'notmuch-show-save-attachments)
 337     (define-key map "v" 'notmuch-show-view-all-mime-parts)
 338     (define-key map "c" 'notmuch-show-stash-map)
 339     (define-key map "b" 'notmuch-show-resend-message)
 340
 341     ;; these apply to the message pane
 342     (define-key map (kbd "M-TAB")     'notmuch-tree-previous-message-button)
 343     (define-key map (kbd "<backtab>") 'notmuch-tree-previous-message-button)
 344     (define-key map (kbd "TAB")       'notmuch-tree-next-message-button)
 345     (define-key map "$" 'notmuch-tree-toggle-message-process-crypto)
 346
 347     ;; bindings from show (or elsewhere) but we close the message pane first.
 348     (define-key map "f" 'notmuch-tree-forward-message)
 349     (define-key map "r" 'notmuch-tree-reply-sender)
 350     (define-key map "R" 'notmuch-tree-reply)
 351     (define-key map "V" 'notmuch-tree-view-raw-message)
 352
 353     ;; The main tree view bindings
 354     (define-key map (kbd "RET") 'notmuch-tree-show-message)
 355     (define-key map [mouse-1] 'notmuch-tree-show-message)
 356     (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
 357     (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
 358     (define-key map "A" 'notmuch-tree-archive-thread-then-next)
 359     (define-key map "a" 'notmuch-tree-archive-message-then-next)
 360     (define-key map "z" 'notmuch-tree-to-tree)
 361     (define-key map "n" 'notmuch-tree-next-matching-message)
 362     (define-key map "p" 'notmuch-tree-prev-matching-message)
 363     (define-key map "N" 'notmuch-tree-next-message)
 364     (define-key map "P" 'notmuch-tree-prev-message)
 365     (define-key map (kbd "M-p") 'notmuch-tree-prev-thread)
 366     (define-key map (kbd "M-n") 'notmuch-tree-next-thread)
 367     (define-key map "k" 'notmuch-tag-jump)
 368     (define-key map "-" 'notmuch-tree-remove-tag)
 369     (define-key map "+" 'notmuch-tree-add-tag)
 370     (define-key map "*" 'notmuch-tree-tag-thread)
 371     (define-key map " " 'notmuch-tree-scroll-or-next)
 372     (define-key map (kbd "DEL") 'notmuch-tree-scroll-message-window-back)
 373     (define-key map "e" 'notmuch-tree-resume-message)
 374     map)
 375   "Keymap for \"notmuch tree\" buffers.")
 376
 377 ;;; Message properties
 378
 379 (defun notmuch-tree-get-message-properties ()
 380   "Return the properties of the current message as a plist.
 381
 382 Some useful entries are:
 383 :headers - Property list containing the headers :Date, :Subject, :From, etc.
 384 :tags - Tags for this message."
 385   (save-excursion
 386     (beginning-of-line)
 387     (get-text-property (point) :notmuch-message-properties)))
 388
 389 (defun notmuch-tree-set-message-properties (props)
 390   (save-excursion
 391     (beginning-of-line)
 392     (put-text-property (point)
 393                        (+ (point) 1)
 394                        :notmuch-message-properties props)))
 395
 396 (defun notmuch-tree-set-prop (prop val &optional props)
 397   (let ((inhibit-read-only t)
 398         (props (or props
 399                    (notmuch-tree-get-message-properties))))
 400     (plist-put props prop val)
 401     (notmuch-tree-set-message-properties props)))
 402
 403 (defun notmuch-tree-get-prop (prop &optional props)
 404   (plist-get (or props (notmuch-tree-get-message-properties))
 405              prop))
 406
 407 (defun notmuch-tree-set-tags (tags)
 408   "Set the tags of the current message."
 409   (notmuch-tree-set-prop :tags tags))
 410
 411 (defun notmuch-tree-get-tags ()
 412   "Return the tags of the current message."
 413   (notmuch-tree-get-prop :tags))
 414
 415 (defun notmuch-tree-get-message-id (&optional bare)
 416   "Return the message id of the current message."
 417   (let ((id (notmuch-tree-get-prop :id)))
 418     (if id
 419         (if bare
 420             id
 421           (notmuch-id-to-query id))
 422       nil)))
 423
 424 (defun notmuch-tree-get-match ()
 425   "Return whether the current message is a match."
 426   (interactive)
 427   (notmuch-tree-get-prop :match))
 428
 429 ;;; Update display
 430
 431 (defun notmuch-tree-refresh-result ()
 432   "Redisplay the current message line.
 433
 434 This redisplays the current line based on the messages
 435 properties (as they are now). This is used when tags are
 436 updated."
 437   (let ((init-point (point))
 438         (end (line-end-position))
 439         (msg (notmuch-tree-get-message-properties))
 440         (inhibit-read-only t))
 441     (beginning-of-line)
 442     ;; This is a little tricky: we override
 443     ;; notmuch-tree-previous-subject to get the decision between
 444     ;; ... and a subject right and it stops notmuch-tree-insert-msg
 445     ;; from overwriting the buffer local copy of
 446     ;; notmuch-tree-previous-subject if this is called while the
 447     ;; buffer is displaying.
 448     (let ((notmuch-tree-previous-subject
 449            (notmuch-tree-get-prop :previous-subject)))
 450       (delete-region (point) (1+ (line-end-position)))
 451       (notmuch-tree-insert-msg msg))
 452     (let ((new-end (line-end-position)))
 453       (goto-char (if (= init-point end)
 454                      new-end
 455                    (min init-point (- new-end 1)))))))
 456
 457 (defun notmuch-tree-tag-update-display (&optional tag-changes)
 458   "Update display for TAG-CHANGES to current message.
 459
 460 Updates the message in the message pane if appropriate, but does
 461 NOT change the database."
 462   (let* ((current-tags (notmuch-tree-get-tags))
 463          (new-tags (notmuch-update-tags current-tags tag-changes))
 464          (tree-msg-id (notmuch-tree-get-message-id)))
 465     (unless (equal current-tags new-tags)
 466       (notmuch-tree-set-tags new-tags)
 467       (notmuch-tree-refresh-result)
 468       (when (window-live-p notmuch-tree-message-window)
 469         (with-selected-window notmuch-tree-message-window
 470           (when (string= tree-msg-id (notmuch-show-get-message-id))
 471             (notmuch-show-update-tags new-tags)))))))
 472
 473 ;;; Commands (and some helper functions used by them)
 474
 475 (defun notmuch-tree-tag (tag-changes)
 476   "Change tags for the current message."
 477   (interactive
 478    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message")))
 479   (notmuch-tag (notmuch-tree-get-message-id) tag-changes)
 480   (notmuch-tree-tag-update-display tag-changes))
 481
 482 (defun notmuch-tree-add-tag (tag-changes)
 483   "Same as `notmuch-tree-tag' but sets initial input to '+'."
 484   (interactive
 485    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "+")))
 486   (notmuch-tree-tag tag-changes))
 487
 488 (defun notmuch-tree-remove-tag (tag-changes)
 489   "Same as `notmuch-tree-tag' but sets initial input to '-'."
 490   (interactive
 491    (list (notmuch-read-tag-changes (notmuch-tree-get-tags) "Tag message" "-")))
 492   (notmuch-tree-tag tag-changes))
 493
 494 (defun notmuch-tree-resume-message ()
 495   "Resume EDITING the current draft message."
 496   (interactive)
 497   (notmuch-tree-close-message-window)
 498   (let ((id (notmuch-tree-get-message-id)))
 499     (if id
 500         (notmuch-draft-resume id)
 501       (message "No message to resume!"))))
 502
 503 ;; The next two functions close the message window before calling
 504 ;; notmuch-search or notmuch-tree but they do so after the user has
 505 ;; entered the query (in case the user was basing the query on
 506 ;; something in the message window).
 507
 508 (defun notmuch-tree-to-search ()
 509   "Run \"notmuch search\" with the given `query' and display results."
 510   (interactive)
 511   (let ((query (notmuch-read-query "Notmuch search: ")))
 512     (notmuch-tree-close-message-window)
 513     (notmuch-search query)))
 514
 515 (defun notmuch-tree-to-tree ()
 516   "Run a query and display results in tree view."
 517   (interactive)
 518   (let ((query (notmuch-read-query "Notmuch tree view search: ")))
 519     (notmuch-tree-close-message-window)
 520     (notmuch-tree query)))
 521
 522 (defun notmuch-tree-archive-thread-then-next ()
 523   "Archive all messages in the current buffer, then show next thread from search."
 524   (interactive)
 525   (notmuch-tree-archive-thread)
 526   (notmuch-tree-next-thread))
 527
 528 (defun notmuch-unthreaded-from-tree-current-query ()
 529   "Switch from tree view to unthreaded view."
 530   (interactive)
 531   (unless notmuch-tree-unthreaded
 532     (notmuch-tree-refresh-view 'unthreaded)))
 533
 534 (defun notmuch-tree-from-unthreaded-current-query ()
 535   "Switch from unthreaded view to tree view."
 536   (interactive)
 537   (when notmuch-tree-unthreaded
 538     (notmuch-tree-refresh-view 'tree)))
 539
 540 (defun notmuch-search-from-tree-current-query ()
 541   "Call notmuch search with the current query."
 542   (interactive)
 543   (notmuch-tree-close-message-window)
 544   (notmuch-search (notmuch-tree-get-query)))
 545
 546 (defun notmuch-tree-message-window-kill-hook ()
 547   "Close the message pane when exiting the show buffer."
 548   (let ((buffer (current-buffer)))
 549     (when (and (window-live-p notmuch-tree-message-window)
 550                (eq (window-buffer notmuch-tree-message-window) buffer))
 551       ;; We could check whether this is the only window in its frame,
 552       ;; but simply ignoring the error that is thrown otherwise is
 553       ;; what we had to do for Emacs 24 and we stick to that because
 554       ;; it is still the simplest approach.
 555       (ignore-errors
 556         (delete-window notmuch-tree-message-window)))))
 557
 558 (defun notmuch-tree-command-hook ()
 559   (when (eq major-mode 'notmuch-tree-mode)
 560     ;; We just run the notmuch-show-command-hook on the message pane.
 561     (when (buffer-live-p notmuch-tree-message-buffer)
 562       (with-current-buffer notmuch-tree-message-buffer
 563         (notmuch-show-command-hook)))))
 564
 565 (defun notmuch-tree-show-message-in ()
 566   "Show the current message (in split-pane)."
 567   (interactive)
 568   (let ((id (notmuch-tree-get-message-id))
 569         (inhibit-read-only t)
 570         buffer)
 571     (when id
 572       ;; We close and reopen the window to kill off un-needed buffers
 573       ;; this might cause flickering but seems ok.
 574       (notmuch-tree-close-message-window)
 575       (setq notmuch-tree-message-window
 576             (split-window-vertically (/ (window-height) 4)))
 577       (with-selected-window notmuch-tree-message-window
 578         (let (;; Since we are only displaying one message do not indent.
 579               (notmuch-show-indent-messages-width 0)
 580               (notmuch-show-only-matching-messages t)
 581               ;; Ensure that `pop-to-buffer-same-window' uses the
 582               ;; window we want it to use.
 583               (display-buffer-overriding-action
 584                  '((display-buffer-same-window)
 585                    (inhibit-same-window . nil))))
 586           (setq buffer (notmuch-show id))))
 587       ;; We need the `let' as notmuch-tree-message-window is buffer local.
 588       (let ((window notmuch-tree-message-window))
 589         (with-current-buffer buffer
 590           (setq notmuch-tree-message-window window)
 591           (add-hook 'kill-buffer-hook 'notmuch-tree-message-window-kill-hook)))
 592       (when notmuch-show-mark-read-tags
 593         (notmuch-tree-tag-update-display notmuch-show-mark-read-tags))
 594       (setq notmuch-tree-message-buffer buffer))))
 595
 596 (defun notmuch-tree-show-message-out ()
 597   "Show the current message (in whole window)."
 598   (interactive)
 599   (let ((id (notmuch-tree-get-message-id))
 600         (inhibit-read-only t))
 601     (when id
 602       ;; We close the window to kill off un-needed buffers.
 603       (notmuch-tree-close-message-window)
 604       (notmuch-show id))))
 605
 606 (defun notmuch-tree-show-message (arg)
 607   "Show the current message.
 608
 609 Shows in split pane or whole window according to value of
 610 `notmuch-tree-show-out'. A prefix argument reverses the choice."
 611   (interactive "P")
 612   (if (or (and (notmuch-tree-show-out) (not arg))
 613           (and (not (notmuch-tree-show-out)) arg))
 614       (notmuch-tree-show-message-out)
 615     (notmuch-tree-show-message-in)))
 616
 617 (defun notmuch-tree-scroll-message-window ()
 618   "Scroll the message window (if it exists)."
 619   (interactive)
 620   (when (window-live-p notmuch-tree-message-window)
 621     (with-selected-window notmuch-tree-message-window
 622       (if (pos-visible-in-window-p (point-max))
 623           t
 624         (scroll-up)))))
 625
 626 (defun notmuch-tree-scroll-message-window-back ()
 627   "Scroll the message window back (if it exists)."
 628   (interactive)
 629   (when (window-live-p notmuch-tree-message-window)
 630     (with-selected-window notmuch-tree-message-window
 631       (if (pos-visible-in-window-p (point-min))
 632           t
 633         (scroll-down)))))
 634
 635 (defun notmuch-tree-scroll-or-next ()
 636   "Scroll the message window.
 637 If it at end go to next message."
 638   (interactive)
 639   (when (notmuch-tree-scroll-message-window)
 640     (notmuch-tree-next-matching-message)))
 641
 642 (defun notmuch-tree-quit (&optional kill-both)
 643   "Close the split view or exit tree."
 644   (interactive "P")
 645   (when (or (not (notmuch-tree-close-message-window)) kill-both)
 646     (kill-buffer (current-buffer))))
 647
 648 (defun notmuch-tree-close-message-window ()
 649   "Close the message-window. Return t if close succeeds."
 650   (interactive)
 651   (when (and (window-live-p notmuch-tree-message-window)
 652              (eq (window-buffer notmuch-tree-message-window)
 653                  notmuch-tree-message-buffer))
 654     (delete-window notmuch-tree-message-window)
 655     (unless (get-buffer-window-list notmuch-tree-message-buffer)
 656       (kill-buffer notmuch-tree-message-buffer))
 657     t))
 658
 659 (defun notmuch-tree-archive-message (&optional unarchive)
 660   "Archive the current message.
 661
 662 Archive the current message by applying the tag changes in
 663 `notmuch-archive-tags' to it. If a prefix argument is given, the
 664 message will be \"unarchived\", i.e. the tag changes in
 665 `notmuch-archive-tags' will be reversed."
 666   (interactive "P")
 667   (when notmuch-archive-tags
 668     (notmuch-tree-tag
 669      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 670
 671 (defun notmuch-tree-archive-message-then-next (&optional unarchive)
 672   "Archive the current message and move to next matching message."
 673   (interactive "P")
 674   (notmuch-tree-archive-message unarchive)
 675   (notmuch-tree-next-matching-message))
 676
 677 (defun notmuch-tree-archive-thread-then-exit ()
 678   "Archive all messages in the current buffer, then exit notmuch-tree."
 679   (interactive)
 680   (notmuch-tree-archive-thread)
 681   (notmuch-tree-quit t))
 682
 683 (defun notmuch-tree-archive-message-then-next-or-exit ()
 684   "Archive current message, then show next open message in current thread.
 685
 686 If at the last open message in the current thread, then exit back
 687 to search results."
 688   (interactive)
 689   (notmuch-tree-archive-message)
 690   (notmuch-tree-next-matching-message t))
 691
 692 (defun notmuch-tree-next-message ()
 693   "Move to next message."
 694   (interactive)
 695   (forward-line)
 696   (when (window-live-p notmuch-tree-message-window)
 697     (notmuch-tree-show-message-in)))
 698
 699 (defun notmuch-tree-prev-message ()
 700   "Move to previous message."
 701   (interactive)
 702   (forward-line -1)
 703   (when (window-live-p notmuch-tree-message-window)
 704     (notmuch-tree-show-message-in)))
 705
 706 (defun notmuch-tree-goto-matching-message (&optional prev)
 707   "Move to the next or previous matching message.
 708
 709 Returns t if there was a next matching message in the thread to show,
 710 nil otherwise."
 711   (let ((dir (if prev -1 nil))
 712         (eobfn (if prev #'bobp #'eobp)))
 713     (while (and (not (funcall eobfn))
 714                 (not (notmuch-tree-get-match)))
 715       (forward-line dir))
 716     (not (funcall eobfn))))
 717
 718 (defun notmuch-tree-matching-message (&optional prev pop-at-end)
 719   "Move to the next or previous matching message."
 720   (interactive "P")
 721   (forward-line (if prev -1 nil))
 722   (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
 723       (notmuch-tree-quit pop-at-end)
 724     (when (window-live-p notmuch-tree-message-window)
 725       (notmuch-tree-show-message-in))))
 726
 727 (defun notmuch-tree-prev-matching-message (&optional pop-at-end)
 728   "Move to previous matching message."
 729   (interactive "P")
 730   (notmuch-tree-matching-message t pop-at-end))
 731
 732 (defun notmuch-tree-next-matching-message (&optional pop-at-end)
 733   "Move to next matching message."
 734   (interactive "P")
 735   (notmuch-tree-matching-message nil pop-at-end))
 736
 737 (defun notmuch-tree-refresh-view (&optional view)
 738   "Refresh view."
 739   (interactive)
 740   (when (get-buffer-process (current-buffer))
 741     (error "notmuch tree process already running for current buffer"))
 742   (let ((inhibit-read-only t)
 743         (basic-query notmuch-tree-basic-query)
 744         (unthreaded (cond ((eq view 'unthreaded) t)
 745                           ((eq view 'tree) nil)
 746                           (t notmuch-tree-unthreaded)))
 747         (query-context notmuch-tree-query-context)
 748         (target (notmuch-tree-get-message-id)))
 749     (erase-buffer)
 750     (notmuch-tree-worker basic-query
 751                          query-context
 752                          target
 753                          nil
 754                          unthreaded)))
 755
 756 (defun notmuch-tree-thread-top ()
 757   (when (notmuch-tree-get-message-properties)
 758     (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 759       (forward-line -1))))
 760
 761 (defun notmuch-tree-prev-thread-in-tree ()
 762   "Move to the previous thread in the current tree"
 763   (interactive)
 764   (forward-line -1)
 765   (notmuch-tree-thread-top)
 766   (not (bobp)))
 767
 768 (defun notmuch-tree-next-thread-in-tree ()
 769   "Get the next thread in the current tree. Returns t if a thread was
 770 found or nil if not."
 771   (interactive)
 772   (forward-line 1)
 773   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
 774     (forward-line 1))
 775   (not (eobp)))
 776
 777 (defun notmuch-tree-next-thread-from-search (&optional previous)
 778   "Move to the next thread in the parent search results, if any.
 779
 780 If PREVIOUS is non-nil, move to the previous item in the
 781 search results instead."
 782   (interactive "P")
 783   (let ((parent-buffer notmuch-tree-parent-buffer))
 784     (notmuch-tree-quit t)
 785     (when (buffer-live-p parent-buffer)
 786       (switch-to-buffer parent-buffer)
 787       (if previous
 788           (notmuch-search-previous-thread)
 789         (notmuch-search-next-thread))
 790       (notmuch-tree-from-search-thread))))
 791
 792 (defun notmuch-tree-next-thread (&optional previous)
 793   "Move to the next thread in the current tree or parent search results.
 794
 795 If PREVIOUS is non-nil, move to the previous thread in the tree or
 796 search results instead."
 797   (interactive)
 798   (unless (if previous (notmuch-tree-prev-thread-in-tree)
 799             (notmuch-tree-next-thread-in-tree))
 800     (notmuch-tree-next-thread-from-search previous)))
 801
 802 (defun notmuch-tree-prev-thread ()
 803   "Move to the previous thread in the current tree or parent search results."
 804   (interactive)
 805   (notmuch-tree-next-thread t))
 806
 807 (defun notmuch-tree-thread-mapcar (function)
 808   "Call FUNCTION for each message in the current thread.
 809 FUNCTION is called for side effects only."
 810   (save-excursion
 811     (notmuch-tree-thread-top)
 812     (cl-loop collect (funcall function)
 813              do (forward-line)
 814              while (and (notmuch-tree-get-message-properties)
 815                         (not (notmuch-tree-get-prop :first))))))
 816
 817 (defun notmuch-tree-get-messages-ids-thread-search ()
 818   "Return a search string for all message ids of messages in the current thread."
 819   (mapconcat 'identity
 820              (notmuch-tree-thread-mapcar 'notmuch-tree-get-message-id)
 821              " or "))
 822
 823 (defun notmuch-tree-tag-thread (tag-changes)
 824   "Tag all messages in the current thread."
 825   (interactive
 826    (let ((tags (apply #'append (notmuch-tree-thread-mapcar
 827                                 (lambda () (notmuch-tree-get-tags))))))
 828      (list (notmuch-read-tag-changes tags "Tag thread"))))
 829   (when (notmuch-tree-get-message-properties)
 830     (notmuch-tag (notmuch-tree-get-messages-ids-thread-search) tag-changes)
 831     (notmuch-tree-thread-mapcar
 832      (lambda () (notmuch-tree-tag-update-display tag-changes)))))
 833
 834 (defun notmuch-tree-archive-thread (&optional unarchive)
 835   "Archive each message in thread.
 836
 837 Archive each message currently shown by applying the tag changes
 838 in `notmuch-archive-tags' to each. If a prefix argument is given,
 839 the messages will be \"unarchived\", i.e. the tag changes in
 840 `notmuch-archive-tags' will be reversed.
 841
 842 Note: This command is safe from any race condition of new messages
 843 being delivered to the same thread. It does not archive the
 844 entire thread, but only the messages shown in the current
 845 buffer."
 846   (interactive "P")
 847   (when notmuch-archive-tags
 848     (notmuch-tree-tag-thread
 849      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
 850
 851 ;;; Functions for displaying the tree buffer itself
 852
 853 (defun notmuch-tree-clean-address (address)
 854   "Try to clean a single email ADDRESS for display. Return
 855 AUTHOR_NAME if present, otherwise return AUTHOR_EMAIL. Return
 856 unchanged ADDRESS if parsing fails."
 857   (let* ((clean-address (notmuch-clean-address address))
 858          (p-address (car clean-address))
 859          (p-name (cdr clean-address)))
 860
 861     ;; If we have a name return that otherwise return the address.
 862     (or p-name p-address)))
 863
 864 (defun notmuch-tree-format-field (field format-string msg)
 865   "Format a FIELD of MSG according to FORMAT-STRING and return string."
 866   (let* ((headers (plist-get msg :headers))
 867          (match (plist-get msg :match)))
 868     (cond
 869      ((listp field)
 870       (format format-string (notmuch-tree-format-field-list field msg)))
 871
 872      ((string-equal field "date")
 873       (let ((face (if match
 874                       'notmuch-tree-match-date-face
 875                     'notmuch-tree-no-match-date-face)))
 876         (propertize (format format-string (plist-get msg :date_relative))
 877                     'face face)))
 878
 879      ((string-equal field "tree")
 880       (let ((tree-status (plist-get msg :tree-status))
 881             (face (if match
 882                       'notmuch-tree-match-tree-face
 883                     'notmuch-tree-no-match-tree-face)))
 884
 885         (propertize (format format-string
 886                             (mapconcat #'identity (reverse tree-status) ""))
 887                     'face face)))
 888
 889      ((string-equal field "subject")
 890       (let ((bare-subject (notmuch-show-strip-re (plist-get headers :Subject)))
 891             (previous-subject notmuch-tree-previous-subject)
 892             (face (if match
 893                       'notmuch-tree-match-subject-face
 894                     'notmuch-tree-no-match-subject-face)))
 895
 896         (setq notmuch-tree-previous-subject bare-subject)
 897         (propertize (format format-string
 898                             (if (string= previous-subject bare-subject)
 899                                 " ..."
 900                               bare-subject))
 901                     'face face)))
 902
 903      ((string-equal field "authors")
 904       (let ((author (notmuch-tree-clean-address (plist-get headers :From)))
 905             (len (length (format format-string "")))
 906             (face (if match
 907                       'notmuch-tree-match-author-face
 908                     'notmuch-tree-no-match-author-face)))
 909         (when (> (length author) len)
 910           (setq author (substring author 0 len)))
 911         (propertize (format format-string author) 'face face)))
 912
 913      ((string-equal field "tags")
 914       (let ((tags (plist-get msg :tags))
 915             (orig-tags (plist-get msg :orig-tags))
 916             (face (if match
 917                       'notmuch-tree-match-tag-face
 918                     'notmuch-tree-no-match-tag-face)))
 919         (format format-string (notmuch-tag-format-tags tags orig-tags face)))))))
 920
 921 (defun notmuch-tree-format-field-list (field-list msg)
 922   "Format fields of MSG according to FIELD-LIST and return string."
 923   (let ((face (if (plist-get msg :match)
 924                   'notmuch-tree-match-face
 925                 'notmuch-tree-no-match-face))
 926         (result-string))
 927     (dolist (spec field-list result-string)
 928       (let ((field-string (notmuch-tree-format-field (car spec) (cdr spec) msg)))
 929         (setq result-string (concat result-string field-string))))
 930     (notmuch-apply-face result-string face t)))
 931
 932 (defun notmuch-tree-insert-msg (msg)
 933   "Insert the message MSG according to notmuch-tree-result-format."
 934   ;; We need to save the previous subject as it will get overwritten
 935   ;; by the insert-field calls.
 936   (let ((previous-subject notmuch-tree-previous-subject))
 937     (insert (notmuch-tree-format-field-list (notmuch-tree-result-format) msg))
 938     (notmuch-tree-set-message-properties msg)
 939     (notmuch-tree-set-prop :previous-subject previous-subject)
 940     (insert "\n")))
 941
 942 (defun notmuch-tree-goto-and-insert-msg (msg)
 943   "Insert msg at the end of the buffer. Move point to msg if it is the target."
 944   (save-excursion
 945     (goto-char (point-max))
 946     (notmuch-tree-insert-msg msg))
 947   (let ((msg-id (notmuch-id-to-query (plist-get msg :id)))
 948         (target notmuch-tree-target-msg))
 949     (when (or (and (not target) (plist-get msg :match))
 950               (string= msg-id target))
 951       (setq notmuch-tree-target-msg "found")
 952       (goto-char (point-max))
 953       (forward-line -1)
 954       (when notmuch-tree-open-target
 955         (notmuch-tree-show-message-in)))))
 956
 957 (defun notmuch-tree-insert-tree (tree depth tree-status first last)
 958   "Insert the message tree TREE at depth DEPTH in the current thread.
 959
 960 A message tree is another name for a single sub-thread: i.e., a
 961 message together with all its descendents."
 962   (let ((msg (car tree))
 963         (replies (cadr tree)))
 964     (cond
 965      ((and (< 0 depth) (not last))
 966       (push "├" tree-status))
 967      ((and (< 0 depth) last)
 968       (push "╰" tree-status))
 969      ((and (eq 0 depth) first last)
 970       ;; Choice between these two variants is a matter of taste.
 971       ;; (push "─" tree-status))
 972       (push " " tree-status))
 973      ((and (eq 0 depth) first (not last))
 974       (push "┬" tree-status))
 975      ((and (eq 0 depth) (not first) last)
 976       (push "╰" tree-status))
 977      ((and (eq 0 depth) (not first) (not last))
 978       (push "├" tree-status)))
 979     (push (concat (if replies "┬" "─") "►") tree-status)
 980     (setq msg (plist-put msg :first (and first (eq 0 depth))))
 981     (setq msg (plist-put msg :tree-status tree-status))
 982     (setq msg (plist-put msg :orig-tags (plist-get msg :tags)))
 983     (notmuch-tree-goto-and-insert-msg msg)
 984     (pop tree-status)
 985     (pop tree-status)
 986     (if last
 987         (push " " tree-status)
 988       (push "│" tree-status))
 989     (notmuch-tree-insert-thread replies (1+ depth) tree-status)))
 990
 991 (defun notmuch-tree-insert-thread (thread depth tree-status)
 992   "Insert the collection of sibling sub-threads THREAD at depth DEPTH in the current forest."
 993   (let ((n (length thread)))
 994     (cl-loop for tree in thread
 995              for count from 1 to n
 996              do (notmuch-tree-insert-tree tree depth tree-status
 997                                           (eq count 1)
 998                                           (eq count n)))))
 999
1000 (defun notmuch-tree-insert-forest-thread (forest-thread)
1001   "Insert a single complete thread."
1002   (let (tree-status)
1003     ;; Reset at the start of each main thread.
1004     (setq notmuch-tree-previous-subject nil)
1005     (notmuch-tree-insert-thread forest-thread 0 tree-status)))
1006
1007 (defun notmuch-tree-insert-forest (forest)
1008   "Insert a forest of threads.
1009
1010 This function inserts a collection of several complete threads as
1011 passed to it by notmuch-tree-process-filter."
1012   (mapc 'notmuch-tree-insert-forest-thread forest))
1013
1014 (define-derived-mode notmuch-tree-mode fundamental-mode "notmuch-tree"
1015   "Major mode displaying messages (as opposed to threads) of a notmuch search.
1016
1017 This buffer contains the results of a \"notmuch tree\" of your
1018 email archives. Each line in the buffer represents a single
1019 message giving the relative date, the author, subject, and any
1020 tags.
1021
1022 Pressing \\[notmuch-tree-show-message] on any line displays that message.
1023
1024 Complete list of currently available key bindings:
1025
1026 \\{notmuch-tree-mode-map}"
1027   (setq notmuch-buffer-refresh-function #'notmuch-tree-refresh-view)
1028   (hl-line-mode 1)
1029   (setq buffer-read-only t)
1030   (setq truncate-lines t))
1031
1032 (defun notmuch-tree-process-sentinel (proc _msg)
1033   "Add a message to let user know when \"notmuch tree\" exits."
1034   (let ((buffer (process-buffer proc))
1035         (status (process-status proc))
1036         (exit-status (process-exit-status proc)))
1037     (when (memq status '(exit signal))
1038       (kill-buffer (process-get proc 'parse-buf))
1039       (when (buffer-live-p buffer)
1040         (with-current-buffer buffer
1041           (save-excursion
1042             (let ((inhibit-read-only t))
1043               (goto-char (point-max))
1044               (when (eq status 'signal)
1045                 (insert "Incomplete search results (tree view process was killed).\n"))
1046               (when (eq status 'exit)
1047                 (insert "End of search results.")
1048                 (unless (= exit-status 0)
1049                   (insert (format " (process returned %d)" exit-status)))
1050                 (insert "\n")))))))))
1051
1052 (defun notmuch-tree-process-filter (proc string)
1053   "Process and filter the output of \"notmuch show\" for tree view."
1054   (let ((results-buf (process-buffer proc))
1055         (parse-buf (process-get proc 'parse-buf))
1056         (inhibit-read-only t))
1057     (if (not (buffer-live-p results-buf))
1058         (delete-process proc)
1059       (with-current-buffer parse-buf
1060         ;; Insert new data
1061         (save-excursion
1062           (goto-char (point-max))
1063           (insert string))
1064         (notmuch-sexp-parse-partial-list 'notmuch-tree-insert-forest-thread
1065                                          results-buf)))))
1066
1067 (defun notmuch-tree-worker (basic-query &optional query-context target open-target unthreaded)
1068   "Insert the tree view of the search in the current buffer.
1069
1070 This is is a helper function for notmuch-tree. The arguments are
1071 the same as for the function notmuch-tree."
1072   (interactive)
1073   (notmuch-tree-mode)
1074   (add-hook 'post-command-hook #'notmuch-tree-command-hook t t)
1075   (setq notmuch-tree-unthreaded unthreaded)
1076   (setq notmuch-tree-basic-query basic-query)
1077   (setq notmuch-tree-query-context (if (or (string= query-context "")
1078                                            (string= query-context "*"))
1079                                        nil
1080                                      query-context))
1081   (setq notmuch-tree-target-msg target)
1082   (setq notmuch-tree-open-target open-target)
1083   ;; Set the default value for `notmuch-show-process-crypto' in this
1084   ;; buffer. Although we don't use this some of the functions we call
1085   ;; (such as reply) do. It is a buffer local variable so setting it
1086   ;; will not affect genuine show buffers.
1087   (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1088   (erase-buffer)
1089   (goto-char (point-min))
1090   (let* ((search-args (concat basic-query
1091                               (and query-context
1092                                    (concat " and (" query-context ")"))))
1093          (message-arg (if unthreaded "--unthreaded" "--entire-thread")))
1094     (when (equal (car (process-lines notmuch-command "count" search-args)) "0")
1095       (setq search-args basic-query))
1096     (notmuch-tag-clear-cache)
1097     (let ((proc (notmuch-start-notmuch
1098                  "notmuch-tree" (current-buffer) #'notmuch-tree-process-sentinel
1099                  "show" "--body=false" "--format=sexp" "--format-version=4"
1100                  message-arg search-args))
1101           ;; Use a scratch buffer to accumulate partial output.
1102           ;; This buffer will be killed by the sentinel, which
1103           ;; should be called no matter how the process dies.
1104           (parse-buf (generate-new-buffer " *notmuch tree parse*")))
1105       (process-put proc 'parse-buf parse-buf)
1106       (set-process-filter proc 'notmuch-tree-process-filter)
1107       (set-process-query-on-exit-flag proc nil))))
1108
1109 (defun notmuch-tree-get-query ()
1110   "Return the current query in this tree buffer."
1111   (if notmuch-tree-query-context
1112       (concat notmuch-tree-basic-query
1113               " and ("
1114               notmuch-tree-query-context
1115               ")")
1116     notmuch-tree-basic-query))
1117
1118 (defun notmuch-tree (&optional query query-context target buffer-name open-target unthreaded parent-buffer)
1119   "Display threads matching QUERY in tree view.
1120
1121 The arguments are:
1122   QUERY: the main query. This can be any query but in many cases will be
1123       a single thread. If nil this is read interactively from the minibuffer.
1124   QUERY-CONTEXT: is an additional term for the query. The query used
1125       is QUERY and QUERY-CONTEXT unless that does not match any messages
1126       in which case we fall back to just QUERY.
1127   TARGET: A message ID (with the id: prefix) that will be made
1128       current if it appears in the tree view results.
1129   BUFFER-NAME: the name of the buffer to display the tree view. If
1130       it is nil \"*notmuch-tree\" followed by QUERY is used.
1131   OPEN-TARGET: If TRUE open the target message in the message pane.
1132   UNTHREADED: If TRUE only show matching messages in an unthreaded view."
1133   (interactive)
1134   (unless query
1135     (setq query (notmuch-read-query (concat "Notmuch "
1136                                             (if unthreaded "unthreaded " "tree ")
1137                                             "view search: "))))
1138   (let ((buffer (get-buffer-create (generate-new-buffer-name
1139                                     (or buffer-name
1140                                         (concat "*notmuch-"
1141                                                 (if unthreaded "unthreaded-" "tree-")
1142                                                 query "*")))))
1143         (inhibit-read-only t))
1144     (pop-to-buffer-same-window buffer))
1145   ;; Don't track undo information for this buffer
1146   (setq buffer-undo-list t)
1147   (notmuch-tree-worker query query-context target open-target unthreaded)
1148   (setq notmuch-tree-parent-buffer parent-buffer)
1149   (setq truncate-lines t))
1150
1151 (defun notmuch-unthreaded (&optional query query-context target buffer-name open-target)
1152   (interactive)
1153   (notmuch-tree query query-context target buffer-name open-target t))
1154
1155 ;;; _
1156
1157 (provide 'notmuch-tree)
1158
1159 ;;; notmuch-tree.el ends here