git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-show)
  56 (require 'notmuch-mua)
  57 (require 'notmuch-hello)
  58 (require 'notmuch-maildir-fcc)
  59 (require 'notmuch-message)
  60
  61 (defcustom notmuch-search-result-format
  62   `(("date" . "%s ")
  63     ("count" . "%-7s ")
  64     ("authors" . "%-20s ")
  65     ("subject" . "%s ")
  66     ("tags" . "(%s)"))
  67   "Search result formating. Supported fields are:
  68         date, count, authors, subject, tags
  69 For example:
  70         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  71                                              \(\"subject\" . \"%s\"\)\)\)"
  72   :type '(alist :key-type (string) :value-type (string))
  73   :group 'notmuch)
  74
  75 (defun notmuch-select-tag-with-completion (prompt &rest search-terms)
  76   (let ((tag-list
  77          (with-output-to-string
  78            (with-current-buffer standard-output
  79              (apply 'call-process notmuch-command nil t nil "search-tags" search-terms)))))
  80     (completing-read prompt (split-string tag-list "\n+" t) nil nil nil)))
  81
  82 (defun notmuch-foreach-mime-part (function mm-handle)
  83   (cond ((stringp (car mm-handle))
  84          (dolist (part (cdr mm-handle))
  85            (notmuch-foreach-mime-part function part)))
  86         ((bufferp (car mm-handle))
  87          (funcall function mm-handle))
  88         (t (dolist (part mm-handle)
  89              (notmuch-foreach-mime-part function part)))))
  90
  91 (defun notmuch-count-attachments (mm-handle)
  92   (let ((count 0))
  93     (notmuch-foreach-mime-part
  94      (lambda (p)
  95        (let ((disposition (mm-handle-disposition p)))
  96          (and (listp disposition)
  97               (or (equal (car disposition) "attachment")
  98                   (and (equal (car disposition) "inline")
  99                        (assq 'filename disposition)))
 100               (incf count))))
 101      mm-handle)
 102     count))
 103
 104 (defun notmuch-save-attachments (mm-handle &optional queryp)
 105   (notmuch-foreach-mime-part
 106    (lambda (p)
 107      (let ((disposition (mm-handle-disposition p)))
 108        (and (listp disposition)
 109             (or (equal (car disposition) "attachment")
 110                 (and (equal (car disposition) "inline")
 111                      (assq 'filename disposition)))
 112             (or (not queryp)
 113                 (y-or-n-p
 114                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 115             (mm-save-part p))))
 116    mm-handle))
 117
 118 (defun notmuch-documentation-first-line (symbol)
 119   "Return the first line of the documentation string for SYMBOL."
 120   (let ((doc (documentation symbol)))
 121     (if doc
 122         (with-temp-buffer
 123           (insert (documentation symbol t))
 124           (goto-char (point-min))
 125           (let ((beg (point)))
 126             (end-of-line)
 127             (buffer-substring beg (point))))
 128       "")))
 129
 130 (defun notmuch-prefix-key-description (key)
 131   "Given a prefix key code, return a human-readable string representation.
 132
 133 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 134   (let ((desc (format-kbd-macro (vector key))))
 135     (if (string= desc "ESC")
 136         "M-"
 137       (concat desc " "))))
 138
 139 ; I would think that emacs would have code handy for walking a keymap
 140 ; and generating strings for each key, and I would prefer to just call
 141 ; that. But I couldn't find any (could be all implemented in C I
 142 ; suppose), so I wrote my own here.
 143 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 144   "For a key binding, return a string showing a human-readable
 145 representation of the prefixed key as well as the first line of
 146 documentation from the bound function.
 147
 148 For a mouse binding, return nil."
 149   (let ((key (car binding))
 150         (action (cdr binding)))
 151     (if (mouse-event-p key)
 152         nil
 153       (if (keymapp action)
 154           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 155                 (as-list))
 156             (map-keymap (lambda (a b)
 157                           (push (cons a b) as-list))
 158                         action)
 159             (mapconcat substitute as-list "\n"))
 160         (concat prefix (format-kbd-macro (vector key))
 161                 "\t"
 162                 (notmuch-documentation-first-line action))))))
 163
 164 (defalias 'notmuch-substitute-one-command-key
 165   (apply-partially 'notmuch-substitute-one-command-key-with-prefix nil))
 166
 167 (defun notmuch-substitute-command-keys (doc)
 168   "Like `substitute-command-keys' but with documentation, not function names."
 169   (let ((beg 0))
 170     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 171       (let ((map (substring doc (match-beginning 1) (match-end 1))))
 172         (setq doc (replace-match (mapconcat 'notmuch-substitute-one-command-key
 173                                             (cdr (symbol-value (intern map))) "\n") 1 1 doc)))
 174       (setq beg (match-end 0)))
 175     doc))
 176
 177 (defun notmuch-help ()
 178   "Display help for the current notmuch mode."
 179   (interactive)
 180   (let* ((mode major-mode)
 181          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 182     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 183       (insert doc)
 184       (goto-char (point-min))
 185       (set-buffer-modified-p nil)
 186       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 187
 188 (defcustom notmuch-search-hook '(hl-line-mode)
 189   "List of functions to call when notmuch displays the search results."
 190   :type 'hook
 191   :options '(hl-line-mode)
 192   :group 'notmuch)
 193
 194 (defvar notmuch-search-mode-map
 195   (let ((map (make-sparse-keymap)))
 196     (define-key map "?" 'notmuch-help)
 197     (define-key map "q" 'notmuch-search-quit)
 198     (define-key map "x" 'notmuch-search-quit)
 199     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 200     (define-key map "b" 'notmuch-search-scroll-down)
 201     (define-key map " " 'notmuch-search-scroll-up)
 202     (define-key map "<" 'notmuch-search-first-thread)
 203     (define-key map ">" 'notmuch-search-last-thread)
 204     (define-key map "p" 'notmuch-search-previous-thread)
 205     (define-key map "n" 'notmuch-search-next-thread)
 206     (define-key map "r" 'notmuch-search-reply-to-thread)
 207     (define-key map "m" 'notmuch-mua-mail)
 208     (define-key map "s" 'notmuch-search)
 209     (define-key map "o" 'notmuch-search-toggle-order)
 210     (define-key map "=" 'notmuch-search-refresh-view)
 211     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 212     (define-key map "t" 'notmuch-search-filter-by-tag)
 213     (define-key map "f" 'notmuch-search-filter)
 214     (define-key map [mouse-1] 'notmuch-search-show-thread)
 215     (define-key map "*" 'notmuch-search-operate-all)
 216     (define-key map "a" 'notmuch-search-archive-thread)
 217     (define-key map "-" 'notmuch-search-remove-tag)
 218     (define-key map "+" 'notmuch-search-add-tag)
 219     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 220     map)
 221   "Keymap for \"notmuch search\" buffers.")
 222 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 223
 224 (defvar notmuch-search-query-string)
 225 (defvar notmuch-search-target-thread)
 226 (defvar notmuch-search-target-line)
 227 (defvar notmuch-search-continuation)
 228
 229 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 230
 231 (defun notmuch-search-quit ()
 232   "Exit the search buffer, calling any defined continuation function."
 233   (interactive)
 234   (let ((continuation notmuch-search-continuation))
 235     (kill-this-buffer)
 236     (when continuation
 237       (funcall continuation))))
 238
 239 (defun notmuch-search-scroll-up ()
 240   "Move forward through search results by one window's worth."
 241   (interactive)
 242   (condition-case nil
 243       (scroll-up nil)
 244     ((end-of-buffer) (notmuch-search-last-thread))))
 245
 246 (defun notmuch-search-scroll-down ()
 247   "Move backward through the search results by one window's worth."
 248   (interactive)
 249   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 250   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 251   ;
 252   ; So instead of trapping a signal we instead check whether the
 253   ; window begins on the first line of the buffer and if so, move
 254   ; directly to that position. (We have to count lines since the
 255   ; window-start position is not the same as point-min due to the
 256   ; invisible thread-ID characters on the first line.
 257   (if (equal (count-lines (point-min) (window-start)) 0)
 258       (goto-char (point-min))
 259     (scroll-down nil)))
 260
 261 (defun notmuch-search-next-thread ()
 262   "Select the next thread in the search results."
 263   (interactive)
 264   (forward-line 1))
 265
 266 (defun notmuch-search-previous-thread ()
 267   "Select the previous thread in the search results."
 268   (interactive)
 269   (forward-line -1))
 270
 271 (defun notmuch-search-last-thread ()
 272   "Select the last thread in the search results."
 273   (interactive)
 274   (goto-char (point-max))
 275   (forward-line -2))
 276
 277 (defun notmuch-search-first-thread ()
 278   "Select the first thread in the search results."
 279   (interactive)
 280   (goto-char (point-min)))
 281
 282 (defface notmuch-message-summary-face
 283  '((((class color) (background light)) (:background "#f0f0f0"))
 284    (((class color) (background dark)) (:background "#303030")))
 285  "Face for the single-line message summary in notmuch-show-mode."
 286  :group 'notmuch)
 287
 288 (defface notmuch-tag-face
 289   '((((class color)
 290       (background dark))
 291      (:foreground "OliveDrab1"))
 292     (((class color)
 293       (background light))
 294      (:foreground "navy blue" :bold t))
 295     (t
 296      (:bold t)))
 297   "Notmuch search mode face used to highligh tags."
 298   :group 'notmuch)
 299
 300 ;;;###autoload
 301 (defun notmuch-search-mode ()
 302   "Major mode displaying results of a notmuch search.
 303
 304 This buffer contains the results of a \"notmuch search\" of your
 305 email archives. Each line in the buffer represents a single
 306 thread giving a summary of the thread (a relative date, the
 307 number of matched messages and total messages in the thread,
 308 participants in the thread, a representative subject line, and
 309 any tags).
 310
 311 Pressing \\[notmuch-search-show-thread] on any line displays that thread. The '\\[notmuch-search-add-tag]' and '\\[notmuch-search-remove-tag]'
 312 keys can be used to add or remove tags from a thread. The '\\[notmuch-search-archive-thread]' key
 313 is a convenience for archiving a thread (removing the \"inbox\"
 314 tag). The '\\[notmuch-search-operate-all]' key can be used to add or remove a tag from all
 315 threads in the current buffer.
 316
 317 Other useful commands are '\\[notmuch-search-filter]' for filtering the current search
 318 based on an additional query string, '\\[notmuch-search-filter-by-tag]' for filtering to include
 319 only messages with a given tag, and '\\[notmuch-search]' to execute a new, global
 320 search.
 321
 322 Complete list of currently available key bindings:
 323
 324 \\{notmuch-search-mode-map}"
 325   (interactive)
 326   (kill-all-local-variables)
 327   (make-local-variable 'notmuch-search-query-string)
 328   (make-local-variable 'notmuch-search-oldest-first)
 329   (make-local-variable 'notmuch-search-target-thread)
 330   (make-local-variable 'notmuch-search-target-line)
 331   (set (make-local-variable 'notmuch-search-continuation) nil)
 332   (set (make-local-variable 'scroll-preserve-screen-position) t)
 333   (add-to-invisibility-spec 'notmuch-search)
 334   (use-local-map notmuch-search-mode-map)
 335   (setq truncate-lines t)
 336   (setq major-mode 'notmuch-search-mode
 337         mode-name "notmuch-search")
 338   (setq buffer-read-only t))
 339
 340 (defun notmuch-search-properties-in-region (property beg end)
 341   (save-excursion
 342     (let ((output nil)
 343           (last-line (line-number-at-pos end))
 344           (max-line (- (line-number-at-pos (point-max)) 2)))
 345       (goto-char beg)
 346       (beginning-of-line)
 347       (while (<= (line-number-at-pos) (min last-line max-line))
 348         (setq output (cons (get-text-property (point) property) output))
 349         (forward-line 1))
 350       output)))
 351
 352 (defun notmuch-search-find-thread-id ()
 353   "Return the thread for the current thread"
 354   (get-text-property (point) 'notmuch-search-thread-id))
 355
 356 (defun notmuch-search-find-thread-id-region (beg end)
 357   "Return a list of threads for the current region"
 358   (notmuch-search-properties-in-region 'notmuch-search-thread-id beg end))
 359
 360 (defun notmuch-search-find-authors ()
 361   "Return the authors for the current thread"
 362   (get-text-property (point) 'notmuch-search-authors))
 363
 364 (defun notmuch-search-find-authors-region (beg end)
 365   "Return a list of authors for the current region"
 366   (notmuch-search-properties-in-region 'notmuch-search-authors beg end))
 367
 368 (defun notmuch-search-find-subject ()
 369   "Return the subject for the current thread"
 370   (get-text-property (point) 'notmuch-search-subject))
 371
 372 (defun notmuch-search-find-subject-region (beg end)
 373   "Return a list of authors for the current region"
 374   (notmuch-search-properties-in-region 'notmuch-search-subject beg end))
 375
 376 (defun notmuch-search-show-thread ()
 377   "Display the currently selected thread."
 378   (interactive)
 379   (let ((thread-id (notmuch-search-find-thread-id))
 380         (subject (notmuch-search-find-subject)))
 381     (if (> (length thread-id) 0)
 382         (notmuch-show thread-id
 383                       (current-buffer)
 384                       notmuch-search-query-string
 385                       ;; name the buffer based on notmuch-search-find-subject
 386                       (if (string-match "^[ \t]*$" subject)
 387                           "[No Subject]"
 388                         (truncate-string-to-width
 389                          (concat "*"
 390                                  (truncate-string-to-width subject 32 nil nil t)
 391                                  "*")
 392                          32 nil nil t)))
 393       (error "End of search results"))))
 394
 395 (defun notmuch-search-reply-to-thread ()
 396   "Begin composing a reply to the entire current thread in a new buffer."
 397   (interactive)
 398   (let ((message-id (notmuch-search-find-thread-id)))
 399     (notmuch-mua-reply message-id)))
 400
 401 (defun notmuch-call-notmuch-process (&rest args)
 402   "Synchronously invoke \"notmuch\" with the given list of arguments.
 403
 404 Output from the process will be presented to the user as an error
 405 and will also appear in a buffer named \"*Notmuch errors*\"."
 406   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 407     (with-current-buffer error-buffer
 408         (erase-buffer))
 409     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 410         (point)
 411       (progn
 412         (with-current-buffer error-buffer
 413           (let ((beg (point-min))
 414                 (end (- (point-max) 1)))
 415             (error (buffer-substring beg end))
 416             ))))))
 417
 418 (defun notmuch-search-set-tags (tags)
 419   (save-excursion
 420     (end-of-line)
 421     (re-search-backward "(")
 422     (forward-char)
 423     (let ((beg (point))
 424           (inhibit-read-only t))
 425       (re-search-forward ")")
 426       (backward-char)
 427       (let ((end (point)))
 428         (delete-region beg end)
 429         (insert (propertize (mapconcat  'identity tags " ")
 430                             'font-lock-face 'notmuch-tag-face))))))
 431
 432 (defun notmuch-search-get-tags ()
 433   (save-excursion
 434     (end-of-line)
 435     (re-search-backward "(")
 436     (let ((beg (+ (point) 1)))
 437       (re-search-forward ")")
 438       (let ((end (- (point) 1)))
 439         (split-string (buffer-substring beg end))))))
 440
 441 (defun notmuch-search-get-tags-region (beg end)
 442   (save-excursion
 443     (let ((output nil)
 444           (last-line (line-number-at-pos end))
 445           (max-line (- (line-number-at-pos (point-max)) 2)))
 446       (goto-char beg)
 447       (while (<= (line-number-at-pos) (min last-line max-line))
 448         (setq output (append output (notmuch-search-get-tags)))
 449         (forward-line 1))
 450       output)))
 451
 452 (defun notmuch-search-add-tag-thread (tag)
 453   (notmuch-search-add-tag-region tag (point) (point)))
 454
 455 (defun notmuch-search-add-tag-region (tag beg end)
 456   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 457     (notmuch-call-notmuch-process "tag" (concat "+" tag) search-id-string)
 458     (save-excursion
 459       (let ((last-line (line-number-at-pos end))
 460             (max-line (- (line-number-at-pos (point-max)) 2)))
 461         (goto-char beg)
 462         (while (<= (line-number-at-pos) (min last-line max-line))
 463           (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<)))
 464           (forward-line))))))
 465
 466 (defun notmuch-search-remove-tag-thread (tag)
 467   (notmuch-search-remove-tag-region tag (point) (point)))
 468
 469 (defun notmuch-search-remove-tag-region (tag beg end)
 470   (let ((search-id-string (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or ")))
 471     (notmuch-call-notmuch-process "tag" (concat "-" tag) search-id-string)
 472     (save-excursion
 473       (let ((last-line (line-number-at-pos end))
 474             (max-line (- (line-number-at-pos (point-max)) 2)))
 475         (goto-char beg)
 476         (while (<= (line-number-at-pos) (min last-line max-line))
 477           (notmuch-search-set-tags (delete tag (notmuch-search-get-tags)))
 478           (forward-line))))))
 479
 480 (defun notmuch-search-add-tag (tag)
 481   "Add a tag to the currently selected thread or region.
 482
 483 The tag is added to all messages in the currently selected thread
 484 or threads in the current region."
 485   (interactive
 486    (list (notmuch-select-tag-with-completion "Tag to add: ")))
 487   (save-excursion
 488     (if (region-active-p)
 489         (let* ((beg (region-beginning))
 490                (end (region-end)))
 491           (notmuch-search-add-tag-region tag beg end))
 492       (notmuch-search-add-tag-thread tag))))
 493
 494 (defun notmuch-search-remove-tag (tag)
 495   "Remove a tag from the currently selected thread or region.
 496
 497 The tag is removed from all messages in the currently selected
 498 thread or threads in the current region."
 499   (interactive
 500    (list (notmuch-select-tag-with-completion
 501           "Tag to remove: "
 502           (if (region-active-p)
 503               (mapconcat 'identity
 504                          (notmuch-search-find-thread-id-region (region-beginning) (region-end))
 505                          " ")
 506             (notmuch-search-find-thread-id)))))
 507   (save-excursion
 508     (if (region-active-p)
 509         (let* ((beg (region-beginning))
 510                (end (region-end)))
 511           (notmuch-search-remove-tag-region tag beg end))
 512       (notmuch-search-remove-tag-thread tag))))
 513
 514 (defun notmuch-search-archive-thread ()
 515   "Archive the currently selected thread (remove its \"inbox\" tag).
 516
 517 This function advances the next thread when finished."
 518   (interactive)
 519   (notmuch-search-remove-tag-thread "inbox")
 520   (forward-line))
 521
 522 (defun notmuch-search-process-sentinel (proc msg)
 523   "Add a message to let user know when \"notmuch search\" exits"
 524   (let ((buffer (process-buffer proc))
 525         (status (process-status proc))
 526         (exit-status (process-exit-status proc))
 527         (never-found-target-thread nil))
 528     (if (memq status '(exit signal))
 529         (if (buffer-live-p buffer)
 530             (with-current-buffer buffer
 531               (save-excursion
 532                 (let ((inhibit-read-only t)
 533                       (atbob (bobp)))
 534                   (goto-char (point-max))
 535                   (if (eq status 'signal)
 536                       (insert "Incomplete search results (search process was killed).\n"))
 537                   (if (eq status 'exit)
 538                       (progn
 539                         (insert "End of search results.")
 540                         (if (not (= exit-status 0))
 541                             (insert (format " (process returned %d)" exit-status)))
 542                         (insert "\n")
 543                         (if (and atbob
 544                                  (not (string= notmuch-search-target-thread "found")))
 545                             (set 'never-found-target-thread t))))))
 546               (if (and never-found-target-thread
 547                        notmuch-search-target-line)
 548                   (goto-line notmuch-search-target-line)))))))
 549
 550 (defcustom notmuch-search-line-faces nil
 551   "Tag/face mapping for line highlighting in notmuch-search.
 552
 553 Here is an example of how to color search results based on tags.
 554 (the following text would be placed in your ~/.emacs file):
 555
 556 (setq notmuch-search-line-faces '((\"delete\" . '(:foreground \"red\"))
 557                                  (\"unread\" . '(:foreground \"green\"))))
 558
 559 Order matters: for lines with multiple tags, the the first
 560 matching will be applied."
 561   :type '(alist :key-type (string) :value-type (list))
 562   :group 'notmuch)
 563
 564 (defun notmuch-search-color-line (start end line-tag-list)
 565   "Colorize lines in notmuch-show based on tags"
 566   (if notmuch-search-line-faces
 567       (let ((overlay (make-overlay start end))
 568             (tags-faces (copy-alist notmuch-search-line-faces)))
 569         (while tags-faces
 570           (let* ((tag-face (car tags-faces))
 571                  (tag (car tag-face))
 572                  (face (cdr tag-face)))
 573             (cond ((member tag line-tag-list)
 574                    (overlay-put overlay 'face face)
 575                    (setq tags-faces nil))
 576                   (t
 577                    (setq tags-faces (cdr tags-faces)))))))))
 578
 579 (defun notmuch-search-insert-field (field date count authors subject tags)
 580   (cond
 581    ((string-equal field "date")
 582     (insert (format (cdr (assoc field notmuch-search-result-format)) date)))
 583    ((string-equal field "count")
 584     (insert (format (cdr (assoc field notmuch-search-result-format)) count)))
 585    ((string-equal field "authors")
 586     (insert (let* ((format-string (cdr (assoc field notmuch-search-result-format)))
 587                    (formatted-sample (format format-string ""))
 588                    (formatted-authors (format format-string authors)))
 589               (if (> (length formatted-authors)
 590                      (length formatted-sample))
 591                   (concat (substring authors 0 (- (length formatted-sample) 4)) "... ")
 592                 formatted-authors))))
 593    ((string-equal field "subject")
 594     (insert (format (cdr (assoc field notmuch-search-result-format)) subject)))
 595    ((string-equal field "tags")
 596     (insert (concat "(" (propertize tags 'font-lock-face 'notmuch-tag-face) ")")))))
 597
 598 (defun notmuch-search-show-result (date count authors subject tags)
 599   (let ((fields) (field))
 600     (setq fields (mapcar 'car notmuch-search-result-format))
 601     (loop for field in fields
 602           do (notmuch-search-insert-field field date count authors subject tags)))
 603   (insert "\n"))
 604
 605 (defun notmuch-search-process-filter (proc string)
 606   "Process and filter the output of \"notmuch search\""
 607   (let ((buffer (process-buffer proc))
 608         (found-target nil))
 609     (if (buffer-live-p buffer)
 610         (with-current-buffer buffer
 611           (save-excursion
 612             (let ((line 0)
 613                   (more t)
 614                   (inhibit-read-only t))
 615               (while more
 616                 (if (string-match "^\\(thread:[0-9A-Fa-f]*\\) \\(.*\\) \\(\\[[0-9/]*\\]\\) \\([^;]*\\); \\(.*\\) (\\([^()]*\\))$" string line)
 617                     (let* ((thread-id (match-string 1 string))
 618                            (date (match-string 2 string))
 619                            (count (match-string 3 string))
 620                            (authors (match-string 4 string))
 621                            (subject (match-string 5 string))
 622                            (tags (match-string 6 string))
 623                            (tag-list (if tags (save-match-data (split-string tags)))))
 624                       (goto-char (point-max))
 625                       (let ((beg (point-marker)))
 626                         (notmuch-search-show-result date count authors subject tags)
 627                         (notmuch-search-color-line beg (point-marker) tag-list)
 628                         (put-text-property beg (point-marker) 'notmuch-search-thread-id thread-id)
 629                         (put-text-property beg (point-marker) 'notmuch-search-authors authors)
 630                         (put-text-property beg (point-marker) 'notmuch-search-subject subject)
 631                         (if (string= thread-id notmuch-search-target-thread)
 632                             (progn
 633                               (set 'found-target beg)
 634                               (set 'notmuch-search-target-thread "found"))))
 635                       (set 'line (match-end 0)))
 636                   (set 'more nil)))))
 637           (if found-target
 638               (goto-char found-target)))
 639       (delete-process proc))))
 640
 641 (defun notmuch-search-operate-all (action)
 642   "Add/remove tags from all matching messages.
 643
 644 Tis command adds or removes tags from all messages matching the
 645 current search terms. When called interactively, this command
 646 will prompt for tags to be added or removed. Tags prefixed with
 647 '+' will be added and tags prefixed with '-' will be removed.
 648
 649 Each character of the tag name may consist of alphanumeric
 650 characters as well as `_.+-'.
 651 "
 652   (interactive "sOperation (+add -drop): notmuch tag ")
 653   (let ((action-split (split-string action " +")))
 654     ;; Perform some validation
 655     (let ((words action-split))
 656       (when (null words) (error "No operation given"))
 657       (while words
 658         (unless (string-match-p "^[-+][-+_.[:word:]]+$" (car words))
 659           (error "Action must be of the form `+thistag -that_tag'"))
 660         (setq words (cdr words))))
 661     (apply 'notmuch-call-notmuch-process "tag"
 662            (append action-split (list notmuch-search-query-string) nil))))
 663
 664 (defun notmuch-search-buffer-title (query)
 665   "Returns the title for a buffer with notmuch search results."
 666   (let* ((saved-search (rassoc-if (lambda (key)
 667                                     (string-match (concat "^" (regexp-quote key))
 668                                                   query))
 669                                   (reverse (notmuch-saved-searches))))
 670          (saved-search-name (car saved-search))
 671          (saved-search-query (cdr saved-search)))
 672     (cond ((and saved-search (equal saved-search-query query))
 673            ;; Query is the same as saved search (ignoring case)
 674            (concat "*notmuch-saved-search-" saved-search-name "*"))
 675           (saved-search
 676            (concat "*notmuch-search-"
 677                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 678                                              (concat "[ " saved-search-name " ]")
 679                                              query)
 680                    "*"))
 681           (t
 682            (concat "*notmuch-search-" query "*"))
 683           )))
 684
 685 ;;;###autoload
 686 (defun notmuch-search (query &optional oldest-first target-thread target-line continuation)
 687   "Run \"notmuch search\" with the given query string and display results.
 688
 689 The optional parameters are used as follows:
 690
 691   oldest-first: A Boolean controlling the sort order of returned threads
 692   target-thread: A thread ID (with the thread: prefix) that will be made
 693                  current if it appears in the search results.
 694   target-line: The line number to move to if the target thread does not
 695                appear in the search results."
 696   (interactive "sNotmuch search: ")
 697   (let ((buffer (get-buffer-create (notmuch-search-buffer-title query))))
 698     (switch-to-buffer buffer)
 699     (notmuch-search-mode)
 700     (set 'notmuch-search-query-string query)
 701     (set 'notmuch-search-oldest-first oldest-first)
 702     (set 'notmuch-search-target-thread target-thread)
 703     (set 'notmuch-search-target-line target-line)
 704     (set 'notmuch-search-continuation continuation)
 705     (let ((proc (get-buffer-process (current-buffer)))
 706           (inhibit-read-only t))
 707       (if proc
 708           (error "notmuch search process already running for query `%s'" query)
 709         )
 710       (erase-buffer)
 711       (goto-char (point-min))
 712       (save-excursion
 713         (let ((proc (start-process-shell-command
 714                      "notmuch-search" buffer notmuch-command "search"
 715                      (if oldest-first "--sort=oldest-first" "--sort=newest-first")
 716                      (shell-quote-argument query))))
 717           (set-process-sentinel proc 'notmuch-search-process-sentinel)
 718           (set-process-filter proc 'notmuch-search-process-filter))))
 719     (run-hooks 'notmuch-search-hook)))
 720
 721 (defun notmuch-search-refresh-view ()
 722   "Refresh the current view.
 723
 724 Kills the current buffer and runs a new search with the same
 725 query string as the current search. If the current thread is in
 726 the new search results, then point will be placed on the same
 727 thread. Otherwise, point will be moved to attempt to be in the
 728 same relative position within the new buffer."
 729   (interactive)
 730   (let ((target-line (line-number-at-pos))
 731         (oldest-first notmuch-search-oldest-first)
 732         (target-thread (notmuch-search-find-thread-id))
 733         (query notmuch-search-query-string)
 734         (continuation notmuch-search-continuation))
 735     (kill-this-buffer)
 736     (notmuch-search query oldest-first target-thread target-line continuation)
 737     (goto-char (point-min))))
 738
 739 (defcustom notmuch-poll-script ""
 740   "An external script to incorporate new mail into the notmuch database.
 741
 742 If this variable is non empty, then it should name a script to be
 743 invoked by `notmuch-search-poll-and-refresh-view' and
 744 `notmuch-hello-poll-and-update' (each have a default keybinding
 745 of 'G'). The script could do any of the following depending on
 746 the user's needs:
 747
 748 1. Invoke a program to transfer mail to the local mail store
 749 2. Invoke \"notmuch new\" to incorporate the new mail
 750 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 751   :type 'string
 752   :group 'notmuch)
 753
 754 (defun notmuch-poll ()
 755   "Run external script to import mail.
 756
 757 Invokes `notmuch-poll-script' if it is not set to an empty string."
 758   (interactive)
 759   (if (not (string= notmuch-poll-script ""))
 760       (call-process notmuch-poll-script nil nil)))
 761
 762 (defun notmuch-search-poll-and-refresh-view ()
 763   "Invoke `notmuch-poll' to import mail, then refresh the current view."
 764   (interactive)
 765   (notmuch-poll)
 766   (notmuch-search-refresh-view))
 767
 768 (defun notmuch-search-toggle-order ()
 769   "Toggle the current search order.
 770
 771 By default, the \"inbox\" view created by `notmuch' is displayed
 772 in chronological order (oldest thread at the beginning of the
 773 buffer), while any global searches created by `notmuch-search'
 774 are displayed in reverse-chronological order (newest thread at
 775 the beginning of the buffer).
 776
 777 This command toggles the sort order for the current search.
 778
 779 Note that any filtered searches created by
 780 `notmuch-search-filter' retain the search order of the parent
 781 search."
 782   (interactive)
 783   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 784   (notmuch-search-refresh-view))
 785
 786 (defun notmuch-search-filter (query)
 787   "Filter the current search results based on an additional query string.
 788
 789 Runs a new search matching only messages that match both the
 790 current search results AND the additional query string provided."
 791   (interactive "sFilter search: ")
 792   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 793                            (concat "( " query " )")
 794                          query)))
 795     (notmuch-search (if (string= notmuch-search-query-string "*")
 796                         grouped-query
 797                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 798
 799 (defun notmuch-search-filter-by-tag (tag)
 800   "Filter the current search results based on a single tag.
 801
 802 Runs a new search matching only messages that match both the
 803 current search results AND that are tagged with the given tag."
 804   (interactive
 805    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 806   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 807
 808 ;;;###autoload
 809 (defun notmuch ()
 810   "Run notmuch and display saved searches, known tags, etc."
 811   (interactive)
 812   (notmuch-hello))
 813
 814 (setq mail-user-agent 'notmuch-user-agent)
 815
 816 (provide 'notmuch)