git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61
  62 (defcustom notmuch-search-result-format
  63   `(("date" . "%s ")
  64     ("count" . "%-7s ")
  65     ("authors" . "%-20s ")
  66     ("subject" . "%s ")
  67     ("tags" . "(%s)"))
  68   "Search result formatting. Supported fields are:
  69         date, count, authors, subject, tags
  70 For example:
  71         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  72                                              \(\"subject\" . \"%s\"\)\)\)"
  73   :type '(alist :key-type (string) :value-type (string))
  74   :group 'notmuch-search)
  75
  76 (defvar notmuch-query-history nil
  77   "Variable to store minibuffer history for notmuch queries")
  78
  79 (defun notmuch-foreach-mime-part (function mm-handle)
  80   (cond ((stringp (car mm-handle))
  81          (dolist (part (cdr mm-handle))
  82            (notmuch-foreach-mime-part function part)))
  83         ((bufferp (car mm-handle))
  84          (funcall function mm-handle))
  85         (t (dolist (part mm-handle)
  86              (notmuch-foreach-mime-part function part)))))
  87
  88 (defun notmuch-count-attachments (mm-handle)
  89   (let ((count 0))
  90     (notmuch-foreach-mime-part
  91      (lambda (p)
  92        (let ((disposition (mm-handle-disposition p)))
  93          (and (listp disposition)
  94               (or (equal (car disposition) "attachment")
  95                   (and (equal (car disposition) "inline")
  96                        (assq 'filename disposition)))
  97               (incf count))))
  98      mm-handle)
  99     count))
 100
 101 (defun notmuch-save-attachments (mm-handle &optional queryp)
 102   (notmuch-foreach-mime-part
 103    (lambda (p)
 104      (let ((disposition (mm-handle-disposition p)))
 105        (and (listp disposition)
 106             (or (equal (car disposition) "attachment")
 107                 (and (equal (car disposition) "inline")
 108                      (assq 'filename disposition)))
 109             (or (not queryp)
 110                 (y-or-n-p
 111                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 112             (mm-save-part p))))
 113    mm-handle))
 114
 115 (defun notmuch-documentation-first-line (symbol)
 116   "Return the first line of the documentation string for SYMBOL."
 117   (let ((doc (documentation symbol)))
 118     (if doc
 119         (with-temp-buffer
 120           (insert (documentation symbol t))
 121           (goto-char (point-min))
 122           (let ((beg (point)))
 123             (end-of-line)
 124             (buffer-substring beg (point))))
 125       "")))
 126
 127 (defun notmuch-prefix-key-description (key)
 128   "Given a prefix key code, return a human-readable string representation.
 129
 130 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 131   (let ((desc (format-kbd-macro (vector key))))
 132     (if (string= desc "ESC")
 133         "M-"
 134       (concat desc " "))))
 135
 136 ;; I would think that emacs would have code handy for walking a keymap
 137 ;; and generating strings for each key, and I would prefer to just call
 138 ;; that. But I couldn't find any (could be all implemented in C I
 139 ;; suppose), so I wrote my own here.
 140 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 141   "For a key binding, return a string showing a human-readable
 142 representation of the prefixed key as well as the first line of
 143 documentation from the bound function.
 144
 145 For a mouse binding, return nil."
 146   (let ((key (car binding))
 147         (action (cdr binding)))
 148     (if (mouse-event-p key)
 149         nil
 150       (if (keymapp action)
 151           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 152                 (as-list))
 153             (map-keymap (lambda (a b)
 154                           (push (cons a b) as-list))
 155                         action)
 156             (mapconcat substitute as-list "\n"))
 157         (concat prefix (format-kbd-macro (vector key))
 158                 "\t"
 159                 (notmuch-documentation-first-line action))))))
 160
 161 (defun notmuch-substitute-command-keys-one (key)
 162   ;; A `keymap' key indicates inheritance from a parent keymap - the
 163   ;; inherited mappings follow, so there is nothing to print for
 164   ;; `keymap' itself.
 165   (when (not (eq key 'keymap))
 166     (notmuch-substitute-one-command-key-with-prefix nil key)))
 167
 168 (defun notmuch-substitute-command-keys (doc)
 169   "Like `substitute-command-keys' but with documentation, not function names."
 170   (let ((beg 0))
 171     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 172       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 173              (keymap (symbol-value (intern keymap-name))))
 174         (setq doc (replace-match
 175                    (mapconcat #'notmuch-substitute-command-keys-one
 176                               (cdr keymap) "\n")
 177                    1 1 doc)))
 178       (setq beg (match-end 0)))
 179     doc))
 180
 181 (defun notmuch-help ()
 182   "Display help for the current notmuch mode."
 183   (interactive)
 184   (let* ((mode major-mode)
 185          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 186     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 187       (insert doc)
 188       (goto-char (point-min))
 189       (set-buffer-modified-p nil)
 190       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 191
 192 (require 'hl-line)
 193
 194 (defun notmuch-hl-line-mode ()
 195   (prog1 (hl-line-mode)
 196     (when hl-line-overlay
 197       (overlay-put hl-line-overlay 'priority 1))))
 198
 199 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 200   "List of functions to call when notmuch displays the search results."
 201   :type 'hook
 202   :options '(notmuch-hl-line-mode)
 203   :group 'notmuch-search
 204   :group 'notmuch-hooks)
 205
 206 (defvar notmuch-search-mode-map
 207   (let ((map (make-sparse-keymap)))
 208     (define-key map "?" 'notmuch-help)
 209     (define-key map "q" 'notmuch-search-quit)
 210     (define-key map "x" 'notmuch-search-quit)
 211     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 212     (define-key map "b" 'notmuch-search-scroll-down)
 213     (define-key map " " 'notmuch-search-scroll-up)
 214     (define-key map "<" 'notmuch-search-first-thread)
 215     (define-key map ">" 'notmuch-search-last-thread)
 216     (define-key map "p" 'notmuch-search-previous-thread)
 217     (define-key map "n" 'notmuch-search-next-thread)
 218     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 219     (define-key map "R" 'notmuch-search-reply-to-thread)
 220     (define-key map "m" 'notmuch-mua-new-mail)
 221     (define-key map "s" 'notmuch-search)
 222     (define-key map "o" 'notmuch-search-toggle-order)
 223     (define-key map "c" 'notmuch-search-stash-map)
 224     (define-key map "=" 'notmuch-search-refresh-view)
 225     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 226     (define-key map "t" 'notmuch-search-filter-by-tag)
 227     (define-key map "f" 'notmuch-search-filter)
 228     (define-key map [mouse-1] 'notmuch-search-show-thread)
 229     (define-key map "*" 'notmuch-search-tag-all)
 230     (define-key map "a" 'notmuch-search-archive-thread)
 231     (define-key map "-" 'notmuch-search-remove-tag)
 232     (define-key map "+" 'notmuch-search-add-tag)
 233     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 234     map)
 235   "Keymap for \"notmuch search\" buffers.")
 236 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 237
 238 (defvar notmuch-search-stash-map
 239   (let ((map (make-sparse-keymap)))
 240     (define-key map "i" 'notmuch-search-stash-thread-id)
 241     map)
 242   "Submap for stash commands")
 243 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 244
 245 (defun notmuch-search-stash-thread-id ()
 246   "Copy thread ID of current thread to kill-ring."
 247   (interactive)
 248   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 249
 250 (defvar notmuch-search-query-string)
 251 (defvar notmuch-search-target-thread)
 252 (defvar notmuch-search-target-line)
 253 (defvar notmuch-search-continuation)
 254
 255 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 256
 257 (defun notmuch-search-quit ()
 258   "Exit the search buffer, calling any defined continuation function."
 259   (interactive)
 260   (let ((continuation notmuch-search-continuation))
 261     (notmuch-kill-this-buffer)
 262     (when continuation
 263       (funcall continuation))))
 264
 265 (defun notmuch-search-scroll-up ()
 266   "Move forward through search results by one window's worth."
 267   (interactive)
 268   (condition-case nil
 269       (scroll-up nil)
 270     ((end-of-buffer) (notmuch-search-last-thread))))
 271
 272 (defun notmuch-search-scroll-down ()
 273   "Move backward through the search results by one window's worth."
 274   (interactive)
 275   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 276   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 277   ;;
 278   ;; So instead of trapping a signal we instead check whether the
 279   ;; window begins on the first line of the buffer and if so, move
 280   ;; directly to that position. (We have to count lines since the
 281   ;; window-start position is not the same as point-min due to the
 282   ;; invisible thread-ID characters on the first line.
 283   (if (equal (count-lines (point-min) (window-start)) 0)
 284       (goto-char (point-min))
 285     (scroll-down nil)))
 286
 287 (defun notmuch-search-next-thread ()
 288   "Select the next thread in the search results."
 289   (interactive)
 290   (forward-line 1))
 291
 292 (defun notmuch-search-previous-thread ()
 293   "Select the previous thread in the search results."
 294   (interactive)
 295   (forward-line -1))
 296
 297 (defun notmuch-search-last-thread ()
 298   "Select the last thread in the search results."
 299   (interactive)
 300   (goto-char (point-max))
 301   (forward-line -2))
 302
 303 (defun notmuch-search-first-thread ()
 304   "Select the first thread in the search results."
 305   (interactive)
 306   (goto-char (point-min)))
 307
 308 (defface notmuch-message-summary-face
 309  '((((class color) (background light)) (:background "#f0f0f0"))
 310    (((class color) (background dark)) (:background "#303030")))
 311  "Face for the single-line message summary in notmuch-show-mode."
 312  :group 'notmuch-show
 313  :group 'notmuch-faces)
 314
 315 (defface notmuch-search-date
 316   '((t :inherit default))
 317   "Face used in search mode for dates."
 318   :group 'notmuch-search
 319   :group 'notmuch-faces)
 320
 321 (defface notmuch-search-count
 322   '((t :inherit default))
 323   "Face used in search mode for the count matching the query."
 324   :group 'notmuch-search
 325   :group 'notmuch-faces)
 326
 327 (defface notmuch-search-subject
 328   '((t :inherit default))
 329   "Face used in search mode for subjects."
 330   :group 'notmuch-search
 331   :group 'notmuch-faces)
 332
 333 (defface notmuch-search-matching-authors
 334   '((t :inherit default))
 335   "Face used in search mode for authors matching the query."
 336   :group 'notmuch-search
 337   :group 'notmuch-faces)
 338
 339 (defface notmuch-search-non-matching-authors
 340   '((((class color)
 341       (background dark))
 342      (:foreground "grey30"))
 343     (((class color)
 344       (background light))
 345      (:foreground "grey60"))
 346     (t
 347      (:italic t)))
 348   "Face used in search mode for authors not matching the query."
 349   :group 'notmuch-search
 350   :group 'notmuch-faces)
 351
 352 (defface notmuch-tag-face
 353   '((((class color)
 354       (background dark))
 355      (:foreground "OliveDrab1"))
 356     (((class color)
 357       (background light))
 358      (:foreground "navy blue" :bold t))
 359     (t
 360      (:bold t)))
 361   "Face used in search mode face for tags."
 362   :group 'notmuch-search
 363   :group 'notmuch-faces)
 364
 365 (defun notmuch-search-mode ()
 366   "Major mode displaying results of a notmuch search.
 367
 368 This buffer contains the results of a \"notmuch search\" of your
 369 email archives. Each line in the buffer represents a single
 370 thread giving a summary of the thread (a relative date, the
 371 number of matched messages and total messages in the thread,
 372 participants in the thread, a representative subject line, and
 373 any tags).
 374
 375 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 376 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 377 is a convenience for archiving a thread (removing the \"inbox\"
 378 tag). The '\\[notmuch-search-tag-all]' key can be used to add or remove a tag from all
 379 threads in the current buffer.
 380
 381 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 382 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 383 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 384 search.
 385
 386 Complete list of currently available key bindings:
 387
 388 \\{notmuch-search-mode-map}"
 389   (interactive)
 390   (kill-all-local-variables)
 391   (make-local-variable 'notmuch-search-query-string)
 392   (make-local-variable 'notmuch-search-oldest-first)
 393   (make-local-variable 'notmuch-search-target-thread)
 394   (make-local-variable 'notmuch-search-target-line)
 395   (set (make-local-variable 'notmuch-search-continuation) nil)
 396   (set (make-local-variable 'scroll-preserve-screen-position) t)
 397   (add-to-invisibility-spec (cons 'ellipsis t))
 398   (use-local-map notmuch-search-mode-map)
 399   (setq truncate-lines t)
 400   (setq major-mode 'notmuch-search-mode
 401         mode-name "notmuch-search")
 402   (setq buffer-read-only t))
 403
 404 (defun notmuch-search-properties-in-region (property beg end)
 405   (save-excursion
 406     (let ((output nil)
 407           (last-line (line-number-at-pos end))
 408           (max-line (- (line-number-at-pos (point-max)) 2)))
 409       (goto-char beg)
 410       (beginning-of-line)
 411       (while (<= (line-number-at-pos) (min last-line max-line))
 412         (setq output (cons (get-text-property (point) property) output))
 413         (forward-line 1))
 414       output)))
 415
 416 (defun notmuch-search-find-thread-id ()
 417   "Return the thread for the current thread"
 418   (get-text-property (point) 'notmuch-search-thread-id))
 419
 420 (defun notmuch-search-find-thread-id-region (beg end)
 421   "Return a list of threads for the current region"
 422   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 423
 424 (defun notmuch-search-find-thread-id-region-search (beg end)
 425   "Return a search string for threads for the current region"
 426   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 427
 428 (defun notmuch-search-find-authors ()
 429   "Return the authors for the current thread"
 430   (get-text-property (point) 'notmuch-search-authors))
 431
 432 (defun notmuch-search-find-authors-region (beg end)
 433   "Return a list of authors for the current region"
 434   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 435
 436 (defun notmuch-search-find-subject ()
 437   "Return the subject for the current thread"
 438   (get-text-property (point) 'notmuch-search-subject))
 439
 440 (defun notmuch-search-find-subject-region (beg end)
 441   "Return a list of authors for the current region"
 442   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 443
 444 (defun notmuch-search-show-thread ()
 445   "Display the currently selected thread."
 446   (interactive)
 447   (let ((thread-id (notmuch-search-find-thread-id))
 448         (subject (notmuch-search-find-subject)))
 449     (if (> (length thread-id) 0)
 450         (notmuch-show thread-id
 451                       (current-buffer)
 452                       notmuch-search-query-string
 453                       ;; Name the buffer based on the subject.
 454                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 455       (message "End of search results."))))
 456
 457 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 458   "Begin composing a reply-all to the entire current thread in a new buffer."
 459   (interactive "P")
 460   (let ((message-id (notmuch-search-find-thread-id)))
 461     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 462
 463 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 464   "Begin composing a reply to the entire current thread in a new buffer."
 465   (interactive "P")
 466   (let ((message-id (notmuch-search-find-thread-id)))
 467     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 468
 469 (defun notmuch-call-notmuch-process (&rest args)
 470   "Synchronously invoke \"notmuch\" with the given list of arguments.
 471
 472 Output from the process will be presented to the user as an error
 473 and will also appear in a buffer named \"*Notmuch errors*\"."
 474   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 475     (with-current-buffer error-buffer
 476         (erase-buffer))
 477     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 478         (point)
 479       (progn
 480         (with-current-buffer error-buffer
 481           (let ((beg (point-min))
 482                 (end (- (point-max) 1)))
 483             (error (buffer-substring beg end))
 484             ))))))
 485
 486 (defun notmuch-search-set-tags (tags)
 487   (save-excursion
 488     (end-of-line)
 489     (re-search-backward "(")
 490     (forward-char)
 491     (let ((beg (point))
 492           (inhibit-read-only t))
 493       (re-search-forward ")")
 494       (backward-char)
 495       (let ((end (point)))
 496         (delete-region beg end)
 497         (insert (propertize (mapconcat  'identity tags " ")
 498                             'face 'notmuch-tag-face))))))
 499
 500 (defun notmuch-search-get-tags ()
 501   (save-excursion
 502     (end-of-line)
 503     (re-search-backward "(")
 504     (let ((beg (+ (point) 1)))
 505       (re-search-forward ")")
 506       (let ((end (- (point) 1)))
 507         (split-string (buffer-substring-no-properties beg end))))))
 508
 509 (defun notmuch-search-get-tags-region (beg end)
 510   (save-excursion
 511     (let ((output nil)
 512           (last-line (line-number-at-pos end))
 513           (max-line (- (line-number-at-pos (point-max)) 2)))
 514       (goto-char beg)
 515       (while (<= (line-number-at-pos) (min last-line max-line))
 516         (setq output (append output (notmuch-search-get-tags)))
 517         (forward-line 1))
 518       output)))
 519
 520 (defun notmuch-search-tag-thread (&rest tag-changes)
 521   "Change tags for the currently selected thread.
 522
 523 See `notmuch-search-tag-region' for details."
 524   (apply 'notmuch-search-tag-region (point) (point) tag-changes))
 525
 526 (defun notmuch-search-tag-region (beg end &rest tag-changes)
 527   "Change tags for threads in the given region.
 528
 529 TAGS is a list of tag operations for `notmuch-tag'.  The tags are
 530 added or removed for all threads in the region from BEG to END."
 531   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 532     (apply 'notmuch-tag search-string tag-changes)
 533     (save-excursion
 534       (let ((last-line (line-number-at-pos end))
 535             (max-line (- (line-number-at-pos (point-max)) 2)))
 536         (goto-char beg)
 537         (while (<= (line-number-at-pos) (min last-line max-line))
 538           (notmuch-search-set-tags
 539            (notmuch-update-tags (notmuch-search-get-tags) tag-changes))
 540           (forward-line))))))
 541
 542 (defun notmuch-search-tag (&optional initial-input)
 543   "Change tags for the currently selected thread or region."
 544   (interactive)
 545   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 546          (end (if (region-active-p) (region-end) (point)))
 547          (search-string (notmuch-search-find-thread-id-region-search beg end))
 548          (tags (notmuch-read-tag-changes initial-input search-string)))
 549     (apply 'notmuch-search-tag-region beg end tags)))
 550
 551 (defun notmuch-search-add-tag ()
 552   "Same as `notmuch-search-tag' but sets initial input to '+'."
 553   (interactive)
 554   (notmuch-search-tag "+"))
 555
 556 (defun notmuch-search-remove-tag ()
 557   "Same as `notmuch-search-tag' but sets initial input to '-'."
 558   (interactive)
 559   (notmuch-search-tag "-"))
 560
 561 (defun notmuch-search-archive-thread ()
 562   "Archive the currently selected thread (remove its \"inbox\" tag).
 563
 564 This function advances the next thread when finished."
 565   (interactive)
 566   (notmuch-search-tag-thread "-inbox")
 567   (notmuch-search-next-thread))
 568
 569 (defvar notmuch-search-process-filter-data nil
 570   "Data that has not yet been processed.")
 571 (make-variable-buffer-local 'notmuch-search-process-filter-data)
 572
 573 (defun notmuch-search-process-sentinel (proc msg)
 574   "Add a message to let user know when \"notmuch search\" exits"
 575   (let ((buffer (process-buffer proc))
 576         (status (process-status proc))
 577         (exit-status (process-exit-status proc))
 578         (never-found-target-thread nil))
 579     (if (memq status '(exit signal))
 580         (if (buffer-live-p buffer)
 581             (with-current-buffer buffer
 582               (save-excursion
 583                 (let ((inhibit-read-only t)
 584                       (atbob (bobp)))
 585                   (goto-char (point-max))
 586                   (if (eq status 'signal)
 587                       (insert "Incomplete search results (search process was killed).\n"))
 588                   (when (eq status 'exit)
 589                     (if notmuch-search-process-filter-data
 590                         (insert (concat "Error: Unexpected output from notmuch search:\n" notmuch-search-process-filter-data)))
 591                     (insert "End of search results.")
 592                     (unless (= exit-status 0)
 593                       (insert (format " (process returned %d)" exit-status)))
 594                     (insert "\n")
 595                     (if (and atbob
 596                              (not (string= notmuch-search-target-thread "found")))
 597                         (set 'never-found-target-thread t)))))
 598               (when (and never-found-target-thread
 599                        notmuch-search-target-line)
 600                   (goto-char (point-min))
 601                   (forward-line (1- notmuch-search-target-line))))))))
 602
 603 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 604                                        ("flagged" :foreground "blue"))
 605   "Tag/face mapping for line highlighting in notmuch-search.
 606
 607 Here is an example of how to color search results based on tags.
 608  (the following text would be placed in your ~/.emacs file):
 609
 610  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 611                                                   :background \"blue\"))
 612                                    (\"unread\" . (:foreground \"green\"))))
 613
 614 The attributes defined for matching tags are merged, with later
 615 attributes overriding earlier. A message having both \"deleted\"
 616 and \"unread\" tags with the above settings would have a green
 617 foreground and blue background."
 618   :type '(alist :key-type (string) :value-type (custom-face-edit))
 619   :group 'notmuch-search
 620   :group 'notmuch-faces)
 621
 622 (defun notmuch-search-color-line (start end line-tag-list)
 623   "Colorize lines in `notmuch-show' based on tags."
 624   ;; Create the overlay only if the message has tags which match one
 625   ;; of those specified in `notmuch-search-line-faces'.
 626   (let (overlay)
 627     (mapc (lambda (elem)
 628             (let ((tag (car elem))
 629                   (attributes (cdr elem)))
 630               (when (member tag line-tag-list)
 631                 (when (not overlay)
 632                   (setq overlay (make-overlay start end)))
 633                 ;; Merge the specified properties with any already
 634                 ;; applied from an earlier match.
 635                 (overlay-put overlay 'face
 636                              (append (overlay-get overlay 'face) attributes)))))
 637           notmuch-search-line-faces)))
 638
 639 (defun notmuch-search-author-propertize (authors)
 640   "Split `authors' into matching and non-matching authors and
 641 propertize appropriately. If no boundary between authors and
 642 non-authors is found, assume that all of the authors match."
 643   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 644       (concat (propertize (concat (match-string 1 authors) ",")
 645                           'face 'notmuch-search-matching-authors)
 646               (propertize (match-string 2 authors)
 647                           'face 'notmuch-search-non-matching-authors))
 648     (propertize authors 'face 'notmuch-search-matching-authors)))
 649
 650 (defun notmuch-search-insert-authors (format-string authors)
 651   ;; Save the match data to avoid interfering with
 652   ;; `notmuch-search-process-filter'.
 653   (save-match-data
 654     (let* ((formatted-authors (format format-string authors))
 655            (formatted-sample (format format-string ""))
 656            (visible-string formatted-authors)
 657            (invisible-string "")
 658            (padding ""))
 659
 660       ;; Truncate the author string to fit the specification.
 661       (if (> (length formatted-authors)
 662              (length formatted-sample))
 663           (let ((visible-length (- (length formatted-sample)
 664                                    (length "... "))))
 665             ;; Truncate the visible string according to the width of
 666             ;; the display string.
 667             (setq visible-string (substring formatted-authors 0 visible-length)
 668                   invisible-string (substring formatted-authors visible-length))
 669             ;; If possible, truncate the visible string at a natural
 670             ;; break (comma or pipe), as incremental search doesn't
 671             ;; match across the visible/invisible border.
 672             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 673               ;; Second clause is destructive on `visible-string', so
 674               ;; order is important.
 675               (setq invisible-string (concat (match-string 3 visible-string)
 676                                              invisible-string)
 677                     visible-string (concat (match-string 1 visible-string)
 678                                            (match-string 2 visible-string))))
 679             ;; `visible-string' may be shorter than the space allowed
 680             ;; by `format-string'. If so we must insert some padding
 681             ;; after `invisible-string'.
 682             (setq padding (make-string (- (length formatted-sample)
 683                                           (length visible-string)
 684                                           (length "..."))
 685                                        ? ))))
 686
 687       ;; Use different faces to show matching and non-matching authors.
 688       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 689           ;; The visible string contains both matching and
 690           ;; non-matching authors.
 691           (setq visible-string (notmuch-search-author-propertize visible-string)
 692                 ;; The invisible string must contain only non-matching
 693                 ;; authors, as the visible-string contains both.
 694                 invisible-string (propertize invisible-string
 695                                              'face 'notmuch-search-non-matching-authors))
 696         ;; The visible string contains only matching authors.
 697         (setq visible-string (propertize visible-string
 698                                          'face 'notmuch-search-matching-authors)
 699               ;; The invisible string may contain both matching and
 700               ;; non-matching authors.
 701               invisible-string (notmuch-search-author-propertize invisible-string)))
 702
 703       ;; If there is any invisible text, add it as a tooltip to the
 704       ;; visible text.
 705       (when (not (string= invisible-string ""))
 706         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 707
 708       ;; Insert the visible and, if present, invisible author strings.
 709       (insert visible-string)
 710       (when (not (string= invisible-string ""))
 711         (let ((start (point))
 712               overlay)
 713           (insert invisible-string)
 714           (setq overlay (make-overlay start (point)))
 715           (overlay-put overlay 'invisible 'ellipsis)
 716           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 717       (insert padding))))
 718
 719 (defun notmuch-search-insert-field (field date count authors subject tags)
 720   (cond
 721    ((string-equal field "date")
 722     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) date)
 723                         'face 'notmuch-search-date)))
 724    ((string-equal field "count")
 725     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) count)
 726                         'face 'notmuch-search-count)))
 727    ((string-equal field "subject")
 728     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) subject)
 729                         'face 'notmuch-search-subject)))
 730
 731    ((string-equal field "authors")
 732     (notmuch-search-insert-authors (cdr (assoc field notmuch-search-result-format)) authors))
 733
 734    ((string-equal field "tags")
 735     (insert (concat "(" (propertize tags 'font-lock-face 'notmuch-tag-face) ")")))))
 736
 737 (defun notmuch-search-show-result (date count authors subject tags)
 738   (let ((fields) (field))
 739     (setq fields (mapcar 'car notmuch-search-result-format))
 740     (loop for field in fields
 741           do (notmuch-search-insert-field field date count authors subject tags)))
 742   (insert "\n"))
 743
 744 (defun notmuch-search-process-filter (proc string)
 745   "Process and filter the output of \"notmuch search\""
 746   (let ((buffer (process-buffer proc))
 747         (found-target nil))
 748     (if (buffer-live-p buffer)
 749         (with-current-buffer buffer
 750           (save-excursion
 751             (let ((line 0)
 752                   (more t)
 753                   (inhibit-read-only t)
 754                   (string (concat notmuch-search-process-filter-data string)))
 755               (setq notmuch-search-process-filter-data nil)
 756               (while more
 757                 (while (and (< line (length string)) (= (elt string line) ?\n))
 758                   (setq line (1+ line)))
 759                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\([^][]*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 760                     (let* ((thread-id (match-string 1 string))
 761                            (date (match-string 2 string))
 762                            (count (match-string 3 string))
 763                            (authors (match-string 4 string))
 764                            (subject (match-string 5 string))
 765                            (tags (match-string 6 string))
 766                            (tag-list (if tags (save-match-data (split-string tags)))))
 767                       (goto-char (point-max))
 768                       (if (/= (match-beginning 1) line)
 769                           (insert (concat "Error: Unexpected output from notmuch search:\n" (substring string line (match-beginning 1)) "\n")))
 770                       ;; We currently just throw away excluded matches.
 771                       (unless (eq (aref count 1) ?0)
 772                         (let ((beg (point)))
 773                           (notmuch-search-show-result date count authors subject tags)
 774                           (notmuch-search-color-line beg (point) tag-list)
 775                           (put-text-property beg (point) 'notmuch-search-thread-id thread-id)
 776                           (put-text-property beg (point) 'notmuch-search-authors authors)
 777                           (put-text-property beg (point) 'notmuch-search-subject subject)
 778                           (when (string= thread-id notmuch-search-target-thread)
 779                             (set 'found-target beg)
 780                             (set 'notmuch-search-target-thread "found"))))
 781                       (set 'line (match-end 0)))
 782                   (set 'more nil)
 783                   (while (and (< line (length string)) (= (elt string line) ?\n))
 784                     (setq line (1+ line)))
 785                   (if (< line (length string))
 786                       (setq notmuch-search-process-filter-data (substring string line)))
 787                   ))))
 788           (if found-target
 789               (goto-char found-target)))
 790       (delete-process proc))))
 791
 792 (defun notmuch-search-tag-all (&rest tag-changes)
 793   "Add/remove tags from all matching messages.
 794
 795 This command adds or removes tags from all messages matching the
 796 current search terms. When called interactively, this command
 797 will prompt for tags to be added or removed. Tags prefixed with
 798 '+' will be added and tags prefixed with '-' will be removed.
 799
 800 Each character of the tag name may consist of alphanumeric
 801 characters as well as `_.+-'.
 802 "
 803   (interactive (notmuch-read-tag-changes))
 804   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
 805
 806 (defun notmuch-search-buffer-title (query)
 807   "Returns the title for a buffer with notmuch search results."
 808   (let* ((saved-search
 809           (let (longest
 810                 (longest-length 0))
 811             (loop for tuple in notmuch-saved-searches
 812                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 813                        (and (string-match (concat "^" quoted-query) query)
 814                             (> (length (match-string 0 query))
 815                                longest-length)))
 816                   do (setq longest tuple))
 817             longest))
 818          (saved-search-name (car saved-search))
 819          (saved-search-query (cdr saved-search)))
 820     (cond ((and saved-search (equal saved-search-query query))
 821            ;; Query is the same as saved search (ignoring case)
 822            (concat "*notmuch-saved-search-" saved-search-name "*"))
 823           (saved-search
 824            (concat "*notmuch-search-"
 825                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 826                                              (concat "[ " saved-search-name " ]")
 827                                              query)
 828                    "*"))
 829           (t
 830            (concat "*notmuch-search-" query "*"))
 831           )))
 832
 833 (defun notmuch-read-query (prompt)
 834   "Read a notmuch-query from the minibuffer with completion.
 835
 836 PROMPT is the string to prompt with."
 837   (lexical-let
 838       ((completions
 839         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 840                       "subject:" "attachment:")
 841                 (mapcar (lambda (tag)
 842                           (concat "tag:" tag))
 843                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 844     (let ((keymap (copy-keymap minibuffer-local-map))
 845           (minibuffer-completion-table
 846            (completion-table-dynamic
 847             (lambda (string)
 848               ;; generate a list of possible completions for the current input
 849               (cond
 850                ;; this ugly regexp is used to get the last word of the input
 851                ;; possibly preceded by a '('
 852                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 853                 (mapcar (lambda (compl)
 854                           (concat (match-string-no-properties 1 string) compl))
 855                         (all-completions (match-string-no-properties 2 string)
 856                                          completions)))
 857                (t (list string)))))))
 858       ;; this was simpler than convincing completing-read to accept spaces:
 859       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 860       (let ((history-delete-duplicates t))
 861         (read-from-minibuffer prompt nil keymap nil
 862                               'notmuch-search-history nil nil)))))
 863
 864 ;;;###autoload
 865 (defun notmuch-search (&optional query oldest-first target-thread target-line continuation)
 866   "Run \"notmuch search\" with the given `query' and display results.
 867
 868 If `query' is nil, it is read interactively from the minibuffer.
 869 Other optional parameters are used as follows:
 870
 871   oldest-first: A Boolean controlling the sort order of returned threads
 872   target-thread: A thread ID (with the thread: prefix) that will be made
 873                  current if it appears in the search results.
 874   target-line: The line number to move to if the target thread does not
 875                appear in the search results."
 876   (interactive)
 877   (if (null query)
 878       (setq query (notmuch-read-query "Notmuch search: ")))
 879   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 880     (switch-to-buffer buffer)
 881     (notmuch-search-mode)
 882     ;; Don't track undo information for this buffer
 883     (set 'buffer-undo-list t)
 884     (set 'notmuch-search-query-string query)
 885     (set 'notmuch-search-oldest-first oldest-first)
 886     (set 'notmuch-search-target-thread target-thread)
 887     (set 'notmuch-search-target-line target-line)
 888     (set 'notmuch-search-continuation continuation)
 889     (let ((proc (get-buffer-process (current-buffer)))
 890           (inhibit-read-only t))
 891       (if proc
 892           (error "notmuch search process already running for query `%s'" query)
 893         )
 894       (erase-buffer)
 895       (goto-char (point-min))
 896       (save-excursion
 897         (let ((proc (start-process
 898                      "notmuch-search" buffer
 899                      notmuch-command "search"
 900                      (if oldest-first
 901                          "--sort=oldest-first"
 902                        "--sort=newest-first")
 903                      query)))
 904           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 905           (set-process-filter proc 'notmuch-search-process-filter)
 906           (set-process-query-on-exit-flag proc nil))))
 907     (run-hooks 'notmuch-search-hook)))
 908
 909 (defun notmuch-search-refresh-view ()
 910   "Refresh the current view.
 911
 912 Kills the current buffer and runs a new search with the same
 913 query string as the current search. If the current thread is in
 914 the new search results, then point will be placed on the same
 915 thread. Otherwise, point will be moved to attempt to be in the
 916 same relative position within the new buffer."
 917   (interactive)
 918   (let ((target-line (line-number-at-pos))
 919         (oldest-first notmuch-search-oldest-first)
 920         (target-thread (notmuch-search-find-thread-id))
 921         (query notmuch-search-query-string)
 922         (continuation notmuch-search-continuation))
 923     (notmuch-kill-this-buffer)
 924     (notmuch-search query oldest-first target-thread target-line continuation)
 925     (goto-char (point-min))))
 926
 927 (defcustom notmuch-poll-script nil
 928   "An external script to incorporate new mail into the notmuch database.
 929
 930 This variable controls the action invoked by
 931 `notmuch-search-poll-and-refresh-view' and
 932 `notmuch-hello-poll-and-update' (each have a default keybinding
 933 of 'G') to incorporate new mail into the notmuch database.
 934
 935 If set to nil (the default), new mail is processed by invoking
 936 \"notmuch new\". Otherwise, this should be set to a string that
 937 gives the name of an external script that processes new mail. If
 938 set to the empty string, no command will be run.
 939
 940 The external script could do any of the following depending on
 941 the user's needs:
 942
 943 1. Invoke a program to transfer mail to the local mail store
 944 2. Invoke \"notmuch new\" to incorporate the new mail
 945 3. Invoke one or more \"notmuch tag\" commands to classify the mail
 946
 947 Note that the recommended way of achieving the same is using
 948 \"notmuch new\" hooks."
 949   :type '(choice (const :tag "notmuch new" nil)
 950                  (const :tag "Disabled" "")
 951                  (string :tag "Custom script"))
 952   :group 'notmuch-external)
 953
 954 (defun notmuch-poll ()
 955   "Run \"notmuch new\" or an external script to import mail.
 956
 957 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 958 depending on the value of `notmuch-poll-script'."
 959   (interactive)
 960   (if (stringp notmuch-poll-script)
 961       (unless (string= notmuch-poll-script "")
 962         (call-process notmuch-poll-script nil nil))
 963     (call-process notmuch-command nil nil nil "new")))
 964
 965 (defun notmuch-search-poll-and-refresh-view ()
 966   "Invoke `notmuch-poll' to import mail, then refresh the current view."
 967   (interactive)
 968   (notmuch-poll)
 969   (notmuch-search-refresh-view))
 970
 971 (defun notmuch-search-toggle-order ()
 972   "Toggle the current search order.
 973
 974 By default, the \"inbox\" view created by `notmuch' is displayed
 975 in chronological order (oldest thread at the beginning of the
 976 buffer), while any global searches created by `notmuch-search'
 977 are displayed in reverse-chronological order (newest thread at
 978 the beginning of the buffer).
 979
 980 This command toggles the sort order for the current search.
 981
 982 Note that any filtered searches created by
 983 `notmuch-search-filter' retain the search order of the parent
 984 search."
 985   (interactive)
 986   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 987   (notmuch-search-refresh-view))
 988
 989 (defun notmuch-search-filter (query)
 990   "Filter the current search results based on an additional query string.
 991
 992 Runs a new search matching only messages that match both the
 993 current search results AND the additional query string provided."
 994   (interactive (list (notmuch-read-query "Filter search: ")))
 995   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 996                            (concat "( " query " )")
 997                          query)))
 998     (notmuch-search (if (string= notmuch-search-query-string "*")
 999                         grouped-query
1000                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1001
1002 (defun notmuch-search-filter-by-tag (tag)
1003   "Filter the current search results based on a single tag.
1004
1005 Runs a new search matching only messages that match both the
1006 current search results AND that are tagged with the given tag."
1007   (interactive
1008    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1009   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1010
1011 ;;;###autoload
1012 (defun notmuch ()
1013   "Run notmuch and display saved searches, known tags, etc."
1014   (interactive)
1015   (notmuch-hello))
1016
1017 (defun notmuch-interesting-buffer (b)
1018   "Is the current buffer of interest to a notmuch user?"
1019   (with-current-buffer b
1020     (memq major-mode '(notmuch-show-mode
1021                        notmuch-search-mode
1022                        notmuch-hello-mode
1023                        message-mode))))
1024
1025 ;;;###autoload
1026 (defun notmuch-cycle-notmuch-buffers ()
1027   "Cycle through any existing notmuch buffers (search, show or hello).
1028
1029 If the current buffer is the only notmuch buffer, bury it. If no
1030 notmuch buffers exist, run `notmuch'."
1031   (interactive)
1032
1033   (let (start first)
1034     ;; If the current buffer is a notmuch buffer, remember it and then
1035     ;; bury it.
1036     (when (notmuch-interesting-buffer (current-buffer))
1037       (setq start (current-buffer))
1038       (bury-buffer))
1039
1040     ;; Find the first notmuch buffer.
1041     (setq first (loop for buffer in (buffer-list)
1042                      if (notmuch-interesting-buffer buffer)
1043                      return buffer))
1044
1045     (if first
1046         ;; If the first one we found is any other than the starting
1047         ;; buffer, switch to it.
1048         (unless (eq first start)
1049           (switch-to-buffer first))
1050       (notmuch))))
1051
1052 (setq mail-user-agent 'notmuch-user-agent)
1053
1054 (provide 'notmuch)