git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'crm)
  52 (require 'mm-view)
  53 (require 'message)
  54
  55 (require 'notmuch-lib)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61
  62 (defcustom notmuch-search-result-format
  63   `(("date" . "%s ")
  64     ("count" . "%-7s ")
  65     ("authors" . "%-20s ")
  66     ("subject" . "%s ")
  67     ("tags" . "(%s)"))
  68   "Search result formatting. Supported fields are:
  69         date, count, authors, subject, tags
  70 For example:
  71         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  72                                              \(\"subject\" . \"%s\"\)\)\)"
  73   :type '(alist :key-type (string) :value-type (string))
  74   :group 'notmuch-search)
  75
  76 (defvar notmuch-query-history nil
  77   "Variable to store minibuffer history for notmuch queries")
  78
  79 (defun notmuch-tag-completions (&optional prefixes search-terms)
  80   (let ((tag-list
  81          (split-string
  82           (with-output-to-string
  83             (with-current-buffer standard-output
  84               (apply 'call-process notmuch-command nil t
  85                      nil "search-tags" search-terms)))
  86           "\n+" t)))
  87     (if (null prefixes)
  88         tag-list
  89       (apply #'append
  90              (mapcar (lambda (tag)
  91                        (mapcar (lambda (prefix)
  92                                  (concat prefix tag)) prefixes))
  93                      tag-list)))))
  94
  95 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
  96   (let ((tag-list (notmuch-tag-completions nil search-terms)))
  97     (completing-read prompt tag-list)))
  98
  99 (defun notmuch-select-tags-with-completion (prompt &optional prefixes &rest search-terms)
 100   (let ((tag-list (notmuch-tag-completions prefixes search-terms))
 101         (crm-separator " ")
 102         ;; By default, space is bound to "complete word" function.
 103         ;; Re-bind it to insert a space instead.  Note that <tab>
 104         ;; still does the completion.
 105         (crm-local-completion-map
 106          (let ((map (make-sparse-keymap)))
 107            (set-keymap-parent map crm-local-completion-map)
 108            (define-key map " " 'self-insert-command)
 109            map)))
 110     (delete "" (completing-read-multiple prompt tag-list))))
 111
 112 (defun notmuch-foreach-mime-part (function mm-handle)
 113   (cond ((stringp (car mm-handle))
 114          (dolist (part (cdr mm-handle))
 115            (notmuch-foreach-mime-part function part)))
 116         ((bufferp (car mm-handle))
 117          (funcall function mm-handle))
 118         (t (dolist (part mm-handle)
 119              (notmuch-foreach-mime-part function part)))))
 120
 121 (defun notmuch-count-attachments (mm-handle)
 122   (let ((count 0))
 123     (notmuch-foreach-mime-part
 124      (lambda (p)
 125        (let ((disposition (mm-handle-disposition p)))
 126          (and (listp disposition)
 127               (or (equal (car disposition) "attachment")
 128                   (and (equal (car disposition) "inline")
 129                        (assq 'filename disposition)))
 130               (incf count))))
 131      mm-handle)
 132     count))
 133
 134 (defun notmuch-save-attachments (mm-handle &optional queryp)
 135   (notmuch-foreach-mime-part
 136    (lambda (p)
 137      (let ((disposition (mm-handle-disposition p)))
 138        (and (listp disposition)
 139             (or (equal (car disposition) "attachment")
 140                 (and (equal (car disposition) "inline")
 141                      (assq 'filename disposition)))
 142             (or (not queryp)
 143                 (y-or-n-p
 144                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 145             (mm-save-part p))))
 146    mm-handle))
 147
 148 (defun notmuch-documentation-first-line (symbol)
 149   "Return the first line of the documentation string for SYMBOL."
 150   (let ((doc (documentation symbol)))
 151     (if doc
 152         (with-temp-buffer
 153           (insert (documentation symbol t))
 154           (goto-char (point-min))
 155           (let ((beg (point)))
 156             (end-of-line)
 157             (buffer-substring beg (point))))
 158       "")))
 159
 160 (defun notmuch-prefix-key-description (key)
 161   "Given a prefix key code, return a human-readable string representation.
 162
 163 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 164   (let ((desc (format-kbd-macro (vector key))))
 165     (if (string= desc "ESC")
 166         "M-"
 167       (concat desc " "))))
 168
 169 ;; I would think that emacs would have code handy for walking a keymap
 170 ;; and generating strings for each key, and I would prefer to just call
 171 ;; that. But I couldn't find any (could be all implemented in C I
 172 ;; suppose), so I wrote my own here.
 173 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 174   "For a key binding, return a string showing a human-readable
 175 representation of the prefixed key as well as the first line of
 176 documentation from the bound function.
 177
 178 For a mouse binding, return nil."
 179   (let ((key (car binding))
 180         (action (cdr binding)))
 181     (if (mouse-event-p key)
 182         nil
 183       (if (keymapp action)
 184           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 185                 (as-list))
 186             (map-keymap (lambda (a b)
 187                           (push (cons a b) as-list))
 188                         action)
 189             (mapconcat substitute as-list "\n"))
 190         (concat prefix (format-kbd-macro (vector key))
 191                 "\t"
 192                 (notmuch-documentation-first-line action))))))
 193
 194 (defun notmuch-substitute-command-keys-one (key)
 195   ;; A `keymap' key indicates inheritance from a parent keymap - the
 196   ;; inherited mappings follow, so there is nothing to print for
 197   ;; `keymap' itself.
 198   (when (not (eq key 'keymap))
 199     (notmuch-substitute-one-command-key-with-prefix nil key)))
 200
 201 (defun notmuch-substitute-command-keys (doc)
 202   "Like `substitute-command-keys' but with documentation, not function names."
 203   (let ((beg 0))
 204     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 205       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 206              (keymap (symbol-value (intern keymap-name))))
 207         (setq doc (replace-match
 208                    (mapconcat #'notmuch-substitute-command-keys-one
 209                               (cdr keymap) "\n")
 210                    1 1 doc)))
 211       (setq beg (match-end 0)))
 212     doc))
 213
 214 (defun notmuch-help ()
 215   "Display help for the current notmuch mode."
 216   (interactive)
 217   (let* ((mode major-mode)
 218          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 219     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 220       (insert doc)
 221       (goto-char (point-min))
 222       (set-buffer-modified-p nil)
 223       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 224
 225 (defcustom notmuch-search-hook '(hl-line-mode)
 226   "List of functions to call when notmuch displays the search results."
 227   :type 'hook
 228   :options '(hl-line-mode)
 229   :group 'notmuch-search
 230   :group 'notmuch-hooks)
 231
 232 (defvar notmuch-search-mode-map
 233   (let ((map (make-sparse-keymap)))
 234     (define-key map "?" 'notmuch-help)
 235     (define-key map "q" 'notmuch-search-quit)
 236     (define-key map "x" 'notmuch-search-quit)
 237     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 238     (define-key map "b" 'notmuch-search-scroll-down)
 239     (define-key map " " 'notmuch-search-scroll-up)
 240     (define-key map "<" 'notmuch-search-first-thread)
 241     (define-key map ">" 'notmuch-search-last-thread)
 242     (define-key map "p" 'notmuch-search-previous-thread)
 243     (define-key map "n" 'notmuch-search-next-thread)
 244     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 245     (define-key map "R" 'notmuch-search-reply-to-thread)
 246     (define-key map "m" 'notmuch-mua-new-mail)
 247     (define-key map "s" 'notmuch-search)
 248     (define-key map "o" 'notmuch-search-toggle-order)
 249     (define-key map "c" 'notmuch-search-stash-map)
 250     (define-key map "=" 'notmuch-search-refresh-view)
 251     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 252     (define-key map "t" 'notmuch-search-filter-by-tag)
 253     (define-key map "f" 'notmuch-search-filter)
 254     (define-key map [mouse-1] 'notmuch-search-show-thread)
 255     (define-key map "*" 'notmuch-search-operate-all)
 256     (define-key map "a" 'notmuch-search-archive-thread)
 257     (define-key map "-" 'notmuch-search-remove-tag)
 258     (define-key map "+" 'notmuch-search-add-tag)
 259     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 260     map)
 261   "Keymap for \"notmuch search\" buffers.")
 262 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 263
 264 (defvar notmuch-search-stash-map
 265   (let ((map (make-sparse-keymap)))
 266     (define-key map "i" 'notmuch-search-stash-thread-id)
 267     map)
 268   "Submap for stash commands")
 269 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 270
 271 (defun notmuch-search-stash-thread-id ()
 272   "Copy thread ID of current thread to kill-ring."
 273   (interactive)
 274   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 275
 276 (defvar notmuch-search-query-string)
 277 (defvar notmuch-search-target-thread)
 278 (defvar notmuch-search-target-line)
 279 (defvar notmuch-search-continuation)
 280
 281 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 282
 283 (defun notmuch-search-quit ()
 284   "Exit the search buffer, calling any defined continuation function."
 285   (interactive)
 286   (let ((continuation notmuch-search-continuation))
 287     (notmuch-kill-this-buffer)
 288     (when continuation
 289       (funcall continuation))))
 290
 291 (defun notmuch-search-scroll-up ()
 292   "Move forward through search results by one window's worth."
 293   (interactive)
 294   (condition-case nil
 295       (scroll-up nil)
 296     ((end-of-buffer) (notmuch-search-last-thread))))
 297
 298 (defun notmuch-search-scroll-down ()
 299   "Move backward through the search results by one window's worth."
 300   (interactive)
 301   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 302   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 303   ;;
 304   ;; So instead of trapping a signal we instead check whether the
 305   ;; window begins on the first line of the buffer and if so, move
 306   ;; directly to that position. (We have to count lines since the
 307   ;; window-start position is not the same as point-min due to the
 308   ;; invisible thread-ID characters on the first line.
 309   (if (equal (count-lines (point-min) (window-start)) 0)
 310       (goto-char (point-min))
 311     (scroll-down nil)))
 312
 313 (defun notmuch-search-next-thread ()
 314   "Select the next thread in the search results."
 315   (interactive)
 316   (forward-line 1))
 317
 318 (defun notmuch-search-previous-thread ()
 319   "Select the previous thread in the search results."
 320   (interactive)
 321   (forward-line -1))
 322
 323 (defun notmuch-search-last-thread ()
 324   "Select the last thread in the search results."
 325   (interactive)
 326   (goto-char (point-max))
 327   (forward-line -2))
 328
 329 (defun notmuch-search-first-thread ()
 330   "Select the first thread in the search results."
 331   (interactive)
 332   (goto-char (point-min)))
 333
 334 (defface notmuch-message-summary-face
 335  '((((class color) (background light)) (:background "#f0f0f0"))
 336    (((class color) (background dark)) (:background "#303030")))
 337  "Face for the single-line message summary in notmuch-show-mode."
 338  :group 'notmuch-show
 339  :group 'notmuch-faces)
 340
 341 (defface notmuch-search-date
 342   '((t :inherit default))
 343   "Face used in search mode for dates."
 344   :group 'notmuch-search
 345   :group 'notmuch-faces)
 346
 347 (defface notmuch-search-count
 348   '((t :inherit default))
 349   "Face used in search mode for the count matching the query."
 350   :group 'notmuch-search
 351   :group 'notmuch-faces)
 352
 353 (defface notmuch-search-subject
 354   '((t :inherit default))
 355   "Face used in search mode for subjects."
 356   :group 'notmuch-search
 357   :group 'notmuch-faces)
 358
 359 (defface notmuch-search-matching-authors
 360   '((t :inherit default))
 361   "Face used in search mode for authors matching the query."
 362   :group 'notmuch-search
 363   :group 'notmuch-faces)
 364
 365 (defface notmuch-search-non-matching-authors
 366   '((((class color)
 367       (background dark))
 368      (:foreground "grey30"))
 369     (((class color)
 370       (background light))
 371      (:foreground "grey60"))
 372     (t
 373      (:italic t)))
 374   "Face used in search mode for authors not matching the query."
 375   :group 'notmuch-search
 376   :group 'notmuch-faces)
 377
 378 (defface notmuch-tag-face
 379   '((((class color)
 380       (background dark))
 381      (:foreground "OliveDrab1"))
 382     (((class color)
 383       (background light))
 384      (:foreground "navy blue" :bold t))
 385     (t
 386      (:bold t)))
 387   "Face used in search mode face for tags."
 388   :group 'notmuch-search
 389   :group 'notmuch-faces)
 390
 391 (defun notmuch-search-mode ()
 392   "Major mode displaying results of a notmuch search.
 393
 394 This buffer contains the results of a \"notmuch search\" of your
 395 email archives. Each line in the buffer represents a single
 396 thread giving a summary of the thread (a relative date, the
 397 number of matched messages and total messages in the thread,
 398 participants in the thread, a representative subject line, and
 399 any tags).
 400
 401 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 402 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 403 is a convenience for archiving a thread (removing the \"inbox\"
 404 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
 405 threads in the current buffer.
 406
 407 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 408 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 409 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 410 search.
 411
 412 Complete list of currently available key bindings:
 413
 414 \\{notmuch-search-mode-map}"
 415   (interactive)
 416   (kill-all-local-variables)
 417   (make-local-variable 'notmuch-search-query-string)
 418   (make-local-variable 'notmuch-search-oldest-first)
 419   (make-local-variable 'notmuch-search-target-thread)
 420   (make-local-variable 'notmuch-search-target-line)
 421   (set (make-local-variable 'notmuch-search-continuation) nil)
 422   (set (make-local-variable 'scroll-preserve-screen-position) t)
 423   (add-to-invisibility-spec (cons 'ellipsis t))
 424   (use-local-map notmuch-search-mode-map)
 425   (setq truncate-lines t)
 426   (setq major-mode 'notmuch-search-mode
 427         mode-name "notmuch-search")
 428   (setq buffer-read-only t))
 429
 430 (defun notmuch-search-properties-in-region (property beg end)
 431   (save-excursion
 432     (let ((output nil)
 433           (last-line (line-number-at-pos end))
 434           (max-line (- (line-number-at-pos (point-max)) 2)))
 435       (goto-char beg)
 436       (beginning-of-line)
 437       (while (<= (line-number-at-pos) (min last-line max-line))
 438         (setq output (cons (get-text-property (point) property) output))
 439         (forward-line 1))
 440       output)))
 441
 442 (defun notmuch-search-find-thread-id ()
 443   "Return the thread for the current thread"
 444   (get-text-property (point) 'notmuch-search-thread-id))
 445
 446 (defun notmuch-search-find-thread-id-region (beg end)
 447   "Return a list of threads for the current region"
 448   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 449
 450 (defun notmuch-search-find-authors ()
 451   "Return the authors for the current thread"
 452   (get-text-property (point) 'notmuch-search-authors))
 453
 454 (defun notmuch-search-find-authors-region (beg end)
 455   "Return a list of authors for the current region"
 456   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 457
 458 (defun notmuch-search-find-subject ()
 459   "Return the subject for the current thread"
 460   (get-text-property (point) 'notmuch-search-subject))
 461
 462 (defun notmuch-search-find-subject-region (beg end)
 463   "Return a list of authors for the current region"
 464   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 465
 466 (defun notmuch-search-show-thread (&optional crypto-switch)
 467   "Display the currently selected thread."
 468   (interactive "P")
 469   (let ((thread-id (notmuch-search-find-thread-id))
 470         (subject (notmuch-prettify-subject (notmuch-search-find-subject))))
 471     (if (> (length thread-id) 0)
 472         (notmuch-show thread-id
 473                       (current-buffer)
 474                       notmuch-search-query-string
 475                       ;; Name the buffer based on the subject.
 476                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*")
 477                       crypto-switch)
 478       (message "End of search results."))))
 479
 480 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 481   "Begin composing a reply-all to the entire current thread in a new buffer."
 482   (interactive "P")
 483   (let ((message-id (notmuch-search-find-thread-id)))
 484     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 485
 486 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 487   "Begin composing a reply to the entire current thread in a new buffer."
 488   (interactive "P")
 489   (let ((message-id (notmuch-search-find-thread-id)))
 490     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 491
 492 (defun notmuch-call-notmuch-process (&rest args)
 493   "Synchronously invoke \"notmuch\" with the given list of arguments.
 494
 495 Output from the process will be presented to the user as an error
 496 and will also appear in a buffer named \"*Notmuch errors*\"."
 497   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 498     (with-current-buffer error-buffer
 499         (erase-buffer))
 500     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 501         (point)
 502       (progn
 503         (with-current-buffer error-buffer
 504           (let ((beg (point-min))
 505                 (end (- (point-max) 1)))
 506             (error (buffer-substring beg end))
 507             ))))))
 508
 509 (defun notmuch-tag (query &rest tags)
 510   "Add/remove tags in TAGS to messages matching QUERY.
 511
 512 TAGS should be a list of strings of the form \"+TAG\" or \"-TAG\" and
 513 QUERY should be a string containing the search-query.
 514
 515 Note: Other code should always use this function alter tags of
 516 messages instead of running (notmuch-call-notmuch-process \"tag\" ..)
 517 directly, so that hooks specified in notmuch-before-tag-hook and
 518 notmuch-after-tag-hook will be run."
 519   (run-hooks 'notmuch-before-tag-hook)
 520   (apply 'notmuch-call-notmuch-process
 521          (append (list "tag") tags (list "--" query)))
 522   (run-hooks 'notmuch-after-tag-hook))
 523
 524 (defcustom notmuch-before-tag-hook nil
 525   "Hooks that are run before tags of a message are modified.
 526
 527 'tags' will contain the tags that are about to be added or removed as
 528 a list of strings of the form \"+TAG\" or \"-TAG\".
 529 'query' will be a string containing the search query that determines
 530 the messages that are about to be tagged"
 531
 532   :type 'hook
 533   :options '(hl-line-mode)
 534   :group 'notmuch-hooks)
 535
 536 (defcustom notmuch-after-tag-hook nil
 537   "Hooks that are run after tags of a message are modified.
 538
 539 'tags' will contain the tags that were added or removed as
 540 a list of strings of the form \"+TAG\" or \"-TAG\".
 541 'query' will be a string containing the search query that determines
 542 the messages that were tagged"
 543   :type 'hook
 544   :options '(hl-line-mode)
 545   :group 'notmuch-hooks)
 546
 547 (defun notmuch-search-set-tags (tags)
 548   (save-excursion
 549     (end-of-line)
 550     (re-search-backward "(")
 551     (forward-char)
 552     (let ((beg (point))
 553           (inhibit-read-only t))
 554       (re-search-forward ")")
 555       (backward-char)
 556       (let ((end (point)))
 557         (delete-region beg end)
 558         (insert (propertize (mapconcat  'identity tags " ")
 559                             'face 'notmuch-tag-face))))))
 560
 561 (defun notmuch-search-get-tags ()
 562   (save-excursion
 563     (end-of-line)
 564     (re-search-backward "(")
 565     (let ((beg (+ (point) 1)))
 566       (re-search-forward ")")
 567       (let ((end (- (point) 1)))
 568         (split-string (buffer-substring beg end))))))
 569
 570 (defun notmuch-search-get-tags-region (beg end)
 571   (save-excursion
 572     (let ((output nil)
 573           (last-line (line-number-at-pos end))
 574           (max-line (- (line-number-at-pos (point-max)) 2)))
 575       (goto-char beg)
 576       (while (<= (line-number-at-pos) (min last-line max-line))
 577         (setq output (append output (notmuch-search-get-tags)))
 578         (forward-line 1))
 579       output)))
 580
 581 (defun notmuch-search-add-tag-thread (tag)
 582   (notmuch-search-add-tag-region tag (point) (point)))
 583
 584 (defun notmuch-search-add-tag-region (tag beg end)
 585   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 586     (notmuch-tag search-id-string (concat "+" tag))
 587     (save-excursion
 588       (let ((last-line (line-number-at-pos end))
 589             (max-line (- (line-number-at-pos (point-max)) 2)))
 590         (goto-char beg)
 591         (while (<= (line-number-at-pos) (min last-line max-line))
 592           (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<)))
 593           (forward-line))))))
 594
 595 (defun notmuch-search-remove-tag-thread (tag)
 596   (notmuch-search-remove-tag-region tag (point) (point)))
 597
 598 (defun notmuch-search-remove-tag-region (tag beg end)
 599   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 600     (notmuch-tag search-id-string (concat "-" tag))
 601     (save-excursion
 602       (let ((last-line (line-number-at-pos end))
 603             (max-line (- (line-number-at-pos (point-max)) 2)))
 604         (goto-char beg)
 605         (while (<= (line-number-at-pos) (min last-line max-line))
 606           (notmuch-search-set-tags (delete tag (notmuch-search-get-tags)))
 607           (forward-line))))))
 608
 609 (defun notmuch-search-add-tag (tag)
 610   "Add a tag to the currently selected thread or region.
 611
 612 The tag is added to all messages in the currently selected thread
 613 or threads in the current region."
 614   (interactive
 615    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 616   (save-excursion
 617     (if (region-active-p)
 618         (let* ((beg (region-beginning))
 619                (end (region-end)))
 620           (notmuch-search-add-tag-region tag beg end))
 621       (notmuch-search-add-tag-thread tag))))
 622
 623 (defun notmuch-search-remove-tag (tag)
 624   "Remove a tag from the currently selected thread or region.
 625
 626 The tag is removed from all messages in the currently selected
 627 thread or threads in the current region."
 628   (interactive
 629    (list (notmuch-select-tag-with-completion
 630           "Tag to remove: "
 631           (if (region-active-p)
 632               (mapconcat 'identity
 633                          (notmuch-search-find-thread-id-region (region-beginning) (region-end))
 634                          " ")
 635             (notmuch-search-find-thread-id)))))
 636   (save-excursion
 637     (if (region-active-p)
 638         (let* ((beg (region-beginning))
 639                (end (region-end)))
 640           (notmuch-search-remove-tag-region tag beg end))
 641       (notmuch-search-remove-tag-thread tag))))
 642
 643 (defun notmuch-search-archive-thread ()
 644   "Archive the currently selected thread (remove its \"inbox\" tag).
 645
 646 This function advances the next thread when finished."
 647   (interactive)
 648   (notmuch-search-remove-tag-thread "inbox")
 649   (notmuch-search-next-thread))
 650
 651 (defvar notmuch-search-process-filter-data nil
 652   "Data that has not yet been processed.")
 653 (make-variable-buffer-local 'notmuch-search-process-filter-data)
 654
 655 (defun notmuch-search-process-sentinel (proc msg)
 656   "Add a message to let user know when \"notmuch search\" exits"
 657   (let ((buffer (process-buffer proc))
 658         (status (process-status proc))
 659         (exit-status (process-exit-status proc))
 660         (never-found-target-thread nil))
 661     (if (memq status '(exit signal))
 662         (if (buffer-live-p buffer)
 663             (with-current-buffer buffer
 664               (save-excursion
 665                 (let ((inhibit-read-only t)
 666                       (atbob (bobp)))
 667                   (goto-char (point-max))
 668                   (if (eq status 'signal)
 669                       (insert "Incomplete search results (search process was killed).\n"))
 670                   (when (eq status 'exit)
 671                     (if notmuch-search-process-filter-data
 672                         (insert (concat "Error: Unexpected output from notmuch search:\n" notmuch-search-process-filter-data)))
 673                     (insert "End of search results.")
 674                     (unless (= exit-status 0)
 675                       (insert (format " (process returned %d)" exit-status)))
 676                     (insert "\n")
 677                     (if (and atbob
 678                              (not (string= notmuch-search-target-thread "found")))
 679                         (set 'never-found-target-thread t)))))
 680               (when (and never-found-target-thread
 681                        notmuch-search-target-line)
 682                   (goto-char (point-min))
 683                   (forward-line (1- notmuch-search-target-line))))))))
 684
 685 (defcustom notmuch-search-line-faces nil
 686   "Tag/face mapping for line highlighting in notmuch-search.
 687
 688 Here is an example of how to color search results based on tags.
 689  (the following text would be placed in your ~/.emacs file):
 690
 691  (setq notmuch-search-line-faces '((\"delete\" . (:foreground \"red\"
 692                                                   :background \"blue\"))
 693                                    (\"unread\" . (:foreground \"green\"))))
 694
 695 The attributes defined for matching tags are merged, with later
 696 attributes overriding earlier. A message having both \"delete\"
 697 and \"unread\" tags with the above settings would have a green
 698 foreground and blue background."
 699   :type '(alist :key-type (string) :value-type (custom-face-edit))
 700   :group 'notmuch-search
 701   :group 'notmuch-faces)
 702
 703 (defun notmuch-search-color-line (start end line-tag-list)
 704   "Colorize lines in `notmuch-show' based on tags."
 705   ;; Create the overlay only if the message has tags which match one
 706   ;; of those specified in `notmuch-search-line-faces'.
 707   (let (overlay)
 708     (mapc (lambda (elem)
 709             (let ((tag (car elem))
 710                   (attributes (cdr elem)))
 711               (when (member tag line-tag-list)
 712                 (when (not overlay)
 713                   (setq overlay (make-overlay start end)))
 714                 ;; Merge the specified properties with any already
 715                 ;; applied from an earlier match.
 716                 (overlay-put overlay 'face
 717                              (append (overlay-get overlay 'face) attributes)))))
 718           notmuch-search-line-faces)))
 719
 720 (defun notmuch-search-author-propertize (authors)
 721   "Split `authors' into matching and non-matching authors and
 722 propertize appropriately. If no boundary between authors and
 723 non-authors is found, assume that all of the authors match."
 724   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 725       (concat (propertize (concat (match-string 1 authors) ",")
 726                           'face 'notmuch-search-matching-authors)
 727               (propertize (match-string 2 authors)
 728                           'face 'notmuch-search-non-matching-authors))
 729     (propertize authors 'face 'notmuch-search-matching-authors)))
 730
 731 (defun notmuch-search-insert-authors (format-string authors)
 732   ;; Save the match data to avoid interfering with
 733   ;; `notmuch-search-process-filter'.
 734   (save-match-data
 735     (let* ((formatted-authors (format format-string authors))
 736            (formatted-sample (format format-string ""))
 737            (visible-string formatted-authors)
 738            (invisible-string "")
 739            (padding ""))
 740
 741       ;; Truncate the author string to fit the specification.
 742       (if (> (length formatted-authors)
 743              (length formatted-sample))
 744           (let ((visible-length (- (length formatted-sample)
 745                                    (length "... "))))
 746             ;; Truncate the visible string according to the width of
 747             ;; the display string.
 748             (setq visible-string (substring formatted-authors 0 visible-length)
 749                   invisible-string (substring formatted-authors visible-length))
 750             ;; If possible, truncate the visible string at a natural
 751             ;; break (comma or pipe), as incremental search doesn't
 752             ;; match across the visible/invisible border.
 753             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 754               ;; Second clause is destructive on `visible-string', so
 755               ;; order is important.
 756               (setq invisible-string (concat (match-string 3 visible-string)
 757                                              invisible-string)
 758                     visible-string (concat (match-string 1 visible-string)
 759                                            (match-string 2 visible-string))))
 760             ;; `visible-string' may be shorter than the space allowed
 761             ;; by `format-string'. If so we must insert some padding
 762             ;; after `invisible-string'.
 763             (setq padding (make-string (- (length formatted-sample)
 764                                           (length visible-string)
 765                                           (length "..."))
 766                                        ? ))))
 767
 768       ;; Use different faces to show matching and non-matching authors.
 769       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 770           ;; The visible string contains both matching and
 771           ;; non-matching authors.
 772           (setq visible-string (notmuch-search-author-propertize visible-string)
 773                 ;; The invisible string must contain only non-matching
 774                 ;; authors, as the visible-string contains both.
 775                 invisible-string (propertize invisible-string
 776                                              'face 'notmuch-search-non-matching-authors))
 777         ;; The visible string contains only matching authors.
 778         (setq visible-string (propertize visible-string
 779                                          'face 'notmuch-search-matching-authors)
 780               ;; The invisible string may contain both matching and
 781               ;; non-matching authors.
 782               invisible-string (notmuch-search-author-propertize invisible-string)))
 783
 784       ;; If there is any invisible text, add it as a tooltip to the
 785       ;; visible text.
 786       (when (not (string= invisible-string ""))
 787         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 788
 789       ;; Insert the visible and, if present, invisible author strings.
 790       (insert visible-string)
 791       (when (not (string= invisible-string ""))
 792         (let ((start (point))
 793               overlay)
 794           (insert invisible-string)
 795           (setq overlay (make-overlay start (point)))
 796           (overlay-put overlay 'invisible 'ellipsis)
 797           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 798       (insert padding))))
 799
 800 (defun notmuch-search-insert-field (field date count authors subject tags)
 801   (cond
 802    ((string-equal field "date")
 803     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) date)
 804                         'face 'notmuch-search-date)))
 805    ((string-equal field "count")
 806     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) count)
 807                         'face 'notmuch-search-count)))
 808    ((string-equal field "subject")
 809     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) subject)
 810                         'face 'notmuch-search-subject)))
 811
 812    ((string-equal field "authors")
 813     (notmuch-search-insert-authors (cdr (assoc field notmuch-search-result-format)) authors))
 814
 815    ((string-equal field "tags")
 816     (insert (concat "(" (propertize tags 'font-lock-face 'notmuch-tag-face) ")")))))
 817
 818 (defun notmuch-search-show-result (date count authors subject tags)
 819   (let ((fields) (field))
 820     (setq fields (mapcar 'car notmuch-search-result-format))
 821     (loop for field in fields
 822           do (notmuch-search-insert-field field date count authors subject tags)))
 823   (insert "\n"))
 824
 825 (defun notmuch-search-process-filter (proc string)
 826   "Process and filter the output of \"notmuch search\""
 827   (let ((buffer (process-buffer proc))
 828         (found-target nil))
 829     (if (buffer-live-p buffer)
 830         (with-current-buffer buffer
 831           (save-excursion
 832             (let ((line 0)
 833                   (more t)
 834                   (inhibit-read-only t)
 835                   (string (concat notmuch-search-process-filter-data string)))
 836               (setq notmuch-search-process-filter-data nil)
 837               (while more
 838                 (while (and (< line (length string)) (= (elt string line) ?\n))
 839                   (setq line (1+ line)))
 840                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\([^][]*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 841                     (let* ((thread-id (match-string 1 string))
 842                            (date (match-string 2 string))
 843                            (count (match-string 3 string))
 844                            (authors (match-string 4 string))
 845                            (subject (match-string 5 string))
 846                            (tags (match-string 6 string))
 847                            (tag-list (if tags (save-match-data (split-string tags)))))
 848                       (goto-char (point-max))
 849                       (if (/= (match-beginning 1) line)
 850                           (insert (concat "Error: Unexpected output from notmuch search:\n" (substring string line (match-beginning 1)) "\n")))
 851                       (let ((beg (point)))
 852                         (notmuch-search-show-result date count authors
 853                                                     (notmuch-prettify-subject subject) tags)
 854                         (notmuch-search-color-line beg (point) tag-list)
 855                         (put-text-property beg (point) 'notmuch-search-thread-id thread-id)
 856                         (put-text-property beg (point) 'notmuch-search-authors authors)
 857                         (put-text-property beg (point) 'notmuch-search-subject subject)
 858                         (when (string= thread-id notmuch-search-target-thread)
 859                           (set 'found-target beg)
 860                           (set 'notmuch-search-target-thread "found")))
 861                       (set 'line (match-end 0)))
 862                   (set 'more nil)
 863                   (while (and (< line (length string)) (= (elt string line) ?\n))
 864                     (setq line (1+ line)))
 865                   (if (< line (length string))
 866                       (setq notmuch-search-process-filter-data (substring string line)))
 867                   ))))
 868           (if found-target
 869               (goto-char found-target)))
 870       (delete-process proc))))
 871
 872 (defun notmuch-search-operate-all (&rest actions)
 873   "Add/remove tags from all matching messages.
 874
 875 This command adds or removes tags from all messages matching the
 876 current search terms. When called interactively, this command
 877 will prompt for tags to be added or removed. Tags prefixed with
 878 '+' will be added and tags prefixed with '-' will be removed.
 879
 880 Each character of the tag name may consist of alphanumeric
 881 characters as well as `_.+-'.
 882 "
 883   (interactive (notmuch-select-tags-with-completion
 884                 "Operations (+add -drop): notmuch tag "
 885                 '("+" "-")))
 886   ;; Perform some validation
 887   (when (null actions) (error "No operations given"))
 888   (mapc (lambda (action)
 889           (unless (string-match-p "^[-+][-+_.[:word:]]+$" action)
 890             (error "Action must be of the form `+this_tag' or `-that_tag'")))
 891         actions)
 892   (apply 'notmuch-tag notmuch-search-query-string actions))
 893
 894 (defun notmuch-search-buffer-title (query)
 895   "Returns the title for a buffer with notmuch search results."
 896   (let* ((saved-search
 897           (let (longest
 898                 (longest-length 0))
 899             (loop for tuple in notmuch-saved-searches
 900                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 901                        (and (string-match (concat "^" quoted-query) query)
 902                             (> (length (match-string 0 query))
 903                                longest-length)))
 904                   do (setq longest tuple))
 905             longest))
 906          (saved-search-name (car saved-search))
 907          (saved-search-query (cdr saved-search)))
 908     (cond ((and saved-search (equal saved-search-query query))
 909            ;; Query is the same as saved search (ignoring case)
 910            (concat "*notmuch-saved-search-" saved-search-name "*"))
 911           (saved-search
 912            (concat "*notmuch-search-"
 913                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 914                                              (concat "[ " saved-search-name " ]")
 915                                              query)
 916                    "*"))
 917           (t
 918            (concat "*notmuch-search-" query "*"))
 919           )))
 920
 921 (defun notmuch-read-query (prompt)
 922   "Read a notmuch-query from the minibuffer with completion.
 923
 924 PROMPT is the string to prompt with."
 925   (lexical-let
 926       ((completions
 927         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 928                       "subject:" "attachment:")
 929                 (mapcar (lambda (tag)
 930                           (concat "tag:" tag))
 931                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 932     (let ((keymap (copy-keymap minibuffer-local-map))
 933           (minibuffer-completion-table
 934            (completion-table-dynamic
 935             (lambda (string)
 936               ;; generate a list of possible completions for the current input
 937               (cond
 938                ;; this ugly regexp is used to get the last word of the input
 939                ;; possibly preceded by a '('
 940                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 941                 (mapcar (lambda (compl)
 942                           (concat (match-string-no-properties 1 string) compl))
 943                         (all-completions (match-string-no-properties 2 string)
 944                                          completions)))
 945                (t (list string)))))))
 946       ;; this was simpler than convincing completing-read to accept spaces:
 947       (define-key keymap (kbd "<tab>") 'minibuffer-complete)
 948       (let ((history-delete-duplicates t))
 949         (read-from-minibuffer prompt nil keymap nil
 950                               'notmuch-search-history nil nil)))))
 951
 952 ;;;###autoload
 953 (defun notmuch-search (&optional query oldest-first target-thread target-line continuation)
 954   "Run \"notmuch search\" with the given `query' and display results.
 955
 956 If `query' is nil, it is read interactively from the minibuffer.
 957 Other optional parameters are used as follows:
 958
 959   oldest-first: A Boolean controlling the sort order of returned threads
 960   target-thread: A thread ID (with the thread: prefix) that will be made
 961                  current if it appears in the search results.
 962   target-line: The line number to move to if the target thread does not
 963                appear in the search results."
 964   (interactive)
 965   (if (null query)
 966       (setq query (notmuch-read-query "Notmuch search: ")))
 967   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 968     (switch-to-buffer buffer)
 969     (notmuch-search-mode)
 970     ;; Don't track undo information for this buffer
 971     (set 'buffer-undo-list t)
 972     (set 'notmuch-search-query-string query)
 973     (set 'notmuch-search-oldest-first oldest-first)
 974     (set 'notmuch-search-target-thread target-thread)
 975     (set 'notmuch-search-target-line target-line)
 976     (set 'notmuch-search-continuation continuation)
 977     (let ((proc (get-buffer-process (current-buffer)))
 978           (inhibit-read-only t))
 979       (if proc
 980           (error "notmuch search process already running for query `%s'" query)
 981         )
 982       (erase-buffer)
 983       (goto-char (point-min))
 984       (save-excursion
 985         (let ((proc (start-process
 986                      "notmuch-search" buffer
 987                      notmuch-command "search"
 988                      (if oldest-first
 989                          "--sort=oldest-first"
 990                        "--sort=newest-first")
 991                      query)))
 992           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 993           (set-process-filter proc 'notmuch-search-process-filter)
 994           (set-process-query-on-exit-flag proc nil))))
 995     (run-hooks 'notmuch-search-hook)))
 996
 997 (defun notmuch-search-refresh-view ()
 998   "Refresh the current view.
 999
1000 Kills the current buffer and runs a new search with the same
1001 query string as the current search. If the current thread is in
1002 the new search results, then point will be placed on the same
1003 thread. Otherwise, point will be moved to attempt to be in the
1004 same relative position within the new buffer."
1005   (interactive)
1006   (let ((target-line (line-number-at-pos))
1007         (oldest-first notmuch-search-oldest-first)
1008         (target-thread (notmuch-search-find-thread-id))
1009         (query notmuch-search-query-string)
1010         (continuation notmuch-search-continuation))
1011     (notmuch-kill-this-buffer)
1012     (notmuch-search query oldest-first target-thread target-line continuation)
1013     (goto-char (point-min))))
1014
1015 (defcustom notmuch-poll-script nil
1016   "An external script to incorporate new mail into the notmuch database.
1017
1018 This variable controls the action invoked by
1019 `notmuch-search-poll-and-refresh-view' and
1020 `notmuch-hello-poll-and-update' (each have a default keybinding
1021 of 'G') to incorporate new mail into the notmuch database.
1022
1023 If set to nil (the default), new mail is processed by invoking
1024 \"notmuch new\". Otherwise, this should be set to a string that
1025 gives the name of an external script that processes new mail. If
1026 set to the empty string, no command will be run.
1027
1028 The external script could do any of the following depending on
1029 the user's needs:
1030
1031 1. Invoke a program to transfer mail to the local mail store
1032 2. Invoke \"notmuch new\" to incorporate the new mail
1033 3. Invoke one or more \"notmuch tag\" commands to classify the mail
1034
1035 Note that the recommended way of achieving the same is using
1036 \"notmuch new\" hooks."
1037   :type '(choice (const :tag "notmuch new" nil)
1038                  (const :tag "Disabled" "")
1039                  (string :tag "Custom script"))
1040   :group 'notmuch-external)
1041
1042 (defun notmuch-poll ()
1043   "Run \"notmuch new\" or an external script to import mail.
1044
1045 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
1046 depending on the value of `notmuch-poll-script'."
1047   (interactive)
1048   (if (stringp notmuch-poll-script)
1049       (unless (string= notmuch-poll-script "")
1050         (call-process notmuch-poll-script nil nil))
1051     (call-process notmuch-command nil nil nil "new")))
1052
1053 (defun notmuch-search-poll-and-refresh-view ()
1054   "Invoke `notmuch-poll' to import mail, then refresh the current view."
1055   (interactive)
1056   (notmuch-poll)
1057   (notmuch-search-refresh-view))
1058
1059 (defun notmuch-search-toggle-order ()
1060   "Toggle the current search order.
1061
1062 By default, the \"inbox\" view created by `notmuch' is displayed
1063 in chronological order (oldest thread at the beginning of the
1064 buffer), while any global searches created by `notmuch-search'
1065 are displayed in reverse-chronological order (newest thread at
1066 the beginning of the buffer).
1067
1068 This command toggles the sort order for the current search.
1069
1070 Note that any filtered searches created by
1071 `notmuch-search-filter' retain the search order of the parent
1072 search."
1073   (interactive)
1074   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1075   (notmuch-search-refresh-view))
1076
1077 (defun notmuch-search-filter (query)
1078   "Filter the current search results based on an additional query string.
1079
1080 Runs a new search matching only messages that match both the
1081 current search results AND the additional query string provided."
1082   (interactive (list (notmuch-read-query "Filter search: ")))
1083   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
1084                            (concat "( " query " )")
1085                          query)))
1086     (notmuch-search (if (string= notmuch-search-query-string "*")
1087                         grouped-query
1088                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1089
1090 (defun notmuch-search-filter-by-tag (tag)
1091   "Filter the current search results based on a single tag.
1092
1093 Runs a new search matching only messages that match both the
1094 current search results AND that are tagged with the given tag."
1095   (interactive
1096    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1097   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1098
1099 ;;;###autoload
1100 (defun notmuch ()
1101   "Run notmuch and display saved searches, known tags, etc."
1102   (interactive)
1103   (notmuch-hello))
1104
1105 (defun notmuch-interesting-buffer (b)
1106   "Is the current buffer of interest to a notmuch user?"
1107   (with-current-buffer b
1108     (memq major-mode '(notmuch-show-mode
1109                        notmuch-search-mode
1110                        notmuch-hello-mode
1111                        message-mode))))
1112
1113 ;;;###autoload
1114 (defun notmuch-cycle-notmuch-buffers ()
1115   "Cycle through any existing notmuch buffers (search, show or hello).
1116
1117 If the current buffer is the only notmuch buffer, bury it. If no
1118 notmuch buffers exist, run `notmuch'."
1119   (interactive)
1120
1121   (let (start first)
1122     ;; If the current buffer is a notmuch buffer, remember it and then
1123     ;; bury it.
1124     (when (notmuch-interesting-buffer (current-buffer))
1125       (setq start (current-buffer))
1126       (bury-buffer))
1127
1128     ;; Find the first notmuch buffer.
1129     (setq first (loop for buffer in (buffer-list)
1130                      if (notmuch-interesting-buffer buffer)
1131                      return buffer))
1132
1133     (if first
1134         ;; If the first one we found is any other than the starting
1135         ;; buffer, switch to it.
1136         (unless (eq first start)
1137           (switch-to-buffer first))
1138       (notmuch))))
1139
1140 (setq mail-user-agent 'notmuch-user-agent)
1141
1142 (provide 'notmuch)