git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-show)
  56 (require 'notmuch-mua)
  57 (require 'notmuch-hello)
  58 (require 'notmuch-maildir-fcc)
  59 (require 'notmuch-message)
  60
  61 (defcustom notmuch-search-result-format
  62   `(("date" . "%s ")
  63     ("count" . "%-7s ")
  64     ("authors" . "%-20s ")
  65     ("subject" . "%s ")
  66     ("tags" . "(%s)"))
  67   "Search result formating. Supported fields are:
  68         date, count, authors, subject, tags
  69 For example:
  70         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  71                                              \(\"subject\" . \"%s\"\)\)\)"
  72   :type '(alist :key-type (string) :value-type (string))
  73   :group 'notmuch)
  74
  75 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
  76   (let ((tag-list
  77          (with-output-to-string
  78            (with-current-buffer standard-output
  79              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
  80     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
  81
  82 (defun notmuch-foreach-mime-part (function mm-handle)
  83   (cond ((stringp (car mm-handle))
  84          (dolist (part (cdr mm-handle))
  85            (notmuch-foreach-mime-part function part)))
  86         ((bufferp (car mm-handle))
  87          (funcall function mm-handle))
  88         (t (dolist (part mm-handle)
  89              (notmuch-foreach-mime-part function part)))))
  90
  91 (defun notmuch-count-attachments (mm-handle)
  92   (let ((count 0))
  93     (notmuch-foreach-mime-part
  94      (lambda (p)
  95        (let ((disposition (mm-handle-disposition p)))
  96          (and (listp disposition)
  97               (or (equal (car disposition) "attachment")
  98                   (and (equal (car disposition) "inline")
  99                        (assq 'filename disposition)))
 100               (incf count))))
 101      mm-handle)
 102     count))
 103
 104 (defun notmuch-save-attachments (mm-handle &optional queryp)
 105   (notmuch-foreach-mime-part
 106    (lambda (p)
 107      (let ((disposition (mm-handle-disposition p)))
 108        (and (listp disposition)
 109             (or (equal (car disposition) "attachment")
 110                 (and (equal (car disposition) "inline")
 111                      (assq 'filename disposition)))
 112             (or (not queryp)
 113                 (y-or-n-p
 114                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 115             (mm-save-part p))))
 116    mm-handle))
 117
 118 (defun notmuch-documentation-first-line (symbol)
 119   "Return the first line of the documentation string for SYMBOL."
 120   (let ((doc (documentation symbol)))
 121     (if doc
 122         (with-temp-buffer
 123           (insert (documentation symbol t))
 124           (goto-char (point-min))
 125           (let ((beg (point)))
 126             (end-of-line)
 127             (buffer-substring beg (point))))
 128       "")))
 129
 130 (defun notmuch-prefix-key-description (key)
 131   "Given a prefix key code, return a human-readable string representation.
 132
 133 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 134   (let ((desc (format-kbd-macro (vector key))))
 135     (if (string= desc "ESC")
 136         "M-"
 137       (concat desc " "))))
 138
 139 ; I would think that emacs would have code handy for walking a keymap
 140 ; and generating strings for each key, and I would prefer to just call
 141 ; that. But I couldn't find any (could be all implemented in C I
 142 ; suppose), so I wrote my own here.
 143 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 144   "For a key binding, return a string showing a human-readable
 145 representation of the prefixed key as well as the first line of
 146 documentation from the bound function.
 147
 148 For a mouse binding, return nil."
 149   (let ((key (car binding))
 150         (action (cdr binding)))
 151     (if (mouse-event-p key)
 152         nil
 153       (if (keymapp action)
 154           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 155                 (as-list))
 156             (map-keymap (lambda (a b)
 157                           (push (cons a b) as-list))
 158                         action)
 159             (mapconcat substitute as-list "\n"))
 160         (concat prefix (format-kbd-macro (vector key))
 161                 "\t"
 162                 (notmuch-documentation-first-line action))))))
 163
 164 (defalias 'notmuch-substitute-one-command-key
 165   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 166
 167 (defun notmuch-substitute-command-keys (doc)
 168   "Like `substitute-command-keys' but with documentation, not function names."
 169   (let ((beg 0))
 170     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 171       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 172         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 173                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 174       (setq beg (match-end 0)))
 175     doc))
 176
 177 (defun notmuch-help ()
 178   "Display help for the current notmuch mode."
 179   (interactive)
 180   (let* ((mode major-mode)
 181          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 182     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 183       (insert doc)
 184       (goto-char (point-min))
 185       (set-buffer-modified-p nil)
 186       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 187
 188 (defcustom notmuch-search-hook '(hl-line-mode)
 189   "List of functions to call when notmuch displays the search results."
 190   :type 'hook
 191   :options '(hl-line-mode)
 192   :group 'notmuch)
 193
 194 (defvar notmuch-search-mode-map
 195   (let ((map (make-sparse-keymap)))
 196     (define-key map "?" 'notmuch-help)
 197     (define-key map "q" 'notmuch-search-quit)
 198     (define-key map "x" 'notmuch-search-quit)
 199     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 200     (define-key map "b" 'notmuch-search-scroll-down)
 201     (define-key map " " 'notmuch-search-scroll-up)
 202     (define-key map "<" 'notmuch-search-first-thread)
 203     (define-key map ">" 'notmuch-search-last-thread)
 204     (define-key map "p" 'notmuch-search-previous-thread)
 205     (define-key map "n" 'notmuch-search-next-thread)
 206     (define-key map "r" 'notmuch-search-reply-to-thread)
 207     (define-key map "m" 'notmuch-mua-mail)
 208     (define-key map "s" 'notmuch-search)
 209     (define-key map "o" 'notmuch-search-toggle-order)
 210     (define-key map "=" 'notmuch-search-refresh-view)
 211     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 212     (define-key map "t" 'notmuch-search-filter-by-tag)
 213     (define-key map "f" 'notmuch-search-filter)
 214     (define-key map [mouse-1] 'notmuch-search-show-thread)
 215     (define-key map "*" 'notmuch-search-operate-all)
 216     (define-key map "a" 'notmuch-search-archive-thread)
 217     (define-key map "-" 'notmuch-search-remove-tag)
 218     (define-key map "+" 'notmuch-search-add-tag)
 219     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 220     map)
 221   "Keymap for \"notmuch search\" buffers.")
 222 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 223
 224 (defvar notmuch-search-query-string)
 225 (defvar notmuch-search-target-thread)
 226 (defvar notmuch-search-target-line)
 227 (defvar notmuch-search-continuation)
 228
 229 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 230
 231 (defun notmuch-search-quit ()
 232   "Exit the search buffer, calling any defined continuation function."
 233   (interactive)
 234   (let ((continuation notmuch-search-continuation))
 235     (kill-this-buffer)
 236     (when continuation
 237       (funcall continuation))))
 238
 239 (defun notmuch-search-scroll-up ()
 240   "Move forward through search results by one window's worth."
 241   (interactive)
 242   (condition-case nil
 243       (scroll-up nil)
 244     ((end-of-buffer) (notmuch-search-last-thread))))
 245
 246 (defun notmuch-search-scroll-down ()
 247   "Move backward through the search results by one window's worth."
 248   (interactive)
 249   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 250   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 251   ;
 252   ; So instead of trapping a signal we instead check whether the
 253   ; window begins on the first line of the buffer and if so, move
 254   ; directly to that position. (We have to count lines since the
 255   ; window-start position is not the same as point-min due to the
 256   ; invisible thread-ID characters on the first line.
 257   (if (equal (count-lines (point-min) (window-start)) 0)
 258       (goto-char (point-min))
 259     (scroll-down nil)))
 260
 261 (defun notmuch-search-next-thread ()
 262   "Select the next thread in the search results."
 263   (interactive)
 264   (forward-line 1))
 265
 266 (defun notmuch-search-previous-thread ()
 267   "Select the previous thread in the search results."
 268   (interactive)
 269   (forward-line -1))
 270
 271 (defun notmuch-search-last-thread ()
 272   "Select the last thread in the search results."
 273   (interactive)
 274   (goto-char (point-max))
 275   (forward-line -2))
 276
 277 (defun notmuch-search-first-thread ()
 278   "Select the first thread in the search results."
 279   (interactive)
 280   (goto-char (point-min)))
 281
 282 (defface notmuch-message-summary-face
 283  '((((class color) (background light)) (:background "#f0f0f0"))
 284    (((class color) (background dark)) (:background "#303030")))
 285  "Face for the single-line message summary in notmuch-show-mode."
 286  :group 'notmuch)
 287
 288 (defface notmuch-search-date
 289   '((t :inherit default))
 290   "Face used in search mode for dates."
 291   :group 'notmuch)
 292
 293 (defface notmuch-search-count
 294   '((t :inherit default))
 295   "Face used in search mode for the count matching the query."
 296   :group 'notmuch)
 297
 298 (defface notmuch-search-subject
 299   '((t :inherit default))
 300   "Face used in search mode for subjects."
 301   :group 'notmuch)
 302
 303 (defface notmuch-search-matching-authors
 304   '((t :inherit default))
 305   "Face used in search mode for authors matching the query."
 306   :group 'notmuch)
 307
 308 (defface notmuch-search-non-matching-authors
 309   '((((class color)
 310       (background dark))
 311      (:foreground "grey30"))
 312     (((class color)
 313       (background light))
 314      (:foreground "grey60"))
 315     (t
 316      (:italic t)))
 317   "Face used in search mode for authors not matching the query."
 318   :group 'notmuch)
 319
 320 (defface notmuch-tag-face
 321   '((((class color)
 322       (background dark))
 323      (:foreground "OliveDrab1"))
 324     (((class color)
 325       (background light))
 326      (:foreground "navy blue" :bold t))
 327     (t
 328      (:bold t)))
 329   "Face used in search mode face for tags."
 330   :group 'notmuch)
 331
 332 ;;;###autoload
 333 (defun notmuch-search-mode ()
 334   "Major mode displaying results of a notmuch search.
 335
 336 This buffer contains the results of a \"notmuch search\" of your
 337 email archives. Each line in the buffer represents a single
 338 thread giving a summary of the thread (a relative date, the
 339 number of matched messages and total messages in the thread,
 340 participants in the thread, a representative subject line, and
 341 any tags).
 342
 343 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 344 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 345 is a convenience for archiving a thread (removing the \"inbox\"
 346 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
 347 threads in the current buffer.
 348
 349 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 350 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 351 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 352 search.
 353
 354 Complete list of currently available key bindings:
 355
 356 \\{notmuch-search-mode-map}"
 357   (interactive)
 358   (kill-all-local-variables)
 359   (make-local-variable 'notmuch-search-query-string)
 360   (make-local-variable 'notmuch-search-oldest-first)
 361   (make-local-variable 'notmuch-search-target-thread)
 362   (make-local-variable 'notmuch-search-target-line)
 363   (set (make-local-variable 'notmuch-search-continuation) nil)
 364   (set (make-local-variable 'scroll-preserve-screen-position) t)
 365   (add-to-invisibility-spec 'notmuch-search)
 366   (use-local-map notmuch-search-mode-map)
 367   (setq truncate-lines t)
 368   (setq major-mode 'notmuch-search-mode
 369         mode-name "notmuch-search")
 370   (setq buffer-read-only t))
 371
 372 (defun notmuch-search-properties-in-region (property beg end)
 373   (save-excursion
 374     (let ((output nil)
 375           (last-line (line-number-at-pos end))
 376           (max-line (- (line-number-at-pos (point-max)) 2)))
 377       (goto-char beg)
 378       (beginning-of-line)
 379       (while (<= (line-number-at-pos) (min last-line max-line))
 380         (setq output (cons (get-text-property (point) property) output))
 381         (forward-line 1))
 382       output)))
 383
 384 (defun notmuch-search-find-thread-id ()
 385   "Return the thread for the current thread"
 386   (get-text-property (point) 'notmuch-search-thread-id))
 387
 388 (defun notmuch-search-find-thread-id-region (beg end)
 389   "Return a list of threads for the current region"
 390   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 391
 392 (defun notmuch-search-find-authors ()
 393   "Return the authors for the current thread"
 394   (get-text-property (point) 'notmuch-search-authors))
 395
 396 (defun notmuch-search-find-authors-region (beg end)
 397   "Return a list of authors for the current region"
 398   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 399
 400 (defun notmuch-search-find-subject ()
 401   "Return the subject for the current thread"
 402   (get-text-property (point) 'notmuch-search-subject))
 403
 404 (defun notmuch-search-find-subject-region (beg end)
 405   "Return a list of authors for the current region"
 406   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 407
 408 (defun notmuch-search-show-thread ()
 409   "Display the currently selected thread."
 410   (interactive)
 411   (let ((thread-id (notmuch-search-find-thread-id))
 412         (subject (notmuch-search-find-subject)))
 413     (if (> (length thread-id) 0)
 414         (notmuch-show thread-id
 415                       (current-buffer)
 416                       notmuch-search-query-string
 417                       ;; name the buffer based on notmuch-search-find-subject
 418                       (if (string-match "^[ \t]*$" subject)
 419                           "[No Subject]"
 420                         (truncate-string-to-width
 421                          (concat "*"
 422                                  (truncate-string-to-width subject 32 nil nil t)
 423                                  "*")
 424                          32 nil nil t)))
 425       (error "End of search results"))))
 426
 427 (defun notmuch-search-reply-to-thread ()
 428   "Begin composing a reply to the entire current thread in a new buffer."
 429   (interactive)
 430   (let ((message-id (notmuch-search-find-thread-id)))
 431     (notmuch-mua-reply message-id)))
 432
 433 (defun notmuch-call-notmuch-process (&rest args)
 434   "Synchronously invoke \"notmuch\" with the given list of arguments.
 435
 436 Output from the process will be presented to the user as an error
 437 and will also appear in a buffer named \"*Notmuch errors*\"."
 438   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 439     (with-current-buffer error-buffer
 440         (erase-buffer))
 441     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 442         (point)
 443       (progn
 444         (with-current-buffer error-buffer
 445           (let ((beg (point-min))
 446                 (end (- (point-max) 1)))
 447             (error (buffer-substring beg end))
 448             ))))))
 449
 450 (defun notmuch-search-set-tags (tags)
 451   (save-excursion
 452     (end-of-line)
 453     (re-search-backward "(")
 454     (forward-char)
 455     (let ((beg (point))
 456           (inhibit-read-only t))
 457       (re-search-forward ")")
 458       (backward-char)
 459       (let ((end (point)))
 460         (delete-region beg end)
 461         (insert (propertize (mapconcat  'identity tags " ")
 462                             'face 'notmuch-tag-face))))))
 463
 464 (defun notmuch-search-get-tags ()
 465   (save-excursion
 466     (end-of-line)
 467     (re-search-backward "(")
 468     (let ((beg (+ (point) 1)))
 469       (re-search-forward ")")
 470       (let ((end (- (point) 1)))
 471         (split-string (buffer-substring beg end))))))
 472
 473 (defun notmuch-search-get-tags-region (beg end)
 474   (save-excursion
 475     (let ((output nil)
 476           (last-line (line-number-at-pos end))
 477           (max-line (- (line-number-at-pos (point-max)) 2)))
 478       (goto-char beg)
 479       (while (<= (line-number-at-pos) (min last-line max-line))
 480         (setq output (append output (notmuch-search-get-tags)))
 481         (forward-line 1))
 482       output)))
 483
 484 (defun notmuch-search-add-tag-thread (tag)
 485   (notmuch-search-add-tag-region tag (point) (point)))
 486
 487 (defun notmuch-search-add-tag-region (tag beg end)
 488   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 489     (notmuch-call-notmuch-process "tag" (concat "+" tag) search-id-string)
 490     (save-excursion
 491       (let ((last-line (line-number-at-pos end))
 492             (max-line (- (line-number-at-pos (point-max)) 2)))
 493         (goto-char beg)
 494         (while (<= (line-number-at-pos) (min last-line max-line))
 495           (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<)))
 496           (forward-line))))))
 497
 498 (defun notmuch-search-remove-tag-thread (tag)
 499   (notmuch-search-remove-tag-region tag (point) (point)))
 500
 501 (defun notmuch-search-remove-tag-region (tag beg end)
 502   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 503     (notmuch-call-notmuch-process "tag" (concat "-" tag) search-id-string)
 504     (save-excursion
 505       (let ((last-line (line-number-at-pos end))
 506             (max-line (- (line-number-at-pos (point-max)) 2)))
 507         (goto-char beg)
 508         (while (<= (line-number-at-pos) (min last-line max-line))
 509           (notmuch-search-set-tags (delete tag (notmuch-search-get-tags)))
 510           (forward-line))))))
 511
 512 (defun notmuch-search-add-tag (tag)
 513   "Add a tag to the currently selected thread or region.
 514
 515 The tag is added to all messages in the currently selected thread
 516 or threads in the current region."
 517   (interactive
 518    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 519   (save-excursion
 520     (if (region-active-p)
 521         (let* ((beg (region-beginning))
 522                (end (region-end)))
 523           (notmuch-search-add-tag-region tag beg end))
 524       (notmuch-search-add-tag-thread tag))))
 525
 526 (defun notmuch-search-remove-tag (tag)
 527   "Remove a tag from the currently selected thread or region.
 528
 529 The tag is removed from all messages in the currently selected
 530 thread or threads in the current region."
 531   (interactive
 532    (list (notmuch-select-tag-with-completion
 533           "Tag to remove: "
 534           (if (region-active-p)
 535               (mapconcat 'identity
 536                          (notmuch-search-find-thread-id-region (region-beginning) (region-end))
 537                          " ")
 538             (notmuch-search-find-thread-id)))))
 539   (save-excursion
 540     (if (region-active-p)
 541         (let* ((beg (region-beginning))
 542                (end (region-end)))
 543           (notmuch-search-remove-tag-region tag beg end))
 544       (notmuch-search-remove-tag-thread tag))))
 545
 546 (defun notmuch-search-archive-thread ()
 547   "Archive the currently selected thread (remove its \"inbox\" tag).
 548
 549 This function advances the next thread when finished."
 550   (interactive)
 551   (notmuch-search-remove-tag-thread "inbox")
 552   (forward-line))
 553
 554 (defun notmuch-search-process-sentinel (proc msg)
 555   "Add a message to let user know when \"notmuch search\" exits"
 556   (let ((buffer (process-buffer proc))
 557         (status (process-status proc))
 558         (exit-status (process-exit-status proc))
 559         (never-found-target-thread nil))
 560     (if (memq status '(exit signal))
 561         (if (buffer-live-p buffer)
 562             (with-current-buffer buffer
 563               (save-excursion
 564                 (let ((inhibit-read-only t)
 565                       (atbob (bobp)))
 566                   (goto-char (point-max))
 567                   (if (eq status 'signal)
 568                       (insert "Incomplete search results (search process was killed).\n"))
 569                   (if (eq status 'exit)
 570                       (progn
 571                         (insert "End of search results.")
 572                         (if (not (= exit-status 0))
 573                             (insert (format " (process returned %d)" exit-status)))
 574                         (insert "\n")
 575                         (if (and atbob
 576                                  (not (string= notmuch-search-target-thread "found")))
 577                             (set 'never-found-target-thread t))))))
 578               (if (and never-found-target-thread
 579                        notmuch-search-target-line)
 580                   (goto-line notmuch-search-target-line)))))))
 581
 582 (defcustom notmuch-search-line-faces nil
 583   "Tag/face mapping for line highlighting in notmuch-search.
 584
 585 Here is an example of how to color search results based on tags.
 586 (the following text would be placed in your ~/.emacs file):
 587
 588 (setq notmuch-search-line-faces '((\"delete\" . '(:foreground \"red\"))
 589                                  (\"unread\" . '(:foreground \"green\"))))
 590
 591 Order matters: for lines with multiple tags, the the first
 592 matching will be applied."
 593   :type '(alist :key-type (string) :value-type (list))
 594   :group 'notmuch)
 595
 596 (defun notmuch-search-color-line (start end line-tag-list)
 597   "Colorize lines in notmuch-show based on tags"
 598   (if notmuch-search-line-faces
 599       (let ((overlay (make-overlay start end))
 600             (tags-faces (copy-alist notmuch-search-line-faces)))
 601         (while tags-faces
 602           (let* ((tag-face (car tags-faces))
 603                  (tag (car tag-face))
 604                  (face (cdr tag-face)))
 605             (cond ((member tag line-tag-list)
 606                    (overlay-put overlay 'face face)
 607                    (setq tags-faces nil))
 608                   (t
 609                    (setq tags-faces (cdr tags-faces)))))))))
 610
 611 (defun notmuch-search-insert-authors (format-string authors)
 612   (insert (let* ((formatted-sample (format format-string ""))
 613                  (formatted-authors (format format-string authors))
 614                  (truncated-string
 615                   (if (> (length formatted-authors)
 616                          (length formatted-sample))
 617                       (concat (substring authors 0 (- (length formatted-sample) 4)) "... ")
 618                     formatted-authors)))
 619             ;; Need to save the match data to avoid interfering with
 620             ;; `notmuch-search-process-filter'.
 621             (save-match-data
 622               (if (string-match "\\(.*\\)|\\(..*\\)" truncated-string)
 623                   (concat (propertize (concat (match-string 1 truncated-string) ",")
 624                                       'face 'notmuch-search-matching-authors)
 625                           (propertize (match-string 2 truncated-string)
 626                                       'face 'notmuch-search-non-matching-authors))
 627                 (propertize truncated-string 'face 'notmuch-search-matching-authors))))))
 628
 629 (defun notmuch-search-insert-field (field date count authors subject tags)
 630   (cond
 631    ((string-equal field "date")
 632     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) date)
 633                         'face 'notmuch-search-date)))
 634    ((string-equal field "count")
 635     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) count)
 636                         'face 'notmuch-search-count)))
 637    ((string-equal field "subject")
 638     (insert (propertize (format (cdr (assoc field notmuch-search-result-format)) subject)
 639                         'face 'notmuch-search-subject)))
 640
 641    ((string-equal field "authors")
 642     (notmuch-search-insert-authors (cdr (assoc field notmuch-search-result-format)) authors))
 643
 644    ((string-equal field "tags")
 645     (insert (concat "(" (propertize tags 'font-lock-face 'notmuch-tag-face) ")")))))
 646
 647 (defun notmuch-search-show-result (date count authors subject tags)
 648   (let ((fields) (field))
 649     (setq fields (mapcar 'car notmuch-search-result-format))
 650     (loop for field in fields
 651           do (notmuch-search-insert-field field date count authors subject tags)))
 652   (insert "\n"))
 653
 654 (defun notmuch-search-process-filter (proc string)
 655   "Process and filter the output of \"notmuch search\""
 656   (let ((buffer (process-buffer proc))
 657         (found-target nil))
 658     (if (buffer-live-p buffer)
 659         (with-current-buffer buffer
 660           (save-excursion
 661             (let ((line 0)
 662                   (more t)
 663                   (inhibit-read-only t))
 664               (while more
 665                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\(.*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 666                     (let* ((thread-id (match-string 1 string))
 667                            (date (match-string 2 string))
 668                            (count (match-string 3 string))
 669                            (authors (match-string 4 string))
 670                            (subject (match-string 5 string))
 671                            (tags (match-string 6 string))
 672                            (tag-list (if tags (save-match-data (split-string tags)))))
 673                       (goto-char (point-max))
 674                       (let ((beg (point-marker)))
 675                         (notmuch-search-show-result date count authors subject tags)
 676                         (notmuch-search-color-line beg (point-marker) tag-list)
 677                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id)
 678                         (put-text-property beg (point-marker) 'notmuch-search-authors authors)
 679                         (put-text-property beg (point-marker) 'notmuch-search-subject subject)
 680                         (if (string= thread-id notmuch-search-target-thread)
 681                             (progn
 682                               (set 'found-target beg)
 683                               (set 'notmuch-search-target-thread "found"))))
 684                       (set 'line (match-end 0)))
 685                   (set 'more nil)))))
 686           (if found-target
 687               (goto-char found-target)))
 688       (delete-process proc))))
 689
 690 (defun notmuch-search-operate-all (action)
 691   "Add/remove tags from all matching messages.
 692
 693 Tis command adds or removes tags from all messages matching the
 694 current search terms. When called interactively, this command
 695 will prompt for tags to be added or removed. Tags prefixed with
 696 '+' will be added and tags prefixed with '-' will be removed.
 697
 698 Each character of the tag name may consist of alphanumeric
 699 characters as well as `_.+-'.
 700 "
 701   (interactive "sOperation (+add -drop): notmuch tag ")
 702   (let ((action-split (split-string action " +")))
 703     ;; Perform some validation
 704     (let ((words action-split))
 705       (when (null words) (error "No operation given"))
 706       (while words
 707         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
 708           (error "Action must be of the form `+thistag -that_tag'"))
 709         (setq words (cdr words))))
 710     (apply 'notmuch-call-notmuch-process "tag"
 711            (append action-split (list notmuch-search-query-string) nil))))
 712
 713 (defun notmuch-search-buffer-title (query)
 714   "Returns the title for a buffer with notmuch search results."
 715   (let* ((saved-search (rassoc-if (lambda (key)
 716                                     (string-match (concat "^" (regexp-quote key))
 717                                                   query))
 718                                   (reverse (notmuch-saved-searches))))
 719          (saved-search-name (car saved-search))
 720          (saved-search-query (cdr saved-search)))
 721     (cond ((and saved-search (equal saved-search-query query))
 722            ;; Query is the same as saved search (ignoring case)
 723            (concat "*notmuch-saved-search-" saved-search-name "*"))
 724           (saved-search
 725            (concat "*notmuch-search-"
 726                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 727                                              (concat "[ " saved-search-name " ]")
 728                                              query)
 729                    "*"))
 730           (t
 731            (concat "*notmuch-search-" query "*"))
 732           )))
 733
 734 ;;;###autoload
 735 (defun notmuch-search (query &optional oldest-first target-thread target-line continuation)
 736   "Run \"notmuch search\" with the given query string and display results.
 737
 738 The optional parameters are used as follows:
 739
 740   oldest-first: A Boolean controlling the sort order of returned threads
 741   target-thread: A thread ID (with the thread: prefix) that will be made
 742                  current if it appears in the search results.
 743   target-line: The line number to move to if the target thread does not
 744                appear in the search results."
 745   (interactive "sNotmuch search: ")
 746   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 747     (switch-to-buffer buffer)
 748     (notmuch-search-mode)
 749     (set 'notmuch-search-query-string query)
 750     (set 'notmuch-search-oldest-first oldest-first)
 751     (set 'notmuch-search-target-thread target-thread)
 752     (set 'notmuch-search-target-line target-line)
 753     (set 'notmuch-search-continuation continuation)
 754     (let ((proc (get-buffer-process (current-buffer)))
 755           (inhibit-read-only t))
 756       (if proc
 757           (error "notmuch search process already running for query `%s'" query)
 758         )
 759       (erase-buffer)
 760       (goto-char (point-min))
 761       (save-excursion
 762         (let ((proc (start-process-shell-command
 763                      "notmuch-search" buffer notmuch-command "search"
 764                      (if oldest-first "--sort=oldest-first" "--sort=newest-first")
 765                      (shell-quote-argument query))))
 766           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 767           (set-process-filter proc 'notmuch-search-process-filter))))
 768     (run-hooks 'notmuch-search-hook)))
 769
 770 (defun notmuch-search-refresh-view ()
 771   "Refresh the current view.
 772
 773 Kills the current buffer and runs a new search with the same
 774 query string as the current search. If the current thread is in
 775 the new search results, then point will be placed on the same
 776 thread. Otherwise, point will be moved to attempt to be in the
 777 same relative position within the new buffer."
 778   (interactive)
 779   (let ((target-line (line-number-at-pos))
 780         (oldest-first notmuch-search-oldest-first)
 781         (target-thread (notmuch-search-find-thread-id))
 782         (query notmuch-search-query-string)
 783         (continuation notmuch-search-continuation))
 784     (kill-this-buffer)
 785     (notmuch-search query oldest-first target-thread target-line continuation)
 786     (goto-char (point-min))))
 787
 788 (defcustom notmuch-poll-script ""
 789   "An external script to incorporate new mail into the notmuch database.
 790
 791 If this variable is non empty, then it should name a script to be
 792 invoked by `notmuch-search-poll-and-refresh-view' and
 793 `notmuch-hello-poll-and-update' (each have a default keybinding
 794 of 'G'). The script could do any of the following depending on
 795 the user's needs:
 796
 797 1. Invoke a program to transfer mail to the local mail store
 798 2. Invoke \"notmuch new\" to incorporate the new mail
 799 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 800   :type 'string
 801   :group 'notmuch)
 802
 803 (defun notmuch-poll ()
 804   "Run external script to import mail.
 805
 806 Invokes `notmuch-poll-script' if it is not set to an empty string."
 807   (interactive)
 808   (if (not (string= notmuch-poll-script ""))
 809       (call-process notmuch-poll-script nil nil)))
 810
 811 (defun notmuch-search-poll-and-refresh-view ()
 812   "Invoke `notmuch-poll' to import mail, then refresh the current view."
 813   (interactive)
 814   (notmuch-poll)
 815   (notmuch-search-refresh-view))
 816
 817 (defun notmuch-search-toggle-order ()
 818   "Toggle the current search order.
 819
 820 By default, the \"inbox\" view created by `notmuch' is displayed
 821 in chronological order (oldest thread at the beginning of the
 822 buffer), while any global searches created by `notmuch-search'
 823 are displayed in reverse-chronological order (newest thread at
 824 the beginning of the buffer).
 825
 826 This command toggles the sort order for the current search.
 827
 828 Note that any filtered searches created by
 829 `notmuch-search-filter' retain the search order of the parent
 830 search."
 831   (interactive)
 832   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 833   (notmuch-search-refresh-view))
 834
 835 (defun notmuch-search-filter (query)
 836   "Filter the current search results based on an additional query string.
 837
 838 Runs a new search matching only messages that match both the
 839 current search results AND the additional query string provided."
 840   (interactive "sFilter search: ")
 841   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 842                            (concat "( " query " )")
 843                          query)))
 844     (notmuch-search (if (string= notmuch-search-query-string "*")
 845                         grouped-query
 846                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 847
 848 (defun notmuch-search-filter-by-tag (tag)
 849   "Filter the current search results based on a single tag.
 850
 851 Runs a new search matching only messages that match both the
 852 current search results AND that are tagged with the given tag."
 853   (interactive
 854    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 855   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 856
 857 ;;;###autoload
 858 (defun notmuch ()
 859   "Run notmuch and display saved searches, known tags, etc."
 860   (interactive)
 861   (notmuch-hello))
 862
 863 (setq mail-user-agent 'notmuch-user-agent)
 864
 865 (provide 'notmuch)