git.notmuchmail.org Git - notmuch/blob - emacs/notmuch-wash.el

   1 ;; notmuch-wash.el --- cleaning up message bodies
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (require 'coolj)
  25
  26 (declare-function notmuch-show-insert-bodypart "notmuch-show" (msg part depth))
  27
  28 ;;
  29
  30 (defvar notmuch-wash-signature-regexp
  31   "^\\(-- ?\\|_+\\)$"
  32   "Pattern to match a line that separates content from signature.")
  33
  34 (defvar notmuch-wash-citation-regexp
  35   "\\(^[[:space:]]*>.*\n\\)+"
  36   "Pattern to match citation lines.")
  37
  38 (defvar notmuch-wash-original-regexp "^\\(--+\s?[oO]riginal [mM]essage\s?--+\\)$"
  39   "Pattern to match a line that separates original message from reply in top-posted message.")
  40
  41 (defvar notmuch-wash-button-signature-hidden-format
  42   "[ %d-line signature. Click/Enter to show. ]"
  43   "String used to construct button text for hidden signatures.
  44 Can use up to one integer format parameter, i.e. %d")
  45
  46 (defvar notmuch-wash-button-signature-visible-format
  47   "[ %d-line signature. Click/Enter to hide. ]"
  48   "String used to construct button text for visible signatures.
  49 Can use up to one integer format parameter, i.e. %d")
  50
  51 (defvar notmuch-wash-button-citation-hidden-format
  52   "[ %d more citation lines. Click/Enter to show. ]"
  53   "String used to construct button text for hidden citations.
  54 Can use up to one integer format parameter, i.e. %d")
  55
  56 (defvar notmuch-wash-button-citation-visible-format
  57   "[ %d more citation lines. Click/Enter to hide. ]"
  58   "String used to construct button text for visible citations.
  59 Can use up to one integer format parameter, i.e. %d")
  60
  61 (defvar notmuch-wash-button-original-hidden-format
  62   "[ %d-line hidden original message. Click/Enter to show. ]"
  63   "String used to construct button text for hidden citations.
  64 Can use up to one integer format parameter, i.e. %d")
  65
  66 (defvar notmuch-wash-button-original-visible-format
  67   "[ %d-line original message. Click/Enter to hide. ]"
  68   "String used to construct button text for visible citations.
  69 Can use up to one integer format parameter, i.e. %d")
  70
  71 (defvar notmuch-wash-signature-lines-max 12
  72   "Maximum length of signature that will be hidden by default.")
  73
  74 (defvar notmuch-wash-citation-lines-prefix 3
  75   "Always show at least this many lines from the start of a citation.
  76
  77 If there is one more line than the sum of
  78 `notmuch-wash-citation-lines-prefix' and
  79 `notmuch-wash-citation-lines-suffix', show that, otherwise
  80 collapse the remaining lines into a button.")
  81
  82 (defvar notmuch-wash-citation-lines-suffix 3
  83   "Always show at least this many lines from the end of a citation.
  84
  85 If there is one more line than the sum of
  86 `notmuch-wash-citation-lines-prefix' and
  87 `notmuch-wash-citation-lines-suffix', show that, otherwise
  88 collapse the remaining lines into a button.")
  89
  90 (defun notmuch-wash-toggle-invisible-action (cite-button)
  91   (let ((invis-spec (button-get cite-button 'invisibility-spec)))
  92     (if (invisible-p invis-spec)
  93         (remove-from-invisibility-spec invis-spec)
  94       (add-to-invisibility-spec invis-spec)))
  95   (let* ((new-start (button-start cite-button))
  96          (overlay (button-get cite-button 'overlay))
  97          (button-label (notmuch-wash-button-label overlay))
  98          (old-point (point))
  99          (inhibit-read-only t))
 100     (goto-char new-start)
 101     (insert button-label)
 102     (let ((old-end (button-end cite-button)))
 103       (move-overlay cite-button new-start (point))
 104       (delete-region (point) old-end))
 105     (goto-char (min old-point (1- (button-end cite-button)))))
 106   (force-window-update)
 107   (redisplay t))
 108
 109 (define-button-type 'notmuch-wash-button-invisibility-toggle-type
 110   'action 'notmuch-wash-toggle-invisible-action
 111   'follow-link t
 112   'face 'font-lock-comment-face)
 113
 114 (define-button-type 'notmuch-wash-button-citation-toggle-type
 115   'help-echo "mouse-1, RET: Show citation"
 116   :supertype 'notmuch-wash-button-invisibility-toggle-type)
 117
 118 (define-button-type 'notmuch-wash-button-signature-toggle-type
 119   'help-echo "mouse-1, RET: Show signature"
 120   :supertype 'notmuch-wash-button-invisibility-toggle-type)
 121
 122 (define-button-type 'notmuch-wash-button-original-toggle-type
 123   'help-echo "mouse-1, RET: Show original message"
 124   :supertype 'notmuch-wash-button-invisibility-toggle-type)
 125
 126 (defun notmuch-wash-region-isearch-show (overlay)
 127   (remove-from-invisibility-spec (overlay-get overlay 'invisible)))
 128
 129 (defun notmuch-wash-button-label (overlay)
 130   (let* ((type (overlay-get overlay 'type))
 131          (invis-spec (overlay-get overlay 'invisible))
 132          (state (if (invisible-p invis-spec) "hidden" "visible"))
 133          (label-format (symbol-value (intern-soft (concat "notmuch-wash-button-"
 134                                                           type "-" state "-format"))))
 135          (lines-count (count-lines (overlay-start overlay) (overlay-end overlay))))
 136     (format label-format lines-count)))
 137
 138 (defun notmuch-wash-region-to-button (beg end type prefix)
 139   "Auxilary function to do the actual making of overlays and buttons
 140
 141 BEG and END are buffer locations. TYPE should a string, either
 142 \"citation\" or \"signature\". PREFIX is some arbitrary text to
 143 insert before the button, probably for indentation."
 144
 145   ;; This uses some slightly tricky conversions between strings and
 146   ;; symbols because of the way the button code works. Note that
 147   ;; replacing intern-soft with make-symbol will cause this to fail,
 148   ;; since the newly created symbol has no plist.
 149
 150   (let ((overlay (make-overlay beg end))
 151         (invis-spec (make-symbol (concat "notmuch-" type "-region")))
 152         (button-type (intern-soft (concat "notmuch-wash-button-"
 153                                           type "-toggle-type"))))
 154     (add-to-invisibility-spec invis-spec)
 155     (overlay-put overlay 'invisible invis-spec)
 156     (overlay-put overlay 'isearch-open-invisible #'notmuch-wash-region-isearch-show)
 157     (overlay-put overlay 'type type)
 158     (goto-char (1+ end))
 159     (save-excursion
 160       (goto-char (1- beg))
 161       (insert prefix)
 162       (insert-button (notmuch-wash-button-label overlay)
 163                      'invisibility-spec invis-spec
 164                      'overlay overlay
 165                      :type button-type))))
 166
 167 (defun notmuch-wash-excerpt-citations (depth)
 168   "Excerpt citations and up to one signature."
 169   (goto-char (point-min))
 170   (beginning-of-line)
 171   (if (and (< (point) (point-max))
 172            (re-search-forward notmuch-wash-original-regexp nil t))
 173       (let* ((msg-start (match-beginning 0))
 174              (msg-end (point-max))
 175              (msg-lines (count-lines msg-start msg-end)))
 176         (notmuch-wash-region-to-button
 177          msg-start msg-end "original" "\n")))
 178   (while (and (< (point) (point-max))
 179               (re-search-forward notmuch-wash-citation-regexp nil t))
 180     (let* ((cite-start (match-beginning 0))
 181            (cite-end (match-end 0))
 182            (cite-lines (count-lines cite-start cite-end)))
 183       (overlay-put (make-overlay cite-start cite-end) 'face 'message-cited-text)
 184       (when (> cite-lines (+ notmuch-wash-citation-lines-prefix
 185                              notmuch-wash-citation-lines-suffix
 186                              1))
 187         (goto-char cite-start)
 188         (forward-line notmuch-wash-citation-lines-prefix)
 189         (let ((hidden-start (point-marker)))
 190           (goto-char cite-end)
 191           (forward-line (- notmuch-wash-citation-lines-suffix))
 192           (notmuch-wash-region-to-button
 193            hidden-start (point-marker)
 194            "citation" "\n")))))
 195   (if (and (not (eobp))
 196            (re-search-forward notmuch-wash-signature-regexp nil t))
 197       (let* ((sig-start (match-beginning 0))
 198              (sig-end (match-end 0))
 199              (sig-lines (count-lines sig-start (point-max))))
 200         (if (<= sig-lines notmuch-wash-signature-lines-max)
 201             (let ((sig-start-marker (make-marker))
 202                   (sig-end-marker (make-marker)))
 203               (set-marker sig-start-marker sig-start)
 204               (set-marker sig-end-marker (point-max))
 205               (overlay-put (make-overlay sig-start-marker sig-end-marker) 'face 'message-cited-text)
 206               (notmuch-wash-region-to-button
 207                sig-start-marker sig-end-marker
 208                "signature" "\n"))))))
 209
 210 ;;
 211
 212 (defun notmuch-wash-elide-blank-lines (depth)
 213   "Elide leading, trailing and successive blank lines."
 214
 215   ;; Algorithm derived from `article-strip-multiple-blank-lines' in
 216   ;; `gnus-art.el'.
 217
 218   ;; Make all blank lines empty.
 219   (goto-char (point-min))
 220   (while (re-search-forward "^[[:space:]\t]+$" nil t)
 221     (replace-match "" nil t))
 222
 223   ;; Replace multiple empty lines with a single empty line.
 224   (goto-char (point-min))
 225   (while (re-search-forward "^\n\\(\n+\\)" nil t)
 226     (delete-region (match-beginning 1) (match-end 1)))
 227
 228   ;; Remove a leading blank line.
 229   (goto-char (point-min))
 230   (if (looking-at "\n")
 231       (delete-region (match-beginning 0) (match-end 0)))
 232
 233   ;; Remove a trailing blank line.
 234   (goto-char (point-max))
 235   (if (looking-at "\n")
 236       (delete-region (match-beginning 0) (match-end 0))))
 237
 238 ;;
 239
 240 (defun notmuch-wash-tidy-citations (depth)
 241   "Improve the display of cited regions of a message.
 242
 243 Perform several transformations on the message body:
 244
 245 - Remove lines of repeated citation leaders with no other
 246   content,
 247 - Remove citation leaders standing alone before a block of cited
 248   text,
 249 - Remove citation trailers standing alone after a block of cited
 250   text."
 251
 252   ;; Remove lines of repeated citation leaders with no other content.
 253   (goto-char (point-min))
 254   (while (re-search-forward "\\(^>[> ]*\n\\)\\{2,\\}" nil t)
 255     (replace-match "\\1"))
 256
 257   ;; Remove citation leaders standing alone before a block of cited
 258   ;; text.
 259   (goto-char (point-min))
 260   (while (re-search-forward "\\(\n\\|^[^>].*\\)\n\\(^>[> ]*\n\\)" nil t)
 261     (replace-match "\\1\n"))
 262
 263   ;; Remove citation trailers standing alone after a block of cited
 264   ;; text.
 265   (goto-char (point-min))
 266   (while (re-search-forward "\\(^>[> ]*\n\\)\\(^$\\|^[^>].*\\)" nil t)
 267     (replace-match "\\2")))
 268
 269 ;;
 270
 271 (defun notmuch-wash-wrap-long-lines (depth)
 272   "Wrap any long lines in the message to the width of the window.
 273
 274 When doing so, maintaining citation leaders in the wrapped text."
 275
 276   (let ((coolj-wrap-follows-window-size nil)
 277         (fill-column (- (window-width)
 278                         depth
 279                         ;; 2 to avoid poor interaction with
 280                         ;; `word-wrap'.
 281                         2)))
 282     (coolj-wrap-region (point-min) (point-max))))
 283
 284 ;;
 285
 286 (require 'diff-mode)
 287
 288 (defvar diff-file-header-re) ; From `diff-mode.el'.
 289
 290 (defun notmuch-wash-convert-inline-patch-to-part (depth)
 291   "Convert an inline patch into a fake 'text/x-diff' attachment.
 292
 293 Given that this function guesses whether a buffer includes a
 294 patch and then guesses the extent of the patch, there is scope
 295 for error."
 296
 297   (goto-char (point-min))
 298   (if (re-search-forward diff-file-header-re nil t)
 299       (progn
 300         (beginning-of-line -1)
 301         (let ((patch-start (point))
 302               (patch-end (point-max))
 303               part)
 304           (goto-char patch-start)
 305           (if (or
 306                ;; Patch ends with signature.
 307                (re-search-forward notmuch-wash-signature-regexp nil t)
 308                ;; Patch ends with bugtraq comment.
 309                (re-search-forward "^\\*\\*\\* " nil t))
 310               (setq patch-end (match-beginning 0)))
 311           (save-restriction
 312             (narrow-to-region patch-start patch-end)
 313             (setq part (plist-put part :content-type "text/x-diff"))
 314             (setq part (plist-put part :content (buffer-string)))
 315             (setq part (plist-put part :id -1))
 316             (setq part (plist-put part :filename "inline patch"))
 317             (delete-region (point-min) (point-max))
 318             (notmuch-show-insert-bodypart nil part depth))))))
 319
 320 ;;
 321
 322 ;; Temporary workaround for Emacs bug #8721
 323 ;; http://debbugs.gnu.org/cgi/bugreport.cgi?bug=8721
 324
 325 (defun notmuch-isearch-range-invisible (beg end)
 326   "Same as `isearch-range-invisible' but with fixed Emacs bug #8721."
 327   (when (/= beg end)
 328     ;; Check that invisibility runs up to END.
 329     (save-excursion
 330       (goto-char beg)
 331       (let (;; can-be-opened keeps track if we can open some overlays.
 332             (can-be-opened (eq search-invisible 'open))
 333             ;; the list of overlays that could be opened
 334             (crt-overlays nil))
 335         (when (and can-be-opened isearch-hide-immediately)
 336           (isearch-close-unnecessary-overlays beg end))
 337         ;; If the following character is currently invisible,
 338         ;; skip all characters with that same `invisible' property value.
 339         ;; Do that over and over.
 340         (while (and (< (point) end) (invisible-p (point)))
 341           (if (invisible-p (get-text-property (point) 'invisible))
 342               (progn
 343                 (goto-char (next-single-property-change (point) 'invisible
 344                                                         nil end))
 345                 ;; if text is hidden by an `invisible' text property
 346                 ;; we cannot open it at all.
 347                 (setq can-be-opened nil))
 348             (when can-be-opened
 349               (let ((overlays (overlays-at (point)))
 350                     ov-list
 351                     o
 352                     invis-prop)
 353                 (while overlays
 354                   (setq o (car overlays)
 355                         invis-prop (overlay-get o 'invisible))
 356                   (if (invisible-p invis-prop)
 357                       (if (overlay-get o 'isearch-open-invisible)
 358                           (setq ov-list (cons o ov-list))
 359                         ;; We found one overlay that cannot be
 360                         ;; opened, that means the whole chunk
 361                         ;; cannot be opened.
 362                         (setq can-be-opened nil)))
 363                   (setq overlays (cdr overlays)))
 364                 (if can-be-opened
 365                     ;; It makes sense to append to the open
 366                     ;; overlays list only if we know that this is
 367                     ;; t.
 368                     (setq crt-overlays (append ov-list crt-overlays)))))
 369             (goto-char (next-overlay-change (point)))))
 370         ;; See if invisibility reaches up thru END.
 371         (if (>= (point) end)
 372             (if (and can-be-opened (consp crt-overlays))
 373                 (progn
 374                   (setq isearch-opened-overlays
 375                         (append isearch-opened-overlays crt-overlays))
 376                   (mapc 'isearch-open-overlay-temporary crt-overlays)
 377                   nil)
 378               (setq isearch-hidden t)))))))
 379
 380 (defadvice isearch-range-invisible (around notmuch-isearch-range-invisible-advice activate)
 381   "Call `notmuch-isearch-range-invisible' instead of the original
 382 `isearch-range-invisible' when in `notmuch-show-mode' mode."
 383   (if (eq major-mode 'notmuch-show-mode)
 384       (setq ad-return-value (notmuch-isearch-range-invisible beg end))
 385     ad-do-it))
 386
 387 ;;
 388
 389 (provide 'notmuch-wash)