]> git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el
Merge branch 'release'
[notmuch] / emacs / notmuch.el
1 ;;; notmuch.el --- run notmuch within emacs
2 ;;
3 ;; Copyright © Carl Worth
4 ;;
5 ;; This file is part of Notmuch.
6 ;;
7 ;; Notmuch is free software: you can redistribute it and/or modify it
8 ;; under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation, either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; Notmuch is distributed in the hope that it will be useful, but
13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;; General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
19 ;;
20 ;; Authors: Carl Worth <cworth@cworth.org>
21 ;; Homepage: https://notmuchmail.org/
22
23 ;;; Commentary:
24
25 ;; This is an emacs-based interface to the notmuch mail system.
26 ;;
27 ;; You will first need to have the notmuch program installed and have a
28 ;; notmuch database built in order to use this. See
29 ;; https://notmuchmail.org for details.
30 ;;
31 ;; To install this software, copy it to a directory that is on the
32 ;; `load-path' variable within emacs (a good candidate is
33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
34 ;; notmuch source distribution then you can simply run:
35 ;;
36 ;;      sudo make install-emacs
37 ;;
38 ;; to install it.
39 ;;
40 ;; Then, to actually run it, add:
41 ;;
42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
43 ;;
44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
45 ;; or run:
46 ;;
47 ;;      emacs -f notmuch
48 ;;
49 ;; Have fun, and let us know if you have any comment, questions, or
50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
51 ;; required, but is available from https://notmuchmail.org).
52
53 ;;; Code:
54
55 (eval-when-compile (require 'cl))
56 (require 'mm-view)
57 (require 'message)
58
59 (require 'notmuch-lib)
60 (require 'notmuch-tag)
61 (require 'notmuch-show)
62 (require 'notmuch-tree)
63 (require 'notmuch-mua)
64 (require 'notmuch-hello)
65 (require 'notmuch-maildir-fcc)
66 (require 'notmuch-message)
67 (require 'notmuch-parser)
68
69 (defcustom notmuch-search-result-format
70   `(("date" . "%12s ")
71     ("count" . "%-7s ")
72     ("authors" . "%-20s ")
73     ("subject" . "%s ")
74     ("tags" . "(%s)"))
75   "Search result formatting. Supported fields are:
76         date, count, authors, subject, tags
77 For example:
78         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
79                                              \(\"subject\" . \"%s\"\)\)\)
80 Line breaks are permitted in format strings (though this is
81 currently experimental).  Note that a line break at the end of an
82 \"authors\" field will get elided if the authors list is long;
83 place it instead at the beginning of the following field.  To
84 enter a line break when setting this variable with setq, use \\n.
85 To enter a line break in customize, press \\[quoted-insert] C-j."
86   :type '(alist :key-type (string) :value-type (string))
87   :group 'notmuch-search)
88
89 ;; The name of this variable `notmuch-init-file' is consistent with the
90 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
91 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
92 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
93   "Your Notmuch Emacs-Lisp configuration file name.
94 If a file with one of the suffixes defined by `get-load-suffixes' exists,
95 it will be read instead.
96 This file is read once when notmuch is loaded; the notmuch hooks added
97 there will be called at other points of notmuch execution."
98   :type 'file
99   :group 'notmuch)
100
101 (defvar notmuch-query-history nil
102   "Variable to store minibuffer history for notmuch queries")
103
104 (defun notmuch-foreach-mime-part (function mm-handle)
105   (cond ((stringp (car mm-handle))
106          (dolist (part (cdr mm-handle))
107            (notmuch-foreach-mime-part function part)))
108         ((bufferp (car mm-handle))
109          (funcall function mm-handle))
110         (t (dolist (part mm-handle)
111              (notmuch-foreach-mime-part function part)))))
112
113 (defun notmuch-count-attachments (mm-handle)
114   (let ((count 0))
115     (notmuch-foreach-mime-part
116      (lambda (p)
117        (let ((disposition (mm-handle-disposition p)))
118          (and (listp disposition)
119               (or (equal (car disposition) "attachment")
120                   (and (equal (car disposition) "inline")
121                        (assq 'filename disposition)))
122               (incf count))))
123      mm-handle)
124     count))
125
126 (defun notmuch-save-attachments (mm-handle &optional queryp)
127   (notmuch-foreach-mime-part
128    (lambda (p)
129      (let ((disposition (mm-handle-disposition p)))
130        (and (listp disposition)
131             (or (equal (car disposition) "attachment")
132                 (and (equal (car disposition) "inline")
133                      (assq 'filename disposition)))
134             (or (not queryp)
135                 (y-or-n-p
136                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
137             (mm-save-part p))))
138    mm-handle))
139
140 (require 'hl-line)
141
142 (defun notmuch-hl-line-mode ()
143   (prog1 (hl-line-mode)
144     (when hl-line-overlay
145       (overlay-put hl-line-overlay 'priority 1))))
146
147 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
148   "List of functions to call when notmuch displays the search results."
149   :type 'hook
150   :options '(notmuch-hl-line-mode)
151   :group 'notmuch-search
152   :group 'notmuch-hooks)
153
154 (defvar notmuch-search-mode-map
155   (let ((map (make-sparse-keymap)))
156     (set-keymap-parent map notmuch-common-keymap)
157     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
158     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
159     (define-key map "b" 'notmuch-search-scroll-down)
160     (define-key map " " 'notmuch-search-scroll-up)
161     (define-key map "<" 'notmuch-search-first-thread)
162     (define-key map ">" 'notmuch-search-last-thread)
163     (define-key map "p" 'notmuch-search-previous-thread)
164     (define-key map "n" 'notmuch-search-next-thread)
165     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
166     (define-key map "R" 'notmuch-search-reply-to-thread)
167     (define-key map "o" 'notmuch-search-toggle-order)
168     (define-key map "c" 'notmuch-search-stash-map)
169     (define-key map "t" 'notmuch-search-filter-by-tag)
170     (define-key map "l" 'notmuch-search-filter)
171     (define-key map [mouse-1] 'notmuch-search-show-thread)
172     (define-key map "k" 'notmuch-tag-jump)
173     (define-key map "*" 'notmuch-search-tag-all)
174     (define-key map "a" 'notmuch-search-archive-thread)
175     (define-key map "-" 'notmuch-search-remove-tag)
176     (define-key map "+" 'notmuch-search-add-tag)
177     (define-key map (kbd "RET") 'notmuch-search-show-thread)
178     (define-key map "Z" 'notmuch-tree-from-search-current-query)
179     map)
180   "Keymap for \"notmuch search\" buffers.")
181 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
182
183 (defvar notmuch-search-stash-map
184   (let ((map (make-sparse-keymap)))
185     (define-key map "i" 'notmuch-search-stash-thread-id)
186     (define-key map "q" 'notmuch-stash-query)
187     (define-key map "?" 'notmuch-subkeymap-help)
188     map)
189   "Submap for stash commands")
190 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
191
192 (defun notmuch-search-stash-thread-id ()
193   "Copy thread ID of current thread to kill-ring."
194   (interactive)
195   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
196
197 (defun notmuch-stash-query ()
198   "Copy current query to kill-ring."
199   (interactive)
200   (notmuch-common-do-stash (notmuch-search-get-query)))
201
202 (defvar notmuch-search-query-string)
203 (defvar notmuch-search-target-thread)
204 (defvar notmuch-search-target-line)
205
206 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
207
208 (defun notmuch-search-scroll-up ()
209   "Move forward through search results by one window's worth."
210   (interactive)
211   (condition-case nil
212       (scroll-up nil)
213     ((end-of-buffer) (notmuch-search-last-thread))))
214
215 (defun notmuch-search-scroll-down ()
216   "Move backward through the search results by one window's worth."
217   (interactive)
218   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
219   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
220   ;;
221   ;; So instead of trapping a signal we instead check whether the
222   ;; window begins on the first line of the buffer and if so, move
223   ;; directly to that position. (We have to count lines since the
224   ;; window-start position is not the same as point-min due to the
225   ;; invisible thread-ID characters on the first line.
226   (if (equal (count-lines (point-min) (window-start)) 0)
227       (goto-char (point-min))
228     (scroll-down nil)))
229
230 (defun notmuch-search-next-thread ()
231   "Select the next thread in the search results."
232   (interactive)
233   (when (notmuch-search-get-result)
234     (goto-char (notmuch-search-result-end))))
235
236 (defun notmuch-search-previous-thread ()
237   "Select the previous thread in the search results."
238   (interactive)
239   (if (notmuch-search-get-result)
240       (unless (bobp)
241         (goto-char (notmuch-search-result-beginning (- (point) 1))))
242     ;; We must be past the end; jump to the last result
243     (notmuch-search-last-thread)))
244
245 (defun notmuch-search-last-thread ()
246   "Select the last thread in the search results."
247   (interactive)
248   (goto-char (point-max))
249   (forward-line -2)
250   (let ((beg (notmuch-search-result-beginning)))
251     (when beg (goto-char beg))))
252
253 (defun notmuch-search-first-thread ()
254   "Select the first thread in the search results."
255   (interactive)
256   (goto-char (point-min)))
257
258 (defface notmuch-message-summary-face
259  '((((class color) (background light)) (:background "#f0f0f0"))
260    (((class color) (background dark)) (:background "#303030")))
261  "Face for the single-line message summary in notmuch-show-mode."
262  :group 'notmuch-show
263  :group 'notmuch-faces)
264
265 (defface notmuch-search-date
266   '((t :inherit default))
267   "Face used in search mode for dates."
268   :group 'notmuch-search
269   :group 'notmuch-faces)
270
271 (defface notmuch-search-count
272   '((t :inherit default))
273   "Face used in search mode for the count matching the query."
274   :group 'notmuch-search
275   :group 'notmuch-faces)
276
277 (defface notmuch-search-subject
278   '((t :inherit default))
279   "Face used in search mode for subjects."
280   :group 'notmuch-search
281   :group 'notmuch-faces)
282
283 (defface notmuch-search-matching-authors
284   '((t :inherit default))
285   "Face used in search mode for authors matching the query."
286   :group 'notmuch-search
287   :group 'notmuch-faces)
288
289 (defface notmuch-search-non-matching-authors
290   '((((class color)
291       (background dark))
292      (:foreground "grey30"))
293     (((class color)
294       (background light))
295      (:foreground "grey60"))
296     (t
297      (:italic t)))
298   "Face used in search mode for authors not matching the query."
299   :group 'notmuch-search
300   :group 'notmuch-faces)
301
302 (defface notmuch-tag-face
303   '((((class color)
304       (background dark))
305      (:foreground "OliveDrab1"))
306     (((class color)
307       (background light))
308      (:foreground "navy blue" :bold t))
309     (t
310      (:bold t)))
311   "Face used in search mode face for tags."
312   :group 'notmuch-search
313   :group 'notmuch-faces)
314
315 (defface notmuch-search-flagged-face
316   '((((class color)
317       (background dark))
318      (:foreground "LightBlue1"))
319     (((class color)
320       (background light))
321      (:foreground "blue")))
322   "Face used in search mode face for flagged threads.
323
324 This face is the default value for the \"flagged\" tag in
325 `notmuch-search-line-faces`."
326   :group 'notmuch-search
327   :group 'notmuch-faces)
328
329 (defface notmuch-search-unread-face
330   '((t
331      (:weight bold)))
332   "Face used in search mode for unread threads.
333
334 This face is the default value for the \"unread\" tag in
335 `notmuch-search-line-faces`."
336   :group 'notmuch-search
337   :group 'notmuch-faces)
338
339 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
340   "Major mode displaying results of a notmuch search.
341
342 This buffer contains the results of a \"notmuch search\" of your
343 email archives. Each line in the buffer represents a single
344 thread giving a summary of the thread (a relative date, the
345 number of matched messages and total messages in the thread,
346 participants in the thread, a representative subject line, and
347 any tags).
348
349 Pressing \\[notmuch-search-show-thread] on any line displays that
350 thread. The '\\[notmuch-search-add-tag]' and
351 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
352 tags from a thread. The '\\[notmuch-search-archive-thread]' key
353 is a convenience for archiving a thread (applying changes in
354 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
355 be used to add and/or remove tags from all messages (as opposed
356 to threads) that match the current query.  Use with caution, as
357 this will also tag matching messages that arrived *after*
358 constructing the buffer.
359
360 Other useful commands are '\\[notmuch-search-filter]' for
361 filtering the current search based on an additional query string,
362 '\\[notmuch-search-filter-by-tag]' for filtering to include only
363 messages with a given tag, and '\\[notmuch-search]' to execute a
364 new, global search.
365
366 Complete list of currently available key bindings:
367
368 \\{notmuch-search-mode-map}"
369   (make-local-variable 'notmuch-search-query-string)
370   (make-local-variable 'notmuch-search-oldest-first)
371   (make-local-variable 'notmuch-search-target-thread)
372   (make-local-variable 'notmuch-search-target-line)
373   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
374   (set (make-local-variable 'scroll-preserve-screen-position) t)
375   (add-to-invisibility-spec (cons 'ellipsis t))
376   (setq truncate-lines t)
377   (setq buffer-read-only t))
378
379 (defun notmuch-search-get-result (&optional pos)
380   "Return the result object for the thread at POS (or point).
381
382 If there is no thread at POS (or point), returns nil."
383   (get-text-property (or pos (point)) 'notmuch-search-result))
384
385 (defun notmuch-search-result-beginning (&optional pos)
386   "Return the point at the beginning of the thread at POS (or point).
387
388 If there is no thread at POS (or point), returns nil."
389   (when (notmuch-search-get-result pos)
390     ;; We pass 1+point because previous-single-property-change starts
391     ;; searching one before the position we give it.
392     (previous-single-property-change (1+ (or pos (point)))
393                                      'notmuch-search-result nil (point-min))))
394
395 (defun notmuch-search-result-end (&optional pos)
396   "Return the point at the end of the thread at POS (or point).
397
398 The returned point will be just after the newline character that
399 ends the result line.  If there is no thread at POS (or point),
400 returns nil"
401   (when (notmuch-search-get-result pos)
402     (next-single-property-change (or pos (point)) 'notmuch-search-result
403                                  nil (point-max))))
404
405 (defun notmuch-search-foreach-result (beg end function)
406   "Invoke FUNCTION for each result between BEG and END.
407
408 FUNCTION should take one argument.  It will be applied to the
409 character position of the beginning of each result that overlaps
410 the region between points BEG and END.  As a special case, if (=
411 BEG END), FUNCTION will be applied to the result containing point
412 BEG."
413
414   (lexical-let ((pos (notmuch-search-result-beginning beg))
415                 ;; End must be a marker in case function changes the
416                 ;; text.
417                 (end (copy-marker end))
418                 ;; Make sure we examine at least one result, even if
419                 ;; (= beg end).
420                 (first t))
421     ;; We have to be careful if the region extends beyond the results.
422     ;; In this case, pos could be null or there could be no result at
423     ;; pos.
424     (while (and pos (or (< pos end) first))
425       (when (notmuch-search-get-result pos)
426         (funcall function pos))
427       (setq pos (notmuch-search-result-end pos)
428             first nil))))
429 ;; Unindent the function argument of notmuch-search-foreach-result so
430 ;; the indentation of callers doesn't get out of hand.
431 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
432
433 (defun notmuch-search-properties-in-region (property beg end)
434   (let (output)
435     (notmuch-search-foreach-result beg end
436       (lambda (pos)
437         (push (plist-get (notmuch-search-get-result pos) property) output)))
438     output))
439
440 (defun notmuch-search-find-thread-id (&optional bare)
441   "Return the thread for the current thread
442
443 If BARE is set then do not prefix with \"thread:\""
444   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
445     (when thread (concat (unless bare "thread:") thread))))
446
447 (defun notmuch-search-find-stable-query ()
448   "Return the stable queries for the current thread.
449
450 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
451 matched and unmatched messages in the current thread."
452   (plist-get (notmuch-search-get-result) :query))
453
454 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
455   "Return the stable query for the current region.
456
457 If ONLY-MATCHED is non-nil, include only matched messages.  If it
458 is nil, include both matched and unmatched messages. If there are
459 no messages in the region then return nil."
460   (let ((query-list nil) (all (not only-matched)))
461     (dolist (queries (notmuch-search-properties-in-region :query beg end))
462       (when (first queries)
463         (push (first queries) query-list))
464       (when (and all (second queries))
465         (push (second queries) query-list)))
466     (when query-list
467       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
468
469 (defun notmuch-search-find-authors ()
470   "Return the authors for the current thread"
471   (plist-get (notmuch-search-get-result) :authors))
472
473 (defun notmuch-search-find-authors-region (beg end)
474   "Return a list of authors for the current region"
475   (notmuch-search-properties-in-region :authors beg end))
476
477 (defun notmuch-search-find-subject ()
478   "Return the subject for the current thread"
479   (plist-get (notmuch-search-get-result) :subject))
480
481 (defun notmuch-search-find-subject-region (beg end)
482   "Return a list of authors for the current region"
483   (notmuch-search-properties-in-region :subject beg end))
484
485 (defun notmuch-search-show-thread (&optional elide-toggle)
486   "Display the currently selected thread.
487
488 With a prefix argument, invert the default value of
489 `notmuch-show-only-matching-messages' when displaying the
490 thread."
491   (interactive "P")
492   (let ((thread-id (notmuch-search-find-thread-id))
493         (subject (notmuch-search-find-subject)))
494     (if (> (length thread-id) 0)
495         (notmuch-show thread-id
496                       elide-toggle
497                       (current-buffer)
498                       notmuch-search-query-string
499                       ;; Name the buffer based on the subject.
500                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
501       (message "End of search results."))))
502
503 (defun notmuch-tree-from-search-current-query ()
504   "Call notmuch tree with the current query"
505   (interactive)
506   (notmuch-tree notmuch-search-query-string))
507
508 (defun notmuch-tree-from-search-thread ()
509   "Show the selected thread with notmuch-tree"
510   (interactive)
511   (notmuch-tree (notmuch-search-find-thread-id)
512                 notmuch-search-query-string
513                 nil
514                 (notmuch-prettify-subject (notmuch-search-find-subject))
515                 t))
516
517 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
518   "Begin composing a reply-all to the entire current thread in a new buffer."
519   (interactive "P")
520   (let ((message-id (notmuch-search-find-thread-id)))
521     (notmuch-mua-new-reply message-id prompt-for-sender t)))
522
523 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
524   "Begin composing a reply to the entire current thread in a new buffer."
525   (interactive "P")
526   (let ((message-id (notmuch-search-find-thread-id)))
527     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
528
529 (defun notmuch-search-set-tags (tags &optional pos)
530   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
531     (notmuch-search-update-result new-result pos)))
532
533 (defun notmuch-search-get-tags (&optional pos)
534   (plist-get (notmuch-search-get-result pos) :tags))
535
536 (defun notmuch-search-get-tags-region (beg end)
537   (let (output)
538     (notmuch-search-foreach-result beg end
539       (lambda (pos)
540         (setq output (append output (notmuch-search-get-tags pos)))))
541     output))
542
543 (defun notmuch-search-interactive-region ()
544   "Return the bounds of the current interactive region.
545
546 This returns (BEG END), where BEG and END are the bounds of the
547 region if the region is active, or both `point' otherwise."
548   (if (region-active-p)
549       (list (region-beginning) (region-end))
550     (list (point) (point))))
551
552 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
553   "Prompt for tag changes for the current thread or region.
554
555 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
556   (let* ((region (notmuch-search-interactive-region))
557          (beg (first region)) (end (second region))
558          (prompt (if (= beg end) "Tag thread" "Tag region")))
559     (cons (notmuch-read-tag-changes
560            (notmuch-search-get-tags-region beg end) prompt initial-input)
561           region)))
562
563 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
564   "Change tags for the currently selected thread or region.
565
566 See `notmuch-tag' for information on the format of TAG-CHANGES.
567 When called interactively, this uses the region if the region is
568 active.  When called directly, BEG and END provide the region.
569 If these are nil or not provided, then, if the region is active
570 this applied to all threads meeting the region, and if the region
571 is inactive this applies to the thread at point.
572
573 If ONLY-MATCHED is non-nil, only tag matched messages."
574   (interactive (notmuch-search-interactive-tag-changes))
575   (unless (and beg end)
576     (setq beg (car (notmuch-search-interactive-region))
577           end (cadr (notmuch-search-interactive-region))))
578   (let ((search-string (notmuch-search-find-stable-query-region
579                         beg end only-matched)))
580     (notmuch-tag search-string tag-changes)
581     (notmuch-search-foreach-result beg end
582       (lambda (pos)
583         (notmuch-search-set-tags
584          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
585          pos)))))
586
587 (defun notmuch-search-add-tag (tag-changes &optional beg end)
588   "Change tags for the current thread or region (defaulting to add).
589
590 Same as `notmuch-search-tag' but sets initial input to '+'."
591   (interactive (notmuch-search-interactive-tag-changes "+"))
592   (notmuch-search-tag tag-changes beg end))
593
594 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
595   "Change tags for the current thread or region (defaulting to remove).
596
597 Same as `notmuch-search-tag' but sets initial input to '-'."
598   (interactive (notmuch-search-interactive-tag-changes "-"))
599   (notmuch-search-tag tag-changes beg end))
600
601 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
602      "Un-archive the currently selected thread.")
603 (defun notmuch-search-archive-thread (&optional unarchive beg end)
604   "Archive the currently selected thread or region.
605
606 Archive each message in the currently selected thread by applying
607 the tag changes in `notmuch-archive-tags' to each (remove the
608 \"inbox\" tag by default). If a prefix argument is given, the
609 messages will be \"unarchived\" (i.e. the tag changes in
610 `notmuch-archive-tags' will be reversed).
611
612 This function advances the next thread when finished."
613   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
614   (when notmuch-archive-tags
615     (notmuch-search-tag
616      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
617   (when (eq beg end)
618     (notmuch-search-next-thread)))
619
620 (defun notmuch-search-update-result (result &optional pos)
621   "Replace the result object of the thread at POS (or point) by
622 RESULT and redraw it.
623
624 This will keep point in a reasonable location.  However, if there
625 are enclosing save-excursions and the saved point is in the
626 result being updated, the point will be restored to the beginning
627 of the result."
628   (let ((start (notmuch-search-result-beginning pos))
629         (end (notmuch-search-result-end pos))
630         (init-point (point))
631         (inhibit-read-only t))
632     ;; Delete the current thread
633     (delete-region start end)
634     ;; Insert the updated thread
635     (notmuch-search-show-result result start)
636     ;; If point was inside the old result, make an educated guess
637     ;; about where to place it now.  Unfortunately, this won't work
638     ;; with save-excursion (or any other markers that would be nice to
639     ;; preserve, such as the window start), but there's nothing we can
640     ;; do about that without a way to retrieve markers in a region.
641     (when (and (>= init-point start) (<= init-point end))
642       (let* ((new-end (notmuch-search-result-end start))
643              (new-point (if (= init-point end)
644                             new-end
645                           (min init-point (- new-end 1)))))
646         (goto-char new-point)))))
647
648 (defun notmuch-search-process-sentinel (proc msg)
649   "Add a message to let user know when \"notmuch search\" exits"
650   (let ((buffer (process-buffer proc))
651         (status (process-status proc))
652         (exit-status (process-exit-status proc))
653         (never-found-target-thread nil))
654     (when (memq status '(exit signal))
655       (catch 'return
656         (kill-buffer (process-get proc 'parse-buf))
657         (if (buffer-live-p buffer)
658             (with-current-buffer buffer
659               (save-excursion
660                 (let ((inhibit-read-only t)
661                       (atbob (bobp)))
662                   (goto-char (point-max))
663                   (if (eq status 'signal)
664                       (insert "Incomplete search results (search process was killed).\n"))
665                   (when (eq status 'exit)
666                     (insert "End of search results.\n")
667                     ;; For version mismatch, there's no point in
668                     ;; showing the search buffer
669                     (when (or (= exit-status 20) (= exit-status 21))
670                       (kill-buffer)
671                       (throw 'return nil))
672                     (if (and atbob
673                              (not (string= notmuch-search-target-thread "found")))
674                         (set 'never-found-target-thread t)))))
675               (when (and never-found-target-thread
676                        notmuch-search-target-line)
677                   (goto-char (point-min))
678                   (forward-line (1- notmuch-search-target-line)))))))))
679
680 (define-widget 'notmuch--custom-face-edit 'lazy
681   "Custom face edit with a tag Edit Face"
682   ;; I could not persuage custom-face-edit to respect the :tag
683   ;; property so create a widget specially
684   :tag "Manually specify face"
685   :type 'custom-face-edit)
686
687 (defcustom notmuch-search-line-faces
688   '(("unread" . notmuch-search-unread-face)
689     ("flagged" . notmuch-search-flagged-face))
690   "Alist of tags to faces for line highlighting in notmuch-search.
691 Each element looks like (TAG . FACE).
692 A thread with TAG will have FACE applied.
693
694 Here is an example of how to color search results based on tags.
695  (the following text would be placed in your ~/.emacs file):
696
697  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
698                                    (\"deleted\" . (:foreground \"red\"
699                                                   :background \"blue\"))))
700
701 The FACE must be a face name (a symbol or string), a property
702 list of face attributes, or a list of these.  The faces for
703 matching tags are merged, with earlier attributes overriding
704 later. A message having both \"deleted\" and \"unread\" tags with
705 the above settings would have a green foreground and blue
706 background."
707   :type '(alist :key-type (string)
708                 :value-type (radio (face :tag "Face name")
709                                     (notmuch--custom-face-edit)))
710   :group 'notmuch-search
711   :group 'notmuch-faces)
712
713 (defun notmuch-search-color-line (start end line-tag-list)
714   "Colorize lines in `notmuch-show' based on tags."
715   ;; Reverse the list so earlier entries take precedence
716   (dolist (elem (reverse notmuch-search-line-faces))
717     (let ((tag (car elem))
718           (face (cdr elem)))
719       (when (member tag line-tag-list)
720         (notmuch-apply-face nil face nil start end)))))
721
722 (defun notmuch-search-author-propertize (authors)
723   "Split `authors' into matching and non-matching authors and
724 propertize appropriately. If no boundary between authors and
725 non-authors is found, assume that all of the authors match."
726   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
727       (concat (propertize (concat (match-string 1 authors) ",")
728                           'face 'notmuch-search-matching-authors)
729               (propertize (match-string 2 authors)
730                           'face 'notmuch-search-non-matching-authors))
731     (propertize authors 'face 'notmuch-search-matching-authors)))
732
733 (defun notmuch-search-insert-authors (format-string authors)
734   ;; Save the match data to avoid interfering with
735   ;; `notmuch-search-process-filter'.
736   (save-match-data
737     (let* ((formatted-authors (format format-string authors))
738            (formatted-sample (format format-string ""))
739            (visible-string formatted-authors)
740            (invisible-string "")
741            (padding ""))
742
743       ;; Truncate the author string to fit the specification.
744       (if (> (length formatted-authors)
745              (length formatted-sample))
746           (let ((visible-length (- (length formatted-sample)
747                                    (length "... "))))
748             ;; Truncate the visible string according to the width of
749             ;; the display string.
750             (setq visible-string (substring formatted-authors 0 visible-length)
751                   invisible-string (substring formatted-authors visible-length))
752             ;; If possible, truncate the visible string at a natural
753             ;; break (comma or pipe), as incremental search doesn't
754             ;; match across the visible/invisible border.
755             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
756               ;; Second clause is destructive on `visible-string', so
757               ;; order is important.
758               (setq invisible-string (concat (match-string 3 visible-string)
759                                              invisible-string)
760                     visible-string (concat (match-string 1 visible-string)
761                                            (match-string 2 visible-string))))
762             ;; `visible-string' may be shorter than the space allowed
763             ;; by `format-string'. If so we must insert some padding
764             ;; after `invisible-string'.
765             (setq padding (make-string (- (length formatted-sample)
766                                           (length visible-string)
767                                           (length "..."))
768                                        ? ))))
769
770       ;; Use different faces to show matching and non-matching authors.
771       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
772           ;; The visible string contains both matching and
773           ;; non-matching authors.
774           (setq visible-string (notmuch-search-author-propertize visible-string)
775                 ;; The invisible string must contain only non-matching
776                 ;; authors, as the visible-string contains both.
777                 invisible-string (propertize invisible-string
778                                              'face 'notmuch-search-non-matching-authors))
779         ;; The visible string contains only matching authors.
780         (setq visible-string (propertize visible-string
781                                          'face 'notmuch-search-matching-authors)
782               ;; The invisible string may contain both matching and
783               ;; non-matching authors.
784               invisible-string (notmuch-search-author-propertize invisible-string)))
785
786       ;; If there is any invisible text, add it as a tooltip to the
787       ;; visible text.
788       (when (not (string= invisible-string ""))
789         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
790
791       ;; Insert the visible and, if present, invisible author strings.
792       (insert visible-string)
793       (when (not (string= invisible-string ""))
794         (let ((start (point))
795               overlay)
796           (insert invisible-string)
797           (setq overlay (make-overlay start (point)))
798           (overlay-put overlay 'invisible 'ellipsis)
799           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
800       (insert padding))))
801
802 (defun notmuch-search-insert-field (field format-string result)
803   (cond
804    ((string-equal field "date")
805     (insert (propertize (format format-string (plist-get result :date_relative))
806                         'face 'notmuch-search-date)))
807    ((string-equal field "count")
808     (insert (propertize (format format-string
809                                 (format "[%s/%s]" (plist-get result :matched)
810                                         (plist-get result :total)))
811                         'face 'notmuch-search-count)))
812    ((string-equal field "subject")
813     (insert (propertize (format format-string
814                                 (notmuch-sanitize (plist-get result :subject)))
815                         'face 'notmuch-search-subject)))
816
817    ((string-equal field "authors")
818     (notmuch-search-insert-authors
819      format-string (notmuch-sanitize (plist-get result :authors))))
820
821    ((string-equal field "tags")
822     (let ((tags (plist-get result :tags))
823           (orig-tags (plist-get result :orig-tags)))
824       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
825
826 (defun notmuch-search-show-result (result pos)
827   "Insert RESULT at POS."
828   ;; Ignore excluded matches
829   (unless (= (plist-get result :matched) 0)
830     (save-excursion
831       (goto-char pos)
832       (dolist (spec notmuch-search-result-format)
833         (notmuch-search-insert-field (car spec) (cdr spec) result))
834       (insert "\n")
835       (notmuch-search-color-line pos (point) (plist-get result :tags))
836       (put-text-property pos (point) 'notmuch-search-result result))))
837
838 (defun notmuch-search-append-result (result)
839   "Insert RESULT at the end of the buffer.
840
841 This is only called when a result is first inserted so it also
842 sets the :orig-tag property."
843   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
844         (pos (point-max)))
845     (notmuch-search-show-result new-result pos)
846     (when (string= (plist-get result :thread) notmuch-search-target-thread)
847       (setq notmuch-search-target-thread "found")
848       (goto-char pos))))
849
850 (defun notmuch-search-process-filter (proc string)
851   "Process and filter the output of \"notmuch search\""
852   (let ((results-buf (process-buffer proc))
853         (parse-buf (process-get proc 'parse-buf))
854         (inhibit-read-only t)
855         done)
856     (when (buffer-live-p results-buf)
857       (with-current-buffer parse-buf
858         ;; Insert new data
859         (save-excursion
860           (goto-char (point-max))
861           (insert string))
862         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
863                                          results-buf)))))
864
865 (defun notmuch-search-tag-all (tag-changes)
866   "Add/remove tags from all messages in current search buffer.
867
868 See `notmuch-tag' for information on the format of TAG-CHANGES."
869   (interactive
870    (list (notmuch-read-tag-changes
871           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
872   (notmuch-search-tag tag-changes (point-min) (point-max) t))
873
874 (defun notmuch-search-buffer-title (query)
875   "Returns the title for a buffer with notmuch search results."
876   (let* ((saved-search
877           (let (longest
878                 (longest-length 0))
879             (loop for tuple in notmuch-saved-searches
880                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
881                        (and (string-match (concat "^" quoted-query) query)
882                             (> (length (match-string 0 query))
883                                longest-length)))
884                   do (setq longest tuple))
885             longest))
886          (saved-search-name (notmuch-saved-search-get saved-search :name))
887          (saved-search-query (notmuch-saved-search-get saved-search :query)))
888     (cond ((and saved-search (equal saved-search-query query))
889            ;; Query is the same as saved search (ignoring case)
890            (concat "*notmuch-saved-search-" saved-search-name "*"))
891           (saved-search
892            (concat "*notmuch-search-"
893                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
894                                              (concat "[ " saved-search-name " ]")
895                                              query)
896                    "*"))
897           (t
898            (concat "*notmuch-search-" query "*"))
899           )))
900
901 (defun notmuch-read-query (prompt)
902   "Read a notmuch-query from the minibuffer with completion.
903
904 PROMPT is the string to prompt with."
905   (lexical-let*
906       ((all-tags
907         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
908                 (process-lines notmuch-command "search" "--output=tags" "*")))
909        (completions
910          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
911                        "subject:" "attachment:")
912                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
913                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
914                  (mapcar (lambda (mimetype) (concat "mimetype:" mimetype)) (mailcap-mime-types)))))
915     (let ((keymap (copy-keymap minibuffer-local-map))
916           (current-query (case major-mode
917                            (notmuch-search-mode (notmuch-search-get-query))
918                            (notmuch-show-mode (notmuch-show-get-query))
919                            (notmuch-tree-mode (notmuch-tree-get-query))))
920           (minibuffer-completion-table
921            (completion-table-dynamic
922             (lambda (string)
923               ;; generate a list of possible completions for the current input
924               (cond
925                ;; this ugly regexp is used to get the last word of the input
926                ;; possibly preceded by a '('
927                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
928                 (mapcar (lambda (compl)
929                           (concat (match-string-no-properties 1 string) compl))
930                         (all-completions (match-string-no-properties 2 string)
931                                          completions)))
932                (t (list string)))))))
933       ;; this was simpler than convincing completing-read to accept spaces:
934       (define-key keymap (kbd "TAB") 'minibuffer-complete)
935       (let ((history-delete-duplicates t))
936         (read-from-minibuffer prompt nil keymap nil
937                               'notmuch-search-history current-query nil)))))
938
939 (defun notmuch-search-get-query ()
940   "Return the current query in this search buffer"
941   notmuch-search-query-string)
942
943 (put 'notmuch-search 'notmuch-doc "Search for messages.")
944 ;;;###autoload
945 (defun notmuch-search (&optional query oldest-first target-thread target-line no-display)
946   "Display threads matching QUERY in a notmuch-search buffer.
947
948 If QUERY is nil, it is read interactively from the minibuffer.
949 Other optional parameters are used as follows:
950
951   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
952   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
953                  current if it appears in the search results.
954   TARGET-LINE: The line number to move to if the target thread does not
955                appear in the search results.
956   NO-DISPLAY: Do not try to foreground the search results buffer. If it is
957               already foregrounded i.e. displayed in a window, this has no
958               effect, meaning the buffer will remain visible.
959
960 When called interactively, this will prompt for a query and use
961 the configured default sort order."
962   (interactive
963    (list
964     ;; Prompt for a query
965     nil
966     ;; Use the default search order (if we're doing a search from a
967     ;; search buffer, ignore any buffer-local overrides)
968     (default-value 'notmuch-search-oldest-first)))
969
970   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
971          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
972     (if no-display
973         (set-buffer buffer)
974       (switch-to-buffer buffer))
975     (notmuch-search-mode)
976     ;; Don't track undo information for this buffer
977     (set 'buffer-undo-list t)
978     (set 'notmuch-search-query-string query)
979     (set 'notmuch-search-oldest-first oldest-first)
980     (set 'notmuch-search-target-thread target-thread)
981     (set 'notmuch-search-target-line target-line)
982     (notmuch-tag-clear-cache)
983     (let ((proc (get-buffer-process (current-buffer)))
984           (inhibit-read-only t))
985       (if proc
986           (error "notmuch search process already running for query `%s'" query)
987         )
988       (erase-buffer)
989       (goto-char (point-min))
990       (save-excursion
991         (let ((proc (notmuch-start-notmuch
992                      "notmuch-search" buffer #'notmuch-search-process-sentinel
993                      "search" "--format=sexp" "--format-version=2"
994                      (if oldest-first
995                          "--sort=oldest-first"
996                        "--sort=newest-first")
997                      query))
998               ;; Use a scratch buffer to accumulate partial output.
999               ;; This buffer will be killed by the sentinel, which
1000               ;; should be called no matter how the process dies.
1001               (parse-buf (generate-new-buffer " *notmuch search parse*")))
1002           (process-put proc 'parse-buf parse-buf)
1003           (set-process-filter proc 'notmuch-search-process-filter)
1004           (set-process-query-on-exit-flag proc nil))))
1005     (run-hooks 'notmuch-search-hook)))
1006
1007 (defun notmuch-search-refresh-view ()
1008   "Refresh the current view.
1009
1010 Erases the current buffer and runs a new search with the same
1011 query string as the current search. If the current thread is in
1012 the new search results, then point will be placed on the same
1013 thread. Otherwise, point will be moved to attempt to be in the
1014 same relative position within the new buffer."
1015   (interactive)
1016   (let ((target-line (line-number-at-pos))
1017         (oldest-first notmuch-search-oldest-first)
1018         (target-thread (notmuch-search-find-thread-id 'bare))
1019         (query notmuch-search-query-string))
1020     ;; notmuch-search erases the current buffer.
1021     (notmuch-search query oldest-first target-thread target-line t)
1022     (goto-char (point-min))))
1023
1024 (defun notmuch-search-toggle-order ()
1025   "Toggle the current search order.
1026
1027 This command toggles the sort order for the current search. The
1028 default sort order is defined by `notmuch-search-oldest-first'."
1029   (interactive)
1030   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1031   (notmuch-search-refresh-view))
1032
1033 (defun notmuch-group-disjunctive-query-string (query-string)
1034   "Group query if it contains a complex expression.
1035
1036 Enclose QUERY-STRING in parentheses if it matches
1037 `notmuch-search-disjunctive-regexp'."
1038   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1039       (concat "( " query-string " )")
1040     query-string))
1041
1042 (defun notmuch-search-filter (query)
1043   "Filter or LIMIT the current search results based on an additional query string.
1044
1045 Runs a new search matching only messages that match both the
1046 current search results AND the additional query string provided."
1047   (interactive (list (notmuch-read-query "Filter search: ")))
1048   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1049         (grouped-original-query (notmuch-group-disjunctive-query-string
1050                                  notmuch-search-query-string)))
1051     (notmuch-search (if (string= grouped-original-query "*")
1052                         grouped-query
1053                       (concat grouped-original-query " and " grouped-query))
1054                     notmuch-search-oldest-first)))
1055
1056 (defun notmuch-search-filter-by-tag (tag)
1057   "Filter the current search results based on a single tag.
1058
1059 Runs a new search matching only messages that match both the
1060 current search results AND that are tagged with the given tag."
1061   (interactive
1062    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1063   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1064
1065 ;;;###autoload
1066 (defun notmuch ()
1067   "Run notmuch and display saved searches, known tags, etc."
1068   (interactive)
1069   (notmuch-hello))
1070
1071 (defun notmuch-interesting-buffer (b)
1072   "Is the current buffer of interest to a notmuch user?"
1073   (with-current-buffer b
1074     (memq major-mode '(notmuch-show-mode
1075                        notmuch-search-mode
1076                        notmuch-tree-mode
1077                        notmuch-hello-mode
1078                        notmuch-message-mode))))
1079
1080 ;;;###autoload
1081 (defun notmuch-cycle-notmuch-buffers ()
1082   "Cycle through any existing notmuch buffers (search, show or hello).
1083
1084 If the current buffer is the only notmuch buffer, bury it. If no
1085 notmuch buffers exist, run `notmuch'."
1086   (interactive)
1087
1088   (let (start first)
1089     ;; If the current buffer is a notmuch buffer, remember it and then
1090     ;; bury it.
1091     (when (notmuch-interesting-buffer (current-buffer))
1092       (setq start (current-buffer))
1093       (bury-buffer))
1094
1095     ;; Find the first notmuch buffer.
1096     (setq first (loop for buffer in (buffer-list)
1097                      if (notmuch-interesting-buffer buffer)
1098                      return buffer))
1099
1100     (if first
1101         ;; If the first one we found is any other than the starting
1102         ;; buffer, switch to it.
1103         (unless (eq first start)
1104           (switch-to-buffer first))
1105       (notmuch))))
1106
1107 (setq mail-user-agent 'notmuch-user-agent)
1108
1109 (provide 'notmuch)
1110
1111 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1112 (if init-file-user ; don't load init file if the -q option was used.
1113     (let ((init-file (locate-file notmuch-init-file '("/")
1114                                   (get-load-suffixes))))
1115       (if init-file (load init-file nil t t))))
1116
1117 ;;; notmuch.el ends here