git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-show)
  56 (require 'notmuch-mua)
  57 (require 'notmuch-hello)
  58 (require 'notmuch-maildir-fcc)
  59 (require 'notmuch-message)
  60
  61 (defcustom notmuch-search-result-format
  62   `(("date" . "%s ")
  63     ("count" . "%-7s ")
  64     ("authors" . "%-20s ")
  65     ("subject" . "%s ")
  66     ("tags" . "(%s)"))
  67   "Search result formating. Supported fields are:
  68         date, count, authors, subject, tags
  69 For example:
  70         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  71                                              \(\"subject\" . \"%s\"\)\)\)"
  72   :type '(alist :key-type (string) :value-type (string))
  73   :group 'notmuch)
  74
  75 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
  76   (let ((tag-list
  77          (with-output-to-string
  78            (with-current-buffer standard-output
  79              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
  80     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
  81
  82 (defun notmuch-foreach-mime-part (function mm-handle)
  83   (cond ((stringp (car mm-handle))
  84          (dolist (part (cdr mm-handle))
  85            (notmuch-foreach-mime-part function part)))
  86         ((bufferp (car mm-handle))
  87          (funcall function mm-handle))
  88         (t (dolist (part mm-handle)
  89              (notmuch-foreach-mime-part function part)))))
  90
  91 (defun notmuch-count-attachments (mm-handle)
  92   (let ((count 0))
  93     (notmuch-foreach-mime-part
  94      (lambda (p)
  95        (let ((disposition (mm-handle-disposition p)))
  96          (and (listp disposition)
  97               (or (equal (car disposition) "attachment")
  98                   (and (equal (car disposition) "inline")
  99                        (assq 'filename disposition)))
 100               (incf count))))
 101      mm-handle)
 102     count))
 103
 104 (defun notmuch-save-attachments (mm-handle &optional queryp)
 105   (notmuch-foreach-mime-part
 106    (lambda (p)
 107      (let ((disposition (mm-handle-disposition p)))
 108        (and (listp disposition)
 109             (or (equal (car disposition) "attachment")
 110                 (and (equal (car disposition) "inline")
 111                      (assq 'filename disposition)))
 112             (or (not queryp)
 113                 (y-or-n-p
 114                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 115             (mm-save-part p))))
 116    mm-handle))
 117
 118 (defun notmuch-documentation-first-line (symbol)
 119   "Return the first line of the documentation string for SYMBOL."
 120   (let ((doc (documentation symbol)))
 121     (if doc
 122         (with-temp-buffer
 123           (insert (documentation symbol t))
 124           (goto-char (point-min))
 125           (let ((beg (point)))
 126             (end-of-line)
 127             (buffer-substring beg (point))))
 128       "")))
 129
 130 (defun notmuch-prefix-key-description (key)
 131   "Given a prefix key code, return a human-readable string representation.
 132
 133 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 134   (let ((desc (format-kbd-macro (vector key))))
 135     (if (string= desc "ESC")
 136         "M-"
 137       (concat desc " "))))
 138
 139 ; I would think that emacs would have code handy for walking a keymap
 140 ; and generating strings for each key, and I would prefer to just call
 141 ; that. But I couldn't find any (could be all implemented in C I
 142 ; suppose), so I wrote my own here.
 143 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 144   "For a key binding, return a string showing a human-readable
 145 representation of the prefixed key as well as the first line of
 146 documentation from the bound function.
 147
 148 For a mouse binding, return nil."
 149   (let ((key (car binding))
 150         (action (cdr binding)))
 151     (if (mouse-event-p key)
 152         nil
 153       (if (keymapp action)
 154           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 155                 (as-list))
 156             (map-keymap (lambda (a b)
 157                           (push (cons a b) as-list))
 158                         action)
 159             (mapconcat substitute as-list "\n"))
 160         (concat prefix (format-kbd-macro (vector key))
 161                 "\t"
 162                 (notmuch-documentation-first-line action))))))
 163
 164 (defalias 'notmuch-substitute-one-command-key
 165   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 166
 167 (defun notmuch-substitute-command-keys (doc)
 168   "Like `substitute-command-keys' but with documentation, not function names."
 169   (let ((beg 0))
 170     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 171       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 172         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 173                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 174       (setq beg (match-end 0)))
 175     doc))
 176
 177 (defun notmuch-help ()
 178   "Display help for the current notmuch mode."
 179   (interactive)
 180   (let* ((mode major-mode)
 181          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 182     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 183       (insert doc)
 184       (goto-char (point-min))
 185       (set-buffer-modified-p nil)
 186       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 187
 188 (defcustom notmuch-search-hook '(hl-line-mode)
 189   "List of functions to call when notmuch displays the search results."
 190   :type 'hook
 191   :options '(hl-line-mode)
 192   :group 'notmuch)
 193
 194 (defvar notmuch-search-mode-map
 195   (let ((map (make-sparse-keymap)))
 196     (define-key map "?" 'notmuch-help)
 197     (define-key map "q" 'notmuch-search-quit)
 198     (define-key map "x" 'notmuch-search-quit)
 199     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 200     (define-key map "b" 'notmuch-search-scroll-down)
 201     (define-key map " " 'notmuch-search-scroll-up)
 202     (define-key map "<" 'notmuch-search-first-thread)
 203     (define-key map ">" 'notmuch-search-last-thread)
 204     (define-key map "p" 'notmuch-search-previous-thread)
 205     (define-key map "n" 'notmuch-search-next-thread)
 206     (define-key map "r" 'notmuch-search-reply-to-thread)
 207     (define-key map "m" 'notmuch-mua-mail)
 208     (define-key map "s" 'notmuch-search)
 209     (define-key map "o" 'notmuch-search-toggle-order)
 210     (define-key map "c" 'notmuch-search-stash-map)
 211     (define-key map "=" 'notmuch-search-refresh-view)
 212     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 213     (define-key map "t" 'notmuch-search-filter-by-tag)
 214     (define-key map "f" 'notmuch-search-filter)
 215     (define-key map [mouse-1] 'notmuch-search-show-thread)
 216     (define-key map "*" 'notmuch-search-operate-all)
 217     (define-key map "a" 'notmuch-search-archive-thread)
 218     (define-key map "-" 'notmuch-search-remove-tag)
 219     (define-key map "+" 'notmuch-search-add-tag)
 220     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 221     map)
 222   "Keymap for \"notmuch search\" buffers.")
 223 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 224
 225 (defvar notmuch-search-stash-map
 226   (let ((map (make-sparse-keymap)))
 227     (define-key map "i" 'notmuch-search-stash-thread-id)
 228     map)
 229   "Submap for stash commands")
 230 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 231
 232 (defun notmuch-search-stash-thread-id ()
 233   "Copy thread ID of current thread to kill-ring."
 234   (interactive)
 235   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 236
 237 (defvar notmuch-search-query-string)
 238 (defvar notmuch-search-target-thread)
 239 (defvar notmuch-search-target-line)
 240 (defvar notmuch-search-continuation)
 241
 242 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 243
 244 (defun notmuch-search-quit ()
 245   "Exit the search buffer, calling any defined continuation function."
 246   (interactive)
 247   (let ((continuation notmuch-search-continuation))
 248     (notmuch-kill-this-buffer)
 249     (when continuation
 250       (funcall continuation))))
 251
 252 (defun notmuch-search-scroll-up ()
 253   "Move forward through search results by one window's worth."
 254   (interactive)
 255   (condition-case nil
 256       (scroll-up nil)
 257     ((end-of-buffer) (notmuch-search-last-thread))))
 258
 259 (defun notmuch-search-scroll-down ()
 260   "Move backward through the search results by one window's worth."
 261   (interactive)
 262   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 263   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 264   ;
 265   ; So instead of trapping a signal we instead check whether the
 266   ; window begins on the first line of the buffer and if so, move
 267   ; directly to that position. (We have to count lines since the
 268   ; window-start position is not the same as point-min due to the
 269   ; invisible thread-ID characters on the first line.
 270   (if (equal (count-lines (point-min) (window-start)) 0)
 271       (goto-char (point-min))
 272     (scroll-down nil)))
 273
 274 (defun notmuch-search-next-thread ()
 275   "Select the next thread in the search results."
 276   (interactive)
 277   (forward-line 1))
 278
 279 (defun notmuch-search-previous-thread ()
 280   "Select the previous thread in the search results."
 281   (interactive)
 282   (forward-line -1))
 283
 284 (defun notmuch-search-last-thread ()
 285   "Select the last thread in the search results."
 286   (interactive)
 287   (goto-char (point-max))
 288   (forward-line -2))
 289
 290 (defun notmuch-search-first-thread ()
 291   "Select the first thread in the search results."
 292   (interactive)
 293   (goto-char (point-min)))
 294
 295 (defface notmuch-message-summary-face
 296  '((((class color) (background light)) (:background "#f0f0f0"))
 297    (((class color) (background dark)) (:background "#303030")))
 298  "Face for the single-line message summary in notmuch-show-mode."
 299  :group 'notmuch)
 300
 301 (defface notmuch-search-date
 302   '((t :inherit default))
 303   "Face used in search mode for dates."
 304   :group 'notmuch)
 305
 306 (defface notmuch-search-count
 307   '((t :inherit default))
 308   "Face used in search mode for the count matching the query."
 309   :group 'notmuch)
 310
 311 (defface notmuch-search-subject
 312   '((t :inherit default))
 313   "Face used in search mode for subjects."
 314   :group 'notmuch)
 315
 316 (defface notmuch-search-matching-authors
 317   '((t :inherit default))
 318   "Face used in search mode for authors matching the query."
 319   :group 'notmuch)
 320
 321 (defface notmuch-search-non-matching-authors
 322   '((((class color)
 323       (background dark))
 324      (:foreground "grey30"))
 325     (((class color)
 326       (background light))
 327      (:foreground "grey60"))
 328     (t
 329      (:italic t)))
 330   "Face used in search mode for authors not matching the query."
 331   :group 'notmuch)
 332
 333 (defface notmuch-tag-face
 334   '((((class color)
 335       (background dark))
 336      (:foreground "OliveDrab1"))
 337     (((class color)
 338       (background light))
 339      (:foreground "navy blue" :bold t))
 340     (t
 341      (:bold t)))
 342   "Face used in search mode face for tags."
 343   :group 'notmuch)
 344
 345 (defun notmuch-search-mode ()
 346   "Major mode displaying results of a notmuch search.
 347
 348 This buffer contains the results of a \"notmuch search\" of your
 349 email archives. Each line in the buffer represents a single
 350 thread giving a summary of the thread (a relative date, the
 351 number of matched messages and total messages in the thread,
 352 participants in the thread, a representative subject line, and
 353 any tags).
 354
 355 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 356 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 357 is a convenience for archiving a thread (removing the \"inbox\"
 358 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
 359 threads in the current buffer.
 360
 361 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 362 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 363 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 364 search.
 365
 366 Complete list of currently available key bindings:
 367
 368 \\{notmuch-search-mode-map}"
 369   (interactive)
 370   (kill-all-local-variables)
 371   (make-local-variable 'notmuch-search-query-string)
 372   (make-local-variable 'notmuch-search-oldest-first)
 373   (make-local-variable 'notmuch-search-target-thread)
 374   (make-local-variable 'notmuch-search-target-line)
 375   (set (make-local-variable 'notmuch-search-continuation) nil)
 376   (set (make-local-variable 'scroll-preserve-screen-position) t)
 377   (add-to-invisibility-spec 'notmuch-search)
 378   (use-local-map notmuch-search-mode-map)
 379   (setq truncate-lines t)
 380   (setq major-mode 'notmuch-search-mode
 381         mode-name "notmuch-search")
 382   (setq buffer-read-only t))
 383
 384 (defun notmuch-search-properties-in-region (property beg end)
 385   (save-excursion
 386     (let ((output nil)
 387           (last-line (line-number-at-pos end))
 388           (max-line (- (line-number-at-pos (point-max)) 2)))
 389       (goto-char beg)
 390       (beginning-of-line)
 391       (while (<= (line-number-at-pos) (min last-line max-line))
 392         (setq output (cons (get-text-property (point) property) output))
 393         (forward-line 1))
 394       output)))
 395
 396 (defun notmuch-search-find-thread-id ()
 397   "Return the thread for the current thread"
 398   (get-text-property (point) 'notmuch-search-thread-id))
 399
 400 (defun notmuch-search-find-thread-id-region (beg end)
 401   "Return a list of threads for the current region"
 402   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 403
 404 (defun notmuch-search-find-authors ()
 405   "Return the authors for the current thread"
 406   (get-text-property (point) 'notmuch-search-authors))
 407
 408 (defun notmuch-search-find-authors-region (beg end)
 409   "Return a list of authors for the current region"
 410   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 411
 412 (defun notmuch-search-find-subject ()
 413   "Return the subject for the current thread"
 414   (get-text-property (point) 'notmuch-search-subject))
 415
 416 (defun notmuch-search-find-subject-region (beg end)
 417   "Return a list of authors for the current region"
 418   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 419
 420 (defun notmuch-search-show-thread ()
 421   "Display the currently selected thread."
 422   (interactive)
 423   (let ((thread-id (notmuch-search-find-thread-id))
 424         (subject (notmuch-search-find-subject)))
 425     (if (> (length thread-id) 0)
 426         (notmuch-show thread-id
 427                       (current-buffer)
 428                       notmuch-search-query-string
 429                       ;; name the buffer based on notmuch-search-find-subject
 430                       (if (string-match "^[ \t]*$" subject)
 431                           "[No Subject]"
 432                         (truncate-string-to-width
 433                          (concat "*"
 434                                  (truncate-string-to-width subject 32 nil nil t)
 435                                  "*")
 436                          32 nil nil t)))
 437       (error "End of search results"))))
 438
 439 (defun notmuch-search-reply-to-thread ()
 440   "Begin composing a reply to the entire current thread in a new buffer."
 441   (interactive)
 442   (let ((message-id (notmuch-search-find-thread-id)))
 443     (notmuch-mua-reply message-id)))
 444
 445 (defun notmuch-call-notmuch-process (&rest args)
 446   "Synchronously invoke \"notmuch\" with the given list of arguments.
 447
 448 Output from the process will be presented to the user as an error
 449 and will also appear in a buffer named \"*Notmuch errors*\"."
 450   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 451     (with-current-buffer error-buffer
 452         (erase-buffer))
 453     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 454         (point)
 455       (progn
 456         (with-current-buffer error-buffer
 457           (let ((beg (point-min))
 458                 (end (- (point-max) 1)))
 459             (error (buffer-substring beg end))
 460             ))))))
 461
 462 (defun notmuch-search-set-tags (tags)
 463   (save-excursion
 464     (end-of-line)
 465     (re-search-backward "(")
 466     (forward-char)
 467     (let ((beg (point))
 468           (inhibit-read-only t))
 469       (re-search-forward ")")
 470       (backward-char)
 471       (let ((end (point)))
 472         (delete-region beg end)
 473         (insert (propertize (mapconcat  'identity tags " ")
 474                             'face 'notmuch-tag-face))))))
 475
 476 (defun notmuch-search-get-tags ()
 477   (save-excursion
 478     (end-of-line)
 479     (re-search-backward "(")
 480     (let ((beg (+ (point) 1)))
 481       (re-search-forward ")")
 482       (let ((end (- (point) 1)))
 483         (split-string (buffer-substring beg end))))))
 484
 485 (defun notmuch-search-get-tags-region (beg end)
 486   (save-excursion
 487     (let ((output nil)
 488           (last-line (line-number-at-pos end))
 489           (max-line (- (line-number-at-pos (point-max)) 2)))
 490       (goto-char beg)
 491       (while (<= (line-number-at-pos) (min last-line max-line))
 492         (setq output (append output (notmuch-search-get-tags)))
 493         (forward-line 1))
 494       output)))
 495
 496 (defun notmuch-search-add-tag-thread (tag)
 497   (notmuch-search-add-tag-region tag (point) (point)))
 498
 499 (defun notmuch-search-add-tag-region (tag beg end)
 500   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 501     (notmuch-call-notmuch-process "tag" (concat "+" tag) search-id-string)
 502     (save-excursion
 503       (let ((last-line (line-number-at-pos end))
 504             (max-line (- (line-number-at-pos (point-max)) 2)))
 505         (goto-char beg)
 506         (while (<= (line-number-at-pos) (min last-line max-line))
 507           (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<)))
 508           (forward-line))))))
 509
 510 (defun notmuch-search-remove-tag-thread (tag)
 511   (notmuch-search-remove-tag-region tag (point) (point)))
 512
 513 (defun notmuch-search-remove-tag-region (tag beg end)
 514   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 515     (notmuch-call-notmuch-process "tag" (concat "-" tag) search-id-string)
 516     (save-excursion
 517       (let ((last-line (line-number-at-pos end))
 518             (max-line (- (line-number-at-pos (point-max)) 2)))
 519         (goto-char beg)
 520         (while (<= (line-number-at-pos) (min last-line max-line))
 521           (notmuch-search-set-tags (delete tag (notmuch-search-get-tags)))
 522           (forward-line))))))
 523
 524 (defun notmuch-search-add-tag (tag)
 525   "Add a tag to the currently selected thread or region.
 526
 527 The tag is added to all messages in the currently selected thread
 528 or threads in the current region."
 529   (interactive
 530    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 531   (save-excursion
 532     (if (region-active-p)
 533         (let* ((beg (region-beginning))
 534                (end (region-end)))
 535           (notmuch-search-add-tag-region tag beg end))
 536       (notmuch-search-add-tag-thread tag))))
 537
 538 (defun notmuch-search-remove-tag (tag)
 539   "Remove a tag from the currently selected thread or region.
 540
 541 The tag is removed from all messages in the currently selected
 542 thread or threads in the current region."
 543   (interactive
 544    (list (notmuch-select-tag-with-completion
 545           "Tag to remove: "
 546           (if (region-active-p)
 547               (mapconcat 'identity
 548                          (notmuch-search-find-thread-id-region (region-beginning) (region-end))
 549                          " ")
 550             (notmuch-search-find-thread-id)))))
 551   (save-excursion
 552     (if (region-active-p)
 553         (let* ((beg (region-beginning))
 554                (end (region-end)))
 555           (notmuch-search-remove-tag-region tag beg end))
 556       (notmuch-search-remove-tag-thread tag))))
 557
 558 (defun notmuch-search-archive-thread ()
 559   "Archive the currently selected thread (remove its \"inbox\" tag).
 560
 561 This function advances the next thread when finished."
 562   (interactive)
 563   (notmuch-search-remove-tag-thread "inbox")
 564   (forward-line))
 565
 566 (defun notmuch-search-process-sentinel (proc msg)
 567   "Add a message to let user know when \"notmuch search\" exits"
 568   (let ((buffer (process-buffer proc))
 569         (status (process-status proc))
 570         (exit-status (process-exit-status proc))
 571         (never-found-target-thread nil))
 572     (if (memq status '(exit signal))
 573         (if (buffer-live-p buffer)
 574             (with-current-buffer buffer
 575               (save-excursion
 576                 (let ((inhibit-read-only t)
 577                       (atbob (bobp)))
 578                   (goto-char (point-max))
 579                   (if (eq status 'signal)
 580                       (insert "Incomplete search results (search process was killed).\n"))
 581                   (if (eq status 'exit)
 582                       (progn
 583                         (insert "End of search results.")
 584                         (if (not (= exit-status 0))
 585                             (insert (format " (process returned %d)" exit-status)))
 586                         (insert "\n")
 587                         (if (and atbob
 588                                  (not (string= notmuch-search-target-thread "found")))
 589                             (set 'never-found-target-thread t))))))
 590               (when (and never-found-target-thread
 591                        notmuch-search-target-line)
 592                   (goto-char (point-min))
 593                   (forward-line (1- notmuch-search-target-line))))))))
 594
 595 (defcustom notmuch-search-line-faces nil
 596   "Tag/face mapping for line highlighting in notmuch-search.
 597
 598 Here is an example of how to color search results based on tags.
 599  (the following text would be placed in your ~/.emacs file):
 600
 601  (setq notmuch-search-line-faces '((\"delete\" . '(:foreground \"red\"
 602                                                    :background \"blue\"))
 603                                    (\"unread\" . '(:foreground \"green\"))))
 604
 605 The attributes defined for matching tags are merged, with later
 606 attributes overriding earlier. A message having both \"delete\"
 607 and \"unread\" tags with the above settings would have a green
 608 foreground and blue background."
 609   :type '(alist :key-type (string) :value-type (list))
 610   :group 'notmuch)
 611
 612 (defun notmuch-search-color-line (start end line-tag-list)
 613   "Colorize lines in `notmuch-show' based on tags."
 614   ;; Create the overlay only if the message has tags which match one
 615   ;; of those specified in `notmuch-search-line-faces'.
 616   (let (overlay)
 617     (mapc '(lambda (elem)
 618              (let ((tag (car elem))
 619                    (attributes (cdr elem)))
 620                (when (member tag line-tag-list)
 621                  (when (not overlay)
 622                    (setq overlay (make-overlay start end)))
 623                  ;; Merge the specified properties with any already
 624                  ;; applied from an earlier match.
 625                  (overlay-put overlay 'face
 626                               (append (overlay-get overlay 'face) attributes)))))
 627           notmuch-search-line-faces)))
 628
 629 (defun notmuch-search-isearch-authors-show (overlay)
 630   (remove-from-invisibility-spec (cons (overlay-get overlay 'invisible) t)))
 631
 632 (defun notmuch-search-author-propertize (authors)
 633   "Split `authors' into matching and non-matching authors and
 634 propertize appropriately. If no boundary between authors and
 635 non-authors is found, assume that all of the authors match."
 636   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 637       (concat (propertize (concat (match-string 1 authors) ",")
 638                           'face 'notmuch-search-matching-authors)
 639               (propertize (match-string 2 authors)
 640                           'face 'notmuch-search-non-matching-authors))
 641     (propertize authors 'face 'notmuch-search-matching-authors)))
 642
 643 (defun notmuch-search-insert-authors (format-string authors)
 644   ;; Save the match data to avoid interfering with
 645   ;; `notmuch-search-process-filter'.
 646   (save-match-data
 647     (let* ((formatted-authors (format format-string authors))
 648            (formatted-sample (format format-string ""))
 649            (visible-string formatted-authors)
 650            (invisible-string "")
 651            (padding ""))
 652
 653       ;; Truncate the author string to fit the specification.
 654       (if (> (length formatted-authors)
 655              (length formatted-sample))
 656           (let ((visible-length (- (length formatted-sample)
 657                                    (length "... "))))
 658             ;; Truncate the visible string according to the width of
 659             ;; the display string.
 660             (setq visible-string (substring formatted-authors 0 visible-length)
 661                   invisible-string (substring formatted-authors visible-length))
 662             ;; If possible, truncate the visible string at a natural
 663             ;; break (comma or pipe), as incremental search doesn't
 664             ;; match across the visible/invisible border.
 665             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 666               ;; Second clause is destructive on `visible-string', so
 667               ;; order is important.
 668               (setq invisible-string (concat (match-string 3 visible-string)
 669                                              invisible-string)
 670                     visible-string (concat (match-string 1 visible-string)
 671                                            (match-string 2 visible-string))))
 672             ;; `visible-string' may be shorter than the space allowed
 673             ;; by `format-string'. If so we must insert some padding
 674             ;; after `invisible-string'.
 675             (setq padding (make-string (- (length formatted-sample)
 676                                           (length visible-string)
 677                                           (length "..."))
 678                                        ? ))))
 679
 680       ;; Use different faces to show matching and non-matching authors.
 681       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 682           ;; The visible string contains both matching and
 683           ;; non-matching authors.
 684           (setq visible-string (notmuch-search-author-propertize visible-string)
 685                 ;; The invisible string must contain only non-matching
 686                 ;; authors, as the visible-string contains both.
 687                 invisible-string (propertize invisible-string
 688                                              'face 'notmuch-search-non-matching-authors))
 689         ;; The visible string contains only matching authors.
 690         (setq visible-string (propertize visible-string
 691                                          'face 'notmuch-search-matching-authors)
 692               ;; The invisible string may contain both matching and
 693               ;; non-matching authors.
 694               invisible-string (notmuch-search-author-propertize invisible-string)))
 695
 696       ;; If there is any invisible text, add it as a tooltip to the
 697       ;; visible text.
 698       (when (not (string= invisible-string ""))
 699         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 700
 701       ;; Insert the visible and, if present, invisible author strings.
 702       (insert visible-string)
 703       (when (not (string= invisible-string ""))
 704         (let ((start (point))
 705               (invis-spec (make-symbol "notmuch-search-authors"))
 706               overlay)
 707           (insert invisible-string)
 708           (add-to-invisibility-spec (cons invis-spec t))
 709           (setq overlay (make-overlay start (point)))
 710           (overlay-put overlay 'invisible invis-spec)
 711           (overlay-put overlay 'isearch-open-invisible #'notmuch-search-isearch-authors-show)))
 712       (insert padding))))
 713
 714 (defun notmuch-search-insert-field (field date count authors subject tags)
 715   (cond
 716    ((string-equal field "date")
 717     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) date)
 718                         'face 'notmuch-search-date)))
 719    ((string-equal field "count")
 720     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) count)
 721                         'face 'notmuch-search-count)))
 722    ((string-equal field "subject")
 723     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) subject)
 724                         'face 'notmuch-search-subject)))
 725
 726    ((string-equal field "authors")
 727     (notmuch-search-insert-authors (cdr (assoc field notmuch-search-result-format)) authors))
 728
 729    ((string-equal field "tags")
 730     (insert (concat "(" (propertize tags 'font-lock-face 'notmuch-tag-face) ")")))))
 731
 732 (defun notmuch-search-show-result (date count authors subject tags)
 733   (let ((fields) (field))
 734     (setq fields (mapcar 'car notmuch-search-result-format))
 735     (loop for field in fields
 736           do (notmuch-search-insert-field field date count authors subject tags)))
 737   (insert "\n"))
 738
 739 (defun notmuch-search-process-filter (proc string)
 740   "Process and filter the output of \"notmuch search\""
 741   (let ((buffer (process-buffer proc))
 742         (found-target nil))
 743     (if (buffer-live-p buffer)
 744         (with-current-buffer buffer
 745           (save-excursion
 746             (let ((line 0)
 747                   (more t)
 748                   (inhibit-read-only t))
 749               (while more
 750                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\([^][]*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 751                     (let* ((thread-id (match-string 1 string))
 752                            (date (match-string 2 string))
 753                            (count (match-string 3 string))
 754                            (authors (match-string 4 string))
 755                            (subject (match-string 5 string))
 756                            (tags (match-string 6 string))
 757                            (tag-list (if tags (save-match-data (split-string tags)))))
 758                       (goto-char (point-max))
 759                       (let ((beg (point-marker)))
 760                         (notmuch-search-show-result date count authors subject tags)
 761                         (notmuch-search-color-line beg (point-marker) tag-list)
 762                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id)
 763                         (put-text-property beg (point-marker) 'notmuch-search-authors authors)
 764                         (put-text-property beg (point-marker) 'notmuch-search-subject subject)
 765                         (if (string= thread-id notmuch-search-target-thread)
 766                             (progn
 767                               (set 'found-target beg)
 768                               (set 'notmuch-search-target-thread "found"))))
 769                       (set 'line (match-end 0)))
 770                   (set 'more nil)))))
 771           (if found-target
 772               (goto-char found-target)))
 773       (delete-process proc))))
 774
 775 (defun notmuch-search-operate-all (action)
 776   "Add/remove tags from all matching messages.
 777
 778 Tis command adds or removes tags from all messages matching the
 779 current search terms. When called interactively, this command
 780 will prompt for tags to be added or removed. Tags prefixed with
 781 '+' will be added and tags prefixed with '-' will be removed.
 782
 783 Each character of the tag name may consist of alphanumeric
 784 characters as well as `_.+-'.
 785 "
 786   (interactive "sOperation (+add -drop): notmuch tag ")
 787   (let ((action-split (split-string action " +")))
 788     ;; Perform some validation
 789     (let ((words action-split))
 790       (when (null words) (error "No operation given"))
 791       (while words
 792         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
 793           (error "Action must be of the form `+thistag -that_tag'"))
 794         (setq words (cdr words))))
 795     (apply 'notmuch-call-notmuch-process "tag"
 796            (append action-split (list notmuch-search-query-string) nil))))
 797
 798 (defun notmuch-search-buffer-title (query)
 799   "Returns the title for a buffer with notmuch search results."
 800   (let* ((saved-search
 801           (let (longest
 802                 (longest-length 0))
 803             (loop for tuple in notmuch-saved-searches
 804                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 805                        (and (string-match (concat "^" quoted-query) query)
 806                             (> (length (match-string 0 query))
 807                                longest-length)))
 808                   do (setq longest tuple))
 809             longest))
 810          (saved-search-name (car saved-search))
 811          (saved-search-query (cdr saved-search)))
 812     (cond ((and saved-search (equal saved-search-query query))
 813            ;; Query is the same as saved search (ignoring case)
 814            (concat "*notmuch-saved-search-" saved-search-name "*"))
 815           (saved-search
 816            (concat "*notmuch-search-"
 817                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 818                                              (concat "[ " saved-search-name " ]")
 819                                              query)
 820                    "*"))
 821           (t
 822            (concat "*notmuch-search-" query "*"))
 823           )))
 824
 825 ;;;###autoload
 826 (defun notmuch-search (query &optional oldest-first target-thread target-line continuation)
 827   "Run \"notmuch search\" with the given query string and display results.
 828
 829 The optional parameters are used as follows:
 830
 831   oldest-first: A Boolean controlling the sort order of returned threads
 832   target-thread: A thread ID (with the thread: prefix) that will be made
 833                  current if it appears in the search results.
 834   target-line: The line number to move to if the target thread does not
 835                appear in the search results."
 836   (interactive "sNotmuch search: ")
 837   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 838     (switch-to-buffer buffer)
 839     (notmuch-search-mode)
 840     (set 'notmuch-search-query-string query)
 841     (set 'notmuch-search-oldest-first oldest-first)
 842     (set 'notmuch-search-target-thread target-thread)
 843     (set 'notmuch-search-target-line target-line)
 844     (set 'notmuch-search-continuation continuation)
 845     (let ((proc (get-buffer-process (current-buffer)))
 846           (inhibit-read-only t))
 847       (if proc
 848           (error "notmuch search process already running for query `%s'" query)
 849         )
 850       (erase-buffer)
 851       (goto-char (point-min))
 852       (save-excursion
 853         (let ((proc (start-process
 854                      "notmuch-search" buffer
 855                      notmuch-command "search"
 856                      (if oldest-first
 857                          "--sort=oldest-first"
 858                        "--sort=newest-first")
 859                      query)))
 860           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 861           (set-process-filter proc 'notmuch-search-process-filter))))
 862     (run-hooks 'notmuch-search-hook)))
 863
 864 (defun notmuch-search-refresh-view ()
 865   "Refresh the current view.
 866
 867 Kills the current buffer and runs a new search with the same
 868 query string as the current search. If the current thread is in
 869 the new search results, then point will be placed on the same
 870 thread. Otherwise, point will be moved to attempt to be in the
 871 same relative position within the new buffer."
 872   (interactive)
 873   (let ((target-line (line-number-at-pos))
 874         (oldest-first notmuch-search-oldest-first)
 875         (target-thread (notmuch-search-find-thread-id))
 876         (query notmuch-search-query-string)
 877         (continuation notmuch-search-continuation))
 878     (notmuch-kill-this-buffer)
 879     (notmuch-search query oldest-first target-thread target-line continuation)
 880     (goto-char (point-min))))
 881
 882 (defcustom notmuch-poll-script ""
 883   "An external script to incorporate new mail into the notmuch database.
 884
 885 If this variable is non empty, then it should name a script to be
 886 invoked by `notmuch-search-poll-and-refresh-view' and
 887 `notmuch-hello-poll-and-update' (each have a default keybinding
 888 of 'G'). The script could do any of the following depending on
 889 the user's needs:
 890
 891 1. Invoke a program to transfer mail to the local mail store
 892 2. Invoke \"notmuch new\" to incorporate the new mail
 893 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 894   :type 'string
 895   :group 'notmuch)
 896
 897 (defun notmuch-poll ()
 898   "Run external script to import mail.
 899
 900 Invokes `notmuch-poll-script' if it is not set to an empty string."
 901   (interactive)
 902   (if (not (string= notmuch-poll-script ""))
 903       (call-process notmuch-poll-script nil nil)))
 904
 905 (defun notmuch-search-poll-and-refresh-view ()
 906   "Invoke `notmuch-poll' to import mail, then refresh the current view."
 907   (interactive)
 908   (notmuch-poll)
 909   (notmuch-search-refresh-view))
 910
 911 (defun notmuch-search-toggle-order ()
 912   "Toggle the current search order.
 913
 914 By default, the \"inbox\" view created by `notmuch' is displayed
 915 in chronological order (oldest thread at the beginning of the
 916 buffer), while any global searches created by `notmuch-search'
 917 are displayed in reverse-chronological order (newest thread at
 918 the beginning of the buffer).
 919
 920 This command toggles the sort order for the current search.
 921
 922 Note that any filtered searches created by
 923 `notmuch-search-filter' retain the search order of the parent
 924 search."
 925   (interactive)
 926   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 927   (notmuch-search-refresh-view))
 928
 929 (defun notmuch-search-filter (query)
 930   "Filter the current search results based on an additional query string.
 931
 932 Runs a new search matching only messages that match both the
 933 current search results AND the additional query string provided."
 934   (interactive "sFilter search: ")
 935   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 936                            (concat "( " query " )")
 937                          query)))
 938     (notmuch-search (if (string= notmuch-search-query-string "*")
 939                         grouped-query
 940                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 941
 942 (defun notmuch-search-filter-by-tag (tag)
 943   "Filter the current search results based on a single tag.
 944
 945 Runs a new search matching only messages that match both the
 946 current search results AND that are tagged with the given tag."
 947   (interactive
 948    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 949   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 950
 951 ;;;###autoload
 952 (defun notmuch ()
 953   "Run notmuch and display saved searches, known tags, etc."
 954   (interactive)
 955   (notmuch-hello))
 956
 957 (setq mail-user-agent 'notmuch-user-agent)
 958
 959 (provide 'notmuch)