git.notmuchmail.org Git - notmuch/blob - emacs/notmuch.el

   1 ;; notmuch.el --- run notmuch within emacs
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an emacs-based interface to the notmuch mail system.
  23 ;;
  24 ;; You will first need to have the notmuch program installed and have a
  25 ;; notmuch database built in order to use this. See
  26 ;; http://notmuchmail.org for details.
  27 ;;
  28 ;; To install this software, copy it to a directory that is on the
  29 ;; `load-path' variable within emacs (a good candidate is
  30 ;; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ;; notmuch source distribution then you can simply run:
  32 ;;
  33 ;;      sudo make install-emacs
  34 ;;
  35 ;; to install it.
  36 ;;
  37 ;; Then, to actually run it, add:
  38 ;;
  39 ;;      (autoload 'notmuch "notmuch" "Notmuch mail" t)
  40 ;;
  41 ;; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ;; or run:
  43 ;;
  44 ;;      emacs -f notmuch
  45 ;;
  46 ;; Have fun, and let us know if you have any comment, questions, or
  47 ;; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ;; required, but is available from http://notmuchmail.org).
  49
  50 (eval-when-compile (require 'cl))
  51 (require 'mm-view)
  52 (require 'message)
  53
  54 (require 'notmuch-lib)
  55 (require 'notmuch-tag)
  56 (require 'notmuch-show)
  57 (require 'notmuch-tree)
  58 (require 'notmuch-mua)
  59 (require 'notmuch-hello)
  60 (require 'notmuch-maildir-fcc)
  61 (require 'notmuch-message)
  62 (require 'notmuch-parser)
  63
  64 (unless (require 'notmuch-version nil t)
  65   (defconst notmuch-emacs-version "unknown"
  66     "Placeholder variable when notmuch-version.el[c] is not available."))
  67
  68 (defcustom notmuch-search-result-format
  69   `(("date" . "%12s ")
  70     ("count" . "%-7s ")
  71     ("authors" . "%-20s ")
  72     ("subject" . "%s ")
  73     ("tags" . "(%s)"))
  74   "Search result formatting. Supported fields are:
  75         date, count, authors, subject, tags
  76 For example:
  77         (setq notmuch-search-result-format \(\(\"authors\" . \"%-40s\"\)
  78                                              \(\"subject\" . \"%s\"\)\)\)
  79 Line breaks are permitted in format strings (though this is
  80 currently experimental).  Note that a line break at the end of an
  81 \"authors\" field will get elided if the authors list is long;
  82 place it instead at the beginning of the following field.  To
  83 enter a line break when setting this variable with setq, use \\n.
  84 To enter a line break in customize, press \\[quoted-insert] C-j."
  85   :type '(alist :key-type (string) :value-type (string))
  86   :group 'notmuch-search)
  87
  88 ;; The name of this variable `notmuch-init-file' is consistent with the
  89 ;; convention used in e.g. emacs and gnus. The value, `notmuch-config[.el[c]]'
  90 ;; is consistent with notmuch cli configuration file `~/.notmuch-config'.
  91 (defcustom notmuch-init-file (locate-user-emacs-file "notmuch-config")
  92   "Your Notmuch Emacs-Lisp configuration file name.
  93 If a file with one of the suffixes defined by `get-load-suffixes' exists,
  94 it will be read instead.
  95 This file is read once when notmuch is loaded; the notmuch hooks added
  96 there will be called at other points of notmuch execution."
  97   :type 'file
  98   :group 'notmuch)
  99
 100 (defvar notmuch-query-history nil
 101   "Variable to store minibuffer history for notmuch queries")
 102
 103 (defun notmuch-foreach-mime-part (function mm-handle)
 104   (cond ((stringp (car mm-handle))
 105          (dolist (part (cdr mm-handle))
 106            (notmuch-foreach-mime-part function part)))
 107         ((bufferp (car mm-handle))
 108          (funcall function mm-handle))
 109         (t (dolist (part mm-handle)
 110              (notmuch-foreach-mime-part function part)))))
 111
 112 (defun notmuch-count-attachments (mm-handle)
 113   (let ((count 0))
 114     (notmuch-foreach-mime-part
 115      (lambda (p)
 116        (let ((disposition (mm-handle-disposition p)))
 117          (and (listp disposition)
 118               (or (equal (car disposition) "attachment")
 119                   (and (equal (car disposition) "inline")
 120                        (assq 'filename disposition)))
 121               (incf count))))
 122      mm-handle)
 123     count))
 124
 125 (defun notmuch-save-attachments (mm-handle &optional queryp)
 126   (notmuch-foreach-mime-part
 127    (lambda (p)
 128      (let ((disposition (mm-handle-disposition p)))
 129        (and (listp disposition)
 130             (or (equal (car disposition) "attachment")
 131                 (and (equal (car disposition) "inline")
 132                      (assq 'filename disposition)))
 133             (or (not queryp)
 134                 (y-or-n-p
 135                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 136             (mm-save-part p))))
 137    mm-handle))
 138
 139 (require 'hl-line)
 140
 141 (defun notmuch-hl-line-mode ()
 142   (prog1 (hl-line-mode)
 143     (when hl-line-overlay
 144       (overlay-put hl-line-overlay 'priority 1))))
 145
 146 (defcustom notmuch-search-hook '(notmuch-hl-line-mode)
 147   "List of functions to call when notmuch displays the search results."
 148   :type 'hook
 149   :options '(notmuch-hl-line-mode)
 150   :group 'notmuch-search
 151   :group 'notmuch-hooks)
 152
 153 (defvar notmuch-search-mode-map
 154   (let ((map (make-sparse-keymap)))
 155     (set-keymap-parent map notmuch-common-keymap)
 156     (define-key map "x" 'notmuch-kill-this-buffer)
 157     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 158     (define-key map "b" 'notmuch-search-scroll-down)
 159     (define-key map " " 'notmuch-search-scroll-up)
 160     (define-key map "<" 'notmuch-search-first-thread)
 161     (define-key map ">" 'notmuch-search-last-thread)
 162     (define-key map "p" 'notmuch-search-previous-thread)
 163     (define-key map "n" 'notmuch-search-next-thread)
 164     (define-key map "r" 'notmuch-search-reply-to-thread-sender)
 165     (define-key map "R" 'notmuch-search-reply-to-thread)
 166     (define-key map "o" 'notmuch-search-toggle-order)
 167     (define-key map "c" 'notmuch-search-stash-map)
 168     (define-key map "t" 'notmuch-search-filter-by-tag)
 169     (define-key map "f" 'notmuch-search-filter)
 170     (define-key map [mouse-1] 'notmuch-search-show-thread)
 171     (define-key map "*" 'notmuch-search-tag-all)
 172     (define-key map "a" 'notmuch-search-archive-thread)
 173     (define-key map "-" 'notmuch-search-remove-tag)
 174     (define-key map "+" 'notmuch-search-add-tag)
 175     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 176     (define-key map "Z" 'notmuch-tree-from-search-current-query)
 177     map)
 178   "Keymap for \"notmuch search\" buffers.")
 179 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 180
 181 (defvar notmuch-search-stash-map
 182   (let ((map (make-sparse-keymap)))
 183     (define-key map "i" 'notmuch-search-stash-thread-id)
 184     (define-key map "?" 'notmuch-subkeymap-help)
 185     map)
 186   "Submap for stash commands")
 187 (fset 'notmuch-search-stash-map notmuch-search-stash-map)
 188
 189 (defun notmuch-search-stash-thread-id ()
 190   "Copy thread ID of current thread to kill-ring."
 191   (interactive)
 192   (notmuch-common-do-stash (notmuch-search-find-thread-id)))
 193
 194 (defvar notmuch-search-query-string)
 195 (defvar notmuch-search-target-thread)
 196 (defvar notmuch-search-target-line)
 197
 198 (defvar notmuch-search-disjunctive-regexp      "\\<[oO][rR]\\>")
 199
 200 (defun notmuch-search-scroll-up ()
 201   "Move forward through search results by one window's worth."
 202   (interactive)
 203   (condition-case nil
 204       (scroll-up nil)
 205     ((end-of-buffer) (notmuch-search-last-thread))))
 206
 207 (defun notmuch-search-scroll-down ()
 208   "Move backward through the search results by one window's worth."
 209   (interactive)
 210   ;; I don't know why scroll-down doesn't signal beginning-of-buffer
 211   ;; the way that scroll-up signals end-of-buffer, but c'est la vie.
 212   ;;
 213   ;; So instead of trapping a signal we instead check whether the
 214   ;; window begins on the first line of the buffer and if so, move
 215   ;; directly to that position. (We have to count lines since the
 216   ;; window-start position is not the same as point-min due to the
 217   ;; invisible thread-ID characters on the first line.
 218   (if (equal (count-lines (point-min) (window-start)) 0)
 219       (goto-char (point-min))
 220     (scroll-down nil)))
 221
 222 (defun notmuch-search-next-thread ()
 223   "Select the next thread in the search results."
 224   (interactive)
 225   (when (notmuch-search-get-result)
 226     (goto-char (notmuch-search-result-end))))
 227
 228 (defun notmuch-search-previous-thread ()
 229   "Select the previous thread in the search results."
 230   (interactive)
 231   (if (notmuch-search-get-result)
 232       (unless (bobp)
 233         (goto-char (notmuch-search-result-beginning (- (point) 1))))
 234     ;; We must be past the end; jump to the last result
 235     (notmuch-search-last-thread)))
 236
 237 (defun notmuch-search-last-thread ()
 238   "Select the last thread in the search results."
 239   (interactive)
 240   (goto-char (point-max))
 241   (forward-line -2)
 242   (let ((beg (notmuch-search-result-beginning)))
 243     (when beg (goto-char beg))))
 244
 245 (defun notmuch-search-first-thread ()
 246   "Select the first thread in the search results."
 247   (interactive)
 248   (goto-char (point-min)))
 249
 250 (defface notmuch-message-summary-face
 251  '((((class color) (background light)) (:background "#f0f0f0"))
 252    (((class color) (background dark)) (:background "#303030")))
 253  "Face for the single-line message summary in notmuch-show-mode."
 254  :group 'notmuch-show
 255  :group 'notmuch-faces)
 256
 257 (defface notmuch-search-date
 258   '((t :inherit default))
 259   "Face used in search mode for dates."
 260   :group 'notmuch-search
 261   :group 'notmuch-faces)
 262
 263 (defface notmuch-search-count
 264   '((t :inherit default))
 265   "Face used in search mode for the count matching the query."
 266   :group 'notmuch-search
 267   :group 'notmuch-faces)
 268
 269 (defface notmuch-search-subject
 270   '((t :inherit default))
 271   "Face used in search mode for subjects."
 272   :group 'notmuch-search
 273   :group 'notmuch-faces)
 274
 275 (defface notmuch-search-matching-authors
 276   '((t :inherit default))
 277   "Face used in search mode for authors matching the query."
 278   :group 'notmuch-search
 279   :group 'notmuch-faces)
 280
 281 (defface notmuch-search-non-matching-authors
 282   '((((class color)
 283       (background dark))
 284      (:foreground "grey30"))
 285     (((class color)
 286       (background light))
 287      (:foreground "grey60"))
 288     (t
 289      (:italic t)))
 290   "Face used in search mode for authors not matching the query."
 291   :group 'notmuch-search
 292   :group 'notmuch-faces)
 293
 294 (defface notmuch-tag-face
 295   '((((class color)
 296       (background dark))
 297      (:foreground "OliveDrab1"))
 298     (((class color)
 299       (background light))
 300      (:foreground "navy blue" :bold t))
 301     (t
 302      (:bold t)))
 303   "Face used in search mode face for tags."
 304   :group 'notmuch-search
 305   :group 'notmuch-faces)
 306
 307 (defun notmuch-search-mode ()
 308   "Major mode displaying results of a notmuch search.
 309
 310 This buffer contains the results of a \"notmuch search\" of your
 311 email archives. Each line in the buffer represents a single
 312 thread giving a summary of the thread (a relative date, the
 313 number of matched messages and total messages in the thread,
 314 participants in the thread, a representative subject line, and
 315 any tags).
 316
 317 Pressing \\[notmuch-search-show-thread] on any line displays that
 318 thread. The '\\[notmuch-search-add-tag]' and
 319 '\\[notmuch-search-remove-tag]' keys can be used to add or remove
 320 tags from a thread. The '\\[notmuch-search-archive-thread]' key
 321 is a convenience for archiving a thread (applying changes in
 322 `notmuch-archive-tags'). The '\\[notmuch-search-tag-all]' key can
 323 be used to add and/or remove tags from all messages (as opposed
 324 to threads) that match the current query.  Use with caution, as
 325 this will also tag matching messages that arrived *after*
 326 constructing the buffer.
 327
 328 Other useful commands are '\\[notmuch-search-filter]' for
 329 filtering the current search based on an additional query string,
 330 '\\[notmuch-search-filter-by-tag]' for filtering to include only
 331 messages with a given tag, and '\\[notmuch-search]' to execute a
 332 new, global search.
 333
 334 Complete list of currently available key bindings:
 335
 336 \\{notmuch-search-mode-map}"
 337   (interactive)
 338   (kill-all-local-variables)
 339   (make-local-variable 'notmuch-search-query-string)
 340   (make-local-variable 'notmuch-search-oldest-first)
 341   (make-local-variable 'notmuch-search-target-thread)
 342   (make-local-variable 'notmuch-search-target-line)
 343   (setq notmuch-buffer-refresh-function #'notmuch-search-refresh-view)
 344   (set (make-local-variable 'scroll-preserve-screen-position) t)
 345   (add-to-invisibility-spec (cons 'ellipsis t))
 346   (use-local-map notmuch-search-mode-map)
 347   (setq truncate-lines t)
 348   (setq major-mode 'notmuch-search-mode
 349         mode-name "notmuch-search")
 350   (setq buffer-read-only t))
 351
 352 (defun notmuch-search-get-result (&optional pos)
 353   "Return the result object for the thread at POS (or point).
 354
 355 If there is no thread at POS (or point), returns nil."
 356   (get-text-property (or pos (point)) 'notmuch-search-result))
 357
 358 (defun notmuch-search-result-beginning (&optional pos)
 359   "Return the point at the beginning of the thread at POS (or point).
 360
 361 If there is no thread at POS (or point), returns nil."
 362   (when (notmuch-search-get-result pos)
 363     ;; We pass 1+point because previous-single-property-change starts
 364     ;; searching one before the position we give it.
 365     (previous-single-property-change (1+ (or pos (point)))
 366                                      'notmuch-search-result nil (point-min))))
 367
 368 (defun notmuch-search-result-end (&optional pos)
 369   "Return the point at the end of the thread at POS (or point).
 370
 371 The returned point will be just after the newline character that
 372 ends the result line.  If there is no thread at POS (or point),
 373 returns nil"
 374   (when (notmuch-search-get-result pos)
 375     (next-single-property-change (or pos (point)) 'notmuch-search-result
 376                                  nil (point-max))))
 377
 378 (defun notmuch-search-foreach-result (beg end function)
 379   "Invoke FUNCTION for each result between BEG and END.
 380
 381 FUNCTION should take one argument.  It will be applied to the
 382 character position of the beginning of each result that overlaps
 383 the region between points BEG and END.  As a special case, if (=
 384 BEG END), FUNCTION will be applied to the result containing point
 385 BEG."
 386
 387   (lexical-let ((pos (notmuch-search-result-beginning beg))
 388                 ;; End must be a marker in case function changes the
 389                 ;; text.
 390                 (end (copy-marker end))
 391                 ;; Make sure we examine at least one result, even if
 392                 ;; (= beg end).
 393                 (first t))
 394     ;; We have to be careful if the region extends beyond the results.
 395     ;; In this case, pos could be null or there could be no result at
 396     ;; pos.
 397     (while (and pos (or (< pos end) first))
 398       (when (notmuch-search-get-result pos)
 399         (funcall function pos))
 400       (setq pos (notmuch-search-result-end pos)
 401             first nil))))
 402 ;; Unindent the function argument of notmuch-search-foreach-result so
 403 ;; the indentation of callers doesn't get out of hand.
 404 (put 'notmuch-search-foreach-result 'lisp-indent-function 2)
 405
 406 (defun notmuch-search-properties-in-region (property beg end)
 407   (let (output)
 408     (notmuch-search-foreach-result beg end
 409       (lambda (pos)
 410         (push (plist-get (notmuch-search-get-result pos) property) output)))
 411     output))
 412
 413 (defun notmuch-search-find-thread-id (&optional bare)
 414   "Return the thread for the current thread
 415
 416 If BARE is set then do not prefix with \"thread:\""
 417   (let ((thread (plist-get (notmuch-search-get-result) :thread)))
 418     (when thread (concat (unless bare "thread:") thread))))
 419
 420 (defun notmuch-search-find-stable-query ()
 421   "Return the stable queries for the current thread.
 422
 423 This returns a list (MATCHED-QUERY UNMATCHED-QUERY) for the
 424 matched and unmatched messages in the current thread."
 425   (plist-get (notmuch-search-get-result) :query))
 426
 427 (defun notmuch-search-find-stable-query-region (beg end &optional only-matched)
 428   "Return the stable query for the current region.
 429
 430 If ONLY-MATCHED is non-nil, include only matched messages.  If it
 431 is nil, include both matched and unmatched messages. If there are
 432 no messages in the region then return nil."
 433   (let ((query-list nil) (all (not only-matched)))
 434     (dolist (queries (notmuch-search-properties-in-region :query beg end))
 435       (when (first queries)
 436         (push (first queries) query-list))
 437       (when (and all (second queries))
 438         (push (second queries) query-list)))
 439     (when query-list
 440       (concat "(" (mapconcat 'identity query-list ") or (") ")"))))
 441
 442 (defun notmuch-search-find-authors ()
 443   "Return the authors for the current thread"
 444   (plist-get (notmuch-search-get-result) :authors))
 445
 446 (defun notmuch-search-find-authors-region (beg end)
 447   "Return a list of authors for the current region"
 448   (notmuch-search-properties-in-region :authors beg end))
 449
 450 (defun notmuch-search-find-subject ()
 451   "Return the subject for the current thread"
 452   (plist-get (notmuch-search-get-result) :subject))
 453
 454 (defun notmuch-search-find-subject-region (beg end)
 455   "Return a list of authors for the current region"
 456   (notmuch-search-properties-in-region :subject beg end))
 457
 458 (defun notmuch-search-show-thread (&optional elide-toggle)
 459   "Display the currently selected thread."
 460   (interactive "P")
 461   (let ((thread-id (notmuch-search-find-thread-id))
 462         (subject (notmuch-search-find-subject)))
 463     (if (> (length thread-id) 0)
 464         (notmuch-show thread-id
 465                       elide-toggle
 466                       (current-buffer)
 467                       notmuch-search-query-string
 468                       ;; Name the buffer based on the subject.
 469                       (concat "*" (truncate-string-to-width subject 30 nil nil t) "*"))
 470       (message "End of search results."))))
 471
 472 (defun notmuch-tree-from-search-current-query ()
 473   "Call notmuch tree with the current query"
 474   (interactive)
 475   (notmuch-tree notmuch-search-query-string))
 476
 477 (defun notmuch-tree-from-search-thread ()
 478   "Show the selected thread with notmuch-tree"
 479   (interactive)
 480   (notmuch-tree (notmuch-search-find-thread-id)
 481                 notmuch-search-query-string
 482                 nil
 483                 (notmuch-prettify-subject (notmuch-search-find-subject))
 484                 t))
 485
 486 (defun notmuch-search-reply-to-thread (&optional prompt-for-sender)
 487   "Begin composing a reply-all to the entire current thread in a new buffer."
 488   (interactive "P")
 489   (let ((message-id (notmuch-search-find-thread-id)))
 490     (notmuch-mua-new-reply message-id prompt-for-sender t)))
 491
 492 (defun notmuch-search-reply-to-thread-sender (&optional prompt-for-sender)
 493   "Begin composing a reply to the entire current thread in a new buffer."
 494   (interactive "P")
 495   (let ((message-id (notmuch-search-find-thread-id)))
 496     (notmuch-mua-new-reply message-id prompt-for-sender nil)))
 497
 498 (defun notmuch-search-set-tags (tags &optional pos)
 499   (let ((new-result (plist-put (notmuch-search-get-result pos) :tags tags)))
 500     (notmuch-search-update-result new-result pos)))
 501
 502 (defun notmuch-search-get-tags (&optional pos)
 503   (plist-get (notmuch-search-get-result pos) :tags))
 504
 505 (defun notmuch-search-get-tags-region (beg end)
 506   (let (output)
 507     (notmuch-search-foreach-result beg end
 508       (lambda (pos)
 509         (setq output (append output (notmuch-search-get-tags pos)))))
 510     output))
 511
 512 (defun notmuch-search-interactive-region ()
 513   "Return the bounds of the current interactive region.
 514
 515 This returns (BEG END), where BEG and END are the bounds of the
 516 region if the region is active, or both `point' otherwise."
 517   (if (region-active-p)
 518       (list (region-beginning) (region-end))
 519     (list (point) (point))))
 520
 521 (defun notmuch-search-interactive-tag-changes (&optional initial-input)
 522   "Prompt for tag changes for the current thread or region.
 523
 524 Returns (TAG-CHANGES REGION-BEGIN REGION-END)."
 525   (let* ((region (notmuch-search-interactive-region))
 526          (beg (first region)) (end (second region))
 527          (prompt (if (= beg end) "Tag thread" "Tag region")))
 528     (cons (notmuch-read-tag-changes
 529            (notmuch-search-get-tags-region beg end) prompt initial-input)
 530           region)))
 531
 532 (defun notmuch-search-tag (tag-changes &optional beg end only-matched)
 533   "Change tags for the currently selected thread or region.
 534
 535 See `notmuch-tag' for information on the format of TAG-CHANGES.
 536 When called interactively, this uses the region if the region is
 537 active.  When called directly, BEG and END provide the region.
 538 If these are nil or not provided, this applies to the thread at
 539 point.
 540
 541 If ONLY-MATCHED is non-nil, only tag matched messages."
 542   (interactive (notmuch-search-interactive-tag-changes))
 543   (unless (and beg end) (setq beg (point) end (point)))
 544   (let ((search-string (notmuch-search-find-stable-query-region
 545                         beg end only-matched)))
 546     (notmuch-tag search-string tag-changes)
 547     (notmuch-search-foreach-result beg end
 548       (lambda (pos)
 549         (notmuch-search-set-tags
 550          (notmuch-update-tags (notmuch-search-get-tags pos) tag-changes)
 551          pos)))))
 552
 553 (defun notmuch-search-add-tag (tag-changes &optional beg end)
 554   "Change tags for the current thread or region (defaulting to add).
 555
 556 Same as `notmuch-search-tag' but sets initial input to '+'."
 557   (interactive (notmuch-search-interactive-tag-changes "+"))
 558   (notmuch-search-tag tag-changes beg end))
 559
 560 (defun notmuch-search-remove-tag (tag-changes &optional beg end)
 561   "Change tags for the current thread or region (defaulting to remove).
 562
 563 Same as `notmuch-search-tag' but sets initial input to '-'."
 564   (interactive (notmuch-search-interactive-tag-changes "-"))
 565   (notmuch-search-tag tag-changes beg end))
 566
 567 (put 'notmuch-search-archive-thread 'notmuch-prefix-doc
 568      "Un-archive the currently selected thread.")
 569 (defun notmuch-search-archive-thread (&optional unarchive beg end)
 570   "Archive the currently selected thread or region.
 571
 572 Archive each message in the currently selected thread by applying
 573 the tag changes in `notmuch-archive-tags' to each (remove the
 574 \"inbox\" tag by default). If a prefix argument is given, the
 575 messages will be \"unarchived\" (i.e. the tag changes in
 576 `notmuch-archive-tags' will be reversed).
 577
 578 This function advances the next thread when finished."
 579   (interactive (cons current-prefix-arg (notmuch-search-interactive-region)))
 580   (when notmuch-archive-tags
 581     (notmuch-search-tag
 582      (notmuch-tag-change-list notmuch-archive-tags unarchive) beg end))
 583   (notmuch-search-next-thread))
 584
 585 (defun notmuch-search-update-result (result &optional pos)
 586   "Replace the result object of the thread at POS (or point) by
 587 RESULT and redraw it.
 588
 589 This will keep point in a reasonable location.  However, if there
 590 are enclosing save-excursions and the saved point is in the
 591 result being updated, the point will be restored to the beginning
 592 of the result."
 593   (let ((start (notmuch-search-result-beginning pos))
 594         (end (notmuch-search-result-end pos))
 595         (init-point (point))
 596         (inhibit-read-only t))
 597     ;; Delete the current thread
 598     (delete-region start end)
 599     ;; Insert the updated thread
 600     (notmuch-search-show-result result start)
 601     ;; If point was inside the old result, make an educated guess
 602     ;; about where to place it now.  Unfortunately, this won't work
 603     ;; with save-excursion (or any other markers that would be nice to
 604     ;; preserve, such as the window start), but there's nothing we can
 605     ;; do about that without a way to retrieve markers in a region.
 606     (when (and (>= init-point start) (<= init-point end))
 607       (let* ((new-end (notmuch-search-result-end start))
 608              (new-point (if (= init-point end)
 609                             new-end
 610                           (min init-point (- new-end 1)))))
 611         (goto-char new-point)))))
 612
 613 (defun notmuch-search-process-sentinel (proc msg)
 614   "Add a message to let user know when \"notmuch search\" exits"
 615   (let ((buffer (process-buffer proc))
 616         (status (process-status proc))
 617         (exit-status (process-exit-status proc))
 618         (never-found-target-thread nil))
 619     (when (memq status '(exit signal))
 620       (catch 'return
 621         (kill-buffer (process-get proc 'parse-buf))
 622         (if (buffer-live-p buffer)
 623             (with-current-buffer buffer
 624               (save-excursion
 625                 (let ((inhibit-read-only t)
 626                       (atbob (bobp)))
 627                   (goto-char (point-max))
 628                   (if (eq status 'signal)
 629                       (insert "Incomplete search results (search process was killed).\n"))
 630                   (when (eq status 'exit)
 631                     (insert "End of search results.\n")
 632                     ;; For version mismatch, there's no point in
 633                     ;; showing the search buffer
 634                     (when (or (= exit-status 20) (= exit-status 21))
 635                       (kill-buffer)
 636                       (throw 'return nil))
 637                     (if (and atbob
 638                              (not (string= notmuch-search-target-thread "found")))
 639                         (set 'never-found-target-thread t)))))
 640               (when (and never-found-target-thread
 641                        notmuch-search-target-line)
 642                   (goto-char (point-min))
 643                   (forward-line (1- notmuch-search-target-line)))))))))
 644
 645 (defcustom notmuch-search-line-faces '(("unread" :weight bold)
 646                                        ("flagged" :foreground "blue"))
 647   "Tag/face mapping for line highlighting in notmuch-search.
 648
 649 Here is an example of how to color search results based on tags.
 650  (the following text would be placed in your ~/.emacs file):
 651
 652  (setq notmuch-search-line-faces '((\"unread\" . (:foreground \"green\"))
 653                                    (\"deleted\" . (:foreground \"red\"
 654                                                   :background \"blue\"))))
 655
 656 The attributes defined for matching tags are merged, with earlier
 657 attributes overriding later. A message having both \"deleted\"
 658 and \"unread\" tags with the above settings would have a green
 659 foreground and blue background."
 660   :type '(alist :key-type (string) :value-type (custom-face-edit))
 661   :group 'notmuch-search
 662   :group 'notmuch-faces)
 663
 664 (defun notmuch-search-color-line (start end line-tag-list)
 665   "Colorize lines in `notmuch-show' based on tags."
 666   (mapc (lambda (elem)
 667           (let ((tag (car elem))
 668                 (attributes (cdr elem)))
 669             (when (member tag line-tag-list)
 670               (notmuch-apply-face nil attributes nil start end))))
 671         ;; Reverse the list so earlier entries take precedence
 672         (reverse notmuch-search-line-faces)))
 673
 674 (defun notmuch-search-author-propertize (authors)
 675   "Split `authors' into matching and non-matching authors and
 676 propertize appropriately. If no boundary between authors and
 677 non-authors is found, assume that all of the authors match."
 678   (if (string-match "\\(.*\\)|\\(.*\\)" authors)
 679       (concat (propertize (concat (match-string 1 authors) ",")
 680                           'face 'notmuch-search-matching-authors)
 681               (propertize (match-string 2 authors)
 682                           'face 'notmuch-search-non-matching-authors))
 683     (propertize authors 'face 'notmuch-search-matching-authors)))
 684
 685 (defun notmuch-search-insert-authors (format-string authors)
 686   ;; Save the match data to avoid interfering with
 687   ;; `notmuch-search-process-filter'.
 688   (save-match-data
 689     (let* ((formatted-authors (format format-string authors))
 690            (formatted-sample (format format-string ""))
 691            (visible-string formatted-authors)
 692            (invisible-string "")
 693            (padding ""))
 694
 695       ;; Truncate the author string to fit the specification.
 696       (if (> (length formatted-authors)
 697              (length formatted-sample))
 698           (let ((visible-length (- (length formatted-sample)
 699                                    (length "... "))))
 700             ;; Truncate the visible string according to the width of
 701             ;; the display string.
 702             (setq visible-string (substring formatted-authors 0 visible-length)
 703                   invisible-string (substring formatted-authors visible-length))
 704             ;; If possible, truncate the visible string at a natural
 705             ;; break (comma or pipe), as incremental search doesn't
 706             ;; match across the visible/invisible border.
 707             (when (string-match "\\(.*\\)\\([,|] \\)\\([^,|]*\\)" visible-string)
 708               ;; Second clause is destructive on `visible-string', so
 709               ;; order is important.
 710               (setq invisible-string (concat (match-string 3 visible-string)
 711                                              invisible-string)
 712                     visible-string (concat (match-string 1 visible-string)
 713                                            (match-string 2 visible-string))))
 714             ;; `visible-string' may be shorter than the space allowed
 715             ;; by `format-string'. If so we must insert some padding
 716             ;; after `invisible-string'.
 717             (setq padding (make-string (- (length formatted-sample)
 718                                           (length visible-string)
 719                                           (length "..."))
 720                                        ? ))))
 721
 722       ;; Use different faces to show matching and non-matching authors.
 723       (if (string-match "\\(.*\\)|\\(.*\\)" visible-string)
 724           ;; The visible string contains both matching and
 725           ;; non-matching authors.
 726           (setq visible-string (notmuch-search-author-propertize visible-string)
 727                 ;; The invisible string must contain only non-matching
 728                 ;; authors, as the visible-string contains both.
 729                 invisible-string (propertize invisible-string
 730                                              'face 'notmuch-search-non-matching-authors))
 731         ;; The visible string contains only matching authors.
 732         (setq visible-string (propertize visible-string
 733                                          'face 'notmuch-search-matching-authors)
 734               ;; The invisible string may contain both matching and
 735               ;; non-matching authors.
 736               invisible-string (notmuch-search-author-propertize invisible-string)))
 737
 738       ;; If there is any invisible text, add it as a tooltip to the
 739       ;; visible text.
 740       (when (not (string= invisible-string ""))
 741         (setq visible-string (propertize visible-string 'help-echo (concat "..." invisible-string))))
 742
 743       ;; Insert the visible and, if present, invisible author strings.
 744       (insert visible-string)
 745       (when (not (string= invisible-string ""))
 746         (let ((start (point))
 747               overlay)
 748           (insert invisible-string)
 749           (setq overlay (make-overlay start (point)))
 750           (overlay-put overlay 'invisible 'ellipsis)
 751           (overlay-put overlay 'isearch-open-invisible #'delete-overlay)))
 752       (insert padding))))
 753
 754 (defun notmuch-search-insert-field (field format-string result)
 755   (cond
 756    ((string-equal field "date")
 757     (insert (propertize (format format-string (plist-get result :date_relative))
 758                         'face 'notmuch-search-date)))
 759    ((string-equal field "count")
 760     (insert (propertize (format format-string
 761                                 (format "[%s/%s]" (plist-get result :matched)
 762                                         (plist-get result :total)))
 763                         'face 'notmuch-search-count)))
 764    ((string-equal field "subject")
 765     (insert (propertize (format format-string
 766                                 (notmuch-sanitize (plist-get result :subject)))
 767                         'face 'notmuch-search-subject)))
 768
 769    ((string-equal field "authors")
 770     (notmuch-search-insert-authors
 771      format-string (notmuch-sanitize (plist-get result :authors))))
 772
 773    ((string-equal field "tags")
 774     (let ((tags (plist-get result :tags))
 775           (orig-tags (plist-get result :orig-tags)))
 776       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 777
 778 (defun notmuch-search-show-result (result pos)
 779   "Insert RESULT at POS."
 780   ;; Ignore excluded matches
 781   (unless (= (plist-get result :matched) 0)
 782     (save-excursion
 783       (goto-char pos)
 784       (dolist (spec notmuch-search-result-format)
 785         (notmuch-search-insert-field (car spec) (cdr spec) result))
 786       (insert "\n")
 787       (notmuch-search-color-line pos (point) (plist-get result :tags))
 788       (put-text-property pos (point) 'notmuch-search-result result))))
 789
 790 (defun notmuch-search-append-result (result)
 791   "Insert RESULT at the end of the buffer.
 792
 793 This is only called when a result is first inserted so it also
 794 sets the :orig-tag property."
 795   (let ((new-result (plist-put result :orig-tags (plist-get result :tags)))
 796         (pos (point-max)))
 797     (notmuch-search-show-result new-result pos)
 798     (when (string= (plist-get result :thread) notmuch-search-target-thread)
 799       (setq notmuch-search-target-thread "found")
 800       (goto-char pos))))
 801
 802 (defun notmuch-search-process-filter (proc string)
 803   "Process and filter the output of \"notmuch search\""
 804   (let ((results-buf (process-buffer proc))
 805         (parse-buf (process-get proc 'parse-buf))
 806         (inhibit-read-only t)
 807         done)
 808     (when (buffer-live-p results-buf)
 809       (with-current-buffer parse-buf
 810         ;; Insert new data
 811         (save-excursion
 812           (goto-char (point-max))
 813           (insert string))
 814         (notmuch-sexp-parse-partial-list 'notmuch-search-append-result
 815                                          results-buf)))))
 816
 817 (defun notmuch-search-tag-all (tag-changes)
 818   "Add/remove tags from all messages in current search buffer.
 819
 820 See `notmuch-tag' for information on the format of TAG-CHANGES."
 821   (interactive
 822    (list (notmuch-read-tag-changes
 823           (notmuch-search-get-tags-region (point-min) (point-max)) "Tag all")))
 824   (notmuch-search-tag tag-changes (point-min) (point-max) t))
 825
 826 (defun notmuch-search-buffer-title (query)
 827   "Returns the title for a buffer with notmuch search results."
 828   (let* ((saved-search
 829           (let (longest
 830                 (longest-length 0))
 831             (loop for tuple in notmuch-saved-searches
 832                   if (let ((quoted-query (regexp-quote (notmuch-saved-search-get tuple :query))))
 833                        (and (string-match (concat "^" quoted-query) query)
 834                             (> (length (match-string 0 query))
 835                                longest-length)))
 836                   do (setq longest tuple))
 837             longest))
 838          (saved-search-name (notmuch-saved-search-get saved-search :name))
 839          (saved-search-query (notmuch-saved-search-get saved-search :query)))
 840     (cond ((and saved-search (equal saved-search-query query))
 841            ;; Query is the same as saved search (ignoring case)
 842            (concat "*notmuch-saved-search-" saved-search-name "*"))
 843           (saved-search
 844            (concat "*notmuch-search-"
 845                    (replace-regexp-in-string (concat "^" (regexp-quote saved-search-query))
 846                                              (concat "[ " saved-search-name " ]")
 847                                              query)
 848                    "*"))
 849           (t
 850            (concat "*notmuch-search-" query "*"))
 851           )))
 852
 853 (defun notmuch-read-query (prompt)
 854   "Read a notmuch-query from the minibuffer with completion.
 855
 856 PROMPT is the string to prompt with."
 857   (lexical-let
 858       ((completions
 859         (append (list "folder:" "path:" "thread:" "id:" "date:" "from:" "to:"
 860                       "subject:" "attachment:")
 861                 (mapcar (lambda (tag)
 862                           (concat "tag:" (notmuch-escape-boolean-term tag)))
 863                         (process-lines notmuch-command "search" "--output=tags" "*")))))
 864     (let ((keymap (copy-keymap minibuffer-local-map))
 865           (minibuffer-completion-table
 866            (completion-table-dynamic
 867             (lambda (string)
 868               ;; generate a list of possible completions for the current input
 869               (cond
 870                ;; this ugly regexp is used to get the last word of the input
 871                ;; possibly preceded by a '('
 872                ((string-match "\\(^\\|.* (?\\)\\([^ ]*\\)$" string)
 873                 (mapcar (lambda (compl)
 874                           (concat (match-string-no-properties 1 string) compl))
 875                         (all-completions (match-string-no-properties 2 string)
 876                                          completions)))
 877                (t (list string)))))))
 878       ;; this was simpler than convincing completing-read to accept spaces:
 879       (define-key keymap (kbd "TAB") 'minibuffer-complete)
 880       (let ((history-delete-duplicates t))
 881         (read-from-minibuffer prompt nil keymap nil
 882                               'notmuch-search-history nil nil)))))
 883
 884 ;;;###autoload
 885 (put 'notmuch-search 'notmuch-doc "Search for messages.")
 886 (defun notmuch-search (&optional query oldest-first target-thread target-line)
 887   "Display threads matching QUERY in a notmuch-search buffer.
 888
 889 If QUERY is nil, it is read interactively from the minibuffer.
 890 Other optional parameters are used as follows:
 891
 892   OLDEST-FIRST: A Boolean controlling the sort order of returned threads
 893   TARGET-THREAD: A thread ID (without the thread: prefix) that will be made
 894                  current if it appears in the search results.
 895   TARGET-LINE: The line number to move to if the target thread does not
 896                appear in the search results.
 897
 898 When called interactively, this will prompt for a query and use
 899 the configured default sort order."
 900   (interactive
 901    (list
 902     ;; Prompt for a query
 903     nil
 904     ;; Use the default search order (if we're doing a search from a
 905     ;; search buffer, ignore any buffer-local overrides)
 906     (default-value 'notmuch-search-oldest-first)))
 907
 908   (let* ((query (or query (notmuch-read-query "Notmuch search: ")))
 909          (buffer (get-buffer-create (notmuch-search-buffer-title query))))
 910     (switch-to-buffer buffer)
 911     (notmuch-search-mode)
 912     ;; Don't track undo information for this buffer
 913     (set 'buffer-undo-list t)
 914     (set 'notmuch-search-query-string query)
 915     (set 'notmuch-search-oldest-first oldest-first)
 916     (set 'notmuch-search-target-thread target-thread)
 917     (set 'notmuch-search-target-line target-line)
 918     (notmuch-tag-clear-cache)
 919     (let ((proc (get-buffer-process (current-buffer)))
 920           (inhibit-read-only t))
 921       (if proc
 922           (error "notmuch search process already running for query `%s'" query)
 923         )
 924       (erase-buffer)
 925       (goto-char (point-min))
 926       (save-excursion
 927         (let ((proc (notmuch-start-notmuch
 928                      "notmuch-search" buffer #'notmuch-search-process-sentinel
 929                      "search" "--format=sexp" "--format-version=2"
 930                      (if oldest-first
 931                          "--sort=oldest-first"
 932                        "--sort=newest-first")
 933                      query))
 934               ;; Use a scratch buffer to accumulate partial output.
 935               ;; This buffer will be killed by the sentinel, which
 936               ;; should be called no matter how the process dies.
 937               (parse-buf (generate-new-buffer " *notmuch search parse*")))
 938           (process-put proc 'parse-buf parse-buf)
 939           (set-process-filter proc 'notmuch-search-process-filter)
 940           (set-process-query-on-exit-flag proc nil))))
 941     (run-hooks 'notmuch-search-hook)))
 942
 943 (defun notmuch-search-refresh-view ()
 944   "Refresh the current view.
 945
 946 Kills the current buffer and runs a new search with the same
 947 query string as the current search. If the current thread is in
 948 the new search results, then point will be placed on the same
 949 thread. Otherwise, point will be moved to attempt to be in the
 950 same relative position within the new buffer."
 951   (let ((target-line (line-number-at-pos))
 952         (oldest-first notmuch-search-oldest-first)
 953         (target-thread (notmuch-search-find-thread-id 'bare))
 954         (query notmuch-search-query-string))
 955     (notmuch-kill-this-buffer)
 956     (notmuch-search query oldest-first target-thread target-line)
 957     (goto-char (point-min))))
 958
 959 (defun notmuch-search-toggle-order ()
 960   "Toggle the current search order.
 961
 962 This command toggles the sort order for the current search. The
 963 default sort order is defined by `notmuch-search-oldest-first'."
 964   (interactive)
 965   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
 966   (notmuch-search-refresh-view))
 967
 968 (defun notmuch-search-filter (query)
 969   "Filter the current search results based on an additional query string.
 970
 971 Runs a new search matching only messages that match both the
 972 current search results AND the additional query string provided."
 973   (interactive (list (notmuch-read-query "Filter search: ")))
 974   (let ((grouped-query (if (string-match-p notmuch-search-disjunctive-regexp query)
 975                            (concat "( " query " )")
 976                          query)))
 977     (notmuch-search (if (string= notmuch-search-query-string "*")
 978                         grouped-query
 979                       (concat notmuch-search-query-string " and " grouped-query)) notmuch-search-oldest-first)))
 980
 981 (defun notmuch-search-filter-by-tag (tag)
 982   "Filter the current search results based on a single tag.
 983
 984 Runs a new search matching only messages that match both the
 985 current search results AND that are tagged with the given tag."
 986   (interactive
 987    (list (notmuch-select-tag-with-completion "Filter by tag: ")))
 988   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
 989
 990 ;;;###autoload
 991 (defun notmuch ()
 992   "Run notmuch and display saved searches, known tags, etc."
 993   (interactive)
 994   (notmuch-hello))
 995
 996 (defun notmuch-interesting-buffer (b)
 997   "Is the current buffer of interest to a notmuch user?"
 998   (with-current-buffer b
 999     (memq major-mode '(notmuch-show-mode
1000                        notmuch-search-mode
1001                        notmuch-hello-mode
1002                        message-mode))))
1003
1004 ;;;###autoload
1005 (defun notmuch-cycle-notmuch-buffers ()
1006   "Cycle through any existing notmuch buffers (search, show or hello).
1007
1008 If the current buffer is the only notmuch buffer, bury it. If no
1009 notmuch buffers exist, run `notmuch'."
1010   (interactive)
1011
1012   (let (start first)
1013     ;; If the current buffer is a notmuch buffer, remember it and then
1014     ;; bury it.
1015     (when (notmuch-interesting-buffer (current-buffer))
1016       (setq start (current-buffer))
1017       (bury-buffer))
1018
1019     ;; Find the first notmuch buffer.
1020     (setq first (loop for buffer in (buffer-list)
1021                      if (notmuch-interesting-buffer buffer)
1022                      return buffer))
1023
1024     (if first
1025         ;; If the first one we found is any other than the starting
1026         ;; buffer, switch to it.
1027         (unless (eq first start)
1028           (switch-to-buffer first))
1029       (notmuch))))
1030
1031 (setq mail-user-agent 'notmuch-user-agent)
1032
1033 (provide 'notmuch)
1034
1035 ;; After provide to avoid loops if notmuch was require'd via notmuch-init-file.
1036 (if init-file-user ; don't load init file if the -q option was used.
1037     (let ((init-file (locate-file notmuch-init-file '("/")
1038                                   (get-load-suffixes))))
1039       (if init-file (load init-file nil t t))))