git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-tree)
  58 (require 'notmuch-mua)
  59 (require 'notmuch-hello)
  60 (require 'notmuch-maildir-fcc)
  61 (require 'notmuch-message)
  62 (require 'notmuch-parser)
  63
  64 (defcustom notmuch-search-result-format
  65   `(("date" . "%12s ")
  66     ("count" . "%-7s ")
  67     ("authors" . "%-20s ")
  68     ("subject" . "%s ")
  69     ("tags" . "(%s)"))
  70   "Search result formatting. Supported fields are:
  71         date, count, authors, subject, tags
  72 For example:
  73         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  74                                              \(\"subject\" . \"%s\"\)\)\)
  75 Line breaks are permitted in format strings (though this is
  76 currently experimental).  Note that a line break at the end of an
  77 \"authors\" field will get elided if the authors list is long;
  78 place it instead at the beginning of the following field.  To
  79 enter a line break when setting this variable with setq, use \\n.
  80 To enter a line break in customize, press \\[quoted-insert] C-j."
  81   :type '(alist :key-type (string) :value-type (string))
  82   :group 'notmuch-search)
  83
  84 ;; The name of this variable `notmuch-init-file' is consistent with the
  85 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  86 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  87 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  88   "Your Notmuch Emacs-Lisp configuration file name.
  89 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  90 it will be read instead.
  91 This file is read once when notmuch is loaded; the notmuch hooks added
  92 there will be called at other points of notmuch execution."
  93   :type 'file
  94   :group 'notmuch)
  95
  96 (defvar notmuch-query-history nil
  97   "Variable to store minibuffer history for notmuch queries")
  98
  99 (defun notmuch-foreach-mime-part (function mm-handle)
 100   (cond ((stringp (car mm-handle))
 101          (dolist (part (cdr mm-handle))
 102            (notmuch-foreach-mime-part function part)))
 103         ((bufferp (car mm-handle))
 104          (funcall function mm-handle))
 105         (t (dolist (part mm-handle)
 106              (notmuch-foreach-mime-part function part)))))
 107
 108 (defun notmuch-count-attachments (mm-handle)
 109   (let ((count 0))
 110     (notmuch-foreach-mime-part
 111      (lambda (p)
 112        (let ((disposition (mm-handle-disposition p)))
 113          (and (listp disposition)
 114               (or (equal (car disposition) "attachment")
 115                   (and (equal (car disposition) "inline")
 116                        (assq 'filename disposition)))
 117               (incf count))))
 118      mm-handle)
 119     count))
 120
 121 (defun notmuch-save-attachments (mm-handle &optional queryp)
 122   (notmuch-foreach-mime-part
 123    (lambda (p)
 124      (let ((disposition (mm-handle-disposition p)))
 125        (and (listp disposition)
 126             (or (equal (car disposition) "attachment")
 127                 (and (equal (car disposition) "inline")
 128                      (assq 'filename disposition)))
 129             (or (not queryp)
 130                 (y-or-n-p
 131                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 132             (mm-save-part p))))
 133    mm-handle))
 134
 135 (require 'hl-line)
 136
 137 (defun notmuch-hl-line-mode ()
 138   (prog1 (hl-line-mode)
 139     (when hl-line-overlay
 140       (overlay-put hl-line-overlay 'priority 1))))
 141
 142 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 143   "List of functions to call when notmuch displays the search results."
 144   :type 'hook
 145   :options '(notmuch-hl-line-mode)
 146   :group 'notmuch-search
 147   :group 'notmuch-hooks)
 148
 149 (defvar notmuch-search-mode-map
 150   (let ((map (make-sparse-keymap)))
 151     (set-keymap-parent map notmuch-common-keymap)
 152     (define-key map "x" 'notmuch-kill-this-buffer)
 153     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 154     (define-key map "b" 'notmuch-search-scroll-down)
 155     (define-key map " " 'notmuch-search-scroll-up)
 156     (define-key map "<" 'notmuch-search-first-thread)
 157     (define-key map ">" 'notmuch-search-last-thread)
 158     (define-key map "p" 'notmuch-search-previous-thread)
 159     (define-key map "n" 'notmuch-search-next-thread)
 160     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 161     (define-key map "R" 'notmuch-search-reply-to-thread)
 162     (define-key map "o" 'notmuch-search-toggle-order)
 163     (define-key map "c" 'notmuch-search-stash-map)
 164     (define-key map "t" 'notmuch-search-filter-by-tag)
 165     (define-key map "f" 'notmuch-search-filter)
 166     (define-key map [mouse-1] 'notmuch-search-show-thread)
 167     (define-key map "*" 'notmuch-search-tag-all)
 168     (define-key map "a" 'notmuch-search-archive-thread)
 169     (define-key map "-" 'notmuch-search-remove-tag)
 170     (define-key map "+" 'notmuch-search-add-tag)
 171     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 172     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 173     map)
 174   "Keymap for \"notmuch search\" buffers.")
 175 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 176
 177 (defvar notmuch-search-stash-map
 178   (let ((map (make-sparse-keymap)))
 179     (define-key map "i" 'notmuch-search-stash-thread-id)
 180     (define-key map "?" 'notmuch-subkeymap-help)
 181     map)
 182   "Submap for stash commands")
 183 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 184
 185 (defun notmuch-search-stash-thread-id ()
 186   "Copy thread ID of current thread to kill-ring."
 187   (interactive)
 188   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 189
 190 (defvar notmuch-search-query-string)
 191 (defvar notmuch-search-target-thread)
 192 (defvar notmuch-search-target-line)
 193
 194 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 195
 196 (defun notmuch-search-scroll-up ()
 197   "Move forward through search results by one window's worth."
 198   (interactive)
 199   (condition-case nil
 200       (scroll-up nil)
 201     ((end-of-buffer) (notmuch-search-last-thread))))
 202
 203 (defun notmuch-search-scroll-down ()
 204   "Move backward through the search results by one window's worth."
 205   (interactive)
 206   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 207   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 208   ;;
 209   ;; So instead of trapping a signal we instead check whether the
 210   ;; window begins on the first line of the buffer and if so, move
 211   ;; directly to that position. (We have to count lines since the
 212   ;; window-start position is not the same as point-min due to the
 213   ;; invisible thread-ID characters on the first line.
 214   (if (equal (count-lines (point-min) (window-start)) 0)
 215       (goto-char (point-min))
 216     (scroll-down nil)))
 217
 218 (defun notmuch-search-next-thread ()
 219   "Select the next thread in the search results."
 220   (interactive)
 221   (when (notmuch-search-get-result)
 222     (goto-char (notmuch-search-result-end))))
 223
 224 (defun notmuch-search-previous-thread ()
 225   "Select the previous thread in the search results."
 226   (interactive)
 227   (if (notmuch-search-get-result)
 228       (unless (bobp)
 229         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 230     ;; We must be past the end; jump to the last result
 231     (notmuch-search-last-thread)))
 232
 233 (defun notmuch-search-last-thread ()
 234   "Select the last thread in the search results."
 235   (interactive)
 236   (goto-char (point-max))
 237   (forward-line -2)
 238   (let ((beg (notmuch-search-result-beginning)))
 239     (when beg (goto-char beg))))
 240
 241 (defun notmuch-search-first-thread ()
 242   "Select the first thread in the search results."
 243   (interactive)
 244   (goto-char (point-min)))
 245
 246 (defface notmuch-message-summary-face
 247  '((((class color) (background light)) (:background "#f0f0f0"))
 248    (((class color) (background dark)) (:background "#303030")))
 249  "Face for the single-line message summary in notmuch-show-mode."
 250  :group 'notmuch-show
 251  :group 'notmuch-faces)
 252
 253 (defface notmuch-search-date
 254   '((t :inherit default))
 255   "Face used in search mode for dates."
 256   :group 'notmuch-search
 257   :group 'notmuch-faces)
 258
 259 (defface notmuch-search-count
 260   '((t :inherit default))
 261   "Face used in search mode for the count matching the query."
 262   :group 'notmuch-search
 263   :group 'notmuch-faces)
 264
 265 (defface notmuch-search-subject
 266   '((t :inherit default))
 267   "Face used in search mode for subjects."
 268   :group 'notmuch-search
 269   :group 'notmuch-faces)
 270
 271 (defface notmuch-search-matching-authors
 272   '((t :inherit default))
 273   "Face used in search mode for authors matching the query."
 274   :group 'notmuch-search
 275   :group 'notmuch-faces)
 276
 277 (defface notmuch-search-non-matching-authors
 278   '((((class color)
 279       (background dark))
 280      (:foreground "grey30"))
 281     (((class color)
 282       (background light))
 283      (:foreground "grey60"))
 284     (t
 285      (:italic t)))
 286   "Face used in search mode for authors not matching the query."
 287   :group 'notmuch-search
 288   :group 'notmuch-faces)
 289
 290 (defface notmuch-tag-face
 291   '((((class color)
 292       (background dark))
 293      (:foreground "OliveDrab1"))
 294     (((class color)
 295       (background light))
 296      (:foreground "navy blue" :bold t))
 297     (t
 298      (:bold t)))
 299   "Face used in search mode face for tags."
 300   :group 'notmuch-search
 301   :group 'notmuch-faces)
 302
 303 (defun notmuch-search-mode ()
 304   "Major mode displaying results of a notmuch search.
 305
 306 This buffer contains the results of a \"notmuch search\" of your
 307 email archives. Each line in the buffer represents a single
 308 thread giving a summary of the thread (a relative date, the
 309 number of matched messages and total messages in the thread,
 310 participants in the thread, a representative subject line, and
 311 any tags).
 312
 313 Pressing \\[notmuch-search-show-thread] on any line displays that
 314 thread. The '\\[notmuch-search-add-tag]' and
 315 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 316 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 317 is a convenience for archiving a thread (applying changes in
 318 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 319 be used to add and/or remove tags from all messages (as opposed
 320 to threads) that match the current query.  Use with caution, as
 321 this will also tag matching messages that arrived *after*
 322 constructing the buffer.
 323
 324 Other useful commands are '\\[notmuch-search-filter]' for
 325 filtering the current search based on an additional query string,
 326 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 327 messages with a given tag, and '\\[notmuch-search]' to execute a
 328 new, global search.
 329
 330 Complete list of currently available key bindings:
 331
 332 \\{notmuch-search-mode-map}"
 333   (interactive)
 334   (kill-all-local-variables)
 335   (make-local-variable 'notmuch-search-query-string)
 336   (make-local-variable 'notmuch-search-oldest-first)
 337   (make-local-variable 'notmuch-search-target-thread)
 338   (make-local-variable 'notmuch-search-target-line)
 339   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 340   (set (make-local-variable 'scroll-preserve-screen-position) t)
 341   (add-to-invisibility-spec (cons 'ellipsis t))
 342   (use-local-map notmuch-search-mode-map)
 343   (setq truncate-lines t)
 344   (setq major-mode 'notmuch-search-mode
 345         mode-name "notmuch-search")
 346   (setq buffer-read-only t))
 347
 348 (defun notmuch-search-get-result (&optional pos)
 349   "Return the result object for the thread at POS (or point).
 350
 351 If there is no thread at POS (or point), returns nil."
 352   (get-text-property (or pos (point)) 'notmuch-search-result))
 353
 354 (defun notmuch-search-result-beginning (&optional pos)
 355   "Return the point at the beginning of the thread at POS (or point).
 356
 357 If there is no thread at POS (or point), returns nil."
 358   (when (notmuch-search-get-result pos)
 359     ;; We pass 1+point because previous-single-property-change starts
 360     ;; searching one before the position we give it.
 361     (previous-single-property-change (1+ (or pos (point)))
 362                                      'notmuch-search-result nil (point-min))))
 363
 364 (defun notmuch-search-result-end (&optional pos)
 365   "Return the point at the end of the thread at POS (or point).
 366
 367 The returned point will be just after the newline character that
 368 ends the result line.  If there is no thread at POS (or point),
 369 returns nil"
 370   (when (notmuch-search-get-result pos)
 371     (next-single-property-change (or pos (point)) 'notmuch-search-result
 372                                  nil (point-max))))
 373
 374 (defun notmuch-search-foreach-result (beg end function)
 375   "Invoke FUNCTION for each result between BEG and END.
 376
 377 FUNCTION should take one argument.  It will be applied to the
 378 character position of the beginning of each result that overlaps
 379 the region between points BEG and END.  As a special case, if (=
 380 BEG END), FUNCTION will be applied to the result containing point
 381 BEG."
 382
 383   (lexical-let ((pos (notmuch-search-result-beginning beg))
 384                 ;; End must be a marker in case function changes the
 385                 ;; text.
 386                 (end (copy-marker end))
 387                 ;; Make sure we examine at least one result, even if
 388                 ;; (= beg end).
 389                 (first t))
 390     ;; We have to be careful if the region extends beyond the results.
 391     ;; In this case, pos could be null or there could be no result at
 392     ;; pos.
 393     (while (and pos (or (< pos end) first))
 394       (when (notmuch-search-get-result pos)
 395         (funcall function pos))
 396       (setq pos (notmuch-search-result-end pos)
 397             first nil))))
 398 ;; Unindent the function argument of notmuch-search-foreach-result so
 399 ;; the indentation of callers doesn't get out of hand.
 400 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 401
 402 (defun notmuch-search-properties-in-region (property beg end)
 403   (let (output)
 404     (notmuch-search-foreach-result beg end
 405       (lambda (pos)
 406         (push (plist-get (notmuch-search-get-result pos) property) output)))
 407     output))
 408
 409 (defun notmuch-search-find-thread-id (&optional bare)
 410   "Return the thread for the current thread
 411
 412 If BARE is set then do not prefix with \"thread:\""
 413   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 414     (when thread (concat (unless bare "thread:") thread))))
 415
 416 (defun notmuch-search-find-stable-query ()
 417   "Return the stable queries for the current thread.
 418
 419 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 420 matched and unmatched messages in the current thread."
 421   (plist-get (notmuch-search-get-result) :query))
 422
 423 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 424   "Return the stable query for the current region.
 425
 426 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 427 is nil, include both matched and unmatched messages."
 428   (let ((query-list nil) (all (not only-matched)))
 429     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 430       (when (first queries)
 431         (push (first queries) query-list))
 432       (when (and all (second queries))
 433         (push (second queries) query-list)))
 434     (concat "(" (mapconcat 'identity query-list ") or (") ")")))
 435
 436 (defun notmuch-search-find-authors ()
 437   "Return the authors for the current thread"
 438   (plist-get (notmuch-search-get-result) :authors))
 439
 440 (defun notmuch-search-find-authors-region (beg end)
 441   "Return a list of authors for the current region"
 442   (notmuch-search-properties-in-region :authors beg end))
 443
 444 (defun notmuch-search-find-subject ()
 445   "Return the subject for the current thread"
 446   (plist-get (notmuch-search-get-result) :subject))
 447
 448 (defun notmuch-search-find-subject-region (beg end)
 449   "Return a list of authors for the current region"
 450   (notmuch-search-properties-in-region :subject beg end))
 451
 452 (defun notmuch-search-show-thread (&optional elide-toggle)
 453   "Display the currently selected thread."
 454   (interactive "P")
 455   (let ((thread-id (notmuch-search-find-thread-id))
 456         (subject (notmuch-search-find-subject)))
 457     (if (> (length thread-id) 0)
 458         (notmuch-show thread-id
 459                       elide-toggle
 460                       (current-buffer)
 461                       notmuch-search-query-string
 462                       ;; Name the buffer based on the subject.
 463                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 464       (message "End of search results."))))
 465
 466 (defun notmuch-tree-from-search-current-query ()
 467   "Call notmuch tree with the current query"
 468   (interactive)
 469   (notmuch-tree notmuch-search-query-string))
 470
 471 (defun notmuch-tree-from-search-thread ()
 472   "Show the selected thread with notmuch-tree"
 473   (interactive)
 474   (notmuch-tree (notmuch-search-find-thread-id)
 475                 notmuch-search-query-string
 476                 nil
 477                 (notmuch-prettify-subject (notmuch-search-find-subject))
 478                 t))
 479
 480 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 481   "Begin composing a reply-all to the entire current thread in a new buffer."
 482   (interactive "P")
 483   (let ((message-id (notmuch-search-find-thread-id)))
 484     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 485
 486 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 487   "Begin composing a reply to the entire current thread in a new buffer."
 488   (interactive "P")
 489   (let ((message-id (notmuch-search-find-thread-id)))
 490     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 491
 492 (defun notmuch-search-set-tags (tags &optional pos)
 493   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 494     (notmuch-search-update-result new-result pos)))
 495
 496 (defun notmuch-search-get-tags (&optional pos)
 497   (plist-get (notmuch-search-get-result pos) :tags))
 498
 499 (defun notmuch-search-get-tags-region (beg end)
 500   (let (output)
 501     (notmuch-search-foreach-result beg end
 502       (lambda (pos)
 503         (setq output (append output (notmuch-search-get-tags pos)))))
 504     output))
 505
 506 (defun notmuch-search-interactive-region ()
 507   "Return the bounds of the current interactive region.
 508
 509 This returns (BEG END), where BEG and END are the bounds of the
 510 region if the region is active, or both `point' otherwise."
 511   (if (region-active-p)
 512       (list (region-beginning) (region-end))
 513     (list (point) (point))))
 514
 515 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 516   "Prompt for tag changes for the current thread or region.
 517
 518 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 519   (let* ((region (notmuch-search-interactive-region))
 520          (beg (first region)) (end (second region))
 521          (prompt (if (= beg end) "Tag thread" "Tag region")))
 522     (cons (notmuch-read-tag-changes
 523            (notmuch-search-get-tags-region beg end) prompt initial-input)
 524           region)))
 525
 526 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 527   "Change tags for the currently selected thread or region.
 528
 529 See `notmuch-tag' for information on the format of TAG-CHANGES.
 530 When called interactively, this uses the region if the region is
 531 active.  When called directly, BEG and END provide the region.
 532 If these are nil or not provided, this applies to the thread at
 533 point.
 534
 535 If ONLY-MATCHED is non-nil, only tag matched messages."
 536   (interactive (notmuch-search-interactive-tag-changes))
 537   (unless (and beg end) (setq beg (point) end (point)))
 538   (let ((search-string (notmuch-search-find-stable-query-region
 539                         beg end only-matched)))
 540     (notmuch-tag search-string tag-changes)
 541     (notmuch-search-foreach-result beg end
 542       (lambda (pos)
 543         (notmuch-search-set-tags
 544          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 545          pos)))))
 546
 547 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 548   "Change tags for the current thread or region (defaulting to add).
 549
 550 Same as `notmuch-search-tag' but sets initial input to '+'."
 551   (interactive (notmuch-search-interactive-tag-changes "+"))
 552   (notmuch-search-tag tag-changes beg end))
 553
 554 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 555   "Change tags for the current thread or region (defaulting to remove).
 556
 557 Same as `notmuch-search-tag' but sets initial input to '-'."
 558   (interactive (notmuch-search-interactive-tag-changes "-"))
 559   (notmuch-search-tag tag-changes beg end))
 560
 561 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 562      "Un-archive the currently selected thread.")
 563 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 564   "Archive the currently selected thread or region.
 565
 566 Archive each message in the currently selected thread by applying
 567 the tag changes in `notmuch-archive-tags' to each (remove the
 568 \"inbox\" tag by default). If a prefix argument is given, the
 569 messages will be \"unarchived\" (i.e. the tag changes in
 570 `notmuch-archive-tags' will be reversed).
 571
 572 This function advances the next thread when finished."
 573   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 574   (when notmuch-archive-tags
 575     (notmuch-search-tag
 576      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 577   (notmuch-search-next-thread))
 578
 579 (defun notmuch-search-update-result (result &optional pos)
 580   "Replace the result object of the thread at POS (or point) by
 581 RESULT and redraw it.
 582
 583 This will keep point in a reasonable location.  However, if there
 584 are enclosing save-excursions and the saved point is in the
 585 result being updated, the point will be restored to the beginning
 586 of the result."
 587   (let ((start (notmuch-search-result-beginning pos))
 588         (end (notmuch-search-result-end pos))
 589         (init-point (point))
 590         (inhibit-read-only t))
 591     ;; Delete the current thread
 592     (delete-region start end)
 593     ;; Insert the updated thread
 594     (notmuch-search-show-result result start)
 595     ;; If point was inside the old result, make an educated guess
 596     ;; about where to place it now.  Unfortunately, this won't work
 597     ;; with save-excursion (or any other markers that would be nice to
 598     ;; preserve, such as the window start), but there's nothing we can
 599     ;; do about that without a way to retrieve markers in a region.
 600     (when (and (>= init-point start) (<= init-point end))
 601       (let* ((new-end (notmuch-search-result-end start))
 602              (new-point (if (= init-point end)
 603                             new-end
 604                           (min init-point (- new-end 1)))))
 605         (goto-char new-point)))))
 606
 607 (defun notmuch-search-process-sentinel (proc msg)
 608   "Add a message to let user know when \"notmuch search\" exits"
 609   (let ((buffer (process-buffer proc))
 610         (status (process-status proc))
 611         (exit-status (process-exit-status proc))
 612         (never-found-target-thread nil))
 613     (when (memq status '(exit signal))
 614       (catch 'return
 615         (kill-buffer (process-get proc 'parse-buf))
 616         (if (buffer-live-p buffer)
 617             (with-current-buffer buffer
 618               (save-excursion
 619                 (let ((inhibit-read-only t)
 620                       (atbob (bobp)))
 621                   (goto-char (point-max))
 622                   (if (eq status 'signal)
 623                       (insert "Incomplete search results (search process was killed).\n"))
 624                   (when (eq status 'exit)
 625                     (insert "End of search results.\n")
 626                     ;; For version mismatch, there's no point in
 627                     ;; showing the search buffer
 628                     (when (or (= exit-status 20) (= exit-status 21))
 629                       (kill-buffer)
 630                       (throw 'return nil))
 631                     (if (and atbob
 632                              (not (string= notmuch-search-target-thread "found")))
 633                         (set 'never-found-target-thread t)))))
 634               (when (and never-found-target-thread
 635                        notmuch-search-target-line)
 636                   (goto-char (point-min))
 637                   (forward-line (1- notmuch-search-target-line)))))))))
 638
 639 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 640                                        ("flagged" :foreground "blue"))
 641   "Tag/face mapping for line highlighting in notmuch-search.
 642
 643 Here is an example of how to color search results based on tags.
 644  (the following text would be placed in your ~/.emacs file):
 645
 646  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 647                                                   :background \"blue\"))
 648                                    (\"unread\" . (:foreground \"green\"))))
 649
 650 The attributes defined for matching tags are merged, with later
 651 attributes overriding earlier. A message having both \"deleted\"
 652 and \"unread\" tags with the above settings would have a green
 653 foreground and blue background."
 654   :type '(alist :key-type (string) :value-type (custom-face-edit))
 655   :group 'notmuch-search
 656   :group 'notmuch-faces)
 657
 658 (defun notmuch-search-color-line (start end line-tag-list)
 659   "Colorize lines in `notmuch-show' based on tags."
 660   (mapc (lambda (elem)
 661           (let ((tag (car elem))
 662                 (attributes (cdr elem)))
 663             (when (member tag line-tag-list)
 664               (notmuch-apply-face nil attributes nil start end))))
 665         ;; Reverse the list so earlier entries take precedence
 666         (reverse notmuch-search-line-faces)))
 667
 668 (defun notmuch-search-author-propertize (authors)
 669   "Split `authors' into matching and non-matching authors and
 670 propertize appropriately. If no boundary between authors and
 671 non-authors is found, assume that all of the authors match."
 672   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 673       (concat (propertize (concat (match-string 1 authors) ",")
 674                           'face 'notmuch-search-matching-authors)
 675               (propertize (match-string 2 authors)
 676                           'face 'notmuch-search-non-matching-authors))
 677     (propertize authors 'face 'notmuch-search-matching-authors)))
 678
 679 (defun notmuch-search-insert-authors (format-string authors)
 680   ;; Save the match data to avoid interfering with
 681   ;; `notmuch-search-process-filter'.
 682   (save-match-data
 683     (let* ((formatted-authors (format format-string authors))
 684            (formatted-sample (format format-string ""))
 685            (visible-string formatted-authors)
 686            (invisible-string "")
 687            (padding ""))
 688
 689       ;; Truncate the author string to fit the specification.
 690       (if (> (length formatted-authors)
 691              (length formatted-sample))
 692           (let ((visible-length (- (length formatted-sample)
 693                                    (length "... "))))
 694             ;; Truncate the visible string according to the width of
 695             ;; the display string.
 696             (setq visible-string (substring formatted-authors 0 visible-length)
 697                   invisible-string (substring formatted-authors visible-length))
 698             ;; If possible, truncate the visible string at a natural
 699             ;; break (comma or pipe), as incremental search doesn't
 700             ;; match across the visible/invisible border.
 701             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 702               ;; Second clause is destructive on `visible-string', so
 703               ;; order is important.
 704               (setq invisible-string (concat (match-string 3 visible-string)
 705                                              invisible-string)
 706                     visible-string (concat (match-string 1 visible-string)
 707                                            (match-string 2 visible-string))))
 708             ;; `visible-string' may be shorter than the space allowed
 709             ;; by `format-string'. If so we must insert some padding
 710             ;; after `invisible-string'.
 711             (setq padding (make-string (- (length formatted-sample)
 712                                           (length visible-string)
 713                                           (length "..."))
 714                                        ? ))))
 715
 716       ;; Use different faces to show matching and non-matching authors.
 717       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 718           ;; The visible string contains both matching and
 719           ;; non-matching authors.
 720           (setq visible-string (notmuch-search-author-propertize visible-string)
 721                 ;; The invisible string must contain only non-matching
 722                 ;; authors, as the visible-string contains both.
 723                 invisible-string (propertize invisible-string
 724                                              'face 'notmuch-search-non-matching-authors))
 725         ;; The visible string contains only matching authors.
 726         (setq visible-string (propertize visible-string
 727                                          'face 'notmuch-search-matching-authors)
 728               ;; The invisible string may contain both matching and
 729               ;; non-matching authors.
 730               invisible-string (notmuch-search-author-propertize invisible-string)))
 731
 732       ;; If there is any invisible text, add it as a tooltip to the
 733       ;; visible text.
 734       (when (not (string= invisible-string ""))
 735         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 736
 737       ;; Insert the visible and, if present, invisible author strings.
 738       (insert visible-string)
 739       (when (not (string= invisible-string ""))
 740         (let ((start (point))
 741               overlay)
 742           (insert invisible-string)
 743           (setq overlay (make-overlay start (point)))
 744           (overlay-put overlay 'invisible 'ellipsis)
 745           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 746       (insert padding))))
 747
 748 (defun notmuch-search-insert-field (field format-string result)
 749   (cond
 750    ((string-equal field "date")
 751     (insert (propertize (format format-string (plist-get result :date_relative))
 752                         'face 'notmuch-search-date)))
 753    ((string-equal field "count")
 754     (insert (propertize (format format-string
 755                                 (format "[%s/%s]" (plist-get result :matched)
 756                                         (plist-get result :total)))
 757                         'face 'notmuch-search-count)))
 758    ((string-equal field "subject")
 759     (insert (propertize (format format-string
 760                                 (notmuch-sanitize (plist-get result :subject)))
 761                         'face 'notmuch-search-subject)))
 762
 763    ((string-equal field "authors")
 764     (notmuch-search-insert-authors
 765      format-string (notmuch-sanitize (plist-get result :authors))))
 766
 767    ((string-equal field "tags")
 768     (let ((tags (plist-get result :tags))
 769           (orig-tags (plist-get result :orig-tags)))
 770       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 771
 772 (defun notmuch-search-show-result (result pos)
 773   "Insert RESULT at POS."
 774   ;; Ignore excluded matches
 775   (unless (= (plist-get result :matched) 0)
 776     (save-excursion
 777       (goto-char pos)
 778       (dolist (spec notmuch-search-result-format)
 779         (notmuch-search-insert-field (car spec) (cdr spec) result))
 780       (insert "\n")
 781       (notmuch-search-color-line pos (point) (plist-get result :tags))
 782       (put-text-property pos (point) 'notmuch-search-result result))))
 783
 784 (defun notmuch-search-append-result (result)
 785   "Insert RESULT at the end of the buffer.
 786
 787 This is only called when a result is first inserted so it also
 788 sets the :orig-tag property."
 789   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 790         (pos (point-max)))
 791     (notmuch-search-show-result new-result pos)
 792     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 793       (setq notmuch-search-target-thread "found")
 794       (goto-char pos))))
 795
 796 (defun notmuch-search-process-filter (proc string)
 797   "Process and filter the output of \"notmuch search\""
 798   (let ((results-buf (process-buffer proc))
 799         (parse-buf (process-get proc 'parse-buf))
 800         (inhibit-read-only t)
 801         done)
 802     (when (buffer-live-p results-buf)
 803       (with-current-buffer parse-buf
 804         ;; Insert new data
 805         (save-excursion
 806           (goto-char (point-max))
 807           (insert string))
 808         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 809                                          results-buf)))))
 810
 811 (defun notmuch-search-tag-all (tag-changes)
 812   "Add/remove tags from all messages in current search buffer.
 813
 814 See `notmuch-tag' for information on the format of TAG-CHANGES."
 815   (interactive
 816    (list (notmuch-read-tag-changes
 817           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 818   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 819
 820 (defun notmuch-search-buffer-title (query)
 821   "Returns the title for a buffer with notmuch search results."
 822   (let* ((saved-search
 823           (let (longest
 824                 (longest-length 0))
 825             (loop for tuple in notmuch-saved-searches
 826                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 827                        (and (string-match (concat "^" quoted-query) query)
 828                             (> (length (match-string 0 query))
 829                                longest-length)))
 830                   do (setq longest tuple))
 831             longest))
 832          (saved-search-name (car saved-search))
 833          (saved-search-query (cdr saved-search)))
 834     (cond ((and saved-search (equal saved-search-query query))
 835            ;; Query is the same as saved search (ignoring case)
 836            (concat "*notmuch-saved-search-" saved-search-name "*"))
 837           (saved-search
 838            (concat "*notmuch-search-"
 839                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 840                                              (concat "[ " saved-search-name " ]")
 841                                              query)
 842                    "*"))
 843           (t
 844            (concat "*notmuch-search-" query "*"))
 845           )))
 846
 847 (defun notmuch-read-query (prompt)
 848   "Read a notmuch-query from the minibuffer with completion.
 849
 850 PROMPT is the string to prompt with."
 851   (lexical-let
 852       ((completions
 853         (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 854                       "subject:" "attachment:")
 855                 (mapcar (lambda (tag)
 856                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 857                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 858     (let ((keymap (copy-keymap minibuffer-local-map))
 859           (minibuffer-completion-table
 860            (completion-table-dynamic
 861             (lambda (string)
 862               ;; generate a list of possible completions for the current input
 863               (cond
 864                ;; this ugly regexp is used to get the last word of the input
 865                ;; possibly preceded by a '('
 866                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 867                 (mapcar (lambda (compl)
 868                           (concat (match-string-no-properties 1 string) compl))
 869                         (all-completions (match-string-no-properties 2 string)
 870                                          completions)))
 871                (t (list string)))))))
 872       ;; this was simpler than convincing completing-read to accept spaces:
 873       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 874       (let ((history-delete-duplicates t))
 875         (read-from-minibuffer prompt nil keymap nil
 876                               'notmuch-search-history nil nil)))))
 877
 878 ;;;###autoload
 879 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 880 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 881   "Display threads matching QUERY in a notmuch-search buffer.
 882
 883 If QUERY is nil, it is read interactively from the minibuffer.
 884 Other optional parameters are used as follows:
 885
 886   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 887   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 888                  current if it appears in the search results.
 889   TARGET-LINE: The line number to move to if the target thread does not
 890                appear in the search results.
 891
 892 When called interactively, this will prompt for a query and use
 893 the configured default sort order."
 894   (interactive
 895    (list
 896     ;; Prompt for a query
 897     nil
 898     ;; Use the default search order (if we're doing a search from a
 899     ;; search buffer, ignore any buffer-local overrides)
 900     (default-value 'notmuch-search-oldest-first)))
 901
 902   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 903          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 904     (switch-to-buffer buffer)
 905     (notmuch-search-mode)
 906     ;; Don't track undo information for this buffer
 907     (set 'buffer-undo-list t)
 908     (set 'notmuch-search-query-string query)
 909     (set 'notmuch-search-oldest-first oldest-first)
 910     (set 'notmuch-search-target-thread target-thread)
 911     (set 'notmuch-search-target-line target-line)
 912     (notmuch-tag-clear-cache)
 913     (let ((proc (get-buffer-process (current-buffer)))
 914           (inhibit-read-only t))
 915       (if proc
 916           (error "notmuch search process already running for query `%s'" query)
 917         )
 918       (erase-buffer)
 919       (goto-char (point-min))
 920       (save-excursion
 921         (let ((proc (notmuch-start-notmuch
 922                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 923                      "search" "--format=sexp" "--format-version=2"
 924                      (if oldest-first
 925                          "--sort=oldest-first"
 926                        "--sort=newest-first")
 927                      query))
 928               ;; Use a scratch buffer to accumulate partial output.
 929               ;; This buffer will be killed by the sentinel, which
 930               ;; should be called no matter how the process dies.
 931               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 932           (process-put proc 'parse-buf parse-buf)
 933           (set-process-filter proc 'notmuch-search-process-filter)
 934           (set-process-query-on-exit-flag proc nil))))
 935     (run-hooks 'notmuch-search-hook)))
 936
 937 (defun notmuch-search-refresh-view ()
 938   "Refresh the current view.
 939
 940 Kills the current buffer and runs a new search with the same
 941 query string as the current search. If the current thread is in
 942 the new search results, then point will be placed on the same
 943 thread. Otherwise, point will be moved to attempt to be in the
 944 same relative position within the new buffer."
 945   (let ((target-line (line-number-at-pos))
 946         (oldest-first notmuch-search-oldest-first)
 947         (target-thread (notmuch-search-find-thread-id 'bare))
 948         (query notmuch-search-query-string))
 949     (notmuch-kill-this-buffer)
 950     (notmuch-search query oldest-first target-thread target-line)
 951     (goto-char (point-min))))
 952
 953 (defun notmuch-search-toggle-order ()
 954   "Toggle the current search order.
 955
 956 This command toggles the sort order for the current search. The
 957 default sort order is defined by `notmuch-search-oldest-first'."
 958   (interactive)
 959   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 960   (notmuch-search-refresh-view))
 961
 962 (defun notmuch-search-filter (query)
 963   "Filter the current search results based on an additional query string.
 964
 965 Runs a new search matching only messages that match both the
 966 current search results AND the additional query string provided."
 967   (interactive (list (notmuch-read-query "Filter search: ")))
 968   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 969                            (concat "( " query " )")
 970                          query)))
 971     (notmuch-search (if (string= notmuch-search-query-string "*")
 972                         grouped-query
 973                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 974
 975 (defun notmuch-search-filter-by-tag (tag)
 976   "Filter the current search results based on a single tag.
 977
 978 Runs a new search matching only messages that match both the
 979 current search results AND that are tagged with the given tag."
 980   (interactive
 981    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 982   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 983
 984 ;;;###autoload
 985 (defun notmuch ()
 986   "Run notmuch and display saved searches, known tags, etc."
 987   (interactive)
 988   (notmuch-hello))
 989
 990 (defun notmuch-interesting-buffer (b)
 991   "Is the current buffer of interest to a notmuch user?"
 992   (with-current-buffer b
 993     (memq major-mode '(notmuch-show-mode
 994                        notmuch-search-mode
 995                        notmuch-hello-mode
 996                        message-mode))))
 997
 998 ;;;###autoload
 999 (defun notmuch-cycle-notmuch-buffers ()
1000   "Cycle through any existing notmuch buffers (search, show or hello).
1001
1002 If the current buffer is the only notmuch buffer, bury it. If no
1003 notmuch buffers exist, run `notmuch'."
1004   (interactive)
1005
1006   (let (start first)
1007     ;; If the current buffer is a notmuch buffer, remember it and then
1008     ;; bury it.
1009     (when (notmuch-interesting-buffer (current-buffer))
1010       (setq start (current-buffer))
1011       (bury-buffer))
1012
1013     ;; Find the first notmuch buffer.
1014     (setq first (loop for buffer in (buffer-list)
1015                      if (notmuch-interesting-buffer buffer)
1016                      return buffer))
1017
1018     (if first
1019         ;; If the first one we found is any other than the starting
1020         ;; buffer, switch to it.
1021         (unless (eq first start)
1022           (switch-to-buffer first))
1023       (notmuch))))
1024
1025 (setq mail-user-agent 'notmuch-user-agent)
1026
1027 (provide 'notmuch)
1028
1029 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1030 (if init-file-user ; don't load init file if the -q option was used.
1031     (let ((init-file (locate-file notmuch-init-file '("/")
1032                                   (get-load-suffixes))))
1033       (if init-file (load init-file nil t t))))