git.notmuchmail.org Git - notmuch/blob - notmuch.el

   1 ; notmuch.el --- run notmuch within emacs
   2 ;
   3 ; Copyright © Carl Worth
   4 ;
   5 ; This file is part of Notmuch.
   6 ;
   7 ; Notmuch is free software: you can redistribute it and/or modify it
   8 ; under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 3 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; Notmuch is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ; General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;
  20 ; Authors: Carl Worth <cworth@cworth.org>
  21
  22 (defvar notmuch-show-mode-map
  23   (let ((map (make-sparse-keymap)))
  24     ; I don't actually want all of these toggle commands occupying
  25     ; keybindings. They steal valuable key-binding space, are hard
  26     ; to remember, and act globally rather than locally.
  27     ;
  28     ; Will be much preferable to switch to direct manipulation for
  29     ; toggling visibility of these components. Probably using
  30     ; overlays-at to query and manipulate the current overlay.
  31     (define-key map "a" 'notmuch-show-archive-thread)
  32     (define-key map "b" 'notmuch-show-toggle-body-read-visible)
  33     (define-key map "c" 'notmuch-show-toggle-citations-visible)
  34     (define-key map "h" 'notmuch-show-toggle-headers-visible)
  35     (define-key map "n" 'notmuch-show-mark-read-then-next-message)
  36     (define-key map "p" 'notmuch-show-previous-message)
  37     (define-key map "q" 'kill-this-buffer)
  38     (define-key map "s" 'notmuch-show-toggle-signatures-visible)
  39     (define-key map "x" 'kill-this-buffer)
  40     (define-key map "+" 'notmuch-show-add-tag)
  41     (define-key map "-" 'notmuch-show-remove-tag)
  42     map)
  43   "Keymap for \"notmuch show\" buffers.")
  44 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
  45
  46 (defvar notmuch-show-message-begin-regexp    "\fmessage{")
  47 (defvar notmuch-show-message-end-regexp      "\fmessage}")
  48 (defvar notmuch-show-header-begin-regexp     "\fheader{")
  49 (defvar notmuch-show-header-end-regexp       "\fheader}")
  50 (defvar notmuch-show-body-begin-regexp       "\fbody{")
  51 (defvar notmuch-show-body-end-regexp         "\fbody}")
  52 (defvar notmuch-show-attachment-begin-regexp "\fattachment{")
  53 (defvar notmuch-show-attachment-end-regexp   "\fattachment}")
  54 (defvar notmuch-show-part-begin-regexp       "\fpart{")
  55 (defvar notmuch-show-part-end-regexp         "\fpart}")
  56 (defvar notmuch-show-marker-regexp "\f\\(message\\|header\\|body\\|attachment\\|part\\)[{}].*$")
  57
  58 (defvar notmuch-show-id-regexp "ID: \\(.*\\)$")
  59 (defvar notmuch-show-tags-regexp "(\\([^)]*\\))$")
  60
  61 (defun notmuch-show-get-message-id ()
  62   (save-excursion
  63     (beginning-of-line)
  64     (if (not (looking-at notmuch-show-message-begin-regexp))
  65         (re-search-backward notmuch-show-message-begin-regexp))
  66     (re-search-forward notmuch-show-id-regexp)
  67     (buffer-substring (match-beginning 1) (match-end 1))))
  68
  69 (defun notmuch-show-set-tags (tags)
  70   (save-excursion
  71     (beginning-of-line)
  72     (if (not (looking-at notmuch-show-message-begin-regexp))
  73         (re-search-backward notmuch-show-message-begin-regexp))
  74     (re-search-forward notmuch-show-tags-regexp)
  75     (let ((inhibit-read-only t)
  76           (beg (match-beginning 1))
  77           (end (match-end 1)))
  78       (delete-region beg end)
  79       (goto-char beg)
  80       (insert (mapconcat 'identity tags " ")))))
  81
  82 (defun notmuch-show-get-tags ()
  83   (save-excursion
  84     (beginning-of-line)
  85     (if (not (looking-at notmuch-show-message-begin-regexp))
  86         (re-search-backward notmuch-show-message-begin-regexp))
  87     (re-search-forward notmuch-show-tags-regexp)
  88     (split-string (buffer-substring (match-beginning 1) (match-end 1)))))
  89
  90 (defun notmuch-show-add-tag (tag)
  91   (interactive "sTag to add: ")
  92   (notmuch-call-notmuch-process "tag" (concat "+" tag) (concat "id:" (notmuch-show-get-message-id)))
  93   (notmuch-show-set-tags (delete-dups (sort (cons tag (notmuch-show-get-tags)) 'string<))))
  94
  95 (defun notmuch-show-remove-tag (tag)
  96   (interactive "sTag to remove: ")
  97   (notmuch-call-notmuch-process "tag" (concat "-" tag) (concat "id:" (notmuch-show-get-message-id)))
  98   (notmuch-show-set-tags (delete tag (notmuch-show-get-tags))))
  99
 100 (defun notmuch-show-archive-thread ()
 101   "Archive each message currrently shown by removing the \"inbox\" tag from each.
 102
 103 This command is safe from any race condition of new messages
 104 being delivered to the same thread. It does not archive the
 105 entire thread, but only the messages shown in the current
 106 buffer."
 107   (interactive)
 108   (save-excursion
 109     (goto-char (point-min))
 110     (while (not (eobp))
 111       (notmuch-show-remove-tag "inbox")
 112       (if (not (eobp))
 113           (forward-char))
 114       (if (not (re-search-forward notmuch-show-message-begin-regexp nil t))
 115           (goto-char (point-max))))))
 116
 117 (defun notmuch-show-next-message ()
 118   "Advance point to the beginning of the next message in the buffer.
 119
 120 Does nothing if already on the last message."
 121   (interactive)
 122   ; First, ensure we get off the current message marker
 123   (if (not (eobp))
 124       (forward-char))
 125   (re-search-forward notmuch-show-message-begin-regexp nil t)
 126   ; This dance might look pointless, but it's important. I originally
 127   ; just had (beginning-of-line) here which looked right on the
 128   ; display but actually put point all the way back to the first
 129   ; character of the first invisible line. That is, it put point into
 130   ; the closing markers of the previous message rather than at the
 131   ; beginning of the current message. And that in turn meant that
 132   ; looking up the current message-ID would actually return the
 133   ; previous message ID.
 134   ;
 135   ; So this dance ensures that we're actually on the current message
 136   ; when it looks like we are.
 137   (end-of-visible-line)
 138   (beginning-of-line)
 139   (recenter 0))
 140
 141 (defun notmuch-show-previous-message ()
 142   "Backup to the beginning of the previous message in the buffer.
 143
 144 Does nothing if already on the first message in the buffer."
 145   (interactive)
 146   ; First, ensure we get off the current message marker
 147   (if (not (bobp))
 148       (previous-line))
 149   (re-search-backward notmuch-show-message-begin-regexp nil t)
 150   ; This dance might look pointless, but it's important. I originally
 151   ; just had (beginning-of-line) here which looked right on the
 152   ; display but actually put point all the way back to the first
 153   ; character of the first invisible line. That is, it put point into
 154   ; the closing markers of the previous message rather than at the
 155   ; beginning of the current message. And that in turn meant that
 156   ; looking up the current message-ID would actually return the
 157   ; previous message ID.
 158   ;
 159   ; So this dance ensures that we're actually on the current message
 160   ; when it looks like we are.
 161   (end-of-visible-line)
 162   (beginning-of-line)
 163   (recenter 0))
 164
 165 (defun notmuch-show-mark-read-then-next-message ()
 166   "Remove uread tag from current message, then advance to next message."
 167   (interactive)
 168   (if (member "unread" (notmuch-show-get-tags))
 169       (notmuch-show-remove-tag "unread"))
 170   (notmuch-show-next-message))
 171
 172 (defun notmuch-show-markup-citations-region (beg end)
 173   (goto-char beg)
 174   (beginning-of-line)
 175   (while (< (point) end)
 176     (let ((beg-sub (point)))
 177       (if (looking-at ">")
 178           (progn
 179             (while (looking-at ">")
 180               (next-line))
 181             (let ((overlay (make-overlay beg-sub (point))))
 182               (overlay-put overlay 'invisible 'notmuch-show-citation)
 183               (overlay-put overlay 'before-string
 184                            (concat "[" (number-to-string (count-lines beg-sub (point)))
 185                                    " quoted lines.]")))))
 186       (if (looking-at "--[ ]?$")
 187           (let ((overlay (make-overlay beg-sub end)))
 188             (overlay-put overlay 'invisible 'notmuch-show-signature)
 189             (overlay-put overlay 'before-string
 190                          (concat "[" (number-to-string (count-lines beg-sub (point)))
 191                                  "-line signature.]"))
 192             (goto-char end)))
 193       (next-line))))
 194
 195 (defun notmuch-show-markup-body ()
 196   (re-search-forward notmuch-show-body-begin-regexp)
 197   (next-line 1)
 198   (beginning-of-line)
 199   (let ((beg (point)))
 200     (re-search-forward notmuch-show-body-end-regexp)
 201     (let ((end (match-beginning 0)))
 202       (if (not (member "unread" (notmuch-show-get-tags)))
 203           (overlay-put (make-overlay beg end)
 204                        'invisible 'notmuch-show-body-read))
 205       (notmuch-show-markup-citations-region beg end))))
 206
 207 (defun notmuch-show-markup-header ()
 208   (re-search-forward notmuch-show-header-begin-regexp)
 209   (next-line 2)
 210   (beginning-of-line)
 211   (let ((beg (point)))
 212     (re-search-forward notmuch-show-header-end-regexp)
 213     (overlay-put (make-overlay beg (match-beginning 0))
 214                  'invisible 'notmuch-show-header)))
 215
 216 (defun notmuch-show-markup-message ()
 217   (if (re-search-forward notmuch-show-message-begin-regexp nil t)
 218       (progn
 219         (notmuch-show-markup-header)
 220         (notmuch-show-markup-body))
 221     (goto-char (point-max))))
 222
 223 (defun notmuch-show-hide-markers ()
 224   (save-excursion
 225     (goto-char (point-min))
 226     (while (not (eobp))
 227       (if (re-search-forward notmuch-show-marker-regexp nil t)
 228           (progn
 229             (overlay-put (make-overlay (match-beginning 0) (+ (match-end 0) 1))
 230                          'invisible 'notmuch-show-marker))
 231         (goto-char (point-max))))))
 232
 233 (defun notmuch-show-markup-messages ()
 234   (save-excursion
 235     (goto-char (point-min))
 236     (while (not (eobp))
 237       (notmuch-show-markup-message)))
 238   (notmuch-show-hide-markers))
 239
 240 (defun notmuch-show-toggle-citations-visible ()
 241   "Toggle visibility of citations"
 242   (interactive)
 243   (if notmuch-show-citations-visible
 244       (add-to-invisibility-spec 'notmuch-show-citation)
 245     (remove-from-invisibility-spec 'notmuch-show-citation))
 246   (set 'notmuch-show-citations-visible (not notmuch-show-citations-visible))
 247   ; Need to force the redisplay for some reason
 248   (force-window-update)
 249   (redisplay t))
 250
 251 (defun notmuch-show-toggle-signatures-visible ()
 252   "Toggle visibility of signatures"
 253   (interactive)
 254   (if notmuch-show-signatures-visible
 255       (add-to-invisibility-spec 'notmuch-show-signature)
 256     (remove-from-invisibility-spec 'notmuch-show-signature))
 257   (set 'notmuch-show-signatures-visible (not notmuch-show-signatures-visible))
 258   ; Need to force the redisplay for some reason
 259   (force-window-update)
 260   (redisplay t))
 261
 262 (defun notmuch-show-toggle-headers-visible ()
 263   "Toggle visibility of header fields"
 264   (interactive)
 265   (if notmuch-show-headers-visible
 266       (add-to-invisibility-spec 'notmuch-show-header)
 267     (remove-from-invisibility-spec 'notmuch-show-header))
 268   (set 'notmuch-show-headers-visible (not notmuch-show-headers-visible))
 269   ; Need to force the redisplay for some reason
 270   (force-window-update)
 271   (redisplay t))
 272
 273 (defun notmuch-show-toggle-body-read-visible ()
 274   "Toggle visibility of message bodies of read messages"
 275   (interactive)
 276   (if notmuch-show-body-read-visible
 277       (add-to-invisibility-spec 'notmuch-show-body-read)
 278     (remove-from-invisibility-spec 'notmuch-show-body-read))
 279   (set 'notmuch-show-body-read-visible (not notmuch-show-body-read-visible))
 280   ; Need to force the redisplay for some reason
 281   (force-window-update)
 282   (redisplay t))
 283
 284 ;;;###autoload
 285 (defun notmuch-show-mode ()
 286   "Major mode for handling the output of \"notmuch show\""
 287   (interactive)
 288   (kill-all-local-variables)
 289   (set (make-local-variable 'notmuch-show-headers-visible) t)
 290   (notmuch-show-toggle-headers-visible)
 291   (set (make-local-variable 'notmuch-show-body-read-visible) t)
 292   (notmuch-show-toggle-body-read-visible)
 293   (set (make-local-variable 'notmuch-show-citations-visible) t)
 294   (notmuch-show-toggle-citations-visible)
 295   (set (make-local-variable 'notmuch-show-signatures-visible) t)
 296   (notmuch-show-toggle-signatures-visible)
 297   (add-to-invisibility-spec 'notmuch-show-marker)
 298   (use-local-map notmuch-show-mode-map)
 299   (setq major-mode 'notmuch-show-mode
 300         mode-name "notmuch-show")
 301   (setq buffer-read-only t))
 302
 303 (defun notmuch-show (thread-id)
 304   "Run \"notmuch show\" with the given thread ID and display results."
 305   (interactive "sNotmuch show: ")
 306   (let ((buffer (get-buffer-create (concat "*notmuch-show-" thread-id "*"))))
 307     (switch-to-buffer buffer)
 308     (notmuch-show-mode)
 309     (let ((proc (get-buffer-process (current-buffer)))
 310           (inhibit-read-only t))
 311       (if proc
 312           (error "notmuch search process already running for query `%s'" query)
 313         )
 314       (erase-buffer)
 315       (goto-char (point-min))
 316       (save-excursion
 317         (call-process "notmuch" nil t nil "show" thread-id)
 318         (notmuch-show-markup-messages)
 319         )
 320       )))
 321
 322 (defvar notmuch-search-mode-map
 323   (let ((map (make-sparse-keymap)))
 324     (define-key map "a" 'notmuch-search-archive-thread)
 325     (define-key map "b" 'scroll-down)
 326     (define-key map "f" 'notmuch-search-filter)
 327     (define-key map "n" 'next-line)
 328     (define-key map "p" 'previous-line)
 329     (define-key map "q" 'kill-this-buffer)
 330     (define-key map "s" 'notmuch-search)
 331     (define-key map "x" 'kill-this-buffer)
 332     (define-key map "\r" 'notmuch-search-show-thread)
 333     (define-key map "+" 'notmuch-search-add-tag)
 334     (define-key map "-" 'notmuch-search-remove-tag)
 335     (define-key map "<" 'beginning-of-buffer)
 336     (define-key map ">" 'notmuch-search-goto-last-thread)
 337     (define-key map "=" 'notmuch-search-refresh-view)
 338     (define-key map "\M->" 'notmuch-search-goto-last-thread)
 339     (define-key map " " 'scroll-up)
 340     (define-key map (kbd "<DEL>") 'scroll-down)
 341     map)
 342   "Keymap for \"notmuch search\" buffers.")
 343 (fset 'notmuch-search-mode-map notmuch-search-mode-map)
 344
 345 (defun notmuch-search-goto-last-thread (&optional arg)
 346   "Move point to the last thread in the buffer."
 347   (interactive "^P")
 348   (end-of-buffer arg)
 349   (beginning-of-line))
 350
 351 ;;;###autoload
 352 (defun notmuch-search-mode ()
 353   "Major mode for handling the output of \"notmuch search\""
 354   (interactive)
 355   (kill-all-local-variables)
 356   (make-local-variable 'notmuch-search-query-string)
 357   (set (make-local-variable 'scroll-preserve-screen-position) t)
 358   (add-to-invisibility-spec 'notmuch-search)
 359   (use-local-map notmuch-search-mode-map)
 360   (setq major-mode 'notmuch-search-mode
 361         mode-name "notmuch-search")
 362   (setq buffer-read-only t))
 363
 364 (defun notmuch-search-find-thread-id ()
 365   (save-excursion
 366     (beginning-of-line)
 367     (let ((beg (point)))
 368       (re-search-forward "[a-fA-F0-9]*")
 369       (filter-buffer-substring beg (point)))))
 370
 371 (defun notmuch-search-markup-this-thread-id ()
 372   (beginning-of-line)
 373   (let ((beg (point)))
 374     (re-search-forward "[a-fA-F0-9]*")
 375     (forward-char)
 376     (overlay-put (make-overlay beg (point)) 'invisible 'notmuch-search)))
 377
 378 (defun notmuch-search-markup-thread-ids ()
 379   (save-excursion
 380     (goto-char (point-min))
 381     (while (not (eobp))
 382       (notmuch-search-markup-this-thread-id)
 383       (next-line))))
 384
 385 (defun notmuch-search-hide-thread-ids ()
 386   (interactive)
 387   (add-to-invisibility-spec 'notmuch-search)
 388   (force-window-update)
 389   (redisplay t))
 390
 391 (defun notmuch-search-show-thread-ids ()
 392   (interactive)
 393   (remove-from-invisibility-spec 'notmuch-search)
 394   (force-window-update)
 395   (redisplay t))
 396
 397 (defun notmuch-search-show-thread ()
 398   (interactive)
 399   (notmuch-show (notmuch-search-find-thread-id)))
 400
 401 (defun notmuch-call-notmuch-process (&rest args)
 402   (let ((error-buffer (get-buffer-create "*Notmuch errors*")))
 403     (with-current-buffer error-buffer
 404         (erase-buffer))
 405     (if (eq (apply 'call-process "notmuch" nil error-buffer nil args) 0)
 406         (point)
 407       (progn
 408         (with-current-buffer error-buffer
 409           (let ((beg (point-min))
 410                 (end (- (point-max) 1)))
 411             (error (buffer-substring beg end))
 412             ))))))
 413
 414 (defun notmuch-search-set-tags (tags)
 415   (save-excursion
 416     (end-of-line)
 417     (re-search-backward "(")
 418     (forward-char)
 419     (let ((beg (point))
 420           (inhibit-read-only t))
 421       (re-search-forward ")")
 422       (backward-char)
 423       (let ((end (point)))
 424         (delete-region beg end)
 425         (insert (mapconcat  'identity tags " "))))))
 426
 427 (defun notmuch-search-get-tags ()
 428   (save-excursion
 429     (end-of-line)
 430     (re-search-backward "(")
 431     (let ((beg (+ (point) 1)))
 432       (re-search-forward ")")
 433       (let ((end (- (point) 1)))
 434         (split-string (buffer-substring beg end))))))
 435
 436 (defun notmuch-search-add-tag (tag)
 437   (interactive "sTag to add: ")
 438   (notmuch-call-notmuch-process "tag" (concat "+" tag) (concat "thread:" (notmuch-search-find-thread-id)))
 439   (notmuch-search-set-tags (delete-dups (sort (cons tag (notmuch-search-get-tags)) 'string<))))
 440
 441 (defun notmuch-search-remove-tag (tag)
 442   (interactive "sTag to remove: ")
 443   (notmuch-call-notmuch-process "tag" (concat "-" tag) (concat "thread:" (notmuch-search-find-thread-id)))
 444   (notmuch-search-set-tags (delete tag (notmuch-search-get-tags))))
 445
 446 (defun notmuch-search-archive-thread ()
 447   (interactive)
 448   (notmuch-search-remove-tag "inbox"))
 449
 450 (defun notmuch-search (query)
 451   "Run \"notmuch search\" with the given query string and display results."
 452   (interactive "sNotmuch search: ")
 453   (let ((buffer (get-buffer-create (concat "*notmuch-search-" query "*"))))
 454     (switch-to-buffer buffer)
 455     (notmuch-search-mode)
 456     (set 'notmuch-search-query-string query)
 457     (let ((proc (get-buffer-process (current-buffer)))
 458           (inhibit-read-only t))
 459       (if proc
 460           (error "notmuch search process already running for query `%s'" query)
 461         )
 462       (erase-buffer)
 463       (goto-char (point-min))
 464       (save-excursion
 465         (call-process "notmuch" nil t nil "search" query)
 466         (notmuch-search-markup-thread-ids)
 467         ; A well-behaved program ends its output with a newline, but we
 468         ; don't actually want the blank line at the end of the file.
 469         (goto-char (point-max))
 470         (if (looking-at "^$")
 471             (delete-backward-char 1)
 472           )
 473         ))))
 474
 475 (defun notmuch-search-refresh-view ()
 476   "Refresh the current view.
 477
 478 Kills the current buffer and runs a new search with the same
 479 query string as the current search. If the current thread is in
 480 the new search results, then point will be placed on the same
 481 thread. Otherwise, point will be moved to attempt to be in the
 482 same relative position within the new buffer."
 483   (interactive)
 484   (let ((here (point))
 485         (thread (notmuch-search-find-thread-id))
 486         (query notmuch-search-query-string))
 487     (kill-this-buffer)
 488     (notmuch-search query)
 489     (goto-char (point-min))
 490     (if (re-search-forward (concat "^" thread) nil t)
 491         (beginning-of-line)
 492       (goto-char here))))
 493
 494 (defun notmuch-search-filter (query)
 495   "Run \"notmuch search\" to refine the current search results.
 496
 497 A search string will be constructed by appending QUERY to the
 498 current search string, and the results of \"notmuch search\" for
 499 the combined query will be displayed."
 500   (interactive "sFilter search: ")
 501   (notmuch-search (concat notmuch-search-query-string " and " query)))
 502
 503 (defun notmuch ()
 504   "Run notmuch to display all mail with tag of 'inbox'"
 505   (interactive)
 506   (notmuch-search "tag:inbox"))
 507
 508 (provide 'notmuch)