git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (require 'notmuch)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-mua)
  58 (require 'notmuch-hello)
  59 (require 'notmuch-maildir-fcc)
  60 (require 'notmuch-message)
  61 (require 'notmuch-parser)
  62
  63 (defcustom notmuch-search-result-format
  64   `(("date" . "%12s ")
  65     ("count" . "%-7s ")
  66     ("authors" . "%-20s ")
  67     ("subject" . "%s ")
  68     ("tags" . "(%s)"))
  69   "Search result formatting. Supported fields are:
  70         date, count, authors, subject, tags
  71 For example:
  72         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  73                                              \(\"subject\" . \"%s\"\)\)\)
  74 Line breaks are permitted in format strings (though this is
  75 currently experimental).  Note that a line break at the end of an
  76 \"authors\" field will get elided if the authors list is long;
  77 place it instead at the beginning of the following field.  To
  78 enter a line break when setting this variable with setq, use \\n.
  79 To enter a line break in customize, press \\[quoted-insert] C-j."
  80   :type '(alist :key-type (string) :value-type (string))
  81   :group 'notmuch-search)
  82
  83 (defvar notmuch-query-history nil
  84   "Variable to store minibuffer history for notmuch queries")
  85
  86 (defun notmuch-foreach-mime-part (function mm-handle)
  87   (cond ((stringp (car mm-handle))
  88          (dolist (part (cdr mm-handle))
  89            (notmuch-foreach-mime-part function part)))
  90         ((bufferp (car mm-handle))
  91          (funcall function mm-handle))
  92         (t (dolist (part mm-handle)
  93              (notmuch-foreach-mime-part function part)))))
  94
  95 (defun notmuch-count-attachments (mm-handle)
  96   (let ((count 0))
  97     (notmuch-foreach-mime-part
  98      (lambda (p)
  99        (let ((disposition (mm-handle-disposition p)))
 100          (and (listp disposition)
 101               (or (equal (car disposition) "attachment")
 102                   (and (equal (car disposition) "inline")
 103                        (assq 'filename disposition)))
 104               (incf count))))
 105      mm-handle)
 106     count))
 107
 108 (defun notmuch-save-attachments (mm-handle &optional queryp)
 109   (notmuch-foreach-mime-part
 110    (lambda (p)
 111      (let ((disposition (mm-handle-disposition p)))
 112        (and (listp disposition)
 113             (or (equal (car disposition) "attachment")
 114                 (and (equal (car disposition) "inline")
 115                      (assq 'filename disposition)))
 116             (or (not queryp)
 117                 (y-or-n-p
 118                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 119             (mm-save-part p))))
 120    mm-handle))
 121
 122 (defun notmuch-documentation-first-line (symbol)
 123   "Return the first line of the documentation string for SYMBOL."
 124   (let ((doc (documentation symbol)))
 125     (if doc
 126         (with-temp-buffer
 127           (insert (documentation symbol t))
 128           (goto-char (point-min))
 129           (let ((beg (point)))
 130             (end-of-line)
 131             (buffer-substring beg (point))))
 132       "")))
 133
 134 (defun notmuch-prefix-key-description (key)
 135   "Given a prefix key code, return a human-readable string representation.
 136
 137 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 138   (let ((desc (format-kbd-macro (vector key))))
 139     (if (string= desc "ESC")
 140         "M-"
 141       (concat desc " "))))
 142
 143 ;; I would think that emacs would have code handy for walking a keymap
 144 ;; and generating strings for each key, and I would prefer to just call
 145 ;; that. But I couldn't find any (could be all implemented in C I
 146 ;; suppose), so I wrote my own here.
 147 (defun notmuch-substitute-one-command-key-with-prefix (prefix binding)
 148   "For a key binding, return a string showing a human-readable
 149 representation of the prefixed key as well as the first line of
 150 documentation from the bound function.
 151
 152 For a mouse binding, return nil."
 153   (let ((key (car binding))
 154         (action (cdr binding)))
 155     (if (mouse-event-p key)
 156         nil
 157       (if (keymapp action)
 158           (let ((substitute (apply-partially 'notmuch-substitute-one-command-key-with-prefix (notmuch-prefix-key-description key)))
 159                 (as-list))
 160             (map-keymap (lambda (a b)
 161                           (push (cons a b) as-list))
 162                         action)
 163             (mapconcat substitute as-list "\n"))
 164         (concat prefix (format-kbd-macro (vector key))
 165                 "\t"
 166                 (notmuch-documentation-first-line action))))))
 167
 168 (defun notmuch-substitute-command-keys-one (key)
 169   ;; A `keymap' key indicates inheritance from a parent keymap - the
 170   ;; inherited mappings follow, so there is nothing to print for
 171   ;; `keymap' itself.
 172   (when (not (eq key 'keymap))
 173     (notmuch-substitute-one-command-key-with-prefix nil key)))
 174
 175 (defun notmuch-substitute-command-keys (doc)
 176   "Like `substitute-command-keys' but with documentation, not function names."
 177   (let ((beg 0))
 178     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 179       (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 180              (keymap (symbol-value (intern keymap-name))))
 181         (setq doc (replace-match
 182                    (mapconcat #'notmuch-substitute-command-keys-one
 183                               (cdr keymap) "\n")
 184                    1 1 doc)))
 185       (setq beg (match-end 0)))
 186     doc))
 187
 188 (defun notmuch-help ()
 189   "Display help for the current notmuch mode."
 190   (interactive)
 191   (let* ((mode major-mode)
 192          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 193     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 194       (insert doc)
 195       (goto-char (point-min))
 196       (set-buffer-modified-p nil)
 197       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 198
 199 (require 'hl-line)
 200
 201 (defun notmuch-hl-line-mode ()
 202   (prog1 (hl-line-mode)
 203     (when hl-line-overlay
 204       (overlay-put hl-line-overlay 'priority 1))))
 205
 206 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 207   "List of functions to call when notmuch displays the search results."
 208   :type 'hook
 209   :options '(notmuch-hl-line-mode)
 210   :group 'notmuch-search
 211   :group 'notmuch-hooks)
 212
 213 (defvar notmuch-search-mode-map
 214   (let ((map (make-sparse-keymap)))
 215     (define-key map "?" 'notmuch-help)
 216     (define-key map "q" 'notmuch-kill-this-buffer)
 217     (define-key map "x" 'notmuch-kill-this-buffer)
 218     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 219     (define-key map "b" 'notmuch-search-scroll-down)
 220     (define-key map " " 'notmuch-search-scroll-up)
 221     (define-key map "<" 'notmuch-search-first-thread)
 222     (define-key map ">" 'notmuch-search-last-thread)
 223     (define-key map "p" 'notmuch-search-previous-thread)
 224     (define-key map "n" 'notmuch-search-next-thread)
 225     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 226     (define-key map "R" 'notmuch-search-reply-to-thread)
 227     (define-key map "m" 'notmuch-mua-new-mail)
 228     (define-key map "s" 'notmuch-search)
 229     (define-key map "o" 'notmuch-search-toggle-order)
 230     (define-key map "c" 'notmuch-search-stash-map)
 231     (define-key map "=" 'notmuch-search-refresh-view)
 232     (define-key map "G" 'notmuch-search-poll-and-refresh-view)
 233     (define-key map "t" 'notmuch-search-filter-by-tag)
 234     (define-key map "f" 'notmuch-search-filter)
 235     (define-key map [mouse-1] 'notmuch-search-show-thread)
 236     (define-key map "*" 'notmuch-search-tag-all)
 237     (define-key map "a" 'notmuch-search-archive-thread)
 238     (define-key map "-" 'notmuch-search-remove-tag)
 239     (define-key map "+" 'notmuch-search-add-tag)
 240     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 241     map)
 242   "Keymap for \"notmuch search\" buffers.")
 243 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 244
 245 (defvar notmuch-search-stash-map
 246   (let ((map (make-sparse-keymap)))
 247     (define-key map "i" 'notmuch-search-stash-thread-id)
 248     map)
 249   "Submap for stash commands")
 250 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 251
 252 (defun notmuch-search-stash-thread-id ()
 253   "Copy thread ID of current thread to kill-ring."
 254   (interactive)
 255   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 256
 257 (defvar notmuch-search-query-string)
 258 (defvar notmuch-search-target-thread)
 259 (defvar notmuch-search-target-line)
 260
 261 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 262
 263 (defun notmuch-search-scroll-up ()
 264   "Move forward through search results by one window's worth."
 265   (interactive)
 266   (condition-case nil
 267       (scroll-up nil)
 268     ((end-of-buffer) (notmuch-search-last-thread))))
 269
 270 (defun notmuch-search-scroll-down ()
 271   "Move backward through the search results by one window's worth."
 272   (interactive)
 273   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 274   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 275   ;;
 276   ;; So instead of trapping a signal we instead check whether the
 277   ;; window begins on the first line of the buffer and if so, move
 278   ;; directly to that position. (We have to count lines since the
 279   ;; window-start position is not the same as point-min due to the
 280   ;; invisible thread-ID characters on the first line.
 281   (if (equal (count-lines (point-min) (window-start)) 0)
 282       (goto-char (point-min))
 283     (scroll-down nil)))
 284
 285 (defun notmuch-search-next-thread ()
 286   "Select the next thread in the search results."
 287   (interactive)
 288   (when (notmuch-search-get-result)
 289     (goto-char (notmuch-search-result-end))))
 290
 291 (defun notmuch-search-previous-thread ()
 292   "Select the previous thread in the search results."
 293   (interactive)
 294   (if (notmuch-search-get-result)
 295       (unless (bobp)
 296         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 297     ;; We must be past the end; jump to the last result
 298     (notmuch-search-last-thread)))
 299
 300 (defun notmuch-search-last-thread ()
 301   "Select the last thread in the search results."
 302   (interactive)
 303   (goto-char (point-max))
 304   (forward-line -2)
 305   (let ((beg (notmuch-search-result-beginning)))
 306     (when beg (goto-char beg))))
 307
 308 (defun notmuch-search-first-thread ()
 309   "Select the first thread in the search results."
 310   (interactive)
 311   (goto-char (point-min)))
 312
 313 (defface notmuch-message-summary-face
 314  '((((class color) (background light)) (:background "#f0f0f0"))
 315    (((class color) (background dark)) (:background "#303030")))
 316  "Face for the single-line message summary in notmuch-show-mode."
 317  :group 'notmuch-show
 318  :group 'notmuch-faces)
 319
 320 (defface notmuch-search-date
 321   '((t :inherit default))
 322   "Face used in search mode for dates."
 323   :group 'notmuch-search
 324   :group 'notmuch-faces)
 325
 326 (defface notmuch-search-count
 327   '((t :inherit default))
 328   "Face used in search mode for the count matching the query."
 329   :group 'notmuch-search
 330   :group 'notmuch-faces)
 331
 332 (defface notmuch-search-subject
 333   '((t :inherit default))
 334   "Face used in search mode for subjects."
 335   :group 'notmuch-search
 336   :group 'notmuch-faces)
 337
 338 (defface notmuch-search-matching-authors
 339   '((t :inherit default))
 340   "Face used in search mode for authors matching the query."
 341   :group 'notmuch-search
 342   :group 'notmuch-faces)
 343
 344 (defface notmuch-search-non-matching-authors
 345   '((((class color)
 346       (background dark))
 347      (:foreground "grey30"))
 348     (((class color)
 349       (background light))
 350      (:foreground "grey60"))
 351     (t
 352      (:italic t)))
 353   "Face used in search mode for authors not matching the query."
 354   :group 'notmuch-search
 355   :group 'notmuch-faces)
 356
 357 (defface notmuch-tag-face
 358   '((((class color)
 359       (background dark))
 360      (:foreground "OliveDrab1"))
 361     (((class color)
 362       (background light))
 363      (:foreground "navy blue" :bold t))
 364     (t
 365      (:bold t)))
 366   "Face used in search mode face for tags."
 367   :group 'notmuch-search
 368   :group 'notmuch-faces)
 369
 370 (defun notmuch-search-mode ()
 371   "Major mode displaying results of a notmuch search.
 372
 373 This buffer contains the results of a \"notmuch search\" of your
 374 email archives. Each line in the buffer represents a single
 375 thread giving a summary of the thread (a relative date, the
 376 number of matched messages and total messages in the thread,
 377 participants in the thread, a representative subject line, and
 378 any tags).
 379
 380 Pressing \\[notmuch-search-show-thread] on any line displays that
 381 thread. The '\\[notmuch-search-add-tag]' and
 382 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 383 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 384 is a convenience for archiving a thread (applying changes in
 385 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 386 be used to add and/or remove tags from all messages (as opposed
 387 to threads) that match the current query.  Use with caution, as
 388 this will also tag matching messages that arrived *after*
 389 constructing the buffer.
 390
 391 Other useful commands are '\\[notmuch-search-filter]' for
 392 filtering the current search based on an additional query string,
 393 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 394 messages with a given tag, and '\\[notmuch-search]' to execute a
 395 new, global search.
 396
 397 Complete list of currently available key bindings:
 398
 399 \\{notmuch-search-mode-map}"
 400   (interactive)
 401   (kill-all-local-variables)
 402   (make-local-variable 'notmuch-search-query-string)
 403   (make-local-variable 'notmuch-search-oldest-first)
 404   (make-local-variable 'notmuch-search-target-thread)
 405   (make-local-variable 'notmuch-search-target-line)
 406   (set (make-local-variable 'scroll-preserve-screen-position) t)
 407   (add-to-invisibility-spec (cons 'ellipsis t))
 408   (use-local-map notmuch-search-mode-map)
 409   (setq truncate-lines t)
 410   (setq major-mode 'notmuch-search-mode
 411         mode-name "notmuch-search")
 412   (setq buffer-read-only t))
 413
 414 (defun notmuch-search-get-result (&optional pos)
 415   "Return the result object for the thread at POS (or point).
 416
 417 If there is no thread at POS (or point), returns nil."
 418   (get-text-property (or pos (point)) 'notmuch-search-result))
 419
 420 (defun notmuch-search-result-beginning (&optional pos)
 421   "Return the point at the beginning of the thread at POS (or point).
 422
 423 If there is no thread at POS (or point), returns nil."
 424   (when (notmuch-search-get-result pos)
 425     ;; We pass 1+point because previous-single-property-change starts
 426     ;; searching one before the position we give it.
 427     (previous-single-property-change (1+ (or pos (point)))
 428                                      'notmuch-search-result nil (point-min))))
 429
 430 (defun notmuch-search-result-end (&optional pos)
 431   "Return the point at the end of the thread at POS (or point).
 432
 433 The returned point will be just after the newline character that
 434 ends the result line.  If there is no thread at POS (or point),
 435 returns nil"
 436   (when (notmuch-search-get-result pos)
 437     (next-single-property-change (or pos (point)) 'notmuch-search-result
 438                                  nil (point-max))))
 439
 440 (defun notmuch-search-foreach-result (beg end function)
 441   "Invoke FUNCTION for each result between BEG and END.
 442
 443 FUNCTION should take one argument.  It will be applied to the
 444 character position of the beginning of each result that overlaps
 445 the region between points BEG and END.  As a special case, if (=
 446 BEG END), FUNCTION will be applied to the result containing point
 447 BEG."
 448
 449   (lexical-let ((pos (notmuch-search-result-beginning beg))
 450                 ;; End must be a marker in case function changes the
 451                 ;; text.
 452                 (end (copy-marker end))
 453                 ;; Make sure we examine at least one result, even if
 454                 ;; (= beg end).
 455                 (first t))
 456     ;; We have to be careful if the region extends beyond the results.
 457     ;; In this case, pos could be null or there could be no result at
 458     ;; pos.
 459     (while (and pos (or (< pos end) first))
 460       (when (notmuch-search-get-result pos)
 461         (funcall function pos))
 462       (setq pos (notmuch-search-result-end pos)
 463             first nil))))
 464 ;; Unindent the function argument of notmuch-search-foreach-result so
 465 ;; the indentation of callers doesn't get out of hand.
 466 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 467
 468 (defun notmuch-search-properties-in-region (property beg end)
 469   (let (output)
 470     (notmuch-search-foreach-result beg end
 471       (lambda (pos)
 472         (push (plist-get (notmuch-search-get-result pos) property) output)))
 473     output))
 474
 475 (defun notmuch-search-find-thread-id (&optional bare)
 476   "Return the thread for the current thread
 477
 478 If BARE is set then do not prefix with \"thread:\""
 479   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 480     (when thread (concat (unless bare "thread:") thread))))
 481
 482 (defun notmuch-search-find-thread-id-region (beg end)
 483   "Return a list of threads for the current region"
 484   (mapcar (lambda (thread) (concat "thread:" thread))
 485           (notmuch-search-properties-in-region :thread beg end)))
 486
 487 (defun notmuch-search-find-thread-id-region-search (beg end)
 488   "Return a search string for threads for the current region"
 489   (mapconcat 'identity (notmuch-search-find-thread-id-region beg end) " or "))
 490
 491 (defun notmuch-search-find-authors ()
 492   "Return the authors for the current thread"
 493   (plist-get (notmuch-search-get-result) :authors))
 494
 495 (defun notmuch-search-find-authors-region (beg end)
 496   "Return a list of authors for the current region"
 497   (notmuch-search-properties-in-region :authors beg end))
 498
 499 (defun notmuch-search-find-subject ()
 500   "Return the subject for the current thread"
 501   (plist-get (notmuch-search-get-result) :subject))
 502
 503 (defun notmuch-search-find-subject-region (beg end)
 504   "Return a list of authors for the current region"
 505   (notmuch-search-properties-in-region :subject beg end))
 506
 507 (defun notmuch-search-show-thread ()
 508   "Display the currently selected thread."
 509   (interactive)
 510   (let ((thread-id (notmuch-search-find-thread-id))
 511         (subject (notmuch-search-find-subject)))
 512     (if (> (length thread-id) 0)
 513         (notmuch-show thread-id
 514                       (current-buffer)
 515                       notmuch-search-query-string
 516                       ;; Name the buffer based on the subject.
 517                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 518       (message "End of search results."))))
 519
 520 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 521   "Begin composing a reply-all to the entire current thread in a new buffer."
 522   (interactive "P")
 523   (let ((message-id (notmuch-search-find-thread-id)))
 524     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 525
 526 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 527   "Begin composing a reply to the entire current thread in a new buffer."
 528   (interactive "P")
 529   (let ((message-id (notmuch-search-find-thread-id)))
 530     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 531
 532 (defun notmuch-call-notmuch-process (&rest args)
 533   "Synchronously invoke \"notmuch\" with the given list of arguments.
 534
 535 If notmuch exits with a non-zero status, output from the process
 536 will appear in a buffer named \"*Notmuch errors*\" and an error
 537 will be signaled."
 538   (with-temp-buffer
 539     (let ((status (apply #'call-process notmuch-command nil t nil args)))
 540       (notmuch-check-exit-status status (cons notmuch-command args)
 541                                  (buffer-string)))))
 542
 543 (defun notmuch-search-set-tags (tags &optional pos)
 544   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 545     (notmuch-search-update-result new-result pos)))
 546
 547 (defun notmuch-search-get-tags (&optional pos)
 548   (plist-get (notmuch-search-get-result pos) :tags))
 549
 550 (defun notmuch-search-get-tags-region (beg end)
 551   (let (output)
 552     (notmuch-search-foreach-result beg end
 553       (lambda (pos)
 554         (setq output (append output (notmuch-search-get-tags pos)))))
 555     output))
 556
 557 (defun notmuch-search-tag-region (beg end &optional tag-changes)
 558   "Change tags for threads in the given region."
 559   (let ((search-string (notmuch-search-find-thread-id-region-search beg end)))
 560     (setq tag-changes (notmuch-tag search-string tag-changes))
 561     (notmuch-search-foreach-result beg end
 562       (lambda (pos)
 563         (notmuch-search-set-tags
 564          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 565          pos)))))
 566
 567 (defun notmuch-search-tag (&optional tag-changes)
 568   "Change tags for the currently selected thread or region.
 569
 570 See `notmuch-tag' for information on the format of TAG-CHANGES."
 571   (interactive)
 572   (let* ((beg (if (region-active-p) (region-beginning) (point)))
 573          (end (if (region-active-p) (region-end) (point))))
 574     (notmuch-search-tag-region beg end tag-changes)))
 575
 576 (defun notmuch-search-add-tag ()
 577   "Same as `notmuch-search-tag' but sets initial input to '+'."
 578   (interactive)
 579   (notmuch-search-tag "+"))
 580
 581 (defun notmuch-search-remove-tag ()
 582   "Same as `notmuch-search-tag' but sets initial input to '-'."
 583   (interactive)
 584   (notmuch-search-tag "-"))
 585
 586 (defun notmuch-search-archive-thread (&optional unarchive)
 587   "Archive the currently selected thread.
 588
 589 Archive each message in the currently selected thread by applying
 590 the tag changes in `notmuch-archive-tags' to each (remove the
 591 \"inbox\" tag by default). If a prefix argument is given, the
 592 messages will be \"unarchived\" (i.e. the tag changes in
 593 `notmuch-archive-tags' will be reversed).
 594
 595 This function advances the next thread when finished."
 596   (interactive "P")
 597   (when notmuch-archive-tags
 598     (notmuch-search-tag
 599      (notmuch-tag-change-list notmuch-archive-tags unarchive)))
 600   (notmuch-search-next-thread))
 601
 602 (defun notmuch-search-update-result (result &optional pos)
 603   "Replace the result object of the thread at POS (or point) by
 604 RESULT and redraw it.
 605
 606 This will keep point in a reasonable location.  However, if there
 607 are enclosing save-excursions and the saved point is in the
 608 result being updated, the point will be restored to the beginning
 609 of the result."
 610   (let ((start (notmuch-search-result-beginning pos))
 611         (end (notmuch-search-result-end pos))
 612         (init-point (point))
 613         (inhibit-read-only t))
 614     ;; Delete the current thread
 615     (delete-region start end)
 616     ;; Insert the updated thread
 617     (notmuch-search-show-result result start)
 618     ;; If point was inside the old result, make an educated guess
 619     ;; about where to place it now.  Unfortunately, this won't work
 620     ;; with save-excursion (or any other markers that would be nice to
 621     ;; preserve, such as the window start), but there's nothing we can
 622     ;; do about that without a way to retrieve markers in a region.
 623     (when (and (>= init-point start) (<= init-point end))
 624       (let* ((new-end (notmuch-search-result-end start))
 625              (new-point (if (= init-point end)
 626                             new-end
 627                           (min init-point (- new-end 1)))))
 628         (goto-char new-point)))))
 629
 630 (defun notmuch-search-process-sentinel (proc msg)
 631   "Add a message to let user know when \"notmuch search\" exits"
 632   (let ((buffer (process-buffer proc))
 633         (status (process-status proc))
 634         (exit-status (process-exit-status proc))
 635         (never-found-target-thread nil))
 636     (when (memq status '(exit signal))
 637       (catch 'return
 638         (kill-buffer (process-get proc 'parse-buf))
 639         (if (buffer-live-p buffer)
 640             (with-current-buffer buffer
 641               (save-excursion
 642                 (let ((inhibit-read-only t)
 643                       (atbob (bobp)))
 644                   (goto-char (point-max))
 645                   (if (eq status 'signal)
 646                       (insert "Incomplete search results (search process was killed).\n"))
 647                   (when (eq status 'exit)
 648                     (insert "End of search results.\n")
 649                     ;; For version mismatch, there's no point in
 650                     ;; showing the search buffer
 651                     (when (or (= exit-status 20) (= exit-status 21))
 652                       (kill-buffer)
 653                       (throw 'return nil))
 654                     (if (and atbob
 655                              (not (string= notmuch-search-target-thread "found")))
 656                         (set 'never-found-target-thread t)))))
 657               (when (and never-found-target-thread
 658                        notmuch-search-target-line)
 659                   (goto-char (point-min))
 660                   (forward-line (1- notmuch-search-target-line)))))))))
 661
 662 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 663                                        ("flagged" :foreground "blue"))
 664   "Tag/face mapping for line highlighting in notmuch-search.
 665
 666 Here is an example of how to color search results based on tags.
 667  (the following text would be placed in your ~/.emacs file):
 668
 669  (setq notmuch-search-line-faces '((\"deleted\" . (:foreground \"red\"
 670                                                   :background \"blue\"))
 671                                    (\"unread\" . (:foreground \"green\"))))
 672
 673 The attributes defined for matching tags are merged, with later
 674 attributes overriding earlier. A message having both \"deleted\"
 675 and \"unread\" tags with the above settings would have a green
 676 foreground and blue background."
 677   :type '(alist :key-type (string) :value-type (custom-face-edit))
 678   :group 'notmuch-search
 679   :group 'notmuch-faces)
 680
 681 (defun notmuch-search-color-line (start end line-tag-list)
 682   "Colorize lines in `notmuch-show' based on tags."
 683   (mapc (lambda (elem)
 684           (let ((tag (car elem))
 685                 (attributes (cdr elem)))
 686             (when (member tag line-tag-list)
 687               (notmuch-combine-face-text-property start end attributes))))
 688         ;; Reverse the list so earlier entries take precedence
 689         (reverse notmuch-search-line-faces)))
 690
 691 (defun notmuch-search-author-propertize (authors)
 692   "Split `authors' into matching and non-matching authors and
 693 propertize appropriately. If no boundary between authors and
 694 non-authors is found, assume that all of the authors match."
 695   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 696       (concat (propertize (concat (match-string 1 authors) ",")
 697                           'face 'notmuch-search-matching-authors)
 698               (propertize (match-string 2 authors)
 699                           'face 'notmuch-search-non-matching-authors))
 700     (propertize authors 'face 'notmuch-search-matching-authors)))
 701
 702 (defun notmuch-search-insert-authors (format-string authors)
 703   ;; Save the match data to avoid interfering with
 704   ;; `notmuch-search-process-filter'.
 705   (save-match-data
 706     (let* ((formatted-authors (format format-string authors))
 707            (formatted-sample (format format-string ""))
 708            (visible-string formatted-authors)
 709            (invisible-string "")
 710            (padding ""))
 711
 712       ;; Truncate the author string to fit the specification.
 713       (if (> (length formatted-authors)
 714              (length formatted-sample))
 715           (let ((visible-length (- (length formatted-sample)
 716                                    (length "... "))))
 717             ;; Truncate the visible string according to the width of
 718             ;; the display string.
 719             (setq visible-string (substring formatted-authors 0 visible-length)
 720                   invisible-string (substring formatted-authors visible-length))
 721             ;; If possible, truncate the visible string at a natural
 722             ;; break (comma or pipe), as incremental search doesn't
 723             ;; match across the visible/invisible border.
 724             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 725               ;; Second clause is destructive on `visible-string', so
 726               ;; order is important.
 727               (setq invisible-string (concat (match-string 3 visible-string)
 728                                              invisible-string)
 729                     visible-string (concat (match-string 1 visible-string)
 730                                            (match-string 2 visible-string))))
 731             ;; `visible-string' may be shorter than the space allowed
 732             ;; by `format-string'. If so we must insert some padding
 733             ;; after `invisible-string'.
 734             (setq padding (make-string (- (length formatted-sample)
 735                                           (length visible-string)
 736                                           (length "..."))
 737                                        ? ))))
 738
 739       ;; Use different faces to show matching and non-matching authors.
 740       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 741           ;; The visible string contains both matching and
 742           ;; non-matching authors.
 743           (setq visible-string (notmuch-search-author-propertize visible-string)
 744                 ;; The invisible string must contain only non-matching
 745                 ;; authors, as the visible-string contains both.
 746                 invisible-string (propertize invisible-string
 747                                              'face 'notmuch-search-non-matching-authors))
 748         ;; The visible string contains only matching authors.
 749         (setq visible-string (propertize visible-string
 750                                          'face 'notmuch-search-matching-authors)
 751               ;; The invisible string may contain both matching and
 752               ;; non-matching authors.
 753               invisible-string (notmuch-search-author-propertize invisible-string)))
 754
 755       ;; If there is any invisible text, add it as a tooltip to the
 756       ;; visible text.
 757       (when (not (string= invisible-string ""))
 758         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 759
 760       ;; Insert the visible and, if present, invisible author strings.
 761       (insert visible-string)
 762       (when (not (string= invisible-string ""))
 763         (let ((start (point))
 764               overlay)
 765           (insert invisible-string)
 766           (setq overlay (make-overlay start (point)))
 767           (overlay-put overlay 'invisible 'ellipsis)
 768           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 769       (insert padding))))
 770
 771 (defun notmuch-search-insert-field (field format-string result)
 772   (cond
 773    ((string-equal field "date")
 774     (insert (propertize (format format-string (plist-get result :date_relative))
 775                         'face 'notmuch-search-date)))
 776    ((string-equal field "count")
 777     (insert (propertize (format format-string
 778                                 (format "[%s/%s]" (plist-get result :matched)
 779                                         (plist-get result :total)))
 780                         'face 'notmuch-search-count)))
 781    ((string-equal field "subject")
 782     (insert (propertize (format format-string (plist-get result :subject))
 783                         'face 'notmuch-search-subject)))
 784
 785    ((string-equal field "authors")
 786     (notmuch-search-insert-authors format-string (plist-get result :authors)))
 787
 788    ((string-equal field "tags")
 789     (let ((tags (plist-get result :tags)))
 790       (insert (format format-string (notmuch-tag-format-tags tags)))))))
 791
 792 (defun notmuch-search-show-result (result &optional pos)
 793   "Insert RESULT at POS or the end of the buffer if POS is null."
 794   ;; Ignore excluded matches
 795   (unless (= (plist-get result :matched) 0)
 796     (let ((beg (or pos (point-max))))
 797       (save-excursion
 798         (goto-char beg)
 799         (dolist (spec notmuch-search-result-format)
 800           (notmuch-search-insert-field (car spec) (cdr spec) result))
 801         (insert "\n")
 802         (notmuch-search-color-line beg (point) (plist-get result :tags))
 803         (put-text-property beg (point) 'notmuch-search-result result))
 804       (when (string= (plist-get result :thread) notmuch-search-target-thread)
 805         (setq notmuch-search-target-thread "found")
 806         (goto-char beg)))))
 807
 808 (defun notmuch-search-process-filter (proc string)
 809   "Process and filter the output of \"notmuch search\""
 810   (let ((results-buf (process-buffer proc))
 811         (parse-buf (process-get proc 'parse-buf))
 812         (inhibit-read-only t)
 813         done)
 814     (when (buffer-live-p results-buf)
 815       (with-current-buffer parse-buf
 816         ;; Insert new data
 817         (save-excursion
 818           (goto-char (point-max))
 819           (insert string))
 820         (notmuch-sexp-parse-partial-list 'notmuch-search-show-result
 821                                          results-buf)))))
 822
 823 (defun notmuch-search-tag-all (&optional tag-changes)
 824   "Add/remove tags from all messages in current search buffer.
 825
 826 See `notmuch-tag' for information on the format of TAG-CHANGES."
 827   (interactive)
 828   (apply 'notmuch-tag notmuch-search-query-string tag-changes))
 829
 830 (defun notmuch-search-buffer-title (query)
 831   "Returns the title for a buffer with notmuch search results."
 832   (let* ((saved-search
 833           (let (longest
 834                 (longest-length 0))
 835             (loop for tuple in notmuch-saved-searches
 836                   if (let ((quoted-query (regexp-quote (cdr tuple))))
 837                        (and (string-match (concat "^" quoted-query) query)
 838                             (> (length (match-string 0 query))
 839                                longest-length)))
 840                   do (setq longest tuple))
 841             longest))
 842          (saved-search-name (car saved-search))
 843          (saved-search-query (cdr saved-search)))
 844     (cond ((and saved-search (equal saved-search-query query))
 845            ;; Query is the same as saved search (ignoring case)
 846            (concat "*notmuch-saved-search-" saved-search-name "*"))
 847           (saved-search
 848            (concat "*notmuch-search-"
 849                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 850                                              (concat "[ " saved-search-name " ]")
 851                                              query)
 852                    "*"))
 853           (t
 854            (concat "*notmuch-search-" query "*"))
 855           )))
 856
 857 (defun notmuch-read-query (prompt)
 858   "Read a notmuch-query from the minibuffer with completion.
 859
 860 PROMPT is the string to prompt with."
 861   (lexical-let
 862       ((completions
 863         (append (list "folder:" "thread:" "id:" "date:" "from:" "to:"
 864                       "subject:" "attachment:")
 865                 (mapcar (lambda (tag)
 866                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 867                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 868     (let ((keymap (copy-keymap minibuffer-local-map))
 869           (minibuffer-completion-table
 870            (completion-table-dynamic
 871             (lambda (string)
 872               ;; generate a list of possible completions for the current input
 873               (cond
 874                ;; this ugly regexp is used to get the last word of the input
 875                ;; possibly preceded by a '('
 876                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 877                 (mapcar (lambda (compl)
 878                           (concat (match-string-no-properties 1 string) compl))
 879                         (all-completions (match-string-no-properties 2 string)
 880                                          completions)))
 881                (t (list string)))))))
 882       ;; this was simpler than convincing completing-read to accept spaces:
 883       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 884       (let ((history-delete-duplicates t))
 885         (read-from-minibuffer prompt nil keymap nil
 886                               'notmuch-search-history nil nil)))))
 887
 888 ;;;###autoload
 889 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 890   "Run \"notmuch search\" with the given `query' and display results.
 891
 892 If `query' is nil, it is read interactively from the minibuffer.
 893 Other optional parameters are used as follows:
 894
 895   oldest-first: A Boolean controlling the sort order of returned threads
 896   target-thread: A thread ID (without the thread: prefix) that will be made
 897                  current if it appears in the search results.
 898   target-line: The line number to move to if the target thread does not
 899                appear in the search results.
 900
 901 When called interactively, this will prompt for a query and use
 902 the configured default sort order."
 903   (interactive
 904    (list
 905     ;; Prompt for a query
 906     nil
 907     ;; Use the default search order (if we're doing a search from a
 908     ;; search buffer, ignore any buffer-local overrides)
 909     (default-value notmuch-search-oldest-first)))
 910
 911   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 912          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 913     (switch-to-buffer buffer)
 914     (notmuch-search-mode)
 915     ;; Don't track undo information for this buffer
 916     (set 'buffer-undo-list t)
 917     (set 'notmuch-search-query-string query)
 918     (set 'notmuch-search-oldest-first oldest-first)
 919     (set 'notmuch-search-target-thread target-thread)
 920     (set 'notmuch-search-target-line target-line)
 921     (let ((proc (get-buffer-process (current-buffer)))
 922           (inhibit-read-only t))
 923       (if proc
 924           (error "notmuch search process already running for query `%s'" query)
 925         )
 926       (erase-buffer)
 927       (goto-char (point-min))
 928       (save-excursion
 929         (let ((proc (notmuch-start-notmuch
 930                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 931                      "search" "--format=sexp" "--format-version=1"
 932                      (if oldest-first
 933                          "--sort=oldest-first"
 934                        "--sort=newest-first")
 935                      query))
 936               ;; Use a scratch buffer to accumulate partial output.
 937               ;; This buffer will be killed by the sentinel, which
 938               ;; should be called no matter how the process dies.
 939               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 940           (process-put proc 'parse-buf parse-buf)
 941           (set-process-filter proc 'notmuch-search-process-filter)
 942           (set-process-query-on-exit-flag proc nil))))
 943     (run-hooks 'notmuch-search-hook)))
 944
 945 (defun notmuch-search-refresh-view ()
 946   "Refresh the current view.
 947
 948 Kills the current buffer and runs a new search with the same
 949 query string as the current search. If the current thread is in
 950 the new search results, then point will be placed on the same
 951 thread. Otherwise, point will be moved to attempt to be in the
 952 same relative position within the new buffer."
 953   (interactive)
 954   (let ((target-line (line-number-at-pos))
 955         (oldest-first notmuch-search-oldest-first)
 956         (target-thread (notmuch-search-find-thread-id 'bare))
 957         (query notmuch-search-query-string))
 958     (notmuch-kill-this-buffer)
 959     (notmuch-search query oldest-first target-thread target-line)
 960     (goto-char (point-min))))
 961
 962 (defcustom notmuch-poll-script nil
 963   "An external script to incorporate new mail into the notmuch database.
 964
 965 This variable controls the action invoked by
 966 `notmuch-search-poll-and-refresh-view' and
 967 `notmuch-hello-poll-and-update' (each have a default keybinding
 968 of 'G') to incorporate new mail into the notmuch database.
 969
 970 If set to nil (the default), new mail is processed by invoking
 971 \"notmuch new\". Otherwise, this should be set to a string that
 972 gives the name of an external script that processes new mail. If
 973 set to the empty string, no command will be run.
 974
 975 The external script could do any of the following depending on
 976 the user's needs:
 977
 978 1. Invoke a program to transfer mail to the local mail store
 979 2. Invoke \"notmuch new\" to incorporate the new mail
 980 3. Invoke one or more \"notmuch tag\" commands to classify the mail
 981
 982 Note that the recommended way of achieving the same is using
 983 \"notmuch new\" hooks."
 984   :type '(choice (const :tag "notmuch new" nil)
 985                  (const :tag "Disabled" "")
 986                  (string :tag "Custom script"))
 987   :group 'notmuch-external)
 988
 989 (defun notmuch-poll ()
 990   "Run \"notmuch new\" or an external script to import mail.
 991
 992 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 993 depending on the value of `notmuch-poll-script'."
 994   (interactive)
 995   (if (stringp notmuch-poll-script)
 996       (unless (string= notmuch-poll-script "")
 997         (call-process notmuch-poll-script nil nil))
 998     (call-process notmuch-command nil nil nil "new")))
 999
1000 (defun notmuch-search-poll-and-refresh-view ()
1001   "Invoke `notmuch-poll' to import mail, then refresh the current view."
1002   (interactive)
1003   (notmuch-poll)
1004   (notmuch-search-refresh-view))
1005
1006 (defun notmuch-search-toggle-order ()
1007   "Toggle the current search order.
1008
1009 This command toggles the sort order for the current search. The
1010 default sort order is defined by `notmuch-search-oldest-first'."
1011   (interactive)
1012   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1013   (notmuch-search-refresh-view))
1014
1015 (defun notmuch-search-filter (query)
1016   "Filter the current search results based on an additional query string.
1017
1018 Runs a new search matching only messages that match both the
1019 current search results AND the additional query string provided."
1020   (interactive (list (notmuch-read-query "Filter search: ")))
1021   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
1022                            (concat "( " query " )")
1023                          query)))
1024     (notmuch-search (if (string= notmuch-search-query-string "*")
1025                         grouped-query
1026                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
1027
1028 (defun notmuch-search-filter-by-tag (tag)
1029   "Filter the current search results based on a single tag.
1030
1031 Runs a new search matching only messages that match both the
1032 current search results AND that are tagged with the given tag."
1033   (interactive
1034    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
1035   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1036
1037 ;;;###autoload
1038 (defun notmuch ()
1039   "Run notmuch and display saved searches, known tags, etc."
1040   (interactive)
1041   (notmuch-hello))
1042
1043 (defun notmuch-interesting-buffer (b)
1044   "Is the current buffer of interest to a notmuch user?"
1045   (with-current-buffer b
1046     (memq major-mode '(notmuch-show-mode
1047                        notmuch-search-mode
1048                        notmuch-hello-mode
1049                        message-mode))))
1050
1051 ;;;###autoload
1052 (defun notmuch-cycle-notmuch-buffers ()
1053   "Cycle through any existing notmuch buffers (search, show or hello).
1054
1055 If the current buffer is the only notmuch buffer, bury it. If no
1056 notmuch buffers exist, run `notmuch'."
1057   (interactive)
1058
1059   (let (start first)
1060     ;; If the current buffer is a notmuch buffer, remember it and then
1061     ;; bury it.
1062     (when (notmuch-interesting-buffer (current-buffer))
1063       (setq start (current-buffer))
1064       (bury-buffer))
1065
1066     ;; Find the first notmuch buffer.
1067     (setq first (loop for buffer in (buffer-list)
1068                      if (notmuch-interesting-buffer buffer)
1069                      return buffer))
1070
1071     (if first
1072         ;; If the first one we found is any other than the starting
1073         ;; buffer, switch to it.
1074         (unless (eq first start)
1075           (switch-to-buffer first))
1076       (notmuch))))
1077
1078 (setq mail-user-agent 'notmuch-user-agent)
1079
1080 (provide 'notmuch)