git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-tree)
  58 (require 'notmuch-mua)
  59 (require 'notmuch-hello)
  60 (require 'notmuch-maildir-fcc)
  61 (require 'notmuch-message)
  62 (require 'notmuch-parser)
  63
  64 (unless (require 'notmuch-version nil t)
  65   (defconst notmuch-emacs-version "unknown"
  66     "Placeholder variable when notmuch-version.el[c] is not available."))
  67
  68 (defcustom notmuch-search-result-format
  69   `(("date" . "%12s ")
  70     ("count" . "%-7s ")
  71     ("authors" . "%-20s ")
  72     ("subject" . "%s ")
  73     ("tags" . "(%s)"))
  74   "Search result formatting. Supported fields are:
  75         date, count, authors, subject, tags
  76 For example:
  77         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  78                                              \(\"subject\" . \"%s\"\)\)\)
  79 Line breaks are permitted in format strings (though this is
  80 currently experimental).  Note that a line break at the end of an
  81 \"authors\" field will get elided if the authors list is long;
  82 place it instead at the beginning of the following field.  To
  83 enter a line break when setting this variable with setq, use \\n.
  84 To enter a line break in customize, press \\[quoted-insert] C-j."
  85   :type '(alist :key-type (string) :value-type (string))
  86   :group 'notmuch-search)
  87
  88 ;; The name of this variable `notmuch-init-file' is consistent with the
  89 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  90 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  91 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  92   "Your Notmuch Emacs-Lisp configuration file name.
  93 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  94 it will be read instead.
  95 This file is read once when notmuch is loaded; the notmuch hooks added
  96 there will be called at other points of notmuch execution."
  97   :type 'file
  98   :group 'notmuch)
  99
 100 (defvar notmuch-query-history nil
 101   "Variable to store minibuffer history for notmuch queries")
 102
 103 (defun notmuch-foreach-mime-part (function mm-handle)
 104   (cond ((stringp (car mm-handle))
 105          (dolist (part (cdr mm-handle))
 106            (notmuch-foreach-mime-part function part)))
 107         ((bufferp (car mm-handle))
 108          (funcall function mm-handle))
 109         (t (dolist (part mm-handle)
 110              (notmuch-foreach-mime-part function part)))))
 111
 112 (defun notmuch-count-attachments (mm-handle)
 113   (let ((count 0))
 114     (notmuch-foreach-mime-part
 115      (lambda (p)
 116        (let ((disposition (mm-handle-disposition p)))
 117          (and (listp disposition)
 118               (or (equal (car disposition) "attachment")
 119                   (and (equal (car disposition) "inline")
 120                        (assq 'filename disposition)))
 121               (incf count))))
 122      mm-handle)
 123     count))
 124
 125 (defun notmuch-save-attachments (mm-handle &optional queryp)
 126   (notmuch-foreach-mime-part
 127    (lambda (p)
 128      (let ((disposition (mm-handle-disposition p)))
 129        (and (listp disposition)
 130             (or (equal (car disposition) "attachment")
 131                 (and (equal (car disposition) "inline")
 132                      (assq 'filename disposition)))
 133             (or (not queryp)
 134                 (y-or-n-p
 135                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 136             (mm-save-part p))))
 137    mm-handle))
 138
 139 (require 'hl-line)
 140
 141 (defun notmuch-hl-line-mode ()
 142   (prog1 (hl-line-mode)
 143     (when hl-line-overlay
 144       (overlay-put hl-line-overlay 'priority 1))))
 145
 146 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 147   "List of functions to call when notmuch displays the search results."
 148   :type 'hook
 149   :options '(notmuch-hl-line-mode)
 150   :group 'notmuch-search
 151   :group 'notmuch-hooks)
 152
 153 (defvar notmuch-search-mode-map
 154   (let ((map (make-sparse-keymap)))
 155     (set-keymap-parent map notmuch-common-keymap)
 156     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
 157     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 158     (define-key map "b" 'notmuch-search-scroll-down)
 159     (define-key map " " 'notmuch-search-scroll-up)
 160     (define-key map "<" 'notmuch-search-first-thread)
 161     (define-key map ">" 'notmuch-search-last-thread)
 162     (define-key map "p" 'notmuch-search-previous-thread)
 163     (define-key map "n" 'notmuch-search-next-thread)
 164     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 165     (define-key map "R" 'notmuch-search-reply-to-thread)
 166     (define-key map "o" 'notmuch-search-toggle-order)
 167     (define-key map "c" 'notmuch-search-stash-map)
 168     (define-key map "t" 'notmuch-search-filter-by-tag)
 169     (define-key map "f" 'notmuch-search-filter)
 170     (define-key map [mouse-1] 'notmuch-search-show-thread)
 171     (define-key map "*" 'notmuch-search-tag-all)
 172     (define-key map "a" 'notmuch-search-archive-thread)
 173     (define-key map "-" 'notmuch-search-remove-tag)
 174     (define-key map "+" 'notmuch-search-add-tag)
 175     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 176     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 177     map)
 178   "Keymap for \"notmuch search\" buffers.")
 179 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 180
 181 (defvar notmuch-search-stash-map
 182   (let ((map (make-sparse-keymap)))
 183     (define-key map "i" 'notmuch-search-stash-thread-id)
 184     (define-key map "q" 'notmuch-stash-query)
 185     (define-key map "?" 'notmuch-subkeymap-help)
 186     map)
 187   "Submap for stash commands")
 188 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 189
 190 (defun notmuch-search-stash-thread-id ()
 191   "Copy thread ID of current thread to kill-ring."
 192   (interactive)
 193   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 194
 195 (defun notmuch-stash-query ()
 196   "Copy current query to kill-ring."
 197   (interactive)
 198   (notmuch-common-do-stash (notmuch-search-get-query)))
 199
 200 (defvar notmuch-search-query-string)
 201 (defvar notmuch-search-target-thread)
 202 (defvar notmuch-search-target-line)
 203
 204 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 205
 206 (defun notmuch-search-scroll-up ()
 207   "Move forward through search results by one window's worth."
 208   (interactive)
 209   (condition-case nil
 210       (scroll-up nil)
 211     ((end-of-buffer) (notmuch-search-last-thread))))
 212
 213 (defun notmuch-search-scroll-down ()
 214   "Move backward through the search results by one window's worth."
 215   (interactive)
 216   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 217   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 218   ;;
 219   ;; So instead of trapping a signal we instead check whether the
 220   ;; window begins on the first line of the buffer and if so, move
 221   ;; directly to that position. (We have to count lines since the
 222   ;; window-start position is not the same as point-min due to the
 223   ;; invisible thread-ID characters on the first line.
 224   (if (equal (count-lines (point-min) (window-start)) 0)
 225       (goto-char (point-min))
 226     (scroll-down nil)))
 227
 228 (defun notmuch-search-next-thread ()
 229   "Select the next thread in the search results."
 230   (interactive)
 231   (when (notmuch-search-get-result)
 232     (goto-char (notmuch-search-result-end))))
 233
 234 (defun notmuch-search-previous-thread ()
 235   "Select the previous thread in the search results."
 236   (interactive)
 237   (if (notmuch-search-get-result)
 238       (unless (bobp)
 239         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 240     ;; We must be past the end; jump to the last result
 241     (notmuch-search-last-thread)))
 242
 243 (defun notmuch-search-last-thread ()
 244   "Select the last thread in the search results."
 245   (interactive)
 246   (goto-char (point-max))
 247   (forward-line -2)
 248   (let ((beg (notmuch-search-result-beginning)))
 249     (when beg (goto-char beg))))
 250
 251 (defun notmuch-search-first-thread ()
 252   "Select the first thread in the search results."
 253   (interactive)
 254   (goto-char (point-min)))
 255
 256 (defface notmuch-message-summary-face
 257  '((((class color) (background light)) (:background "#f0f0f0"))
 258    (((class color) (background dark)) (:background "#303030")))
 259  "Face for the single-line message summary in notmuch-show-mode."
 260  :group 'notmuch-show
 261  :group 'notmuch-faces)
 262
 263 (defface notmuch-search-date
 264   '((t :inherit default))
 265   "Face used in search mode for dates."
 266   :group 'notmuch-search
 267   :group 'notmuch-faces)
 268
 269 (defface notmuch-search-count
 270   '((t :inherit default))
 271   "Face used in search mode for the count matching the query."
 272   :group 'notmuch-search
 273   :group 'notmuch-faces)
 274
 275 (defface notmuch-search-subject
 276   '((t :inherit default))
 277   "Face used in search mode for subjects."
 278   :group 'notmuch-search
 279   :group 'notmuch-faces)
 280
 281 (defface notmuch-search-matching-authors
 282   '((t :inherit default))
 283   "Face used in search mode for authors matching the query."
 284   :group 'notmuch-search
 285   :group 'notmuch-faces)
 286
 287 (defface notmuch-search-non-matching-authors
 288   '((((class color)
 289       (background dark))
 290      (:foreground "grey30"))
 291     (((class color)
 292       (background light))
 293      (:foreground "grey60"))
 294     (t
 295      (:italic t)))
 296   "Face used in search mode for authors not matching the query."
 297   :group 'notmuch-search
 298   :group 'notmuch-faces)
 299
 300 (defface notmuch-tag-face
 301   '((((class color)
 302       (background dark))
 303      (:foreground "OliveDrab1"))
 304     (((class color)
 305       (background light))
 306      (:foreground "navy blue" :bold t))
 307     (t
 308      (:bold t)))
 309   "Face used in search mode face for tags."
 310   :group 'notmuch-search
 311   :group 'notmuch-faces)
 312
 313 (defun notmuch-search-mode ()
 314   "Major mode displaying results of a notmuch search.
 315
 316 This buffer contains the results of a \"notmuch search\" of your
 317 email archives. Each line in the buffer represents a single
 318 thread giving a summary of the thread (a relative date, the
 319 number of matched messages and total messages in the thread,
 320 participants in the thread, a representative subject line, and
 321 any tags).
 322
 323 Pressing \\[notmuch-search-show-thread] on any line displays that
 324 thread. The '\\[notmuch-search-add-tag]' and
 325 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 326 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 327 is a convenience for archiving a thread (applying changes in
 328 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 329 be used to add and/or remove tags from all messages (as opposed
 330 to threads) that match the current query.  Use with caution, as
 331 this will also tag matching messages that arrived *after*
 332 constructing the buffer.
 333
 334 Other useful commands are '\\[notmuch-search-filter]' for
 335 filtering the current search based on an additional query string,
 336 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 337 messages with a given tag, and '\\[notmuch-search]' to execute a
 338 new, global search.
 339
 340 Complete list of currently available key bindings:
 341
 342 \\{notmuch-search-mode-map}"
 343   (interactive)
 344   (kill-all-local-variables)
 345   (make-local-variable 'notmuch-search-query-string)
 346   (make-local-variable 'notmuch-search-oldest-first)
 347   (make-local-variable 'notmuch-search-target-thread)
 348   (make-local-variable 'notmuch-search-target-line)
 349   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 350   (set (make-local-variable 'scroll-preserve-screen-position) t)
 351   (add-to-invisibility-spec (cons 'ellipsis t))
 352   (use-local-map notmuch-search-mode-map)
 353   (setq truncate-lines t)
 354   (setq major-mode 'notmuch-search-mode
 355         mode-name "notmuch-search")
 356   (setq buffer-read-only t))
 357
 358 (defun notmuch-search-get-result (&optional pos)
 359   "Return the result object for the thread at POS (or point).
 360
 361 If there is no thread at POS (or point), returns nil."
 362   (get-text-property (or pos (point)) 'notmuch-search-result))
 363
 364 (defun notmuch-search-result-beginning (&optional pos)
 365   "Return the point at the beginning of the thread at POS (or point).
 366
 367 If there is no thread at POS (or point), returns nil."
 368   (when (notmuch-search-get-result pos)
 369     ;; We pass 1+point because previous-single-property-change starts
 370     ;; searching one before the position we give it.
 371     (previous-single-property-change (1+ (or pos (point)))
 372                                      'notmuch-search-result nil (point-min))))
 373
 374 (defun notmuch-search-result-end (&optional pos)
 375   "Return the point at the end of the thread at POS (or point).
 376
 377 The returned point will be just after the newline character that
 378 ends the result line.  If there is no thread at POS (or point),
 379 returns nil"
 380   (when (notmuch-search-get-result pos)
 381     (next-single-property-change (or pos (point)) 'notmuch-search-result
 382                                  nil (point-max))))
 383
 384 (defun notmuch-search-foreach-result (beg end function)
 385   "Invoke FUNCTION for each result between BEG and END.
 386
 387 FUNCTION should take one argument.  It will be applied to the
 388 character position of the beginning of each result that overlaps
 389 the region between points BEG and END.  As a special case, if (=
 390 BEG END), FUNCTION will be applied to the result containing point
 391 BEG."
 392
 393   (lexical-let ((pos (notmuch-search-result-beginning beg))
 394                 ;; End must be a marker in case function changes the
 395                 ;; text.
 396                 (end (copy-marker end))
 397                 ;; Make sure we examine at least one result, even if
 398                 ;; (= beg end).
 399                 (first t))
 400     ;; We have to be careful if the region extends beyond the results.
 401     ;; In this case, pos could be null or there could be no result at
 402     ;; pos.
 403     (while (and pos (or (< pos end) first))
 404       (when (notmuch-search-get-result pos)
 405         (funcall function pos))
 406       (setq pos (notmuch-search-result-end pos)
 407             first nil))))
 408 ;; Unindent the function argument of notmuch-search-foreach-result so
 409 ;; the indentation of callers doesn't get out of hand.
 410 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 411
 412 (defun notmuch-search-properties-in-region (property beg end)
 413   (let (output)
 414     (notmuch-search-foreach-result beg end
 415       (lambda (pos)
 416         (push (plist-get (notmuch-search-get-result pos) property) output)))
 417     output))
 418
 419 (defun notmuch-search-find-thread-id (&optional bare)
 420   "Return the thread for the current thread
 421
 422 If BARE is set then do not prefix with \"thread:\""
 423   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 424     (when thread (concat (unless bare "thread:") thread))))
 425
 426 (defun notmuch-search-find-stable-query ()
 427   "Return the stable queries for the current thread.
 428
 429 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 430 matched and unmatched messages in the current thread."
 431   (plist-get (notmuch-search-get-result) :query))
 432
 433 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 434   "Return the stable query for the current region.
 435
 436 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 437 is nil, include both matched and unmatched messages. If there are
 438 no messages in the region then return nil."
 439   (let ((query-list nil) (all (not only-matched)))
 440     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 441       (when (first queries)
 442         (push (first queries) query-list))
 443       (when (and all (second queries))
 444         (push (second queries) query-list)))
 445     (when query-list
 446       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 447
 448 (defun notmuch-search-find-authors ()
 449   "Return the authors for the current thread"
 450   (plist-get (notmuch-search-get-result) :authors))
 451
 452 (defun notmuch-search-find-authors-region (beg end)
 453   "Return a list of authors for the current region"
 454   (notmuch-search-properties-in-region :authors beg end))
 455
 456 (defun notmuch-search-find-subject ()
 457   "Return the subject for the current thread"
 458   (plist-get (notmuch-search-get-result) :subject))
 459
 460 (defun notmuch-search-find-subject-region (beg end)
 461   "Return a list of authors for the current region"
 462   (notmuch-search-properties-in-region :subject beg end))
 463
 464 (defun notmuch-search-show-thread (&optional elide-toggle)
 465   "Display the currently selected thread."
 466   (interactive "P")
 467   (let ((thread-id (notmuch-search-find-thread-id))
 468         (subject (notmuch-search-find-subject)))
 469     (if (> (length thread-id) 0)
 470         (notmuch-show thread-id
 471                       elide-toggle
 472                       (current-buffer)
 473                       notmuch-search-query-string
 474                       ;; Name the buffer based on the subject.
 475                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 476       (message "End of search results."))))
 477
 478 (defun notmuch-tree-from-search-current-query ()
 479   "Call notmuch tree with the current query"
 480   (interactive)
 481   (notmuch-tree notmuch-search-query-string))
 482
 483 (defun notmuch-tree-from-search-thread ()
 484   "Show the selected thread with notmuch-tree"
 485   (interactive)
 486   (notmuch-tree (notmuch-search-find-thread-id)
 487                 notmuch-search-query-string
 488                 nil
 489                 (notmuch-prettify-subject (notmuch-search-find-subject))
 490                 t))
 491
 492 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 493   "Begin composing a reply-all to the entire current thread in a new buffer."
 494   (interactive "P")
 495   (let ((message-id (notmuch-search-find-thread-id)))
 496     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 497
 498 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 499   "Begin composing a reply to the entire current thread in a new buffer."
 500   (interactive "P")
 501   (let ((message-id (notmuch-search-find-thread-id)))
 502     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 503
 504 (defun notmuch-search-set-tags (tags &optional pos)
 505   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 506     (notmuch-search-update-result new-result pos)))
 507
 508 (defun notmuch-search-get-tags (&optional pos)
 509   (plist-get (notmuch-search-get-result pos) :tags))
 510
 511 (defun notmuch-search-get-tags-region (beg end)
 512   (let (output)
 513     (notmuch-search-foreach-result beg end
 514       (lambda (pos)
 515         (setq output (append output (notmuch-search-get-tags pos)))))
 516     output))
 517
 518 (defun notmuch-search-interactive-region ()
 519   "Return the bounds of the current interactive region.
 520
 521 This returns (BEG END), where BEG and END are the bounds of the
 522 region if the region is active, or both `point' otherwise."
 523   (if (region-active-p)
 524       (list (region-beginning) (region-end))
 525     (list (point) (point))))
 526
 527 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 528   "Prompt for tag changes for the current thread or region.
 529
 530 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 531   (let* ((region (notmuch-search-interactive-region))
 532          (beg (first region)) (end (second region))
 533          (prompt (if (= beg end) "Tag thread" "Tag region")))
 534     (cons (notmuch-read-tag-changes
 535            (notmuch-search-get-tags-region beg end) prompt initial-input)
 536           region)))
 537
 538 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 539   "Change tags for the currently selected thread or region.
 540
 541 See `notmuch-tag' for information on the format of TAG-CHANGES.
 542 When called interactively, this uses the region if the region is
 543 active.  When called directly, BEG and END provide the region.
 544 If these are nil or not provided, this applies to the thread at
 545 point.
 546
 547 If ONLY-MATCHED is non-nil, only tag matched messages."
 548   (interactive (notmuch-search-interactive-tag-changes))
 549   (unless (and beg end) (setq beg (point) end (point)))
 550   (let ((search-string (notmuch-search-find-stable-query-region
 551                         beg end only-matched)))
 552     (notmuch-tag search-string tag-changes)
 553     (notmuch-search-foreach-result beg end
 554       (lambda (pos)
 555         (notmuch-search-set-tags
 556          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 557          pos)))))
 558
 559 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 560   "Change tags for the current thread or region (defaulting to add).
 561
 562 Same as `notmuch-search-tag' but sets initial input to '+'."
 563   (interactive (notmuch-search-interactive-tag-changes "+"))
 564   (notmuch-search-tag tag-changes beg end))
 565
 566 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 567   "Change tags for the current thread or region (defaulting to remove).
 568
 569 Same as `notmuch-search-tag' but sets initial input to '-'."
 570   (interactive (notmuch-search-interactive-tag-changes "-"))
 571   (notmuch-search-tag tag-changes beg end))
 572
 573 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 574      "Un-archive the currently selected thread.")
 575 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 576   "Archive the currently selected thread or region.
 577
 578 Archive each message in the currently selected thread by applying
 579 the tag changes in `notmuch-archive-tags' to each (remove the
 580 \"inbox\" tag by default). If a prefix argument is given, the
 581 messages will be \"unarchived\" (i.e. the tag changes in
 582 `notmuch-archive-tags' will be reversed).
 583
 584 This function advances the next thread when finished."
 585   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 586   (when notmuch-archive-tags
 587     (notmuch-search-tag
 588      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 589   (when (eq beg end)
 590     (notmuch-search-next-thread)))
 591
 592 (defun notmuch-search-update-result (result &optional pos)
 593   "Replace the result object of the thread at POS (or point) by
 594 RESULT and redraw it.
 595
 596 This will keep point in a reasonable location.  However, if there
 597 are enclosing save-excursions and the saved point is in the
 598 result being updated, the point will be restored to the beginning
 599 of the result."
 600   (let ((start (notmuch-search-result-beginning pos))
 601         (end (notmuch-search-result-end pos))
 602         (init-point (point))
 603         (inhibit-read-only t))
 604     ;; Delete the current thread
 605     (delete-region start end)
 606     ;; Insert the updated thread
 607     (notmuch-search-show-result result start)
 608     ;; If point was inside the old result, make an educated guess
 609     ;; about where to place it now.  Unfortunately, this won't work
 610     ;; with save-excursion (or any other markers that would be nice to
 611     ;; preserve, such as the window start), but there's nothing we can
 612     ;; do about that without a way to retrieve markers in a region.
 613     (when (and (>= init-point start) (<= init-point end))
 614       (let* ((new-end (notmuch-search-result-end start))
 615              (new-point (if (= init-point end)
 616                             new-end
 617                           (min init-point (- new-end 1)))))
 618         (goto-char new-point)))))
 619
 620 (defun notmuch-search-process-sentinel (proc msg)
 621   "Add a message to let user know when \"notmuch search\" exits"
 622   (let ((buffer (process-buffer proc))
 623         (status (process-status proc))
 624         (exit-status (process-exit-status proc))
 625         (never-found-target-thread nil))
 626     (when (memq status '(exit signal))
 627       (catch 'return
 628         (kill-buffer (process-get proc 'parse-buf))
 629         (if (buffer-live-p buffer)
 630             (with-current-buffer buffer
 631               (save-excursion
 632                 (let ((inhibit-read-only t)
 633                       (atbob (bobp)))
 634                   (goto-char (point-max))
 635                   (if (eq status 'signal)
 636                       (insert "Incomplete search results (search process was killed).\n"))
 637                   (when (eq status 'exit)
 638                     (insert "End of search results.\n")
 639                     ;; For version mismatch, there's no point in
 640                     ;; showing the search buffer
 641                     (when (or (= exit-status 20) (= exit-status 21))
 642                       (kill-buffer)
 643                       (throw 'return nil))
 644                     (if (and atbob
 645                              (not (string= notmuch-search-target-thread "found")))
 646                         (set 'never-found-target-thread t)))))
 647               (when (and never-found-target-thread
 648                        notmuch-search-target-line)
 649                   (goto-char (point-min))
 650                   (forward-line (1- notmuch-search-target-line)))))))))
 651
 652 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 653                                        ("flagged" :foreground "blue"))
 654   "Tag/face mapping for line highlighting in notmuch-search.
 655
 656 Here is an example of how to color search results based on tags.
 657  (the following text would be placed in your ~/.emacs file):
 658
 659  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
 660                                    (\"deleted\" . (:foreground \"red\"
 661                                                   :background \"blue\"))))
 662
 663 The attributes defined for matching tags are merged, with earlier
 664 attributes overriding later. A message having both \"deleted\"
 665 and \"unread\" tags with the above settings would have a green
 666 foreground and blue background."
 667   :type '(alist :key-type (string) :value-type (custom-face-edit))
 668   :group 'notmuch-search
 669   :group 'notmuch-faces)
 670
 671 (defun notmuch-search-color-line (start end line-tag-list)
 672   "Colorize lines in `notmuch-show' based on tags."
 673   (mapc (lambda (elem)
 674           (let ((tag (car elem))
 675                 (attributes (cdr elem)))
 676             (when (member tag line-tag-list)
 677               (notmuch-apply-face nil attributes nil start end))))
 678         ;; Reverse the list so earlier entries take precedence
 679         (reverse notmuch-search-line-faces)))
 680
 681 (defun notmuch-search-author-propertize (authors)
 682   "Split `authors' into matching and non-matching authors and
 683 propertize appropriately. If no boundary between authors and
 684 non-authors is found, assume that all of the authors match."
 685   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 686       (concat (propertize (concat (match-string 1 authors) ",")
 687                           'face 'notmuch-search-matching-authors)
 688               (propertize (match-string 2 authors)
 689                           'face 'notmuch-search-non-matching-authors))
 690     (propertize authors 'face 'notmuch-search-matching-authors)))
 691
 692 (defun notmuch-search-insert-authors (format-string authors)
 693   ;; Save the match data to avoid interfering with
 694   ;; `notmuch-search-process-filter'.
 695   (save-match-data
 696     (let* ((formatted-authors (format format-string authors))
 697            (formatted-sample (format format-string ""))
 698            (visible-string formatted-authors)
 699            (invisible-string "")
 700            (padding ""))
 701
 702       ;; Truncate the author string to fit the specification.
 703       (if (> (length formatted-authors)
 704              (length formatted-sample))
 705           (let ((visible-length (- (length formatted-sample)
 706                                    (length "... "))))
 707             ;; Truncate the visible string according to the width of
 708             ;; the display string.
 709             (setq visible-string (substring formatted-authors 0 visible-length)
 710                   invisible-string (substring formatted-authors visible-length))
 711             ;; If possible, truncate the visible string at a natural
 712             ;; break (comma or pipe), as incremental search doesn't
 713             ;; match across the visible/invisible border.
 714             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 715               ;; Second clause is destructive on `visible-string', so
 716               ;; order is important.
 717               (setq invisible-string (concat (match-string 3 visible-string)
 718                                              invisible-string)
 719                     visible-string (concat (match-string 1 visible-string)
 720                                            (match-string 2 visible-string))))
 721             ;; `visible-string' may be shorter than the space allowed
 722             ;; by `format-string'. If so we must insert some padding
 723             ;; after `invisible-string'.
 724             (setq padding (make-string (- (length formatted-sample)
 725                                           (length visible-string)
 726                                           (length "..."))
 727                                        ? ))))
 728
 729       ;; Use different faces to show matching and non-matching authors.
 730       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 731           ;; The visible string contains both matching and
 732           ;; non-matching authors.
 733           (setq visible-string (notmuch-search-author-propertize visible-string)
 734                 ;; The invisible string must contain only non-matching
 735                 ;; authors, as the visible-string contains both.
 736                 invisible-string (propertize invisible-string
 737                                              'face 'notmuch-search-non-matching-authors))
 738         ;; The visible string contains only matching authors.
 739         (setq visible-string (propertize visible-string
 740                                          'face 'notmuch-search-matching-authors)
 741               ;; The invisible string may contain both matching and
 742               ;; non-matching authors.
 743               invisible-string (notmuch-search-author-propertize invisible-string)))
 744
 745       ;; If there is any invisible text, add it as a tooltip to the
 746       ;; visible text.
 747       (when (not (string= invisible-string ""))
 748         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 749
 750       ;; Insert the visible and, if present, invisible author strings.
 751       (insert visible-string)
 752       (when (not (string= invisible-string ""))
 753         (let ((start (point))
 754               overlay)
 755           (insert invisible-string)
 756           (setq overlay (make-overlay start (point)))
 757           (overlay-put overlay 'invisible 'ellipsis)
 758           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 759       (insert padding))))
 760
 761 (defun notmuch-search-insert-field (field format-string result)
 762   (cond
 763    ((string-equal field "date")
 764     (insert (propertize (format format-string (plist-get result :date_relative))
 765                         'face 'notmuch-search-date)))
 766    ((string-equal field "count")
 767     (insert (propertize (format format-string
 768                                 (format "[%s/%s]" (plist-get result :matched)
 769                                         (plist-get result :total)))
 770                         'face 'notmuch-search-count)))
 771    ((string-equal field "subject")
 772     (insert (propertize (format format-string
 773                                 (notmuch-sanitize (plist-get result :subject)))
 774                         'face 'notmuch-search-subject)))
 775
 776    ((string-equal field "authors")
 777     (notmuch-search-insert-authors
 778      format-string (notmuch-sanitize (plist-get result :authors))))
 779
 780    ((string-equal field "tags")
 781     (let ((tags (plist-get result :tags))
 782           (orig-tags (plist-get result :orig-tags)))
 783       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 784
 785 (defun notmuch-search-show-result (result pos)
 786   "Insert RESULT at POS."
 787   ;; Ignore excluded matches
 788   (unless (= (plist-get result :matched) 0)
 789     (save-excursion
 790       (goto-char pos)
 791       (dolist (spec notmuch-search-result-format)
 792         (notmuch-search-insert-field (car spec) (cdr spec) result))
 793       (insert "\n")
 794       (notmuch-search-color-line pos (point) (plist-get result :tags))
 795       (put-text-property pos (point) 'notmuch-search-result result))))
 796
 797 (defun notmuch-search-append-result (result)
 798   "Insert RESULT at the end of the buffer.
 799
 800 This is only called when a result is first inserted so it also
 801 sets the :orig-tag property."
 802   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 803         (pos (point-max)))
 804     (notmuch-search-show-result new-result pos)
 805     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 806       (setq notmuch-search-target-thread "found")
 807       (goto-char pos))))
 808
 809 (defun notmuch-search-process-filter (proc string)
 810   "Process and filter the output of \"notmuch search\""
 811   (let ((results-buf (process-buffer proc))
 812         (parse-buf (process-get proc 'parse-buf))
 813         (inhibit-read-only t)
 814         done)
 815     (when (buffer-live-p results-buf)
 816       (with-current-buffer parse-buf
 817         ;; Insert new data
 818         (save-excursion
 819           (goto-char (point-max))
 820           (insert string))
 821         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 822                                          results-buf)))))
 823
 824 (defun notmuch-search-tag-all (tag-changes)
 825   "Add/remove tags from all messages in current search buffer.
 826
 827 See `notmuch-tag' for information on the format of TAG-CHANGES."
 828   (interactive
 829    (list (notmuch-read-tag-changes
 830           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 831   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 832
 833 (defun notmuch-search-buffer-title (query)
 834   "Returns the title for a buffer with notmuch search results."
 835   (let* ((saved-search
 836           (let (longest
 837                 (longest-length 0))
 838             (loop for tuple in notmuch-saved-searches
 839                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
 840                        (and (string-match (concat "^" quoted-query) query)
 841                             (> (length (match-string 0 query))
 842                                longest-length)))
 843                   do (setq longest tuple))
 844             longest))
 845          (saved-search-name (notmuch-saved-search-get saved-search :name))
 846          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 847     (cond ((and saved-search (equal saved-search-query query))
 848            ;; Query is the same as saved search (ignoring case)
 849            (concat "*notmuch-saved-search-" saved-search-name "*"))
 850           (saved-search
 851            (concat "*notmuch-search-"
 852                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 853                                              (concat "[ " saved-search-name " ]")
 854                                              query)
 855                    "*"))
 856           (t
 857            (concat "*notmuch-search-" query "*"))
 858           )))
 859
 860 (defun notmuch-read-query (prompt)
 861   "Read a notmuch-query from the minibuffer with completion.
 862
 863 PROMPT is the string to prompt with."
 864   (lexical-let*
 865       ((all-tags
 866         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
 867                 (process-lines notmuch-command "search" "--output=tags" "*")))
 868        (completions
 869          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 870                        "subject:" "attachment:" "mimetype:")
 871                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
 872                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags))))
 873     (let ((keymap (copy-keymap minibuffer-local-map))
 874           (current-query (case major-mode
 875                            (notmuch-search-mode (notmuch-search-get-query))
 876                            (notmuch-show-mode (notmuch-show-get-query))
 877                            (notmuch-tree-mode (notmuch-tree-get-query))))
 878           (minibuffer-completion-table
 879            (completion-table-dynamic
 880             (lambda (string)
 881               ;; generate a list of possible completions for the current input
 882               (cond
 883                ;; this ugly regexp is used to get the last word of the input
 884                ;; possibly preceded by a '('
 885                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 886                 (mapcar (lambda (compl)
 887                           (concat (match-string-no-properties 1 string) compl))
 888                         (all-completions (match-string-no-properties 2 string)
 889                                          completions)))
 890                (t (list string)))))))
 891       ;; this was simpler than convincing completing-read to accept spaces:
 892       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 893       (let ((history-delete-duplicates t))
 894         (read-from-minibuffer prompt nil keymap nil
 895                               'notmuch-search-history current-query nil)))))
 896
 897 (defun notmuch-search-get-query ()
 898   "Return the current query in this search buffer"
 899   notmuch-search-query-string)
 900
 901 ;;;###autoload
 902 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 903 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 904   "Display threads matching QUERY in a notmuch-search buffer.
 905
 906 If QUERY is nil, it is read interactively from the minibuffer.
 907 Other optional parameters are used as follows:
 908
 909   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 910   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 911                  current if it appears in the search results.
 912   TARGET-LINE: The line number to move to if the target thread does not
 913                appear in the search results.
 914
 915 When called interactively, this will prompt for a query and use
 916 the configured default sort order."
 917   (interactive
 918    (list
 919     ;; Prompt for a query
 920     nil
 921     ;; Use the default search order (if we're doing a search from a
 922     ;; search buffer, ignore any buffer-local overrides)
 923     (default-value 'notmuch-search-oldest-first)))
 924
 925   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 926          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 927     (switch-to-buffer buffer)
 928     (notmuch-search-mode)
 929     ;; Don't track undo information for this buffer
 930     (set 'buffer-undo-list t)
 931     (set 'notmuch-search-query-string query)
 932     (set 'notmuch-search-oldest-first oldest-first)
 933     (set 'notmuch-search-target-thread target-thread)
 934     (set 'notmuch-search-target-line target-line)
 935     (notmuch-tag-clear-cache)
 936     (let ((proc (get-buffer-process (current-buffer)))
 937           (inhibit-read-only t))
 938       (if proc
 939           (error "notmuch search process already running for query `%s'" query)
 940         )
 941       (erase-buffer)
 942       (goto-char (point-min))
 943       (save-excursion
 944         (let ((proc (notmuch-start-notmuch
 945                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 946                      "search" "--format=sexp" "--format-version=2"
 947                      (if oldest-first
 948                          "--sort=oldest-first"
 949                        "--sort=newest-first")
 950                      query))
 951               ;; Use a scratch buffer to accumulate partial output.
 952               ;; This buffer will be killed by the sentinel, which
 953               ;; should be called no matter how the process dies.
 954               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 955           (process-put proc 'parse-buf parse-buf)
 956           (set-process-filter proc 'notmuch-search-process-filter)
 957           (set-process-query-on-exit-flag proc nil))))
 958     (run-hooks 'notmuch-search-hook)))
 959
 960 (defun notmuch-search-refresh-view ()
 961   "Refresh the current view.
 962
 963 Kills the current buffer and runs a new search with the same
 964 query string as the current search. If the current thread is in
 965 the new search results, then point will be placed on the same
 966 thread. Otherwise, point will be moved to attempt to be in the
 967 same relative position within the new buffer."
 968   (let ((target-line (line-number-at-pos))
 969         (oldest-first notmuch-search-oldest-first)
 970         (target-thread (notmuch-search-find-thread-id 'bare))
 971         (query notmuch-search-query-string))
 972     (notmuch-bury-or-kill-this-buffer)
 973     (notmuch-search query oldest-first target-thread target-line)
 974     (goto-char (point-min))))
 975
 976 (defun notmuch-search-toggle-order ()
 977   "Toggle the current search order.
 978
 979 This command toggles the sort order for the current search. The
 980 default sort order is defined by `notmuch-search-oldest-first'."
 981   (interactive)
 982   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 983   (notmuch-search-refresh-view))
 984
 985 (defun notmuch-search-filter (query)
 986   "Filter the current search results based on an additional query string.
 987
 988 Runs a new search matching only messages that match both the
 989 current search results AND the additional query string provided."
 990   (interactive (list (notmuch-read-query "Filter search: ")))
 991   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 992                            (concat "( " query " )")
 993                          query)))
 994     (notmuch-search (if (string= notmuch-search-query-string "*")
 995                         grouped-query
 996                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 997
 998 (defun notmuch-search-filter-by-tag (tag)
 999   "Filter the current search results based on a single tag.
1000
1001 Runs a new search matching only messages that match both the
1002 current search results AND that are tagged with the given tag."
1003   (interactive
1004    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1005   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1006
1007 ;;;###autoload
1008 (defun notmuch ()
1009   "Run notmuch and display saved searches, known tags, etc."
1010   (interactive)
1011   (notmuch-hello))
1012
1013 (defun notmuch-interesting-buffer (b)
1014   "Is the current buffer of interest to a notmuch user?"
1015   (with-current-buffer b
1016     (memq major-mode '(notmuch-show-mode
1017                        notmuch-search-mode
1018                        notmuch-hello-mode
1019                        message-mode))))
1020
1021 ;;;###autoload
1022 (defun notmuch-cycle-notmuch-buffers ()
1023   "Cycle through any existing notmuch buffers (search, show or hello).
1024
1025 If the current buffer is the only notmuch buffer, bury it. If no
1026 notmuch buffers exist, run `notmuch'."
1027   (interactive)
1028
1029   (let (start first)
1030     ;; If the current buffer is a notmuch buffer, remember it and then
1031     ;; bury it.
1032     (when (notmuch-interesting-buffer (current-buffer))
1033       (setq start (current-buffer))
1034       (bury-buffer))
1035
1036     ;; Find the first notmuch buffer.
1037     (setq first (loop for buffer in (buffer-list)
1038                      if (notmuch-interesting-buffer buffer)
1039                      return buffer))
1040
1041     (if first
1042         ;; If the first one we found is any other than the starting
1043         ;; buffer, switch to it.
1044         (unless (eq first start)
1045           (switch-to-buffer first))
1046       (notmuch))))
1047
1048 (setq mail-user-agent 'notmuch-user-agent)
1049
1050 (provide 'notmuch)
1051
1052 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1053 (if init-file-user ; don't load init file if the -q option was used.
1054     (let ((init-file (locate-file notmuch-init-file '("/")
1055                                   (get-load-suffixes))))
1056       (if init-file (load init-file nil t t))))