git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61
  62 (defcustom notmuch-search-result-format
  63   `(("date" . "%12s ")
  64     ("count" . "%-7s ")
  65     ("authors" . "%-20s ")
  66     ("subject" . "%s ")
  67     ("tags" . "(%s)"))
  68   "Search result formatting. Supported fields are:
  69         date, count, authors, subject, tags
  70 For example:
  71         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  72                                              \(\"subject\" . \"%s\"\)\)\)"
  73   :type '(alist :key-type (string) :value-type (string))
  74   :group 'notmuch-search)
  75
  76 (defvar notmuch-query-history nil
  77   "Variable to store minibuffer history for notmuch queries")
  78
  79 (defun notmuch-foreach-mime-part (function mm-handle)
  80   (cond ((stringp (car mm-handle))
  81          (dolist (part (cdr mm-handle))
  82            (notmuch-foreach-mime-part function part)))
  83         ((bufferp (car mm-handle))
  84          (funcall function mm-handle))
  85         (t (dolist (part mm-handle)
  86              (notmuch-foreach-mime-part function part)))))
  87
  88 (defun notmuch-count-attachments (mm-handle)
  89   (let ((count 0))
  90     (notmuch-foreach-mime-part
  91      (lambda (p)
  92        (let ((disposition (mm-handle-disposition p)))
  93          (and (listp disposition)
  94               (or (equal (car disposition) "attachment")
  95                   (and (equal (car disposition) "inline")
  96                        (assq 'filename disposition)))
  97               (incf count))))
  98      mm-handle)
  99     count))
 100
 101 (defun notmuch-save-attachments (mm-handle &optional queryp)
 102   (notmuch-foreach-mime-part
 103    (lambda (p)
 104      (let ((disposition (mm-handle-disposition p)))
 105        (and (listp disposition)
 106             (or (equal (car disposition) "attachment")
 107                 (and (equal (car disposition) "inline")
 108                      (assq 'filename disposition)))
 109             (or (not queryp)
 110                 (y-or-n-p
 111                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 112             (mm-save-part p))))
 113    mm-handle))
 114
 115 (defun notmuch-documentation-first-line (symbol)
 116   "Return the first line of the documentation string for SYMBOL."
 117   (let ((doc (documentation symbol)))
 118     (if doc
 119         (with-temp-buffer
 120           (insert (documentation symbol t))
 121           (goto-char (point-min))
 122           (let ((beg (point)))
 123             (end-of-line)
 124             (buffer-substring beg (point))))
 125       "")))
 126
 127 (defun notmuch-prefix-key-description (key)
 128   "Given a prefix key code, return a human-readable string representation.
 129
 130 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 131   (let ((desc (format-kbd-macro (vector key))))
 132     (if (string= desc "ESC")
 133         "M-"
 134       (concat desc " "))))
 135
 136 ;; I would think that emacs would have code handy for walking a keymap
 137 ;; and generating strings for each key, and I would prefer to just call
 138 ;; that. But I couldn't find any (could be all implemented in C I
 139 ;; suppose), so I wrote my own here.
 140 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 141   "For a key binding, return a string showing a human-readable
 142 representation of the prefixed key as well as the first line of
 143 documentation from the bound function.
 144
 145 For a mouse binding, return nil."
 146   (let ((key (car binding))
 147         (action (cdr binding)))
 148     (if (mouse-event-p key)
 149         nil
 150       (if (keymapp action)
 151           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 152                 (as-list))
 153             (map-keymap (lambda (a b)
 154                           (push (cons a b) as-list))
 155                         action)
 156             (mapconcat substitute as-list "\n"))
 157         (concat prefix (format-kbd-macro (vector key))
 158                 "\t"
 159                 (notmuch-documentation-first-line action))))))
 160
 161 (defun notmuch-substitute-command-keys-one (key)
 162   ;; A `keymap' key indicates inheritance from a parent keymap - the
 163   ;; inherited mappings follow, so there is nothing to print for
 164   ;; `keymap' itself.
 165   (when (not (eq key 'keymap))
 166     (notmuch-substitute-one-command-key-with-prefix nil key)))
 167
 168 (defun notmuch-substitute-command-keys (doc)
 169   "Like `substitute-command-keys' but with documentation, not function names."
 170   (let ((beg 0))
 171     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 172       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 173              (keymap (symbol-value (intern keymap-name))))
 174         (setq doc (replace-match
 175                    (mapconcat #'notmuch-substitute-command-keys-one
 176                               (cdr keymap) "\n")
 177                    1 1 doc)))
 178       (setq beg (match-end 0)))
 179     doc))
 180
 181 (defun notmuch-help ()
 182   "Display help for the current notmuch mode."
 183   (interactive)
 184   (let* ((mode major-mode)
 185          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 186     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 187       (insert doc)
 188       (goto-char (point-min))
 189       (set-buffer-modified-p nil)
 190       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 191
 192 (require 'hl-line)
 193
 194 (defun notmuch-hl-line-mode ()
 195   (prog1 (hl-line-mode)
 196     (when hl-line-overlay
 197       (overlay-put hl-line-overlay 'priority 1))))
 198
 199 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 200   "List of functions to call when notmuch displays the search results."
 201   :type 'hook
 202   :options '(notmuch-hl-line-mode)
 203   :group 'notmuch-search
 204   :group 'notmuch-hooks)
 205
 206 (defvar notmuch-search-mode-map
 207   (let ((map (make-sparse-keymap)))
 208     (define-key map "?" 'notmuch-help)
 209     (define-key map "q" 'notmuch-search-quit)
 210     (define-key map "x" 'notmuch-search-quit)
 211     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 212     (define-key map "b" 'notmuch-search-scroll-down)
 213     (define-key map " " 'notmuch-search-scroll-up)
 214     (define-key map "<" 'notmuch-search-first-thread)
 215     (define-key map ">" 'notmuch-search-last-thread)
 216     (define-key map "p" 'notmuch-search-previous-thread)
 217     (define-key map "n" 'notmuch-search-next-thread)
 218     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 219     (define-key map "R" 'notmuch-search-reply-to-thread)
 220     (define-key map "m" 'notmuch-mua-new-mail)
 221     (define-key map "s" 'notmuch-search)
 222     (define-key map "o" 'notmuch-search-toggle-order)
 223     (define-key map "c" 'notmuch-search-stash-map)
 224     (define-key map "=" 'notmuch-search-refresh-view)
 225     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 226     (define-key map "t" 'notmuch-search-filter-by-tag)
 227     (define-key map "f" 'notmuch-search-filter)
 228     (define-key map [mouse-1] 'notmuch-search-show-thread)
 229     (define-key map "*" 'notmuch-search-tag-all)
 230     (define-key map "a" 'notmuch-search-archive-thread)
 231     (define-key map "-" 'notmuch-search-remove-tag)
 232     (define-key map "+" 'notmuch-search-add-tag)
 233     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 234     map)
 235   "Keymap for \"notmuch search\" buffers.")
 236 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 237
 238 (defvar notmuch-search-stash-map
 239   (let ((map (make-sparse-keymap)))
 240     (define-key map "i" 'notmuch-search-stash-thread-id)
 241     map)
 242   "Submap for stash commands")
 243 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 244
 245 (defun notmuch-search-stash-thread-id ()
 246   "Copy thread ID of current thread to kill-ring."
 247   (interactive)
 248   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 249
 250 (defvar notmuch-search-query-string)
 251 (defvar notmuch-search-target-thread)
 252 (defvar notmuch-search-target-line)
 253 (defvar notmuch-search-continuation)
 254
 255 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 256
 257 (defun notmuch-search-quit ()
 258   "Exit the search buffer, calling any defined continuation function."
 259   (interactive)
 260   (let ((continuation notmuch-search-continuation))
 261     (notmuch-kill-this-buffer)
 262     (when continuation
 263       (funcall continuation))))
 264
 265 (defun notmuch-search-scroll-up ()
 266   "Move forward through search results by one window's worth."
 267   (interactive)
 268   (condition-case nil
 269       (scroll-up nil)
 270     ((end-of-buffer) (notmuch-search-last-thread))))
 271
 272 (defun notmuch-search-scroll-down ()
 273   "Move backward through the search results by one window's worth."
 274   (interactive)
 275   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 276   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 277   ;;
 278   ;; So instead of trapping a signal we instead check whether the
 279   ;; window begins on the first line of the buffer and if so, move
 280   ;; directly to that position. (We have to count lines since the
 281   ;; window-start position is not the same as point-min due to the
 282   ;; invisible thread-ID characters on the first line.
 283   (if (equal (count-lines (point-min) (window-start)) 0)
 284       (goto-char (point-min))
 285     (scroll-down nil)))
 286
 287 (defun notmuch-search-next-thread ()
 288   "Select the next thread in the search results."
 289   (interactive)
 290   (forward-line 1))
 291
 292 (defun notmuch-search-previous-thread ()
 293   "Select the previous thread in the search results."
 294   (interactive)
 295   (forward-line -1))
 296
 297 (defun notmuch-search-last-thread ()
 298   "Select the last thread in the search results."
 299   (interactive)
 300   (goto-char (point-max))
 301   (forward-line -2))
 302
 303 (defun notmuch-search-first-thread ()
 304   "Select the first thread in the search results."
 305   (interactive)
 306   (goto-char (point-min)))
 307
 308 (defface notmuch-message-summary-face
 309  '((((class color) (background light)) (:background "#f0f0f0"))
 310    (((class color) (background dark)) (:background "#303030")))
 311  "Face for the single-line message summary in notmuch-show-mode."
 312  :group 'notmuch-show
 313  :group 'notmuch-faces)
 314
 315 (defface notmuch-search-date
 316   '((t :inherit default))
 317   "Face used in search mode for dates."
 318   :group 'notmuch-search
 319   :group 'notmuch-faces)
 320
 321 (defface notmuch-search-count
 322   '((t :inherit default))
 323   "Face used in search mode for the count matching the query."
 324   :group 'notmuch-search
 325   :group 'notmuch-faces)
 326
 327 (defface notmuch-search-subject
 328   '((t :inherit default))
 329   "Face used in search mode for subjects."
 330   :group 'notmuch-search
 331   :group 'notmuch-faces)
 332
 333 (defface notmuch-search-matching-authors
 334   '((t :inherit default))
 335   "Face used in search mode for authors matching the query."
 336   :group 'notmuch-search
 337   :group 'notmuch-faces)
 338
 339 (defface notmuch-search-non-matching-authors
 340   '((((class color)
 341       (background dark))
 342      (:foreground "grey30"))
 343     (((class color)
 344       (background light))
 345      (:foreground "grey60"))
 346     (t
 347      (:italic t)))
 348   "Face used in search mode for authors not matching the query."
 349   :group 'notmuch-search
 350   :group 'notmuch-faces)
 351
 352 (defface notmuch-tag-face
 353   '((((class color)
 354       (background dark))
 355      (:foreground "OliveDrab1"))
 356     (((class color)
 357       (background light))
 358      (:foreground "navy blue" :bold t))
 359     (t
 360      (:bold t)))
 361   "Face used in search mode face for tags."
 362   :group 'notmuch-search
 363   :group 'notmuch-faces)
 364
 365 (defun notmuch-search-mode ()
 366   "Major mode displaying results of a notmuch search.
 367
 368 This buffer contains the results of a \"notmuch search\" of your
 369 email archives. Each line in the buffer represents a single
 370 thread giving a summary of the thread (a relative date, the
 371 number of matched messages and total messages in the thread,
 372 participants in the thread, a representative subject line, and
 373 any tags).
 374
 375 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 376 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 377 is a convenience for archiving a thread (removing the \"inbox\"
 378 tag). The '\\[notmuch-search-tag-all]' key can be used to add or remove a tag from all
 379 threads in the current buffer.
 380
 381 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 382 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 383 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 384 search.
 385
 386 Complete list of currently available key bindings:
 387
 388 \\{notmuch-search-mode-map}"
 389   (interactive)
 390   (kill-all-local-variables)
 391   (make-local-variable 'notmuch-search-query-string)
 392   (make-local-variable 'notmuch-search-oldest-first)
 393   (make-local-variable 'notmuch-search-target-thread)
 394   (make-local-variable 'notmuch-search-target-line)
 395   (set (make-local-variable 'notmuch-search-continuation) nil)
 396   (set (make-local-variable 'scroll-preserve-screen-position) t)
 397   (add-to-invisibility-spec (cons 'ellipsis t))
 398   (use-local-map notmuch-search-mode-map)
 399   (setq truncate-lines t)
 400   (setq major-mode 'notmuch-search-mode
 401         mode-name "notmuch-search")
 402   (setq buffer-read-only t))
 403
 404 (defun notmuch-search-get-result (&optional pos)
 405   "Return the result object for the thread at POS (or point).
 406
 407 If there is no thread at POS (or point), returns nil."
 408   (get-text-property (or pos (point)) 'notmuch-search-result))
 409
 410 (defun notmuch-search-result-beginning (&optional pos)
 411   "Return the point at the beginning of the thread at POS (or point).
 412
 413 If there is no thread at POS (or point), returns nil."
 414   (when (notmuch-search-get-result pos)
 415     ;; We pass 1+point because previous-single-property-change starts
 416     ;; searching one before the position we give it.
 417     (previous-single-property-change (1+ (or pos (point)))
 418                                      'notmuch-search-result nil (point-min))))
 419
 420 (defun notmuch-search-result-end (&optional pos)
 421   "Return the point at the end of the thread at POS (or point).
 422
 423 The returned point will be just after the newline character that
 424 ends the result line.  If there is no thread at POS (or point),
 425 returns nil"
 426   (when (notmuch-search-get-result pos)
 427     (next-single-property-change (or pos (point)) 'notmuch-search-result
 428                                  nil (point-max))))
 429
 430 (defun notmuch-search-properties-in-region (property beg end)
 431   (save-excursion
 432     (let ((output nil)
 433           (last-line (line-number-at-pos end))
 434           (max-line (- (line-number-at-pos (point-max)) 2)))
 435       (goto-char beg)
 436       (beginning-of-line)
 437       (while (<= (line-number-at-pos) (min last-line max-line))
 438         (setq output (cons (get-text-property (point) property) output))
 439         (forward-line 1))
 440       output)))
 441
 442 (defun notmuch-search-find-thread-id ()
 443   "Return the thread for the current thread"
 444   (get-text-property (point) 'notmuch-search-thread-id))
 445
 446 (defun notmuch-search-find-thread-id-region (beg end)
 447   "Return a list of threads for the current region"
 448   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 449
 450 (defun notmuch-search-find-thread-id-region-search (beg end)
 451   "Return a search string for threads for the current region"
 452   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 453
 454 (defun notmuch-search-find-authors ()
 455   "Return the authors for the current thread"
 456   (get-text-property (point) 'notmuch-search-authors))
 457
 458 (defun notmuch-search-find-authors-region (beg end)
 459   "Return a list of authors for the current region"
 460   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 461
 462 (defun notmuch-search-find-subject ()
 463   "Return the subject for the current thread"
 464   (get-text-property (point) 'notmuch-search-subject))
 465
 466 (defun notmuch-search-find-subject-region (beg end)
 467   "Return a list of authors for the current region"
 468   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 469
 470 (defun notmuch-search-show-thread ()
 471   "Display the currently selected thread."
 472   (interactive)
 473   (let ((thread-id (notmuch-search-find-thread-id))
 474         (subject (notmuch-search-find-subject)))
 475     (if (> (length thread-id) 0)
 476         (notmuch-show thread-id
 477                       (current-buffer)
 478                       notmuch-search-query-string
 479                       ;; Name the buffer based on the subject.
 480                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 481       (message "End of search results."))))
 482
 483 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 484   "Begin composing a reply-all to the entire current thread in a new buffer."
 485   (interactive "P")
 486   (let ((message-id (notmuch-search-find-thread-id)))
 487     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 488
 489 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 490   "Begin composing a reply to the entire current thread in a new buffer."
 491   (interactive "P")
 492   (let ((message-id (notmuch-search-find-thread-id)))
 493     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 494
 495 (defun notmuch-call-notmuch-process (&rest args)
 496   "Synchronously invoke \"notmuch\" with the given list of arguments.
 497
 498 Output from the process will be presented to the user as an error
 499 and will also appear in a buffer named \"*Notmuch errors*\"."
 500   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 501     (with-current-buffer error-buffer
 502         (erase-buffer))
 503     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 504         (point)
 505       (progn
 506         (with-current-buffer error-buffer
 507           (let ((beg (point-min))
 508                 (end (- (point-max) 1)))
 509             (error (buffer-substring beg end))
 510             ))))))
 511
 512 (defun notmuch-search-set-tags (tags)
 513   (save-excursion
 514     (end-of-line)
 515     (re-search-backward "(")
 516     (forward-char)
 517     (let ((beg (point))
 518           (inhibit-read-only t))
 519       (re-search-forward ")")
 520       (backward-char)
 521       (let ((end (point)))
 522         (delete-region beg end)
 523         (insert (propertize (mapconcat  'identity tags " ")
 524                             'face 'notmuch-tag-face))))))
 525
 526 (defun notmuch-search-get-tags ()
 527   (save-excursion
 528     (end-of-line)
 529     (re-search-backward "(")
 530     (let ((beg (+ (point) 1)))
 531       (re-search-forward ")")
 532       (let ((end (- (point) 1)))
 533         (split-string (buffer-substring-no-properties beg end))))))
 534
 535 (defun notmuch-search-get-tags-region (beg end)
 536   (save-excursion
 537     (let ((output nil)
 538           (last-line (line-number-at-pos end))
 539           (max-line (- (line-number-at-pos (point-max)) 2)))
 540       (goto-char beg)
 541       (while (<= (line-number-at-pos) (min last-line max-line))
 542         (setq output (append output (notmuch-search-get-tags)))
 543         (forward-line 1))
 544       output)))
 545
 546 (defun notmuch-search-tag-region (beg end &optional tag-changes)
 547   "Change tags for threads in the given region."
 548   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 549     (setq tag-changes (funcall 'notmuch-tag search-string tag-changes))
 550     (save-excursion
 551       (let ((last-line (line-number-at-pos end))
 552             (max-line (- (line-number-at-pos (point-max)) 2)))
 553         (goto-char beg)
 554         (while (<= (line-number-at-pos) (min last-line max-line))
 555           (notmuch-search-set-tags
 556            (notmuch-update-tags (notmuch-search-get-tags) tag-changes))
 557           (forward-line))))))
 558
 559 (defun notmuch-search-tag (&optional tag-changes)
 560   "Change tags for the currently selected thread or region.
 561
 562 See `notmuch-tag' for information on the format of TAG-CHANGES."
 563   (interactive)
 564   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 565          (end (if (region-active-p) (region-end) (point))))
 566     (funcall 'notmuch-search-tag-region beg end tag-changes)))
 567
 568 (defun notmuch-search-add-tag ()
 569   "Same as `notmuch-search-tag' but sets initial input to '+'."
 570   (interactive)
 571   (notmuch-search-tag "+"))
 572
 573 (defun notmuch-search-remove-tag ()
 574   "Same as `notmuch-search-tag' but sets initial input to '-'."
 575   (interactive)
 576   (notmuch-search-tag "-"))
 577
 578 (defun notmuch-search-archive-thread ()
 579   "Archive the currently selected thread (remove its \"inbox\" tag).
 580
 581 This function advances the next thread when finished."
 582   (interactive)
 583   (notmuch-search-tag '("-inbox"))
 584   (notmuch-search-next-thread))
 585
 586 (defun notmuch-search-process-sentinel (proc msg)
 587   "Add a message to let user know when \"notmuch search\" exits"
 588   (let ((buffer (process-buffer proc))
 589         (status (process-status proc))
 590         (exit-status (process-exit-status proc))
 591         (never-found-target-thread nil))
 592     (when (memq status '(exit signal))
 593         (kill-buffer (process-get proc 'parse-buf))
 594         (if (buffer-live-p buffer)
 595             (with-current-buffer buffer
 596               (save-excursion
 597                 (let ((inhibit-read-only t)
 598                       (atbob (bobp)))
 599                   (goto-char (point-max))
 600                   (if (eq status 'signal)
 601                       (insert "Incomplete search results (search process was killed).\n"))
 602                   (when (eq status 'exit)
 603                     (insert "End of search results.")
 604                     (unless (= exit-status 0)
 605                       (insert (format " (process returned %d)" exit-status)))
 606                     (insert "\n")
 607                     (if (and atbob
 608                              (not (string= notmuch-search-target-thread "found")))
 609                         (set 'never-found-target-thread t)))))
 610               (when (and never-found-target-thread
 611                        notmuch-search-target-line)
 612                   (goto-char (point-min))
 613                   (forward-line (1- notmuch-search-target-line))))))))
 614
 615 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 616                                        ("flagged" :foreground "blue"))
 617   "Tag/face mapping for line highlighting in notmuch-search.
 618
 619 Here is an example of how to color search results based on tags.
 620  (the following text would be placed in your ~/.emacs file):
 621
 622  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 623                                                   :background \"blue\"))
 624                                    (\"unread\" . (:foreground \"green\"))))
 625
 626 The attributes defined for matching tags are merged, with later
 627 attributes overriding earlier. A message having both \"deleted\"
 628 and \"unread\" tags with the above settings would have a green
 629 foreground and blue background."
 630   :type '(alist :key-type (string) :value-type (custom-face-edit))
 631   :group 'notmuch-search
 632   :group 'notmuch-faces)
 633
 634 (defun notmuch-search-color-line (start end line-tag-list)
 635   "Colorize lines in `notmuch-show' based on tags."
 636   (mapc (lambda (elem)
 637           (let ((tag (car elem))
 638                 (attributes (cdr elem)))
 639             (when (member tag line-tag-list)
 640               (notmuch-combine-face-text-property start end attributes))))
 641         ;; Reverse the list so earlier entries take precedence
 642         (reverse notmuch-search-line-faces)))
 643
 644 (defun notmuch-search-author-propertize (authors)
 645   "Split `authors' into matching and non-matching authors and
 646 propertize appropriately. If no boundary between authors and
 647 non-authors is found, assume that all of the authors match."
 648   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 649       (concat (propertize (concat (match-string 1 authors) ",")
 650                           'face 'notmuch-search-matching-authors)
 651               (propertize (match-string 2 authors)
 652                           'face 'notmuch-search-non-matching-authors))
 653     (propertize authors 'face 'notmuch-search-matching-authors)))
 654
 655 (defun notmuch-search-insert-authors (format-string authors)
 656   ;; Save the match data to avoid interfering with
 657   ;; `notmuch-search-process-filter'.
 658   (save-match-data
 659     (let* ((formatted-authors (format format-string authors))
 660            (formatted-sample (format format-string ""))
 661            (visible-string formatted-authors)
 662            (invisible-string "")
 663            (padding ""))
 664
 665       ;; Truncate the author string to fit the specification.
 666       (if (> (length formatted-authors)
 667              (length formatted-sample))
 668           (let ((visible-length (- (length formatted-sample)
 669                                    (length "... "))))
 670             ;; Truncate the visible string according to the width of
 671             ;; the display string.
 672             (setq visible-string (substring formatted-authors 0 visible-length)
 673                   invisible-string (substring formatted-authors visible-length))
 674             ;; If possible, truncate the visible string at a natural
 675             ;; break (comma or pipe), as incremental search doesn't
 676             ;; match across the visible/invisible border.
 677             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 678               ;; Second clause is destructive on `visible-string', so
 679               ;; order is important.
 680               (setq invisible-string (concat (match-string 3 visible-string)
 681                                              invisible-string)
 682                     visible-string (concat (match-string 1 visible-string)
 683                                            (match-string 2 visible-string))))
 684             ;; `visible-string' may be shorter than the space allowed
 685             ;; by `format-string'. If so we must insert some padding
 686             ;; after `invisible-string'.
 687             (setq padding (make-string (- (length formatted-sample)
 688                                           (length visible-string)
 689                                           (length "..."))
 690                                        ? ))))
 691
 692       ;; Use different faces to show matching and non-matching authors.
 693       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 694           ;; The visible string contains both matching and
 695           ;; non-matching authors.
 696           (setq visible-string (notmuch-search-author-propertize visible-string)
 697                 ;; The invisible string must contain only non-matching
 698                 ;; authors, as the visible-string contains both.
 699                 invisible-string (propertize invisible-string
 700                                              'face 'notmuch-search-non-matching-authors))
 701         ;; The visible string contains only matching authors.
 702         (setq visible-string (propertize visible-string
 703                                          'face 'notmuch-search-matching-authors)
 704               ;; The invisible string may contain both matching and
 705               ;; non-matching authors.
 706               invisible-string (notmuch-search-author-propertize invisible-string)))
 707
 708       ;; If there is any invisible text, add it as a tooltip to the
 709       ;; visible text.
 710       (when (not (string= invisible-string ""))
 711         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 712
 713       ;; Insert the visible and, if present, invisible author strings.
 714       (insert visible-string)
 715       (when (not (string= invisible-string ""))
 716         (let ((start (point))
 717               overlay)
 718           (insert invisible-string)
 719           (setq overlay (make-overlay start (point)))
 720           (overlay-put overlay 'invisible 'ellipsis)
 721           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 722       (insert padding))))
 723
 724 (defun notmuch-search-insert-field (field format-string result)
 725   (cond
 726    ((string-equal field "date")
 727     (insert (propertize (format format-string (plist-get result :date_relative))
 728                         'face 'notmuch-search-date)))
 729    ((string-equal field "count")
 730     (insert (propertize (format format-string
 731                                 (format "[%s/%s]" (plist-get result :matched)
 732                                         (plist-get result :total)))
 733                         'face 'notmuch-search-count)))
 734    ((string-equal field "subject")
 735     (insert (propertize (format format-string (plist-get result :subject))
 736                         'face 'notmuch-search-subject)))
 737
 738    ((string-equal field "authors")
 739     (notmuch-search-insert-authors format-string (plist-get result :authors)))
 740
 741    ((string-equal field "tags")
 742     ;; Ignore format-string here because notmuch-search-set-tags
 743     ;; depends on the format of this
 744     (insert (concat "(" (propertize
 745                          (mapconcat 'identity (plist-get result :tags) " ")
 746                          'font-lock-face 'notmuch-tag-face) ")")))))
 747
 748 (defun notmuch-search-show-result (result)
 749   ;; Ignore excluded matches
 750   (unless (= (plist-get result :matched) 0)
 751     (let ((beg (point-max)))
 752       (save-excursion
 753         (goto-char beg)
 754         (dolist (spec notmuch-search-result-format)
 755           (notmuch-search-insert-field (car spec) (cdr spec) result))
 756         (insert "\n")
 757         (notmuch-search-color-line beg (point) (plist-get result :tags))
 758         (put-text-property beg (point) 'notmuch-search-result result)
 759         (put-text-property beg (point) 'notmuch-search-thread-id
 760                            (concat "thread:" (plist-get result :thread)))
 761         (put-text-property beg (point) 'notmuch-search-authors
 762                            (plist-get result :authors))
 763         (put-text-property beg (point) 'notmuch-search-subject
 764                            (plist-get result :subject)))
 765       (when (string= (plist-get result :thread) notmuch-search-target-thread)
 766         (setq notmuch-search-target-thread "found")
 767         (goto-char beg)))))
 768
 769 (defun notmuch-search-show-error (string &rest objects)
 770   (save-excursion
 771     (goto-char (point-max))
 772     (insert "Error: Unexpected output from notmuch search:\n")
 773     (insert (apply #'format string objects))
 774     (insert "\n")))
 775
 776 (defvar notmuch-search-process-state nil
 777   "Parsing state of the search process filter.")
 778
 779 (defvar notmuch-search-json-parser nil
 780   "Incremental JSON parser for the search process filter.")
 781
 782 (defun notmuch-search-process-filter (proc string)
 783   "Process and filter the output of \"notmuch search\""
 784   (let ((results-buf (process-buffer proc))
 785         (parse-buf (process-get proc 'parse-buf))
 786         (inhibit-read-only t)
 787         done)
 788     (if (not (buffer-live-p results-buf))
 789         (delete-process proc)
 790       (with-current-buffer parse-buf
 791         ;; Insert new data
 792         (save-excursion
 793           (goto-char (point-max))
 794           (insert string)))
 795       (with-current-buffer results-buf
 796         (while (not done)
 797           (condition-case nil
 798               (case notmuch-search-process-state
 799                 ((begin)
 800                  ;; Enter the results list
 801                  (if (eq (notmuch-json-begin-compound
 802                           notmuch-search-json-parser) 'retry)
 803                      (setq done t)
 804                    (setq notmuch-search-process-state 'result)))
 805                 ((result)
 806                  ;; Parse a result
 807                  (let ((result (notmuch-json-read notmuch-search-json-parser)))
 808                    (case result
 809                      ((retry) (setq done t))
 810                      ((end) (setq notmuch-search-process-state 'end))
 811                      (otherwise (notmuch-search-show-result result)))))
 812                 ((end)
 813                  ;; Any trailing data is unexpected
 814                  (notmuch-json-eof notmuch-search-json-parser)
 815                  (setq done t)))
 816             (json-error
 817              ;; Do our best to resynchronize and ensure forward
 818              ;; progress
 819              (notmuch-search-show-error
 820               "%s"
 821               (with-current-buffer parse-buf
 822                 (let ((bad (buffer-substring (line-beginning-position)
 823                                              (line-end-position))))
 824                   (forward-line)
 825                   bad))))))
 826         ;; Clear out what we've parsed
 827         (with-current-buffer parse-buf
 828           (delete-region (point-min) (point)))))))
 829
 830 (defun notmuch-search-tag-all (&optional tag-changes)
 831   "Add/remove tags from all messages in current search buffer.
 832
 833 See `notmuch-tag' for information on the format of TAG-CHANGES."
 834   (interactive)
 835   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
 836
 837 (defun notmuch-search-buffer-title (query)
 838   "Returns the title for a buffer with notmuch search results."
 839   (let* ((saved-search
 840           (let (longest
 841                 (longest-length 0))
 842             (loop for tuple in notmuch-saved-searches
 843                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 844                        (and (string-match (concat "^" quoted-query) query)
 845                             (> (length (match-string 0 query))
 846                                longest-length)))
 847                   do (setq longest tuple))
 848             longest))
 849          (saved-search-name (car saved-search))
 850          (saved-search-query (cdr saved-search)))
 851     (cond ((and saved-search (equal saved-search-query query))
 852            ;; Query is the same as saved search (ignoring case)
 853            (concat "*notmuch-saved-search-" saved-search-name "*"))
 854           (saved-search
 855            (concat "*notmuch-search-"
 856                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 857                                              (concat "[ " saved-search-name " ]")
 858                                              query)
 859                    "*"))
 860           (t
 861            (concat "*notmuch-search-" query "*"))
 862           )))
 863
 864 (defun notmuch-read-query (prompt)
 865   "Read a notmuch-query from the minibuffer with completion.
 866
 867 PROMPT is the string to prompt with."
 868   (lexical-let
 869       ((completions
 870         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 871                       "subject:" "attachment:")
 872                 (mapcar (lambda (tag)
 873                           (concat "tag:" tag))
 874                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 875     (let ((keymap (copy-keymap minibuffer-local-map))
 876           (minibuffer-completion-table
 877            (completion-table-dynamic
 878             (lambda (string)
 879               ;; generate a list of possible completions for the current input
 880               (cond
 881                ;; this ugly regexp is used to get the last word of the input
 882                ;; possibly preceded by a '('
 883                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 884                 (mapcar (lambda (compl)
 885                           (concat (match-string-no-properties 1 string) compl))
 886                         (all-completions (match-string-no-properties 2 string)
 887                                          completions)))
 888                (t (list string)))))))
 889       ;; this was simpler than convincing completing-read to accept spaces:
 890       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 891       (let ((history-delete-duplicates t))
 892         (read-from-minibuffer prompt nil keymap nil
 893                               'notmuch-search-history nil nil)))))
 894
 895 ;;;###autoload
 896 (defun notmuch-search (&optional query oldest-first target-thread target-line continuation)
 897   "Run \"notmuch search\" with the given `query' and display results.
 898
 899 If `query' is nil, it is read interactively from the minibuffer.
 900 Other optional parameters are used as follows:
 901
 902   oldest-first: A Boolean controlling the sort order of returned threads
 903   target-thread: A thread ID (with the thread: prefix) that will be made
 904                  current if it appears in the search results.
 905   target-line: The line number to move to if the target thread does not
 906                appear in the search results."
 907   (interactive)
 908   (if (null query)
 909       (setq query (notmuch-read-query "Notmuch search: ")))
 910   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 911     (switch-to-buffer buffer)
 912     (notmuch-search-mode)
 913     ;; Don't track undo information for this buffer
 914     (set 'buffer-undo-list t)
 915     (set 'notmuch-search-query-string query)
 916     (set 'notmuch-search-oldest-first oldest-first)
 917     (set 'notmuch-search-target-thread target-thread)
 918     (set 'notmuch-search-target-line target-line)
 919     (set 'notmuch-search-continuation continuation)
 920     (let ((proc (get-buffer-process (current-buffer)))
 921           (inhibit-read-only t))
 922       (if proc
 923           (error "notmuch search process already running for query `%s'" query)
 924         )
 925       (erase-buffer)
 926       (goto-char (point-min))
 927       (save-excursion
 928         (let ((proc (start-process
 929                      "notmuch-search" buffer
 930                      notmuch-command "search"
 931                      "--format=json"
 932                      (if oldest-first
 933                          "--sort=oldest-first"
 934                        "--sort=newest-first")
 935                      query))
 936               ;; Use a scratch buffer to accumulate partial output.
 937               ;; This buffer will be killed by the sentinel, which
 938               ;; should be called no matter how the process dies.
 939               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 940           (set (make-local-variable 'notmuch-search-process-state) 'begin)
 941           (set (make-local-variable 'notmuch-search-json-parser)
 942                (notmuch-json-create-parser parse-buf))
 943           (process-put proc 'parse-buf parse-buf)
 944           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 945           (set-process-filter proc 'notmuch-search-process-filter)
 946           (set-process-query-on-exit-flag proc nil))))
 947     (run-hooks 'notmuch-search-hook)))
 948
 949 (defun notmuch-search-refresh-view ()
 950   "Refresh the current view.
 951
 952 Kills the current buffer and runs a new search with the same
 953 query string as the current search. If the current thread is in
 954 the new search results, then point will be placed on the same
 955 thread. Otherwise, point will be moved to attempt to be in the
 956 same relative position within the new buffer."
 957   (interactive)
 958   (let ((target-line (line-number-at-pos))
 959         (oldest-first notmuch-search-oldest-first)
 960         (target-thread (notmuch-search-find-thread-id))
 961         (query notmuch-search-query-string)
 962         (continuation notmuch-search-continuation))
 963     (notmuch-kill-this-buffer)
 964     (notmuch-search query oldest-first target-thread target-line continuation)
 965     (goto-char (point-min))))
 966
 967 (defcustom notmuch-poll-script nil
 968   "An external script to incorporate new mail into the notmuch database.
 969
 970 This variable controls the action invoked by
 971 `notmuch-search-poll-and-refresh-view' and
 972 `notmuch-hello-poll-and-update' (each have a default keybinding
 973 of 'G') to incorporate new mail into the notmuch database.
 974
 975 If set to nil (the default), new mail is processed by invoking
 976 \"notmuch new\". Otherwise, this should be set to a string that
 977 gives the name of an external script that processes new mail. If
 978 set to the empty string, no command will be run.
 979
 980 The external script could do any of the following depending on
 981 the user's needs:
 982
 983 1. Invoke a program to transfer mail to the local mail store
 984 2. Invoke \"notmuch new\" to incorporate the new mail
 985 3. Invoke one or more \"notmuch tag\" commands to classify the mail
 986
 987 Note that the recommended way of achieving the same is using
 988 \"notmuch new\" hooks."
 989   :type '(choice (const :tag "notmuch new" nil)
 990                  (const :tag "Disabled" "")
 991                  (string :tag "Custom script"))
 992   :group 'notmuch-external)
 993
 994 (defun notmuch-poll ()
 995   "Run \"notmuch new\" or an external script to import mail.
 996
 997 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 998 depending on the value of `notmuch-poll-script'."
 999   (interactive)
1000   (if (stringp notmuch-poll-script)
1001       (unless (string= notmuch-poll-script "")
1002         (call-process notmuch-poll-script nil nil))
1003     (call-process notmuch-command nil nil nil "new")))
1004
1005 (defun notmuch-search-poll-and-refresh-view ()
1006   "Invoke `notmuch-poll' to import mail, then refresh the current view."
1007   (interactive)
1008   (notmuch-poll)
1009   (notmuch-search-refresh-view))
1010
1011 (defun notmuch-search-toggle-order ()
1012   "Toggle the current search order.
1013
1014 By default, the \"inbox\" view created by `notmuch' is displayed
1015 in chronological order (oldest thread at the beginning of the
1016 buffer), while any global searches created by `notmuch-search'
1017 are displayed in reverse-chronological order (newest thread at
1018 the beginning of the buffer).
1019
1020 This command toggles the sort order for the current search.
1021
1022 Note that any filtered searches created by
1023 `notmuch-search-filter' retain the search order of the parent
1024 search."
1025   (interactive)
1026   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1027   (notmuch-search-refresh-view))
1028
1029 (defun notmuch-search-filter (query)
1030   "Filter the current search results based on an additional query string.
1031
1032 Runs a new search matching only messages that match both the
1033 current search results AND the additional query string provided."
1034   (interactive (list (notmuch-read-query "Filter search: ")))
1035   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
1036                            (concat "( " query " )")
1037                          query)))
1038     (notmuch-search (if (string= notmuch-search-query-string "*")
1039                         grouped-query
1040                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1041
1042 (defun notmuch-search-filter-by-tag (tag)
1043   "Filter the current search results based on a single tag.
1044
1045 Runs a new search matching only messages that match both the
1046 current search results AND that are tagged with the given tag."
1047   (interactive
1048    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1049   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1050
1051 ;;;###autoload
1052 (defun notmuch ()
1053   "Run notmuch and display saved searches, known tags, etc."
1054   (interactive)
1055   (notmuch-hello))
1056
1057 (defun notmuch-interesting-buffer (b)
1058   "Is the current buffer of interest to a notmuch user?"
1059   (with-current-buffer b
1060     (memq major-mode '(notmuch-show-mode
1061                        notmuch-search-mode
1062                        notmuch-hello-mode
1063                        message-mode))))
1064
1065 ;;;###autoload
1066 (defun notmuch-cycle-notmuch-buffers ()
1067   "Cycle through any existing notmuch buffers (search, show or hello).
1068
1069 If the current buffer is the only notmuch buffer, bury it. If no
1070 notmuch buffers exist, run `notmuch'."
1071   (interactive)
1072
1073   (let (start first)
1074     ;; If the current buffer is a notmuch buffer, remember it and then
1075     ;; bury it.
1076     (when (notmuch-interesting-buffer (current-buffer))
1077       (setq start (current-buffer))
1078       (bury-buffer))
1079
1080     ;; Find the first notmuch buffer.
1081     (setq first (loop for buffer in (buffer-list)
1082                      if (notmuch-interesting-buffer buffer)
1083                      return buffer))
1084
1085     (if first
1086         ;; If the first one we found is any other than the starting
1087         ;; buffer, switch to it.
1088         (unless (eq first start)
1089           (switch-to-buffer first))
1090       (notmuch))))
1091
1092 (setq mail-user-agent 'notmuch-user-agent)
1093
1094 (provide 'notmuch)