git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ; This is an emacs-based interface to the notmuch mail system.
  23 ;
  24 ; You will first need to have the notmuch program installed and have a
  25 ; notmuch database built in order to use this. See
  26 ; http://notmuchmail.org for details.
  27 ;
  28 ; To install this software, copy it to a directory that is on the
  29 ; `load-path' variable within emacs (a good candidate is
  30 ; /usr/local/share/emacs/site-lisp). If you are viewing this from the
  31 ; notmuch source distribution then you can simply run:
  32 ;
  33 ;       sudo make install-emacs
  34 ;
  35 ; to install it.
  36 ;
  37 ; Then, to actually run it, add:
  38 ;
  39 ;       (require 'notmuch)
  40 ;
  41 ; to your ~/.emacs file, and then run "M-x notmuch" from within emacs,
  42 ; or run:
  43 ;
  44 ;       emacs -f notmuch
  45 ;
  46 ; Have fun, and let us know if you have any comment, questions, or
  47 ; kudos: Notmuch list <notmuch@notmuchmail.org> (subscription is not
  48 ; required, but is available from http://notmuchmail.org).
  49
  50 (require 'cl)
  51 (require 'mm-view)
  52
  53 (defvar notmuch-show-mode-map
  54   (let ((map (make-sparse-keymap)))
  55     ; I don't actually want all of these toggle commands occupying
  56     ; keybindings. They steal valuable key-binding space, are hard
  57     ; to remember, and act globally rather than locally.
  58     ;
  59     ; Will be much preferable to switch to direct manipulation for
  60     ; toggling visibility of these components. Probably using
  61     ; overlays-at to query and manipulate the current overlay.
  62     (define-key map "a" 'notmuch-show-archive-thread)
  63     (define-key map "A" 'notmuch-show-mark-read-then-archive-thread)
  64     (define-key map "b" 'notmuch-show-toggle-body-read-visible)
  65     (define-key map "c" 'notmuch-show-toggle-citations-visible)
  66     (define-key map "h" 'notmuch-show-toggle-headers-visible)
  67     (define-key map "m" 'message-mail)
  68     (define-key map "n" 'notmuch-show-next-message)
  69     (define-key map "N" 'notmuch-show-mark-read-then-next-open-message)
  70     (define-key map "p" 'notmuch-show-previous-message)
  71     (define-key map (kbd "C-n") 'notmuch-show-next-line)
  72     (define-key map (kbd "C-p") 'notmuch-show-previous-line)
  73     (define-key map "q" 'kill-this-buffer)
  74     (define-key map "r" 'notmuch-show-reply)
  75     (define-key map "s" 'notmuch-show-toggle-signatures-visible)
  76     (define-key map "v" 'notmuch-show-view-all-mime-parts)
  77     (define-key map "w" 'notmuch-show-view-raw-message)
  78     (define-key map "x" 'kill-this-buffer)
  79     (define-key map "+" 'notmuch-show-add-tag)
  80     (define-key map "-" 'notmuch-show-remove-tag)
  81     (define-key map (kbd "DEL") 'notmuch-show-rewind)
  82     (define-key map " " 'notmuch-show-advance-marking-read-and-archiving)
  83     (define-key map "|" 'notmuch-show-pipe-message)
  84     (define-key map "?" 'describe-mode)
  85     map)
  86   "Keymap for \"notmuch show\" buffers.")
  87 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  88
  89 (defvar notmuch-show-signature-regexp "\\(-- ?\\|_+\\)$"
  90   "Pattern to match a line that separates content from signature.
  91
  92 The regexp can (and should) include $ to match the end of the
  93 line, but should not include ^ to match the beginning of the
  94 line. This is because notmuch may have inserted additional space
  95 for indentation at the beginning of the line. But notmuch will
  96 move past the indentation when testing this pattern, (so that the
  97 pattern can still test against the entire line).")
  98
  99 (defvar notmuch-show-signature-lines-max 12
 100   "Maximum length of signature that will be hidden by default.")
 101
 102 (defvar notmuch-command "notmuch"
 103   "Command to run the notmuch binary.")
 104
 105 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
 106 (defvar notmuch-show-message-end-regexp      "\fmessage}")
 107 (defvar notmuch-show-header-begin-regexp     "\fheader{")
 108 (defvar notmuch-show-header-end-regexp       "\fheader}")
 109 (defvar notmuch-show-body-begin-regexp       "\fbody{")
 110 (defvar notmuch-show-body-end-regexp         "\fbody}")
 111 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
 112 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
 113 (defvar notmuch-show-part-begin-regexp       "\fpart{")
 114 (defvar notmuch-show-part-end-regexp         "\fpart}")
 115 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
 116
 117 (defvar notmuch-show-id-regexp "\\(id:[^ ]*\\)")
 118 (defvar notmuch-show-depth-regexp " depth:\\([0-9]*\\) ")
 119 (defvar notmuch-show-filename-regexp "filename:\\(.*\\)$")
 120 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
 121
 122 (defvar notmuch-show-parent-buffer nil)
 123 (defvar notmuch-show-body-read-visible nil)
 124 (defvar notmuch-show-citations-visible nil)
 125 (defvar notmuch-show-signatures-visible nil)
 126 (defvar notmuch-show-headers-visible nil)
 127
 128 ; XXX: This should be a generic function in emacs somewhere, not here
 129 (defun point-invisible-p ()
 130   "Return whether the character at point is invisible.
 131
 132 Here visibility is determined by `buffer-invisibility-spec' and
 133 the invisible property of any overlays for point. It doesn't have
 134 anything to do with whether point is currently being displayed
 135 within the current window."
 136   (let ((prop (get-char-property (point) 'invisible)))
 137     (if (eq buffer-invisibility-spec t)
 138         prop
 139       (or (memq prop buffer-invisibility-spec)
 140           (assq prop buffer-invisibility-spec)))))
 141
 142 (defun notmuch-show-next-line ()
 143   "Like builtin `next-line' but ensuring we end on a visible character.
 144
 145 By advancing forward until reaching a visible character.
 146
 147 Unlike builtin `next-line' this version accepts no arguments."
 148   (interactive)
 149   (set 'this-command 'next-line)
 150   (call-interactively 'next-line)
 151   (while (point-invisible-p)
 152     (forward-char)))
 153
 154 (defun notmuch-show-previous-line ()
 155   "Like builtin `previous-line' but ensuring we end on a visible character.
 156
 157 By advancing forward until reaching a visible character.
 158
 159 Unlike builtin `next-line' this version accepts no arguments."
 160   (interactive)
 161   (set 'this-command 'previous-line)
 162   (call-interactively 'previous-line)
 163   (while (point-invisible-p)
 164     (forward-char)))
 165
 166 (defun notmuch-show-get-message-id ()
 167   (save-excursion
 168     (beginning-of-line)
 169     (if (not (looking-at notmuch-show-message-begin-regexp))
 170         (re-search-backward notmuch-show-message-begin-regexp))
 171     (re-search-forward notmuch-show-id-regexp)
 172     (buffer-substring (match-beginning 1) (match-end 1))))
 173
 174 (defun notmuch-show-get-filename ()
 175   (save-excursion
 176     (beginning-of-line)
 177     (if (not (looking-at notmuch-show-message-begin-regexp))
 178         (re-search-backward notmuch-show-message-begin-regexp))
 179     (re-search-forward notmuch-show-filename-regexp)
 180     (buffer-substring (match-beginning 1) (match-end 1))))
 181
 182 (defun notmuch-show-set-tags (tags)
 183   (save-excursion
 184     (beginning-of-line)
 185     (if (not (looking-at notmuch-show-message-begin-regexp))
 186         (re-search-backward notmuch-show-message-begin-regexp))
 187     (re-search-forward notmuch-show-tags-regexp)
 188     (let ((inhibit-read-only t)
 189           (beg (match-beginning 1))
 190           (end (match-end 1)))
 191       (delete-region beg end)
 192       (goto-char beg)
 193       (insert (mapconcat 'identity tags " ")))))
 194
 195 (defun notmuch-show-get-tags ()
 196   (save-excursion
 197     (beginning-of-line)
 198     (if (not (looking-at notmuch-show-message-begin-regexp))
 199         (re-search-backward notmuch-show-message-begin-regexp))
 200     (re-search-forward notmuch-show-tags-regexp)
 201     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
 202
 203 (defun notmuch-show-add-tag (&rest toadd)
 204   "Add a tag to the current message."
 205   (interactive "sTag to add: ")
 206   (apply 'notmuch-call-notmuch-process
 207          (append (cons "tag"
 208                        (mapcar (lambda (s) (concat "+" s)) toadd))
 209                  (cons (notmuch-show-get-message-id) nil)))
 210   (notmuch-show-set-tags (sort (union toadd (notmuch-show-get-tags) :test 'string=) 'string<)))
 211
 212 (defun notmuch-show-remove-tag (&rest toremove)
 213   "Remove a tag from the current message."
 214   (interactive "sTag to remove: ")
 215   (let ((tags (notmuch-show-get-tags)))
 216     (if (intersection tags toremove :test 'string=)
 217         (progn
 218           (apply 'notmuch-call-notmuch-process
 219                  (append (cons "tag"
 220                                (mapcar (lambda (s) (concat "-" s)) toremove))
 221                          (cons (notmuch-show-get-message-id) nil)))
 222           (notmuch-show-set-tags (sort (set-difference tags toremove :test 'string=) 'string<))))))
 223
 224 (defun notmuch-show-archive-thread-maybe-mark-read (markread)
 225   (save-excursion
 226     (goto-char (point-min))
 227     (while (not (eobp))
 228       (if markread
 229           (notmuch-show-remove-tag "unread" "inbox")
 230         (notmuch-show-remove-tag "inbox"))
 231       (if (not (eobp))
 232           (forward-char))
 233       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 234           (goto-char (point-max)))))
 235   (let ((parent-buffer notmuch-show-parent-buffer))
 236     (kill-this-buffer)
 237     (if parent-buffer
 238         (progn
 239           (switch-to-buffer parent-buffer)
 240           (forward-line)
 241           (notmuch-search-show-thread)))))
 242
 243 (defun notmuch-show-mark-read-then-archive-thread ()
 244   "Remove \"unread\" tag from each message, then archive and show next thread.
 245
 246 Archive each message currently shown by removing the \"unread\"
 247 and \"inbox\" tag from each. Then kill this buffer and show the
 248 next thread from the search from which this thread was originally
 249 shown.
 250
 251 Note: This command is safe from any race condition of new messages
 252 being delivered to the same thread. It does not archive the
 253 entire thread, but only the messages shown in the current
 254 buffer."
 255   (interactive)
 256   (notmuch-show-archive-thread-maybe-mark-read t))
 257
 258 (defun notmuch-show-archive-thread ()
 259   "Archive each message in thread, and show next thread from search.
 260
 261 Archive each message currently shown by removing the \"inbox\"
 262 tag from each. Then kill this buffer and show the next thread
 263 from the search from which this thread was originally shown.
 264
 265 Note: This command is safe from any race condition of new messages
 266 being delivered to the same thread. It does not archive the
 267 entire thread, but only the messages shown in the current
 268 buffer."
 269   (interactive)
 270   (notmuch-show-archive-thread-maybe-mark-read nil))
 271
 272 (defun notmuch-show-view-raw-message ()
 273   "View the raw email of the current message."
 274   (interactive)
 275   (view-file (notmuch-show-get-filename)))
 276
 277 (defun notmuch-show-view-all-mime-parts ()
 278   "Use external viewers (according to mailcap) to view all MIME-encoded parts."
 279   (interactive)
 280   (save-excursion
 281     (let ((filename (notmuch-show-get-filename)))
 282       (switch-to-buffer (generate-new-buffer (concat "*notmuch-mime-"
 283                                                      filename
 284                                                      "*")))
 285       (insert-file-contents filename nil nil nil t)
 286       (mm-display-parts (mm-dissect-buffer))
 287       (kill-this-buffer))))
 288
 289 (defun notmuch-reply (query-string)
 290   (switch-to-buffer (generate-new-buffer "notmuch-draft"))
 291   (call-process notmuch-command nil t nil "reply" query-string)
 292   (goto-char (point-min))
 293   (if (re-search-forward "^$" nil t)
 294       (progn
 295         (insert "--text follows this line--")
 296         (forward-line)))
 297   (message-mode))
 298
 299 (defun notmuch-show-reply ()
 300   "Begin composing a reply to the current message in a new buffer."
 301   (interactive)
 302   (let ((message-id (notmuch-show-get-message-id)))
 303     (notmuch-reply message-id)))
 304
 305 (defun notmuch-show-pipe-message (command)
 306   "Pipe the contents of the current message to the given command.
 307
 308 The given command will be executed with the raw contents of the
 309 current email message as stdin. Anything printed by the command
 310 to stdout or stderr will appear in the *Messages* buffer."
 311   (interactive "sPipe message to command: ")
 312   (apply 'start-process-shell-command "notmuch-pipe-command" "*notmuch-pipe*" (split-string (concat command " < " (notmuch-show-get-filename)))))
 313
 314 (defun notmuch-show-move-to-current-message-summary-line ()
 315   "Move to the beginning of the one-line summary of the current message.
 316
 317 This gives us a stable place to move to and work from since the
 318 summary line is always visible. This is important since moving to
 319 an invisible location is unreliable, (the main command loop moves
 320 point either forward or backward to the next visible character
 321 when a command ends with point on an invisible character).
 322
 323 Emits an error if point is not within a valid message, (that is
 324 not pattern of `notmuch-show-message-begin-regexp' could be found
 325 by searching backward)."
 326   (beginning-of-line)
 327   (if (not (looking-at notmuch-show-message-begin-regexp))
 328       (if (re-search-backward notmuch-show-message-begin-regexp nil t)
 329           (forward-line 2)
 330         (error "Not within a valid message."))
 331     (forward-line 2)))
 332
 333 (defun notmuch-show-last-message-p ()
 334   "Predicate testing whether point is within the last message."
 335   (save-window-excursion
 336     (save-excursion
 337       (notmuch-show-move-to-current-message-summary-line)
 338       (not (re-search-forward notmuch-show-message-begin-regexp nil t)))))
 339
 340 (defun notmuch-show-message-unread-p ()
 341   "Preficate testing whether current message is unread."
 342   (member "unread" (notmuch-show-get-tags)))
 343
 344 (defun notmuch-show-next-message ()
 345   "Advance to the beginning of the next message in the buffer.
 346
 347 Moves to the last visible character of the current message if
 348 already on the last message in the buffer."
 349   (interactive)
 350   (notmuch-show-move-to-current-message-summary-line)
 351   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 352       (notmuch-show-move-to-current-message-summary-line)
 353     (goto-char (- (point-max) 1))
 354     (while (point-invisible-p)
 355       (backward-char)))
 356   (recenter 0))
 357
 358 (defun notmuch-show-find-next-message ()
 359   "Returns the position of the next message in the buffer.
 360
 361 Or the position of the last visible character of the current
 362 message if already within the last message in the buffer."
 363   ; save-excursion doesn't save our window position
 364   ; save-window-excursion doesn't save point
 365   ; Looks like we have to use both.
 366   (save-excursion
 367     (save-window-excursion
 368       (notmuch-show-next-message)
 369       (point))))
 370
 371 (defun notmuch-show-next-unread-message ()
 372   "Advance to the beginning of the next unread message in the buffer.
 373
 374 Moves to the last visible character of the current message if
 375 there are no more unread messages past the current point."
 376   (notmuch-show-next-message)
 377   (while (and (not (notmuch-show-last-message-p))
 378               (not (notmuch-show-message-unread-p)))
 379     (notmuch-show-next-message))
 380   (if (not (notmuch-show-message-unread-p))
 381       (notmuch-show-next-message)))
 382
 383 (defun notmuch-show-next-open-message ()
 384   "Advance to the next message which is not hidden.
 385
 386 If read messages are currently hidden, advance to the next unread
 387 message. Otherwise, advance to the next message."
 388   (if (or (memq 'notmuch-show-body-read buffer-invisibility-spec)
 389           (assq 'notmuch-show-body-read buffer-invisibility-spec))
 390       (notmuch-show-next-unread-message)
 391     (notmuch-show-next-message)))
 392
 393 (defun notmuch-show-previous-message ()
 394   "Backup to the beginning of the previous message in the buffer.
 395
 396 If within a message rather than at the beginning of it, then
 397 simply move to the beginning of the current message."
 398   (interactive)
 399   (let ((start (point)))
 400     (notmuch-show-move-to-current-message-summary-line)
 401     (if (not (< (point) start))
 402         ; Go backward twice to skip the current message's marker
 403         (progn
 404           (re-search-backward notmuch-show-message-begin-regexp nil t)
 405           (re-search-backward notmuch-show-message-begin-regexp nil t)
 406           (notmuch-show-move-to-current-message-summary-line)
 407           ))
 408     (recenter 0)))
 409
 410 (defun notmuch-show-find-previous-message ()
 411   "Returns the position of the previous message in the buffer.
 412
 413 Or the position of the beginning of the current message if point
 414 is originally within the message rather than at the beginning of
 415 it."
 416   ; save-excursion doesn't save our window position
 417   ; save-window-excursion doesn't save point
 418   ; Looks like we have to use both.
 419   (save-excursion
 420     (save-window-excursion
 421       (notmuch-show-previous-message)
 422       (point))))
 423
 424 (defun notmuch-show-mark-read-then-next-open-message ()
 425   "Remove unread tag from current message, then advance to next unread message."
 426   (interactive)
 427   (notmuch-show-remove-tag "unread")
 428   (notmuch-show-next-open-message))
 429
 430 (defun notmuch-show-rewind ()
 431   "Do reverse scrolling compared to `notmuch-show-advance-marking-read-and-archiving'
 432
 433 Specifically, if the beginning of the previous email is fewer
 434 than `window-height' lines from the current point, move to it
 435 just like `notmuch-show-previous-message'.
 436
 437 Otherwise, just scroll down a screenful of the current message.
 438
 439 This command does not modify any message tags, (it does not undo
 440 any effects from previous calls to
 441 `notmuch-show-advance-marking-read-and-archiving'."
 442   (interactive)
 443   (let ((previous (notmuch-show-find-previous-message)))
 444     (if (> (count-lines previous (point)) (- (window-height) next-screen-context-lines))
 445         (progn
 446           (condition-case nil
 447               (scroll-down nil)
 448             ((beginning-of-buffer) nil))
 449           (goto-char (window-start)))
 450       (notmuch-show-previous-message))))
 451
 452 (defun notmuch-show-advance-marking-read-and-archiving ()
 453   "Advance through buffer, marking read and archiving.
 454
 455 This command is intended to be one of the simplest ways to
 456 process a thread of email. It does the following:
 457
 458 If the current message in the thread is not yet fully visible,
 459 scroll by a near screenful to read more of the message.
 460
 461 Otherwise, (the end of the current message is already within the
 462 current window), remove the \"unread\" tag (if present) from the
 463 current message and advance to the next open message.
 464
 465 Finally, if there is no further message to advance to, and this
 466 last message is already read, then archive the entire current
 467 thread, (remove the \"inbox\" tag from each message). Also kill
 468 this buffer, and display the next thread from the search from
 469 which this thread was originally shown."
 470   (interactive)
 471   (let ((next (notmuch-show-find-next-message))
 472         (unread (notmuch-show-message-unread-p)))
 473     (if (> next (window-end))
 474         (scroll-up nil)
 475       (let ((last (notmuch-show-last-message-p)))
 476         (notmuch-show-mark-read-then-next-open-message)
 477         (if last
 478             (notmuch-show-archive-thread))))))
 479
 480 (defun notmuch-show-markup-citations-region (beg end depth)
 481   (goto-char beg)
 482   (beginning-of-line)
 483   (while (< (point) end)
 484     (let ((beg-sub (point-marker))
 485           (indent (make-string depth ? ))
 486           (citation "[[:space:]]*>"))
 487       (if (looking-at citation)
 488           (progn
 489             (while (looking-at citation)
 490               (forward-line))
 491             (let ((overlay (make-overlay beg-sub (point))))
 492               (overlay-put overlay 'invisible 'notmuch-show-citation)
 493               (overlay-put overlay 'before-string
 494                            (concat indent
 495                                    "[" (number-to-string (count-lines beg-sub (point)))
 496                                    "-line citation. Press 'c' to show.]\n")))))
 497       (move-to-column depth)
 498       (if (looking-at notmuch-show-signature-regexp)
 499           (let ((sig-lines (- (count-lines beg-sub end) 1)))
 500             (if (<= sig-lines notmuch-show-signature-lines-max)
 501                 (progn
 502                   (overlay-put (make-overlay beg-sub end)
 503                                'invisible 'notmuch-show-signature)
 504                   (overlay-put (make-overlay beg (- beg-sub 1))
 505                                'after-string
 506                                (concat "\n" indent
 507                                        "[" (number-to-string sig-lines)
 508                                        "-line signature. Press 's' to show.]"))
 509                   (goto-char end)))))
 510       (forward-line))))
 511
 512 (defun notmuch-show-markup-part (beg end depth)
 513   (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 514       (progn
 515         (forward-line)
 516         (let ((beg (point-marker)))
 517           (re-search-forward notmuch-show-part-end-regexp)
 518           (let ((end (copy-marker (match-beginning 0))))
 519             (goto-char end)
 520             (if (not (bolp))
 521                 (insert "\n"))
 522             (indent-rigidly beg end depth)
 523             (notmuch-show-markup-citations-region beg end depth)
 524             ; Advance to the next part (if any) (so the outer loop can
 525             ; determine whether we've left the current message.
 526             (if (re-search-forward notmuch-show-part-begin-regexp nil t)
 527                 (beginning-of-line)))))
 528     (goto-char end)))
 529
 530 (defun notmuch-show-markup-parts-region (beg end depth)
 531   (save-excursion
 532     (goto-char beg)
 533     (while (< (point) end)
 534       (notmuch-show-markup-part beg end depth))))
 535
 536 (defun notmuch-show-markup-body (depth)
 537   (re-search-forward notmuch-show-body-begin-regexp)
 538   (forward-line)
 539   (let ((beg (point-marker)))
 540     (re-search-forward notmuch-show-body-end-regexp)
 541     (let ((end (copy-marker (match-beginning 0))))
 542       (notmuch-show-markup-parts-region beg end depth)
 543       (if (not (notmuch-show-message-unread-p))
 544           (overlay-put (make-overlay beg end)
 545                        'invisible 'notmuch-show-body-read))
 546       (set-marker beg nil)
 547       (set-marker end nil)
 548       )))
 549
 550 (defun notmuch-show-markup-header (depth)
 551   (re-search-forward notmuch-show-header-begin-regexp)
 552   (forward-line)
 553   (let ((beg (point-marker)))
 554     (end-of-line)
 555     ; Inverse video for subject
 556     (overlay-put (make-overlay beg (point)) 'face '((cons :inverse-video t)))
 557     (forward-line 2)
 558     (let ((beg-hidden (point-marker)))
 559       (re-search-forward notmuch-show-header-end-regexp)
 560       (beginning-of-line)
 561       (let ((end (point-marker)))
 562         (indent-rigidly beg end depth)
 563         (overlay-put (make-overlay beg-hidden end)
 564                      'invisible 'notmuch-show-header)
 565         (set-marker beg nil)
 566         (set-marker beg-hidden nil)
 567         (set-marker end nil)
 568         ))))
 569
 570 (defun notmuch-show-markup-message ()
 571   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 572       (progn
 573         (re-search-forward notmuch-show-depth-regexp)
 574         (let ((depth (string-to-number (buffer-substring (match-beginning 1) (match-end 1)))))
 575           (notmuch-show-markup-header depth)
 576           (notmuch-show-markup-body depth)))
 577     (goto-char (point-max))))
 578
 579 (defun notmuch-show-hide-markers ()
 580   (save-excursion
 581     (goto-char (point-min))
 582     (while (not (eobp))
 583       (if (re-search-forward notmuch-show-marker-regexp nil t)
 584           (progn
 585             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 586                          'invisible 'notmuch-show-marker))
 587         (goto-char (point-max))))))
 588
 589 (defun notmuch-show-markup-messages ()
 590   (save-excursion
 591     (goto-char (point-min))
 592     (while (not (eobp))
 593       (notmuch-show-markup-message)))
 594   (notmuch-show-hide-markers))
 595
 596 (defun notmuch-show-toggle-citations-visible ()
 597   "Toggle visibility of citations"
 598   (interactive)
 599   (if notmuch-show-citations-visible
 600       (add-to-invisibility-spec 'notmuch-show-citation)
 601     (remove-from-invisibility-spec 'notmuch-show-citation))
 602   (set 'notmuch-show-citations-visible (not notmuch-show-citations-visible))
 603   ; Need to force the redisplay for some reason
 604   (force-window-update)
 605   (redisplay t))
 606
 607 (defun notmuch-show-toggle-signatures-visible ()
 608   "Toggle visibility of signatures"
 609   (interactive)
 610   (if notmuch-show-signatures-visible
 611       (add-to-invisibility-spec 'notmuch-show-signature)
 612     (remove-from-invisibility-spec 'notmuch-show-signature))
 613   (set 'notmuch-show-signatures-visible (not notmuch-show-signatures-visible))
 614   ; Need to force the redisplay for some reason
 615   (force-window-update)
 616   (redisplay t))
 617
 618 (defun notmuch-show-toggle-headers-visible ()
 619   "Toggle visibility of header fields"
 620   (interactive)
 621   (if notmuch-show-headers-visible
 622       (add-to-invisibility-spec 'notmuch-show-header)
 623     (remove-from-invisibility-spec 'notmuch-show-header))
 624   (set 'notmuch-show-headers-visible (not notmuch-show-headers-visible))
 625   ; Need to force the redisplay for some reason
 626   (force-window-update)
 627   (redisplay t))
 628
 629 (defun notmuch-show-toggle-body-read-visible ()
 630   "Toggle visibility of message bodies of read messages"
 631   (interactive)
 632   (if notmuch-show-body-read-visible
 633       (add-to-invisibility-spec 'notmuch-show-body-read)
 634     (remove-from-invisibility-spec 'notmuch-show-body-read))
 635   (set 'notmuch-show-body-read-visible (not notmuch-show-body-read-visible))
 636   ; Need to force the redisplay for some reason
 637   (force-window-update)
 638   (redisplay t))
 639
 640 ;;;###autoload
 641 (defun notmuch-show-mode ()
 642   "Major mode for viewing a thread with notmuch.
 643
 644 This buffer contains the results of the \"notmuch show\" command
 645 for displaying a single thread of email from your email archives.
 646
 647 By default, various components of email messages, (citations,
 648 signatures, already-read messages), are invisible to help you
 649 focus on the most important things, (new text from unread
 650 messages). See the various commands below for toggling the
 651 visibility of hidden components.
 652
 653 The `notmuch-show-next-message' and
 654 `notmuch-show-previous-message' commands, (bound to 'n' and 'p by
 655 default), allow you to navigate to the next and previous
 656 messages. Each time you navigate away from a message with
 657 `notmuch-show-next-message' the current message will have its
 658 \"unread\" tag removed.
 659
 660 You can add or remove tags from the current message with '+' and
 661 '-'.  You can also archive all messages in the current
 662 view, (remove the \"inbox\" tag from each), with
 663 `notmuch-show-archive-thread' (bound to 'a' by default).
 664
 665 \\{notmuch-show-mode-map}"
 666   (interactive)
 667   (kill-all-local-variables)
 668   (set (make-local-variable 'notmuch-show-headers-visible) t)
 669   (notmuch-show-toggle-headers-visible)
 670   (set (make-local-variable 'notmuch-show-body-read-visible) t)
 671   (notmuch-show-toggle-body-read-visible)
 672   (set (make-local-variable 'notmuch-show-citations-visible) t)
 673   (notmuch-show-toggle-citations-visible)
 674   (set (make-local-variable 'notmuch-show-signatures-visible) t)
 675   (notmuch-show-toggle-signatures-visible)
 676   (add-to-invisibility-spec 'notmuch-show-marker)
 677   (use-local-map notmuch-show-mode-map)
 678   (setq major-mode 'notmuch-show-mode
 679         mode-name "notmuch-show")
 680   (setq buffer-read-only t))
 681
 682 ;;;###autoload
 683
 684 (defgroup notmuch nil
 685   "Notmuch mail reader for Emacs."
 686   :group 'mail)
 687
 688 (defcustom notmuch-show-hook nil
 689   "List of functions to call when notmuch displays a message."
 690   :type 'hook
 691   :options '(goto-address)
 692   :group 'notmuch)
 693
 694 (defcustom notmuch-search-hook nil
 695   "List of functions to call when notmuch displays the search results."
 696   :type 'hook
 697   :options '(hl-line-mode)
 698   :group 'notmuch)
 699
 700 ; Make show mode a bit prettier, highlighting URLs and using word wrap
 701
 702 (defun notmuch-show-pretty-hook ()
 703   (goto-address-mode 1)
 704   (visual-line-mode))
 705
 706 (add-hook 'notmuch-show-hook 'notmuch-show-pretty-hook)
 707 (add-hook 'notmuch-search-hook
 708           (lambda()
 709             (hl-line-mode 1) ))
 710
 711 (defun notmuch-show (thread-id &optional parent-buffer)
 712   "Run \"notmuch show\" with the given thread ID and display results.
 713
 714 The optional PARENT-BUFFER is the notmuch-search buffer from
 715 which this notmuch-show command was executed, (so that the next
 716 thread from that buffer can be show when done with this one)."
 717   (interactive "sNotmuch show: ")
 718   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 719     (switch-to-buffer buffer)
 720     (notmuch-show-mode)
 721     (set (make-local-variable 'notmuch-show-parent-buffer) parent-buffer)
 722     (let ((proc (get-buffer-process (current-buffer)))
 723           (inhibit-read-only t))
 724       (if proc
 725           (error "notmuch search process already running for query `%s'" thread-id)
 726         )
 727       (erase-buffer)
 728       (goto-char (point-min))
 729       (save-excursion
 730         (call-process notmuch-command nil t nil "show" thread-id)
 731         (notmuch-show-markup-messages)
 732         )
 733       (run-hooks 'notmuch-show-hook)
 734       ; Move straight to the first unread message
 735       (if (not (notmuch-show-message-unread-p))
 736           (progn
 737             (notmuch-show-next-unread-message)
 738             ; But if there are no unread messages, go back to the
 739             ; beginning of the buffer, and open up the bodies of all
 740             ; read message.
 741             (if (not (notmuch-show-message-unread-p))
 742                 (progn
 743                   (goto-char (point-min))
 744                   (notmuch-show-toggle-body-read-visible)))))
 745       )))
 746
 747 (defvar notmuch-search-authors-width 40
 748   "Number of columns to use to display authors in a notmuch-search buffer.")
 749
 750 (defvar notmuch-search-mode-map
 751   (let ((map (make-sparse-keymap)))
 752     (define-key map "a" 'notmuch-search-archive-thread)
 753     (define-key map "b" 'notmuch-search-scroll-down)
 754     (define-key map "f" 'notmuch-search-filter)
 755     (define-key map "m" 'message-mail)
 756     (define-key map "n" 'next-line)
 757     (define-key map "o" 'notmuch-search-toggle-order)
 758     (define-key map "p" 'previous-line)
 759     (define-key map "q" 'kill-this-buffer)
 760     (define-key map "r" 'notmuch-search-reply-to-thread)
 761     (define-key map "s" 'notmuch-search)
 762     (define-key map "t" 'notmuch-search-filter-by-tag)
 763     (define-key map "x" 'kill-this-buffer)
 764     (define-key map (kbd "RET") 'notmuch-search-show-thread)
 765     (define-key map "+" 'notmuch-search-add-tag)
 766     (define-key map "-" 'notmuch-search-remove-tag)
 767     (define-key map "<" 'beginning-of-buffer)
 768     (define-key map ">" 'notmuch-search-goto-last-thread)
 769     (define-key map "=" 'notmuch-search-refresh-view)
 770     (define-key map "\M->" 'notmuch-search-goto-last-thread)
 771     (define-key map " " 'notmuch-search-scroll-up)
 772     (define-key map (kbd "<DEL>") 'notmuch-search-scroll-down)
 773     (define-key map "?" 'describe-mode)
 774     map)
 775   "Keymap for \"notmuch search\" buffers.")
 776 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 777
 778 (defvar notmuch-search-query-string)
 779 (defvar notmuch-search-oldest-first)
 780
 781 (defun notmuch-search-scroll-up ()
 782   "Scroll up, moving point to last message in thread if at end."
 783   (interactive)
 784   (condition-case nil
 785       (scroll-up nil)
 786     ((end-of-buffer) (notmuch-search-goto-last-thread))))
 787
 788 (defun notmuch-search-scroll-down ()
 789   "Scroll down, moving point to first message in thread if at beginning."
 790   (interactive)
 791   ; I don't know why scroll-down doesn't signal beginning-of-buffer
 792   ; the way that scroll-up signals end-of-buffer, but c'est la vie.
 793   ;
 794   ; So instead of trapping a signal we instead check whether the
 795   ; window begins on the first line of the buffer and if so, move
 796   ; directly to that position. (We have to count lines since the
 797   ; window-start position is not the same as point-min due to the
 798   ; invisible thread-ID characters on the first line.
 799   (if (equal (count-lines (point-min) (window-start)) 1)
 800       (goto-char (window-start))
 801     (scroll-down nil)))
 802
 803 (defun notmuch-search-goto-last-thread ()
 804   "Move point to the last thread in the buffer."
 805   (interactive)
 806   (goto-char (point-max))
 807   (forward-line -1))
 808
 809 ;;;###autoload
 810 (defun notmuch-search-mode ()
 811   "Major mode for searching mail with notmuch.
 812
 813 This buffer contains the results of a \"notmuch search\" of your
 814 email archives. Each line in the buffer represents a single
 815 thread giving a relative date for the thread and a subject.
 816
 817 Pressing RET on any line displays that thread. The '+' and '-'
 818 keys can be used to add or remove tags from a thread. The 'a' key
 819 is a convenience key for archiving a thread (removing the
 820 \"inbox\" tag).
 821
 822 Other useful commands are `notmuch-search-filter' for filtering
 823 the current search based on an additional query string,
 824 `notmuch-search-filter-by-tag' for filtering to include only
 825 messages with a given tag, and `notmuch-search' to execute a new,
 826 global search.
 827
 828 \\{notmuch-search-mode-map}"
 829   (interactive)
 830   (kill-all-local-variables)
 831   (make-local-variable 'notmuch-search-query-string)
 832   (make-local-variable 'notmuch-search-oldest-first)
 833   (set (make-local-variable 'scroll-preserve-screen-position) t)
 834   (add-to-invisibility-spec 'notmuch-search)
 835   (use-local-map notmuch-search-mode-map)
 836   (setq truncate-lines t)
 837   (setq major-mode 'notmuch-search-mode
 838         mode-name "notmuch-search")
 839   (setq buffer-read-only t))
 840
 841 (defun notmuch-search-find-thread-id ()
 842   (save-excursion
 843     (beginning-of-line)
 844     (let ((beg (point)))
 845       (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 846       (filter-buffer-substring beg (point)))))
 847
 848 (defun notmuch-search-markup-this-thread-id ()
 849   (beginning-of-line)
 850   (let ((beg (point)))
 851     (if (re-search-forward "thread:[a-fA-F0-9]*" nil t)
 852         (progn
 853           (forward-char)
 854           (overlay-put (make-overlay beg (point)) 'invisible 'notmuch-search)
 855           (re-search-forward ".*\\[[0-9]*/[0-9]*\\] \\([^;]*\\)\\(;\\)")
 856           (let* ((authors (buffer-substring (match-beginning 1) (match-end 1)))
 857                  (authors-length (length authors)))
 858             ;; Drop the semi-colon
 859             (replace-match "" t nil nil 2)
 860             (if (<= authors-length notmuch-search-authors-width)
 861                 (replace-match (concat authors (make-string
 862                                                 (- notmuch-search-authors-width
 863                                                    authors-length) ? )) t t nil 1)
 864               (replace-match (concat (substring authors 0 (- notmuch-search-authors-width 3)) "...") t t nil 1)))))))
 865
 866 (defun notmuch-search-markup-thread-ids ()
 867   (save-excursion
 868     (goto-char (point-min))
 869     (while (not (eobp))
 870       (notmuch-search-markup-this-thread-id)
 871       (forward-line))))
 872
 873 (defun notmuch-search-show-thread ()
 874   (interactive)
 875   (let ((thread-id (notmuch-search-find-thread-id)))
 876     (if (> (length thread-id) 0)
 877         (notmuch-show thread-id (current-buffer))
 878       (error "End of search results"))))
 879
 880 (defun notmuch-search-reply-to-thread ()
 881   "Begin composing a reply to the entire current thread in a new buffer."
 882   (interactive)
 883   (let ((message-id (notmuch-search-find-thread-id)))
 884     (notmuch-reply message-id)))
 885
 886 (defun notmuch-call-notmuch-process (&rest args)
 887   "Synchronously invoke \"notmuch\" with the given list of arguments.
 888
 889 Output from the process will be presented to the user as an error
 890 and will also appear in a buffer named \"*Notmuch errors*\"."
 891   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 892     (with-current-buffer error-buffer
 893         (erase-buffer))
 894     (if (eq (apply 'call-process notmuch-command nil error-buffer nil args) 0)
 895         (point)
 896       (progn
 897         (with-current-buffer error-buffer
 898           (let ((beg (point-min))
 899                 (end (- (point-max) 1)))
 900             (error (buffer-substring beg end))
 901             ))))))
 902
 903 (defun notmuch-search-set-tags (tags)
 904   (save-excursion
 905     (end-of-line)
 906     (re-search-backward "(")
 907     (forward-char)
 908     (let ((beg (point))
 909           (inhibit-read-only t))
 910       (re-search-forward ")")
 911       (backward-char)
 912       (let ((end (point)))
 913         (delete-region beg end)
 914         (insert (mapconcat  'identity tags " "))))))
 915
 916 (defun notmuch-search-get-tags ()
 917   (save-excursion
 918     (end-of-line)
 919     (re-search-backward "(")
 920     (let ((beg (+ (point) 1)))
 921       (re-search-forward ")")
 922       (let ((end (- (point) 1)))
 923         (split-string (buffer-substring beg end))))))
 924
 925 (defun notmuch-search-add-tag (tag)
 926   (interactive "sTag to add: ")
 927   (notmuch-call-notmuch-process "tag" (concat "+" tag) (notmuch-search-find-thread-id))
 928   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
 929
 930 (defun notmuch-search-remove-tag (tag)
 931   (interactive "sTag to remove: ")
 932   (notmuch-call-notmuch-process "tag" (concat "-" tag) (notmuch-search-find-thread-id))
 933   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
 934
 935 (defun notmuch-search-archive-thread ()
 936   "Archive the current thread (remove its \"inbox\" tag).
 937
 938 This function advances point to the next line when finished."
 939   (interactive)
 940   (notmuch-search-remove-tag "inbox")
 941   (forward-line))
 942
 943 (defun notmuch-search (query &optional oldest-first)
 944   "Run \"notmuch search\" with the given query string and display results."
 945   (interactive "sNotmuch search: ")
 946   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
 947     (switch-to-buffer buffer)
 948     (notmuch-search-mode)
 949     (set 'notmuch-search-query-string query)
 950     (set 'notmuch-search-oldest-first oldest-first)
 951     (let ((proc (get-buffer-process (current-buffer)))
 952           (inhibit-read-only t))
 953       (if proc
 954           (error "notmuch search process already running for query `%s'" query)
 955         )
 956       (erase-buffer)
 957       (goto-char (point-min))
 958       (save-excursion
 959         (if oldest-first
 960             (call-process notmuch-command nil t nil "search" "--sort=oldest-first" query)
 961           (call-process notmuch-command nil t nil "search" "--sort=newest-first" query))
 962         (notmuch-search-markup-thread-ids)
 963         ))
 964     (run-hooks 'notmuch-search-hook)))
 965
 966 (defun notmuch-search-refresh-view ()
 967   "Refresh the current view.
 968
 969 Kills the current buffer and runs a new search with the same
 970 query string as the current search. If the current thread is in
 971 the new search results, then point will be placed on the same
 972 thread. Otherwise, point will be moved to attempt to be in the
 973 same relative position within the new buffer."
 974   (interactive)
 975   (let ((here (point))
 976         (oldest-first notmuch-search-oldest-first)
 977         (thread (notmuch-search-find-thread-id))
 978         (query notmuch-search-query-string))
 979     (kill-this-buffer)
 980     (notmuch-search query oldest-first)
 981     (goto-char (point-min))
 982     (if (re-search-forward (concat "^" thread) nil t)
 983         (beginning-of-line)
 984       (goto-char here))))
 985
 986 (defun notmuch-search-toggle-order ()
 987   "Toggle the current search order.
 988
 989 By default, the \"inbox\" view created by `notmuch' is displayed
 990 in chronological order (oldest thread at the beginning of the
 991 buffer), while any global searches created by `notmuch-search'
 992 are displayed in reverse-chronological order (newest thread at
 993 the beginning of the buffer).
 994
 995 This command toggles the sort order for the current search.
 996
 997 Note that any filtered searches created by
 998 `notmuch-search-filter' retain the search order of the parent
 999 search."
1000   (interactive)
1001   (set 'notmuch-search-oldest-first (not notmuch-search-oldest-first))
1002   (notmuch-search-refresh-view))
1003
1004 (defun notmuch-search-filter (query)
1005   "Filter the current search results based on an additional query string.
1006
1007 Runs a new search matching only messages that match both the
1008 current search results AND the additional query string provided."
1009   (interactive "sFilter search: ")
1010   (notmuch-search (concat notmuch-search-query-string " and " query) notmuch-search-oldest-first))
1011
1012 (defun notmuch-search-filter-by-tag (tag)
1013   "Filter the current search results based on a single tag.
1014
1015 Runs a new search matching only messages that match both the
1016 current search results AND that are tagged with the given tag."
1017   (interactive "sFilter by tag: ")
1018   (notmuch-search (concat notmuch-search-query-string " and tag:" tag) notmuch-search-oldest-first))
1019
1020 (defun notmuch ()
1021   "Run notmuch to display all mail with tag of 'inbox'"
1022   (interactive)
1023   (notmuch-search "tag:inbox" t))
1024
1025 (setq mail-user-agent 'message-user-agent)
1026
1027 (provide 'notmuch)