git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21 ;; Homepage: https://notmuchmail.org/
  22
  23 ;;; Commentary:
  24
  25 ;; This is an emacs-based interface to the notmuch mail system.
  26 ;;
  27 ;; You will first need to have the notmuch program installed and have a
  28 ;; notmuch database built in order to use this. See
  29 ;; https://notmuchmail.org for details.
  30 ;;
  31 ;; To install this software, copy it to a directory that is on the
  32 ;; `load-path' variable within emacs (a good candidate is
  33 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  34 ;; notmuch source distribution then you can simply run:
  35 ;;
  36 ;;      sudo make install-emacs
  37 ;;
  38 ;; to install it.
  39 ;;
  40 ;; Then, to actually run it, add:
  41 ;;
  42 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  43 ;;
  44 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  45 ;; or run:
  46 ;;
  47 ;;      emacs -f notmuch
  48 ;;
  49 ;; Have fun, and let us know if you have any comment, questions, or
  50 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  51 ;; required, but is available from https://notmuchmail.org).
  52
  53 ;;; Code:
  54
  55 (eval-when-compile (require 'cl))
  56 (require 'mm-view)
  57 (require 'message)
  58
  59 (require 'notmuch-lib)
  60 (require 'notmuch-tag)
  61 (require 'notmuch-show)
  62 (require 'notmuch-tree)
  63 (require 'notmuch-mua)
  64 (require 'notmuch-hello)
  65 (require 'notmuch-maildir-fcc)
  66 (require 'notmuch-message)
  67 (require 'notmuch-parser)
  68
  69 (defcustom notmuch-search-result-format
  70   `(("date" . "%12s ")
  71     ("count" . "%-7s ")
  72     ("authors" . "%-20s ")
  73     ("subject" . "%s ")
  74     ("tags" . "(%s)"))
  75   "Search result formatting. Supported fields are:
  76         date, count, authors, subject, tags
  77 For example:
  78         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  79                                              \(\"subject\" . \"%s\"\)\)\)
  80 Line breaks are permitted in format strings (though this is
  81 currently experimental).  Note that a line break at the end of an
  82 \"authors\" field will get elided if the authors list is long;
  83 place it instead at the beginning of the following field.  To
  84 enter a line break when setting this variable with setq, use \\n.
  85 To enter a line break in customize, press \\[quoted-insert] C-j."
  86   :type '(alist :key-type (string) :value-type (string))
  87   :group 'notmuch-search)
  88
  89 ;; The name of this variable `notmuch-init-file' is consistent with the
  90 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  91 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  92 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  93   "Your Notmuch Emacs-Lisp configuration file name.
  94 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  95 it will be read instead.
  96 This file is read once when notmuch is loaded; the notmuch hooks added
  97 there will be called at other points of notmuch execution."
  98   :type 'file
  99   :group 'notmuch)
 100
 101 (defvar notmuch-query-history nil
 102   "Variable to store minibuffer history for notmuch queries")
 103
 104 (defun notmuch-foreach-mime-part (function mm-handle)
 105   (cond ((stringp (car mm-handle))
 106          (dolist (part (cdr mm-handle))
 107            (notmuch-foreach-mime-part function part)))
 108         ((bufferp (car mm-handle))
 109          (funcall function mm-handle))
 110         (t (dolist (part mm-handle)
 111              (notmuch-foreach-mime-part function part)))))
 112
 113 (defun notmuch-count-attachments (mm-handle)
 114   (let ((count 0))
 115     (notmuch-foreach-mime-part
 116      (lambda (p)
 117        (let ((disposition (mm-handle-disposition p)))
 118          (and (listp disposition)
 119               (or (equal (car disposition) "attachment")
 120                   (and (equal (car disposition) "inline")
 121                        (assq 'filename disposition)))
 122               (incf count))))
 123      mm-handle)
 124     count))
 125
 126 (defun notmuch-save-attachments (mm-handle &optional queryp)
 127   (notmuch-foreach-mime-part
 128    (lambda (p)
 129      (let ((disposition (mm-handle-disposition p)))
 130        (and (listp disposition)
 131             (or (equal (car disposition) "attachment")
 132                 (and (equal (car disposition) "inline")
 133                      (assq 'filename disposition)))
 134             (or (not queryp)
 135                 (y-or-n-p
 136                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 137             (mm-save-part p))))
 138    mm-handle))
 139
 140 (require 'hl-line)
 141
 142 (defun notmuch-hl-line-mode ()
 143   (prog1 (hl-line-mode)
 144     (when hl-line-overlay
 145       (overlay-put hl-line-overlay 'priority 1))))
 146
 147 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 148   "List of functions to call when notmuch displays the search results."
 149   :type 'hook
 150   :options '(notmuch-hl-line-mode)
 151   :group 'notmuch-search
 152   :group 'notmuch-hooks)
 153
 154 (defvar notmuch-search-mode-map
 155   (let ((map (make-sparse-keymap)))
 156     (set-keymap-parent map notmuch-common-keymap)
 157     (define-key map "x" 'notmuch-bury-or-kill-this-buffer)
 158     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 159     (define-key map "b" 'notmuch-search-scroll-down)
 160     (define-key map " " 'notmuch-search-scroll-up)
 161     (define-key map "<" 'notmuch-search-first-thread)
 162     (define-key map ">" 'notmuch-search-last-thread)
 163     (define-key map "p" 'notmuch-search-previous-thread)
 164     (define-key map "n" 'notmuch-search-next-thread)
 165     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 166     (define-key map "R" 'notmuch-search-reply-to-thread)
 167     (define-key map "o" 'notmuch-search-toggle-order)
 168     (define-key map "c" 'notmuch-search-stash-map)
 169     (define-key map "t" 'notmuch-search-filter-by-tag)
 170     (define-key map "l" 'notmuch-search-filter)
 171     (define-key map [mouse-1] 'notmuch-search-show-thread)
 172     (define-key map "k" 'notmuch-tag-jump)
 173     (define-key map "*" 'notmuch-search-tag-all)
 174     (define-key map "a" 'notmuch-search-archive-thread)
 175     (define-key map "-" 'notmuch-search-remove-tag)
 176     (define-key map "+" 'notmuch-search-add-tag)
 177     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 178     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 179     map)
 180   "Keymap for \"notmuch search\" buffers.")
 181 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 182
 183 (defvar notmuch-search-stash-map
 184   (let ((map (make-sparse-keymap)))
 185     (define-key map "i" 'notmuch-search-stash-thread-id)
 186     (define-key map "q" 'notmuch-stash-query)
 187     (define-key map "?" 'notmuch-subkeymap-help)
 188     map)
 189   "Submap for stash commands")
 190 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 191
 192 (defun notmuch-search-stash-thread-id ()
 193   "Copy thread ID of current thread to kill-ring."
 194   (interactive)
 195   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 196
 197 (defun notmuch-stash-query ()
 198   "Copy current query to kill-ring."
 199   (interactive)
 200   (notmuch-common-do-stash (notmuch-search-get-query)))
 201
 202 (defvar notmuch-search-query-string)
 203 (defvar notmuch-search-target-thread)
 204 (defvar notmuch-search-target-line)
 205
 206 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 207
 208 (defun notmuch-search-scroll-up ()
 209   "Move forward through search results by one window's worth."
 210   (interactive)
 211   (condition-case nil
 212       (scroll-up nil)
 213     ((end-of-buffer) (notmuch-search-last-thread))))
 214
 215 (defun notmuch-search-scroll-down ()
 216   "Move backward through the search results by one window's worth."
 217   (interactive)
 218   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 219   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 220   ;;
 221   ;; So instead of trapping a signal we instead check whether the
 222   ;; window begins on the first line of the buffer and if so, move
 223   ;; directly to that position. (We have to count lines since the
 224   ;; window-start position is not the same as point-min due to the
 225   ;; invisible thread-ID characters on the first line.
 226   (if (equal (count-lines (point-min) (window-start)) 0)
 227       (goto-char (point-min))
 228     (scroll-down nil)))
 229
 230 (defun notmuch-search-next-thread ()
 231   "Select the next thread in the search results."
 232   (interactive)
 233   (when (notmuch-search-get-result)
 234     (goto-char (notmuch-search-result-end))))
 235
 236 (defun notmuch-search-previous-thread ()
 237   "Select the previous thread in the search results."
 238   (interactive)
 239   (if (notmuch-search-get-result)
 240       (unless (bobp)
 241         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 242     ;; We must be past the end; jump to the last result
 243     (notmuch-search-last-thread)))
 244
 245 (defun notmuch-search-last-thread ()
 246   "Select the last thread in the search results."
 247   (interactive)
 248   (goto-char (point-max))
 249   (forward-line -2)
 250   (let ((beg (notmuch-search-result-beginning)))
 251     (when beg (goto-char beg))))
 252
 253 (defun notmuch-search-first-thread ()
 254   "Select the first thread in the search results."
 255   (interactive)
 256   (goto-char (point-min)))
 257
 258 (defface notmuch-message-summary-face
 259  '((((class color) (background light)) (:background "#f0f0f0"))
 260    (((class color) (background dark)) (:background "#303030")))
 261  "Face for the single-line message summary in notmuch-show-mode."
 262  :group 'notmuch-show
 263  :group 'notmuch-faces)
 264
 265 (defface notmuch-search-date
 266   '((t :inherit default))
 267   "Face used in search mode for dates."
 268   :group 'notmuch-search
 269   :group 'notmuch-faces)
 270
 271 (defface notmuch-search-count
 272   '((t :inherit default))
 273   "Face used in search mode for the count matching the query."
 274   :group 'notmuch-search
 275   :group 'notmuch-faces)
 276
 277 (defface notmuch-search-subject
 278   '((t :inherit default))
 279   "Face used in search mode for subjects."
 280   :group 'notmuch-search
 281   :group 'notmuch-faces)
 282
 283 (defface notmuch-search-matching-authors
 284   '((t :inherit default))
 285   "Face used in search mode for authors matching the query."
 286   :group 'notmuch-search
 287   :group 'notmuch-faces)
 288
 289 (defface notmuch-search-non-matching-authors
 290   '((((class color)
 291       (background dark))
 292      (:foreground "grey30"))
 293     (((class color)
 294       (background light))
 295      (:foreground "grey60"))
 296     (t
 297      (:italic t)))
 298   "Face used in search mode for authors not matching the query."
 299   :group 'notmuch-search
 300   :group 'notmuch-faces)
 301
 302 (defface notmuch-tag-face
 303   '((((class color)
 304       (background dark))
 305      (:foreground "OliveDrab1"))
 306     (((class color)
 307       (background light))
 308      (:foreground "navy blue" :bold t))
 309     (t
 310      (:bold t)))
 311   "Face used in search mode face for tags."
 312   :group 'notmuch-search
 313   :group 'notmuch-faces)
 314
 315 (defface notmuch-search-flagged-face
 316   '((((class color)
 317       (background dark))
 318      (:foreground "LightBlue1"))
 319     (((class color)
 320       (background light))
 321      (:foreground "blue")))
 322   "Face used in search mode face for flagged threads.
 323
 324 This face is the default value for the \"flagged\" tag in
 325 `notmuch-search-line-faces`."
 326   :group 'notmuch-search
 327   :group 'notmuch-faces)
 328
 329 (defface notmuch-search-unread-face
 330   '((t
 331      (:weight bold)))
 332   "Face used in search mode for unread threads.
 333
 334 This face is the default value for the \"unread\" tag in
 335 `notmuch-search-line-faces`."
 336   :group 'notmuch-search
 337   :group 'notmuch-faces)
 338
 339 (define-derived-mode notmuch-search-mode fundamental-mode "notmuch-search"
 340   "Major mode displaying results of a notmuch search.
 341
 342 This buffer contains the results of a \"notmuch search\" of your
 343 email archives. Each line in the buffer represents a single
 344 thread giving a summary of the thread (a relative date, the
 345 number of matched messages and total messages in the thread,
 346 participants in the thread, a representative subject line, and
 347 any tags).
 348
 349 Pressing \\[notmuch-search-show-thread] on any line displays that
 350 thread. The '\\[notmuch-search-add-tag]' and
 351 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 352 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 353 is a convenience for archiving a thread (applying changes in
 354 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 355 be used to add and/or remove tags from all messages (as opposed
 356 to threads) that match the current query.  Use with caution, as
 357 this will also tag matching messages that arrived *after*
 358 constructing the buffer.
 359
 360 Other useful commands are '\\[notmuch-search-filter]' for
 361 filtering the current search based on an additional query string,
 362 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 363 messages with a given tag, and '\\[notmuch-search]' to execute a
 364 new, global search.
 365
 366 Complete list of currently available key bindings:
 367
 368 \\{notmuch-search-mode-map}"
 369   (make-local-variable 'notmuch-search-query-string)
 370   (make-local-variable 'notmuch-search-oldest-first)
 371   (make-local-variable 'notmuch-search-target-thread)
 372   (make-local-variable 'notmuch-search-target-line)
 373   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 374   (set (make-local-variable 'scroll-preserve-screen-position) t)
 375   (add-to-invisibility-spec (cons 'ellipsis t))
 376   (setq truncate-lines t)
 377   (setq buffer-read-only t)
 378   (setq imenu-prev-index-position-function
 379         #'notmuch-search-imenu-prev-index-position-function)
 380   (setq imenu-extract-index-name-function
 381         #'notmuch-search-imenu-extract-index-name-function))
 382
 383 (defun notmuch-search-get-result (&optional pos)
 384   "Return the result object for the thread at POS (or point).
 385
 386 If there is no thread at POS (or point), returns nil."
 387   (get-text-property (or pos (point)) 'notmuch-search-result))
 388
 389 (defun notmuch-search-result-beginning (&optional pos)
 390   "Return the point at the beginning of the thread at POS (or point).
 391
 392 If there is no thread at POS (or point), returns nil."
 393   (when (notmuch-search-get-result pos)
 394     ;; We pass 1+point because previous-single-property-change starts
 395     ;; searching one before the position we give it.
 396     (previous-single-property-change (1+ (or pos (point)))
 397                                      'notmuch-search-result nil (point-min))))
 398
 399 (defun notmuch-search-result-end (&optional pos)
 400   "Return the point at the end of the thread at POS (or point).
 401
 402 The returned point will be just after the newline character that
 403 ends the result line.  If there is no thread at POS (or point),
 404 returns nil"
 405   (when (notmuch-search-get-result pos)
 406     (next-single-property-change (or pos (point)) 'notmuch-search-result
 407                                  nil (point-max))))
 408
 409 (defun notmuch-search-foreach-result (beg end fn)
 410   "Invoke FN for each result between BEG and END.
 411
 412 FN should take one argument.  It will be applied to the
 413 character position of the beginning of each result that overlaps
 414 the region between points BEG and END.  As a special case, if (=
 415 BEG END), FN will be applied to the result containing point
 416 BEG."
 417
 418   (lexical-let ((pos (notmuch-search-result-beginning beg))
 419                 ;; End must be a marker in case fn changes the
 420                 ;; text.
 421                 (end (copy-marker end))
 422                 ;; Make sure we examine at least one result, even if
 423                 ;; (= beg end).
 424                 (first t))
 425     ;; We have to be careful if the region extends beyond the results.
 426     ;; In this case, pos could be null or there could be no result at
 427     ;; pos.
 428     (while (and pos (or (< pos end) first))
 429       (when (notmuch-search-get-result pos)
 430         (funcall fn pos))
 431       (setq pos (notmuch-search-result-end pos)
 432             first nil))))
 433 ;; Unindent the function argument of notmuch-search-foreach-result so
 434 ;; the indentation of callers doesn't get out of hand.
 435 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 436
 437 (defun notmuch-search-properties-in-region (property beg end)
 438   (let (output)
 439     (notmuch-search-foreach-result beg end
 440       (lambda (pos)
 441         (push (plist-get (notmuch-search-get-result pos) property) output)))
 442     output))
 443
 444 (defun notmuch-search-find-thread-id (&optional bare)
 445   "Return the thread for the current thread
 446
 447 If BARE is set then do not prefix with \"thread:\""
 448   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 449     (when thread (concat (unless bare "thread:") thread))))
 450
 451 (defun notmuch-search-find-stable-query ()
 452   "Return the stable queries for the current thread.
 453
 454 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 455 matched and unmatched messages in the current thread."
 456   (plist-get (notmuch-search-get-result) :query))
 457
 458 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 459   "Return the stable query for the current region.
 460
 461 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 462 is nil, include both matched and unmatched messages. If there are
 463 no messages in the region then return nil."
 464   (let ((query-list nil) (all (not only-matched)))
 465     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 466       (when (first queries)
 467         (push (first queries) query-list))
 468       (when (and all (second queries))
 469         (push (second queries) query-list)))
 470     (when query-list
 471       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 472
 473 (defun notmuch-search-find-authors ()
 474   "Return the authors for the current thread"
 475   (plist-get (notmuch-search-get-result) :authors))
 476
 477 (defun notmuch-search-find-authors-region (beg end)
 478   "Return a list of authors for the current region"
 479   (notmuch-search-properties-in-region :authors beg end))
 480
 481 (defun notmuch-search-find-subject ()
 482   "Return the subject for the current thread"
 483   (plist-get (notmuch-search-get-result) :subject))
 484
 485 (defun notmuch-search-find-subject-region (beg end)
 486   "Return a list of authors for the current region"
 487   (notmuch-search-properties-in-region :subject beg end))
 488
 489 (defun notmuch-search-show-thread (&optional elide-toggle)
 490   "Display the currently selected thread.
 491
 492 With a prefix argument, invert the default value of
 493 `notmuch-show-only-matching-messages' when displaying the
 494 thread."
 495   (interactive "P")
 496   (let ((thread-id (notmuch-search-find-thread-id))
 497         (subject (notmuch-search-find-subject)))
 498     (if (> (length thread-id) 0)
 499         (notmuch-show thread-id
 500                       elide-toggle
 501                       (current-buffer)
 502                       notmuch-search-query-string
 503                       ;; Name the buffer based on the subject.
 504                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 505       (message "End of search results."))))
 506
 507 (defun notmuch-tree-from-search-current-query ()
 508   "Call notmuch tree with the current query"
 509   (interactive)
 510   (notmuch-tree notmuch-search-query-string))
 511
 512 (defun notmuch-tree-from-search-thread ()
 513   "Show the selected thread with notmuch-tree"
 514   (interactive)
 515   (notmuch-tree (notmuch-search-find-thread-id)
 516                 notmuch-search-query-string
 517                 nil
 518                 (notmuch-prettify-subject (notmuch-search-find-subject))
 519                 t))
 520
 521 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 522   "Begin composing a reply-all to the entire current thread in a new buffer."
 523   (interactive "P")
 524   (let ((message-id (notmuch-search-find-thread-id)))
 525     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 526
 527 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 528   "Begin composing a reply to the entire current thread in a new buffer."
 529   (interactive "P")
 530   (let ((message-id (notmuch-search-find-thread-id)))
 531     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 532
 533 (defun notmuch-search-set-tags (tags &optional pos)
 534   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 535     (notmuch-search-update-result new-result pos)))
 536
 537 (defun notmuch-search-get-tags (&optional pos)
 538   (plist-get (notmuch-search-get-result pos) :tags))
 539
 540 (defun notmuch-search-get-tags-region (beg end)
 541   (let (output)
 542     (notmuch-search-foreach-result beg end
 543       (lambda (pos)
 544         (setq output (append output (notmuch-search-get-tags pos)))))
 545     output))
 546
 547 (defun notmuch-search-interactive-region ()
 548   "Return the bounds of the current interactive region.
 549
 550 This returns (BEG END), where BEG and END are the bounds of the
 551 region if the region is active, or both `point' otherwise."
 552   (if (region-active-p)
 553       (list (region-beginning) (region-end))
 554     (list (point) (point))))
 555
 556 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 557   "Prompt for tag changes for the current thread or region.
 558
 559 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 560   (let* ((region (notmuch-search-interactive-region))
 561          (beg (first region)) (end (second region))
 562          (prompt (if (= beg end) "Tag thread" "Tag region")))
 563     (cons (notmuch-read-tag-changes
 564            (notmuch-search-get-tags-region beg end) prompt initial-input)
 565           region)))
 566
 567 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 568   "Change tags for the currently selected thread or region.
 569
 570 See `notmuch-tag' for information on the format of TAG-CHANGES.
 571 When called interactively, this uses the region if the region is
 572 active.  When called directly, BEG and END provide the region.
 573 If these are nil or not provided, then, if the region is active
 574 this applied to all threads meeting the region, and if the region
 575 is inactive this applies to the thread at point.
 576
 577 If ONLY-MATCHED is non-nil, only tag matched messages."
 578   (interactive (notmuch-search-interactive-tag-changes))
 579   (unless (and beg end)
 580     (setq beg (car (notmuch-search-interactive-region))
 581           end (cadr (notmuch-search-interactive-region))))
 582   (let ((search-string (notmuch-search-find-stable-query-region
 583                         beg end only-matched)))
 584     (notmuch-tag search-string tag-changes)
 585     (notmuch-search-foreach-result beg end
 586       (lambda (pos)
 587         (notmuch-search-set-tags
 588          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 589          pos)))))
 590
 591 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 592   "Change tags for the current thread or region (defaulting to add).
 593
 594 Same as `notmuch-search-tag' but sets initial input to '+'."
 595   (interactive (notmuch-search-interactive-tag-changes "+"))
 596   (notmuch-search-tag tag-changes beg end))
 597
 598 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 599   "Change tags for the current thread or region (defaulting to remove).
 600
 601 Same as `notmuch-search-tag' but sets initial input to '-'."
 602   (interactive (notmuch-search-interactive-tag-changes "-"))
 603   (notmuch-search-tag tag-changes beg end))
 604
 605 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 606      "Un-archive the currently selected thread.")
 607 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 608   "Archive the currently selected thread or region.
 609
 610 Archive each message in the currently selected thread by applying
 611 the tag changes in `notmuch-archive-tags' to each (remove the
 612 \"inbox\" tag by default). If a prefix argument is given, the
 613 messages will be \"unarchived\" (i.e. the tag changes in
 614 `notmuch-archive-tags' will be reversed).
 615
 616 This function advances the next thread when finished."
 617   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 618   (when notmuch-archive-tags
 619     (notmuch-search-tag
 620      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 621   (when (eq beg end)
 622     (notmuch-search-next-thread)))
 623
 624 (defun notmuch-search-update-result (result &optional pos)
 625   "Replace the result object of the thread at POS (or point) by
 626 RESULT and redraw it.
 627
 628 This will keep point in a reasonable location.  However, if there
 629 are enclosing save-excursions and the saved point is in the
 630 result being updated, the point will be restored to the beginning
 631 of the result."
 632   (let ((start (notmuch-search-result-beginning pos))
 633         (end (notmuch-search-result-end pos))
 634         (init-point (point))
 635         (inhibit-read-only t))
 636     ;; Delete the current thread
 637     (delete-region start end)
 638     ;; Insert the updated thread
 639     (notmuch-search-show-result result start)
 640     ;; If point was inside the old result, make an educated guess
 641     ;; about where to place it now.  Unfortunately, this won't work
 642     ;; with save-excursion (or any other markers that would be nice to
 643     ;; preserve, such as the window start), but there's nothing we can
 644     ;; do about that without a way to retrieve markers in a region.
 645     (when (and (>= init-point start) (<= init-point end))
 646       (let* ((new-end (notmuch-search-result-end start))
 647              (new-point (if (= init-point end)
 648                             new-end
 649                           (min init-point (- new-end 1)))))
 650         (goto-char new-point)))))
 651
 652 (defun notmuch-search-process-sentinel (proc msg)
 653   "Add a message to let user know when \"notmuch search\" exits"
 654   (let ((buffer (process-buffer proc))
 655         (status (process-status proc))
 656         (exit-status (process-exit-status proc))
 657         (never-found-target-thread nil))
 658     (when (memq status '(exit signal))
 659       (catch 'return
 660         (kill-buffer (process-get proc 'parse-buf))
 661         (if (buffer-live-p buffer)
 662             (with-current-buffer buffer
 663               (save-excursion
 664                 (let ((inhibit-read-only t)
 665                       (atbob (bobp)))
 666                   (goto-char (point-max))
 667                   (if (eq status 'signal)
 668                       (insert "Incomplete search results (search process was killed).\n"))
 669                   (when (eq status 'exit)
 670                     (insert "End of search results.\n")
 671                     ;; For version mismatch, there's no point in
 672                     ;; showing the search buffer
 673                     (when (or (= exit-status 20) (= exit-status 21))
 674                       (kill-buffer)
 675                       (throw 'return nil))
 676                     (if (and atbob
 677                              (not (string= notmuch-search-target-thread "found")))
 678                         (set 'never-found-target-thread t)))))
 679               (when (and never-found-target-thread
 680                        notmuch-search-target-line)
 681                   (goto-char (point-min))
 682                   (forward-line (1- notmuch-search-target-line)))))))))
 683
 684 (define-widget 'notmuch--custom-face-edit 'lazy
 685   "Custom face edit with a tag Edit Face"
 686   ;; I could not persuage custom-face-edit to respect the :tag
 687   ;; property so create a widget specially
 688   :tag "Manually specify face"
 689   :type 'custom-face-edit)
 690
 691 (defcustom notmuch-search-line-faces
 692   '(("unread" . notmuch-search-unread-face)
 693     ("flagged" . notmuch-search-flagged-face))
 694   "Alist of tags to faces for line highlighting in notmuch-search.
 695 Each element looks like (TAG . FACE).
 696 A thread with TAG will have FACE applied.
 697
 698 Here is an example of how to color search results based on tags.
 699  (the following text would be placed in your ~/.emacs file):
 700
 701  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
 702                                    (\"deleted\" . (:foreground \"red\"
 703                                                   :background \"blue\"))))
 704
 705 The FACE must be a face name (a symbol or string), a property
 706 list of face attributes, or a list of these.  The faces for
 707 matching tags are merged, with earlier attributes overriding
 708 later. A message having both \"deleted\" and \"unread\" tags with
 709 the above settings would have a green foreground and blue
 710 background."
 711   :type '(alist :key-type (string)
 712                 :value-type (radio (face :tag "Face name")
 713                                     (notmuch--custom-face-edit)))
 714   :group 'notmuch-search
 715   :group 'notmuch-faces)
 716
 717 (defun notmuch-search-color-line (start end line-tag-list)
 718   "Colorize lines in `notmuch-show' based on tags."
 719   ;; Reverse the list so earlier entries take precedence
 720   (dolist (elem (reverse notmuch-search-line-faces))
 721     (let ((tag (car elem))
 722           (face (cdr elem)))
 723       (when (member tag line-tag-list)
 724         (notmuch-apply-face nil face nil start end)))))
 725
 726 (defun notmuch-search-author-propertize (authors)
 727   "Split `authors' into matching and non-matching authors and
 728 propertize appropriately. If no boundary between authors and
 729 non-authors is found, assume that all of the authors match."
 730   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 731       (concat (propertize (concat (match-string 1 authors) ",")
 732                           'face 'notmuch-search-matching-authors)
 733               (propertize (match-string 2 authors)
 734                           'face 'notmuch-search-non-matching-authors))
 735     (propertize authors 'face 'notmuch-search-matching-authors)))
 736
 737 (defun notmuch-search-insert-authors (format-string authors)
 738   ;; Save the match data to avoid interfering with
 739   ;; `notmuch-search-process-filter'.
 740   (save-match-data
 741     (let* ((formatted-authors (format format-string authors))
 742            (formatted-sample (format format-string ""))
 743            (visible-string formatted-authors)
 744            (invisible-string "")
 745            (padding ""))
 746
 747       ;; Truncate the author string to fit the specification.
 748       (if (> (length formatted-authors)
 749              (length formatted-sample))
 750           (let ((visible-length (- (length formatted-sample)
 751                                    (length "... "))))
 752             ;; Truncate the visible string according to the width of
 753             ;; the display string.
 754             (setq visible-string (substring formatted-authors 0 visible-length)
 755                   invisible-string (substring formatted-authors visible-length))
 756             ;; If possible, truncate the visible string at a natural
 757             ;; break (comma or pipe), as incremental search doesn't
 758             ;; match across the visible/invisible border.
 759             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 760               ;; Second clause is destructive on `visible-string', so
 761               ;; order is important.
 762               (setq invisible-string (concat (match-string 3 visible-string)
 763                                              invisible-string)
 764                     visible-string (concat (match-string 1 visible-string)
 765                                            (match-string 2 visible-string))))
 766             ;; `visible-string' may be shorter than the space allowed
 767             ;; by `format-string'. If so we must insert some padding
 768             ;; after `invisible-string'.
 769             (setq padding (make-string (- (length formatted-sample)
 770                                           (length visible-string)
 771                                           (length "..."))
 772                                        ? ))))
 773
 774       ;; Use different faces to show matching and non-matching authors.
 775       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 776           ;; The visible string contains both matching and
 777           ;; non-matching authors.
 778           (setq visible-string (notmuch-search-author-propertize visible-string)
 779                 ;; The invisible string must contain only non-matching
 780                 ;; authors, as the visible-string contains both.
 781                 invisible-string (propertize invisible-string
 782                                              'face 'notmuch-search-non-matching-authors))
 783         ;; The visible string contains only matching authors.
 784         (setq visible-string (propertize visible-string
 785                                          'face 'notmuch-search-matching-authors)
 786               ;; The invisible string may contain both matching and
 787               ;; non-matching authors.
 788               invisible-string (notmuch-search-author-propertize invisible-string)))
 789
 790       ;; If there is any invisible text, add it as a tooltip to the
 791       ;; visible text.
 792       (when (not (string= invisible-string ""))
 793         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 794
 795       ;; Insert the visible and, if present, invisible author strings.
 796       (insert visible-string)
 797       (when (not (string= invisible-string ""))
 798         (let ((start (point))
 799               overlay)
 800           (insert invisible-string)
 801           (setq overlay (make-overlay start (point)))
 802           (overlay-put overlay 'invisible 'ellipsis)
 803           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 804       (insert padding))))
 805
 806 (defun notmuch-search-insert-field (field format-string result)
 807   (cond
 808    ((string-equal field "date")
 809     (insert (propertize (format format-string (plist-get result :date_relative))
 810                         'face 'notmuch-search-date)))
 811    ((string-equal field "count")
 812     (insert (propertize (format format-string
 813                                 (format "[%s/%s]" (plist-get result :matched)
 814                                         (plist-get result :total)))
 815                         'face 'notmuch-search-count)))
 816    ((string-equal field "subject")
 817     (insert (propertize (format format-string
 818                                 (notmuch-sanitize (plist-get result :subject)))
 819                         'face 'notmuch-search-subject)))
 820
 821    ((string-equal field "authors")
 822     (notmuch-search-insert-authors
 823      format-string (notmuch-sanitize (plist-get result :authors))))
 824
 825    ((string-equal field "tags")
 826     (let ((tags (plist-get result :tags))
 827           (orig-tags (plist-get result :orig-tags)))
 828       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 829
 830 (defun notmuch-search-show-result (result pos)
 831   "Insert RESULT at POS."
 832   ;; Ignore excluded matches
 833   (unless (= (plist-get result :matched) 0)
 834     (save-excursion
 835       (goto-char pos)
 836       (dolist (spec notmuch-search-result-format)
 837         (notmuch-search-insert-field (car spec) (cdr spec) result))
 838       (insert "\n")
 839       (notmuch-search-color-line pos (point) (plist-get result :tags))
 840       (put-text-property pos (point) 'notmuch-search-result result))))
 841
 842 (defun notmuch-search-append-result (result)
 843   "Insert RESULT at the end of the buffer.
 844
 845 This is only called when a result is first inserted so it also
 846 sets the :orig-tag property."
 847   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 848         (pos (point-max)))
 849     (notmuch-search-show-result new-result pos)
 850     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 851       (setq notmuch-search-target-thread "found")
 852       (goto-char pos))))
 853
 854 (defun notmuch-search-process-filter (proc string)
 855   "Process and filter the output of \"notmuch search\""
 856   (let ((results-buf (process-buffer proc))
 857         (parse-buf (process-get proc 'parse-buf))
 858         (inhibit-read-only t)
 859         done)
 860     (when (buffer-live-p results-buf)
 861       (with-current-buffer parse-buf
 862         ;; Insert new data
 863         (save-excursion
 864           (goto-char (point-max))
 865           (insert string))
 866         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 867                                          results-buf)))))
 868
 869 (defun notmuch-search-tag-all (tag-changes)
 870   "Add/remove tags from all messages in current search buffer.
 871
 872 See `notmuch-tag' for information on the format of TAG-CHANGES."
 873   (interactive
 874    (list (notmuch-read-tag-changes
 875           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 876   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 877
 878 (defun notmuch-search-buffer-title (query)
 879   "Returns the title for a buffer with notmuch search results."
 880   (let* ((saved-search
 881           (let (longest
 882                 (longest-length 0))
 883             (loop for tuple in notmuch-saved-searches
 884                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
 885                        (and (string-match (concat "^" quoted-query) query)
 886                             (> (length (match-string 0 query))
 887                                longest-length)))
 888                   do (setq longest tuple))
 889             longest))
 890          (saved-search-name (notmuch-saved-search-get saved-search :name))
 891          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 892     (cond ((and saved-search (equal saved-search-query query))
 893            ;; Query is the same as saved search (ignoring case)
 894            (concat "*notmuch-saved-search-" saved-search-name "*"))
 895           (saved-search
 896            (concat "*notmuch-search-"
 897                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 898                                              (concat "[ " saved-search-name " ]")
 899                                              query)
 900                    "*"))
 901           (t
 902            (concat "*notmuch-search-" query "*"))
 903           )))
 904
 905 (defun notmuch-read-query (prompt)
 906   "Read a notmuch-query from the minibuffer with completion.
 907
 908 PROMPT is the string to prompt with."
 909   (lexical-let*
 910       ((all-tags
 911         (mapcar (lambda (tag) (notmuch-escape-boolean-term tag))
 912                 (process-lines notmuch-command "search" "--output=tags" "*")))
 913        (completions
 914          (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 915                        "subject:" "attachment:")
 916                  (mapcar (lambda (tag) (concat "tag:" tag)) all-tags)
 917                  (mapcar (lambda (tag) (concat "is:" tag)) all-tags)
 918                  (mapcar (lambda (mimetype) (concat "mimetype:" mimetype)) (mailcap-mime-types)))))
 919     (let ((keymap (copy-keymap minibuffer-local-map))
 920           (current-query (case major-mode
 921                            (notmuch-search-mode (notmuch-search-get-query))
 922                            (notmuch-show-mode (notmuch-show-get-query))
 923                            (notmuch-tree-mode (notmuch-tree-get-query))))
 924           (minibuffer-completion-table
 925            (completion-table-dynamic
 926             (lambda (string)
 927               ;; generate a list of possible completions for the current input
 928               (cond
 929                ;; this ugly regexp is used to get the last word of the input
 930                ;; possibly preceded by a '('
 931                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 932                 (mapcar (lambda (compl)
 933                           (concat (match-string-no-properties 1 string) compl))
 934                         (all-completions (match-string-no-properties 2 string)
 935                                          completions)))
 936                (t (list string)))))))
 937       ;; this was simpler than convincing completing-read to accept spaces:
 938       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 939       (let ((history-delete-duplicates t))
 940         (read-from-minibuffer prompt nil keymap nil
 941                               'notmuch-search-history current-query nil)))))
 942
 943 (defun notmuch-search-get-query ()
 944   "Return the current query in this search buffer"
 945   notmuch-search-query-string)
 946
 947 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 948 ;;;###autoload
 949 (defun notmuch-search (&optional query oldest-first target-thread target-line no-display)
 950   "Display threads matching QUERY in a notmuch-search buffer.
 951
 952 If QUERY is nil, it is read interactively from the minibuffer.
 953 Other optional parameters are used as follows:
 954
 955   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 956   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 957                  current if it appears in the search results.
 958   TARGET-LINE: The line number to move to if the target thread does not
 959                appear in the search results.
 960   NO-DISPLAY: Do not try to foreground the search results buffer. If it is
 961               already foregrounded i.e. displayed in a window, this has no
 962               effect, meaning the buffer will remain visible.
 963
 964 When called interactively, this will prompt for a query and use
 965 the configured default sort order."
 966   (interactive
 967    (list
 968     ;; Prompt for a query
 969     nil
 970     ;; Use the default search order (if we're doing a search from a
 971     ;; search buffer, ignore any buffer-local overrides)
 972     (default-value 'notmuch-search-oldest-first)))
 973
 974   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 975          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 976     (if no-display
 977         (set-buffer buffer)
 978       (switch-to-buffer buffer))
 979     (notmuch-search-mode)
 980     ;; Don't track undo information for this buffer
 981     (set 'buffer-undo-list t)
 982     (set 'notmuch-search-query-string query)
 983     (set 'notmuch-search-oldest-first oldest-first)
 984     (set 'notmuch-search-target-thread target-thread)
 985     (set 'notmuch-search-target-line target-line)
 986     (notmuch-tag-clear-cache)
 987     (let ((proc (get-buffer-process (current-buffer)))
 988           (inhibit-read-only t))
 989       (if proc
 990           (error "notmuch search process already running for query `%s'" query)
 991         )
 992       (erase-buffer)
 993       (goto-char (point-min))
 994       (save-excursion
 995         (let ((proc (notmuch-start-notmuch
 996                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 997                      "search" "--format=sexp" "--format-version=2"
 998                      (if oldest-first
 999                          "--sort=oldest-first"
1000                        "--sort=newest-first")
1001                      query))
1002               ;; Use a scratch buffer to accumulate partial output.
1003               ;; This buffer will be killed by the sentinel, which
1004               ;; should be called no matter how the process dies.
1005               (parse-buf (generate-new-buffer " *notmuch search parse*")))
1006           (process-put proc 'parse-buf parse-buf)
1007           (set-process-filter proc 'notmuch-search-process-filter)
1008           (set-process-query-on-exit-flag proc nil))))
1009     (run-hooks 'notmuch-search-hook)))
1010
1011 (defun notmuch-search-refresh-view ()
1012   "Refresh the current view.
1013
1014 Erases the current buffer and runs a new search with the same
1015 query string as the current search. If the current thread is in
1016 the new search results, then point will be placed on the same
1017 thread. Otherwise, point will be moved to attempt to be in the
1018 same relative position within the new buffer."
1019   (interactive)
1020   (let ((target-line (line-number-at-pos))
1021         (oldest-first notmuch-search-oldest-first)
1022         (target-thread (notmuch-search-find-thread-id 'bare))
1023         (query notmuch-search-query-string))
1024     ;; notmuch-search erases the current buffer.
1025     (notmuch-search query oldest-first target-thread target-line t)
1026     (goto-char (point-min))))
1027
1028 (defun notmuch-search-toggle-order ()
1029   "Toggle the current search order.
1030
1031 This command toggles the sort order for the current search. The
1032 default sort order is defined by `notmuch-search-oldest-first'."
1033   (interactive)
1034   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1035   (notmuch-search-refresh-view))
1036
1037 (defun notmuch-group-disjunctive-query-string (query-string)
1038   "Group query if it contains a complex expression.
1039
1040 Enclose QUERY-STRING in parentheses if it matches
1041 `notmuch-search-disjunctive-regexp'."
1042   (if (string-match-p notmuch-search-disjunctive-regexp query-string)
1043       (concat "( " query-string " )")
1044     query-string))
1045
1046 (defun notmuch-search-filter (query)
1047   "Filter or LIMIT the current search results based on an additional query string.
1048
1049 Runs a new search matching only messages that match both the
1050 current search results AND the additional query string provided."
1051   (interactive (list (notmuch-read-query "Filter search: ")))
1052   (let ((grouped-query (notmuch-group-disjunctive-query-string query))
1053         (grouped-original-query (notmuch-group-disjunctive-query-string
1054                                  notmuch-search-query-string)))
1055     (notmuch-search (if (string= grouped-original-query "*")
1056                         grouped-query
1057                       (concat grouped-original-query " and " grouped-query))
1058                     notmuch-search-oldest-first)))
1059
1060 (defun notmuch-search-filter-by-tag (tag)
1061   "Filter the current search results based on a single tag.
1062
1063 Runs a new search matching only messages that match both the
1064 current search results AND that are tagged with the given tag."
1065   (interactive
1066    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1067   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1068
1069 ;;;###autoload
1070 (defun notmuch ()
1071   "Run notmuch and display saved searches, known tags, etc."
1072   (interactive)
1073   (notmuch-hello))
1074
1075 (defun notmuch-interesting-buffer (b)
1076   "Is the current buffer of interest to a notmuch user?"
1077   (with-current-buffer b
1078     (memq major-mode '(notmuch-show-mode
1079                        notmuch-search-mode
1080                        notmuch-tree-mode
1081                        notmuch-hello-mode
1082                        notmuch-message-mode))))
1083
1084 ;;;###autoload
1085 (defun notmuch-cycle-notmuch-buffers ()
1086   "Cycle through any existing notmuch buffers (search, show or hello).
1087
1088 If the current buffer is the only notmuch buffer, bury it. If no
1089 notmuch buffers exist, run `notmuch'."
1090   (interactive)
1091
1092   (let (start first)
1093     ;; If the current buffer is a notmuch buffer, remember it and then
1094     ;; bury it.
1095     (when (notmuch-interesting-buffer (current-buffer))
1096       (setq start (current-buffer))
1097       (bury-buffer))
1098
1099     ;; Find the first notmuch buffer.
1100     (setq first (loop for buffer in (buffer-list)
1101                       if (notmuch-interesting-buffer buffer)
1102                       return buffer))
1103
1104     (if first
1105         ;; If the first one we found is any other than the starting
1106         ;; buffer, switch to it.
1107         (unless (eq first start)
1108           (switch-to-buffer first))
1109       (notmuch))))
1110
1111 ;;;; Imenu Support
1112
1113 (defun notmuch-search-imenu-prev-index-position-function ()
1114   "Move point to previous message in notmuch-search buffer.
1115 This function is used as a value for
1116 `imenu-prev-index-position-function'."
1117   (notmuch-search-previous-thread))
1118
1119 (defun notmuch-search-imenu-extract-index-name-function ()
1120   "Return imenu name for line at point.
1121 This function is used as a value for
1122 `imenu-extract-index-name-function'.  Point should be at the
1123 beginning of the line."
1124   (let ((subject (notmuch-search-find-subject))
1125         (author (notmuch-search-find-authors)))
1126     (format "%s (%s)" subject author)))
1127
1128 (setq mail-user-agent 'notmuch-user-agent)
1129
1130 (provide 'notmuch)
1131
1132 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1133 (if init-file-user ; don't load init file if the -q option was used.
1134     (let ((init-file (locate-file notmuch-init-file '("/")
1135                                   (get-load-suffixes))))
1136       (if init-file (load init-file nil t t))))
1137
1138 ;;; notmuch.el ends here